lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 ;; Functions
  36
  37 ;;;###autoload
  38 (defun describe-function (function)
  39   "Display the full documentation of FUNCTION (a symbol)."
  40   (interactive
  41    (let ((fn (function-called-at-point))
  42          (enable-recursive-minibuffers t)
  43          val)
  44      (setq val (completing-read (if fn
  45                                     (format "Describe function (default %s): " fn)
  46                                   "Describe function: ")
  47                                 obarray 'fboundp t nil nil
  48                                 (and fn (symbol-name fn))))
  49      (list (if (equal val "")
  50                fn (intern val)))))
  51   (if (null function)
  52       (message "You didn't specify a function")
  53     (help-setup-xref (list #'describe-function function)
  54                      (called-interactively-p 'interactive))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info.
  69 DEF is the function whose usage we're looking for in DOCSTRING."
  70   ;; Functions can get the calling sequence at the end of the doc string.
  71   ;; In cases where `function' has been fset to a subr we can't search for
  72   ;; function's name in the doc string so we use `fn' as the anonymous
  73   ;; function name instead.
  74   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  75     (cons (format "(%s%s"
  76                   ;; Replace `fn' with the actual function name.
  77                   (if (consp def) "anonymous" def)
  78                   (match-string 1 docstring))
  79           (substring docstring 0 (match-beginning 0)))))
  80
  81 (defun help-add-fundoc-usage (docstring arglist)
  82   "Add the usage info to DOCSTRING.
  83 If DOCSTRING already has a usage info, then just return it unchanged.
  84 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  85 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  86   (unless (stringp docstring) (setq docstring "Not documented"))
  87   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  88       docstring
  89     (concat docstring
  90             (if (string-match "\n?\n\\'" docstring)
  91                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  92               "\n\n")
  93             (if (and (stringp arglist)
  94                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  95                 (concat "(fn" (match-string 1 arglist) ")")
  96               (format "%S" (help-make-usage 'fn arglist))))))
  97
  98 (defun help-function-arglist (def)
  99   ;; Handle symbols aliased to other symbols.
 100   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 101   ;; If definition is a macro, find the function inside it.
 102   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 103   (cond
 104    ((byte-code-function-p def) (aref def 0))
 105    ((eq (car-safe def) 'lambda) (nth 1 def))
 106    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 107     "[Arg list not available until function definition is loaded.]")
 108    (t t)))
 109
 110 (defun help-make-usage (function arglist)
 111   (cons (if (symbolp function) function 'anonymous)
 112         (mapcar (lambda (arg)
 113                   (if (not (symbolp arg))
 114                       (if (and (consp arg) (symbolp (car arg)))
 115                           ;; CL style default values for optional args.
 116                           (cons (intern (upcase (symbol-name (car arg))))
 117                                 (cdr arg))
 118                         arg)
 119                     (let ((name (symbol-name arg)))
 120                       (if (string-match "\\`&" name) arg
 121                         (intern (upcase name))))))
 122                 arglist)))
 123
 124 ;; Could be this, if we make symbol-file do the work below.
 125 ;; (defun help-C-file-name (subr-or-var kind)
 126 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 127 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 128 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 129 ;;               (subr-name subr-or-var))
 130 ;;             (if (eq kind 'var) 'defvar 'defun)))
 131 ;;;###autoload
 132 (defun help-C-file-name (subr-or-var kind)
 133   "Return the name of the C file where SUBR-OR-VAR is defined.
 134 KIND should be `var' for a variable or `subr' for a subroutine."
 135   (let ((docbuf (get-buffer-create " *DOC*"))
 136         (name (if (eq 'var kind)
 137                   (concat "V" (symbol-name subr-or-var))
 138                 (concat "F" (subr-name subr-or-var)))))
 139     (with-current-buffer docbuf
 140       (goto-char (point-min))
 141       (if (eobp)
 142           (insert-file-contents-literally
 143            (expand-file-name internal-doc-file-name doc-directory)))
 144       (let ((file (catch 'loop
 145                     (while t
 146                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 147                         (re-search-backward "\x1fS\\(.*\\)")
 148                         (let ((file (match-string 1)))
 149                           (if (member file build-files)
 150                               (throw 'loop file)
 151                             (goto-char pnt))))))))
 152         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 153             (setq file (replace-match ".m" t t file 1))
 154           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 155               (setq file (replace-match ".c" t t file))))
 156         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 157             (concat "src/" file)
 158           file)))))
 159
 160 (defcustom help-downcase-arguments nil
 161   "If non-nil, argument names in *Help* buffers are downcased."
 162   :type 'boolean
 163   :group 'help
 164   :version "23.2")
 165
 166 (defun help-highlight-arg (arg)
 167   "Highlight ARG as an argument name for a *Help* buffer.
 168 Return ARG in face `help-argument-name'; ARG is also downcased
 169 if the variable `help-downcase-arguments' is non-nil."
 170   (propertize (if help-downcase-arguments (downcase arg) arg)
 171               'face 'help-argument-name))
 172
 173 (defun help-do-arg-highlight (doc args)
 174   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 175     (modify-syntax-entry ?\- "w")
 176     (dolist (arg args doc)
 177       (setq doc (replace-regexp-in-string
 178                  ;; This is heuristic, but covers all common cases
 179                  ;; except ARG1-ARG2
 180                  (concat "\\<"                   ; beginning of word
 181                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 182                          "\\("
 183                          (regexp-quote arg)
 184                          "\\)"
 185                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 186                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 187                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 188                          "\\>")                  ; end of word
 189                  (help-highlight-arg arg)
 190                  doc t t 1)))))
 191
 192 (defun help-highlight-arguments (usage doc &rest args)
 193   (when usage
 194     (with-temp-buffer
 195       (insert usage)
 196       (goto-char (point-min))
 197       (let ((case-fold-search nil)
 198             (next (not (or args (looking-at "\\["))))
 199             (opt nil))
 200         ;; Make a list of all arguments
 201         (skip-chars-forward "^ ")
 202         (while next
 203           (or opt (not (looking-at " &")) (setq opt t))
 204           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 205               (setq next nil)
 206             (setq args (cons (match-string 2) args))
 207             (when (and opt (string= (match-string 1) "("))
 208               ;; A pesky CL-style optional argument with default value,
 209               ;; so let's skip over it
 210               (search-backward "(")
 211               (goto-char (scan-sexps (point) 1)))))
 212         ;; Highlight aguments in the USAGE string
 213         (setq usage (help-do-arg-highlight (buffer-string) args))
 214         ;; Highlight arguments in the DOC string
 215         (setq doc (and doc (help-do-arg-highlight doc args))))))
 216   ;; Return value is like the one from help-split-fundoc, but highlighted
 217   (cons usage doc))
 218
 219 ;; The following function was compiled from the former functions
 220 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 221 ;; some excerpts from `describe-function-1' and `describe-variable'.
 222 ;; The only additional twists provided are (1) locate the defining file
 223 ;; for autoloaded functions, and (2) give preference to files in the
 224 ;; "install directory" (directories found via `load-path') rather than
 225 ;; to files in the "compile directory" (directories found by searching
 226 ;; the loaddefs.el file).  We autoload it because it's also used by
 227 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 228
 229 ;;;###autoload
 230 (defun find-lisp-object-file-name (object type)
 231   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 232 OBJECT should be a symbol associated with a function, variable, or face;
 233   alternatively, it can be a function definition.
 234 If TYPE is `defvar', search for a variable definition.
 235 If TYPE is `defface', search for a face definition.
 236 If TYPE is the value returned by `symbol-function' for a function symbol,
 237  search for a function definition.
 238
 239 The return value is the absolute name of a readable file where OBJECT is
 240 defined.  If several such files exist, preference is given to a file
 241 found via `load-path'.  The return value can also be `C-source', which
 242 means that OBJECT is a function or variable defined in C.  If no
 243 suitable file is found, return nil."
 244   (let* ((autoloaded (eq (car-safe type) 'autoload))
 245          (file-name (or (and autoloaded (nth 1 type))
 246                         (symbol-file
 247                          object (if (memq type (list 'defvar 'defface))
 248                                     type
 249                                   'defun)))))
 250     (cond
 251      (autoloaded
 252       ;; An autoloaded function: Locate the file since `symbol-function'
 253       ;; has only returned a bare string here.
 254       (setq file-name
 255             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 256      ((and (stringp file-name)
 257            (string-match "[.]*loaddefs.el\\'" file-name))
 258       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 259       ;; and try to extract the defining file.  The following form is
 260       ;; from `describe-function-1' and `describe-variable'.
 261       (let ((location
 262              (condition-case nil
 263                  (find-function-search-for-symbol object nil file-name)
 264                (error nil))))
 265         (when (cdr location)
 266           (with-current-buffer (car location)
 267             (goto-char (cdr location))
 268             (when (re-search-backward
 269                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 270               (setq file-name
 271                     (locate-file
 272                      (file-name-sans-extension
 273                       (match-string-no-properties 1))
 274                      load-path '(".el" ".elc") 'readable))))))))
 275
 276     (cond
 277      ((and (not file-name) (subrp type))
 278       ;; A built-in function.  The form is from `describe-function-1'.
 279       (if (get-buffer " *DOC*")
 280           (help-C-file-name type 'subr)
 281         'C-source))
 282      ((and (not file-name) (symbolp object)
 283            (integerp (get object 'variable-documentation)))
 284       ;; A variable defined in C.  The form is from `describe-variable'.
 285       (if (get-buffer " *DOC*")
 286           (help-C-file-name object 'var)
 287         'C-source))
 288      ((not (stringp file-name))
 289       ;; If we don't have a file-name string by now, we lost.
 290       nil)
 291      ;; Now, `file-name' should have become an absolute file name.
 292      ;; For files loaded from ~/.emacs.elc, try ~/.emacs.
 293      ((let (fn)
 294         (and (string-equal file-name
 295                            (expand-file-name ".emacs.elc" "~"))
 296              (file-readable-p (setq fn (expand-file-name ".emacs" "~")))
 297              fn)))
 298      ;; When the Elisp source file can be found in the install
 299      ;; directory, return the name of that file.
 300      ((let ((lib-name
 301              (if (string-match "[.]elc\\'" file-name)
 302                  (substring-no-properties file-name 0 -1)
 303                file-name)))
 304         (or (and (file-readable-p lib-name) lib-name)
 305             ;; The library might be compressed.
 306             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 307      ((let* ((lib-name (file-name-nondirectory file-name))
 308              ;; The next form is from `describe-simplify-lib-file-name'.
 309              (file-name
 310               ;; Try converting the absolute file name to a library
 311               ;; name, convert that back to a file name and see if we
 312               ;; get the original one.  If so, they are equivalent.
 313               (if (equal file-name (locate-file lib-name load-path '("")))
 314                   (if (string-match "[.]elc\\'" lib-name)
 315                       (substring-no-properties lib-name 0 -1)
 316                     lib-name)
 317                 file-name))
 318              ;; The next three forms are from `find-source-lisp-file'.
 319              (elc-file (locate-file
 320                         (concat file-name
 321                                 (if (string-match "\\.el\\'" file-name)
 322                                     "c"
 323                                   ".elc"))
 324                         load-path nil 'readable))
 325              (str (when elc-file
 326                     (with-temp-buffer
 327                       (insert-file-contents-literally elc-file nil 0 256)
 328                       (buffer-string))))
 329              (src-file (and str
 330                             (string-match ";;; from file \\(.*\\.el\\)" str)
 331                             (match-string 1 str))))
 332         (and src-file (file-readable-p src-file) src-file))))))
 333
 334 (declare-function ad-get-advice-info "advice" (function))
 335
 336 ;;;###autoload
 337 (defun describe-function-1 (function)
 338   (let* ((advised (and (symbolp function) (featurep 'advice)
 339                        (ad-get-advice-info function)))
 340          ;; If the function is advised, use the symbol that has the
 341          ;; real definition, if that symbol is already set up.
 342          (real-function
 343           (or (and advised
 344                    (let ((origname (cdr (assq 'origname advised))))
 345                      (and (fboundp origname) origname)))
 346               function))
 347          ;; Get the real definition.
 348          (def (if (symbolp real-function)
 349                   (symbol-function real-function)
 350                 function))
 351          file-name string
 352          (beg (if (commandp def) "an interactive " "a "))
 353          (pt1 (with-current-buffer (help-buffer) (point)))
 354          errtype)
 355     (setq string
 356           (cond ((or (stringp def)
 357                      (vectorp def))
 358                  "a keyboard macro")
 359                 ((subrp def)
 360                  (if (eq 'unevalled (cdr (subr-arity def)))
 361                      (concat beg "special form")
 362                    (concat beg "built-in function")))
 363                 ((byte-code-function-p def)
 364                  (concat beg "compiled Lisp function"))
 365                 ((symbolp def)
 366                  (while (and (fboundp def)
 367                              (symbolp (symbol-function def)))
 368                    (setq def (symbol-function def)))
 369                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 370                  (or (fboundp def) (setq errtype 'alias))
 371                  (format "an alias for `%s'" def))
 372                 ((eq (car-safe def) 'lambda)
 373                  (concat beg "Lisp function"))
 374                 ((eq (car-safe def) 'macro)
 375                  "a Lisp macro")
 376                 ((eq (car-safe def) 'autoload)
 377                  (format "%s autoloaded %s"
 378                          (if (commandp def) "an interactive" "an")
 379                          (if (eq (nth 4 def) 'keymap) "keymap"
 380                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 381                 ((keymapp def)
 382                  (let ((is-full nil)
 383                        (elts (cdr-safe def)))
 384                    (while elts
 385                      (if (char-table-p (car-safe elts))
 386                          (setq is-full t
 387                                elts nil))
 388                      (setq elts (cdr-safe elts)))
 389                    (if is-full
 390                        "a full keymap"
 391                      "a sparse keymap")))
 392                 (t "")))
 393     (princ string)
 394     (if (eq errtype 'alias)
 395         (princ ",\nwhich is not defined.  Please make a bug report.")
 396       (with-current-buffer standard-output
 397         (save-excursion
 398           (save-match-data
 399             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 400               (help-xref-button 1 'help-function def)))))
 401
 402       (setq file-name (find-lisp-object-file-name function def))
 403       (when file-name
 404         (princ " in `")
 405         ;; We used to add .el to the file name,
 406         ;; but that's completely wrong when the user used load-file.
 407         (princ (if (eq file-name 'C-source)
 408                    "C source code"
 409                  (file-name-nondirectory file-name)))
 410         (princ "'")
 411         ;; Make a hyperlink to the library.
 412         (with-current-buffer standard-output
 413           (save-excursion
 414             (re-search-backward "`\\([^`']+\\)'" nil t)
 415             (help-xref-button 1 'help-function-def function file-name))))
 416       (princ ".")
 417       (with-current-buffer (help-buffer)
 418         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 419                                   (point)))
 420       (terpri)(terpri)
 421       (when (commandp function)
 422         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 423               (remapped (command-remapping function)))
 424           (unless (memq remapped '(ignore undefined))
 425             (let ((keys (where-is-internal
 426                          (or remapped function) overriding-local-map nil nil))
 427                   non-modified-keys)
 428               (if (and (eq function 'self-insert-command)
 429                        (vectorp (car-safe keys))
 430                        (consp (aref (car keys) 0)))
 431                   (princ "It is bound to many ordinary text characters.\n")
 432                 ;; Which non-control non-meta keys run this command?
 433                 (dolist (key keys)
 434                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 435                       (push key non-modified-keys)))
 436                 (when remapped
 437                   (princ "It is remapped to `")
 438                   (princ (symbol-name remapped))
 439                   (princ "'"))
 440
 441                 (when keys
 442                   (princ (if remapped ", which is bound to " "It is bound to "))
 443                   ;; If lots of ordinary text characters run this command,
 444                   ;; don't mention them one by one.
 445                   (if (< (length non-modified-keys) 10)
 446                       (princ (mapconcat 'key-description keys ", "))
 447                     (dolist (key non-modified-keys)
 448                       (setq keys (delq key keys)))
 449                     (if keys
 450                         (progn
 451                           (princ (mapconcat 'key-description keys ", "))
 452                           (princ ", and many ordinary text characters"))
 453                       (princ "many ordinary text characters"))))
 454                 (when (or remapped keys non-modified-keys)
 455                   (princ ".")
 456                   (terpri)))))
 457
 458           (with-current-buffer (help-buffer)
 459             (fill-region-as-paragraph pt2 (point))
 460             (unless (looking-back "\n\n")
 461               (terpri)))))
 462       ;; Note that list* etc do not get this property until
 463       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 464       (when (and (symbolp function)
 465                  (eq (get function 'byte-compile)
 466                      'cl-byte-compile-compiler-macro))
 467         (princ "This function has a compiler macro")
 468         (let ((lib (get function 'compiler-macro-file)))
 469           (when (stringp lib)
 470             (princ (format " in `%s'" lib))
 471             (with-current-buffer standard-output
 472               (save-excursion
 473                 (re-search-backward "`\\([^`']+\\)'" nil t)
 474                 (help-xref-button 1 'help-function-cmacro function lib)))))
 475         (princ ".\n\n"))
 476       (let* ((advertised (gethash def advertised-signature-table t))
 477              (arglist (if (listp advertised)
 478                           advertised (help-function-arglist def)))
 479              (doc (condition-case err (documentation function)
 480                     (error (format "No Doc! %S" err))))
 481              (usage (help-split-fundoc doc function)))
 482         (with-current-buffer standard-output
 483           ;; If definition is a keymap, skip arglist note.
 484           (unless (keymapp function)
 485             (if usage (setq doc (cdr usage)))
 486             (let* ((use (cond
 487                          ((and usage (not (listp advertised))) (car usage))
 488                          ((listp arglist)
 489                           (format "%S" (help-make-usage function arglist)))
 490                          ((stringp arglist) arglist)
 491                          ;; Maybe the arglist is in the docstring of a symbol
 492                          ;; this one is aliased to.
 493                          ((let ((fun real-function))
 494                             (while (and (symbolp fun)
 495                                         (setq fun (symbol-function fun))
 496                                         (not (setq usage (help-split-fundoc
 497                                                           (documentation fun)
 498                                                           function)))))
 499                             usage)
 500                           (car usage))
 501                          ((or (stringp def)
 502                               (vectorp def))
 503                           (format "\nMacro: %s" (format-kbd-macro def)))
 504                          (t "[Missing arglist.  Please make a bug report.]")))
 505                    (high (help-highlight-arguments use doc)))
 506               (let ((fill-begin (point)))
 507                 (insert (car high) "\n")
 508                 (fill-region fill-begin (point)))
 509               (setq doc (cdr high))))
 510           (let* ((obsolete (and
 511                             ;; function might be a lambda construct.
 512                             (symbolp function)
 513                             (get function 'byte-obsolete-info)))
 514                  (use (car obsolete)))
 515             (when obsolete
 516               (princ "\nThis function is obsolete")
 517               (when (nth 2 obsolete)
 518                 (insert (format " since %s" (nth 2 obsolete))))
 519               (insert (cond ((stringp use) (concat ";\n" use))
 520                             (use (format ";\nuse `%s' instead." use))
 521                             (t "."))
 522                       "\n"))
 523             (insert "\n"
 524                     (or doc "Not documented."))))))))
 525
 526 \f
 527 ;; Variables
 528
 529 ;;;###autoload
 530 (defun variable-at-point (&optional any-symbol)
 531   "Return the bound variable symbol found at or before point.
 532 Return 0 if there is no such symbol.
 533 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 534   (with-syntax-table emacs-lisp-mode-syntax-table
 535     (or (condition-case ()
 536             (save-excursion
 537               (skip-chars-forward "'")
 538               (or (not (zerop (skip-syntax-backward "_w")))
 539                   (eq (char-syntax (following-char)) ?w)
 540                   (eq (char-syntax (following-char)) ?_)
 541                   (forward-sexp -1))
 542               (skip-chars-forward "'")
 543               (let ((obj (read (current-buffer))))
 544                 (and (symbolp obj) (boundp obj) obj)))
 545           (error nil))
 546         (let* ((str (find-tag-default))
 547                (sym (if str (intern-soft str))))
 548           (if (and sym (or any-symbol (boundp sym)))
 549               sym
 550             (save-match-data
 551               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 552                 (setq sym (intern-soft (match-string 1 str)))
 553                 (and (or any-symbol (boundp sym)) sym)))))
 554         0)))
 555
 556 (defun describe-variable-custom-version-info (variable)
 557   (let ((custom-version (get variable 'custom-version))
 558         (cpv (get variable 'custom-package-version))
 559         (output nil))
 560     (if custom-version
 561         (setq output
 562               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 563                       custom-version))
 564       (when cpv
 565         (let* ((package (car-safe cpv))
 566                (version (if (listp (cdr-safe cpv))
 567                             (car (cdr-safe cpv))
 568                           (cdr-safe cpv)))
 569                (pkg-versions (assq package customize-package-emacs-version-alist))
 570                (emacsv (cdr (assoc version pkg-versions))))
 571           (if (and package version)
 572               (setq output
 573                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 574                                     (if emacsv
 575                                         (format " that is part of Emacs %s" emacsv))
 576                                     ".\n")
 577                             version package))))))
 578     output))
 579
 580 ;;;###autoload
 581 (defun describe-variable (variable &optional buffer frame)
 582   "Display the full documentation of VARIABLE (a symbol).
 583 Returns the documentation as a string, also.
 584 If VARIABLE has a buffer-local value in BUFFER or FRAME
 585 \(default to the current buffer and current frame),
 586 it is displayed along with the global value."
 587   (interactive
 588    (let ((v (variable-at-point))
 589          (enable-recursive-minibuffers t)
 590          val)
 591      (setq val (completing-read (if (symbolp v)
 592                                     (format
 593                                      "Describe variable (default %s): " v)
 594                                   "Describe variable: ")
 595                                 obarray
 596                                 (lambda (vv)
 597                                   (and (not (keywordp vv))
 598                                        (or (boundp vv)
 599                                            (get vv 'variable-documentation))))
 600                                 t nil nil
 601                                 (if (symbolp v) (symbol-name v))))
 602      (list (if (equal val "")
 603                v (intern val)))))
 604   (let (file-name)
 605     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 606     (unless (frame-live-p frame) (setq frame (selected-frame)))
 607     (if (not (symbolp variable))
 608         (message "You did not specify a variable")
 609       (save-excursion
 610         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 611               val val-start-pos locus)
 612           ;; Extract the value before setting up the output buffer,
 613           ;; in case `buffer' *is* the output buffer.
 614           (unless valvoid
 615             (with-selected-frame frame
 616               (with-current-buffer buffer
 617                 (setq val (symbol-value variable)
 618                       locus (variable-binding-locus variable)))))
 619           (help-setup-xref (list #'describe-variable variable buffer)
 620                            (called-interactively-p 'interactive))
 621           (with-help-window (help-buffer)
 622             (with-current-buffer buffer
 623               (prin1 variable)
 624               (setq file-name (find-lisp-object-file-name variable 'defvar))
 625
 626               (if file-name
 627                   (progn
 628                     (princ " is a variable defined in `")
 629                     (princ (if (eq file-name 'C-source)
 630                                "C source code"
 631                              (file-name-nondirectory file-name)))
 632                     (princ "'.\n")
 633                     (with-current-buffer standard-output
 634                       (save-excursion
 635                         (re-search-backward "`\\([^`']+\\)'" nil t)
 636                         (help-xref-button 1 'help-variable-def
 637                                           variable file-name)))
 638                     (if valvoid
 639                         (princ "It is void as a variable.")
 640                       (princ "Its ")))
 641                 (if valvoid
 642                     (princ " is void as a variable.")
 643                   (princ "'s "))))
 644             (unless valvoid
 645               (with-current-buffer standard-output
 646                 (setq val-start-pos (point))
 647                 (princ "value is ")
 648                 (let ((from (point)))
 649                   (terpri)
 650                   (pp val)
 651                   (if (< (point) (+ 68 (line-beginning-position 0)))
 652                       (delete-region from (1+ from))
 653                     (delete-region (1- from) from))
 654                   (let* ((sv (get variable 'standard-value))
 655                          (origval (and (consp sv)
 656                                        (condition-case nil
 657                                            (eval (car sv))
 658                                          (error :help-eval-error)))))
 659                     (when (and (consp sv)
 660                                (not (equal origval val))
 661                                (not (equal origval :help-eval-error)))
 662                       (princ "\nOriginal value was \n")
 663                       (setq from (point))
 664                       (pp origval)
 665                       (if (< (point) (+ from 20))
 666                           (delete-region (1- from) from)))))))
 667             (terpri)
 668             (when locus
 669               (if (bufferp locus)
 670                   (princ (format "%socal in buffer %s; "
 671                                  (if (get variable 'permanent-local)
 672                                      "Permanently l" "L")
 673                                  (buffer-name)))
 674                 (princ (format "It is a frame-local variable; ")))
 675               (if (not (default-boundp variable))
 676                   (princ "globally void")
 677                 (let ((val (default-value variable)))
 678                   (with-current-buffer standard-output
 679                     (princ "global value is ")
 680                     (terpri)
 681                     ;; Fixme: pp can take an age if you happen to
 682                     ;; ask for a very large expression.  We should
 683                     ;; probably print it raw once and check it's a
 684                     ;; sensible size before prettyprinting.  -- fx
 685                     (let ((from (point)))
 686                       (pp val)
 687                       ;; See previous comment for this function.
 688                       ;; (help-xref-on-pp from (point))
 689                       (if (< (point) (+ from 20))
 690                           (delete-region (1- from) from))))))
 691               (terpri))
 692
 693             ;; If the value is large, move it to the end.
 694             (with-current-buffer standard-output
 695               (when (> (count-lines (point-min) (point-max)) 10)
 696                 ;; Note that setting the syntax table like below
 697                 ;; makes forward-sexp move over a `'s' at the end
 698                 ;; of a symbol.
 699                 (set-syntax-table emacs-lisp-mode-syntax-table)
 700                 (goto-char val-start-pos)
 701                 ;; The line below previously read as
 702                 ;; (delete-region (point) (progn (end-of-line) (point)))
 703                 ;; which suppressed display of the buffer local value for
 704                 ;; large values.
 705                 (when (looking-at "value is") (replace-match ""))
 706                 (save-excursion
 707                   (insert "\n\nValue:")
 708                   (set (make-local-variable 'help-button-cache)
 709                        (point-marker)))
 710                 (insert "value is shown ")
 711                 (insert-button "below"
 712                                'action help-button-cache
 713                                'follow-link t
 714                                'help-echo "mouse-2, RET: show value")
 715                 (insert ".\n")))
 716             (terpri)
 717
 718             (let* ((alias (condition-case nil
 719                               (indirect-variable variable)
 720                             (error variable)))
 721                    (obsolete (get variable 'byte-obsolete-variable))
 722                    (use (car obsolete))
 723                    (safe-var (get variable 'safe-local-variable))
 724                    (doc (or (documentation-property variable 'variable-documentation)
 725                             (documentation-property alias 'variable-documentation)))
 726                    (extra-line nil))
 727               ;; Add a note for variables that have been make-var-buffer-local.
 728               (when (and (local-variable-if-set-p variable)
 729                          (or (not (local-variable-p variable))
 730                              (with-temp-buffer
 731                                (local-variable-if-set-p variable))))
 732                 (setq extra-line t)
 733                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 734
 735               ;; Mention if it's an alias
 736               (unless (eq alias variable)
 737                 (setq extra-line t)
 738                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 739
 740               (when obsolete
 741                 (setq extra-line t)
 742                 (princ "  This variable is obsolete")
 743                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 744                 (princ (cond ((stringp use) (concat ";\n  " use))
 745                              (use (format ";\n  use `%s' instead." (car obsolete)))
 746                              (t ".")))
 747                 (terpri))
 748
 749               (when (member (cons variable val) file-local-variables-alist)
 750                 (setq extra-line t)
 751                 (if (member (cons variable val) dir-local-variables-alist)
 752                     (let ((file (and (buffer-file-name)
 753                                       (not (file-remote-p (buffer-file-name)))
 754                                       (dir-locals-find-file
 755                                        (buffer-file-name))))
 756                           (type "file"))
 757                       (princ "  This variable is a directory local variable")
 758                       (when file
 759                         (if (consp file) ; result from cache
 760                             ;; If the cache element has an mtime, we
 761                             ;; assume it came from a file.
 762                             (if (nth 2 file)
 763                                 (setq file (expand-file-name
 764                                             dir-locals-file (car file)))
 765                               ;; Otherwise, assume it was set directly.
 766                               (setq type "directory")))
 767                         (princ (format "\n  from the %s \"%s\"" type file)))
 768                       (princ ".\n"))
 769                   (princ "  This variable is a file local variable.\n")))
 770
 771               (when (memq variable ignored-local-variables)
 772                 (setq extra-line t)
 773                 (princ "  This variable is ignored when used as a file local \
 774 variable.\n"))
 775
 776               ;; Can be both risky and safe, eg auto-fill-function.
 777               (when (risky-local-variable-p variable)
 778                 (setq extra-line t)
 779                 (princ "  This variable is potentially risky when used as a \
 780 file local variable.\n")
 781                 (when (assq variable safe-local-variable-values)
 782                   (princ "  However, you have added it to \
 783 `safe-local-variable-values'.\n")))
 784
 785               (when safe-var
 786                 (setq extra-line t)
 787                 (princ "  This variable is safe as a file local variable ")
 788                 (princ "if its value\n  satisfies the predicate ")
 789                 (princ (if (byte-code-function-p safe-var)
 790                            "which is byte-compiled expression.\n"
 791                          (format "`%s'.\n" safe-var))))
 792
 793               (if extra-line (terpri))
 794               (princ "Documentation:\n")
 795               (with-current-buffer standard-output
 796                 (insert (or doc "Not documented as a variable."))))
 797
 798             ;; Make a link to customize if this variable can be customized.
 799             (when (custom-variable-p variable)
 800               (let ((customize-label "customize"))
 801                 (terpri)
 802                 (terpri)
 803                 (princ (concat "You can " customize-label " this variable."))
 804                 (with-current-buffer standard-output
 805                   (save-excursion
 806                     (re-search-backward
 807                      (concat "\\(" customize-label "\\)") nil t)
 808                     (help-xref-button 1 'help-customize-variable variable))))
 809               ;; Note variable's version or package version
 810               (let ((output (describe-variable-custom-version-info variable)))
 811                 (when output
 812                   (terpri)
 813                   (terpri)
 814                   (princ output))))
 815
 816             (with-current-buffer standard-output
 817               ;; Return the text we displayed.
 818               (buffer-string))))))))
 819
 820
 821 ;;;###autoload
 822 (defun describe-syntax (&optional buffer)
 823   "Describe the syntax specifications in the syntax table of BUFFER.
 824 The descriptions are inserted in a help buffer, which is then displayed.
 825 BUFFER defaults to the current buffer."
 826   (interactive)
 827   (setq buffer (or buffer (current-buffer)))
 828   (help-setup-xref (list #'describe-syntax buffer)
 829                    (called-interactively-p 'interactive))
 830   (with-help-window (help-buffer)
 831     (let ((table (with-current-buffer buffer (syntax-table))))
 832       (with-current-buffer standard-output
 833         (describe-vector table 'internal-describe-syntax-value)
 834         (while (setq table (char-table-parent table))
 835           (insert "\nThe parent syntax table is:")
 836           (describe-vector table 'internal-describe-syntax-value))))))
 837
 838 (defun help-describe-category-set (value)
 839   (insert (cond
 840            ((null value) "default")
 841            ((char-table-p value) "deeper char-table ...")
 842            (t (condition-case err
 843                   (category-set-mnemonics value)
 844                 (error "invalid"))))))
 845
 846 ;;;###autoload
 847 (defun describe-categories (&optional buffer)
 848   "Describe the category specifications in the current category table.
 849 The descriptions are inserted in a buffer, which is then displayed.
 850 If BUFFER is non-nil, then describe BUFFER's category table instead.
 851 BUFFER should be a buffer or a buffer name."
 852   (interactive)
 853   (setq buffer (or buffer (current-buffer)))
 854   (help-setup-xref (list #'describe-categories buffer)
 855                    (called-interactively-p 'interactive))
 856   (with-help-window (help-buffer)
 857     (let* ((table (with-current-buffer buffer (category-table)))
 858            (docs (char-table-extra-slot table 0)))
 859       (if (or (not (vectorp docs)) (/= (length docs) 95))
 860           (error "Invalid first extra slot in this category table\n"))
 861       (with-current-buffer standard-output
 862         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 863         (let ((pos (point)) (items 0) lines n)
 864           (dotimes (i 95)
 865             (if (aref docs i) (setq items (1+ items))))
 866           (setq lines (1+ (/ (1- items) 4)))
 867           (setq n 0)
 868           (dotimes (i 95)
 869             (let ((elt (aref docs i)))
 870               (when elt
 871                 (string-match ".*" elt)
 872                 (setq elt (match-string 0 elt))
 873                 (if (>= (length elt) 17)
 874                     (setq elt (concat (substring elt 0 14) "...")))
 875                 (if (< (point) (point-max))
 876                     (move-to-column (* 20 (/ n lines)) t))
 877                 (insert (+ i ?\s) ?: elt)
 878                 (if (< (point) (point-max))
 879                     (forward-line 1)
 880                   (insert "\n"))
 881                 (setq n (1+ n))
 882                 (if (= (% n lines) 0)
 883                     (goto-char pos))))))
 884         (goto-char (point-max))
 885         (insert "\n"
 886                 "character(s)\tcategory mnemonics\n"
 887                 "------------\t------------------")
 888         (describe-vector table 'help-describe-category-set)
 889         (insert "Legend of category mnemonics:\n")
 890         (dotimes (i 95)
 891           (let ((elt (aref docs i)))
 892             (when elt
 893               (if (string-match "\n" elt)
 894                   (setq elt (substring elt (match-end 0))))
 895               (insert (+ i ?\s) ": " elt "\n"))))
 896         (while (setq table (char-table-parent table))
 897           (insert "\nThe parent category table is:")
 898           (describe-vector table 'help-describe-category-set))))))
 899
 900 \f
 901 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
 902
 903 ;; Replaces lib-src/digest-doc.c.
 904 ;;;###autoload
 905 (defun doc-file-to-man (file)
 906   "Produce an nroff buffer containing the doc-strings from the DOC file."
 907   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 908                                      internal-doc-file-name t)))
 909   (or (file-readable-p file)
 910       (error "Cannot read file `%s'" file))
 911   (pop-to-buffer (generate-new-buffer "*man-doc*"))
 912   (setq buffer-undo-list t)
 913   (insert ".TH \"Command Summary for GNU Emacs\"\n"
 914           ".AU Richard M. Stallman\n")
 915   (insert-file-contents file)
 916   (let (notfirst)
 917     (while (search-forward "\x1f" nil 'move)
 918       (if (looking-at "S")
 919           (delete-region (1- (point)) (line-end-position))
 920         (delete-char -1)
 921         (if notfirst
 922             (insert "\n.DE\n")
 923           (setq notfirst t))
 924         (insert "\n.SH ")
 925         (insert (if (looking-at "F") "Function " "Variable "))
 926         (delete-char 1)
 927         (forward-line 1)
 928         (insert ".DS L\n"))))
 929   (insert "\n.DE\n")
 930   (setq buffer-undo-list nil)
 931   (nroff-mode))
 932
 933 ;; Replaces lib-src/sorted-doc.c.
 934 ;;;###autoload
 935 (defun doc-file-to-info (file)
 936   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
 937   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 938                                      internal-doc-file-name t)))
 939   (or (file-readable-p file)
 940       (error "Cannot read file `%s'" file))
 941   (let ((i 0) type name doc alist)
 942     (with-temp-buffer
 943       (insert-file-contents file)
 944       ;; The characters "@{}" need special treatment.
 945       (while (re-search-forward "[@{}]" nil t)
 946         (backward-char)
 947         (insert "@")
 948         (forward-char 1))
 949       (goto-char (point-min))
 950       (while (search-forward "\x1f" nil t)
 951         (unless (looking-at "S")
 952           (setq type (char-after)
 953                 name (buffer-substring (1+ (point)) (line-end-position))
 954                 doc (buffer-substring (line-beginning-position 2)
 955                                       (if (search-forward  "\x1f" nil 'move)
 956                                           (1- (point))
 957                                         (point)))
 958                 alist (cons (list name type doc) alist))
 959           (backward-char 1))))
 960     (pop-to-buffer (generate-new-buffer "*info-doc*"))
 961     (setq buffer-undo-list t)
 962     ;; Write the output header.
 963     (insert "\\input texinfo  @c -*-texinfo-*-\n"
 964             "@setfilename emacsdoc.info\n"
 965             "@settitle Command Summary for GNU Emacs\n"
 966             "@finalout\n"
 967             "\n@node Top\n"
 968             "@unnumbered Command Summary for GNU Emacs\n\n"
 969             "@table @asis\n\n"
 970             "@iftex\n"
 971             "@global@let@ITEM@item\n"
 972             "@def@item{@filbreak@vskip5pt@ITEM}\n"
 973             "@font@tensy cmsy10 scaled @magstephalf\n"
 974             "@font@teni cmmi10 scaled @magstephalf\n"
 975             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
 976             "@def|{{@tensy@char106}}\n"
 977             "@def@{{{@tensy@char102}}\n"
 978             "@def@}{{@tensy@char103}}\n"
 979             "@def<{{@teni@char62}}\n"
 980             "@def>{{@teni@char60}}\n"
 981             "@chardef@@64\n"
 982             "@catcode43=12\n"
 983             "@tableindent-0.2in\n"
 984             "@end iftex\n")
 985     ;; Sort the array by name; within each name, by type (functions first).
 986     (setq alist (sort alist (lambda (e1 e2)
 987                               (if (string-equal (car e1) (car e2))
 988                                   (<= (cadr e1) (cadr e2))
 989                                 (string-lessp (car e1) (car e2))))))
 990     ;; Print each function.
 991     (dolist (e alist)
 992       (insert "\n@item "
 993               (if (char-equal (cadr e) ?\F) "Function" "Variable")
 994               " @code{" (car e) "}\n@display\n"
 995               (nth 2 e)
 996               "\n@end display\n")
 997       ;; Try to avoid a save size overflow in the TeX output routine.
 998       (if (zerop (setq i (% (1+ i) 100)))
 999           (insert "\n@end table\n@table @asis\n")))
1000     (insert "@end table\n"
1001             "@bye\n")
1002     (setq buffer-undo-list nil)
1003     (texinfo-mode)))
1004
1005 (provide 'help-fns)
1006
1007 ;;; help-fns.el ends here