lisp/org/ob-ruby.el

   1 ;;; ob-ruby.el --- org-babel functions for ruby evaluation
   2
   3 ;; Copyright (C) 2009-2011  Free Software Foundation
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.4
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating ruby source code.
  28
  29 ;;; Requirements:
  30
  31 ;; - ruby and irb executables :: http://www.ruby-lang.org/
  32 ;;
  33 ;; - ruby-mode :: Can be installed through ELPA, or from
  34 ;;   http://github.com/eschulte/rinari/raw/master/util/ruby-mode.el
  35 ;;
  36 ;; - inf-ruby mode :: Can be installed through ELPA, or from
  37 ;;   http://github.com/eschulte/rinari/raw/master/util/inf-ruby.el
  38
  39 ;;; Code:
  40 (require 'ob)
  41 (require 'ob-ref)
  42 (require 'ob-comint)
  43 (require 'ob-eval)
  44 (eval-when-compile (require 'cl))
  45
  46 (declare-function run-ruby "ext:inf-ruby" (&optional command name))
  47
  48 (add-to-list 'org-babel-tangle-lang-exts '("ruby" . "rb"))
  49
  50 (defvar org-babel-default-header-args:ruby '())
  51
  52 (defvar org-babel-ruby-command "ruby"
  53   "Name of command to use for executing ruby code.")
  54
  55 (defun org-babel-execute:ruby (body params)
  56   "Execute a block of Ruby code with Babel.
  57 This function is called by `org-babel-execute-src-block'."
  58   (let* ((session (org-babel-ruby-initiate-session
  59                    (cdr (assoc :session params))))
  60          (result-params (cdr (assoc :result-params params)))
  61          (result-type (cdr (assoc :result-type params)))
  62          (full-body (org-babel-expand-body:generic
  63                      body params (org-babel-variable-assignments:ruby params)))
  64          (result (org-babel-ruby-evaluate
  65                   session full-body result-type result-params)))
  66     (or (cdr (assoc :file params))
  67         (org-babel-reassemble-table
  68          result
  69          (org-babel-pick-name (cdr (assoc :colname-names params))
  70                               (cdr (assoc :colnames params)))
  71          (org-babel-pick-name (cdr (assoc :rowname-names params))
  72                               (cdr (assoc :rownames params)))))))
  73
  74 (defun org-babel-prep-session:ruby (session params)
  75   "Prepare SESSION according to the header arguments specified in PARAMS."
  76   ;; (message "params=%S" params) ;; debugging
  77   (let* ((session (org-babel-ruby-initiate-session session))
  78          (var-lines (org-babel-variable-assignments:ruby params)))
  79     (org-babel-comint-in-buffer session
  80       (sit-for .5) (goto-char (point-max))
  81       (mapc (lambda (var)
  82               (insert var) (comint-send-input nil t)
  83               (org-babel-comint-wait-for-output session)
  84               (sit-for .1) (goto-char (point-max))) var-lines))
  85     session))
  86
  87 (defun org-babel-load-session:ruby (session body params)
  88   "Load BODY into SESSION."
  89   (save-window-excursion
  90     (let ((buffer (org-babel-prep-session:ruby session params)))
  91       (with-current-buffer buffer
  92         (goto-char (process-mark (get-buffer-process (current-buffer))))
  93         (insert (org-babel-chomp body)))
  94       buffer)))
  95
  96 ;; helper functions
  97
  98 (defun org-babel-variable-assignments:ruby (params)
  99   "Return list of ruby statements assigning the block's variables"
 100   (mapcar
 101    (lambda (pair)
 102      (format "%s=%s"
 103              (car pair)
 104              (org-babel-ruby-var-to-ruby (cdr pair))))
 105    (mapcar #'cdr (org-babel-get-header params :var))))
 106
 107 (defun org-babel-ruby-var-to-ruby (var)
 108   "Convert VAR into a ruby variable.
 109 Convert an elisp value into a string of ruby source code
 110 specifying a variable of the same value."
 111   (if (listp var)
 112       (concat "[" (mapconcat #'org-babel-ruby-var-to-ruby var ", ") "]")
 113     (format "%S" var)))
 114
 115 (defun org-babel-ruby-table-or-string (results)
 116   "Convert RESULTS into an appropriate elisp value.
 117 If RESULTS look like a table, then convert them into an
 118 Emacs-lisp table, otherwise return the results as a string."
 119   (org-babel-script-escape results))
 120
 121 (defun org-babel-ruby-initiate-session (&optional session params)
 122   "Initiate a ruby session.
 123 If there is not a current inferior-process-buffer in SESSION
 124 then create one.  Return the initialized session."
 125   (require 'inf-ruby)
 126   (unless (string= session "none")
 127     (let ((session-buffer (save-window-excursion
 128                             (run-ruby nil session) (current-buffer))))
 129       (if (org-babel-comint-buffer-livep session-buffer)
 130           (progn (sit-for .25) session-buffer)
 131         (sit-for .5)
 132         (org-babel-ruby-initiate-session session)))))
 133
 134 (defvar org-babel-ruby-eoe-indicator ":org_babel_ruby_eoe"
 135   "String to indicate that evaluation has completed.")
 136 (defvar org-babel-ruby-f-write
 137   "File.open('%s','w'){|f| f.write((_.class == String) ? _ : _.inspect)}")
 138 (defvar org-babel-ruby-pp-f-write
 139   "File.open('%s','w'){|f| $stdout = f; pp(results); $stdout = orig_out}")
 140 (defvar org-babel-ruby-wrapper-method
 141   "
 142 def main()
 143 %s
 144 end
 145 results = main()
 146 File.open('%s', 'w'){ |f| f.write((results.class == String) ? results : results.inspect) }
 147 ")
 148 (defvar org-babel-ruby-pp-wrapper-method
 149   "
 150 require 'pp'
 151 def main()
 152 %s
 153 end
 154 results = main()
 155 File.open('%s', 'w') do |f|
 156   $stdout = f
 157   pp results
 158 end
 159 ")
 160
 161 (defun org-babel-ruby-evaluate
 162   (buffer body &optional result-type result-params)
 163   "Pass BODY to the Ruby process in BUFFER.
 164 If RESULT-TYPE equals 'output then return a list of the outputs
 165 of the statements in BODY, if RESULT-TYPE equals 'value then
 166 return the value of the last statement in BODY, as elisp."
 167   (if (not buffer)
 168       ;; external process evaluation
 169       (case result-type
 170         (output (org-babel-eval org-babel-ruby-command body))
 171         (value (let ((tmp-file (org-babel-temp-file "ruby-")))
 172                  (org-babel-eval
 173                   org-babel-ruby-command
 174                   (format (if (member "pp" result-params)
 175                               org-babel-ruby-pp-wrapper-method
 176                             org-babel-ruby-wrapper-method)
 177                           body (org-babel-process-file-name tmp-file 'noquote)))
 178                  ((lambda (raw)
 179                     (if (or (member "code" result-params)
 180                             (member "pp" result-params))
 181                         raw
 182                       (org-babel-ruby-table-or-string raw)))
 183                   (org-babel-eval-read-file tmp-file)))))
 184     ;; comint session evaluation
 185     (case result-type
 186       (output
 187        (mapconcat
 188         #'identity
 189         (butlast
 190          (split-string
 191           (mapconcat
 192            #'org-babel-trim
 193            (butlast
 194             (org-babel-comint-with-output
 195                 (buffer org-babel-ruby-eoe-indicator t body)
 196               (mapc
 197                (lambda (line)
 198                  (insert (org-babel-chomp line)) (comint-send-input nil t))
 199                (list body org-babel-ruby-eoe-indicator))
 200               (comint-send-input nil t)) 2)
 201            "\n") "[\r\n]")) "\n"))
 202       (value
 203        ((lambda (results)
 204           (if (or (member "code" result-params) (member "pp" result-params))
 205               results
 206             (org-babel-ruby-table-or-string results)))
 207         (let* ((tmp-file (org-babel-temp-file "ruby-"))
 208                (ppp (or (member "code" result-params)
 209                         (member "pp" result-params))))
 210           (org-babel-comint-with-output
 211               (buffer org-babel-ruby-eoe-indicator t body)
 212             (when ppp (insert "require 'pp';") (comint-send-input nil t))
 213             (mapc
 214              (lambda (line)
 215                (insert (org-babel-chomp line)) (comint-send-input nil t))
 216              (append
 217               (list body)
 218               (if (not ppp)
 219                   (list (format org-babel-ruby-f-write
 220                                 (org-babel-process-file-name tmp-file 'noquote)))
 221                 (list
 222                  "results=_" "require 'pp'" "orig_out = $stdout"
 223                  (format org-babel-ruby-pp-f-write
 224                          (org-babel-process-file-name tmp-file 'noquote))))
 225               (list org-babel-ruby-eoe-indicator)))
 226             (comint-send-input nil t))
 227           (org-babel-eval-read-file tmp-file)))))))
 228
 229 (defun org-babel-ruby-read-string (string)
 230   "Strip \\\"s from around a ruby string."
 231   (if (string-match "^\"\\([^\000]+\\)\"$" string)
 232       (match-string 1 string)
 233     string))
 234
 235 (provide 'ob-ruby)
 236
 237
 238 ;;; ob-ruby.el ends here