lisp/vc-sccs.el

   1 ;;; vc-sccs.el --- support for SCCS version-control
   2
   3 ;; Copyright (C) 1992,93,94,95,96,97,98,99,2000,2001 Free Software Foundation, Inc.
   4
   5 ;; Author:     FSF (see vc.el for full credits)
   6 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   7
   8 ;; $Id: vc-sccs.el,v 1.18 2002/11/12 19:50:54 rost Exp $
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'vc))
  33
  34 ;;;
  35 ;;; Customization options
  36 ;;;
  37
  38 (defcustom vc-sccs-register-switches nil
  39   "*Extra switches for registering a file in SCCS.
  40 A string or list of strings passed to the checkin program by
  41 \\[vc-sccs-register]."
  42   :type '(choice (const :tag "None" nil)
  43                  (string :tag "Argument String")
  44                  (repeat :tag "Argument List"
  45                          :value ("")
  46                          string))
  47   :version "21.1"
  48   :group 'vc)
  49
  50 (defcustom vc-sccs-diff-switches nil
  51   "*A string or list of strings specifying extra switches for `vcdiff',
  52 the diff utility used for SCCS under VC."
  53     :type '(choice (const :tag "None" nil)
  54                  (string :tag "Argument String")
  55                  (repeat :tag "Argument List"
  56                          :value ("")
  57                          string))
  58   :version "21.1"
  59   :group 'vc)
  60
  61 (defcustom vc-sccs-header (or (cdr (assoc 'SCCS vc-header-alist)) '("%W%"))
  62   "*Header keywords to be inserted by `vc-insert-headers'."
  63   :type '(repeat string)
  64   :group 'vc)
  65
  66 ;;;###autoload
  67 (defcustom vc-sccs-master-templates
  68   '("%sSCCS/s.%s" "%ss.%s" vc-sccs-search-project-dir)
  69   "*Where to look for SCCS master files.
  70 For a description of possible values, see `vc-check-master-templates'."
  71   :type '(choice (const :tag "Use standard SCCS file names"
  72                         ("%sSCCS/s.%s" "%ss.%s" vc-sccs-search-project-dir))
  73                  (repeat :tag "User-specified"
  74                          (choice string
  75                                  function)))
  76   :version "21.1"
  77   :group 'vc)
  78
  79 \f
  80 ;;;
  81 ;;; Internal variables
  82 ;;;
  83
  84 (defconst vc-sccs-name-assoc-file "VC-names")
  85
  86 \f
  87 ;;;
  88 ;;; State-querying functions
  89 ;;;
  90
  91 ;;; The autoload cookie below places vc-sccs-registered directly into
  92 ;;; loaddefs.el, so that vc-sccs.el does not need to be loaded for
  93 ;;; every file that is visited.  The definition is repeated below
  94 ;;; so that Help and etags can find it.
  95
  96 ;;;###autoload (defun vc-sccs-registered(f) (vc-default-registered 'SCCS f))
  97 (defun vc-sccs-registered (f) (vc-default-registered 'SCCS f))
  98
  99 (defun vc-sccs-state (file)
 100   "SCCS-specific function to compute the version control state."
 101   (with-temp-buffer
 102     (if (vc-insert-file (vc-sccs-lock-file file))
 103         (let* ((locks (vc-sccs-parse-locks))
 104                (workfile-version (vc-workfile-version file))
 105                (locking-user (cdr (assoc workfile-version locks))))
 106           (if (not locking-user)
 107               (if (vc-workfile-unchanged-p file)
 108                   'up-to-date
 109                 'unlocked-changes)
 110             (if (string= locking-user (vc-user-login-name))
 111                 'edited
 112               locking-user)))
 113       'up-to-date)))
 114
 115 (defun vc-sccs-state-heuristic (file)
 116   "SCCS-specific state heuristic."
 117   (if (not (vc-mistrust-permissions file))
 118       ;;   This implementation assumes that any file which is under version
 119       ;; control and has -rw-r--r-- is locked by its owner.  This is true
 120       ;; for both RCS and SCCS, which keep unlocked files at -r--r--r--.
 121       ;; We have to be careful not to exclude files with execute bits on;
 122       ;; scripts can be under version control too.  Also, we must ignore the
 123       ;; group-read and other-read bits, since paranoid users turn them off.
 124       (let* ((attributes (file-attributes file))
 125              (owner-uid  (nth 2 attributes))
 126              (permissions (nth 8 attributes)))
 127         (if (string-match ".r-..-..-." permissions)
 128             'up-to-date
 129           (if (string-match ".rw..-..-." permissions)
 130               (if (file-ownership-preserved-p file)
 131                   'edited
 132                 (vc-user-login-name owner-uid))
 133           ;; Strange permissions.
 134           ;; Fall through to real state computation.
 135           (vc-sccs-state file)))
 136     (vc-sccs-state file))))
 137
 138 (defun vc-sccs-workfile-version (file)
 139   "SCCS-specific version of `vc-workfile-version'."
 140   (with-temp-buffer
 141     (vc-insert-file (vc-name file) "^\001e")
 142     (vc-parse-buffer "^\001d D \\([^ ]+\\)" 1)))
 143
 144 (defun vc-sccs-checkout-model (file)
 145   "SCCS-specific version of `vc-checkout-model'."
 146   'locking)
 147
 148 (defun vc-sccs-workfile-unchanged-p (file)
 149   "SCCS-specific implementation of vc-workfile-unchanged-p."
 150   (zerop (apply 'vc-do-command nil 1 "vcdiff" (vc-name file)
 151                 (list "--brief" "-q"
 152                       (concat "-r" (vc-workfile-version file))))))
 153
 154 \f
 155 ;;;
 156 ;;; State-changing functions
 157 ;;;
 158
 159 (defun vc-sccs-register (file &optional rev comment)
 160   "Register FILE into the SCCS version-control system.
 161 REV is the optional revision number for the file.  COMMENT can be used
 162 to provide an initial description of FILE.
 163
 164 `vc-register-switches' and `vc-sccs-register-switches' are passed to
 165 the SCCS command (in that order).
 166
 167 Automatically retrieve a read-only version of the file with keywords
 168 expanded if `vc-keep-workfiles' is non-nil, otherwise, delete the workfile."
 169     (let* ((switches (append
 170                      (if (stringp vc-register-switches)
 171                          (list vc-register-switches)
 172                        vc-register-switches)
 173                      (if (stringp vc-sccs-register-switches)
 174                          (list vc-sccs-register-switches)
 175                        vc-sccs-register-switches)))
 176            (dirname (or (file-name-directory file) ""))
 177            (basename (file-name-nondirectory file))
 178            (project-file (vc-sccs-search-project-dir dirname basename)))
 179       (let ((vc-name
 180              (or project-file
 181                  (format (car vc-sccs-master-templates) dirname basename)))|)
 182         (apply 'vc-do-command nil 0 "admin" vc-name
 183                (and rev (concat "-r" rev))
 184                "-fb"
 185                (concat "-i" (file-relative-name file))
 186                (and comment (concat "-y" comment))
 187                switches))
 188       (delete-file file)
 189       (if vc-keep-workfiles
 190           (vc-do-command nil 0 "get" (vc-name file)))))
 191
 192 (defun vc-sccs-responsible-p (file)
 193   "Return non-nil if SCCS thinks it would be responsible for registering FILE."
 194   ;; TODO: check for all the patterns in vc-sccs-master-templates
 195   (or (file-directory-p (expand-file-name "SCCS" (file-name-directory file)))
 196       (stringp (vc-sccs-search-project-dir (or (file-name-directory file) "")
 197                                            (file-name-nondirectory file)))))
 198
 199 (defun vc-sccs-checkin (file rev comment)
 200   "SCCS-specific version of `vc-backend-checkin'."
 201   (let ((switches (if (stringp vc-checkin-switches)
 202                       (list vc-checkin-switches)
 203                     vc-checkin-switches)))
 204     (apply 'vc-do-command nil 0 "delta" (vc-name file)
 205            (if rev (concat "-r" rev))
 206            (concat "-y" comment)
 207            switches)
 208     (if vc-keep-workfiles
 209         (vc-do-command nil 0 "get" (vc-name file)))))
 210
 211 (defun vc-sccs-find-version (file rev buffer)
 212   (apply 'vc-do-command
 213          buffer 0 "get" (vc-name file)
 214          "-s" ;; suppress diagnostic output
 215          "-p"
 216          (and rev
 217               (concat "-r"
 218                       (vc-sccs-lookup-triple file rev)))
 219          (if (stringp vc-checkout-switches)
 220              (list vc-checkout-switches)
 221            vc-checkout-switches)))
 222
 223 (defun vc-sccs-checkout (file &optional editable rev)
 224   "Retrieve a copy of a saved version of SCCS controlled FILE.
 225 EDITABLE non-nil means that the file should be writable and
 226 locked.  REV is the revision to check out."
 227   (let ((file-buffer (get-file-buffer file))
 228         switches)
 229     (message "Checking out %s..." file)
 230     (save-excursion
 231       ;; Change buffers to get local value of vc-checkout-switches.
 232       (if file-buffer (set-buffer file-buffer))
 233       (setq switches (if (stringp vc-checkout-switches)
 234                          (list vc-checkout-switches)
 235                        vc-checkout-switches))
 236       ;; Save this buffer's default-directory
 237       ;; and use save-excursion to make sure it is restored
 238       ;; in the same buffer it was saved in.
 239       (let ((default-directory default-directory))
 240         (save-excursion
 241           ;; Adjust the default-directory so that the check-out creates
 242           ;; the file in the right place.
 243           (setq default-directory (file-name-directory file))
 244
 245           (and rev (string= rev "") (setq rev nil))
 246           (apply 'vc-do-command nil 0 "get" (vc-name file)
 247                  (if editable "-e")
 248                  (and rev (concat "-r" (vc-sccs-lookup-triple file rev)))
 249                  switches))))
 250     (message "Checking out %s...done" file)))
 251
 252 (defun vc-sccs-revert (file &optional contents-done)
 253   "Revert FILE to the version it was based on."
 254   (vc-do-command nil 0 "unget" (vc-name file))
 255   (vc-do-command nil 0 "get" (vc-name file))
 256   ;; Checking out explicit versions is not supported under SCCS, yet.
 257   ;; We always "revert" to the latest version; therefore
 258   ;; vc-workfile-version is cleared here so that it gets recomputed.
 259   (vc-file-setprop file 'vc-workfile-version nil))
 260
 261 (defun vc-sccs-cancel-version (file editable)
 262   "Undo the most recent checkin of FILE.
 263 EDITABLE non-nil means previous version should be locked."
 264   (vc-do-command nil 0 "rmdel"
 265                  (vc-name file)
 266                  (concat "-r" (vc-workfile-version file)))
 267   (vc-do-command nil 0 "get"
 268                  (vc-name file)
 269                  (if editable "-e")))
 270
 271 (defun vc-sccs-steal-lock (file &optional rev)
 272   "Steal the lock on the current workfile for FILE and revision REV."
 273   (vc-do-command nil 0 "unget" (vc-name file) "-n" (if rev (concat "-r" rev)))
 274   (vc-do-command nil 0 "get" (vc-name file) "-g" (if rev (concat "-r" rev))))
 275
 276 \f
 277 ;;;
 278 ;;; History functions
 279 ;;;
 280
 281 (defun vc-sccs-print-log (file)
 282   "Get change log associated with FILE."
 283   (vc-do-command nil 0 "prs" (vc-name file)))
 284
 285 (defun vc-sccs-logentry-check ()
 286   "Check that the log entry in the current buffer is acceptable for SCCS."
 287   (when (>= (buffer-size) 512)
 288     (goto-char 512)
 289     (error "Log must be less than 512 characters; point is now at pos 512")))
 290
 291 (defun vc-sccs-diff (file &optional oldvers newvers)
 292   "Get a difference report using SCCS between two versions of FILE."
 293   (setq oldvers (vc-sccs-lookup-triple file oldvers))
 294   (setq newvers (vc-sccs-lookup-triple file newvers))
 295   (apply 'vc-do-command "*vc-diff*" 1 "vcdiff" (vc-name file)
 296          (append (list "-q"
 297                        (and oldvers (concat "-r" oldvers))
 298                        (and newvers (concat "-r" newvers)))
 299                  (vc-diff-switches-list 'SCCS))))
 300
 301 \f
 302 ;;;
 303 ;;; Snapshot system
 304 ;;;
 305
 306 (defun vc-sccs-assign-name (file name)
 307   "Assign to FILE's latest version a given NAME."
 308   (vc-sccs-add-triple name file (vc-workfile-version file)))
 309
 310 \f
 311 ;;;
 312 ;;; Miscellaneous
 313 ;;;
 314
 315 (defun vc-sccs-check-headers ()
 316   "Check if the current file has any headers in it."
 317   (save-excursion
 318     (goto-char (point-min))
 319     (re-search-forward  "%[A-Z]%" nil t)))
 320
 321 (defun vc-sccs-rename-file (old new)
 322   ;; Move the master file (using vc-rcs-master-templates).
 323   (vc-rename-master (vc-name old) new vc-sccs-master-templates)
 324   ;; Update the snapshot file.
 325   (with-current-buffer
 326       (find-file-noselect
 327        (expand-file-name vc-sccs-name-assoc-file
 328                          (file-name-directory (vc-name old))))
 329     (goto-char (point-min))
 330     ;; (replace-regexp (concat ":" (regexp-quote old) "$") (concat ":" new))
 331     (while (re-search-forward (concat ":" (regexp-quote old) "$") nil t)
 332       (replace-match (concat ":" new) nil nil))
 333     (basic-save-buffer)
 334     (kill-buffer (current-buffer))))
 335
 336 \f
 337 ;;;
 338 ;;; Internal functions
 339 ;;;
 340
 341 ;; This function is wrapped with `progn' so that the autoload cookie
 342 ;; copies the whole function itself into loaddefs.el rather than just placing
 343 ;; a (autoload 'vc-sccs-search-project-dir "vc-sccs") which would not
 344 ;; help us avoid loading vc-sccs.
 345 ;;;###autoload
 346 (progn (defun vc-sccs-search-project-dir (dirname basename)
 347   "Return the name of a master file in the SCCS project directory.
 348 Does not check whether the file exists but returns nil if it does not
 349 find any project directory."
 350   (let ((project-dir (getenv "PROJECTDIR")) dirs dir)
 351     (when project-dir
 352       (if (file-name-absolute-p project-dir)
 353           (setq dirs '("SCCS" ""))
 354         (setq dirs '("src/SCCS" "src" "source/SCCS" "source"))
 355         (setq project-dir (expand-file-name (concat "~" project-dir))))
 356       (while (and (not dir) dirs)
 357         (setq dir (expand-file-name (car dirs) project-dir))
 358         (unless (file-directory-p dir)
 359           (setq dir nil)
 360           (setq dirs (cdr dirs))))
 361       (and dir (expand-file-name (concat "s." basename) dir))))))
 362
 363 (defun vc-sccs-lock-file (file)
 364   "Generate lock file name corresponding to FILE."
 365   (let ((master (vc-name file)))
 366     (and
 367      master
 368      (string-match "\\(.*/\\)\\(s\\.\\)\\(.*\\)" master)
 369      (replace-match "p." t t master 2))))
 370
 371 (defun vc-sccs-parse-locks ()
 372   "Parse SCCS locks in current buffer.
 373 The result is a list of the form ((VERSION . USER) (VERSION . USER) ...)."
 374   (let (master-locks)
 375     (goto-char (point-min))
 376     (while (re-search-forward "^\\([0-9.]+\\) [0-9.]+ \\([^ ]+\\) .*\n?"
 377                               nil t)
 378       (setq master-locks
 379             (cons (cons (match-string 1) (match-string 2)) master-locks)))
 380     ;; FIXME: is it really necessary to reverse ?
 381     (nreverse master-locks)))
 382
 383 (defun vc-sccs-add-triple (name file rev)
 384   (with-current-buffer
 385       (find-file-noselect
 386        (expand-file-name vc-sccs-name-assoc-file
 387                          (file-name-directory (vc-name file))))
 388     (goto-char (point-max))
 389     (insert name "\t:\t" file "\t" rev "\n")
 390     (basic-save-buffer)
 391     (kill-buffer (current-buffer))))
 392
 393 (defun vc-sccs-lookup-triple (file name)
 394   "Return the numeric version corresponding to a named snapshot of FILE.
 395 If NAME is nil or a version number string it's just passed through."
 396   (if (or (null name)
 397           (let ((firstchar (aref name 0)))
 398             (and (>= firstchar ?0) (<= firstchar ?9))))
 399       name
 400     (with-temp-buffer
 401       (vc-insert-file
 402        (expand-file-name vc-sccs-name-assoc-file
 403                          (file-name-directory (vc-name file))))
 404       (vc-parse-buffer (concat name "\t:\t" file "\t\\(.+\\)") 1))))
 405
 406 (provide 'vc-sccs)
 407
 408 ;;; vc-sccs.el ends here