lisp/progmodes/f90.el

   1 ;;; f90.el --- Fortran-90 mode (free format)  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1995-1997, 2000-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Torbjörn Einarsson <Torbjorn.Einarsson@era.ericsson.se>
   6 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   7 ;; Keywords: fortran, f90, languages
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Major mode for editing F90 programs in FREE FORMAT.
  27 ;; The minor language revision F95 is also supported (with font-locking).
  28 ;; Some/many (?) aspects of F2003 are supported.
  29 ;; Some aspects of F2008 are supported.
  30
  31 ;; Knows about continuation lines, named structured statements, and other
  32 ;; features in F90 including HPF (High Performance Fortran) structures.
  33 ;; The basic feature provides accurate indentation of F90 programs.
  34 ;; In addition, there are many more features like automatic matching of all
  35 ;; end statements, an auto-fill function to break long lines, a join-lines
  36 ;; function which joins continued lines, etc.
  37
  38 ;; To facilitate typing, a fairly complete list of abbreviations is provided.
  39 ;; All abbreviations begin with the backquote character "`"
  40 ;; For example, `i expands to integer (if abbrev-mode is on).
  41
  42 ;; There are two separate features for altering the appearance of code:
  43 ;;   1) Upcasing or capitalizing of all keywords.
  44 ;;   2) Colors/fonts using font-lock-mode.
  45 ;; Automatic upcase or downcase of keywords is controlled by the variable
  46 ;; f90-auto-keyword-case.
  47
  48 ;; The indentations of lines starting with ! is determined by the first of the
  49 ;; following matches (values in the left column are the defaults):
  50
  51 ;; start-string/regexp  indent         variable holding start-string/regexp
  52 ;;    !!!                  0
  53 ;;    !hpf\\$ (re)         0              f90-directive-comment-re
  54 ;;    !!$                  0              f90-comment-region
  55 ;;    !      (re)        as code          f90-indented-comment-re
  56 ;;    default            comment-column
  57
  58 ;; Ex: Here is the result of 3 different settings of f90-indented-comment-re
  59 ;;     f90-indented-comment-re  !-indentation      !!-indentation
  60 ;;          !                    as code             as code
  61 ;;          !!                   comment-column      as code
  62 ;;          ![^!]                as code             comment-column
  63 ;; Trailing comments are indented to comment-column with indent-for-comment.
  64 ;; The function f90-comment-region toggles insertion of
  65 ;; the variable f90-comment-region in every line of the region.
  66
  67 ;; One common convention for free vs. fixed format is that free format files
  68 ;; have the ending .f90 or .f95 while fixed format files have the ending .f.
  69 ;; Emacs automatically loads Fortran files in the appropriate mode based
  70 ;; on extension. You can modify this by adjusting the variable auto-mode-alist.
  71 ;; For example:
  72 ;; (add-to-list 'auto-mode-alist '("\\.f\\'" . f90-mode))
  73
  74 ;; Once you have entered f90-mode, you may get more info by using
  75 ;; the command describe-mode (C-h m). For online help use
  76 ;; C-h f <Name of function you want described>, or
  77 ;; C-h v <Name of variable you want described>.
  78
  79 ;; To customize f90-mode for your taste, use, for example:
  80 ;; (you don't have to specify values for all the parameters below)
  81 ;;
  82 ;; (add-hook 'f90-mode-hook
  83 ;;       ;; These are the default values.
  84 ;;       (lambda () (setq f90-do-indent 3
  85 ;;                        f90-if-indent 3
  86 ;;                        f90-type-indent 3
  87 ;;                        f90-program-indent 2
  88 ;;                        f90-continuation-indent 5
  89 ;;                        f90-comment-region "!!$"
  90 ;;                        f90-directive-comment-re "!hpf\\$"
  91 ;;                        f90-indented-comment-re "!"
  92 ;;                        f90-break-delimiters "[-+\\*/><=,% \t]"
  93 ;;                        f90-break-before-delimiters t
  94 ;;                        f90-beginning-ampersand t
  95 ;;                        f90-smart-end 'blink
  96 ;;                        f90-auto-keyword-case nil
  97 ;;                        f90-leave-line-no nil
  98 ;;                        indent-tabs-mode nil
  99 ;;                        f90-font-lock-keywords f90-font-lock-keywords-2
 100 ;;                  )
 101 ;;       ;; These are not default.
 102 ;;       (abbrev-mode 1)             ; turn on abbreviation mode
 103 ;;       (f90-add-imenu-menu)        ; extra menu with functions etc.
 104 ;;       (if f90-auto-keyword-case   ; change case of all keywords on startup
 105 ;;           (f90-change-keywords f90-auto-keyword-case))
 106 ;;       ))
 107 ;;
 108 ;; in your .emacs file. You can also customize the lists
 109 ;; f90-font-lock-keywords, etc.
 110 ;;
 111 ;; The auto-fill and abbreviation minor modes are accessible from the F90 menu,
 112 ;; or by using M-x auto-fill-mode and M-x abbrev-mode, respectively.
 113
 114 ;; Remarks
 115 ;; 1) Line numbers are by default left-justified. If f90-leave-line-no is
 116 ;;    non-nil, the line numbers are never touched.
 117 ;; 2) Multi-; statements like "do i=1,20 ; j=j+i ; end do" are not handled
 118 ;;    correctly, but I imagine them to be rare.
 119 ;; 3) Regexps for hilit19 are no longer supported.
 120 ;; 4) For FIXED FORMAT code, use fortran mode.
 121 ;; 5) This mode does not work under emacs-18.x.
 122 ;; 6) Preprocessor directives, i.e., lines starting with # are left-justified
 123 ;;    and are untouched by all case-changing commands. There is, at present, no
 124 ;;    mechanism for treating multi-line directives (continued by \ ).
 125 ;; 7) f77 do-loops do 10 i=.. ; ; 10 continue are not correctly indented.
 126 ;;    You are urged to use f90-do loops (with labels if you wish).
 127 ;; 8) The highlighting mode under XEmacs is not as complete as under Emacs.
 128
 129 ;; List of user commands
 130 ;;   f90-previous-statement         f90-next-statement
 131 ;;   f90-beginning-of-subprogram    f90-end-of-subprogram   f90-mark-subprogram
 132 ;;   f90-comment-region
 133 ;;   f90-indent-line                f90-indent-new-line
 134 ;;   f90-indent-region    (can be called by calling indent-region)
 135 ;;   f90-indent-subprogram
 136 ;;   f90-break-line                 f90-join-lines
 137 ;;   f90-fill-region
 138 ;;   f90-insert-end
 139 ;;   f90-upcase-keywords            f90-upcase-region-keywords
 140 ;;   f90-downcase-keywords          f90-downcase-region-keywords
 141 ;;   f90-capitalize-keywords        f90-capitalize-region-keywords
 142 ;;   f90-add-imenu-menu
 143 ;;   f90-font-lock-1, f90-font-lock-2, f90-font-lock-3, f90-font-lock-4
 144
 145 ;; Original author's thanks
 146 ;; Thanks to all the people who have tested the mode. Special thanks to Jens
 147 ;; Bloch Helmers for encouraging me to write this code, for creative
 148 ;; suggestions as well as for the lists of hpf-commands.
 149 ;; Also thanks to the authors of the fortran and pascal modes, on which some
 150 ;; of this code is built.
 151
 152 ;;; Code:
 153
 154 ;; TODO
 155 ;; 1. Any missing F2003 syntax?
 156 ;; 2. Have "f90-mode" just recognize F90 syntax, then derived modes
 157 ;; "f95-mode", "f2003-mode" for the language revisions.
 158 ;; 3. Support for align.
 159 ;; Font-locking:
 160 ;; 1. OpenMP, OpenMPI?, preprocessor highlighting.
 161 ;; 2. integer_name = 1
 162 ;; 3. Labels for "else" statements (F2003)?
 163
 164 (defvar comment-auto-fill-only-comments)
 165 (defvar font-lock-keywords)
 166
 167 ;; User options
 168
 169 (defgroup f90 nil
 170   "Major mode for editing free format Fortran 90,95 code."
 171   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
 172   :group 'languages)
 173
 174 (defgroup f90-indent nil
 175   "Indentation in free format Fortran."
 176   :prefix "f90-"
 177   :group  'f90)
 178
 179
 180 (defcustom f90-do-indent 3
 181   "Extra indentation applied to DO blocks."
 182   :type  'integer
 183   :safe  'integerp
 184   :group 'f90-indent)
 185
 186 (defcustom f90-if-indent 3
 187   "Extra indentation applied to IF, SELECT CASE, WHERE and FORALL blocks."
 188   :type  'integer
 189   :safe  'integerp
 190   :group 'f90-indent)
 191
 192 (defcustom f90-type-indent 3
 193   "Extra indentation applied to TYPE, ENUM, INTERFACE and BLOCK DATA blocks."
 194   :type  'integer
 195   :safe  'integerp
 196   :group 'f90-indent)
 197
 198 (defcustom f90-program-indent 2
 199   "Extra indentation applied to PROGRAM, MODULE, SUBROUTINE, FUNCTION blocks."
 200   :type  'integer
 201   :safe  'integerp
 202   :group 'f90-indent)
 203
 204 (defcustom f90-associate-indent 2
 205   "Extra indentation applied to ASSOCIATE blocks."
 206   :type  'integer
 207   :safe  'integerp
 208   :group 'f90-indent
 209   :version "23.1")
 210
 211 (defcustom f90-critical-indent 2
 212   "Extra indentation applied to BLOCK, CRITICAL blocks."
 213   :type  'integer
 214   :safe  'integerp
 215   :group 'f90-indent
 216   :version "24.1")
 217
 218 (defcustom f90-continuation-indent 5
 219   "Extra indentation applied to continuation lines."
 220   :type  'integer
 221   :safe  'integerp
 222   :group 'f90-indent)
 223
 224 (defcustom f90-comment-region "!!$"
 225   "String inserted by \\[f90-comment-region] at start of each line in region."
 226   :type  'string
 227   :safe  'stringp
 228   :group 'f90-indent)
 229
 230 (defcustom f90-indented-comment-re "!"
 231   "Regexp matching comments to indent as code."
 232   :type  'regexp
 233   :safe  'stringp
 234   :group 'f90-indent)
 235
 236 (defcustom f90-directive-comment-re "!hpf\\$"
 237   "Regexp of comment-like directive like \"!HPF\\\\$\", not to be indented."
 238   :type  'regexp
 239   :safe  'stringp
 240   :group 'f90-indent)
 241
 242 (defcustom f90-beginning-ampersand t
 243   "Non-nil gives automatic insertion of \& at start of continuation line."
 244   :type  'boolean
 245   :safe  'booleanp
 246   :group 'f90)
 247
 248 (defcustom f90-smart-end 'blink
 249   "Qualification of END statements according to the matching block start.
 250 For example, the END that closes an IF block is changed to END
 251 IF.  If the block has a label, this is added as well.  Allowed
 252 values are 'blink, 'no-blink, and nil.  If nil, nothing is done.
 253 The other two settings have the same effect, but 'blink
 254 additionally blinks the cursor to the start of the block."
 255   :type  '(choice (const blink) (const no-blink) (const nil))
 256   :safe  (lambda (value) (memq value '(blink no-blink nil)))
 257   :group 'f90)
 258
 259 (defcustom f90-break-delimiters "[-+\\*/><=,% \t]"
 260   "Regexp matching delimiter characters at which lines may be broken.
 261 There are some common two-character tokens where one or more of
 262 the members matches this regexp.  Although Fortran allows breaks
 263 within lexical tokens (provided the next line has a beginning ampersand),
 264 the constant `f90-no-break-re' ensures that such tokens are not split."
 265   :type 'regexp
 266   :safe 'stringp
 267   :group 'f90)
 268
 269 (defcustom f90-break-before-delimiters t
 270   "Non-nil causes `f90-do-auto-fill' to break lines before delimiters."
 271   :type 'boolean
 272   :safe 'booleanp
 273   :group 'f90)
 274
 275 (defcustom f90-auto-keyword-case nil
 276   "Automatic case conversion of keywords.
 277 The options are 'downcase-word, 'upcase-word, 'capitalize-word and nil."
 278   :type  '(choice (const downcase-word) (const upcase-word)
 279                   (const capitalize-word) (const nil))
 280   :safe (lambda (value) (memq value '(downcase-word
 281                                       capitalize-word upcase-word nil)))
 282   :group 'f90)
 283
 284 (defcustom f90-leave-line-no nil
 285   "If non-nil, line numbers are not left justified."
 286   :type  'boolean
 287   :safe  'booleanp
 288   :group 'f90)
 289
 290 (defcustom f90-mode-hook nil
 291   "Hook run when entering F90 mode."
 292   :type    'hook
 293   ;; Not the only safe options, but some common ones.
 294   :safe    (lambda (value) (member value '((f90-add-imenu-menu) nil)))
 295   :options '(f90-add-imenu-menu)
 296   :group   'f90)
 297
 298 ;; User options end here.
 299
 300 (defconst f90-keywords-re
 301   (regexp-opt '("allocatable" "allocate" "assign" "assignment" "backspace"
 302                 "block" "call" "case" "character" "close" "common" "complex"
 303                 "contains" "continue" "cycle" "data" "deallocate"
 304                 "dimension" "do" "double" "else" "elseif" "elsewhere" "end"
 305                 "enddo" "endfile" "endif" "entry" "equivalence" "exit"
 306                 "external" "forall" "format" "function" "goto" "if"
 307                 "implicit" "include" "inquire" "integer" "intent"
 308                 "interface" "intrinsic" "logical" "module" "namelist" "none"
 309                 "nullify" "only" "open" "operator" "optional" "parameter"
 310                 "pause" "pointer" "precision" "print" "private" "procedure"
 311                 "program" "public" "read" "real" "recursive" "result" "return"
 312                 "rewind" "save" "select" "sequence" "stop" "subroutine"
 313                 "target" "then" "type" "use" "where" "while" "write"
 314                 ;; F95 keywords.
 315                 "elemental" "pure"
 316                 ;; F2003
 317                 "abstract" "associate" "asynchronous" "bind" "class"
 318                 "deferred" "enum" "enumerator" "extends" "extends_type_of"
 319                 "final" "generic" "import" "non_intrinsic" "non_overridable"
 320                 "nopass" "pass" "protected" "same_type_as" "value" "volatile"
 321                 ;; F2008.
 322                 "contiguous" "submodule" "concurrent" "codimension"
 323                 "sync all" "sync memory" "critical" "image_index"
 324                 ) 'words)
 325   "Regexp used by the function `f90-change-keywords'.")
 326
 327 (defconst f90-keywords-level-3-re
 328   (regexp-opt
 329    '("allocatable" "allocate" "assign" "assignment" "backspace"
 330      "close" "deallocate" "dimension" "endfile" "entry" "equivalence"
 331      "external" "inquire" "intent" "intrinsic" "nullify" "only" "open"
 332      ;; FIXME operator and assignment should be F2003 procedures?
 333      "operator" "optional" "parameter" "pause" "pointer" "print" "private"
 334      "public" "read" "recursive" "result" "rewind" "save" "select"
 335      "sequence" "target" "write"
 336      ;; F95 keywords.
 337      "elemental" "pure"
 338      ;; F2003. asynchronous separate.
 339      "abstract" "deferred" "import" "final" "non_intrinsic" "non_overridable"
 340      "nopass" "pass" "protected" "value" "volatile"
 341      ;; F2008.
 342      ;; "concurrent" is only in the sense of "do [,] concurrent", but given
 343      ;; the [,] it's simpler to just do every instance (cf "do while").
 344      "contiguous" "concurrent" "codimension" "sync all" "sync memory"
 345      ) 'words)
 346   "Keyword-regexp for font-lock level >= 3.")
 347
 348 (defconst f90-procedures-re
 349   (concat "\\<"
 350           (regexp-opt
 351            '("abs" "achar" "acos" "adjustl" "adjustr" "aimag" "aint"
 352              "all" "allocated" "anint" "any" "asin" "associated"
 353              "atan" "atan2" "bit_size" "btest" "ceiling" "char" "cmplx"
 354              "conjg" "cos" "cosh" "count" "cshift" "date_and_time" "dble"
 355              "digits" "dim" "dot_product" "dprod" "eoshift" "epsilon"
 356              "exp" "exponent" "floor" "fraction" "huge" "iachar" "iand"
 357              "ibclr" "ibits" "ibset" "ichar" "ieor" "index" "int" "ior"
 358              "ishft" "ishftc" "kind" "lbound" "len" "len_trim" "lge" "lgt"
 359              "lle" "llt" "log" "log10" "logical" "matmul" "max"
 360              "maxexponent" "maxloc" "maxval" "merge" "min" "minexponent"
 361              "minloc" "minval" "mod" "modulo" "mvbits" "nearest" "nint"
 362              "not" "pack" "precision" "present" "product" "radix"
 363              ;; Real is taken out here to avoid highlighting declarations.
 364              "random_number" "random_seed" "range" ;; "real"
 365              "repeat" "reshape" "rrspacing" "scale" "scan"
 366              "selected_int_kind" "selected_real_kind" "set_exponent"
 367              "shape" "sign" "sin" "sinh" "size" "spacing" "spread" "sqrt"
 368              "sum" "system_clock" "tan" "tanh" "tiny" "transfer"
 369              "transpose" "trim" "ubound" "unpack" "verify"
 370              ;; F95 intrinsic functions.
 371              "null" "cpu_time"
 372              ;; F2003.
 373              "move_alloc" "command_argument_count" "get_command"
 374              "get_command_argument" "get_environment_variable"
 375              "selected_char_kind" "wait" "flush" "new_line"
 376              "extends" "extends_type_of" "same_type_as" "bind"
 377              ;; F2003 ieee_arithmetic intrinsic module.
 378              "ieee_support_underflow_control" "ieee_get_underflow_mode"
 379              "ieee_set_underflow_mode"
 380              ;; F2003 iso_c_binding intrinsic module.
 381              "c_loc" "c_funloc" "c_associated" "c_f_pointer"
 382              "c_f_procpointer"
 383              ;; F2008.
 384              "bge" "bgt" "ble" "blt" "dshiftl" "dshiftr" "leadz" "popcnt"
 385              "poppar" "trailz" "maskl" "maskr" "shifta" "shiftl" "shiftr"
 386              "merge_bits" "iall" "iany" "iparity" "storage_size"
 387              "bessel_j0" "bessel_j1" "bessel_jn"
 388              "bessel_y0" "bessel_y1" "bessel_yn"
 389              "erf" "erfc" "erfc_scaled" "gamma" "hypot" "log_gamma"
 390              "norm2" "parity" "findloc" "is_contiguous"
 391              "sync images" "lock" "unlock" "image_index"
 392              "lcobound" "ucobound" "num_images" "this_image"
 393              ;; F2008 iso_fortran_env module.
 394              "compiler_options" "compiler_version"
 395              ;; F2008 iso_c_binding module.
 396              "c_sizeof"
 397              ) t)
 398           ;; A left parenthesis to avoid highlighting non-procedures.
 399           "[ \t]*(")
 400   "Regexp whose first part matches F90 intrinsic procedures.")
 401
 402 (defconst f90-operators-re
 403   (concat "\\."
 404           (regexp-opt '("and" "eq" "eqv" "false" "ge" "gt" "le" "lt" "ne"
 405                         "neqv" "not" "or" "true") t)
 406           "\\.")
 407   "Regexp matching intrinsic operators.")
 408
 409 (defconst f90-hpf-keywords-re
 410   (regexp-opt
 411    ;; Intrinsic procedures.
 412    '("all_prefix" "all_scatter" "all_suffix" "any_prefix"
 413      "any_scatter" "any_suffix" "copy_prefix" "copy_scatter"
 414      "copy_suffix" "count_prefix" "count_scatter" "count_suffix"
 415      "grade_down" "grade_up"
 416      "hpf_alignment" "hpf_distribution" "hpf_template" "iall" "iall_prefix"
 417      "iall_scatter" "iall_suffix" "iany" "iany_prefix" "iany_scatter"
 418      "iany_suffix" "ilen" "iparity" "iparity_prefix"
 419      "iparity_scatter" "iparity_suffix" "leadz" "maxval_prefix"
 420      "maxval_scatter" "maxval_suffix" "minval_prefix" "minval_scatter"
 421      "minval_suffix" "number_of_processors" "parity"
 422      "parity_prefix" "parity_scatter" "parity_suffix" "popcnt" "poppar"
 423      "processors_shape" "product_prefix" "product_scatter"
 424      "product_suffix" "sum_prefix" "sum_scatter" "sum_suffix"
 425      ;; Directives.
 426      "align" "distribute" "dynamic" "independent" "inherit" "processors"
 427      "realign" "redistribute" "template"
 428      ;; Keywords.
 429      "block" "cyclic" "extrinsic" "new" "onto" "pure" "with") 'words)
 430   "Regexp for all HPF keywords, procedures and directives.")
 431
 432 (defconst f90-constants-re
 433   (regexp-opt '( ;; F2003 iso_fortran_env constants.
 434                 "iso_fortran_env"
 435                 "input_unit" "output_unit" "error_unit"
 436                 "iostat_end" "iostat_eor"
 437                 "numeric_storage_size" "character_storage_size"
 438                 "file_storage_size"
 439                 ;; F2003 iso_c_binding constants.
 440                 "iso_c_binding"
 441                 "c_int" "c_short" "c_long" "c_long_long" "c_signed_char"
 442                 "c_size_t"
 443                 "c_int8_t" "c_int16_t" "c_int32_t" "c_int64_t"
 444                 "c_int_least8_t" "c_int_least16_t" "c_int_least32_t"
 445                 "c_int_least64_t"
 446                 "c_int_fast8_t" "c_int_fast16_t" "c_int_fast32_t"
 447                 "c_int_fast64_t"
 448                 "c_intmax_t" "c_intptr_t"
 449                 "c_float" "c_double" "c_long_double"
 450                 "c_float_complex" "c_double_complex" "c_long_double_complex"
 451                 "c_bool" "c_char"
 452                 "c_null_char" "c_alert" "c_backspace" "c_form_feed"
 453                 "c_new_line" "c_carriage_return" "c_horizontal_tab"
 454                 "c_vertical_tab"
 455                 "c_ptr" "c_funptr" "c_null_ptr" "c_null_funptr"
 456                 "ieee_exceptions"
 457                 "ieee_arithmetic"
 458                 "ieee_features"
 459                 ;; F2008 iso_fortran_env constants.
 460                 "character_kinds" "int8" "int16" "int32" "int64"
 461                 "integer_kinds" "iostat_inquire_internal_unit"
 462                 "logical_kinds" "real_kinds" "real32" "real64" "real128"
 463                 "lock_type" "atomic_int_kind" "atomic_logical_kind"
 464                 ) 'words)
 465   "Regexp for Fortran intrinsic constants.")
 466
 467 ;; cf f90-looking-at-type-like.
 468 (defun f90-typedef-matcher (limit)
 469   "Search for the start/end of the definition of a derived type, up to LIMIT.
 470 Set the match data so that subexpression 1,2 are the TYPE, and
 471 type-name parts, respectively."
 472   (let (found l)
 473     (while (and (re-search-forward "\\<\\(\\(?:end[ \t]*\\)?type\\)\\>[ \t]*"
 474                                    limit t)
 475                 (not (setq found
 476                            (progn
 477                              (setq l (match-data))
 478                              (unless (looking-at "\\(is\\>\\|(\\)")
 479                                (when (if (looking-at "\\(\\sw+\\)")
 480                                          (goto-char (match-end 0))
 481                                        (re-search-forward
 482                                         "[ \t]*::[ \t]*\\(\\sw+\\)"
 483                                         (line-end-position) t))
 484                                  ;; 0 is wrong, but we don't use it.
 485                                  (set-match-data
 486                                   (append l (list (match-beginning 1)
 487                                                   (match-end 1))))
 488                                  t)))))))
 489     found))
 490
 491 (defvar f90-font-lock-keywords-1
 492   (list
 493    ;; Special highlighting of "module procedure".
 494    '("\\<\\(module[ \t]*procedure\\)\\>\\([^()\n]*::\\)?[ \t]*\\([^&!\n]*\\)"
 495      (1 font-lock-keyword-face) (3 font-lock-function-name-face nil t))
 496    ;; Highlight definition of derived type.
 497 ;;;    '("\\<\\(\\(?:end[ \t]*\\)?type\\)\\>\\([^()\n]*::\\)?[ \t]*\\(\\sw+\\)"
 498 ;;;      (1 font-lock-keyword-face) (3 font-lock-function-name-face))
 499    '(f90-typedef-matcher
 500      (1 font-lock-keyword-face) (2 font-lock-function-name-face))
 501    ;; F2003.  Prevent operators being highlighted as functions.
 502    '("\\<\\(\\(?:end[ \t]*\\)?interface[ \t]*\\(?:assignment\\|operator\\|\
 503 read\\|write\\)\\)[ \t]*(" (1 font-lock-keyword-face t))
 504    ;; Other functions and declarations.  Named interfaces = F2003.
 505    ;; F2008: end submodule submodule_name.
 506    '("\\<\\(\\(?:end[ \t]*\\)?\\(program\\|\\(?:sub\\)?module\\|\
 507 function\\|associate\\|subroutine\\|interface\\)\\|use\\|call\\)\
 508 \\>[ \t]*\\(\\sw+\\)?"
 509      (1 font-lock-keyword-face) (3 font-lock-function-name-face nil t))
 510    ;; F2008: submodule (parent_name) submodule_name.
 511    '("\\<\\(submodule\\)\\>[ \t]*([^)\n]+)[ \t]*\\(\\sw+\\)?"
 512      (1 font-lock-keyword-face) (2 font-lock-function-name-face nil t))
 513    ;; F2003.
 514    '("\\<\\(use\\)[ \t]*,[ \t]*\\(\\(?:non_\\)?intrinsic\\)[ \t]*::[ \t]*\
 515 \\(\\sw+\\)"
 516      (1 font-lock-keyword-face) (2 font-lock-keyword-face)
 517      (3 font-lock-function-name-face))
 518    "\\<\\(\\(end[ \t]*\\)?block[ \t]*data\\|contains\\)\\>"
 519    ;; "abstract interface" is F2003.
 520    '("\\<abstract[ \t]*interface\\>" (0 font-lock-keyword-face t)))
 521   "This does fairly subdued highlighting of comments and function calls.")
 522
 523 ;; NB not explicitly handling this, yet it seems to work.
 524 ;; type(...) function foo()
 525 (defun f90-typedec-matcher (limit)
 526   "Search for the declaration of variables of derived type, up to LIMIT.
 527 Set the match data so that subexpression 1,2 are the TYPE(...),
 528 and variable-name parts, respectively."
 529   ;; Matcher functions must return nil only when there are no more
 530   ;; matches within the search range.
 531   (let (found l)
 532     (while (and (re-search-forward "\\<\\(type\\|class\\)[ \t]*(" limit t)
 533                 (not
 534                  (setq found
 535                        (condition-case nil
 536                            (progn
 537                              ;; Set l after this to just highlight
 538                              ;; the "type" part.
 539                              (backward-char 1)
 540                              ;; Needed for: type( foo(...) ) :: bar
 541                              (forward-sexp)
 542                              (setq l (list (match-beginning 0) (point)))
 543                              (skip-chars-forward " \t")
 544                              (when
 545                                  (re-search-forward
 546                                   ;; type (foo) bar, qux
 547                                   (if (looking-at "\\sw+")
 548                                       "\\([^&!\n]+\\)"
 549                                     ;; type (foo), stuff :: bar, qux
 550                                     "::[ \t]*\\([^&!\n]+\\)")
 551                                   (line-end-position) t)
 552                                (set-match-data
 553                                 (append (list (car l) (match-end 1))
 554                                         l (list (match-beginning 1)
 555                                                 (match-end 1))))
 556                                t))
 557                          (error nil))))))
 558     found))
 559
 560 (defvar f90-font-lock-keywords-2
 561   (append
 562    f90-font-lock-keywords-1
 563    (list
 564     ;; Variable declarations (avoid the real function call).
 565     ;; NB by accident (?), this correctly fontifies the "integer" in:
 566     ;; integer () function foo ()
 567     ;; because "() function foo ()" matches \\3.
 568     ;; The "pure" part does not really belong here, but was added to
 569     ;; exploit that hack.
 570     ;; The "function foo" bit is correctly fontified by keywords-1.
 571     ;; TODO ? actually check for balanced parens in that case.
 572     '("^[ \t0-9]*\\(?:pure\\|elemental\\)?[ \t]*\
 573 \\(real\\|integer\\|c\\(haracter\\|omplex\\)\\|\
 574 enumerator\\|generic\\|procedure\\|logical\\|double[ \t]*precision\\)\
 575 \\(.*::\\|[ \t]*(.*)\\)?\\([^&!\n]*\\)"
 576       (1 font-lock-type-face t) (4 font-lock-variable-name-face t))
 577     ;; Derived type/class variables.
 578     ;; TODO ? If we just highlighted the "type" part, rather than
 579     ;; "type(...)", this could be in the previous expression. And this
 580     ;; would be consistent with integer( kind=8 ), etc.
 581     '(f90-typedec-matcher
 582       (1 font-lock-type-face) (2 font-lock-variable-name-face))
 583     ;; "real function foo (args)". Must override previous.  Note hack
 584     ;; to get "args" unhighlighted again. Might not always be right,
 585     ;; but probably better than leaving them as variables.
 586     ;; NB not explicitly handling this case:
 587     ;; integer( kind=1 ) function foo()
 588     ;; thanks to the happy accident described above.
 589     ;; Not anchored, so don't need to worry about "pure" etc.
 590     '("\\<\\(\\(real\\|integer\\|c\\(haracter\\|omplex\\)\\|\
 591 logical\\|double[ \t]*precision\\|\
 592 \\(?:type\\|class\\)[ \t]*([ \t]*\\sw+[ \t]*)\\)[ \t]*\\)\
 593 \\(function\\)\\>[ \t]*\\(\\sw+\\)[ \t]*\\(([^&!\n]*)\\)"
 594       (1 font-lock-type-face t) (4 font-lock-keyword-face t)
 595       (5 font-lock-function-name-face t) (6 'default t))
 596     ;; enum (F2003; must be followed by ", bind(C)").
 597     '("\\<\\(enum\\)[ \t]*," (1 font-lock-keyword-face))
 598     ;; end do, enum (F2003), if, select, where, and forall constructs.
 599     ;; block, critical (F2008).
 600     ;; Note that "block data" may get somewhat mixed up with F2008 blocks,
 601     ;; but since the former is obsolete I'm not going to worry about it.
 602     '("\\<\\(end[ \t]*\\(do\\|if\\|enum\\|select\\|forall\\|where\\|\
 603 block\\|critical\\)\\)\\>\
 604 \\([ \t]+\\(\\sw+\\)\\)?"
 605       (1 font-lock-keyword-face) (3 font-lock-constant-face nil t))
 606     '("^[ \t0-9]*\\(\\(\\sw+\\)[ \t]*:[ \t]*\\)?\\(\\(if\\|\
 607 do\\([ \t]*while\\)?\\|select[ \t]*\\(?:case\\|type\\)\\|where\\|\
 608 forall\\|block\\|critical\\)\\)\\>"
 609       (2 font-lock-constant-face nil t) (3 font-lock-keyword-face))
 610     ;; Implicit declaration.
 611     '("\\<\\(implicit\\)[ \t]*\\(real\\|integer\\|c\\(haracter\\|omplex\\)\
 612 \\|enumerator\\|procedure\\|\
 613 logical\\|double[ \t]*precision\\|type[ \t]*(\\sw+)\\|none\\)[ \t]*"
 614       (1 font-lock-keyword-face) (2 font-lock-type-face))
 615     '("\\<\\(namelist\\|common\\)[ \t]*\/\\(\\sw+\\)?\/"
 616       (1 font-lock-keyword-face) (2 font-lock-constant-face nil t))
 617     "\\<else\\([ \t]*if\\|where\\)?\\>"
 618     '("\\(&\\)[ \t]*\\(!\\|$\\)"  (1 font-lock-keyword-face))
 619     "\\<\\(then\\|continue\\|format\\|include\\|stop\\|return\\)\\>"
 620     '("\\<\\(exit\\|cycle\\)[ \t]*\\(\\sw+\\)?\\>"
 621       (1 font-lock-keyword-face) (2 font-lock-constant-face nil t))
 622     '("\\<\\(case\\)[ \t]*\\(default\\|(\\)" . 1)
 623     ;; F2003 "class default".
 624     '("\\<\\(class\\)[ \t]*default" . 1)
 625     ;; F2003 "type is" in a "select type" block.
 626     '("\\<\\(\\(type\\|class\\)[ \t]*is\\)[ \t]*(" (1 font-lock-keyword-face t))
 627     '("\\<\\(do\\|go[ \t]*to\\)\\>[ \t]*\\([0-9]+\\)"
 628       (1 font-lock-keyword-face) (2 font-lock-constant-face))
 629     ;; Line numbers (lines whose first character after number is letter).
 630     '("^[ \t]*\\([0-9]+\\)[ \t]*[a-z]+" (1 font-lock-constant-face t))))
 631   "Highlights declarations, do-loops and other constructs.")
 632
 633 (defvar f90-font-lock-keywords-3
 634   (append f90-font-lock-keywords-2
 635           (list
 636            f90-keywords-level-3-re
 637            f90-operators-re
 638            ;; FIXME why isn't this font-lock-builtin-face, which
 639            ;; otherwise we hardly use, as in fortran.el?
 640            (list f90-procedures-re '(1 font-lock-keyword-face keep))
 641            "\\<real\\>"                 ; avoid overwriting real defs
 642            ;; As an attribute, but not as an optional argument.
 643            '("\\<\\(asynchronous\\)[ \t]*[^=]" . 1)))
 644   "Highlights all F90 keywords and intrinsic procedures.")
 645
 646 (defvar f90-font-lock-keywords-4
 647   (append f90-font-lock-keywords-3
 648           (list (cons f90-constants-re 'font-lock-constant-face)
 649                 f90-hpf-keywords-re))
 650   "Highlights all F90 and HPF keywords and constants.")
 651
 652 (defvar f90-font-lock-keywords
 653   f90-font-lock-keywords-2
 654   "*Default expressions to highlight in F90 mode.
 655 Can be overridden by the value of `font-lock-maximum-decoration'.")
 656
 657
 658 (defvar f90-mode-syntax-table
 659   (let ((table (make-syntax-table)))
 660     (modify-syntax-entry ?\! "<"  table) ; begin comment
 661     (modify-syntax-entry ?\n ">"  table) ; end comment
 662     ;; FIXME: This goes against the convention: it should be "_".
 663     (modify-syntax-entry ?_  "w"  table) ; underscore in names
 664     (modify-syntax-entry ?\' "\"" table) ; string quote
 665     (modify-syntax-entry ?\" "\"" table) ; string quote
 666     ;; FIXME: We used to set ` to word syntax for the benefit of abbrevs, but
 667     ;; we do not need it any more.  Not sure if it should be "_" or "." now.
 668     (modify-syntax-entry ?\` "_"  table)
 669     (modify-syntax-entry ?\r " "  table) ; return is whitespace
 670     (modify-syntax-entry ?+  "."  table) ; punctuation
 671     (modify-syntax-entry ?-  "."  table)
 672     (modify-syntax-entry ?=  "."  table)
 673     (modify-syntax-entry ?*  "."  table)
 674     (modify-syntax-entry ?/  "."  table)
 675     (modify-syntax-entry ?%  "."  table) ; bug#8820
 676     ;; I think that the f95 standard leaves the behavior of \
 677     ;; unspecified, but that f2k will require it to be non-special.
 678     ;; Use `f90-backslash-not-special' to change.
 679     (modify-syntax-entry ?\\ "\\" table) ; escape chars
 680     table)
 681   "Syntax table used in F90 mode.")
 682
 683 (defvar f90-mode-map
 684   (let ((map (make-sparse-keymap)))
 685     (define-key map "`"        'f90-abbrev-start)
 686     (define-key map "\C-c;"    'f90-comment-region)
 687     (define-key map "\C-\M-a"  'f90-beginning-of-subprogram)
 688     (define-key map "\C-\M-e"  'f90-end-of-subprogram)
 689     (define-key map "\C-\M-h"  'f90-mark-subprogram)
 690     (define-key map "\C-\M-n"  'f90-end-of-block)
 691     (define-key map "\C-\M-p"  'f90-beginning-of-block)
 692     (define-key map "\C-\M-q"  'f90-indent-subprogram)
 693     (define-key map "\C-j"     'f90-indent-new-line) ; LFD equals C-j
 694 ;;;    (define-key map "\r"       'newline)
 695     (define-key map "\C-c\r"   'f90-break-line)
 696 ;;;  (define-key map [M-return] 'f90-break-line)
 697     (define-key map "\C-c\C-a" 'f90-previous-block)
 698     (define-key map "\C-c\C-e" 'f90-next-block)
 699     (define-key map "\C-c\C-d" 'f90-join-lines)
 700     (define-key map "\C-c\C-f" 'f90-fill-region)
 701     (define-key map "\C-c\C-p" 'f90-previous-statement)
 702     (define-key map "\C-c\C-n" 'f90-next-statement)
 703     (define-key map "\C-c]"    'f90-insert-end)
 704     (define-key map "\C-c\C-w" 'f90-insert-end)
 705     ;; Standard tab binding will call this, and also handle regions.
 706 ;;;    (define-key map "\t"       'f90-indent-line)
 707     (define-key map ","        'f90-electric-insert)
 708     (define-key map "+"        'f90-electric-insert)
 709     (define-key map "-"        'f90-electric-insert)
 710     (define-key map "*"        'f90-electric-insert)
 711     (define-key map "/"        'f90-electric-insert)
 712
 713     (easy-menu-define f90-menu map "Menu for F90 mode."
 714       `("F90"
 715         ("Customization"
 716          ,(custom-menu-create 'f90)
 717          ;; FIXME useless?
 718          ["Set"  Custom-set :active t
 719           :help "Set current value of all edited settings in the buffer"]
 720          ["Save" Custom-save :active t
 721           :help "Set and save all edited settings"]
 722          ["Reset to Current" Custom-reset-current :active t
 723           :help "Reset all edited settings to current"]
 724          ["Reset to Saved" Custom-reset-saved :active t
 725           :help "Reset all edited or set settings to saved"]
 726          ["Reset to Standard Settings" Custom-reset-standard :active t
 727           :help "Erase all customizations in buffer"]
 728          )
 729         "--"
 730         ["Indent Subprogram" f90-indent-subprogram t]
 731         ["Mark Subprogram" f90-mark-subprogram :active t :help
 732          "Mark the end of the current subprogram, move point to the start"]
 733         ["Beginning of Subprogram" f90-beginning-of-subprogram :active t
 734          :help "Move point to the start of the current subprogram"]
 735         ["End of Subprogram" f90-end-of-subprogram :active t
 736          :help "Move point to the end of the current subprogram"]
 737         "--"
 738         ["(Un)Comment Region" f90-comment-region :active mark-active
 739          :help "Comment or uncomment the region"]
 740         ["Indent Region" f90-indent-region :active mark-active]
 741         ["Fill Region" f90-fill-region :active mark-active
 742          :help "Fill long lines in the region"]
 743         "--"
 744         ["Break Line at Point" f90-break-line :active t
 745          :help "Break the current line at point"]
 746         ["Join with Previous Line" f90-join-lines :active t
 747          :help "Join the current line to the previous one"]
 748         ["Insert Block End" f90-insert-end :active t
 749          :help "Insert an end statement for the current code block"]
 750         "--"
 751         ("Highlighting"
 752          :help "Fontify this buffer to varying degrees"
 753          ["Toggle font-lock-mode" font-lock-mode :selected font-lock-mode
 754           :style toggle :help "Fontify text in this buffer"]
 755          "--"
 756          ["Light highlighting (level 1)"    f90-font-lock-1 t]
 757          ["Moderate highlighting (level 2)" f90-font-lock-2 t]
 758          ["Heavy highlighting (level 3)"    f90-font-lock-3 t]
 759          ["Maximum highlighting (level 4)"  f90-font-lock-4 t]
 760          )
 761         ("Change Keyword Case"
 762          :help "Change the case of keywords in the buffer or region"
 763          ["Upcase Keywords (buffer)"     f90-upcase-keywords     t]
 764          ["Capitalize Keywords (buffer)" f90-capitalize-keywords t]
 765          ["Downcase Keywords (buffer)"   f90-downcase-keywords   t]
 766          "--"
 767          ["Upcase Keywords (region)"     f90-upcase-region-keywords
 768           mark-active]
 769          ["Capitalize Keywords (region)" f90-capitalize-region-keywords
 770           mark-active]
 771          ["Downcase Keywords (region)"   f90-downcase-region-keywords
 772           mark-active]
 773          )
 774         "--"
 775         ["Toggle Auto Fill" auto-fill-mode :selected auto-fill-function
 776          :style toggle
 777          :help "Automatically fill text while typing in this buffer"]
 778         ["Toggle Abbrev Mode" abbrev-mode :selected abbrev-mode
 779          :style toggle :help "Expand abbreviations while typing in this buffer"]
 780         ["Add Imenu Menu" f90-add-imenu-menu
 781          :active   (not (lookup-key (current-local-map) [menu-bar index]))
 782          :included (fboundp 'imenu-add-to-menubar)
 783          :help "Add an index menu to the menu-bar"
 784          ]))
 785     map)
 786   "Keymap used in F90 mode.")
 787
 788
 789 (defun f90-font-lock-n (n)
 790   "Set `font-lock-keywords' to F90 level N keywords."
 791   (font-lock-mode 1)
 792   (setq font-lock-keywords
 793         (symbol-value (intern-soft (format "f90-font-lock-keywords-%d" n))))
 794   (font-lock-fontify-buffer))
 795
 796 (defun f90-font-lock-1 ()
 797   "Set `font-lock-keywords' to `f90-font-lock-keywords-1'."
 798   (interactive)
 799   (f90-font-lock-n 1))
 800
 801 (defun f90-font-lock-2 ()
 802   "Set `font-lock-keywords' to `f90-font-lock-keywords-2'."
 803   (interactive)
 804   (f90-font-lock-n 2))
 805
 806 (defun f90-font-lock-3 ()
 807   "Set `font-lock-keywords' to `f90-font-lock-keywords-3'."
 808   (interactive)
 809   (f90-font-lock-n 3))
 810
 811 (defun f90-font-lock-4 ()
 812   "Set `font-lock-keywords' to `f90-font-lock-keywords-4'."
 813   (interactive)
 814   (f90-font-lock-n 4))
 815 \f
 816 ;; Regexps for finding program structures.
 817 (defconst f90-blocks-re
 818   (concat "\\(block[ \t]*data\\|"
 819           (regexp-opt '("do" "if" "interface" "function" "module" "program"
 820                         "select" "subroutine" "type" "where" "forall"
 821                         ;; F2003.
 822                         "enum" "associate"
 823                         ;; F2008.
 824                         "submodule" "block" "critical"))
 825           "\\)\\>")
 826   "Regexp potentially indicating a \"block\" of F90 code.")
 827
 828 (defconst f90-program-block-re
 829   (regexp-opt '("program" "module" "subroutine" "function" "submodule") 'paren)
 830   "Regexp used to locate the start/end of a \"subprogram\".")
 831
 832 ;; "class is" is F2003.
 833 (defconst f90-else-like-re
 834   "\\(else\\([ \t]*if\\|where\\)?\\|case[ \t]*\\(default\\|(\\)\\|\
 835 \\(class\\|type\\)[ \t]*is[ \t]*(\\|class[ \t]*default\\)"
 836   "Regexp matching an ELSE IF, ELSEWHERE, CASE, CLASS/TYPE IS statement.")
 837
 838 (defconst f90-end-if-re
 839   (concat "end[ \t]*"
 840           (regexp-opt '("if" "select" "where" "forall") 'paren)
 841           "\\>")
 842   "Regexp matching the end of an IF, SELECT, WHERE, FORALL block.")
 843
 844 (defconst f90-end-type-re
 845   "end[ \t]*\\(type\\|enum\\|interface\\|block[ \t]*data\\)\\>"
 846   "Regexp matching the end of a TYPE, ENUM, INTERFACE, BLOCK DATA section.")
 847
 848 (defconst f90-end-associate-re
 849   "end[ \t]*associate\\>"
 850   "Regexp matching the end of an ASSOCIATE block.")
 851
 852 ;; This is for a TYPE block, not a variable of derived TYPE.
 853 ;; Hence no need to add CLASS for F2003.
 854 (defconst f90-type-def-re
 855   ;; type word
 856   ;; type :: word
 857   ;; type, stuff :: word
 858   ;; type, bind(c) :: word
 859   ;; NOT "type ("
 860   "\\<\\(type\\)\\>\\(?:\\(?:[^()\n]*\\|\
 861 .*,[ \t]*bind[ \t]*([ \t]*c[ \t]*)[ \t]*\\)::\\)?[ \t]*\\(\\sw+\\)"
 862   "Regexp matching the definition of a derived type.")
 863
 864 (defconst f90-typeis-re
 865   "\\<\\(class\\|type\\)[ \t]*is[ \t]*("
 866   "Regexp matching a CLASS/TYPE IS statement.")
 867
 868 (defconst f90-no-break-re
 869   (regexp-opt '("**" "//" "=>" ">=" "<=" "==" "/=" "(/" "/)") 'paren)
 870   "Regexp specifying two-character tokens not to split when breaking lines.
 871 Each token has one or more of the characters from `f90-break-delimiters'.
 872 Note that if only one of the characters is from that variable,
 873 then the presence of the token here allows a line-break before or
 874 after the other character, where a break would not normally be
 875 allowed.  This minor issue currently only affects \"(/\" and \"/)\".")
 876
 877 (defvar f90-cache-position nil
 878   "Temporary position used to speed up region operations.")
 879 (make-variable-buffer-local 'f90-cache-position)
 880
 881 \f
 882 ;; Hideshow support.
 883 (defconst f90-end-block-re
 884   (concat "^[ \t0-9]*\\<end[ \t]*"
 885           (regexp-opt '("do" "if" "forall" "function" "interface"
 886                         "module" "program" "select" "subroutine"
 887                         "type" "where" "enum" "associate" "submodule"
 888                         "block" "critical") t)
 889           "\\>")
 890   "Regexp matching the end of an F90 \"block\", from the line start.
 891 Used in the F90 entry in `hs-special-modes-alist'.")
 892
 893 ;; Ignore the fact that FUNCTION, SUBROUTINE, WHERE, FORALL have a
 894 ;; following "(".  DO, CASE, IF can have labels.
 895 (defconst f90-start-block-re
 896   (concat
 897    "^[ \t0-9]*"                         ; statement number
 898    "\\(\\("
 899    "\\(\\sw+[ \t]*:[ \t]*\\)?"          ; structure label
 900    "\\(do\\|select[ \t]*\\(case\\|type\\)\\|"
 901    ;; See comments in fortran-start-block-re for the problems of IF.
 902    "if[ \t]*(\\(.*\\|"
 903    ".*\n\\([^if]*\\([^i].\\|.[^f]\\|.\\>\\)\\)\\)\\<then\\|"
 904    ;; Distinguish WHERE block from isolated WHERE.
 905    "\\(where\\|forall\\)[ \t]*(.*)[ \t]*\\(!\\|$\\)\\)\\)"
 906    "\\|"
 907    ;; Avoid F2003 "type is" in "select type",
 908    ;; and also variables of derived type "type (foo)".
 909    ;; "type, foo" must be a block (?).
 910    "type[ \t,]\\("
 911    "[^i(!\n\"\& \t]\\|"                 ; not-i(
 912    "i[^s!\n\"\& \t]\\|"                 ; i not-s
 913    "is\\sw\\)\\|"
 914    ;; "abstract interface" is F2003; "submodule" is F2008.
 915    "program\\|\\(?:abstract[ \t]*\\)?interface\\|\\(?:sub\\)?module\\|"
 916    ;; "enum", but not "enumerator".
 917    "function\\|subroutine\\|enum[^e]\\|associate\\|block\\|critical"
 918    "\\)"
 919    "[ \t]*")
 920   "Regexp matching the start of an F90 \"block\", from the line start.
 921 A simple regexp cannot do this in fully correct fashion, so this
 922 tries to strike a compromise between complexity and flexibility.
 923 Used in the F90 entry in `hs-special-modes-alist'.")
 924
 925 ;; hs-special-modes-alist is autoloaded.
 926 (add-to-list 'hs-special-modes-alist
 927              `(f90-mode ,f90-start-block-re ,f90-end-block-re
 928                         "!" f90-end-of-block nil))
 929
 930 \f
 931 ;; Imenu support.
 932 ;; FIXME trivial to extend this to enum. Worth it?
 933 (defun f90-imenu-type-matcher ()
 934   "Search backward for the start of a derived type.
 935 Set subexpression 1 in the match-data to the name of the type."
 936   (let (found)
 937     (while (and (re-search-backward "^[ \t0-9]*type[ \t]*" nil t)
 938                 (not (setq found
 939                            (save-excursion
 940                              (goto-char (match-end 0))
 941                              (unless (looking-at "\\(is\\>\\|(\\)")
 942                                (or (looking-at "\\(\\sw+\\)")
 943                                    (re-search-forward
 944                                     "[ \t]*::[ \t]*\\(\\sw+\\)"
 945                                     (line-end-position) t))))))))
 946     found))
 947
 948 (defvar f90-imenu-generic-expression
 949   (let ((good-char "[^!\"\&\n \t]") (not-e "[^e!\n\"\& \t]")
 950         (not-n "[^n!\n\"\& \t]") (not-d "[^d!\n\"\& \t]")
 951         ;; (not-ib "[^i(!\n\"\& \t]") (not-s "[^s!\n\"\& \t]")
 952         )
 953     (list
 954      '(nil "^[ \t0-9]*program[ \t]+\\(\\sw+\\)" 1)
 955      '("Submodules" "^[ \t0-9]*submodule[ \t]*([^)\n]+)[ \t]*\
 956 \\(\\sw+\\)[ \t]*\\(!\\|$\\)" 1)
 957      '("Modules" "^[ \t0-9]*module[ \t]+\\(\\sw+\\)[ \t]*\\(!\\|$\\)" 1)
 958      (list "Types" 'f90-imenu-type-matcher 1)
 959      ;; Does not handle: "type[, stuff] :: foo".
 960 ;;;      (format "^[ \t0-9]*type[ \t]+\\(\\(%s\\|i%s\\|is\\sw\\)\\sw*\\)"
 961 ;;;              not-ib not-s)
 962 ;;;      1)
 963      ;; Can't get the subexpression numbers to match in the two branches.
 964 ;;;      (format "^[ \t0-9]*type\\([ \t]*,.*\\(::\\)[ \t]*\\(\\sw+\\)\\|[ \t]+\\(\\(%s\\|i%s\\|is\\sw\\)\\sw*\\)\\)" not-ib not-s)
 965 ;;;      3)
 966      (list
 967       "Procedures"
 968       (concat
 969        "^[ \t0-9]*"
 970        "\\("
 971        ;; At least three non-space characters before function/subroutine.
 972        ;; Check that the last three non-space characters do not spell E N D.
 973        "[^!\"\&\n]*\\("
 974        not-e good-char good-char "\\|"
 975        good-char not-n good-char "\\|"
 976        good-char good-char not-d "\\)"
 977        "\\|"
 978        ;; Less than three non-space characters before function/subroutine.
 979        good-char "?" good-char "?"
 980        "\\)"
 981        "[ \t]*\\(function\\|subroutine\\)[ \t]+\\(\\sw+\\)")
 982       4)))
 983   "Value for `imenu-generic-expression' in F90 mode.")
 984
 985 (defun f90-add-imenu-menu ()
 986   "Add an imenu menu to the menubar."
 987   (interactive)
 988   (if (lookup-key (current-local-map) [menu-bar index])
 989       (message "%s" "F90-imenu already exists.")
 990     (imenu-add-to-menubar "F90-imenu")
 991     (redraw-frame (selected-frame))))
 992
 993 \f
 994 ;; Abbrevs have generally two letters, except standard types `c, `i, `r, `t.
 995 (define-abbrev-table 'f90-mode-abbrev-table
 996   (mapcar (lambda (e) (list (car e) (cdr e) nil :system t))
 997           '(("`al"  . "allocate"     )
 998             ("`ab"  . "allocatable"  )
 999             ("`ai"  . "abstract interface")
1000             ("`as"  . "assignment"   )
1001             ("`asy" . "asynchronous" )
1002             ("`ba"  . "backspace"    )
1003             ("`bd"  . "block data"   )
1004             ("`bl"  . "block"        )
1005             ("`c"   . "character"    )
1006             ("`cl"  . "close"        )
1007             ("`cm"  . "common"       )
1008             ("`cx"  . "complex"      )
1009             ("`cn"  . "contains"     )
1010             ("`cr"  . "critical"     )
1011             ("`cy"  . "cycle"        )
1012             ("`de"  . "deallocate"   )
1013             ("`df"  . "define"       )
1014             ("`di"  . "dimension"    )
1015             ("`dp"  . "double precision")
1016             ("`dw"  . "do while"     )
1017             ("`el"  . "else"         )
1018             ("`eli" . "else if"      )
1019             ("`elw" . "elsewhere"    )
1020             ("`em"  . "elemental"    )
1021             ("`e"   . "enumerator"   )
1022             ("`eq"  . "equivalence"  )
1023             ("`ex"  . "external"     )
1024             ("`ey"  . "entry"        )
1025             ("`fl"  . "forall"       )
1026             ("`fo"  . "format"       )
1027             ("`fu"  . "function"     )
1028             ("`fa"  . ".false."      )
1029             ("`im"  . "implicit none")
1030             ("`in"  . "include"      )
1031             ("`i"   . "integer"      )
1032             ("`it"  . "intent"       )
1033             ("`if"  . "interface"    )
1034             ("`lo"  . "logical"      )
1035             ("`mo"  . "module"       )
1036             ("`na"  . "namelist"     )
1037             ("`nu"  . "nullify"      )
1038             ("`op"  . "optional"     )
1039             ("`pa"  . "parameter"    )
1040             ("`po"  . "pointer"      )
1041             ("`pr"  . "print"        )
1042             ("`pi"  . "private"      )
1043             ("`pm"  . "program"      )
1044             ("`pr"  . "protected"    )
1045             ("`pu"  . "public"       )
1046             ("`r"   . "real"         )
1047             ("`rc"  . "recursive"    )
1048             ("`rt"  . "return"       )
1049             ("`rw"  . "rewind"       )
1050             ("`se"  . "select"       )
1051             ("`sq"  . "sequence"     )
1052             ("`su"  . "subroutine"   )
1053             ("`ta"  . "target"       )
1054             ("`tr"  . ".true."       )
1055             ("`t"   . "type"         )
1056             ("`vo"  . "volatile"     )
1057             ("`wh"  . "where"        )
1058             ("`wr"  . "write"        )))
1059   "Abbrev table for F90 mode."
1060   ;; Accept ` as the first char of an abbrev.  Also allow _ in abbrevs.
1061   :regexp "\\(?:[^[:word:]_`]\\|^\\)\\(`?[[:word:]_]+\\)[^[:word:]_]*")
1062 \f
1063 ;;;###autoload
1064 (define-derived-mode f90-mode prog-mode "F90"
1065   "Major mode for editing Fortran 90,95 code in free format.
1066 For fixed format code, use `fortran-mode'.
1067
1068 \\[f90-indent-line] indents the current line.
1069 \\[f90-indent-new-line] indents current line and creates a new\
1070  indented line.
1071 \\[f90-indent-subprogram] indents the current subprogram.
1072
1073 Type `? or `\\[help-command] to display a list of built-in\
1074  abbrevs for F90 keywords.
1075
1076 Key definitions:
1077 \\{f90-mode-map}
1078
1079 Variables controlling indentation style and extra features:
1080
1081 `f90-do-indent'
1082   Extra indentation within do blocks (default 3).
1083 `f90-if-indent'
1084   Extra indentation within if/select/where/forall blocks (default 3).
1085 `f90-type-indent'
1086   Extra indentation within type/enum/interface/block-data blocks (default 3).
1087 `f90-program-indent'
1088   Extra indentation within program/module/subroutine/function blocks
1089   (default 2).
1090 `f90-associate-indent'
1091   Extra indentation within associate blocks (default 2).
1092 `f90-critical-indent'
1093   Extra indentation within critical/block blocks (default 2).
1094 `f90-continuation-indent'
1095   Extra indentation applied to continuation lines (default 5).
1096 `f90-comment-region'
1097   String inserted by function \\[f90-comment-region] at start of each
1098   line in region (default \"!!!$\").
1099 `f90-indented-comment-re'
1100   Regexp determining the type of comment to be intended like code
1101   (default \"!\").
1102 `f90-directive-comment-re'
1103   Regexp of comment-like directive like \"!HPF\\\\$\", not to be indented
1104   (default \"!hpf\\\\$\").
1105 `f90-break-delimiters'
1106   Regexp holding list of delimiters at which lines may be broken
1107   (default \"[-+*/><=,% \\t]\").
1108 `f90-break-before-delimiters'
1109   Non-nil causes `f90-do-auto-fill' to break lines before delimiters
1110   (default t).
1111 `f90-beginning-ampersand'
1112   Automatic insertion of \& at beginning of continuation lines (default t).
1113 `f90-smart-end'
1114   From an END statement, check and fill the end using matching block start.
1115   Allowed values are 'blink, 'no-blink, and nil, which determine
1116   whether to blink the matching beginning (default 'blink).
1117 `f90-auto-keyword-case'
1118   Automatic change of case of keywords (default nil).
1119   The possibilities are 'downcase-word, 'upcase-word, 'capitalize-word.
1120 `f90-leave-line-no'
1121   Do not left-justify line numbers (default nil).
1122
1123 Turning on F90 mode calls the value of the variable `f90-mode-hook'
1124 with no args, if that value is non-nil."
1125   :group 'f90
1126   :abbrev-table f90-mode-abbrev-table
1127   (set (make-local-variable 'indent-line-function) 'f90-indent-line)
1128   (set (make-local-variable 'indent-region-function) 'f90-indent-region)
1129   (set (make-local-variable 'comment-start) "!")
1130   (set (make-local-variable 'comment-start-skip) "!+ *")
1131   (set (make-local-variable 'comment-indent-function) 'f90-comment-indent)
1132   (set (make-local-variable 'abbrev-all-caps) t)
1133   (set (make-local-variable 'normal-auto-fill-function) 'f90-do-auto-fill)
1134   (setq indent-tabs-mode nil)           ; auto buffer local
1135   (set (make-local-variable 'font-lock-defaults)
1136        '((f90-font-lock-keywords f90-font-lock-keywords-1
1137                                  f90-font-lock-keywords-2
1138                                  f90-font-lock-keywords-3
1139                                  f90-font-lock-keywords-4)
1140          nil t))
1141   (set (make-local-variable 'imenu-case-fold-search) t)
1142   (set (make-local-variable 'imenu-generic-expression)
1143        f90-imenu-generic-expression)
1144   (set (make-local-variable 'beginning-of-defun-function)
1145        'f90-beginning-of-subprogram)
1146   (set (make-local-variable 'end-of-defun-function) 'f90-end-of-subprogram)
1147   (set (make-local-variable 'add-log-current-defun-function)
1148        #'f90-current-defun))
1149
1150 \f
1151 ;; Inline-functions.
1152 (defsubst f90-in-string ()
1153   "Return non-nil if point is inside a string.
1154 Checks from `point-min', or `f90-cache-position', if that is non-nil
1155 and lies before point."
1156   (let ((beg-pnt
1157          (if (and f90-cache-position (> (point) f90-cache-position))
1158              f90-cache-position
1159            (point-min))))
1160     (nth 3 (parse-partial-sexp beg-pnt (point)))))
1161
1162 (defsubst f90-in-comment ()
1163   "Return non-nil if point is inside a comment.
1164 Checks from `point-min', or `f90-cache-position', if that is non-nil
1165 and lies before point."
1166   (let ((beg-pnt
1167          (if (and f90-cache-position (> (point) f90-cache-position))
1168              f90-cache-position
1169            (point-min))))
1170     (nth 4 (parse-partial-sexp beg-pnt (point)))))
1171
1172 (defsubst f90-line-continued ()
1173   "Return t if the current line is a continued one.
1174 This includes comment lines embedded in continued lines, but
1175 not the last line of a continued statement."
1176   (save-excursion
1177     (beginning-of-line)
1178     (while (and (looking-at "[ \t]*\\(!\\|$\\)") (zerop (forward-line -1))))
1179     (end-of-line)
1180     (while (f90-in-comment)
1181       (search-backward "!" (line-beginning-position))
1182       (skip-chars-backward "!"))
1183     (skip-chars-backward " \t")
1184     (= (preceding-char) ?&)))
1185
1186 ;; GM this is not right, eg a continuation line starting with a number.
1187 ;; Need f90-code-start-position function.
1188 ;; And yet, things seems to work with this...
1189 ;; cf f90-indent-line
1190 ;;     (beginning-of-line)           ; digits after & \n are not line-nos
1191 ;;     (if (not (save-excursion (and (f90-previous-statement)
1192 ;;                                   (f90-line-continued))))
1193 ;;         (f90-indent-line-no)
1194 (defsubst f90-current-indentation ()
1195   "Return indentation of current line.
1196 Line-numbers are considered whitespace characters."
1197   (save-excursion (beginning-of-line) (skip-chars-forward " \t0-9")))
1198
1199 (defsubst f90-indent-to (col &optional no-line-number)
1200   "Indent current line to column COL.
1201 If optional argument NO-LINE-NUMBER is nil, jump over a possible
1202 line-number before indenting."
1203   (beginning-of-line)
1204   (or no-line-number
1205       (skip-chars-forward " \t0-9"))
1206   (delete-horizontal-space)
1207   ;; Leave >= 1 space after line number.
1208   (indent-to col (if (zerop (current-column)) 0 1)))
1209
1210 (defsubst f90-get-present-comment-type ()
1211   "If point lies within a comment, return the string starting the comment.
1212 For example, \"!\" or \"!!\", followed by the appropriate amount of
1213 whitespace, if any."
1214   ;; Include the whitespace for consistent auto-filling of comment blocks.
1215   (save-excursion
1216     (when (f90-in-comment)
1217       (beginning-of-line)
1218       (re-search-forward "!+[ \t]*" (line-end-position))
1219       (while (f90-in-string)
1220         (re-search-forward "!+[ \t]*" (line-end-position)))
1221       (match-string-no-properties 0))))
1222
1223 (defsubst f90-equal-symbols (a b)
1224   "Compare strings A and B neglecting case and allowing for nil value."
1225   (equal (if a (downcase a) nil)
1226          (if b (downcase b) nil)))
1227
1228 (defsubst f90-looking-at-do ()
1229   "Return (\"do\" NAME) if a do statement starts after point.
1230 NAME is nil if the statement has no label."
1231   (if (looking-at "\\(\\(\\sw+\\)[ \t]*:\\)?[ \t]*\\(do\\)\\>")
1232       (list (match-string 3) (match-string 2))))
1233
1234 (defsubst f90-looking-at-select-case ()
1235   "Return (\"select\" NAME) if a select statement starts after point.
1236 NAME is nil if the statement has no label."
1237   (if (looking-at "\\(\\(\\sw+\\)[ \t]*:\\)?[ \t]*\
1238 \\(select\\)[ \t]*\\(case\\|type\\)[ \t]*(")
1239       (list (match-string 3) (match-string 2))))
1240
1241 (defsubst f90-looking-at-if-then ()
1242   "Return (\"if\" NAME) if an if () then statement starts after point.
1243 NAME is nil if the statement has no label."
1244   (save-excursion
1245     (when (looking-at "\\(\\(\\sw+\\)[ \t]*:\\)?[ \t]*\\(if\\)\\>")
1246       (let ((struct (match-string 3))
1247             (label (match-string 2))
1248             (pos (scan-lists (point) 1 0)))
1249         (and pos (goto-char pos))
1250         (skip-chars-forward " \t")
1251         (if (or (looking-at "then\\>")
1252                 (when (f90-line-continued)
1253                   (f90-next-statement)
1254                   (skip-chars-forward " \t0-9&")
1255                   (looking-at "then\\>")))
1256             (list struct label))))))
1257
1258 ;; FIXME label?
1259 (defsubst f90-looking-at-associate ()
1260   "Return (\"associate\") if an associate block starts after point."
1261   (if (looking-at "\\<\\(associate\\)[ \t]*(")
1262       (list (match-string 1))))
1263
1264 (defsubst f90-looking-at-critical ()
1265   "Return (KIND NAME) if a critical or block block starts after point."
1266   (if (looking-at "\\(\\(\\sw+\\)[ \t]*:\\)?[ \t]*\\(critical\\|block\\)\\>")
1267       (let ((struct (match-string 3))
1268             (label (match-string 2)))
1269         (if (or (not (string-equal "block" struct))
1270                 (save-excursion
1271                   (skip-chars-forward " \t")
1272                   (not (looking-at "data\\>"))))
1273             (list struct label)))))
1274
1275 (defsubst f90-looking-at-end-critical ()
1276   "Return non-nil if a critical or block block ends after point."
1277   (if (looking-at "end[ \t]*\\(critical\\|block\\)\\>")
1278       (or (not (string-equal "block" (match-string 1)))
1279           (save-excursion
1280             (skip-chars-forward " \t")
1281             (not (looking-at "data\\>"))))))
1282
1283 (defsubst f90-looking-at-where-or-forall ()
1284   "Return (KIND NAME) if a where or forall block starts after point.
1285 NAME is nil if the statement has no label."
1286   (save-excursion
1287     (when (looking-at "\\(\\(\\sw+\\)[ \t]*:\\)?[ \t]*\
1288 \\(where\\|forall\\)\\>")
1289       (let ((struct (match-string 3))
1290             (label (match-string 2))
1291             (pos (scan-lists (point) 1 0)))
1292         (and pos (goto-char pos))
1293         (skip-chars-forward " \t")
1294         (if (looking-at "\\(!\\|$\\)") (list struct label))))))
1295
1296 (defsubst f90-looking-at-type-like ()
1297   "Return (KIND NAME) if a type/enum/interface/block-data starts after point.
1298 NAME is non-nil only for type and certain interfaces."
1299   (cond
1300    ((save-excursion
1301       (and (looking-at "\\<type\\>[ \t]*")
1302            (goto-char (match-end 0))
1303            (not (looking-at "\\(is\\>\\|(\\)"))
1304            (or (looking-at "\\(\\sw+\\)")
1305                (re-search-forward "[ \t]*::[ \t]*\\(\\sw+\\)"
1306                                   (line-end-position) t))))
1307     (list "type" (match-string 1)))
1308 ;;;    ((and (not (looking-at f90-typeis-re))
1309 ;;;          (looking-at f90-type-def-re))
1310 ;;;     (list (match-string 1) (match-string 2)))
1311    ((looking-at "\\<\\(interface\\)\\>[ \t]*")
1312     (list (match-string 1)
1313           (save-excursion
1314             (goto-char (match-end 0))
1315             (if (or (looking-at "\\(operator\\|assignment\\|read\\|\
1316 write\\)[ \t]*([^)\n]*)")
1317                     (looking-at "\\sw+"))
1318                 (match-string 0)))))
1319    ((looking-at "\\(enum\\|block[ \t]*data\\)\\>")
1320     (list (match-string 1) nil))
1321    ((looking-at "abstract[ \t]*\\(interface\\)\\>")
1322     (list (match-string 1) nil))))
1323
1324 (defsubst f90-looking-at-program-block-start ()
1325   "Return (KIND NAME) if a program block with name NAME starts after point."
1326 ;;;NAME is nil for an un-named main PROGRAM block."
1327   (cond
1328    ((looking-at "\\(program\\)[ \t]+\\(\\sw+\\)\\>")
1329     (list (match-string 1) (match-string 2)))
1330    ((and (not (looking-at "module[ \t]*procedure\\>"))
1331          (looking-at "\\(module\\)[ \t]+\\(\\sw+\\)\\>"))
1332     (list (match-string 1) (match-string 2)))
1333    ((looking-at "\\(submodule\\)[ \t]*([^)\n]+)[ \t]*\\(\\sw+\\)\\>")
1334     (list (match-string 1) (match-string 2)))
1335    ((and (not (looking-at "end[ \t]*\\(function\\|subroutine\\)"))
1336          (looking-at "[^!'\"\&\n]*\\(function\\|subroutine\\)[ \t]+\
1337 \\(\\sw+\\)"))
1338     (list (match-string 1) (match-string 2)))))
1339 ;; Following will match an un-named main program block; however
1340 ;; one needs to check if there is an actual PROGRAM statement after
1341 ;; point (and before any END program). Adding this will require
1342 ;; change to eg f90-calculate-indent.
1343 ;;;   ((save-excursion
1344 ;;;     (not (f90-previous-statement)))
1345 ;;;    '("program" nil))))
1346
1347 (defsubst f90-looking-at-program-block-end ()
1348   "Return (KIND NAME) if a block with name NAME ends after point."
1349   (cond ((looking-at "end[ \t]*\\(interface\\)[ \t]*\\(\
1350 \\(?:assignment\\|operator\\|read\\|write\\)[ \t]*([^)\n]*)\\)")
1351          (list (match-string 1) (match-string 2)))
1352         ((looking-at (concat "end[ \t]*" f90-blocks-re
1353                              "?\\([ \t]+\\(\\sw+\\)\\)?\\>"))
1354         (list (match-string 1) (match-string 3)))))
1355
1356 (defsubst f90-comment-indent ()
1357   "Return the indentation to be used for a comment starting at point.
1358 Used for `comment-indent-function' by F90 mode.
1359 \"!!!\", `f90-directive-comment-re', variable `f90-comment-region' return 0.
1360 `f90-indented-comment-re' (if not trailing code) calls `f90-calculate-indent'.
1361 All others return `comment-column', leaving at least one space after code."
1362   (cond ((looking-at "!!!") 0)
1363         ((and f90-directive-comment-re
1364               (looking-at f90-directive-comment-re)) 0)
1365         ((looking-at (regexp-quote f90-comment-region)) 0)
1366         ((and (looking-at f90-indented-comment-re)
1367               ;; Don't attempt to indent trailing comment as code.
1368               (save-excursion
1369                 (skip-chars-backward " \t")
1370                 (bolp)))
1371          (f90-calculate-indent))
1372         (t (save-excursion
1373              (skip-chars-backward " \t")
1374              (max (if (bolp) 0 (1+ (current-column))) comment-column)))))
1375
1376 (defsubst f90-present-statement-cont ()
1377   "Return continuation properties of present statement.
1378 Possible return values are:
1379 single - statement is not continued.
1380 begin  - current line is the first in a continued statement.
1381 end    - current line is the last in a continued statement
1382 middle - current line is neither first nor last in a continued statement.
1383 Comment lines embedded amongst continued lines return 'middle."
1384   (let (pcont cont)
1385     (save-excursion
1386       (setq pcont (if (f90-previous-statement) (f90-line-continued))))
1387     (setq cont (f90-line-continued))
1388     (cond ((and (not pcont) (not cont)) 'single)
1389           ((and (not pcont) cont)       'begin)
1390           ((and pcont       (not cont)) 'end)
1391           ((and pcont       cont)       'middle)
1392           (t (error "The impossible occurred")))))
1393
1394 (defsubst f90-indent-line-no ()
1395   "If `f90-leave-line-no' is nil, left-justify a line number.
1396 Leaves point at the first non-blank character after the line number.
1397 Call from beginning of line."
1398   (and (null f90-leave-line-no) (looking-at "[ \t]+[0-9]")
1399        (delete-horizontal-space))
1400   (skip-chars-forward " \t0-9"))
1401
1402 (defsubst f90-no-block-limit ()
1403   "Return nil if point is at the edge of a code block.
1404 Searches line forward for \"function\" or \"subroutine\",
1405 if all else fails."
1406   (save-excursion
1407     (not (or (looking-at "end")
1408              (looking-at "\\(do\\|if\\|else\\(if\\|where\\)?\
1409 \\|select[ \t]*\\(case\\|type\\)\\|case\\|where\\|forall\\|\
1410 block\\|critical\\)\\>")
1411              (looking-at "\\(program\\|\\(?:sub\\)?module\\|\
1412 \\(?:abstract[ \t]*\\)?interface\\|block[ \t]*data\\)\\>")
1413              (looking-at "\\(contains\\|\\sw+[ \t]*:\\)")
1414              (looking-at f90-type-def-re)
1415              (re-search-forward "\\(function\\|subroutine\\)"
1416                                 (line-end-position) t)))))
1417
1418 (defsubst f90-update-line ()
1419   "Change case of current line as per `f90-auto-keyword-case'."
1420   (if f90-auto-keyword-case
1421       (f90-change-keywords f90-auto-keyword-case
1422                            (line-beginning-position) (line-end-position))))
1423 \f
1424 (defun f90-electric-insert (&optional arg)
1425   "Change keyword case and auto-fill line as operators are inserted."
1426   (interactive "*p")
1427   (self-insert-command arg)
1428   (if auto-fill-function (f90-do-auto-fill) ; also updates line
1429     (f90-update-line)))
1430
1431 ;; Behave like self-insert-command for delete-selection-mode (bug#5593).
1432 (put 'f90-electric-insert 'delete-selection t)
1433
1434 (defun f90-get-correct-indent ()
1435   "Get correct indent for a line starting with line number.
1436 Does not check type and subprogram indentation."
1437   (let ((epnt (line-end-position)) icol)
1438     (save-excursion
1439       (while (and (f90-previous-statement)
1440                   (or (memq (f90-present-statement-cont) '(middle end))
1441                       (looking-at "[ \t]*[0-9]"))))
1442       (setq icol (current-indentation))
1443       (beginning-of-line)
1444       (when (re-search-forward "\\(if\\|do\\|select\\|where\\|forall\\)"
1445                                (line-end-position) t)
1446         (beginning-of-line)
1447         (skip-chars-forward " \t")
1448         (cond ((f90-looking-at-do)
1449                (setq icol (+ icol f90-do-indent)))
1450               ((or (f90-looking-at-if-then)
1451                    (f90-looking-at-where-or-forall)
1452                    (f90-looking-at-select-case))
1453                (setq icol (+ icol f90-if-indent)))
1454               ;; FIXME this makes no sense, because this section/function is
1455               ;; only for if/do/select/where/forall ?
1456               ((f90-looking-at-associate)
1457                (setq icol (+ icol f90-associate-indent))))
1458         (end-of-line))
1459       (while (re-search-forward
1460               "\\(if\\|do\\|select\\|where\\|forall\\)" epnt t)
1461         (beginning-of-line)
1462         (skip-chars-forward " \t0-9")
1463         (cond ((f90-looking-at-do)
1464                (setq icol (+ icol f90-do-indent)))
1465               ((or (f90-looking-at-if-then)
1466                    (f90-looking-at-where-or-forall)
1467                    (f90-looking-at-select-case))
1468                (setq icol (+ icol f90-if-indent)))
1469               ;; FIXME this makes no sense, because this section/function is
1470               ;; only for if/do/select/where/forall ?
1471               ((f90-looking-at-associate)
1472                (setq icol (+ icol f90-associate-indent)))
1473               ((looking-at f90-end-if-re)
1474                (setq icol (- icol f90-if-indent)))
1475               ((looking-at f90-end-associate-re)
1476                (setq icol (- icol f90-associate-indent)))
1477               ((f90-looking-at-end-critical)
1478                (setq icol (- icol f90-critical-indent)))
1479               ((looking-at "end[ \t]*do\\>")
1480                (setq icol (- icol f90-do-indent))))
1481         (end-of-line))
1482       icol)))
1483
1484 (defun f90-calculate-indent ()
1485   "Calculate the indent column based on previous statements."
1486   (interactive)
1487   (let (icol cont (case-fold-search t) (pnt (point)))
1488     (save-excursion
1489       (if (not (f90-previous-statement))
1490           ;; If f90-previous-statement returns nil, we must have been
1491           ;; called from on or before the first line of the first statement.
1492           (setq icol (if (or (save-excursion
1493                                (goto-char pnt)
1494                                (beginning-of-line)
1495                                ;; Preprocessor line before code statement.
1496                                (looking-at "[ \t]*#"))
1497                              (progn
1498                                ;; f90-previous-statement has moved us over
1499                                ;; comment/blank lines, so we need to get
1500                                ;; back to the first code statement.
1501                                (when (looking-at "[ \t]*\\([!#]\\|$\\)")
1502                                  (f90-next-statement))
1503                                (skip-chars-forward " \t0-9")
1504                                (f90-looking-at-program-block-start)))
1505                          0
1506                        ;; No explicit PROGRAM start statement.
1507                        f90-program-indent))
1508         (setq cont (f90-present-statement-cont))
1509         (if (eq cont 'end)
1510             (while (not (eq 'begin (f90-present-statement-cont)))
1511               (f90-previous-statement)))
1512         (cond ((eq cont 'begin)
1513                (setq icol (+ (f90-current-indentation)
1514                              f90-continuation-indent)))
1515               ((eq cont 'middle) (setq icol (current-indentation)))
1516               (t (setq icol (f90-current-indentation))
1517                  (skip-chars-forward " \t")
1518                  (if (looking-at "[0-9]")
1519                      (setq icol (f90-get-correct-indent))
1520                    (cond ((or (f90-looking-at-if-then)
1521                               (f90-looking-at-where-or-forall)
1522                               (f90-looking-at-select-case)
1523                               (looking-at f90-else-like-re))
1524                           (setq icol (+ icol f90-if-indent)))
1525                          ((f90-looking-at-do)
1526                           (setq icol (+ icol f90-do-indent)))
1527                          ((f90-looking-at-type-like)
1528                           (setq icol (+ icol f90-type-indent)))
1529                          ((f90-looking-at-associate)
1530                           (setq icol (+ icol f90-associate-indent)))
1531                          ((f90-looking-at-critical)
1532                           (setq icol (+ icol f90-critical-indent)))
1533                          ((or (f90-looking-at-program-block-start)
1534                               (looking-at "contains[ \t]*\\($\\|!\\)"))
1535                           (setq icol (+ icol f90-program-indent)))))
1536                  (goto-char pnt)
1537                  (beginning-of-line)
1538                  (cond ((looking-at "[ \t]*$"))
1539                        ((looking-at "[ \t]*#") ; check for cpp directive
1540                         (setq icol 0))
1541                        (t
1542                         (skip-chars-forward " \t0-9")
1543                         (cond ((or (looking-at f90-else-like-re)
1544                                    (looking-at f90-end-if-re))
1545                                (setq icol (- icol f90-if-indent)))
1546                               ((looking-at "end[ \t]*do\\>")
1547                                (setq icol (- icol f90-do-indent)))
1548                               ((looking-at f90-end-type-re)
1549                                (setq icol (- icol f90-type-indent)))
1550                               ((looking-at f90-end-associate-re)
1551                                (setq icol (- icol f90-associate-indent)))
1552                               ((f90-looking-at-end-critical)
1553                                (setq icol (- icol f90-critical-indent)))
1554                               ((or (looking-at "contains[ \t]*\\(!\\|$\\)")
1555                                    (f90-looking-at-program-block-end))
1556                                (setq icol (- icol f90-program-indent))))))))))
1557     icol))
1558 \f
1559 (defun f90-previous-statement ()
1560   "Move point to beginning of the previous F90 statement.
1561 If no previous statement is found (i.e. if called from the first
1562 statement in the buffer), move to the start of the buffer and
1563 return nil.  A statement is a line which is neither blank nor a
1564 comment."
1565   (interactive)
1566   (let (not-first-statement)
1567     (beginning-of-line)
1568     (while (and (setq not-first-statement (zerop (forward-line -1)))
1569                 (looking-at "[ \t0-9]*\\(!\\|$\\|#\\)")))
1570     not-first-statement))
1571
1572 (defun f90-next-statement ()
1573   "Move point to beginning of the next F90 statement.
1574 Return nil if no later statement is found."
1575   (interactive)
1576   (let (not-last-statement)
1577     (beginning-of-line)
1578     (while (and (setq not-last-statement
1579                       (and (zerop (forward-line 1))
1580                            (not (eobp))))
1581                 (looking-at "[ \t0-9]*\\(!\\|$\\|#\\)")))
1582     not-last-statement))
1583
1584 (defun f90-beginning-of-subprogram ()
1585   "Move point to the beginning of the current subprogram.
1586 Return (TYPE NAME), or nil if not found."
1587   (interactive)
1588   (let ((count 1) (case-fold-search t) matching-beg)
1589     (beginning-of-line)
1590     (while (and (> count 0)
1591                 (re-search-backward f90-program-block-re nil 'move))
1592       (beginning-of-line)
1593       (skip-chars-forward " \t0-9")
1594       (cond ((setq matching-beg (f90-looking-at-program-block-start))
1595              (setq count (1- count)))
1596             ((f90-looking-at-program-block-end)
1597              (setq count (1+ count)))))
1598     (beginning-of-line)
1599     (if (zerop count)
1600         matching-beg
1601       ;; Note this includes the case of an un-named main program,
1602       ;; in which case we go to (point-min).
1603       (if (called-interactively-p 'interactive)
1604           (message "No beginning found"))
1605       nil)))
1606
1607 (defun f90-end-of-subprogram ()
1608   "Move point to the end of the current subprogram.
1609 Return (TYPE NAME), or nil if not found."
1610   (interactive)
1611   (let ((case-fold-search t)
1612         (count 1)
1613         matching-end)
1614     (end-of-line)
1615     (while (and (> count 0)
1616                 (re-search-forward f90-program-block-re nil 'move))
1617       (beginning-of-line)
1618       (skip-chars-forward " \t0-9")
1619       (cond ((f90-looking-at-program-block-start)
1620              (setq count (1+ count)))
1621             ((setq matching-end (f90-looking-at-program-block-end))
1622              (setq count (1- count))))
1623       (end-of-line))
1624     ;; This means f90-end-of-subprogram followed by f90-start-of-subprogram
1625     ;; has a net non-zero effect, which seems odd.
1626 ;;;    (forward-line 1)
1627     (if (zerop count)
1628         matching-end
1629       (if (called-interactively-p 'interactive)
1630           (message "No end found"))
1631       nil)))
1632
1633
1634 (defun f90-end-of-block (&optional num)
1635   "Move point forward to the end of the current code block.
1636 With optional argument NUM, go forward that many balanced blocks.
1637 If NUM is negative, go backward to the start of a block.  Checks
1638 for consistency of block types and labels (if present), and
1639 completes outermost block if `f90-smart-end' is non-nil.
1640 Interactively, pushes mark before moving point."
1641   (interactive "p")
1642   ;; Can move some distance.
1643   (if (called-interactively-p 'any) (push-mark (point) t))
1644   (and num (< num 0) (f90-beginning-of-block (- num)))
1645   (let ((f90-smart-end (if f90-smart-end 'no-blink)) ; for final match-end
1646         (case-fold-search t)
1647         (count (or num 1))
1648         start-list start-this start-type start-label end-type end-label)
1649     (end-of-line)                       ; probably want this
1650     (while (and (> count 0) (re-search-forward f90-blocks-re nil 'move))
1651       (beginning-of-line)
1652       (skip-chars-forward " \t0-9")
1653       (cond ((or (f90-in-string) (f90-in-comment)))
1654             ((setq start-this
1655                    (or
1656                     (f90-looking-at-do)
1657                     (f90-looking-at-select-case)
1658                     (f90-looking-at-type-like)
1659                     (f90-looking-at-associate)
1660                     (f90-looking-at-critical)
1661                     (f90-looking-at-program-block-start)
1662                     (f90-looking-at-if-then)
1663                     (f90-looking-at-where-or-forall)))
1664              (setq start-list (cons start-this start-list) ; not add-to-list!
1665                    count (1+ count)))
1666             ((looking-at (concat "end[ \t]*" f90-blocks-re
1667                                  "[ \t]*\\(\\sw+\\)?"))
1668              (setq end-type (match-string 1)
1669                    end-label (match-string 2)
1670                    count (1- count))
1671              ;; Check any internal blocks.
1672              (when start-list
1673                (setq start-this (car start-list)
1674                      start-list (cdr start-list)
1675                      start-type (car start-this)
1676                      start-label (cadr start-this))
1677                (or (f90-equal-symbols start-type end-type)
1678                    (error "End type `%s' does not match start type `%s'"
1679                           end-type start-type))
1680                (or (f90-equal-symbols start-label end-label)
1681                    (error "End label `%s' does not match start label `%s'"
1682                           end-label start-label)))))
1683       (end-of-line))
1684     (if (> count 0) (error "Missing block end"))
1685     ;; Check outermost block.
1686     (when f90-smart-end
1687       (save-excursion
1688         (beginning-of-line)
1689         (skip-chars-forward " \t0-9")
1690         (f90-match-end)))))
1691
1692 (defun f90-beginning-of-block (&optional num)
1693   "Move point backwards to the start of the current code block.
1694 With optional argument NUM, go backward that many balanced blocks.
1695 If NUM is negative, go forward to the end of a block.
1696 Checks for consistency of block types and labels (if present).
1697 Does not check the outermost block, because it may be incomplete.
1698 Interactively, pushes mark before moving point."
1699   (interactive "p")
1700   (if (called-interactively-p 'any) (push-mark (point) t))
1701   (and num (< num 0) (f90-end-of-block (- num)))
1702   (let ((case-fold-search t)
1703         (count (or num 1))
1704         end-list end-this end-type end-label
1705         start-this start-type start-label)
1706     (beginning-of-line)                 ; probably want this
1707     (while (and (> count 0) (re-search-backward f90-blocks-re nil 'move))
1708       (beginning-of-line)
1709       (skip-chars-forward " \t0-9")
1710       (cond ((or (f90-in-string) (f90-in-comment)))
1711             ((looking-at (concat "end[ \t]*" f90-blocks-re
1712                                  "[ \t]*\\(\\sw+\\)?"))
1713              (setq end-list (cons (list (match-string 1) (match-string 2))
1714                                   end-list)
1715                    count (1+ count)))
1716             ((setq start-this
1717                    (or
1718                     (f90-looking-at-do)
1719                     (f90-looking-at-select-case)
1720                     (f90-looking-at-type-like)
1721                     (f90-looking-at-associate)
1722                     (f90-looking-at-critical)
1723                     (f90-looking-at-program-block-start)
1724                     (f90-looking-at-if-then)
1725                     (f90-looking-at-where-or-forall)))
1726              (setq start-type (car start-this)
1727                    start-label (cadr start-this)
1728                    count (1- count))
1729              ;; Check any internal blocks.
1730              (when end-list
1731                (setq end-this (car end-list)
1732                      end-list (cdr end-list)
1733                      end-type (car end-this)
1734                      end-label (cadr end-this))
1735                (or (f90-equal-symbols start-type end-type)
1736                    (error "Start type `%s' does not match end type `%s'"
1737                           start-type end-type))
1738                (or (f90-equal-symbols start-label end-label)
1739                    (error "Start label `%s' does not match end label `%s'"
1740                           start-label end-label))))))
1741     ;; Includes an un-named main program block.
1742     (if (> count 0) (error "Missing block start"))))
1743
1744 (defun f90-next-block (&optional num)
1745   "Move point forward to the next end or start of a code block.
1746 With optional argument NUM, go forward that many blocks.
1747 If NUM is negative, go backwards.
1748 A block is a subroutine, if-endif, etc."
1749   (interactive "p")
1750   (let ((case-fold-search t)
1751         (count (if num (abs num) 1)))
1752     (while (and (> count 0)
1753                 (if (> num 0) (re-search-forward f90-blocks-re nil 'move)
1754                   (re-search-backward f90-blocks-re nil 'move)))
1755       (beginning-of-line)
1756       (skip-chars-forward " \t0-9")
1757       (cond ((or (f90-in-string) (f90-in-comment)))
1758             ((or
1759               (looking-at "end[ \t]*")
1760               (f90-looking-at-do)
1761               (f90-looking-at-select-case)
1762               (f90-looking-at-type-like)
1763               (f90-looking-at-associate)
1764               (f90-looking-at-critical)
1765               (f90-looking-at-program-block-start)
1766               (f90-looking-at-if-then)
1767               (f90-looking-at-where-or-forall))
1768              (setq count (1- count))))
1769       (if (> num 0) (end-of-line)
1770         (beginning-of-line)))))
1771
1772
1773 (defun f90-previous-block (&optional num)
1774   "Move point backward to the previous end or start of a code block.
1775 With optional argument NUM, go backward that many blocks.
1776 If NUM is negative, go forwards.
1777 A block is a subroutine, if-endif, etc."
1778   (interactive "p")
1779   (f90-next-block (- (or num 1))))
1780
1781
1782 (defun f90-mark-subprogram ()
1783   "Put mark at end of F90 subprogram, point at beginning, push mark."
1784   (interactive)
1785   (let ((pos (point)) program)
1786     (f90-end-of-subprogram)
1787     (push-mark)
1788     (goto-char pos)
1789     (setq program (f90-beginning-of-subprogram))
1790     (if (featurep 'xemacs)
1791         (zmacs-activate-region)
1792       (setq mark-active t
1793             deactivate-mark nil))
1794     program))
1795
1796 (defun f90-comment-region (beg-region end-region)
1797   "Comment/uncomment every line in the region.
1798 Insert the variable `f90-comment-region' at the start of every line
1799 in the region, or, if already present, remove it."
1800   (interactive "*r")
1801   (let ((end (copy-marker end-region)))
1802     (goto-char beg-region)
1803     (beginning-of-line)
1804     (if (looking-at (regexp-quote f90-comment-region))
1805         (delete-region (point) (match-end 0))
1806       (insert f90-comment-region))
1807     (while (and (zerop (forward-line 1))
1808                 (< (point) end))
1809       (if (looking-at (regexp-quote f90-comment-region))
1810           (delete-region (point) (match-end 0))
1811         (insert f90-comment-region)))
1812     (set-marker end nil)))
1813
1814 (defun f90-indent-line (&optional no-update)
1815   "Indent current line as F90 code.
1816 Unless optional argument NO-UPDATE is non-nil, call `f90-update-line'
1817 after indenting."
1818   (interactive "*P")
1819   (let ((case-fold-search t)
1820         (pos (point-marker))
1821         indent no-line-number)
1822     (beginning-of-line)           ; digits after & \n are not line-nos
1823     (if (not (save-excursion (and (f90-previous-statement)
1824                                   (f90-line-continued))))
1825         (f90-indent-line-no)
1826       (setq no-line-number t)
1827       (skip-chars-forward " \t"))
1828     (if (looking-at "!")
1829         (setq indent (f90-comment-indent))
1830       (and f90-smart-end (looking-at "end")
1831            (f90-match-end))
1832       (setq indent (f90-calculate-indent)))
1833     (or (= indent (current-column))
1834         (f90-indent-to indent no-line-number))
1835     ;; If initial point was within line's indentation,
1836     ;; position after the indentation.  Else stay at same point in text.
1837     (and (< (point) pos)
1838          (goto-char pos))
1839     (if auto-fill-function
1840         ;; GM NO-UPDATE not honored, since this calls f90-update-line.
1841         (f90-do-auto-fill)
1842       (or no-update (f90-update-line)))
1843     (set-marker pos nil)))
1844
1845 (defun f90-indent-new-line ()
1846   "Re-indent current line, insert a newline and indent the newline.
1847 An abbrev before point is expanded if the variable `abbrev-mode' is non-nil.
1848 If run in the middle of a line, the line is not broken."
1849   (interactive "*")
1850   (if abbrev-mode (expand-abbrev))
1851   (beginning-of-line)             ; reindent where likely to be needed
1852   (f90-indent-line)                ; calls indent-line-no, update-line
1853   (end-of-line)
1854   (delete-horizontal-space)             ; destroy trailing whitespace
1855   (let ((string (f90-in-string))
1856         (cont (f90-line-continued)))
1857     (and string (not cont) (insert "&"))
1858     (newline)
1859     (if (or string (and cont f90-beginning-ampersand)) (insert "&")))
1860   (f90-indent-line 'no-update))         ; nothing to update
1861
1862
1863 ;; TODO not add spaces to empty lines at the start.
1864 ;; Why is second line getting extra indent over first?
1865 (defun f90-indent-region (beg-region end-region)
1866   "Indent every line in region by forward parsing."
1867   (interactive "*r")
1868   (let ((end-region-mark (copy-marker end-region))
1869         (save-point (point-marker))
1870         (case-fold-search t)
1871         block-list ind-lev ind-curr ind-b cont struct beg-struct end-struct)
1872     (goto-char beg-region)
1873     ;; First find a line which is not a continuation line or comment.
1874     (beginning-of-line)
1875     (while (and (looking-at "[ \t]*[0-9]*\\(!\\|#\\|[ \t]*$\\)")
1876                 (progn (f90-indent-line 'no-update)
1877                        (zerop (forward-line 1)))
1878                 (< (point) end-region-mark)))
1879     (setq cont (f90-present-statement-cont))
1880     (while (and (memq cont '(middle end))
1881                 (f90-previous-statement))
1882       (setq cont (f90-present-statement-cont)))
1883     ;; Process present line for beginning of block.
1884     (setq f90-cache-position (point))
1885     (f90-indent-line 'no-update)
1886     (setq ind-lev (f90-current-indentation)
1887           ind-curr ind-lev)
1888     (beginning-of-line)
1889     (skip-chars-forward " \t0-9")
1890     (setq struct nil
1891           ind-b (cond ((setq struct (f90-looking-at-do)) f90-do-indent)
1892                       ((or (setq struct (f90-looking-at-if-then))
1893                            (setq struct (f90-looking-at-select-case))
1894                            (setq struct (f90-looking-at-where-or-forall))
1895                            (looking-at f90-else-like-re))
1896                        f90-if-indent)
1897                       ((setq struct (f90-looking-at-type-like))
1898                        f90-type-indent)
1899                       ((setq struct (f90-looking-at-associate))
1900                        f90-associate-indent)
1901                       ((setq struct (f90-looking-at-critical))
1902                        f90-critical-indent)
1903                       ((or (setq struct (f90-looking-at-program-block-start))
1904                            (looking-at "contains[ \t]*\\($\\|!\\)"))
1905                        f90-program-indent)))
1906     (if ind-b (setq ind-lev (+ ind-lev ind-b)))
1907     (if struct (setq block-list (cons struct block-list)))
1908     (while (and (f90-line-continued) (zerop (forward-line 1))
1909                 (< (point) end-region-mark))
1910       (if (looking-at "[ \t]*!")
1911           (f90-indent-to (f90-comment-indent))
1912         (or (= (current-indentation)
1913                (+ ind-curr f90-continuation-indent))
1914             (f90-indent-to (+ ind-curr f90-continuation-indent) 'no-line-no))))
1915     ;; Process all following lines.
1916     (while (and (zerop (forward-line 1)) (< (point) end-region-mark))
1917       (beginning-of-line)
1918       (f90-indent-line-no)
1919       (setq f90-cache-position (point))
1920       (cond ((looking-at "[ \t]*$") (setq ind-curr 0))
1921             ((looking-at "[ \t]*#") (setq ind-curr 0))
1922             ((looking-at "!") (setq ind-curr (f90-comment-indent)))
1923             ((f90-no-block-limit) (setq ind-curr ind-lev))
1924             ((looking-at f90-else-like-re) (setq ind-curr
1925                                                  (- ind-lev f90-if-indent)))
1926             ((looking-at "contains[ \t]*\\($\\|!\\)")
1927              (setq ind-curr (- ind-lev f90-program-indent)))
1928             ((setq ind-b
1929                    (cond ((setq struct (f90-looking-at-do)) f90-do-indent)
1930                          ((or (setq struct (f90-looking-at-if-then))
1931                               (setq struct (f90-looking-at-select-case))
1932                               (setq struct (f90-looking-at-where-or-forall)))
1933                           f90-if-indent)
1934                          ((setq struct (f90-looking-at-type-like))
1935                           f90-type-indent)
1936                          ((setq struct (f90-looking-at-associate))
1937                           f90-associate-indent)
1938                          ((setq struct (f90-looking-at-critical))
1939                           f90-critical-indent)
1940                          ((setq struct (f90-looking-at-program-block-start))
1941                           f90-program-indent)))
1942              (setq ind-curr ind-lev)
1943              (if ind-b (setq ind-lev (+ ind-lev ind-b)))
1944              (setq block-list (cons struct block-list)))
1945             ((setq end-struct (f90-looking-at-program-block-end))
1946              (setq beg-struct (car block-list)
1947                    block-list (cdr block-list))
1948              (if f90-smart-end
1949                  (save-excursion
1950                    (f90-block-match (car beg-struct) (cadr beg-struct)
1951                                     (car end-struct) (cadr end-struct))))
1952              (setq ind-b
1953                    (cond ((looking-at f90-end-if-re) f90-if-indent)
1954                          ((looking-at "end[ \t]*do\\>")  f90-do-indent)
1955                          ((looking-at f90-end-type-re) f90-type-indent)
1956                          ((looking-at f90-end-associate-re)
1957                           f90-associate-indent)
1958                          ((f90-looking-at-end-critical) f90-critical-indent)
1959                          ((f90-looking-at-program-block-end)
1960                           f90-program-indent)))
1961              (if ind-b (setq ind-lev (- ind-lev ind-b)))
1962              (setq ind-curr ind-lev))
1963             (t (setq ind-curr ind-lev)))
1964       ;; Do the indentation if necessary.
1965       (or (= ind-curr (current-column))
1966           (f90-indent-to ind-curr))
1967       (while (and (f90-line-continued) (zerop (forward-line 1))
1968                   (< (point) end-region-mark))
1969         (if (looking-at "[ \t]*!")
1970             (f90-indent-to (f90-comment-indent))
1971           (or (= (current-indentation)
1972                  (+ ind-curr f90-continuation-indent))
1973               (f90-indent-to
1974                (+ ind-curr f90-continuation-indent) 'no-line-no)))))
1975     ;; Restore point, etc.
1976     (setq f90-cache-position nil)
1977     (goto-char save-point)
1978     (set-marker end-region-mark nil)
1979     (set-marker save-point nil)
1980     (if (featurep 'xemacs)
1981         (zmacs-deactivate-region)
1982       (deactivate-mark))))
1983
1984 (defun f90-indent-subprogram ()
1985   "Properly indent the subprogram containing point."
1986   (interactive "*")
1987   (save-excursion
1988     (let ((program (f90-mark-subprogram)))
1989       (if program
1990           (progn
1991             (message "Indenting %s %s..."
1992                      (car program) (cadr program))
1993             (indent-region (point) (mark) nil)
1994             (message "Indenting %s %s...done"
1995                      (car program) (cadr program)))
1996         (message "Indenting the whole file...")
1997         (indent-region (point) (mark) nil)
1998         (message "Indenting the whole file...done")))))
1999
2000 (defun f90-break-line (&optional no-update)
2001   "Break line at point, insert continuation marker(s) and indent.
2002 Unless in a string or comment, or if the optional argument NO-UPDATE
2003 is non-nil, call `f90-update-line' after inserting the continuation marker."
2004   (interactive "*P")
2005   (cond ((f90-in-string)
2006          (insert "&\n&"))
2007         ((f90-in-comment)
2008          (delete-horizontal-space) ; remove trailing whitespace
2009          (insert "\n" (f90-get-present-comment-type)))
2010         (t (insert "&")
2011            (or no-update (f90-update-line))
2012            (newline 1)
2013            ;; FIXME also need leading ampersand if split lexical token (eg ==).
2014            ;; Or respect f90-no-break-re.
2015            (if f90-beginning-ampersand (insert "&"))))
2016   (indent-according-to-mode))
2017
2018 (defun f90-find-breakpoint ()
2019   "From `fill-column', search backward for break-delimiter."
2020   ;; Commented text more likely than commented code.
2021   (if (f90-in-comment)
2022       (re-search-backward "\\s-" (line-beginning-position))
2023     (re-search-backward f90-break-delimiters (line-beginning-position))
2024     (if (not f90-break-before-delimiters)
2025         (forward-char (if (looking-at f90-no-break-re) 2 1))
2026       (backward-char)
2027       (or (looking-at f90-no-break-re)
2028         (forward-char)))))
2029
2030 (defun f90-do-auto-fill ()
2031   "Break line if non-white characters beyond `fill-column'.
2032 Update keyword case first."
2033   (interactive "*")
2034   ;; Break line before or after last delimiter (non-word char) if
2035   ;; position is beyond fill-column.
2036   ;; Will not break **, //, or => (as specified by f90-no-break-re).
2037   (f90-update-line)
2038   ;; Need this for `f90-electric-insert' and other f90- callers.
2039   (unless (and (boundp 'comment-auto-fill-only-comments)
2040                comment-auto-fill-only-comments
2041                (not (f90-in-comment)))
2042     (while (> (current-column) fill-column)
2043       (let ((pos-mark (point-marker)))
2044         (move-to-column fill-column)
2045         (or (f90-in-string) (f90-find-breakpoint))
2046         (f90-break-line)
2047         (goto-char pos-mark)
2048         (set-marker pos-mark nil)))))
2049
2050 (defun f90-join-lines (&optional arg)
2051   "Join current line to previous, fix whitespace, continuation, comments.
2052 With optional argument ARG, join current line to following line.
2053 Like `join-line', but handles F90 syntax."
2054   (interactive "*P")
2055   (beginning-of-line)
2056   (if arg (forward-line 1))
2057   (when (eq (preceding-char) ?\n)
2058     (skip-chars-forward " \t")
2059     (if (looking-at "\&") (delete-char 1))
2060     (beginning-of-line)
2061     (delete-region (point) (1- (point)))
2062     (skip-chars-backward " \t")
2063     (and (eq (preceding-char) ?&) (delete-char -1))
2064     (and (f90-in-comment)
2065          (looking-at "[ \t]*!+")
2066          (replace-match ""))
2067     (or (f90-in-string)
2068         (fixup-whitespace))))
2069
2070 (defun f90-fill-region (beg-region end-region)
2071   "Fill every line in region by forward parsing.  Join lines if possible."
2072   (interactive "*r")
2073   (let ((end-region-mark (copy-marker end-region))
2074         (go-on t)
2075         f90-smart-end f90-auto-keyword-case auto-fill-function)
2076     (goto-char beg-region)
2077     (while go-on
2078       ;; Join as much as possible.
2079       (while (progn
2080                (end-of-line)
2081                (skip-chars-backward " \t")
2082                (eq (preceding-char) ?&))
2083         (f90-join-lines 'forward))
2084       ;; Chop the line if necessary.
2085       (while (> (save-excursion (end-of-line) (current-column))
2086                 fill-column)
2087         (move-to-column fill-column)
2088         (f90-find-breakpoint)
2089         (f90-break-line 'no-update))
2090       (setq go-on (and (< (point) end-region-mark)
2091                        (zerop (forward-line 1)))
2092             f90-cache-position (point)))
2093     (setq f90-cache-position nil)
2094     (set-marker end-region-mark nil)
2095     (if (featurep 'xemacs)
2096         (zmacs-deactivate-region)
2097       (deactivate-mark))))
2098 \f
2099 (defun f90-block-match (beg-block beg-name end-block end-name)
2100   "Match end-struct with beg-struct and complete end-block if possible.
2101 BEG-BLOCK is the type of block as indicated at the start (e.g., do).
2102 BEG-NAME is the block start name (may be nil).
2103 END-BLOCK is the type of block as indicated at the end (may be nil).
2104 END-NAME is the block end name (may be nil).
2105 Leave point at the end of line."
2106   ;; Hack to deal with the case when this is called from
2107   ;; f90-indent-region on a program block without an explicit PROGRAM
2108   ;; statement at the start. Should really be an error (?).
2109   (or beg-block (setq beg-block "program"))
2110   (search-forward "end" (line-end-position))
2111   (catch 'no-match
2112     (if (and end-block (f90-equal-symbols beg-block end-block))
2113         (search-forward end-block)
2114       (if end-block
2115           (progn
2116             (message "END %s does not match %s." end-block beg-block)
2117             (end-of-line)
2118             (throw 'no-match nil))
2119         (message "Inserting %s." beg-block)
2120         (insert (concat " " beg-block))))
2121     (if (f90-equal-symbols beg-name end-name)
2122         (and end-name (search-forward end-name))
2123       (cond ((and beg-name (not end-name))
2124              (message "Inserting %s." beg-name)
2125              (insert (concat " " beg-name)))
2126             ((and beg-name end-name)
2127              (message "Replacing %s with %s." end-name beg-name)
2128              (search-forward end-name)
2129              (replace-match beg-name))
2130             ((and (not beg-name) end-name)
2131              (message "Deleting %s." end-name)
2132              (search-forward end-name)
2133              (replace-match ""))))
2134     (or (looking-at "[ \t]*!") (delete-horizontal-space))))
2135
2136 (defun f90-match-end ()
2137   "From an end block statement, find the corresponding block and name."
2138   (interactive)
2139   (let ((count 1)
2140         (top-of-window (window-start))
2141         (end-point (point))
2142         (case-fold-search t)
2143         matching-beg beg-name end-name beg-block end-block end-struct)
2144     (when (save-excursion (beginning-of-line) (skip-chars-forward " \t0-9")
2145                           (setq end-struct (f90-looking-at-program-block-end)))
2146       (setq end-block (car end-struct)
2147             end-name  (cadr end-struct))
2148       (save-excursion
2149         (beginning-of-line)
2150         (while (and (> count 0)
2151                     (not (= (line-beginning-position) (point-min))))
2152           (re-search-backward f90-blocks-re nil 'move)
2153           (beginning-of-line)
2154           ;; GM not a line number if continued line.
2155 ;;;          (skip-chars-forward " \t")
2156 ;;;          (skip-chars-forward "0-9")
2157           (skip-chars-forward " \t0-9")
2158           (cond ((or (f90-in-string) (f90-in-comment)))
2159                 ((setq matching-beg
2160                        (or
2161                         (f90-looking-at-do)
2162                         (f90-looking-at-if-then)
2163                         (f90-looking-at-where-or-forall)
2164                         (f90-looking-at-select-case)
2165                         (f90-looking-at-type-like)
2166                         (f90-looking-at-associate)
2167                         (f90-looking-at-critical)
2168                         (f90-looking-at-program-block-start)
2169                         ;; Interpret a single END without a block
2170                         ;; start to be the END of a program block
2171                         ;; without an initial PROGRAM line.
2172                         (if (= (line-beginning-position) (point-min))
2173                             '("program" nil))))
2174                  (setq count (1- count)))
2175                 ((looking-at (concat "end[ \t]*" f90-blocks-re))
2176                  (setq count (1+ count)))))
2177         (if (> count 0)
2178             (message "No matching beginning.")
2179           (f90-update-line)
2180           (if (eq f90-smart-end 'blink)
2181               (if (< (point) top-of-window)
2182                   (message "Matches %s: %s"
2183                            (what-line)
2184                            (buffer-substring
2185                             (line-beginning-position)
2186                             (line-end-position)))
2187                 (sit-for blink-matching-delay)))
2188           (setq beg-block (car matching-beg)
2189                 beg-name (cadr matching-beg))
2190           (goto-char end-point)
2191           (beginning-of-line)
2192           (f90-block-match beg-block beg-name end-block end-name))))))
2193
2194 (defun f90-insert-end ()
2195   "Insert a complete end statement matching beginning of present block."
2196   (interactive "*")
2197   (let ((f90-smart-end (or f90-smart-end 'blink)))
2198     (insert "end")
2199     (f90-indent-new-line)))
2200 \f
2201 ;; Abbrevs and keywords.
2202
2203 (defun f90-abbrev-start ()
2204   "Typing `\\[help-command] or `? lists all the F90 abbrevs.
2205 Any other key combination is executed normally."
2206   (interactive "*")
2207   (insert last-command-event)
2208   (let (char event)
2209     (if (fboundp 'next-command-event) ; XEmacs
2210         (setq event (next-command-event)
2211               char (and (fboundp 'event-to-character)
2212                         (event-to-character event)))
2213       (setq event (read-event)
2214             char event))
2215     ;; Insert char if not equal to `?', or if abbrev-mode is off.
2216     (if (and abbrev-mode (memq char (list ?? help-char)))
2217         (f90-abbrev-help)
2218       (setq unread-command-events (list event)))))
2219
2220 (defun f90-abbrev-help ()
2221   "List the currently defined abbrevs in F90 mode."
2222   (interactive)
2223   (message "Listing abbrev table...")
2224   (display-buffer (f90-prepare-abbrev-list-buffer))
2225   (message "Listing abbrev table...done"))
2226
2227 (defun f90-prepare-abbrev-list-buffer ()
2228   "Create a buffer listing the F90 mode abbreviations."
2229   (with-current-buffer (get-buffer-create "*Abbrevs*")
2230     (erase-buffer)
2231     (insert-abbrev-table-description 'f90-mode-abbrev-table t)
2232     (goto-char (point-min))
2233     (set-buffer-modified-p nil)
2234     (edit-abbrevs-mode))
2235   (get-buffer-create "*Abbrevs*"))
2236
2237 (defun f90-upcase-keywords ()
2238   "Upcase all F90 keywords in the buffer."
2239   (interactive "*")
2240   (f90-change-keywords 'upcase-word))
2241
2242 (defun f90-capitalize-keywords ()
2243   "Capitalize all F90 keywords in the buffer."
2244   (interactive "*")
2245   (f90-change-keywords 'capitalize-word))
2246
2247 (defun f90-downcase-keywords ()
2248   "Downcase all F90 keywords in the buffer."
2249   (interactive "*")
2250   (f90-change-keywords 'downcase-word))
2251
2252 (defun f90-upcase-region-keywords (beg end)
2253   "Upcase all F90 keywords in the region."
2254   (interactive "*r")
2255   (f90-change-keywords 'upcase-word beg end))
2256
2257 (defun f90-capitalize-region-keywords (beg end)
2258   "Capitalize all F90 keywords in the region."
2259   (interactive "*r")
2260   (f90-change-keywords 'capitalize-word beg end))
2261
2262 (defun f90-downcase-region-keywords (beg end)
2263   "Downcase all F90 keywords in the region."
2264   (interactive "*r")
2265   (f90-change-keywords 'downcase-word beg end))
2266
2267 ;; Change the keywords according to argument.
2268 (defun f90-change-keywords (change-word &optional beg end)
2269   "Change the case of F90 keywords in the region (if specified) or buffer.
2270 CHANGE-WORD should be one of 'upcase-word, 'downcase-word, 'capitalize-word."
2271   (save-excursion
2272     (setq beg (or beg (point-min))
2273           end (or end (point-max)))
2274     (let ((keyword-re
2275            (concat "\\("
2276                    f90-keywords-re "\\|" f90-procedures-re "\\|"
2277                    f90-hpf-keywords-re "\\|" f90-operators-re "\\)"))
2278           (ref-point (point-min))
2279           (modified (buffer-modified-p))
2280           state saveword back-point)
2281       (goto-char beg)
2282       (unwind-protect
2283           (while (re-search-forward keyword-re end t)
2284             (unless (progn
2285                       (setq state (parse-partial-sexp ref-point (point)))
2286                       (or (nth 3 state) (nth 4 state)
2287                           ;; GM f90-directive-comment-re?
2288                           (save-excursion ; check for cpp directive
2289                             (beginning-of-line)
2290                             (skip-chars-forward " \t0-9")
2291                             (looking-at "#"))))
2292               (setq ref-point (point)
2293                     back-point (save-excursion (backward-word 1) (point))
2294                     saveword (buffer-substring back-point ref-point))
2295               (funcall change-word -1)
2296               (or (string= saveword (buffer-substring back-point ref-point))
2297                   (setq modified t))))
2298         (or modified (restore-buffer-modified-p nil))))))
2299
2300
2301 (defun f90-current-defun ()
2302   "Function to use for `add-log-current-defun-function' in F90 mode."
2303   (save-excursion
2304     (nth 1 (f90-beginning-of-subprogram))))
2305
2306 (defun f90-backslash-not-special (&optional all)
2307   "Make the backslash character (\\) be non-special in the current buffer.
2308 With optional argument ALL, change the default for all present
2309 and future F90 buffers.  F90 mode normally treats backslash as an
2310 escape character."
2311   (or (derived-mode-p 'f90-mode)
2312       (error "This function should only be used in F90 buffers"))
2313   (when (equal (char-syntax ?\\ ) ?\\ )
2314     (or all (set-syntax-table (copy-syntax-table (syntax-table))))
2315     (modify-syntax-entry ?\\ ".")))
2316
2317
2318 (provide 'f90)
2319
2320 ;; Local Variables:
2321 ;; coding: utf-8
2322 ;; End:
2323
2324 ;;; f90.el ends here