lisp/mail/mailalias.el

   1 ;;; mailalias.el --- expand and complete mailing address aliases
   2
   3 ;; Copyright (C) 1985, 1987, 1995, 1996, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Basic functions for defining and expanding mail aliases.
  27 ;; These seal off the interface to the alias-definition parts of a
  28 ;; .mailrc file formatted for BSD's Mail or USL's mailx.
  29
  30 ;;; Code:
  31
  32 (require 'sendmail)
  33
  34 (defgroup mailalias nil
  35   "Expanding mail aliases."
  36   :group 'mail)
  37
  38 (defcustom mail-passwd-files '("/etc/passwd")
  39   "List of files from which to determine valid user names."
  40   :type '(repeat string)
  41   :group 'mailalias)
  42
  43 (defcustom mail-passwd-command nil
  44   "Shell command to retrieve text to add to `/etc/passwd', or nil."
  45   :type '(choice string (const nil))
  46   :group 'mailalias)
  47
  48 (defvar mail-directory-names t
  49   "Alist of mail address directory entries.
  50 When t this still needs to be initialized.")
  51
  52 (defvar mail-address-field-regexp
  53   "^\\(Resent-\\)?\\(To\\|From\\|CC\\|BCC\\|Reply-to\\):")
  54
  55 (defcustom mail-complete-alist
  56   ;; Don't use backquote here; we don't want backquote to get loaded
  57   ;; just because of loading this file.
  58   ;; Don't refer to mail-address-field-regexp here;
  59   ;; that confuses some things such as cus-dep.el.
  60   (cons '("^\\(Resent-\\)?\\(To\\|From\\|CC\\|BCC\\|Reply-to\\):"
  61           . (mail-get-names pattern))
  62         '(("Newsgroups:" . (if (boundp 'gnus-active-hashtb)
  63                                gnus-active-hashtb
  64                              (if (boundp news-group-article-assoc)
  65                                  news-group-article-assoc)))
  66           ("Followup-To:" . (mail-sentto-newsgroups))
  67           ;;("Distribution:" ???)
  68           ))
  69   "Alist of header field and expression to return alist for completion.
  70 The expression may reference the variable `pattern'
  71 which will hold the string being completed.
  72 If not on matching header, `mail-complete-function' gets called instead."
  73   :type 'alist
  74   :group 'mailalias)
  75 (put 'mail-complete-alist 'risky-local-variable t)
  76
  77 ;;;###autoload
  78 (defcustom mail-complete-style 'angles
  79   "Specifies how \\[mail-complete] formats the full name when it completes.
  80 If `nil', they contain just the return address like:
  81         king@grassland.com
  82 If `parens', they look like:
  83         king@grassland.com (Elvis Parsley)
  84 If `angles', they look like:
  85         Elvis Parsley <king@grassland.com>"
  86   :type '(choice (const angles) (const parens) (const nil))
  87   :group 'mailalias)
  88
  89 (defcustom mail-complete-function 'ispell-complete-word
  90   "Function to call when completing outside `mail-complete-alist'-header."
  91   :type '(choice function (const nil))
  92   :group 'mailalias)
  93
  94 (defcustom mail-directory-function nil
  95   "Function to get completions from directory service or nil for none.
  96 See `mail-directory-requery'."
  97   :type '(choice function (const nil))
  98   :group 'mailalias)
  99
 100 ;; This is for when the directory is huge, or changes frequently.
 101 (defcustom mail-directory-requery nil
 102   "When non-nil call `mail-directory-function' for each completion.
 103 In that case, one argument gets passed to the function, the partial string
 104 entered so far."
 105   :type 'boolean
 106   :group 'mailalias)
 107
 108 (defcustom mail-directory-process nil
 109   "Shell command to get the list of names from a mail directory.
 110 This value is used when the value of `mail-directory-function'
 111 is `mail-directory-process'.  The value should be a list
 112 of the form (COMMAND ARG ...), where each of the list elements
 113 is evaluated.  COMMAND should evaluate to a string.  When
 114 `mail-directory-requery' is non-nil, during evaluation of these
 115 elements, the variable `pattern' contains the partial input being
 116 completed.  `pattern' is nil when `mail-directory-requery' is nil.
 117
 118 The value might look like this:
 119
 120   '(remote-shell-program \"HOST\" \"-nl\" \"USER\" \"COMMAND\")
 121
 122 or like this:
 123
 124   '(remote-shell-program \"HOST\" \"-n\" \"COMMAND '^\" pattern \"'\")"
 125   :type 'sexp
 126   :group 'mailalias)
 127 (put 'mail-directory-process 'risky-local-variable t)
 128
 129 (defcustom mail-directory-stream nil
 130   "List of (HOST SERVICE) for stream connection to mail directory."
 131   :type 'sexp
 132   :group 'mailalias)
 133 (put 'mail-directory-stream 'risky-local-variable t)
 134
 135 (defcustom mail-directory-parser nil
 136   "How to interpret the output of `mail-directory-function'.
 137 Three types of values are possible:
 138
 139   - nil means to gather each line as one name
 140   - regexp means first \\(grouping\\) in successive matches is name
 141   - function called at beginning of buffer that returns an alist of names"
 142   :type '(choice (const nil) regexp function)
 143   :group 'mailalias)
 144 (put 'mail-directory-parser 'risky-local-variable t)
 145
 146 ;; Internal variables.
 147
 148 (defvar mail-names t
 149   "Alist of local users, aliases and directory entries as available.
 150 Elements have the form (MAILNAME) or (MAILNAME . FULLNAME).
 151 If the value means t, it means the real value should be calculated
 152 for the next use.  This is used in `mail-complete'.")
 153
 154 (defvar mail-local-names t
 155   "Alist of local users.
 156 When t this still needs to be initialized.")
 157 \f
 158
 159 ;; Called from sendmail-send-it, or similar functions,
 160 ;; only if some mail aliases are defined.
 161 ;;;###autoload
 162 (defun expand-mail-aliases (beg end &optional exclude)
 163   "Expand all mail aliases in suitable header fields found between BEG and END.
 164 If interactive, expand in header fields.
 165 Suitable header fields are `To', `From', `CC' and `BCC', `Reply-to', and
 166 their `Resent-' variants.
 167
 168 Optional second arg EXCLUDE may be a regular expression defining text to be
 169 removed from alias expansions."
 170   (interactive
 171    (save-excursion
 172      (list (goto-char (point-min))
 173            (mail-header-end))))
 174   (sendmail-sync-aliases)
 175   (when (eq mail-aliases t)
 176     (setq mail-aliases nil)
 177     (build-mail-aliases))
 178   (save-excursion
 179     (goto-char beg)
 180     (setq end (set-marker (make-marker) end))
 181     (let ((case-fold-search nil))
 182       (while (let ((case-fold-search t))
 183                (re-search-forward mail-address-field-regexp end t))
 184         (skip-chars-forward " \t")
 185         (let ((beg1 (point))
 186               end1 pos epos seplen
 187               ;; DISABLED-ALIASES records aliases temporarily disabled
 188               ;; while we scan text that resulted from expanding those aliases.
 189               ;; Each element is (ALIAS . TILL-WHEN), where TILL-WHEN
 190               ;; is where to reenable the alias (expressed as number of chars
 191               ;; counting from END1).
 192               (disabled-aliases nil))
 193           (re-search-forward "^[^ \t]" end 'move)
 194           (beginning-of-line)
 195           (skip-chars-backward " \t\n")
 196           (setq end1 (point-marker))
 197           (goto-char beg1)
 198           (while (< (point) end1)
 199             (setq pos (point))
 200             ;; Reenable any aliases which were disabled for ranges
 201             ;; that we have passed out of.
 202             (while (and disabled-aliases
 203                         (> pos (- end1 (cdr (car disabled-aliases)))))
 204               (setq disabled-aliases (cdr disabled-aliases)))
 205             ;; EPOS gets position of end of next name;
 206             ;; SEPLEN gets length of whitespace&separator that follows it.
 207             (if (re-search-forward "[ \t]*[\n,][ \t]*" end1 t)
 208                 (setq epos (match-beginning 0)
 209                       seplen (- (point) epos))
 210               (setq epos (marker-position end1) seplen 0))
 211             (let ((string (buffer-substring-no-properties pos epos))
 212                   translation)
 213               (if (and (not (assoc string disabled-aliases))
 214                        (setq translation (cdr (assoc string mail-aliases))))
 215                   (progn
 216                     ;; This name is an alias.  Disable it.
 217                     (setq disabled-aliases (cons (cons string (- end1 epos))
 218                                                  disabled-aliases))
 219                     ;; Replace the alias with its expansion
 220                     ;; then rescan the expansion for more aliases.
 221                     (goto-char pos)
 222                     (insert translation)
 223                     (when exclude
 224                       (let ((regexp (concat "\\b\\(" exclude "\\)\\b"))
 225                             (end (point-marker)))
 226                         (goto-char pos)
 227                         (while (re-search-forward regexp end t)
 228                           (replace-match ""))
 229                         (goto-char end)))
 230                     (delete-region (point) (+ (point) (- epos pos)))
 231                     (goto-char pos))
 232                 ;; Name is not an alias.  Skip to start of next name.
 233                 (goto-char epos)
 234                 (forward-char seplen))))
 235           (set-marker end1 nil)))
 236       (set-marker end nil))))
 237
 238 ;; Called by mail-setup, or similar functions, only if the file specified
 239 ;; by mail-personal-alias-file (usually `~/.mailrc') exists.
 240 (defun build-mail-aliases (&optional file)
 241   "Read mail aliases from personal aliases file and set `mail-aliases'.
 242 By default, this is the file specified by `mail-personal-alias-file'."
 243   (setq file (expand-file-name (or file mail-personal-alias-file)))
 244   ;; In case mail-aliases is t, make sure define-mail-alias
 245   ;; does not recursively call build-mail-aliases.
 246   (setq mail-aliases nil)
 247   (with-temp-buffer
 248     (while file
 249       (cond ((get-file-buffer file)
 250              (insert (with-current-buffer (get-file-buffer file)
 251                        (buffer-substring-no-properties
 252                         (point-min) (point-max)))))
 253             ((file-exists-p file) (insert-file-contents file))
 254             ((file-exists-p (setq file (expand-file-name file "~/")))
 255              (insert-file-contents file))
 256             (t (setq file nil)))
 257       (goto-char (point-min))
 258       ;; Delete comments from the contents.
 259       (while (search-forward "# " nil t)
 260         (let ((p (- (point) 2)))
 261           (end-of-line)
 262           (delete-region p (point))))
 263       ;; Don't lose if no final newline.
 264       (goto-char (point-max))
 265       (or (eq (preceding-char) ?\n) (newline))
 266       (goto-char (point-min))
 267       ;; handle "\\\n" continuation lines
 268       (while (not (eobp))
 269         (end-of-line)
 270         (if (= (preceding-char) ?\\)
 271             (progn (delete-char -1) (delete-char 1) (insert ?\ ))
 272           (forward-char 1)))
 273       (goto-char (point-min))
 274       ;; handle `source' directives -- Eddy/1994/May/25
 275       (cond ((re-search-forward "^source[ \t]+" nil t)
 276              (re-search-forward "\\S-+")
 277              (setq file (buffer-substring-no-properties
 278                          (match-beginning 0) (match-end 0)))
 279              (beginning-of-line)
 280              (insert "# ")   ; to ensure we don't re-process this file
 281              (beginning-of-line))
 282             (t (setq file nil))))
 283     (goto-char (point-min))
 284     (while (re-search-forward
 285             "^\\(a\\|alias\\|g\\|group\\)[ \t]+\\([^ \t\n]+\\)" nil t)
 286       (let* ((name (match-string 2))
 287              (start (progn (skip-chars-forward " \t") (point)))
 288              value)
 289         (end-of-line)
 290         (setq value (buffer-substring-no-properties start (point)))
 291         (unless (equal value "")
 292           (define-mail-alias name value t))))
 293     mail-aliases))
 294
 295 ;; Always autoloadable in case the user wants to define aliases
 296 ;; interactively or in .emacs.
 297 ;; define-mail-abbrev in mailabbrev.el duplicates much of this code.
 298 ;;;###autoload
 299 (defun define-mail-alias (name definition &optional from-mailrc-file)
 300   "Define NAME as a mail alias that translates to DEFINITION.
 301 This means that sending a message to NAME will actually send to DEFINITION.
 302
 303 Normally, the addresses in DEFINITION must be separated by commas.
 304 If FROM-MAILRC-FILE is non-nil, then addresses in DEFINITION
 305 can be separated by spaces; an address can contain spaces
 306 if it is quoted with double-quotes."
 307
 308   (interactive "sDefine mail alias: \nsDefine %s as mail alias for: ")
 309   ;; Read the defaults first, if we have not done so.
 310   ;; But not if we are doing that already right now.
 311   (unless from-mailrc-file
 312     (sendmail-sync-aliases))
 313   (if (eq mail-aliases t)
 314       (progn
 315         (setq mail-aliases nil)
 316         (if (file-exists-p mail-personal-alias-file)
 317             (build-mail-aliases))))
 318   ;; strip garbage from front and end
 319   (if (string-match "\\`[ \t\n,]+" definition)
 320       (setq definition (substring definition (match-end 0))))
 321   (if (string-match "[ \t\n,]+\\'" definition)
 322       (setq definition (substring definition 0 (match-beginning 0))))
 323
 324   (let* ((L (length definition))
 325          (start (if (> L 0) 0))
 326          end this-entry result tem)
 327     (while start
 328       (cond
 329        (from-mailrc-file
 330         ;; If we're reading from the mailrc file, addresses are
 331         ;; delimited by spaces, and addresses with embedded spaces are
 332         ;; surrounded by non-escaped double-quotes.
 333         (if (eq ?\" (aref definition start))
 334             (setq start (1+ start)
 335                   end (and (string-match
 336                             "[^\\]\\(\\([\\][\\]\\)*\\)\"[ \t,]*"
 337                             definition start)
 338                            (match-end 1)))
 339           (setq end (string-match "[ \t,]+" definition start)))
 340         ;; Extract the address and advance the loop past it.
 341         (setq this-entry (substring definition start end)
 342               start (and end (/= (match-end 0) L) (match-end 0)))
 343         ;; If the full name contains a problem character, quote it.
 344         (and (string-match "\\(.+?\\)[ \t]*\\(<.*>\\)" this-entry)
 345              (string-match "[^- !#$%&'*+/0-9=?A-Za-z^_`{|}~]"
 346                            (match-string 1 this-entry))
 347              (setq this-entry (replace-regexp-in-string
 348                                "\\(.+?\\)[ \t]*\\(<.*>\\)"
 349                                "\"\\1\" \\2"
 350                                this-entry))))
 351        ;; When we are not reading from .mailrc, addresses are
 352        ;; separated by commas.  Try to accept a rfc822-like syntax.
 353        ;; (Todo: extend rfc822.el to do the work for us.)
 354        ((equal (string-match
 355                 "[ \t,]*\\(\"\\(?:[^\"]\\|[^\\]\\(?:[\\][\\]\\)*\"\\)*\"[ \t]*\
 356 <[-.!#$%&'*+/0-9=?A-Za-z^_`{|}~@]+>\\)[ \t,]*"
 357                 definition start)
 358                start)
 359         ;; If an entry has a valid [ "foo bar" <foo@example.com> ]
 360         ;; form, use it literally .  This also allows commas in the
 361         ;; quoted string, e.g.  [ "foo bar, jr" <foo@example.com> ]
 362         (setq this-entry (match-string 1 definition)
 363               start (and (/= (match-end 0) L) (match-end 0))))
 364        (t
 365         ;; Otherwise, read the next address by looking for a comma.
 366         (setq end (string-match "[ \t\n,]*,[ \t\n]*" definition start))
 367         (setq this-entry (substring definition start end))
 368         ;; Advance the loop past this address.
 369         (setq start (and end (/= (match-end 0) L) (match-end 0)))
 370         ;; If the full name contains a problem character, quote it.
 371         (and (string-match "\\(.+?\\)[ \t]*\\(<.*>\\)" this-entry)
 372              (string-match "[^- !#$%&'*+/0-9=?A-Za-z^_`{|}~]"
 373                            (match-string 1 this-entry))
 374              (setq this-entry (replace-regexp-in-string
 375                                "\\(.+?\\)[ \t]*\\(<.*>\\)" "\"\\1\" \\2"
 376                                this-entry)))))
 377       (push this-entry result))
 378
 379     (setq definition (mapconcat (function identity)
 380                                 (nreverse result) ", "))
 381     (setq tem (assoc name mail-aliases))
 382     (if tem
 383         (rplacd tem definition)
 384       (setq mail-aliases (cons (cons name definition) mail-aliases)
 385             mail-names t))))
 386
 387 ;;;###autoload
 388 (defun mail-complete (arg)
 389   "Perform completion on header field or word preceding point.
 390 Completable headers are according to `mail-complete-alist'.  If none matches
 391 current header, calls `mail-complete-function' and passes prefix arg if any."
 392   (interactive "P")
 393   ;; Read the defaults first, if we have not done so.
 394   (sendmail-sync-aliases)
 395   (if (eq mail-aliases t)
 396       (progn
 397         (setq mail-aliases nil)
 398         (if (file-exists-p mail-personal-alias-file)
 399             (build-mail-aliases))))
 400   (let ((list mail-complete-alist))
 401     (if (and (< 0 (mail-header-end))
 402              (save-excursion
 403                (if (re-search-backward "^[^\t]" nil t)
 404                    (while list
 405                      (if (looking-at (car (car list)))
 406                          (setq arg (cdr (car list))
 407                                list ())
 408                        (setq list (cdr list)))))
 409                arg))
 410         (let* ((end (point))
 411                (beg (save-excursion
 412                       (skip-chars-backward "^ \t<,:")
 413                       (point)))
 414                (pattern (buffer-substring beg end))
 415                completion)
 416           (setq list (eval arg)
 417                 completion (try-completion pattern list))
 418           (cond ((eq completion t))
 419                 ((null completion)
 420                  (message "Can't find completion for \"%s\"" pattern)
 421                  (ding))
 422                 ((not (string= pattern completion))
 423                  (delete-region beg end)
 424                  (let ((alist-elt (assoc completion mail-names)))
 425                    (if (cdr alist-elt)
 426                        (cond ((eq mail-complete-style 'parens)
 427                               (insert completion " (" (cdr alist-elt) ")"))
 428                              ((eq mail-complete-style 'angles)
 429                               (insert (cdr alist-elt) " <" completion ">"))
 430                              (t
 431                               (insert completion)))
 432                      (insert completion))))
 433                 (t
 434                  (message "Making completion list...")
 435                  (with-output-to-temp-buffer "*Completions*"
 436                    (display-completion-list
 437                     (all-completions pattern list)))
 438                  (message "Making completion list...%s" "done"))))
 439       (funcall mail-complete-function arg))))
 440
 441 (defun mail-get-names (pattern)
 442   "Fetch local users and global mail addresses for completion.
 443 Consults `/etc/passwd' and a directory service if one is set up via
 444 `mail-directory-function'.
 445 PATTERN is the string we want to complete."
 446   (if (eq mail-local-names t)
 447       (with-current-buffer (generate-new-buffer " passwd")
 448         (let ((files mail-passwd-files))
 449           (while files
 450             (insert-file-contents (car files) nil nil nil t)
 451             (setq files (cdr files))))
 452         (if mail-passwd-command
 453             (call-process shell-file-name nil t nil
 454                           shell-command-switch mail-passwd-command))
 455         (goto-char (point-min))
 456         (setq mail-local-names nil)
 457         (while (not (eobp))
 458           ;;Recognize lines like
 459           ;;  nobody:*:65534:65534::/:
 460           ;;  +demo::::::/bin/csh
 461           ;;  +ethanb
 462           ;;while skipping
 463           ;;  +@SOFTWARE
 464           ;; The second \(...\) matches the user id.
 465           (if (looking-at "\\+?\\([^:@\n+]+\\):[^:\n]*:\\([^\n:]*\\):")
 466               (add-to-list 'mail-local-names
 467                            (cons (match-string 1)
 468                                  (user-full-name
 469                                   (string-to-number (match-string 2))))))
 470           (beginning-of-line 2))
 471         (kill-buffer (current-buffer))))
 472   (if (or (eq mail-names t)
 473           (eq mail-directory-names t))
 474       (let (directory)
 475         (and mail-directory-function
 476              (eq mail-directory-names t)
 477              (setq directory
 478                    (mail-directory (if mail-directory-requery pattern))))
 479         (or mail-directory-requery
 480             (setq mail-directory-names directory))
 481         (if (or directory
 482                 (eq mail-names t))
 483             (setq mail-names
 484                   (sort (append (if (consp mail-aliases)
 485                                     (mapcar
 486                                      (function (lambda (a) (list (car a))))
 487                                      mail-aliases))
 488                                 (if (consp mail-local-names)
 489                                     mail-local-names)
 490                                 (or directory
 491                                     (when (consp mail-directory-names)
 492                                       mail-directory-names)))
 493                         (lambda (a b)
 494                           ;; should cache downcased strings
 495                           (string< (downcase (car a))
 496                                    (downcase (car b)))))))))
 497   mail-names)
 498
 499
 500 (defun mail-directory (pattern)
 501   "Use mail-directory facility to get user names matching PATTERN.
 502 If PATTERN is nil, get all the defined user names.
 503 This function calls `mail-directory-function' to query the directory,
 504 then uses `mail-directory-parser' to parse the output it returns."
 505   (message "Querying directory...")
 506   (with-current-buffer (generate-new-buffer " *mail-directory*")
 507     (funcall mail-directory-function pattern)
 508     (goto-char (point-min))
 509     (let (directory)
 510       (if (stringp mail-directory-parser)
 511           (while (re-search-forward mail-directory-parser nil t)
 512             (setq directory
 513                   (cons (match-string 1) directory)))
 514         (if mail-directory-parser
 515             (setq directory (funcall mail-directory-parser))
 516           (while (not (eobp))
 517             (setq directory
 518                   (cons (buffer-substring (point)
 519                                           (progn
 520                                             (forward-line)
 521                                             (if (bolp)
 522                                                 (1- (point))
 523                                               (point))))
 524                         directory)))))
 525       (kill-buffer (current-buffer))
 526       (message "Querying directory...done")
 527       directory)))
 528
 529
 530 (defun mail-directory-process (pattern)
 531   "Run a shell command to output names in directory.
 532 See `mail-directory-process'."
 533   (when (consp mail-directory-process)
 534     (apply 'call-process (eval (car mail-directory-process)) nil t nil
 535            (mapcar 'eval (cdr mail-directory-process)))))
 536
 537 ;; This should handle a dialog.  Currently expects port to spit out names.
 538 (defun mail-directory-stream (pattern)
 539   "Open a stream to retrieve names in directory.
 540 See `mail-directory-stream'."
 541   (let (mailalias-done)
 542     (set-process-sentinel
 543      (apply 'open-network-stream "mailalias" (current-buffer)
 544             mail-directory-stream)
 545      (lambda (x y)
 546        (setq mailalias-done t)))
 547     (while (not mailalias-done)
 548       (sit-for .1))))
 549
 550 (defun mail-sentto-newsgroups ()
 551   "Return all entries from Newsgroups: header as completion alist."
 552   (save-excursion
 553     (if (mail-position-on-field "newsgroups" t)
 554         (let ((point (point))
 555               list)
 556           (while (< (skip-chars-backward "^:, \t\n") 0)
 557             (setq list `((,(buffer-substring (point) point))
 558                          ,@list))
 559             (skip-chars-backward ", \t\n")
 560             (setq point (point)))
 561           list))))
 562
 563 (provide 'mailalias)
 564
 565 ;; arch-tag: 1d6a0f87-eb34-4d45-8816-60c1b952cf46
 566 ;;; mailalias.el ends here