Crunch some deleted functions.
[emacs.git] / lisp / calendar / lunar.el
blob1e779452886678f01c5889238c247a0760edcfb1
1 ;;; lunar.el --- calendar functions for phases of the moon
3 ;; Copyright (C) 1992, 1993, 1995, 1997, 2001, 2002, 2003, 2004, 2005,
4 ;; 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
6 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
8 ;; Keywords: calendar
9 ;; Human-Keywords: moon, lunar phases, calendar, diary
11 ;; This file is part of GNU Emacs.
13 ;; GNU Emacs is free software: you can redistribute it and/or modify
14 ;; it under the terms of the GNU General Public License as published by
15 ;; the Free Software Foundation, either version 3 of the License, or
16 ;; (at your option) any later version.
18 ;; GNU Emacs is distributed in the hope that it will be useful,
19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
21 ;; GNU General Public License for more details.
23 ;; You should have received a copy of the GNU General Public License
24 ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
26 ;;; Commentary:
28 ;; See calendar.el.
30 ;; Based on ``Astronomical Formulae for Calculators,'' 3rd ed., by Jean Meeus,
31 ;; Willmann-Bell, Inc., 1985 and ``Astronomical Algorithms'' by Jean Meeus,
32 ;; Willmann-Bell, Inc., 1991.
34 ;; WARNING: The calculations will be accurate only to within a few minutes.
36 ;; The author would be delighted to have an astronomically more sophisticated
37 ;; person rewrite the code for the lunar calculations in this file!
39 ;;; Code:
41 (require 'calendar)
42 (require 'solar)
43 (require 'cal-dst)
44 ;; calendar-astro-to-absolute and v versa are cal-autoloads.
45 ;;;(require 'cal-julian)
47 (defun lunar-phase (index)
48 "Local date and time of lunar phase INDEX.
49 Integer below INDEX/4 gives the lunation number, counting from Jan 1, 1900;
50 remainder mod 4 gives the phase: 0 new moon, 1 first quarter, 2 full moon,
51 3 last quarter."
52 (let* ((phase (mod index 4))
53 (index (/ index 4.0))
54 (time (/ index 1236.85))
55 (date (+ (calendar-absolute-from-gregorian '(1 0.5 1900))
56 0.75933
57 (* 29.53058868 index)
58 (* 0.0001178 time time)
59 (* -0.000000155 time time time)
60 (* 0.00033
61 (solar-sin-degrees (+ 166.56
62 (* 132.87 time)
63 (* -0.009173 time time))))))
64 (sun-anomaly (mod
65 (+ 359.2242
66 (* 29.105356 index)
67 (* -0.0000333 time time)
68 (* -0.00000347 time time time))
69 360.0))
70 (moon-anomaly (mod
71 (+ 306.0253
72 (* 385.81691806 index)
73 (* 0.0107306 time time)
74 (* 0.00001236 time time time))
75 360.0))
76 (moon-lat (mod
77 (+ 21.2964
78 (* 390.67050646 index)
79 (* -0.0016528 time time)
80 (* -0.00000239 time time time))
81 360.0))
82 (adjustment
83 (if (memq phase '(0 2))
84 (+ (* (- 0.1734 (* 0.000393 time))
85 (solar-sin-degrees sun-anomaly))
86 (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
87 (* -0.4068 (solar-sin-degrees moon-anomaly))
88 (* 0.0161 (solar-sin-degrees (* 2 moon-anomaly)))
89 (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
90 (* 0.0104 (solar-sin-degrees (* 2 moon-lat)))
91 (* -0.0051 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
92 (* -0.0074 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
93 (* 0.0004 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
94 (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
95 (* -0.0006 (solar-sin-degrees
96 (+ (* 2 moon-lat) moon-anomaly)))
97 (* 0.0010 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
98 (* 0.0005 (solar-sin-degrees
99 (+ (* 2 moon-anomaly) sun-anomaly))))
100 (+ (* (- 0.1721 (* 0.0004 time))
101 (solar-sin-degrees sun-anomaly))
102 (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
103 (* -0.6280 (solar-sin-degrees moon-anomaly))
104 (* 0.0089 (solar-sin-degrees (* 2 moon-anomaly)))
105 (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
106 (* 0.0079 (solar-sin-degrees (* 2 moon-lat)))
107 (* -0.0119 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
108 (* -0.0047 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
109 (* 0.0003 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
110 (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
111 (* -0.0006 (solar-sin-degrees (+ (* 2 moon-lat) moon-anomaly)))
112 (* 0.0021 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
113 (* 0.0003 (solar-sin-degrees
114 (+ (* 2 moon-anomaly) sun-anomaly)))
115 (* 0.0004 (solar-sin-degrees
116 (- sun-anomaly (* 2 moon-anomaly))))
117 (* -0.0003 (solar-sin-degrees
118 (+ (* 2 sun-anomaly) moon-anomaly))))))
119 (adj (+ 0.0028
120 (* -0.0004 (solar-cosine-degrees
121 sun-anomaly))
122 (* 0.0003 (solar-cosine-degrees
123 moon-anomaly))))
124 (adjustment (cond ((= phase 1) (+ adjustment adj))
125 ((= phase 2) (- adjustment adj))
126 (t adjustment)))
127 (date (+ date adjustment))
128 (date (+ date (/ (- calendar-time-zone
129 (solar-ephemeris-correction
130 (calendar-extract-year
131 (calendar-gregorian-from-absolute
132 (truncate date)))))
133 60.0 24.0)))
134 (time (* 24 (- date (truncate date))))
135 (date (calendar-gregorian-from-absolute (truncate date)))
136 (adj (dst-adjust-time date time)))
137 (list (car adj) (apply 'solar-time-string (cdr adj)) phase)))
139 (defun lunar-phase-list (month year)
140 "List of lunar phases for three months starting with Gregorian MONTH, YEAR."
141 (let* ((end-month month)
142 (end-year year)
143 (start-month month)
144 (start-year year)
145 (end-date (progn
146 (calendar-increment-month end-month end-year 3)
147 (list (list end-month 1 end-year))))
148 (start-date (progn
149 (calendar-increment-month start-month start-year -1)
150 (list (list start-month
151 (calendar-last-day-of-month
152 start-month start-year)
153 start-year))))
154 (index (* 4 (truncate
155 (* 12.3685
156 (+ year
157 ( / (calendar-day-number (list month 1 year))
158 366.0)
159 -1900)))))
160 (new-moon (lunar-phase index))
161 list)
162 (while (calendar-date-compare new-moon end-date)
163 (if (calendar-date-compare start-date new-moon)
164 (setq list (append list (list new-moon))))
165 (setq index (1+ index)
166 new-moon (lunar-phase index)))
167 list))
169 (defun lunar-phase-name (phase)
170 "Name of lunar PHASE.
171 0 = new moon, 1 = first quarter, 2 = full moon, 3 = last quarter."
172 (cond ((= 0 phase) "New Moon")
173 ((= 1 phase) "First Quarter Moon")
174 ((= 2 phase) "Full Moon")
175 ((= 3 phase) "Last Quarter Moon")))
177 (defvar displayed-month) ; from calendar-generate
178 (defvar displayed-year)
180 ;;;###cal-autoload
181 (defun calendar-lunar-phases (&optional event)
182 "Create a buffer with the lunar phases for the current calendar window.
183 If EVENT is non-nil, it's an event indicating the buffer position to
184 use instead of point."
185 (interactive (list last-nonmenu-event))
186 ;; If called from a menu, with the calendar window not selected.
187 (with-current-buffer
188 (if event (window-buffer (posn-window (event-start event)))
189 (current-buffer))
190 (message "Computing phases of the moon...")
191 (let ((m1 displayed-month)
192 (y1 displayed-year)
193 (m2 displayed-month)
194 (y2 displayed-year))
195 (calendar-increment-month m1 y1 -1)
196 (calendar-increment-month m2 y2 1)
197 (calendar-in-read-only-buffer lunar-phases-buffer
198 (calendar-set-mode-line
199 (if (= y1 y2)
200 (format "Phases of the Moon from %s to %s, %d%%-"
201 (calendar-month-name m1) (calendar-month-name m2) y2)
202 (format "Phases of the Moon from %s, %d to %s, %d%%-"
203 (calendar-month-name m1) y1 (calendar-month-name m2) y2)))
204 (insert
205 (mapconcat
206 (lambda (x)
207 (let ((date (car x))
208 (time (cadr x))
209 (phase (nth 2 x)))
210 (concat (calendar-date-string date)
211 ": "
212 (lunar-phase-name phase)
214 time)))
215 (lunar-phase-list m1 y1) "\n")))
216 (message "Computing phases of the moon...done"))))
218 ;;;###cal-autoload
219 (define-obsolete-function-alias 'calendar-phases-of-moon
220 'calendar-lunar-phases "23.1")
222 ;;;###autoload
223 (defun lunar-phases (&optional arg)
224 "Display the quarters of the moon for last month, this month, and next month.
225 If called with an optional prefix argument ARG, prompts for month and year.
226 This function is suitable for execution in a .emacs file."
227 (interactive "P")
228 (save-excursion
229 (let* ((date (if arg (calendar-read-date t)
230 (calendar-current-date)))
231 (displayed-month (calendar-extract-month date))
232 (displayed-year (calendar-extract-year date)))
233 (calendar-lunar-phases))))
235 ;;;###autoload
236 (define-obsolete-function-alias 'phases-of-moon 'lunar-phases "23.1")
238 (defvar date)
240 ;; To be called from diary-list-sexp-entries, where DATE is bound.
242 ;;;###diary-autoload
243 (defun diary-lunar-phases (&optional mark)
244 "Moon phases diary entry.
245 An optional parameter MARK specifies a face or single-character string to
246 use when highlighting the day in the calendar."
247 (let* ((index (* 4
248 (truncate
249 (* 12.3685
250 (+ (calendar-extract-year date)
251 ( / (calendar-day-number date)
252 366.0)
253 -1900)))))
254 (phase (lunar-phase index)))
255 (while (calendar-date-compare phase (list date))
256 (setq index (1+ index)
257 phase (lunar-phase index)))
258 (if (calendar-date-equal (car phase) date)
259 (cons mark (concat (lunar-phase-name (nth 2 phase)) " "
260 (cadr phase))))))
262 ;;;###diary-autoload
263 (define-obsolete-function-alias 'diary-phases-of-moon
264 'diary-lunar-phases "23.1")
266 ;; For the Chinese calendar the calculations for the new moon need to be more
267 ;; accurate than those above, so we use more terms in the approximation.
268 (defun lunar-new-moon-time (k)
269 "Astronomical (Julian) day number of K th new moon."
270 (let* ((T (/ k 1236.85))
271 (T2 (* T T))
272 (T3 (* T T T))
273 (T4 (* T2 T2))
274 (JDE (+ 2451550.09765
275 (* 29.530588853 k)
276 (* 0.0001337 T2)
277 (* -0.000000150 T3)
278 (* 0.00000000073 T4)))
279 (E (- 1 (* 0.002516 T) (* 0.0000074 T2)))
280 (sun-anomaly (+ 2.5534
281 (* 29.10535669 k)
282 (* -0.0000218 T2)
283 (* -0.00000011 T3)))
284 (moon-anomaly (+ 201.5643
285 (* 385.81693528 k)
286 (* 0.0107438 T2)
287 (* 0.00001239 T3)
288 (* -0.000000058 T4)))
289 (moon-argument (+ 160.7108
290 (* 390.67050274 k)
291 (* -0.0016341 T2)
292 (* -0.00000227 T3)
293 (* 0.000000011 T4)))
294 (omega (+ 124.7746
295 (* -1.56375580 k)
296 (* 0.0020691 T2)
297 (* 0.00000215 T3)))
298 (A1 (+ 299.77 (* 0.107408 k) (* -0.009173 T2)))
299 (A2 (+ 251.88 (* 0.016321 k)))
300 (A3 (+ 251.83 (* 26.641886 k)))
301 (A4 (+ 349.42 (* 36.412478 k)))
302 (A5 (+ 84.66 (* 18.206239 k)))
303 (A6 (+ 141.74 (* 53.303771 k)))
304 (A7 (+ 207.14 (* 2.453732 k)))
305 (A8 (+ 154.84 (* 7.306860 k)))
306 (A9 (+ 34.52 (* 27.261239 k)))
307 (A10 (+ 207.19 (* 0.121824 k)))
308 (A11 (+ 291.34 (* 1.844379 k)))
309 (A12 (+ 161.72 (* 24.198154 k)))
310 (A13 (+ 239.56 (* 25.513099 k)))
311 (A14 (+ 331.55 (* 3.592518 k)))
312 (correction
313 (+ (* -0.40720 (solar-sin-degrees moon-anomaly))
314 (* 0.17241 E (solar-sin-degrees sun-anomaly))
315 (* 0.01608 (solar-sin-degrees (* 2 moon-anomaly)))
316 (* 0.01039 (solar-sin-degrees (* 2 moon-argument)))
317 (* 0.00739 E (solar-sin-degrees (- moon-anomaly sun-anomaly)))
318 (* -0.00514 E (solar-sin-degrees (+ moon-anomaly sun-anomaly)))
319 (* 0.00208 E E (solar-sin-degrees (* 2 sun-anomaly)))
320 (* -0.00111 (solar-sin-degrees
321 (- moon-anomaly (* 2 moon-argument))))
322 (* -0.00057 (solar-sin-degrees
323 (+ moon-anomaly (* 2 moon-argument))))
324 (* 0.00056 E (solar-sin-degrees
325 (+ (* 2 moon-anomaly) sun-anomaly)))
326 (* -0.00042 (solar-sin-degrees (* 3 moon-anomaly)))
327 (* 0.00042 E (solar-sin-degrees
328 (+ sun-anomaly (* 2 moon-argument))))
329 (* 0.00038 E (solar-sin-degrees
330 (- sun-anomaly (* 2 moon-argument))))
331 (* -0.00024 E (solar-sin-degrees
332 (- (* 2 moon-anomaly) sun-anomaly)))
333 (* -0.00017 (solar-sin-degrees omega))
334 (* -0.00007 (solar-sin-degrees
335 (+ moon-anomaly (* 2 sun-anomaly))))
336 (* 0.00004 (solar-sin-degrees
337 (- (* 2 moon-anomaly) (* 2 moon-argument))))
338 (* 0.00004 (solar-sin-degrees (* 3 sun-anomaly)))
339 (* 0.00003 (solar-sin-degrees (+ moon-anomaly sun-anomaly
340 (* -2 moon-argument))))
341 (* 0.00003 (solar-sin-degrees
342 (+ (* 2 moon-anomaly) (* 2 moon-argument))))
343 (* -0.00003 (solar-sin-degrees (+ moon-anomaly sun-anomaly
344 (* 2 moon-argument))))
345 (* 0.00003 (solar-sin-degrees (- moon-anomaly sun-anomaly
346 (* -2 moon-argument))))
347 (* -0.00002 (solar-sin-degrees (- moon-anomaly sun-anomaly
348 (* 2 moon-argument))))
349 (* -0.00002 (solar-sin-degrees
350 (+ (* 3 moon-anomaly) sun-anomaly)))
351 (* 0.00002 (solar-sin-degrees (* 4 moon-anomaly)))))
352 (additional
353 (+ (* 0.000325 (solar-sin-degrees A1))
354 (* 0.000165 (solar-sin-degrees A2))
355 (* 0.000164 (solar-sin-degrees A3))
356 (* 0.000126 (solar-sin-degrees A4))
357 (* 0.000110 (solar-sin-degrees A5))
358 (* 0.000062 (solar-sin-degrees A6))
359 (* 0.000060 (solar-sin-degrees A7))
360 (* 0.000056 (solar-sin-degrees A8))
361 (* 0.000047 (solar-sin-degrees A9))
362 (* 0.000042 (solar-sin-degrees A10))
363 (* 0.000040 (solar-sin-degrees A11))
364 (* 0.000037 (solar-sin-degrees A12))
365 (* 0.000035 (solar-sin-degrees A13))
366 (* 0.000023 (solar-sin-degrees A14))))
367 (newJDE (+ JDE correction additional)))
368 (+ newJDE
369 (- (solar-ephemeris-correction
370 (calendar-extract-year
371 (calendar-gregorian-from-absolute
372 (floor (calendar-astro-to-absolute newJDE))))))
373 (/ calendar-time-zone 60.0 24.0))))
375 (defun lunar-new-moon-on-or-after (d)
376 "Julian day number of first new moon on or after Julian day number D.
377 The fractional part is the time of day.
379 The date and time are local time, including any daylight saving rules,
380 as governed by the values of `calendar-daylight-savings-starts',
381 `calendar-daylight-savings-starts-time', `calendar-daylight-savings-ends',
382 `calendar-daylight-savings-ends-time', `calendar-daylight-time-offset', and
383 `calendar-time-zone'."
384 (let* ((date (calendar-gregorian-from-absolute
385 (floor (calendar-astro-to-absolute d))))
386 (year (+ (calendar-extract-year date)
387 (/ (calendar-day-number date) 365.25)))
388 (k (floor (* (- year 2000.0) 12.3685)))
389 (date (lunar-new-moon-time k))
390 (a-date (progn
391 (while (< date d)
392 (setq k (1+ k)
393 date (lunar-new-moon-time k)))
394 (calendar-astro-to-absolute date)))
395 (time (* 24 (- a-date (truncate a-date))))
396 (date (calendar-gregorian-from-absolute (truncate a-date)))
397 (adj (dst-adjust-time date time)))
398 (calendar-astro-from-absolute
399 (+ (calendar-absolute-from-gregorian (car adj))
400 (/ (cadr adj) 24.0)))))
402 (provide 'lunar)
404 ;; arch-tag: 72f0b8a4-7bcc-4a1b-b67a-ff53c4a1d222
405 ;;; lunar.el ends here