lisp/desktop.el

   1 ;;; desktop.el --- save partial status of Emacs when killed
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Morten Welinder <terra@diku.dk>
   6 ;; Keywords: customization
   7 ;; Favourite-brand-of-beer: None, I hate beer.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Save the Desktop, i.e.,
  29 ;;      - some global variables
  30 ;;      - the list of buffers with associated files.  For each buffer also
  31 ;;              - the major mode
  32 ;;              - the default directory
  33 ;;              - the point
  34 ;;              - the mark & mark-active
  35 ;;              - buffer-read-only
  36 ;;              - some local variables
  37
  38 ;; To use this, first put these two lines in the bottom of your .emacs
  39 ;; file (the later the better):
  40 ;;
  41 ;;      (desktop-load-default)
  42 ;;      (desktop-read)
  43 ;;
  44 ;; Between the second and the third line you may wish to add something that
  45 ;; updates the variables `desktop-globals-to-save' and/or
  46 ;; `desktop-locals-to-save'.  If for instance you want to save the local
  47 ;; variable `foobar' for every buffer in which it is local, you could add
  48 ;; the line
  49 ;;
  50 ;;      (setq desktop-locals-to-save (cons 'foobar desktop-locals-to-save))
  51 ;;
  52 ;; To avoid saving excessive amounts of data you may also wish to add
  53 ;; something like the following
  54 ;;
  55 ;;      (add-hook 'kill-emacs-hook
  56 ;;                '(lambda ()
  57 ;;                   (desktop-truncate search-ring 3)
  58 ;;                   (desktop-truncate regexp-search-ring 3)))
  59 ;;
  60 ;; which will make sure that no more than three search items are saved.  You
  61 ;; must place this line *after* the (load "desktop") line.  See also the
  62 ;; variable desktop-save-hook.
  63
  64 ;; Start Emacs in the root directory of your "project". The desktop saver
  65 ;; is inactive by default.  You activate it by M-x desktop-save RET.  When
  66 ;; you exit the next time the above data will be saved.  This ensures that
  67 ;; all the files you were editing will be reloaded the next time you start
  68 ;; Emacs from the same directory and that points will be set where you
  69 ;; left them.  If you save a desktop file in your home directory it will
  70 ;; act as a default desktop when you start Emacs from a directory that
  71 ;; doesn't have its own.  I never do this, but you may want to.
  72
  73 ;; By the way: don't use desktop.el to customize Emacs -- the file .emacs
  74 ;; in your home directory is used for that.  Saving global default values
  75 ;; for buffers is an example of misuse.
  76
  77 ;; PLEASE NOTE: The kill ring can be saved as specified by the variable
  78 ;; `desktop-globals-to-save' (by default it isn't).  This may result in saving
  79 ;; things you did not mean to keep.  Use M-x desktop-clear RET.
  80
  81 ;; Thanks to  hetrick@phys.uva.nl (Jim Hetrick)      for useful ideas.
  82 ;;            avk@rtsg.mot.com (Andrew V. Klein)     for a dired tip.
  83 ;;            chris@tecc.co.uk (Chris Boucher)       for a mark tip.
  84 ;;            f89-kam@nada.kth.se (Klas Mellbourn)   for a mh-e tip.
  85 ;;            kifer@sbkifer.cs.sunysb.edu (M. Kifer) for a bug hunt.
  86 ;;            treese@lcs.mit.edu (Win Treese)        for ange-ftp tips.
  87 ;;            pot@cnuce.cnr.it (Francesco Potorti`)  for misc. tips.
  88 ;; ---------------------------------------------------------------------------
  89 ;; TODO:
  90 ;;
  91 ;; Save window configuration.
  92 ;; Recognize more minor modes.
  93 ;; Save mark rings.
  94 ;; Start-up with buffer-menu???
  95
  96 ;;; Code:
  97
  98 ;; Make the compilation more silent
  99 (eval-when-compile
 100   ;; We use functions from these modules
 101   ;; We can't (require 'mh-e) since that wants to load something.
 102   (mapcar 'require '(info dired reporter)))
 103 ;; ----------------------------------------------------------------------------
 104 ;; USER OPTIONS -- settings you might want to play with.
 105 ;; ----------------------------------------------------------------------------
 106
 107 (defgroup desktop nil
 108   "Save status of Emacs when you exit."
 109   :group 'frames)
 110
 111 (defcustom desktop-enable nil
 112   "*Non-nil enable Desktop to save the state of Emacs when you exit."
 113   :group 'desktop
 114   :type 'boolean
 115   :require 'desktop
 116   :initialize 'custom-initialize-default
 117   :version "20.3")
 118
 119 (defcustom desktop-basefilename
 120   (convert-standard-filename ".emacs.desktop")
 121   "File for Emacs desktop, not including the directory name."
 122   :type 'file
 123   :group 'desktop)
 124
 125 (defcustom desktop-missing-file-warning nil
 126   "*If non-nil then desktop warns when a file no longer exists.
 127 Otherwise it simply ignores that file."
 128   :type 'boolean
 129   :group 'desktop)
 130
 131 (defvar desktop-globals-to-save
 132   (list 'desktop-missing-file-warning
 133         ;; Feature: saving kill-ring implies saving kill-ring-yank-pointer
 134         ;; 'kill-ring
 135         'tags-file-name
 136         'tags-table-list
 137         'search-ring
 138         'regexp-search-ring
 139         'register-alist
 140         ;; 'desktop-globals-to-save     ; Itself!
 141         )
 142   "List of global variables to save when killing Emacs.
 143 An element may be variable name (a symbol)
 144 or a cons cell of the form  (VAR . MAX-SIZE),
 145 which means to truncate VAR's value to at most MAX-SIZE elements
 146 \(if the value is a list) before saving the value.")
 147
 148 (defvar desktop-locals-to-save
 149   (list 'desktop-locals-to-save         ; Itself!  Think it over.
 150         'truncate-lines
 151         'case-fold-search
 152         'case-replace
 153         'fill-column
 154         'overwrite-mode
 155         'change-log-default-name
 156         'line-number-mode
 157         )
 158   "List of local variables to save for each buffer.
 159 The variables are saved only when they really are local.")
 160 (make-variable-buffer-local 'desktop-locals-to-save)
 161
 162 ;; We skip .log files because they are normally temporary.
 163 ;;         (ftp) files because they require passwords and whatnot.
 164 ;;         TAGS files to save time (tags-file-name is saved instead).
 165 (defcustom desktop-buffers-not-to-save
 166  "\\(^nn\\.a[0-9]+\\|\\.log\\|(ftp)\\|^tags\\|^TAGS\\)$"
 167  "Regexp identifying buffers that are to be excluded from saving."
 168  :type 'regexp
 169  :group 'desktop)
 170
 171 ;; Skip ange-ftp files
 172 (defcustom desktop-files-not-to-save
 173   "^/[^/:]*:"
 174   "Regexp identifying files whose buffers are to be excluded from saving."
 175   :type 'regexp
 176   :group 'desktop)
 177
 178 (defcustom desktop-buffer-major-mode nil
 179   "When desktop creates a buffer, this holds the desired Major mode."
 180   :type 'symbol
 181   :group 'desktop)
 182
 183 (defcustom desktop-buffer-file-name nil
 184   "When desktop creates a buffer, this holds the file name to visit."
 185   :type '(choice file (const nil))
 186   :group 'desktop)
 187
 188 (defcustom desktop-buffer-name nil
 189   "When desktop creates a buffer, this holds the desired buffer name."
 190   :type '(choice string (const nil))
 191   :group 'desktop)
 192
 193 (defvar desktop-buffer-misc nil
 194   "When desktop creates a buffer, this holds a list of misc info.
 195 It is used by the `desktop-buffer-handlers' functions.")
 196
 197 (defcustom desktop-buffer-handlers
 198   '(desktop-buffer-dired
 199     desktop-buffer-rmail
 200     desktop-buffer-mh
 201     desktop-buffer-info
 202     desktop-buffer-file)
 203   "*List of functions to call in order to create a buffer.
 204 The functions are called without explicit parameters but can use the
 205 variables `desktop-buffer-major-mode', `desktop-buffer-file-name',
 206 `desktop-buffer-name'.
 207 If one function returns non-nil, no further functions are called.
 208 If the function returns t then the buffer is considered created."
 209   :type '(repeat function)
 210   :group 'desktop)
 211
 212 (defvar desktop-create-buffer-form "(desktop-create-buffer 205"
 213   "Opening of form for creation of new buffers.")
 214
 215 (defcustom desktop-save-hook nil
 216   "Hook run before desktop saves the state of Emacs.
 217 This is useful for truncating history lists, for example."
 218   :type 'hook
 219   :group 'desktop)
 220
 221 ;; ----------------------------------------------------------------------------
 222 (defvar desktop-dirname nil
 223   "The directory in which the current desktop file resides.")
 224
 225 (defconst desktop-header
 226 ";; --------------------------------------------------------------------------
 227 ;; Desktop File for Emacs
 228 ;; --------------------------------------------------------------------------
 229 " "*Header to place in Desktop file.")
 230
 231 (defvar desktop-delay-hook nil
 232   "Hooks run after all buffers are loaded; intended for internal use.")
 233
 234 ;; ----------------------------------------------------------------------------
 235 (defun desktop-truncate (l n)
 236   "Truncate LIST to at most N elements destructively."
 237   (let ((here (nthcdr (1- n) l)))
 238     (if (consp here)
 239         (setcdr here nil))))
 240 ;; ----------------------------------------------------------------------------
 241 (defcustom desktop-clear-preserve-buffers
 242   '("*scratch*" "*Messages*")
 243   "*Buffer names that `desktop-clear' should not delete."
 244   :type '(repeat string)
 245   :group 'desktop)
 246
 247 (defun desktop-clear ()
 248   "Empty the Desktop.
 249 This kills all buffers except for internal ones
 250 and those listed in `desktop-clear-preserve-buffers'."
 251   (interactive)
 252   (setq kill-ring nil
 253         kill-ring-yank-pointer nil
 254         search-ring nil
 255         search-ring-yank-pointer nil
 256         regexp-search-ring nil
 257         regexp-search-ring-yank-pointer nil)
 258   (let ((buffers (buffer-list)))
 259     (while buffers
 260       (or (member (buffer-name (car buffers)) desktop-clear-preserve-buffers)
 261           (null (buffer-name (car buffers)))
 262           ;; Don't kill buffers made for internal purposes.
 263           (and (not (equal (buffer-name (car buffers)) ""))
 264                (eq (aref (buffer-name (car buffers)) 0) ?\ ))
 265           (kill-buffer (car buffers)))
 266       (setq buffers (cdr buffers))))
 267   (delete-other-windows))
 268 ;; ----------------------------------------------------------------------------
 269 (add-hook 'kill-emacs-hook 'desktop-kill)
 270
 271 (defun desktop-kill ()
 272   (if desktop-dirname
 273       (condition-case err
 274           (desktop-save desktop-dirname)
 275         (file-error
 276          (if (yes-or-no-p "Error while saving the desktop.  Quit anyway? ")
 277              nil
 278            (signal (car err) (cdr err)))))))
 279 ;; ----------------------------------------------------------------------------
 280 (defun desktop-list* (&rest args)
 281   (if (null (cdr args))
 282       (car args)
 283     (setq args (nreverse args))
 284     (let ((value (cons (nth 1 args) (car args))))
 285       (setq args (cdr (cdr args)))
 286       (while args
 287         (setq value (cons (car args) value))
 288         (setq args (cdr args)))
 289       value)))
 290
 291 (defun desktop-internal-v2s (val)
 292   "Convert VALUE to a pair (QUOTE . TXT); (eval (read TXT)) gives VALUE.
 293 TXT is a string that when read and evaluated yields value.
 294 QUOTE may be `may' (value may be quoted),
 295 `must' (values must be quoted), or nil (value may not be quoted)."
 296   (cond
 297    ((or (numberp val) (null val) (eq t val))
 298     (cons 'may (prin1-to-string val)))
 299    ((stringp val)
 300     (let ((copy (copy-sequence val)))
 301       (set-text-properties 0 (length copy) nil copy)
 302       ;; Get rid of text properties because we cannot read them
 303       (cons 'may (prin1-to-string copy))))
 304    ((symbolp val)
 305     (cons 'must (prin1-to-string val)))
 306    ((vectorp val)
 307     (let* ((special nil)
 308            (pass1 (mapcar
 309                    (lambda (el)
 310                      (let ((res (desktop-internal-v2s el)))
 311                        (if (null (car res))
 312                            (setq special t))
 313                        res))
 314                    val)))
 315       (if special
 316           (cons nil (concat "(vector "
 317                             (mapconcat (lambda (el)
 318                                          (if (eq (car el) 'must)
 319                                              (concat "'" (cdr el))
 320                                            (cdr el)))
 321                                        pass1
 322                                        " ")
 323                             ")"))
 324         (cons 'may (concat "[" (mapconcat 'cdr pass1 " ") "]")))))
 325    ((consp val)
 326     (let ((p val)
 327           newlist
 328           use-list*
 329           anynil)
 330       (while (consp p)
 331         (let ((q.txt (desktop-internal-v2s (car p))))
 332           (or anynil (setq anynil (null (car q.txt))))
 333           (setq newlist (cons q.txt newlist)))
 334         (setq p (cdr p)))
 335       (if p
 336           (let ((last (desktop-internal-v2s p))
 337                 (el (car newlist)))
 338             (or anynil (setq anynil (null (car last))))
 339             (or anynil
 340                 (setq newlist (cons '(must . ".") newlist)))
 341             (setq use-list* t)
 342             (setq newlist (cons last newlist))))
 343       (setq newlist (nreverse newlist))
 344       (if anynil
 345           (cons nil
 346                 (concat (if use-list* "(desktop-list* "  "(list ")
 347                         (mapconcat (lambda (el)
 348                                      (if (eq (car el) 'must)
 349                                          (concat "'" (cdr el))
 350                                        (cdr el)))
 351                                    newlist
 352                                    " ")
 353                         ")"))
 354         (cons 'must
 355               (concat "(" (mapconcat 'cdr newlist " ") ")")))))
 356    ((subrp val)
 357     (cons nil (concat "(symbol-function '"
 358                       (substring (prin1-to-string val) 7 -1)
 359                       ")")))
 360    ((markerp val)
 361     (let ((pos (prin1-to-string (marker-position val)))
 362           (buf (prin1-to-string (buffer-name (marker-buffer val)))))
 363       (cons nil (concat "(let ((mk (make-marker)))"
 364                         " (add-hook 'desktop-delay-hook"
 365                         " (list 'lambda '() (list 'set-marker mk "
 366                         pos " (get-buffer " buf ")))) mk)"))))
 367    (t                                   ; save as text
 368     (cons 'may "\"Unprintable entity\""))))
 369
 370 (defun desktop-value-to-string (val)
 371   "Convert VALUE to a string that when read evaluates to the same value.
 372 Not all types of values are supported."
 373   (let* ((print-escape-newlines t)
 374          (float-output-format nil)
 375          (quote.txt (desktop-internal-v2s val))
 376          (quote (car quote.txt))
 377          (txt (cdr quote.txt)))
 378     (if (eq quote 'must)
 379         (concat "'" txt)
 380       txt)))
 381 ;; ----------------------------------------------------------------------------
 382 (defun desktop-outvar (varspec)
 383   "Output a setq statement for variable VAR to the desktop file.
 384 The argument VARSPEC may be the variable name VAR (a symbol),
 385 or a cons cell of the form  (VAR . MAX-SIZE),
 386 which means to truncate VAR's value to at most MAX-SIZE elements
 387 \(if the value is a list) before saving the value."
 388   (let (var size)
 389     (if (consp varspec)
 390         (setq var (car varspec) size (cdr varspec))
 391       (setq var varspec))
 392     (if (boundp var)
 393         (progn
 394           (if (and (integerp size)
 395                    (> size 0)
 396                    (listp (eval var)))
 397               (desktop-truncate (eval var) size))
 398           (insert "(setq "
 399                   (symbol-name var)
 400                   " "
 401                   (desktop-value-to-string (symbol-value var))
 402                   ")\n")))))
 403 ;; ----------------------------------------------------------------------------
 404 (defun desktop-save-buffer-p (filename bufname mode &rest dummy)
 405   "Return t if the desktop should record a particular buffer for next startup.
 406 FILENAME is the visited file name, BUFNAME is the buffer name, and
 407 MODE is the major mode."
 408   (let ((case-fold-search nil))
 409     (or (and filename
 410              (not (string-match desktop-buffers-not-to-save bufname))
 411              (not (string-match desktop-files-not-to-save filename)))
 412         (and (eq mode 'dired-mode)
 413              (save-excursion
 414                (set-buffer (get-buffer bufname))
 415                (not (string-match desktop-files-not-to-save
 416                                   default-directory))))
 417         (and (null filename)
 418              (memq mode '(Info-mode rmail-mode))))))
 419 ;; ----------------------------------------------------------------------------
 420 (defun desktop-save (dirname)
 421   "Save the Desktop file.  Parameter DIRNAME specifies where to save desktop."
 422   (interactive "DDirectory to save desktop file in: ")
 423   (run-hooks 'desktop-save-hook)
 424   (save-excursion
 425     (let ((filename (expand-file-name
 426                      (concat dirname desktop-basefilename)))
 427           (info (nreverse
 428                  (mapcar
 429                   (function (lambda (b)
 430                               (set-buffer b)
 431                               (list
 432                                (buffer-file-name)
 433                                (buffer-name)
 434                                major-mode
 435                                (list    ; list explaining minor modes
 436                                 (not (null auto-fill-function)))
 437                                (point)
 438                                (list (mark t) mark-active)
 439                                buffer-read-only
 440                                (cond ((eq major-mode 'Info-mode)
 441                                       (list Info-current-file
 442                                             Info-current-node))
 443                                      ((eq major-mode 'dired-mode)
 444                                       (cons
 445                                        (expand-file-name dired-directory)
 446                                        (cdr
 447                                         (nreverse
 448                                          (mapcar
 449                                           (function car)
 450                                           dired-subdir-alist))))))
 451                                (let ((locals desktop-locals-to-save)
 452                                      (loclist (buffer-local-variables))
 453                                      (ll))
 454                                  (while locals
 455                                    (let ((here (assq (car locals) loclist)))
 456                                      (if here
 457                                          (setq ll (cons here ll))
 458                                        (if (member (car locals) loclist)
 459                                            (setq ll (cons (car locals) ll)))))
 460                                    (setq locals (cdr locals)))
 461                                  ll)
 462                                )))
 463                   (buffer-list))))
 464           (buf (get-buffer-create "*desktop*")))
 465       (set-buffer buf)
 466       (erase-buffer)
 467
 468       (insert desktop-header
 469               ";; Created " (current-time-string) "\n"
 470               ";; Emacs version " emacs-version "\n\n"
 471               ";; Global section:\n")
 472       (mapcar (function desktop-outvar) desktop-globals-to-save)
 473       (if (memq 'kill-ring desktop-globals-to-save)
 474           (insert "(setq kill-ring-yank-pointer (nthcdr "
 475                   (int-to-string
 476                    (- (length kill-ring) (length kill-ring-yank-pointer)))
 477                   " kill-ring))\n"))
 478
 479       (insert "\n;; Buffer section:\n")
 480       (mapcar
 481        (function (lambda (l)
 482                    (if (apply 'desktop-save-buffer-p l)
 483                        (progn
 484                          (insert desktop-create-buffer-form)
 485                          (mapcar
 486                           (function (lambda (e)
 487                                       (insert "\n  "
 488                                               (desktop-value-to-string e))))
 489                           l)
 490                          (insert ")\n\n")))))
 491        info)
 492       (setq default-directory dirname)
 493       (if (file-exists-p filename) (delete-file filename))
 494       (write-region (point-min) (point-max) filename nil 'nomessage)))
 495   (setq desktop-dirname dirname))
 496 ;; ----------------------------------------------------------------------------
 497 (defun desktop-remove ()
 498   "Delete the Desktop file and inactivate the desktop system."
 499   (interactive)
 500   (if desktop-dirname
 501       (let ((filename (concat desktop-dirname desktop-basefilename)))
 502         (setq desktop-dirname nil)
 503         (if (file-exists-p filename)
 504             (delete-file filename)))))
 505 ;; ----------------------------------------------------------------------------
 506 ;;;###autoload
 507 (defun desktop-read ()
 508   "Read the Desktop file and the files it specifies.
 509 This is a no-op when Emacs is running in batch mode."
 510   (interactive)
 511   (if noninteractive
 512       nil
 513     (let ((dirs '("./" "~/")))
 514       (while (and dirs
 515                   (not (file-exists-p (expand-file-name
 516                                        desktop-basefilename
 517                                        (car dirs)))))
 518         (setq dirs (cdr dirs)))
 519       (setq desktop-dirname (and dirs (expand-file-name (car dirs))))
 520       (if desktop-dirname
 521           (progn
 522             (load (expand-file-name desktop-basefilename desktop-dirname)
 523                   t t t)
 524             (run-hooks 'desktop-delay-hook)
 525             (setq desktop-delay-hook nil)
 526             (message "Desktop loaded."))
 527         (desktop-clear)))))
 528 ;; ----------------------------------------------------------------------------
 529 ;;;###autoload
 530 (defun desktop-load-default ()
 531   "Load the `default' start-up library manually.
 532 Also inhibit further loading of it.  Call this from your `.emacs' file
 533 to provide correct modes for autoloaded files."
 534   (if (not inhibit-default-init)        ; safety check
 535       (progn
 536         (load "default" t t)
 537         (setq inhibit-default-init t))))
 538 ;; ----------------------------------------------------------------------------
 539 ;; Note: the following functions use the dynamic variable binding in Lisp.
 540 ;;
 541 (defun desktop-buffer-info () "Load an info file."
 542   (if (eq 'Info-mode desktop-buffer-major-mode)
 543       (progn
 544         (require 'info)
 545         (Info-find-node (nth 0 desktop-buffer-misc) (nth 1 desktop-buffer-misc))
 546         (current-buffer))))
 547 ;; ----------------------------------------------------------------------------
 548 (defun desktop-buffer-rmail () "Load an RMAIL file."
 549   (if (eq 'rmail-mode desktop-buffer-major-mode)
 550       (condition-case error
 551           (progn (rmail-input desktop-buffer-file-name)
 552                          (if (eq major-mode 'rmail-mode)
 553                              (current-buffer)
 554                            rmail-buffer))
 555         (file-locked
 556          (kill-buffer (current-buffer))
 557          'ignored))))
 558 ;; ----------------------------------------------------------------------------
 559 (defun desktop-buffer-mh () "Load a folder in the mh system."
 560   (if (eq 'mh-folder-mode desktop-buffer-major-mode)
 561       (progn
 562         (require 'mh-e)
 563         (mh-find-path)
 564         (mh-visit-folder desktop-buffer-name)
 565         (current-buffer))))
 566 ;; ----------------------------------------------------------------------------
 567 (defun desktop-buffer-dired () "Load a directory using dired."
 568   (if (eq 'dired-mode desktop-buffer-major-mode)
 569       (if (file-directory-p (file-name-directory (car desktop-buffer-misc)))
 570           (progn
 571             (dired (car desktop-buffer-misc))
 572             (mapcar 'dired-maybe-insert-subdir (cdr desktop-buffer-misc))
 573             (current-buffer))
 574         (message "Directory %s no longer exists." (car desktop-buffer-misc))
 575         (sit-for 1)
 576         'ignored)))
 577 ;; ----------------------------------------------------------------------------
 578 (defun desktop-buffer-file () "Load a file."
 579   (if desktop-buffer-file-name
 580       (if (or (file-exists-p desktop-buffer-file-name)
 581               (and desktop-missing-file-warning
 582                    (y-or-n-p (format
 583                               "File \"%s\" no longer exists. Re-create? "
 584                               desktop-buffer-file-name))))
 585           (progn (find-file desktop-buffer-file-name) (current-buffer))
 586         'ignored)))
 587 ;; ----------------------------------------------------------------------------
 588 ;; Create a buffer, load its file, set is mode, ...;  called from Desktop file
 589 ;; only.
 590 (defun desktop-create-buffer (ver desktop-buffer-file-name desktop-buffer-name
 591                                   desktop-buffer-major-mode
 592                                   mim pt mk ro desktop-buffer-misc &optional locals)
 593   (let ((hlist desktop-buffer-handlers)
 594         (result)
 595         (handler))
 596     (while (and (not result) hlist)
 597       (setq handler (car hlist))
 598       (setq result (funcall handler))
 599       (setq hlist (cdr hlist)))
 600     (when (bufferp result)
 601       (set-buffer result)
 602       (if (not (equal (buffer-name) desktop-buffer-name))
 603           (rename-buffer desktop-buffer-name))
 604       (auto-fill-mode (if (nth 0 mim) 1 0))
 605       (goto-char pt)
 606       (if (consp mk)
 607           (progn
 608             (set-mark (car mk))
 609             (setq mark-active (car (cdr mk))))
 610         (set-mark mk))
 611       ;; Never override file system if the file really is read-only marked.
 612       (if ro (setq buffer-read-only ro))
 613       (while locals
 614         (let ((this (car locals)))
 615           (if (consp this)
 616               ;; an entry of this form `(symbol . value)'
 617               (progn
 618                 (make-local-variable (car this))
 619                 (set (car this) (cdr this)))
 620             ;; an entry of the form `symbol'
 621             (make-local-variable this)
 622             (makunbound this)))
 623         (setq locals (cdr locals))))))
 624
 625 ;; Backward compatibility -- update parameters to 205 standards.
 626 (defun desktop-buffer (desktop-buffer-file-name desktop-buffer-name
 627                        desktop-buffer-major-mode
 628                        mim pt mk ro tl fc cfs cr desktop-buffer-misc)
 629   (desktop-create-buffer 205 desktop-buffer-file-name desktop-buffer-name
 630                          desktop-buffer-major-mode (cdr mim) pt mk ro
 631                          desktop-buffer-misc
 632                          (list (cons 'truncate-lines tl)
 633                                (cons 'fill-column fc)
 634                                (cons 'case-fold-search cfs)
 635                                (cons 'case-replace cr)
 636                                (cons 'overwrite-mode (car mim)))))
 637 ;; ----------------------------------------------------------------------------
 638
 639 ;; If the user set desktop-enable to t with Custom,
 640 ;; do the rest of what it takes to use desktop,
 641 ;; but do it after finishing loading the init file.
 642 (add-hook 'after-init-hook
 643           '(lambda ()
 644              (when desktop-enable
 645                (desktop-load-default)
 646                (desktop-read))))
 647
 648 (provide 'desktop)
 649
 650 ;; desktop.el ends here.