lisp/wdired.el

   1 ;;; wdired.el --- Rename files editing their names in dired buffers -*- coding: utf-8; -*-
   2
   3 ;; Copyright (C) 2004-2017 Free Software Foundation, Inc.
   4
   5 ;; Filename: wdired.el
   6 ;; Author: Juan León Lahoz García <juanleon1@gmail.com>
   7 ;; Version: 2.0
   8 ;; Keywords: dired, environment, files, renaming
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; wdired.el (the "w" is for writable) provides an alternative way of
  28 ;; renaming files.
  29 ;;
  30 ;; Have you ever wished to use C-x r t (string-rectangle), M-%
  31 ;; (query-replace), M-c (capitalize-word), etc... to change the name of
  32 ;; the files in a "dired" buffer? Now you can do this.  All the power
  33 ;; of Emacs commands are available to renaming files!
  34 ;;
  35 ;; This package provides a function that makes the filenames of a
  36 ;; dired buffer editable, by changing the buffer mode (which inhibits
  37 ;; all of the commands of dired mode). Here you can edit the names of
  38 ;; one or more files and directories, and when you press C-c C-c, the
  39 ;; renaming takes effect and you are back to dired mode.
  40 ;;
  41 ;; Another things you can do with WDired:
  42 ;;
  43 ;; - To move files to another directory (by typing their path,
  44 ;;   absolute or relative, as a part of the new filename).
  45 ;;
  46 ;; - To change the target of symbolic links.
  47 ;;
  48 ;; - To change the permission bits of the filenames (in systems with a
  49 ;;   working unix-alike `dired-chmod-program'). See and customize the
  50 ;;   variable `wdired-allow-to-change-permissions'.  To change a single
  51 ;;   char (toggling between its two more usual values) you can press
  52 ;;   the space bar over it or left-click the mouse.  To set any char to
  53 ;;   an specific value (this includes the SUID, SGID and STI bits) you
  54 ;;   can use the key labeled as the letter you want.  Please note that
  55 ;;   permissions of the links cannot be changed in that way, because
  56 ;;   the change would affect to their targets, and this would not be
  57 ;;   WYSIWYG :-).
  58 ;;
  59 ;; - To mark files for deletion, by deleting their whole filename.
  60
  61 ;;; Usage:
  62
  63 ;; You can edit the names of the files by typing C-x C-q or by
  64 ;; executing M-x wdired-change-to-wdired-mode.  Use C-c C-c when
  65 ;; finished or C-c C-k to abort.  While editing filenames, a new
  66 ;; submenu "WDired" is available at top level.  You can customize the
  67 ;; behavior of this package from this menu.
  68
  69 ;;; Change Log:
  70
  71 ;; Google is your friend (previous versions with complete changelogs
  72 ;; were posted to gnu.emacs.sources)
  73
  74 ;;; Code:
  75
  76 (require 'dired)
  77 (autoload 'dired-do-create-files-regexp "dired-aux")
  78
  79 (defgroup wdired nil
  80   "Mode to rename files by editing their names in dired buffers."
  81   :group 'dired)
  82
  83 (defcustom wdired-use-interactive-rename nil
  84   "If non-nil, WDired requires confirmation before actually renaming files.
  85 If nil, WDired doesn't require confirmation to change the file names,
  86 and the variable `wdired-confirm-overwrite' controls whether it is ok
  87 to overwrite files without asking."
  88   :type 'boolean
  89   :group 'wdired)
  90
  91 (defcustom wdired-confirm-overwrite t
  92   "If nil the renames can overwrite files without asking.
  93 This variable has no effect at all if `wdired-use-interactive-rename'
  94 is not nil."
  95   :type 'boolean
  96   :group 'wdired)
  97
  98 (defcustom wdired-use-dired-vertical-movement nil
  99   "If t, the \"up\" and \"down\" movement works as in Dired mode.
 100 That is, always move the point to the beginning of the filename at line.
 101
 102 If `sometimes', only move to the beginning of filename if the point is
 103 before it, and `track-eol' is non-nil.  This behavior is very handy
 104 when editing several filenames.
 105
 106 If nil, \"up\" and \"down\" movement is done as in any other buffer."
 107   :type '(choice (const :tag "As in any other mode" nil)
 108                  (const :tag "Smart cursor placement" sometimes)
 109                  (other :tag "As in dired mode" t))
 110   :group 'wdired)
 111
 112 (defcustom wdired-allow-to-redirect-links t
 113   "If non-nil, the target of the symbolic links are editable.
 114 In systems without symbolic links support, this variable has no effect
 115 at all."
 116   :type 'boolean
 117   :group 'wdired)
 118
 119 (defcustom wdired-allow-to-change-permissions nil
 120   "If non-nil, the permissions bits of the files are editable.
 121
 122 If t, to change a single bit, put the cursor over it and press the
 123 space bar, or left click over it.  You can also hit the letter you want
 124 to set: if this value is allowed, the character in the buffer will be
 125 changed.  Anyway, the point is advanced one position, so, for example,
 126 you can keep the <x> key pressed to give execution permissions to
 127 everybody to that file.
 128
 129 If `advanced', the bits are freely editable.  You can use
 130 `string-rectangle', `query-replace', etc.  You can put any value (even
 131 newlines), but if you want your changes to be useful, you better put a
 132 intelligible value.
 133
 134 Anyway, the real change of the permissions is done by the external
 135 program `dired-chmod-program', which must exist."
 136   :type '(choice (const :tag "Not allowed" nil)
 137                  (const :tag "Toggle/set bits" t)
 138                  (other :tag "Bits freely editable" advanced))
 139   :group 'wdired)
 140
 141 (defcustom wdired-keep-marker-rename t
 142   ;; Use t as default so that renamed files "take their markers with them".
 143   "Controls marking of files renamed in WDired.
 144 If t, files keep their previous marks when they are renamed.
 145 If a character, renamed files (whether previously marked or not)
 146 are afterward marked with that character.
 147 This option affects only files renamed by `wdired-finish-edit'.
 148 See `dired-keep-marker-rename' if you want to do the same for files
 149 renamed by `dired-do-rename' and `dired-do-rename-regexp'."
 150   :type '(choice (const :tag "Keep" t)
 151                  (character :tag "Mark" :value ?R))
 152   :version "24.3"
 153   :group 'wdired)
 154
 155 (defcustom wdired-create-parent-directories t
 156   "If non-nil, create parent directories of destination files.
 157 If non-nil, when you rename a file to a destination path within a
 158 nonexistent directory, wdired will create any parent directories
 159 necessary.  When nil, attempts to rename a file into a
 160 nonexistent directory will fail."
 161   :version "26.1"
 162   :type 'boolean
 163   :group 'wdired)
 164
 165 (defvar wdired-mode-map
 166   (let ((map (make-sparse-keymap)))
 167     (define-key map "\C-x\C-s" 'wdired-finish-edit)
 168     (define-key map "\C-c\C-c" 'wdired-finish-edit)
 169     (define-key map "\C-c\C-k" 'wdired-abort-changes)
 170     (define-key map "\C-c\C-[" 'wdired-abort-changes)
 171     (define-key map "\C-x\C-q" 'wdired-exit)
 172     (define-key map "\C-m"     'ignore)
 173     (define-key map "\C-j"     'ignore)
 174     (define-key map "\C-o"     'ignore)
 175     (define-key map [up]       'wdired-previous-line)
 176     (define-key map "\C-p"     'wdired-previous-line)
 177     (define-key map [down]     'wdired-next-line)
 178     (define-key map "\C-n"     'wdired-next-line)
 179
 180     (define-key map [menu-bar wdired]
 181       (cons "WDired" (make-sparse-keymap "WDired")))
 182     (define-key map [menu-bar wdired wdired-customize]
 183       '("Options" . wdired-customize))
 184     (define-key map [menu-bar wdired dashes]
 185       '("--"))
 186     (define-key map [menu-bar wdired wdired-abort-changes]
 187       '(menu-item "Abort Changes" wdired-abort-changes
 188                   :help "Abort changes and return to dired mode"))
 189     (define-key map [menu-bar wdired wdired-finish-edit]
 190       '("Commit Changes" . wdired-finish-edit))
 191
 192     (define-key map [remap upcase-word] 'wdired-upcase-word)
 193     (define-key map [remap capitalize-word] 'wdired-capitalize-word)
 194     (define-key map [remap downcase-word] 'wdired-downcase-word)
 195
 196     map)
 197   "Keymap used in `wdired-mode'.")
 198
 199 (defvar wdired-mode-hook nil
 200   "Hooks run when changing to WDired mode.")
 201
 202 ;; Local variables (put here to avoid compilation gripes)
 203 (defvar wdired-col-perm) ;; Column where the permission bits start
 204 (defvar wdired-old-content)
 205 (defvar wdired-old-point)
 206 (defvar wdired-old-marks)
 207
 208 (defun wdired-mode ()
 209   "Writable Dired (WDired) mode.
 210 \\<wdired-mode-map>
 211 In WDired mode, you can edit the names of the files in the
 212 buffer, the target of the links, and the permission bits of the
 213 files.
 214
 215 Type \\[wdired-finish-edit] to exit WDired mode, returning to
 216 Dired mode, and make your edits \"take effect\" by modifying the
 217 file and directory names, link targets, and/or file permissions
 218 on disk.  If you delete the filename of a file, it is flagged for
 219 deletion in the Dired buffer.
 220
 221 Type \\[wdired-abort-changes] to abort your edits and exit WDired mode.
 222
 223 Type \\[customize-group] RET wdired to customize WDired behavior.
 224
 225 The only editable texts in a WDired buffer are filenames,
 226 symbolic link targets, and filenames permission."
 227   (interactive)
 228   (error "This mode can be enabled only by `wdired-change-to-wdired-mode'"))
 229 (put 'wdired-mode 'mode-class 'special)
 230
 231
 232 ;;;###autoload
 233 (defun wdired-change-to-wdired-mode ()
 234   "Put a Dired buffer in Writable Dired (WDired) mode.
 235 \\<wdired-mode-map>
 236 In WDired mode, you can edit the names of the files in the
 237 buffer, the target of the links, and the permission bits of the
 238 files.  After typing \\[wdired-finish-edit], Emacs modifies the files and
 239 directories to reflect your edits.
 240
 241 See `wdired-mode'."
 242   (interactive)
 243   (unless (eq major-mode 'dired-mode)
 244     (error "Not a Dired buffer"))
 245   (set (make-local-variable 'wdired-old-content)
 246        (buffer-substring (point-min) (point-max)))
 247   (set (make-local-variable 'wdired-old-marks)
 248        (dired-remember-marks (point-min) (point-max)))
 249   (set (make-local-variable 'wdired-old-point) (point))
 250   (set (make-local-variable 'query-replace-skip-read-only) t)
 251   (add-function :after-while (local 'isearch-filter-predicate)
 252                 #'wdired-isearch-filter-read-only)
 253   (use-local-map wdired-mode-map)
 254   (force-mode-line-update)
 255   (setq buffer-read-only nil)
 256   (dired-unadvertise default-directory)
 257   (add-hook 'kill-buffer-hook 'wdired-check-kill-buffer nil t)
 258   (setq major-mode 'wdired-mode)
 259   (setq mode-name "Editable Dired")
 260   (setq revert-buffer-function 'wdired-revert)
 261   ;; I temp disable undo for performance: since I'm going to clear the
 262   ;; undo list, it can save more than a 9% of time with big
 263   ;; directories because setting properties modify the undo-list.
 264   (buffer-disable-undo)
 265   (wdired-preprocess-files)
 266   (if wdired-allow-to-change-permissions
 267       (wdired-preprocess-perms))
 268   (if (and wdired-allow-to-redirect-links (fboundp 'make-symbolic-link))
 269       (wdired-preprocess-symlinks))
 270   (buffer-enable-undo) ; Performance hack. See above.
 271   (set-buffer-modified-p nil)
 272   (setq buffer-undo-list nil)
 273   (run-mode-hooks 'wdired-mode-hook)
 274   (message "%s" (substitute-command-keys
 275                  "Press \\[wdired-finish-edit] when finished \
 276 or \\[wdired-abort-changes] to abort changes")))
 277
 278 (defun wdired-isearch-filter-read-only (beg end)
 279   "Skip matches that have a read-only property."
 280   (not (text-property-not-all (min beg end) (max beg end)
 281                               'read-only nil)))
 282
 283 ;; Protect the buffer so only the filenames can be changed, and put
 284 ;; properties so filenames (old and new) can be easily found.
 285 (defun wdired-preprocess-files ()
 286   (put-text-property (point-min) (1+ (point-min))'front-sticky t)
 287   (save-excursion
 288     (goto-char (point-min))
 289     (let ((b-protection (point))
 290           filename)
 291       (while (not (eobp))
 292         (setq filename (dired-get-filename nil t))
 293         (when (and filename
 294                    (not (member (file-name-nondirectory filename) '("." ".."))))
 295           (dired-move-to-filename)
 296           ;; The rear-nonsticky property below shall ensure that text preceding
 297           ;; the filename can't be modified.
 298           (add-text-properties
 299            (1- (point)) (point) `(old-name ,filename rear-nonsticky (read-only)))
 300           (put-text-property b-protection (point) 'read-only t)
 301           (setq b-protection (dired-move-to-end-of-filename t))
 302           (put-text-property (point) (1+ (point)) 'end-name t))
 303         (forward-line))
 304       (put-text-property b-protection (point-max) 'read-only t))))
 305
 306 ;; This code is a copy of some dired-get-filename lines.
 307 (defsubst wdired-normalize-filename (file unquotep)
 308   (when unquotep
 309     (setq file
 310           ;; FIXME: shouldn't we check for a `b' argument or somesuch before
 311           ;; doing such unquoting?  --Stef
 312           (read (concat
 313                  "\"" (replace-regexp-in-string
 314                        "\\([^\\]\\|\\`\\)\"" "\\1\\\\\"" file)
 315                  "\""))))
 316   (and file buffer-file-coding-system
 317        (not file-name-coding-system)
 318        (not default-file-name-coding-system)
 319        (setq file (encode-coding-string file buffer-file-coding-system)))
 320   file)
 321
 322 (defun wdired-get-filename (&optional no-dir old)
 323   "Return the filename at line.
 324 Similar to `dired-get-filename' but it doesn't rely on regexps.  It
 325 relies on WDired buffer's properties.  Optional arg NO-DIR with value
 326 non-nil means don't include directory.  Optional arg OLD with value
 327 non-nil means return old filename."
 328   ;; FIXME: Use dired-get-filename's new properties.
 329   (let (beg end file)
 330     (save-excursion
 331       (setq end (line-end-position))
 332       (beginning-of-line)
 333       (setq beg (next-single-property-change (point) 'old-name nil end))
 334       (unless (eq beg end)
 335         (if old
 336             (setq file (get-text-property beg 'old-name))
 337           ;; In the following form changed `(1+ beg)' to `beg' so that
 338           ;; the filename end is found even when the filename is empty.
 339           ;; Fixes error and spurious newlines when marking files for
 340           ;; deletion.
 341           (setq end (next-single-property-change beg 'end-name))
 342           (setq file (buffer-substring-no-properties (1+ beg) end)))
 343         ;; Don't unquote the old name, it wasn't quoted in the first place
 344         (and file (setq file (wdired-normalize-filename file (not old)))))
 345       (if (or no-dir old)
 346           file
 347         (and file (> (length file) 0)
 348              (concat (dired-current-directory) file))))))
 349
 350
 351 (defun wdired-change-to-dired-mode ()
 352   "Change the mode back to dired."
 353   (or (eq major-mode 'wdired-mode)
 354       (error "Not a Wdired buffer"))
 355   (let ((inhibit-read-only t))
 356     (remove-text-properties
 357      (point-min) (point-max)
 358      '(front-sticky nil rear-nonsticky nil read-only nil keymap nil)))
 359   (use-local-map dired-mode-map)
 360   (force-mode-line-update)
 361   (setq buffer-read-only t)
 362   (setq major-mode 'dired-mode)
 363   (setq mode-name "Dired")
 364   (dired-advertise)
 365   (remove-hook 'kill-buffer-hook 'wdired-check-kill-buffer t)
 366   (set (make-local-variable 'revert-buffer-function) 'dired-revert))
 367
 368
 369 (defun wdired-abort-changes ()
 370   "Abort changes and return to dired mode."
 371   (interactive)
 372   (let ((inhibit-read-only t))
 373     (erase-buffer)
 374     (insert wdired-old-content)
 375     (goto-char wdired-old-point))
 376   (wdired-change-to-dired-mode)
 377   (set-buffer-modified-p nil)
 378   (setq buffer-undo-list nil)
 379   (message "Changes aborted"))
 380
 381 (defun wdired-finish-edit ()
 382   "Actually rename files based on your editing in the Dired buffer."
 383   (interactive)
 384   (wdired-change-to-dired-mode)
 385   (let ((changes nil)
 386         (errors 0)
 387         files-deleted
 388         files-renamed
 389         some-file-names-unchanged
 390         file-old file-new tmp-value)
 391     (save-excursion
 392       (when (and wdired-allow-to-redirect-links
 393                  (fboundp 'make-symbolic-link))
 394         (setq tmp-value (wdired-do-symlink-changes))
 395         (setq errors (cdr tmp-value))
 396         (setq changes (car tmp-value)))
 397       (when (and wdired-allow-to-change-permissions
 398                  (boundp 'wdired-col-perm)) ; could have been changed
 399         (setq tmp-value (wdired-do-perm-changes))
 400         (setq errors (+ errors (cdr tmp-value)))
 401         (setq changes (or changes (car tmp-value))))
 402       (goto-char (point-max))
 403       (while (not (bobp))
 404         (setq file-old (wdired-get-filename nil t))
 405         (when file-old
 406           (setq file-new (wdired-get-filename))
 407           (if (equal file-new file-old)
 408               (setq some-file-names-unchanged t)
 409             (setq changes t)
 410             (if (not file-new)          ;empty filename!
 411                 (push file-old files-deleted)
 412               (when wdired-keep-marker-rename
 413                 (let ((mark (cond ((integerp wdired-keep-marker-rename)
 414                                    wdired-keep-marker-rename)
 415                                   (wdired-keep-marker-rename
 416                                    (cdr (assoc file-old wdired-old-marks)))
 417                                   (t nil))))
 418                   (when mark
 419                     (push (cons (substitute-in-file-name file-new) mark)
 420                           wdired-old-marks))))
 421               (push (cons file-old (substitute-in-file-name file-new))
 422                     files-renamed))))
 423         (forward-line -1)))
 424     (when files-renamed
 425       (setq errors (+ errors (wdired-do-renames files-renamed))))
 426     (if changes
 427         (progn
 428           ;; If we are displaying a single file (rather than the
 429           ;; contents of a directory), change dired-directory if that
 430           ;; file was renamed.  (This ought to be generalized to
 431           ;; handle the multiple files case, but that's less trivial).
 432           (when (and (stringp dired-directory)
 433                      (not (file-directory-p dired-directory))
 434                      (null some-file-names-unchanged)
 435                      (= (length files-renamed) 1))
 436             (setq dired-directory (cdr (car files-renamed))))
 437           ;; Re-sort the buffer.
 438           (revert-buffer)
 439           (let ((inhibit-read-only t))
 440             (dired-mark-remembered wdired-old-marks)))
 441       (let ((inhibit-read-only t))
 442         (remove-text-properties (point-min) (point-max)
 443                                 '(old-name nil end-name nil old-link nil
 444                                            end-link nil end-perm nil
 445                                            old-perm nil perm-changed nil))
 446         (message "(No changes to be performed)")))
 447     (when files-deleted
 448       (wdired-flag-for-deletion files-deleted))
 449     (when (> errors 0)
 450       (dired-log-summary (format "%d rename actions failed" errors) nil)))
 451   (set-buffer-modified-p nil)
 452   (setq buffer-undo-list nil))
 453
 454 (defun wdired-do-renames (renames)
 455   "Perform RENAMES in parallel."
 456   (let ((residue ())
 457         (progress nil)
 458         (errors 0)
 459         (overwrite (or (not wdired-confirm-overwrite) 1)))
 460     (while (or renames
 461                ;; We've done one round through the renames, we have found
 462                ;; some residue, but we also made some progress, so maybe
 463                ;; some of the residue were resolved: try again.
 464                (prog1 (setq renames residue)
 465                  (setq progress nil)
 466                  (setq residue nil)))
 467       (let* ((rename (pop renames))
 468              (file-new (cdr rename)))
 469         (cond
 470          ((rassoc file-new renames)
 471           (error "Trying to rename 2 files to the same name"))
 472          ((assoc file-new renames)
 473           ;; Renaming to a file name that already exists but will itself be
 474           ;; renamed as well.  Let's wait until that one gets renamed.
 475           (push rename residue))
 476          ((and (assoc file-new residue)
 477                ;; Make sure the file really exists: if it doesn't it's
 478                ;; not really a conflict.  It might be a temp-file generated
 479                ;; specifically to break a circular renaming.
 480                (file-exists-p file-new))
 481           ;; Renaming to a file name that already exists, needed to be renamed,
 482           ;; but whose renaming could not be performed right away.
 483           (if (or progress renames)
 484               ;; There's still a chance the conflict will be resolved.
 485               (push rename residue)
 486             ;; We have not made any progress and we've reached the end of
 487             ;; the renames, so we really have a circular conflict, and we
 488             ;; have to forcefully break the cycle.
 489             (message "Circular renaming: using temporary file name")
 490             (let ((tmp (make-temp-name file-new)))
 491               (push (cons (car rename) tmp) renames)
 492               (push (cons tmp file-new) residue))))
 493          (t
 494           (setq progress t)
 495           (let ((file-ori (car rename)))
 496             (if wdired-use-interactive-rename
 497                 (wdired-search-and-rename file-ori file-new)
 498               ;; If dired-rename-file autoloads dired-aux while
 499               ;; dired-backup-overwrite is locally bound,
 500               ;; dired-backup-overwrite won't be initialized.
 501               ;; So we must ensure dired-aux is loaded.
 502               (require 'dired-aux)
 503               (condition-case err
 504                   (let ((dired-backup-overwrite nil))
 505                     (and wdired-create-parent-directories
 506                          (wdired-create-parentdirs file-new))
 507                     (dired-rename-file file-ori file-new
 508                                        overwrite))
 509                 (error
 510                  (setq errors (1+ errors))
 511                  (dired-log "Rename `%s' to `%s' failed:\n%s\n"
 512                             file-ori file-new
 513                             err)))))))))
 514     errors))
 515
 516 (defun wdired-create-parentdirs (file-new)
 517   "Create parent directories for FILE-NEW if they don't exist."
 518   (and (not (file-exists-p (file-name-directory file-new)))
 519        (message "Creating directory for file %s" file-new)
 520        (make-directory (file-name-directory file-new) t)))
 521
 522 (defun wdired-exit ()
 523   "Exit wdired and return to dired mode.
 524 Just return to dired mode if there are no changes.  Otherwise,
 525 ask a yes-or-no question whether to save or cancel changes,
 526 and proceed depending on the answer."
 527   (interactive)
 528   (if (buffer-modified-p)
 529       (if (y-or-n-p (format "Buffer %s modified; save changes? "
 530                             (current-buffer)))
 531           (wdired-finish-edit)
 532         (wdired-abort-changes))
 533     (wdired-change-to-dired-mode)
 534     (set-buffer-modified-p nil)
 535     (setq buffer-undo-list nil)
 536     (message "(No changes need to be saved)")))
 537
 538 ;; Rename a file, searching it in a modified dired buffer, in order
 539 ;; to be able to use `dired-do-create-files-regexp' and get its
 540 ;; "benefits".
 541 (defun wdired-search-and-rename (filename-ori filename-new)
 542   (save-excursion
 543     (goto-char (point-max))
 544     (forward-line -1)
 545     (let ((done nil)
 546           curr-filename)
 547       (while (and (not done) (not (bobp)))
 548         (setq curr-filename (wdired-get-filename nil t))
 549         (if (equal curr-filename filename-ori)
 550             (progn
 551               (setq done t)
 552               (let ((inhibit-read-only t))
 553                 (dired-move-to-filename)
 554                 (search-forward (wdired-get-filename t) nil t)
 555                 (replace-match (file-name-nondirectory filename-ori) t t))
 556               (dired-do-create-files-regexp
 557                (function dired-rename-file)
 558                "Move" 1 ".*" filename-new nil t))
 559           (forward-line -1))))))
 560
 561 ;; marks a list of files for deletion
 562 (defun wdired-flag-for-deletion (filenames-ori)
 563   (save-excursion
 564     (goto-char (point-min))
 565     (while (not (eobp))
 566       (if (member (dired-get-filename nil t) filenames-ori)
 567           (dired-flag-file-deletion 1)
 568         (forward-line)))))
 569
 570 (defun wdired-customize ()
 571   "Customize WDired options."
 572   (interactive)
 573   (customize-apropos "wdired" 'groups))
 574
 575 (defun wdired-revert (&optional _arg _noconfirm)
 576   "Discard changes in the buffer and update it based on changes on disk.
 577 Optional arguments are ignored."
 578   (wdired-change-to-dired-mode)
 579   (revert-buffer)
 580   (wdired-change-to-wdired-mode))
 581
 582 (defun wdired-check-kill-buffer ()
 583   ;; FIXME: Can't we use the normal mechanism for that?  --Stef
 584   (if (and
 585        (buffer-modified-p)
 586        (not (y-or-n-p "Buffer changed. Discard changes and kill buffer? ")))
 587       (error "Error")))
 588
 589 (defun wdired-next-line (arg)
 590   "Move down lines then position at filename or the current column.
 591 See `wdired-use-dired-vertical-movement'.  Optional prefix ARG
 592 says how many lines to move; default is one line."
 593   (interactive "^p")
 594   (with-no-warnings (next-line arg))
 595   (if (or (eq wdired-use-dired-vertical-movement t)
 596           (and wdired-use-dired-vertical-movement
 597                (< (current-column)
 598                   (save-excursion (dired-move-to-filename)
 599                                   (current-column)))))
 600       (dired-move-to-filename)))
 601
 602 (defun wdired-previous-line (arg)
 603   "Move up lines then position at filename or the current column.
 604 See `wdired-use-dired-vertical-movement'.  Optional prefix ARG
 605 says how many lines to move; default is one line."
 606   (interactive "^p")
 607   (with-no-warnings (previous-line arg))
 608   (if (or (eq wdired-use-dired-vertical-movement t)
 609           (and wdired-use-dired-vertical-movement
 610                (< (current-column)
 611                   (save-excursion (dired-move-to-filename)
 612                                   (current-column)))))
 613       (dired-move-to-filename)))
 614
 615 ;; Put the needed properties to allow the user to change links' targets
 616 (defun wdired-preprocess-symlinks ()
 617   (let ((inhibit-read-only t))
 618     (save-excursion
 619       (goto-char (point-min))
 620       (while (not (eobp))
 621         (if (looking-at dired-re-sym)
 622             (progn
 623               (re-search-forward " -> \\(.*\\)$")
 624               (put-text-property (- (match-beginning 1) 2)
 625                                  (1- (match-beginning 1)) 'old-link
 626                                  (match-string-no-properties 1))
 627               (put-text-property (match-end 1) (1+ (match-end 1)) 'end-link t)
 628               (put-text-property (1- (match-beginning 1))
 629                                  (match-beginning 1)
 630                                  'rear-nonsticky '(read-only))
 631               (put-text-property (match-beginning 1)
 632                                  (match-end 1) 'read-only nil)))
 633         (forward-line)
 634         (beginning-of-line)))))
 635
 636
 637 (defun wdired-get-previous-link (&optional old move)
 638   "Return the next symlink target.
 639 If OLD, return the old target.  If MOVE, move point before it."
 640   (let (beg end target)
 641     (setq beg (previous-single-property-change (point) 'old-link nil))
 642     (if beg
 643         (progn
 644           (if old
 645               (setq target (get-text-property (1- beg) 'old-link))
 646             (setq end (next-single-property-change beg 'end-link))
 647             (setq target (buffer-substring-no-properties (1+ beg) end)))
 648           (if move (goto-char (1- beg)))))
 649     (and target (wdired-normalize-filename target t))))
 650
 651 (declare-function make-symbolic-link "fileio.c")
 652
 653 ;; Perform the changes in the target of the changed links.
 654 (defun wdired-do-symlink-changes ()
 655   (let ((changes nil)
 656         (errors 0)
 657         link-to-ori link-to-new link-from)
 658     (goto-char (point-max))
 659     (while (setq link-to-new (wdired-get-previous-link))
 660       (setq link-to-ori (wdired-get-previous-link t t))
 661       (setq link-from (wdired-get-filename nil t))
 662       (unless (equal link-to-new link-to-ori)
 663         (setq changes t)
 664         (if (equal link-to-new "") ;empty filename!
 665             (setq link-to-new "/dev/null"))
 666         (condition-case err
 667             (progn
 668               (delete-file link-from)
 669               (make-symbolic-link
 670                (substitute-in-file-name link-to-new) link-from))
 671           (error
 672            (setq errors (1+ errors))
 673            (dired-log "Link `%s' to `%s' failed:\n%s\n"
 674                       link-from link-to-new
 675                       err)))))
 676     (cons changes errors)))
 677
 678 ;; Perform a "case command" skipping read-only words.
 679 (defun wdired-xcase-word (command arg)
 680   (if (< arg 0)
 681       (funcall command arg)
 682     (while (> arg 0)
 683       (condition-case nil
 684           (progn
 685             (funcall command 1)
 686             (setq arg (1- arg)))
 687         (error
 688          (if (forward-word-strictly)
 689              ;; Skip any non-word characters to avoid triggering a read-only
 690              ;; error which would cause skipping the next word characters too.
 691              (skip-syntax-forward "^w")
 692            (setq arg 0)))))))
 693
 694 (defun wdired-downcase-word (arg)
 695   "WDired version of `downcase-word'.
 696 Like original function but it skips read-only words."
 697   (interactive "p")
 698   (wdired-xcase-word 'downcase-word arg))
 699
 700 (defun wdired-upcase-word (arg)
 701   "WDired version of `upcase-word'.
 702 Like original function but it skips read-only words."
 703   (interactive "p")
 704   (wdired-xcase-word 'upcase-word arg))
 705
 706 (defun wdired-capitalize-word (arg)
 707   "WDired version of `capitalize-word'.
 708 Like original function but it skips read-only words."
 709   (interactive "p")
 710   (wdired-xcase-word 'capitalize-word arg))
 711
 712
 713 ;; The following code deals with changing the access bits (or
 714 ;; permissions) of the files.
 715
 716 (defvar wdired-perm-mode-map
 717   (let ((map (make-sparse-keymap)))
 718     (define-key map " " 'wdired-toggle-bit)
 719     (define-key map "r" 'wdired-set-bit)
 720     (define-key map "w" 'wdired-set-bit)
 721     (define-key map "x" 'wdired-set-bit)
 722     (define-key map "-" 'wdired-set-bit)
 723     (define-key map "S" 'wdired-set-bit)
 724     (define-key map "s" 'wdired-set-bit)
 725     (define-key map "T" 'wdired-set-bit)
 726     (define-key map "t" 'wdired-set-bit)
 727     (define-key map "s" 'wdired-set-bit)
 728     (define-key map "l" 'wdired-set-bit)
 729     (define-key map [down-mouse-1] 'wdired-mouse-toggle-bit)
 730     map))
 731
 732 ;; Put a keymap property to the permission bits of the files, and store the
 733 ;; original name and permissions as a property
 734 (defun wdired-preprocess-perms ()
 735   (let ((inhibit-read-only t))
 736     (set (make-local-variable 'wdired-col-perm) nil)
 737     (save-excursion
 738       (goto-char (point-min))
 739       (while (not (eobp))
 740         (when (and (not (looking-at dired-re-sym))
 741                    (wdired-get-filename)
 742                    (re-search-forward dired-re-perms (line-end-position) 'eol))
 743           (let ((begin (match-beginning 0))
 744                 (end (match-end 0)))
 745             (unless wdired-col-perm
 746               (setq wdired-col-perm (- (current-column) 9)))
 747             (if (eq wdired-allow-to-change-permissions 'advanced)
 748                 (progn
 749                   (put-text-property begin end 'read-only nil)
 750                   ;; make first permission bit writable
 751                   (put-text-property
 752                    (1- begin) begin 'rear-nonsticky '(read-only)))
 753               ;; avoid that keymap applies to text following permissions
 754               (add-text-properties
 755                (1+ begin) end
 756                `(keymap ,wdired-perm-mode-map rear-nonsticky (keymap))))
 757             (put-text-property end (1+ end) 'end-perm t)
 758             (put-text-property
 759              begin (1+ begin) 'old-perm (match-string-no-properties 0))))
 760         (forward-line)
 761         (beginning-of-line)))))
 762
 763 (defun wdired-perm-allowed-in-pos (char pos)
 764   (cond
 765    ((= char ?-)          t)
 766    ((= char ?r)          (= (% pos 3) 0))
 767    ((= char ?w)          (= (% pos 3) 1))
 768    ((= char ?x)          (= (% pos 3) 2))
 769    ((memq char '(?s ?S)) (memq pos '(2 5)))
 770    ((memq char '(?t ?T)) (= pos 8))
 771    ((= char ?l)          (= pos 5))))
 772
 773 (defun wdired-set-bit ()
 774   "Set a permission bit character."
 775   (interactive)
 776   (if (wdired-perm-allowed-in-pos last-command-event
 777                                   (- (current-column) wdired-col-perm))
 778       (let ((new-bit (char-to-string last-command-event))
 779             (inhibit-read-only t)
 780             (pos-prop (- (point) (- (current-column) wdired-col-perm))))
 781         (put-text-property 0 1 'keymap wdired-perm-mode-map new-bit)
 782         (put-text-property 0 1 'read-only t new-bit)
 783         (insert new-bit)
 784         (delete-char 1)
 785         (put-text-property (1- pos-prop) pos-prop 'perm-changed t)
 786         (put-text-property (1- (point)) (point) 'rear-nonsticky '(keymap)))
 787     (forward-char 1)))
 788
 789 (defun wdired-toggle-bit ()
 790   "Toggle the permission bit at point."
 791   (interactive)
 792   (let ((inhibit-read-only t)
 793         (new-bit "-")
 794         (pos-prop (- (point) (- (current-column) wdired-col-perm))))
 795     (if (eq (char-after (point)) ?-)
 796         (setq new-bit
 797               (if (= (% (- (current-column) wdired-col-perm) 3) 0) "r"
 798                 (if (= (% (- (current-column) wdired-col-perm) 3) 1) "w"
 799                   "x"))))
 800     (put-text-property 0 1 'keymap wdired-perm-mode-map new-bit)
 801     (put-text-property 0 1 'read-only t new-bit)
 802     (insert new-bit)
 803     (delete-char 1)
 804     (put-text-property (1- pos-prop) pos-prop 'perm-changed t)
 805     (put-text-property (1- (point)) (point) 'rear-nonsticky '(keymap))))
 806
 807 (defun wdired-mouse-toggle-bit (event)
 808   "Toggle the permission bit that was left clicked."
 809   (interactive "e")
 810   (mouse-set-point event)
 811   (wdired-toggle-bit))
 812
 813 ;; Allowed chars for 4000 bit are Ss  in position 3
 814 ;; Allowed chars for 2000 bit are Ssl in position 6
 815 ;; Allowed chars for 1000 bit are Tt  in position 9
 816 (defun wdired-perms-to-number (perms)
 817   (let ((nperm 0777))
 818     (if (= (elt perms 1) ?-) (setq nperm (- nperm 400)))
 819     (if (= (elt perms 2) ?-) (setq nperm (- nperm 200)))
 820     (let ((p-bit (elt perms 3)))
 821       (if (memq p-bit '(?- ?S)) (setq nperm (- nperm 100)))
 822       (if (memq p-bit '(?s ?S)) (setq nperm (+ nperm 4000))))
 823     (if (= (elt perms 4) ?-) (setq nperm (- nperm 40)))
 824     (if (= (elt perms 5) ?-) (setq nperm (- nperm 20)))
 825     (let ((p-bit (elt perms 6)))
 826       (if (memq p-bit '(?- ?S ?l)) (setq nperm (- nperm 10)))
 827       (if (memq p-bit '(?s ?S ?l)) (setq nperm (+ nperm 2000))))
 828     (if (= (elt perms 7) ?-) (setq nperm (- nperm 4)))
 829     (if (= (elt perms 8) ?-) (setq nperm (- nperm 2)))
 830     (let ((p-bit (elt perms 9)))
 831       (if (memq p-bit '(?- ?T)) (setq nperm (- nperm 1)))
 832       (if (memq p-bit '(?t ?T)) (setq nperm (+ nperm 1000))))
 833     nperm))
 834
 835 ;; Perform the changes in the permissions of the files that have
 836 ;; changed.
 837 (defun wdired-do-perm-changes ()
 838   (let ((changes nil)
 839         (errors 0)
 840         (prop-wanted (if (eq wdired-allow-to-change-permissions 'advanced)
 841                          'old-perm 'perm-changed))
 842         filename perms-ori perms-new perm-tmp)
 843     (goto-char (next-single-property-change (point-min) prop-wanted
 844                                             nil (point-max)))
 845     (while (not (eobp))
 846       (setq perms-ori (get-text-property (point) 'old-perm))
 847       (setq perms-new (buffer-substring-no-properties
 848                        (point) (next-single-property-change (point) 'end-perm)))
 849       (unless (equal perms-ori perms-new)
 850         (setq changes t)
 851         (setq filename (wdired-get-filename nil t))
 852         (if (= (length perms-new) 10)
 853             (progn
 854               (setq perm-tmp
 855                     (int-to-string (wdired-perms-to-number perms-new)))
 856               (unless (equal 0 (process-file dired-chmod-program
 857                                              nil nil nil perm-tmp filename))
 858                 (setq errors (1+ errors))
 859                 (dired-log "%s %s `%s' failed\n\n"
 860                            dired-chmod-program perm-tmp filename)))
 861           (setq errors (1+ errors))
 862           (dired-log "Cannot parse permission `%s' for file `%s'\n\n"
 863                      perms-new filename)))
 864       (goto-char (next-single-property-change (1+ (point)) prop-wanted
 865                                               nil (point-max))))
 866     (cons changes errors)))
 867
 868 (provide 'wdired)
 869
 870 ;; Local Variables:
 871 ;; byte-compile-dynamic: t
 872 ;; End:
 873
 874 ;;; wdired.el ends here