lisp/vc/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2006-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: vc tools
   8 ;; Package: vc
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a mercurial version control backend
  28
  29 ;;; Thanks:
  30
  31 ;;; Bugs:
  32
  33 ;;; Installation:
  34
  35 ;;; Todo:
  36
  37 ;; 1) Implement the rest of the vc interface. See the comment at the
  38 ;; beginning of vc.el. The current status is:
  39
  40 ;; FUNCTION NAME                               STATUS
  41 ;; BACKEND PROPERTIES
  42 ;; * revision-granularity                      OK
  43 ;; STATE-QUERYING FUNCTIONS
  44 ;; * registered (file)                         OK
  45 ;; * state (file)                              OK
  46 ;; - dir-status (dir update-function)          OK
  47 ;; - dir-status-files (dir files ds uf)        OK
  48 ;; - dir-extra-headers (dir)                   OK
  49 ;; - dir-printer (fileinfo)                    OK
  50 ;; * working-revision (file)                   OK
  51 ;; - latest-on-branch-p (file)                 ??
  52 ;; * checkout-model (files)                    OK
  53 ;; - mode-line-string (file)                   NOT NEEDED
  54 ;; STATE-CHANGING FUNCTIONS
  55 ;; * register (files &optional rev comment)    OK
  56 ;; * create-repo ()                            OK
  57 ;; - responsible-p (file)                      OK
  58 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  59 ;; - unregister (file)                         OK
  60 ;; * checkin (files rev comment)               OK
  61 ;; * find-revision (file rev buffer)           OK
  62 ;; * checkout (file &optional rev)             OK
  63 ;; * revert (file &optional contents-done)     OK
  64 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  65 ;; - merge (file rev1 rev2)                    NEEDED
  66 ;; - merge-news (file)                         NEEDED
  67 ;; - steal-lock (file &optional revision)      NOT NEEDED
  68 ;; HISTORY FUNCTIONS
  69 ;; * print-log (files buffer &optional shortlog start-revision limit) OK
  70 ;; - log-view-mode ()                          OK
  71 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  72 ;; - comment-history (file)                    NOT NEEDED
  73 ;; - update-changelog (files)                  NOT NEEDED
  74 ;; * diff (files &optional rev1 rev2 buffer)   OK
  75 ;; - revision-completion-table (files)         OK?
  76 ;; - annotate-command (file buf &optional rev) OK
  77 ;; - annotate-time ()                          OK
  78 ;; - annotate-current-time ()                  NOT NEEDED
  79 ;; - annotate-extract-revision-at-line ()      OK
  80 ;; TAG SYSTEM
  81 ;; - create-tag (dir name branchp)             OK
  82 ;; - retrieve-tag (dir name update)            OK FIXME UPDATE BUFFERS
  83 ;; MISCELLANEOUS
  84 ;; - make-version-backups-p (file)             ??
  85 ;; - previous-revision (file rev)              OK
  86 ;; - next-revision (file rev)                  OK
  87 ;; - check-headers ()                          ??
  88 ;; - clear-headers ()                          ??
  89 ;; - delete-file (file)                        TEST IT
  90 ;; - rename-file (old new)                     OK
  91 ;; - find-file-hook ()                         added for bug#10709
  92
  93 ;; 2) Implement Stefan Monnier's advice:
  94 ;; vc-hg-registered and vc-hg-state
  95 ;; Both of those functions should be super extra careful to fail gracefully in
  96 ;; unexpected circumstances. The reason this is important is that any error
  97 ;; there will prevent the user from even looking at the file :-(
  98 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
  99 ;; mercurial's control and extracting the current revision should be done
 100 ;; without even using `hg' (this way even if you don't have `hg' installed,
 101 ;; Emacs is able to tell you this file is under mercurial's control).
 102
 103 ;;; History:
 104 ;;
 105
 106 ;;; Code:
 107
 108 (eval-when-compile
 109   (require 'cl-lib)
 110   (require 'vc)
 111   (require 'vc-dir))
 112
 113 ;;; Customization options
 114
 115 (defgroup vc-hg nil
 116   "VC Mercurial (hg) backend."
 117   :version "24.1"
 118   :group 'vc)
 119
 120 (defcustom vc-hg-global-switches nil
 121   "Global switches to pass to any Hg command."
 122   :type '(choice (const :tag "None" nil)
 123          (string :tag "Argument String")
 124          (repeat :tag "Argument List" :value ("") string))
 125   :version "22.2"
 126   :group 'vc-hg)
 127
 128 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 129   "String or list of strings specifying switches for Hg diff under VC.
 130 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 131   :type '(choice (const :tag "Unspecified" nil)
 132                  (const :tag "None" t)
 133                  (string :tag "Argument String")
 134                  (repeat :tag "Argument List" :value ("") string))
 135   :version "23.1"
 136   :group 'vc-hg)
 137
 138 (defcustom vc-hg-program "hg"
 139   "Name of the Mercurial executable (excluding any arguments)."
 140   :type 'string
 141   :group 'vc-hg)
 142
 143 (defcustom vc-hg-root-log-format
 144   `(,(concat "{rev}:{ifeq(branch, 'default','', '{branch}')}"
 145              ":{bookmarks}:{tags}:{author|person}"
 146              " {date|shortdate} {desc|firstline}\\n")
 147     ,(concat "^\\(?:[+@o x|-]*\\)"      ;Graph data.
 148              "\\([0-9]+\\):\\([^:]*\\)"
 149              ":\\([^:]*\\):\\([^:]*\\):\\(.*?\\)"
 150              "[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)")
 151     ((1 'log-view-message-face)
 152      (2 'change-log-file)
 153      (3 'change-log-list)
 154      (4 'change-log-conditionals)
 155      (5 'change-log-name)
 156      (6 'change-log-date)))
 157   "Mercurial log template for `vc-hg-print-log' short format.
 158 This should be a list (TEMPLATE REGEXP KEYWORDS), where TEMPLATE
 159 is the \"--template\" argument string to pass to Mercurial,
 160 REGEXP is a regular expression matching the resulting Mercurial
 161 output, and KEYWORDS is a list of `font-lock-keywords' for
 162 highlighting the Log View buffer."
 163   :type '(list string string (repeat sexp))
 164   :group 'vc-hg
 165   :version "24.5")
 166
 167 \f
 168 ;;; Properties of the backend
 169
 170 (defvar vc-hg-history nil)
 171
 172 (defun vc-hg-revision-granularity () 'repository)
 173 (defun vc-hg-checkout-model (_files) 'implicit)
 174
 175 ;;; State querying functions
 176
 177 ;;;###autoload (defun vc-hg-registered (file)
 178 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 179 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 180 ;;;###autoload       (progn
 181 ;;;###autoload         (load "vc-hg" nil t)
 182 ;;;###autoload         (vc-hg-registered file))))
 183
 184 ;; Modeled after the similar function in vc-bzr.el
 185 (defun vc-hg-registered (file)
 186   "Return non-nil if FILE is registered with hg."
 187   (when (vc-hg-root file)           ; short cut
 188     (let ((state (vc-hg-state file)))  ; expensive
 189       (and state (not (memq state '(ignored unregistered)))))))
 190
 191 (defun vc-hg-state (file)
 192   "Hg-specific version of `vc-state'."
 193   (let*
 194       ((status nil)
 195        (default-directory (file-name-directory file))
 196        (out
 197         (with-output-to-string
 198           (with-current-buffer
 199               standard-output
 200             (setq status
 201                   (condition-case nil
 202                       ;; Ignore all errors.
 203                       (let ((process-environment
 204                              ;; Avoid localization of messages so we
 205                              ;; can parse the output.  Disable pager.
 206                              (append
 207                               (list "TERM=dumb" "LANGUAGE=C" "HGPLAIN=1")
 208                               process-environment)))
 209                         (process-file
 210                          vc-hg-program nil t nil
 211                          "--config" "alias.status=status"
 212                          "--config" "defaults.status="
 213                          "status" "-A" (file-relative-name file)))
 214                     ;; Some problem happened.  E.g. We can't find an `hg'
 215                     ;; executable.
 216                     (error nil)))))))
 217     (when (eq 0 status)
 218         (when (null (string-match ".*: No such file or directory$" out))
 219           (let ((state (aref out 0)))
 220             (cond
 221              ((eq state ?=) 'up-to-date)
 222              ((eq state ?A) 'added)
 223              ((eq state ?M) 'edited)
 224              ((eq state ?I) 'ignored)
 225              ((eq state ?R) 'removed)
 226              ((eq state ?!) 'missing)
 227              ((eq state ??) 'unregistered)
 228              ((eq state ?C) 'up-to-date) ;; Older mercurial versions use this.
 229              (t 'up-to-date)))))))
 230
 231 (defun vc-hg-working-revision (file)
 232   "Hg-specific version of `vc-working-revision'."
 233   (or (ignore-errors
 234         (with-output-to-string
 235           (vc-hg-command standard-output 0 file
 236                          "parent" "--template" "{rev}")))
 237       "0"))
 238
 239 ;;; History functions
 240
 241 (defcustom vc-hg-log-switches nil
 242   "String or list of strings specifying switches for hg log under VC."
 243   :type '(choice (const :tag "None" nil)
 244                  (string :tag "Argument String")
 245                  (repeat :tag "Argument List" :value ("") string))
 246   :group 'vc-hg)
 247
 248 (autoload 'vc-setup-buffer "vc-dispatcher")
 249
 250 (defvar vc-hg-log-graph nil
 251   "If non-nil, use `--graph' in the short log output.")
 252
 253 (defun vc-hg-print-log (files buffer &optional shortlog start-revision limit)
 254   "Print commit log associated with FILES into specified BUFFER.
 255 If SHORTLOG is non-nil, use a short format based on `vc-hg-root-log-format'.
 256 If START-REVISION is non-nil, it is the newest revision to show.
 257 If LIMIT is non-nil, show no more than this many entries."
 258   ;; `vc-do-command' creates the buffer, but we need it before running
 259   ;; the command.
 260   (vc-setup-buffer buffer)
 261   ;; If the buffer exists from a previous invocation it might be
 262   ;; read-only.
 263   (let ((inhibit-read-only t))
 264     (with-current-buffer
 265         buffer
 266       (apply 'vc-hg-command buffer 0 files "log"
 267              (nconc
 268               (when start-revision (list (format "-r%s:0" start-revision)))
 269               (when limit (list "-l" (format "%s" limit)))
 270               (when shortlog `(,@(if vc-hg-log-graph '("--graph"))
 271                                "--template"
 272                                ,(car vc-hg-root-log-format)))
 273               vc-hg-log-switches)))))
 274
 275 (defvar log-view-message-re)
 276 (defvar log-view-file-re)
 277 (defvar log-view-font-lock-keywords)
 278 (defvar log-view-per-file-logs)
 279 (defvar log-view-expanded-log-entry-function)
 280
 281 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 282   (require 'add-log) ;; we need the add-log faces
 283   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 284   (set (make-local-variable 'log-view-per-file-logs) nil)
 285   (set (make-local-variable 'log-view-message-re)
 286        (if (eq vc-log-view-type 'short)
 287            (cadr vc-hg-root-log-format)
 288          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 289   ;; Allow expanding short log entries
 290   (when (eq vc-log-view-type 'short)
 291     (setq truncate-lines t)
 292     (set (make-local-variable 'log-view-expanded-log-entry-function)
 293          'vc-hg-expanded-log-entry))
 294   (set (make-local-variable 'log-view-font-lock-keywords)
 295        (if (eq vc-log-view-type 'short)
 296            (list (cons (nth 1 vc-hg-root-log-format)
 297                        (nth 2 vc-hg-root-log-format)))
 298          (append
 299           log-view-font-lock-keywords
 300           '(
 301             ;; Handle the case:
 302             ;; user: FirstName LastName <foo@bar>
 303             ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 304              (1 'change-log-name)
 305              (2 'change-log-email))
 306             ;; Handle the cases:
 307             ;; user: foo@bar
 308             ;; and
 309             ;; user: foo
 310             ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 311              (1 'change-log-email))
 312             ("^date: \\(.+\\)" (1 'change-log-date))
 313             ("^tag: +\\([^ ]+\\)$" (1 'highlight))
 314             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 315
 316 (autoload 'vc-switches "vc")
 317
 318 (defun vc-hg-diff (files &optional async oldvers newvers buffer)
 319   "Get a difference report using hg between two revisions of FILES."
 320   (let* ((firstfile (car files))
 321          (working (and firstfile (vc-working-revision firstfile))))
 322     (when (and (equal oldvers working) (not newvers))
 323       (setq oldvers nil))
 324     (when (and (not oldvers) newvers)
 325       (setq oldvers working))
 326     (apply #'vc-hg-command
 327            (or buffer "*vc-diff*")
 328            (if async 'async nil)
 329            files "diff"
 330            (append
 331             (vc-switches 'hg 'diff)
 332             (when oldvers
 333               (if newvers
 334                   (list "-r" oldvers "-r" newvers)
 335                 (list "-r" oldvers)))))))
 336
 337 (defun vc-hg-expanded-log-entry (revision)
 338   (with-temp-buffer
 339     (vc-hg-command t nil nil "log" "-r" revision)
 340     (goto-char (point-min))
 341     (unless (eobp)
 342       ;; Indent the expanded log entry.
 343       (indent-region (point-min) (point-max) 2)
 344       (goto-char (point-max))
 345       (buffer-string))))
 346
 347 (defun vc-hg-revision-table (files)
 348   (let ((default-directory (file-name-directory (car files))))
 349     (with-temp-buffer
 350       (vc-hg-command t nil files "log" "--template" "{rev} ")
 351       (split-string
 352        (buffer-substring-no-properties (point-min) (point-max))))))
 353
 354 ;; Modeled after the similar function in vc-cvs.el
 355 (defun vc-hg-revision-completion-table (files)
 356   (letrec ((table (lazy-completion-table
 357                    table (lambda () (vc-hg-revision-table files)))))
 358     table))
 359
 360 (defun vc-hg-annotate-command (file buffer &optional revision)
 361   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 362 Optional arg REVISION is a revision to annotate from."
 363   (vc-hg-command buffer 0 file "annotate" "-d" "-n" "--follow"
 364                  (when revision (concat "-r" revision))))
 365
 366 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 367
 368 ;; The format for one line output by "hg annotate -d -n" looks like this:
 369 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 370 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 371 ;; If the user has set the "--follow" option, the output looks like:
 372 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 373 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 374 (defconst vc-hg-annotate-re
 375   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)\\(?:\\(: \\)\\|\\(?: +\\([^:\n]+\\(?::\\(?:[^: \n][^:\n]*\\)?\\)*\\): \\)\\)")
 376
 377 (defun vc-hg-annotate-time ()
 378   (when (looking-at vc-hg-annotate-re)
 379     (goto-char (match-end 0))
 380     (vc-annotate-convert-time
 381      (date-to-time (match-string-no-properties 2)))))
 382
 383 (defun vc-hg-annotate-extract-revision-at-line ()
 384   (save-excursion
 385     (beginning-of-line)
 386     (when (looking-at vc-hg-annotate-re)
 387       (if (match-beginning 3)
 388           (match-string-no-properties 1)
 389         (cons (match-string-no-properties 1)
 390       (expand-file-name (match-string-no-properties 4)
 391  (vc-hg-root default-directory)))))))
 392
 393 ;;; Tag system
 394
 395 (defun vc-hg-create-tag (dir name branchp)
 396   "Attach the tag NAME to the state of the working copy."
 397   (let ((default-directory dir))
 398     (and (vc-hg-command nil 0 nil "status")
 399          (vc-hg-command nil 0 nil (if branchp "bookmark" "tag") name))))
 400
 401 (defun vc-hg-retrieve-tag (dir name _update)
 402   "Retrieve the version tagged by NAME of all registered files at or below DIR."
 403   (let ((default-directory dir))
 404     (vc-hg-command nil 0 nil "update" name)
 405     ;; FIXME: update buffers if `update' is true
 406     ;; TODO: update *vc-change-log* buffer so can see @ if --graph
 407     ))
 408
 409 ;;; Miscellaneous
 410
 411 (defun vc-hg-previous-revision (_file rev)
 412   (let ((newrev (1- (string-to-number rev))))
 413     (when (>= newrev 0)
 414       (number-to-string newrev))))
 415
 416 (defun vc-hg-next-revision (_file rev)
 417   (let ((newrev (1+ (string-to-number rev)))
 418         (tip-revision
 419          (with-temp-buffer
 420            (vc-hg-command t 0 nil "tip" "--style=default")
 421            (goto-char (point-min))
 422            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 423            (string-to-number (match-string-no-properties 1)))))
 424     ;; We don't want to exceed the maximum possible revision number, ie
 425     ;; the tip revision.
 426     (when (<= newrev tip-revision)
 427       (number-to-string newrev))))
 428
 429 ;; Modeled after the similar function in vc-bzr.el
 430 (defun vc-hg-delete-file (file)
 431   "Delete FILE and delete it in the hg repository."
 432   (condition-case ()
 433       (delete-file file)
 434     (file-error nil))
 435   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 436
 437 ;; Modeled after the similar function in vc-bzr.el
 438 (defun vc-hg-rename-file (old new)
 439   "Rename file from OLD to NEW using `hg mv'."
 440   (vc-hg-command nil 0 new "mv" old))
 441
 442 (defun vc-hg-register (files &optional _comment)
 443   "Register FILES under hg. COMMENT is ignored."
 444   (vc-hg-command nil 0 files "add"))
 445
 446 (defun vc-hg-create-repo ()
 447   "Create a new Mercurial repository."
 448   (vc-hg-command nil 0 nil "init"))
 449
 450 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 451
 452 (defun vc-hg-unregister (file)
 453   "Unregister FILE from hg."
 454   (vc-hg-command nil 0 file "forget"))
 455
 456 (declare-function log-edit-extract-headers "log-edit" (headers string))
 457
 458 (defun vc-hg-checkin (files comment)
 459   "Hg-specific version of `vc-backend-checkin'.
 460 REV is ignored."
 461   (apply 'vc-hg-command nil 0 files
 462          (nconc (list "commit" "-m")
 463                 (log-edit-extract-headers '(("Author" . "--user")
 464                                             ("Date" . "--date"))
 465                                           comment))))
 466
 467 (defun vc-hg-find-revision (file rev buffer)
 468   (let ((coding-system-for-read 'binary)
 469         (coding-system-for-write 'binary))
 470     (if rev
 471         (vc-hg-command buffer 0 file "cat" "-r" rev)
 472       (vc-hg-command buffer 0 file "cat"))))
 473
 474 (defun vc-hg-find-ignore-file (file)
 475   "Return the root directory of the repository of FILE."
 476   (expand-file-name ".hgignore"
 477                     (vc-hg-root file)))
 478
 479 ;; Modeled after the similar function in vc-bzr.el
 480 (defun vc-hg-checkout (file &optional rev)
 481   "Retrieve a revision of FILE.
 482 EDITABLE is ignored.
 483 REV is the revision to check out into WORKFILE."
 484   (let ((coding-system-for-read 'binary)
 485         (coding-system-for-write 'binary))
 486   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 487     (if rev
 488         (vc-hg-command t 0 file "cat" "-r" rev)
 489       (vc-hg-command t 0 file "cat")))))
 490
 491 (defun vc-hg-resolve-when-done ()
 492   "Call \"hg resolve -m\" if the conflict markers have been removed."
 493   (save-excursion
 494     (goto-char (point-min))
 495     (unless (re-search-forward "^<<<<<<< " nil t)
 496       (vc-hg-command nil 0 buffer-file-name "resolve" "-m")
 497       ;; Remove the hook so that it is not called multiple times.
 498       (remove-hook 'after-save-hook 'vc-hg-resolve-when-done t))))
 499
 500 (defun vc-hg-find-file-hook ()
 501   (when (and buffer-file-name
 502              (file-exists-p (concat buffer-file-name ".orig"))
 503              ;; Hg does not seem to have a "conflict" status, eg
 504              ;; hg http://bz.selenic.com/show_bug.cgi?id=2724
 505              (memq (vc-file-getprop buffer-file-name 'vc-state)
 506                    '(edited conflict))
 507              ;; Maybe go on to check that "hg resolve -l" says "U"?
 508              ;; If "hg resolve -l" says there's a conflict but there are no
 509              ;; conflict markers, it's not clear what we should do.
 510              (save-excursion
 511                (goto-char (point-min))
 512                (re-search-forward "^<<<<<<< " nil t)))
 513     ;; Hg may not recognize "conflict" as a state, but we can do better.
 514     (vc-file-setprop buffer-file-name 'vc-state 'conflict)
 515     (smerge-start-session)
 516     (add-hook 'after-save-hook 'vc-hg-resolve-when-done nil t)
 517     (message "There are unresolved conflicts in this file")))
 518
 519
 520 ;; Modeled after the similar function in vc-bzr.el
 521 (defun vc-hg-revert (file &optional contents-done)
 522   (unless contents-done
 523     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 524
 525 ;;; Hg specific functionality.
 526
 527 (defvar vc-hg-extra-menu-map
 528   (let ((map (make-sparse-keymap)))
 529     map))
 530
 531 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 532
 533 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 534
 535 (defvar log-view-vc-backend)
 536
 537 (cl-defstruct (vc-hg-extra-fileinfo
 538             (:copier nil)
 539             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 540             (:conc-name vc-hg-extra-fileinfo->))
 541   rename-state        ;; rename or copy state
 542   extra-name)         ;; original name for copies and rename targets, new name for
 543
 544 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 545
 546 (defun vc-hg-dir-printer (info)
 547   "Pretty-printer for the vc-dir-fileinfo structure."
 548   (let ((extra (vc-dir-fileinfo->extra info)))
 549     (vc-default-dir-printer 'Hg info)
 550     (when extra
 551       (insert (propertize
 552                (format "   (%s %s)"
 553                        (pcase (vc-hg-extra-fileinfo->rename-state extra)
 554                          (`copied "copied from")
 555                          (`renamed-from "renamed from")
 556                          (`renamed-to "renamed to"))
 557                        (vc-hg-extra-fileinfo->extra-name extra))
 558                'face 'font-lock-comment-face)))))
 559
 560 (defun vc-hg-after-dir-status (update-function)
 561   (let ((file nil)
 562         (translation '((?= . up-to-date)
 563                        (?C . up-to-date)
 564                        (?A . added)
 565                        (?R . removed)
 566                        (?M . edited)
 567                        (?I . ignored)
 568                        (?! . missing)
 569                        (?  . copy-rename-line)
 570                        (?? . unregistered)))
 571         (translated nil)
 572         (result nil)
 573         (last-added nil)
 574         (last-line-copy nil))
 575       (goto-char (point-min))
 576       (while (not (eobp))
 577         (setq translated (cdr (assoc (char-after) translation)))
 578         (setq file
 579               (buffer-substring-no-properties (+ (point) 2)
 580                                               (line-end-position)))
 581         (cond ((not translated)
 582                (setq last-line-copy nil))
 583               ((eq translated 'up-to-date)
 584                (setq last-line-copy nil))
 585               ((eq translated 'copy-rename-line)
 586                ;; For copied files the output looks like this:
 587                ;; A COPIED_FILE_NAME
 588                ;;   ORIGINAL_FILE_NAME
 589                (setf (nth 2 last-added)
 590                      (vc-hg-create-extra-fileinfo 'copied file))
 591                (setq last-line-copy t))
 592               ((and last-line-copy (eq translated 'removed))
 593                ;; For renamed files the output looks like this:
 594                ;; A NEW_FILE_NAME
 595                ;;   ORIGINAL_FILE_NAME
 596                ;; R ORIGINAL_FILE_NAME
 597                ;; We need to adjust the previous entry to not think it is a copy.
 598                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 599                      'renamed-from)
 600                (push (list file translated
 601                            (vc-hg-create-extra-fileinfo
 602                             'renamed-to (nth 0 last-added))) result)
 603                (setq last-line-copy nil))
 604               (t
 605                (setq last-added (list file translated nil))
 606                (push last-added result)
 607                (setq last-line-copy nil)))
 608         (forward-line))
 609       (funcall update-function result)))
 610
 611 ;; Follows vc-hg-command (or vc-do-async-command), which uses vc-do-command
 612 ;; from vc-dispatcher.
 613 (declare-function vc-exec-after "vc-dispatcher" (code))
 614 ;; Follows vc-exec-after.
 615 (declare-function vc-set-async-update "vc-dispatcher" (process-buffer))
 616
 617 (defun vc-hg-dir-status (dir update-function)
 618   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 619   (vc-run-delayed
 620    (vc-hg-after-dir-status update-function)))
 621
 622 (defun vc-hg-dir-status-files (dir files _default-state update-function)
 623   (apply 'vc-hg-command (current-buffer) 'async dir "status" "-mardui" "-C" files)
 624   (vc-run-delayed
 625    (vc-hg-after-dir-status update-function)))
 626
 627 (defun vc-hg-dir-extra-header (name &rest commands)
 628   (concat (propertize name 'face 'font-lock-type-face)
 629           (propertize
 630            (with-temp-buffer
 631              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 632              (buffer-substring-no-properties (point-min) (1- (point-max))))
 633            'face 'font-lock-variable-name-face)))
 634
 635 (defun vc-hg-dir-extra-headers (dir)
 636   "Generate extra status headers for a Mercurial tree."
 637   (let ((default-directory dir))
 638     (concat
 639      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 640      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 641      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 642      ;; these change after each commit
 643      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 644      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 645      )))
 646
 647 (defun vc-hg-log-incoming (buffer remote-location)
 648   (vc-hg-command buffer 1 nil "incoming" "-n" (unless (string= remote-location "")
 649                                                 remote-location)))
 650
 651 (defun vc-hg-log-outgoing (buffer remote-location)
 652   (vc-hg-command buffer 1 nil "outgoing" "-n" (unless (string= remote-location "")
 653                                                 remote-location)))
 654
 655 (declare-function log-view-get-marked "log-view" ())
 656
 657 ;; XXX maybe also add key bindings for these functions.
 658 (defun vc-hg-push ()
 659   (interactive)
 660   (let ((marked-list (log-view-get-marked)))
 661     (if marked-list
 662         (apply #'vc-hg-command
 663                nil 0 nil
 664                "push"
 665                (apply 'nconc
 666                       (mapcar (lambda (arg) (list "-r" arg)) marked-list)))
 667       (error "No log entries selected for push"))))
 668
 669 (defvar vc-hg-error-regexp-alist nil
 670   ;; 'hg pull' does not list modified files, so, for now, the only
 671   ;; benefit of `vc-compilation-mode' is that one can get rid of
 672   ;; *vc-hg* buffer with 'q' or 'z'.
 673   ;; TODO: call 'hg incoming' before pull/merge to get the list of
 674   ;;       modified files
 675   "Value of `compilation-error-regexp-alist' in *vc-hg* buffers.")
 676
 677 (autoload 'vc-do-async-command "vc-dispatcher")
 678
 679 (defun vc-hg-pull (prompt)
 680   "Issue a Mercurial pull command.
 681 If called interactively with a set of marked Log View buffers,
 682 call \"hg pull -r REVS\" to pull in the specified revisions REVS.
 683
 684 With a prefix argument or if PROMPT is non-nil, prompt for a
 685 specific Mercurial pull command.  The default is \"hg pull -u\",
 686 which fetches changesets from the default remote repository and
 687 then attempts to update the working directory."
 688   (interactive "P")
 689   (let (marked-list)
 690     ;; The `vc-hg-pull' command existed before the `pull' VC action
 691     ;; was implemented.  Keep it for backward compatibility.
 692     (if (and (called-interactively-p 'interactive)
 693              (setq marked-list (log-view-get-marked)))
 694         (apply #'vc-hg-command
 695                nil 0 nil
 696                "pull"
 697                (apply 'nconc
 698                       (mapcar (lambda (arg) (list "-r" arg))
 699                               marked-list)))
 700       (let* ((root (vc-hg-root default-directory))
 701              (buffer (format "*vc-hg : %s*" (expand-file-name root)))
 702              (command "pull")
 703              (hg-program vc-hg-program)
 704              ;; Fixme: before updating the working copy to the latest
 705              ;; state, should check if it's visiting an old revision.
 706              (args '("-u")))
 707         ;; If necessary, prompt for the exact command.
 708         (when prompt
 709           (setq args (split-string
 710                       (read-shell-command "Run Hg (like this): "
 711                                           (format "%s pull -u" hg-program)
 712                                           'vc-hg-history)
 713                       " " t))
 714           (setq hg-program (car  args)
 715                 command    (cadr args)
 716                 args       (cddr args)))
 717         (apply 'vc-do-async-command buffer root hg-program
 718                command args)
 719         (with-current-buffer buffer
 720           (vc-run-delayed (vc-compilation-mode 'hg)))
 721         (vc-set-async-update buffer)))))
 722
 723 (defun vc-hg-merge-branch ()
 724   "Merge incoming changes into the current working directory.
 725 This runs the command \"hg merge\"."
 726   (let* ((root (vc-hg-root default-directory))
 727          (buffer (format "*vc-hg : %s*" (expand-file-name root))))
 728     (apply 'vc-do-async-command buffer root vc-hg-program '("merge"))
 729     (with-current-buffer buffer (vc-run-delayed (vc-compilation-mode 'hg)))
 730     (vc-set-async-update buffer)))
 731
 732 ;;; Internal functions
 733
 734 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 735   "A wrapper around `vc-do-command' for use in vc-hg.el.
 736 This function differs from vc-do-command in that it invokes
 737 `vc-hg-program', and passes `vc-hg-global-switches' to it before FLAGS."
 738   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-hg-program file-or-list
 739          (if (stringp vc-hg-global-switches)
 740              (cons vc-hg-global-switches flags)
 741            (append vc-hg-global-switches
 742                    flags))))
 743
 744 (defun vc-hg-root (file)
 745   (vc-find-root file ".hg"))
 746
 747 (provide 'vc-hg)
 748
 749 ;;; vc-hg.el ends here