lisp/url/url-cookie.el

   1 ;;; url-cookie.el --- URL cookie support  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1996-1999, 2004-2017 Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'url-util)
  27 (require 'url-parse)
  28 (require 'url-domsuf)
  29
  30 (eval-when-compile (require 'cl-lib))
  31
  32 (defgroup url-cookie nil
  33   "URL cookies."
  34   :prefix "url-"
  35   :prefix "url-cookie-"
  36   :group 'url)
  37
  38 ;; A cookie is stored internally as a vector of 7 slots
  39 ;; [ url-cookie NAME VALUE EXPIRES LOCALPART DOMAIN SECURE ]
  40
  41 (cl-defstruct (url-cookie
  42             (:constructor url-cookie-create)
  43             (:copier nil)
  44             (:type vector)
  45             :named)
  46   name value expires localpart domain secure)
  47
  48 (defvar url-cookie-storage nil         "Where cookies are stored.")
  49 (defvar url-cookie-secure-storage nil  "Where secure cookies are stored.")
  50 (defcustom url-cookie-file nil
  51   "File where cookies are stored on disk."
  52   :type '(choice (const :tag "Default" :value nil) file)
  53   :group 'url-file
  54   :group 'url-cookie)
  55
  56 (defcustom url-cookie-confirmation nil
  57   "If non-nil, confirmation by the user is required to accept HTTP cookies."
  58   :type 'boolean
  59   :group 'url-cookie)
  60
  61 (defcustom url-cookie-multiple-line nil
  62   "If nil, HTTP requests put all cookies for the server on one line.
  63 Some web servers, such as http://www.hotmail.com/, only accept cookies
  64 when they are on one line.  This is broken behavior, but just try
  65 telling Microsoft that."
  66   :type 'boolean
  67   :group 'url-cookie)
  68
  69 (defvar url-cookies-changed-since-last-save nil
  70   "Whether the cookies list has changed since the last save operation.")
  71
  72 (defun url-cookie-parse-file (&optional fname)
  73   "Load FNAME, default `url-cookie-file'."
  74   ;; It's completely normal for the cookies file not to exist yet.
  75   (load (or fname url-cookie-file) t t))
  76
  77 (defun url-cookie-clean-up (&optional secure)
  78   (let ((var (if secure 'url-cookie-secure-storage 'url-cookie-storage))
  79         new new-cookies)
  80     (dolist (cur (symbol-value var))
  81       (setq new-cookies nil)
  82       (dolist (cur-cookie (cdr cur))
  83         (or (not (url-cookie-p cur-cookie))
  84             (url-cookie-expired-p cur-cookie)
  85             (null (url-cookie-expires cur-cookie))
  86             (setq new-cookies (cons cur-cookie new-cookies))))
  87       (when new-cookies
  88         (setcdr cur new-cookies)
  89         (setq new (cons cur new))))
  90     (set var new)))
  91
  92 (defun url-cookie-write-file (&optional fname)
  93   (when url-cookies-changed-since-last-save
  94     (or fname (setq fname (expand-file-name url-cookie-file)))
  95     (if (condition-case nil
  96             (progn
  97               (url-make-private-file fname)
  98               nil)
  99           (error t))
 100         (message "Error accessing cookie file `%s'" fname)
 101     (url-cookie-clean-up)
 102     (url-cookie-clean-up t)
 103     (with-temp-buffer
 104       (insert ";; Emacs-W3 HTTP cookies file\n"
 105               ";; Automatically generated file!!! DO NOT EDIT!!!\n\n"
 106               "(setq url-cookie-storage\n '")
 107       (let ((print-length nil) (print-level nil))
 108         (pp url-cookie-storage (current-buffer))
 109         (insert ")\n(setq url-cookie-secure-storage\n '")
 110         (pp url-cookie-secure-storage (current-buffer)))
 111       (insert ")\n")
 112       (insert "\f\n;; Local Variables:\n"
 113               ";; version-control: never\n"
 114               ";; no-byte-compile: t\n"
 115               ";; End:\n")
 116       (set (make-local-variable 'version-control) 'never)
 117       (write-file fname))
 118     (setq url-cookies-changed-since-last-save nil))))
 119
 120 (defun url-cookie-store (name value &optional expires domain localpart secure)
 121   "Store a cookie."
 122   (when (> (length name) 0)
 123     (let ((storage (if secure url-cookie-secure-storage url-cookie-storage))
 124           tmp found-domain)
 125       ;; First, look for a matching domain.
 126       (if (setq found-domain (assoc domain storage))
 127           ;; Need to either stick the new cookie in existing domain storage
 128           ;; or possibly replace an existing cookie if the names match.
 129           (unless (dolist (cur (setq storage (cdr found-domain)) tmp)
 130                     (and (equal localpart (url-cookie-localpart cur))
 131                          (equal name (url-cookie-name cur))
 132                          (progn
 133                            (setf (url-cookie-expires cur) expires)
 134                            (setf (url-cookie-value cur) value)
 135                            (setq tmp t))))
 136             ;; New cookie.
 137             (setcdr found-domain (cons
 138                                   (url-cookie-create :name name
 139                                                      :value value
 140                                                      :expires expires
 141                                                      :domain domain
 142                                                      :localpart localpart
 143                                                      :secure secure)
 144                                   (cdr found-domain))))
 145         ;; Need to add a new top-level domain.
 146         (setq tmp (url-cookie-create :name name
 147                                      :value value
 148                                      :expires expires
 149                                      :domain domain
 150                                      :localpart localpart
 151                                      :secure secure))
 152         (cond (storage
 153                (setcdr storage (cons (list domain tmp) (cdr storage))))
 154               (secure
 155                (setq url-cookie-secure-storage (list (list domain tmp))))
 156               (t
 157                (setq url-cookie-storage (list (list domain tmp)))))))))
 158
 159 (defun url-cookie-expired-p (cookie)
 160   "Return non-nil if COOKIE is expired."
 161   (let ((exp (url-cookie-expires cookie)))
 162     (and (> (length exp) 0)
 163          (condition-case ()
 164              (> (float-time) (float-time (date-to-time exp)))
 165            (error nil)))))
 166
 167 (defun url-cookie-retrieve (host &optional localpart secure)
 168   "Retrieve all cookies for a specified HOST and LOCALPART."
 169   (let ((storage (if secure
 170                      (append url-cookie-secure-storage url-cookie-storage)
 171                    url-cookie-storage))
 172         (case-fold-search t)
 173         cookies retval localpart-match)
 174     (dolist (cur storage)
 175       (setq cookies (cdr cur))
 176       (if (and (car cur)
 177                (string-match
 178                 (concat "^.*"
 179                         (regexp-quote
 180                          ;; Remove the dot from wildcard domains
 181                          ;; before matching.
 182                          (if (eq ?. (aref (car cur) 0))
 183                              (substring (car cur) 1)
 184                            (car cur)))
 185                         "$") host))
 186           ;; The domains match - a possible hit!
 187           (dolist (cur cookies)
 188             (and (if (and (stringp
 189                            (setq localpart-match (url-cookie-localpart cur)))
 190                           (stringp localpart))
 191                      (string-match (concat "^" (regexp-quote localpart-match))
 192                                    localpart)
 193                    (equal localpart localpart-match))
 194                  (not (url-cookie-expired-p cur))
 195                  (setq retval (cons cur retval))))))
 196     retval))
 197
 198 (defun url-cookie-generate-header-lines (host localpart secure)
 199   (let ((cookies (url-cookie-retrieve host localpart secure))
 200         retval chunk)
 201     ;; Have to sort this for sending most specific cookies first.
 202     (setq cookies (and cookies
 203                        (sort cookies
 204                              (lambda (x y)
 205                                (> (length (url-cookie-localpart x))
 206                                   (length (url-cookie-localpart y)))))))
 207     (dolist (cur cookies)
 208       (setq chunk (format "%s=%s" (url-cookie-name cur) (url-cookie-value cur))
 209             retval (if (and url-cookie-multiple-line
 210                             (< 80 (+ (length retval) (length chunk) 4)))
 211                        (concat retval "\r\nCookie: " chunk)
 212                      (if retval
 213                          (concat retval "; " chunk)
 214                        (concat "Cookie: " chunk)))))
 215     (if retval
 216         (concat retval "\r\n")
 217       "")))
 218
 219 (defcustom url-cookie-trusted-urls nil
 220   "A list of regular expressions matching URLs to always accept cookies from."
 221   :type '(repeat regexp)
 222   :group 'url-cookie)
 223
 224 (defcustom url-cookie-untrusted-urls nil
 225   "A list of regular expressions matching URLs to never accept cookies from."
 226   :type '(repeat regexp)
 227   :group 'url-cookie)
 228
 229 (defun url-cookie-host-can-set-p (host domain)
 230   (cond
 231    ((string= host domain)       ; Apparently netscape lets you do this
 232     t)
 233    ((zerop (length domain))
 234     nil)
 235    (t
 236     ;; Remove the dot from wildcard domains before matching.
 237     (when (eq ?. (aref domain 0))
 238       (setq domain (substring domain 1)))
 239     (and (url-domsuf-cookie-allowed-p domain)
 240          (string-suffix-p domain host 'ignore-case)))))
 241
 242 (defun url-cookie-handle-set-cookie (str)
 243   (setq url-cookies-changed-since-last-save t)
 244   (let* ((args (url-parse-args str t))
 245          (case-fold-search t)
 246          (secure (and (assoc-string "secure" args t) t))
 247          (domain (or (cdr-safe (assoc-string "domain" args t))
 248                      (url-host url-current-object)))
 249          (current-url (url-view-url t))
 250          (trusted url-cookie-trusted-urls)
 251          (untrusted url-cookie-untrusted-urls)
 252          (expires (cdr-safe (assoc-string "expires" args t)))
 253          (localpart (or (cdr-safe (assoc-string "path" args t))
 254                         (file-name-directory
 255                          (url-filename url-current-object))))
 256          (rest nil))
 257     (dolist (this args)
 258       (or (member (downcase (car this)) '("secure" "domain" "expires" "path"))
 259           (setq rest (cons this rest))))
 260
 261     ;; Sometimes we get dates that the timezone package cannot handle very
 262     ;; gracefully - take care of this here, instead of in url-cookie-expired-p
 263     ;; to speed things up.
 264     (and expires
 265          (string-match
 266           (concat "^[^,]+, +\\(..\\)-\\(...\\)-\\(..\\) +"
 267                   "\\(..:..:..\\) +\\[*\\([^]]+\\)\\]*$")
 268           expires)
 269          (setq expires (concat (match-string 1 expires) " "
 270                                (match-string 2 expires) " "
 271                                (match-string 3 expires) " "
 272                                (match-string 4 expires) " ["
 273                                (match-string 5 expires) "]")))
 274
 275     ;; This one is for older Emacs/XEmacs variants that don't
 276     ;; understand this format without tenths of a second in it.
 277     ;; Wednesday, 30-Dec-2037 16:00:00 GMT
 278     ;;       - vs -
 279     ;; Wednesday, 30-Dec-2037 16:00:00.00 GMT
 280     (and expires
 281          (string-match
 282           "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)*[ \t]+\\([-+a-zA-Z0-9]+\\)"
 283           expires)
 284          (setq expires (concat (match-string 1 expires) "-"     ; day
 285                                (match-string 2 expires) "-"     ; month
 286                                (match-string 3 expires) " "     ; year
 287                                (match-string 4 expires) ".00 " ; hour:minutes:seconds
 288                                (match-string 6 expires)))) ":" ; timezone
 289
 290     (while (consp trusted)
 291       (if (string-match (car trusted) current-url)
 292           (setq trusted (- (match-end 0) (match-beginning 0)))
 293         (pop trusted)))
 294     (while (consp untrusted)
 295       (if (string-match (car untrusted) current-url)
 296           (setq untrusted (- (match-end 0) (match-beginning 0)))
 297         (pop untrusted)))
 298     (and trusted untrusted
 299          ;; Choose the more specific match.
 300          (set (if (> trusted untrusted) 'untrusted 'trusted) nil))
 301     (cond
 302      (untrusted
 303       ;; The site was explicitly marked as untrusted by the user.
 304       nil)
 305      ((or (eq url-privacy-level 'paranoid)
 306           (and (listp url-privacy-level) (memq 'cookies url-privacy-level)))
 307       ;; User never wants cookies.
 308       nil)
 309      ((and url-cookie-confirmation
 310            (not trusted)
 311            (save-window-excursion
 312              (with-output-to-temp-buffer "*Cookie Warning*"
 313                (dolist (x rest)
 314                  (princ (format "%s - %s" (car x) (cdr x)))))
 315              (prog1
 316                  (not (funcall url-confirmation-func
 317                                (format "Allow %s to set these cookies? "
 318                                        (url-host url-current-object))))
 319                (if (get-buffer "*Cookie Warning*")
 320                    (kill-buffer "*Cookie Warning*")))))
 321       ;; User wants to be asked, and declined.
 322       nil)
 323      ((url-cookie-host-can-set-p (url-host url-current-object) domain)
 324       ;; Cookie is accepted by the user, and passes our security checks.
 325       (dolist (cur rest)
 326         (url-cookie-store (car cur) (cdr cur) expires domain localpart secure)))
 327      (t
 328       (url-lazy-message "%s tried to set a cookie for domain %s - rejected."
 329                         (url-host url-current-object) domain)))))
 330
 331 (defvar url-cookie-timer nil)
 332
 333 (defcustom url-cookie-save-interval 3600
 334   "The number of seconds between automatic saves of cookies.
 335 Default is 1 hour.  Note that if you change this variable outside of
 336 the `customize' interface after `url-do-setup' has been run, you need
 337 to run the `url-cookie-setup-save-timer' function manually."
 338   :set #'(lambda (var val)
 339            (set-default var val)
 340            (if (bound-and-true-p url-setup-done)
 341                (url-cookie-setup-save-timer)))
 342   :type 'integer
 343   :group 'url-cookie)
 344
 345 (defun url-cookie-setup-save-timer ()
 346   "Reset the cookie saver timer."
 347   (interactive)
 348   (ignore-errors (cancel-timer url-cookie-timer))
 349   (setq url-cookie-timer nil)
 350   (if url-cookie-save-interval
 351       (setq url-cookie-timer (run-at-time url-cookie-save-interval
 352                                           url-cookie-save-interval
 353                                           #'url-cookie-write-file))))
 354
 355 (defun url-cookie-delete-cookies (&optional regexp keep)
 356   "Delete all cookies from the cookie store where the domain matches REGEXP.
 357 If REGEXP is nil, all cookies are deleted.  If KEEP is non-nil,
 358 instead delete all cookies that do not match REGEXP."
 359   (dolist (variable '(url-cookie-secure-storage url-cookie-storage))
 360     (let ((cookies (symbol-value variable)))
 361       (dolist (elem cookies)
 362         (when (or (and (null keep)
 363                        (or (null regexp)
 364                            (string-match regexp (car elem))))
 365                   (and keep
 366                        regexp
 367                        (not (string-match regexp (car elem)))))
 368           (setq cookies (delq elem cookies))))
 369       (set variable cookies)))
 370   (setq url-cookies-changed-since-last-save t)
 371   (url-cookie-write-file))
 372
 373 ;;; Mode for listing and editing cookies.
 374
 375 (defun url-cookie-list ()
 376   "Display a buffer listing the current URL cookies, if there are any.
 377 Use \\<url-cookie-mode-map>\\[url-cookie-delete] to remove cookies."
 378   (interactive)
 379   (unless (or url-cookie-secure-storage
 380               url-cookie-storage)
 381     (error "No cookies are defined"))
 382
 383   (pop-to-buffer "*url cookies*")
 384   (let ((inhibit-read-only t)
 385         (domains (sort
 386                   (copy-sequence
 387                    (append url-cookie-secure-storage
 388                            url-cookie-storage))
 389                   (lambda (e1 e2)
 390                     (string< (car e1) (car e2)))))
 391         (domain-length 0)
 392         start name format domain)
 393     (erase-buffer)
 394     (url-cookie-mode)
 395     (dolist (elem domains)
 396       (setq domain-length (max domain-length (length (car elem)))))
 397     (setq format (format "%%-%ds %%-20s %%s" domain-length)
 398           header-line-format
 399           (concat " " (format format "Domain" "Name" "Value")))
 400     (dolist (elem domains)
 401       (setq domain (car elem))
 402       (dolist (cookie (sort (copy-sequence (cdr elem))
 403                             (lambda (c1 c2)
 404                               (string< (url-cookie-name c1)
 405                                        (url-cookie-name c2)))))
 406         (setq start (point)
 407               name (url-cookie-name cookie))
 408         (when (> (length name) 20)
 409           (setq name (substring name 0 20)))
 410         (insert (format format domain name
 411                         (url-cookie-value cookie))
 412                 "\n")
 413         (setq domain "")
 414         (put-text-property start (1+ start) 'url-cookie cookie)))
 415     (goto-char (point-min))))
 416
 417 (defun url-cookie-delete ()
 418   "Delete the cookie on the current line."
 419   (interactive)
 420   (let ((cookie (get-text-property (line-beginning-position) 'url-cookie))
 421         (inhibit-read-only t)
 422         variable)
 423     (unless cookie
 424       (error "No cookie on the current line"))
 425     (setq variable (if (url-cookie-secure cookie)
 426                        'url-cookie-secure-storage
 427                      'url-cookie-storage))
 428     (let* ((list (symbol-value variable))
 429            (elem (assoc (url-cookie-domain cookie) list)))
 430       (setq elem (delq cookie elem))
 431       (when (zerop (length (cdr elem)))
 432         (setq list (delq elem list)))
 433       (set variable list))
 434     (setq url-cookies-changed-since-last-save t)
 435     (url-cookie-write-file)
 436     (delete-region (line-beginning-position)
 437                    (progn
 438                      (forward-line 1)
 439                      (point)))))
 440
 441 (defvar url-cookie-mode-map
 442   (let ((map (make-sparse-keymap)))
 443     (define-key map [delete] 'url-cookie-delete)
 444     (define-key map [(control k)] 'url-cookie-delete)
 445     map))
 446
 447 (define-derived-mode url-cookie-mode special-mode "URL Cookie"
 448   "Mode for listing cookies.
 449
 450 \\{url-cookie-mode-map}"
 451   (buffer-disable-undo)
 452   (setq buffer-read-only t
 453         truncate-lines t))
 454
 455 (provide 'url-cookie)
 456
 457 ;;; url-cookie.el ends here