lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992-1996, 1998-2012  Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'cl))
  30
  31 (declare-function xw-defined-colors "term/common-win" (&optional frame))
  32
  33 (defvar help-xref-stack-item)
  34
  35 (defvar face-name-history nil
  36   "History list for some commands that read face names.
  37 Maximum length of the history list is determined by the value
  38 of `history-length', which see.")
  39
  40 \f
  41 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  42 ;;; Font selection.
  43 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  44
  45 (defgroup font-selection nil
  46   "Influencing face font selection."
  47   :group 'faces)
  48
  49
  50 (defcustom face-font-selection-order
  51   '(:width :height :weight :slant)
  52   "A list specifying how face font selection chooses fonts.
  53 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  54 must appear once in the list, and the list must not contain any other
  55 elements.  Font selection first tries to find a best matching font
  56 for those face attributes that appear before in the list.  For
  57 example, if `:slant' appears before `:height', font selection first
  58 tries to find a font with a suitable slant, even if this results in
  59 a font height that isn't optimal."
  60   :tag "Font selection order"
  61   :type '(list symbol symbol symbol symbol)
  62   :group 'font-selection
  63   :set #'(lambda (symbol value)
  64            (set-default symbol value)
  65            (internal-set-font-selection-order value)))
  66
  67
  68 ;; In the absence of Fontconfig support, Monospace and Sans Serif are
  69 ;; unavailable, and we fall back on the courier and helv families,
  70 ;; which are generally available.
  71 (defcustom face-font-family-alternatives
  72   (mapcar (lambda (arg) (mapcar 'purecopy arg))
  73   '(("Monospace" "courier" "fixed")
  74     ("courier" "CMU Typewriter Text" "fixed")
  75     ("Sans Serif" "helv" "helvetica" "arial" "fixed")
  76     ("helv" "helvetica" "arial" "fixed")))
  77   "Alist of alternative font family names.
  78 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  79 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  80 ALTERNATIVE2 etc."
  81   :tag "Alternative font families to try"
  82   :type '(repeat (repeat string))
  83   :group 'font-selection
  84   :set #'(lambda (symbol value)
  85            (set-default symbol value)
  86            (internal-set-alternative-font-family-alist value)))
  87
  88
  89 ;; This is defined originally in xfaces.c.
  90 (defcustom face-font-registry-alternatives
  91   (mapcar (lambda (arg) (mapcar 'purecopy arg))
  92   (if (eq system-type 'windows-nt)
  93       '(("iso8859-1" "ms-oemlatin")
  94         ("gb2312.1980" "gb2312" "gbk" "gb18030")
  95         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  96         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  97         ("muletibetan-2" "muletibetan-0"))
  98     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk" "gb18030")
  99       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
 100       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
 101       ("muletibetan-2" "muletibetan-0"))))
 102   "Alist of alternative font registry names.
 103 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
 104 If fonts of registry REGISTRY can be loaded, font selection
 105 tries to find a best matching font among all fonts of registry
 106 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
 107   :tag "Alternative font registries to try"
 108   :type '(repeat (repeat string))
 109   :version "21.1"
 110   :group 'font-selection
 111   :set #'(lambda (symbol value)
 112            (set-default symbol value)
 113            (internal-set-alternative-font-registry-alist value)))
 114
 115 \f
 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 117 ;;; Creation, copying.
 118 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 119
 120
 121 (defun face-list ()
 122   "Return a list of all defined faces."
 123   (mapcar #'car face-new-frame-defaults))
 124
 125 (defun make-face (face &optional no-init-from-resources)
 126   "Define a new face with name FACE, a symbol.
 127 Do not call this directly from Lisp code; use `defface' instead.
 128
 129 If NO-INIT-FROM-RESOURCES is non-nil, don't initialize face
 130 attributes from X resources.  If FACE is already known as a face,
 131 leave it unmodified.  Return FACE."
 132   (interactive (list (read-from-minibuffer
 133                       "Make face: " nil nil t 'face-name-history)))
 134   (unless (facep face)
 135     ;; Make frame-local faces (this also makes the global one).
 136     (dolist (frame (frame-list))
 137       (internal-make-lisp-face face frame))
 138     ;; Add the face to the face menu.
 139     (when (fboundp 'facemenu-add-new-face)
 140       (facemenu-add-new-face face))
 141     ;; Define frame-local faces for all frames from X resources.
 142     (unless no-init-from-resources
 143       (make-face-x-resource-internal face)))
 144   face)
 145
 146 (defun make-empty-face (face)
 147   "Define a new, empty face with name FACE.
 148 Do not call this directly from Lisp code; use `defface' instead."
 149   (interactive (list (read-from-minibuffer
 150                       "Make empty face: " nil nil t 'face-name-history)))
 151   (make-face face 'no-init-from-resources))
 152
 153 (defun copy-face (old-face new-face &optional frame new-frame)
 154   "Define a face named NEW-FACE, which is a copy of OLD-FACE.
 155 This function does not copy face customization data, so NEW-FACE
 156 will not be made customizable.  Most Lisp code should not call
 157 this function; use `defface' with :inherit instead.
 158
 159 If NEW-FACE already exists as a face, modify it to be like
 160 OLD-FACE.  If NEW-FACE doesn't already exist, create it.
 161
 162 If the optional argument FRAME is a frame, change NEW-FACE on
 163 FRAME only.  If FRAME is t, copy the frame-independent default
 164 specification for OLD-FACE to NEW-FACE.  If FRAME is nil, copy
 165 the defaults as well as the faces on each existing frame.
 166
 167 If the optional fourth argument NEW-FRAME is given, copy the
 168 information from face OLD-FACE on frame FRAME to NEW-FACE on
 169 frame NEW-FRAME.  In this case, FRAME must not be nil."
 170   (let ((inhibit-quit t))
 171     (if (null frame)
 172         (progn
 173           (when new-frame
 174             (error "Copying face %s from all frames to one frame"
 175                    old-face))
 176           (make-empty-face new-face)
 177           (dolist (frame (frame-list))
 178             (copy-face old-face new-face frame))
 179           (copy-face old-face new-face t))
 180       (make-empty-face new-face)
 181       (internal-copy-lisp-face old-face new-face frame new-frame))
 182     new-face))
 183
 184 \f
 185 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 186 ;;; Predicates, type checks.
 187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 188
 189 (defun facep (face)
 190   "Return non-nil if FACE is a face name; nil otherwise.
 191 A face name can be a string or a symbol."
 192   (internal-lisp-face-p face))
 193
 194
 195 (defun check-face (face)
 196   "Signal an error if FACE doesn't name a face.
 197 Value is FACE."
 198   (unless (facep face)
 199     (error "Not a face: %s" face))
 200   face)
 201
 202
 203 ;; The ID returned is not to be confused with the internally used IDs
 204 ;; of realized faces.  The ID assigned to Lisp faces is used to
 205 ;; support faces in display table entries.
 206
 207 (defun face-id (face &optional _frame)
 208   "Return the internal ID of face with name FACE.
 209 If FACE is a face-alias, return the ID of the target face.
 210 The optional argument FRAME is ignored, since the internal face ID
 211 of a face name is the same for all frames."
 212   (check-face face)
 213   (or (get face 'face)
 214       (face-id (get face 'face-alias))))
 215
 216 (defun face-equal (face1 face2 &optional frame)
 217   "Non-nil if faces FACE1 and FACE2 are equal.
 218 Faces are considered equal if all their attributes are equal.
 219 If the optional argument FRAME is given, report on FACE1 and FACE2 in that frame.
 220 If FRAME is t, report on the defaults for FACE1 and FACE2 (for new frames).
 221 If FRAME is omitted or nil, use the selected frame."
 222   (internal-lisp-face-equal-p face1 face2 frame))
 223
 224
 225 (defun face-differs-from-default-p (face &optional frame)
 226   "Return non-nil if FACE displays differently from the default face.
 227 If the optional argument FRAME is given, report on face FACE in that frame.
 228 If FRAME is t, report on the defaults for face FACE (for new frames).
 229 If FRAME is omitted or nil, use the selected frame."
 230   (let ((attrs
 231          (delq :inherit (mapcar 'car face-attribute-name-alist)))
 232         (differs nil))
 233     (while (and attrs (not differs))
 234       (let* ((attr (pop attrs))
 235              (attr-val (face-attribute face attr frame t)))
 236         (when (and
 237                (not (eq attr-val 'unspecified))
 238                (display-supports-face-attributes-p (list attr attr-val)
 239                                                    frame))
 240           (setq differs attr))))
 241     differs))
 242
 243
 244 (defun face-nontrivial-p (face &optional frame)
 245   "True if face FACE has some non-nil attribute.
 246 If the optional argument FRAME is given, report on face FACE in that frame.
 247 If FRAME is t, report on the defaults for face FACE (for new frames).
 248 If FRAME is omitted or nil, use the selected frame."
 249   (not (internal-lisp-face-empty-p face frame)))
 250
 251
 252 \f
 253 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 254 ;;; Setting face attributes from X resources.
 255 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 256
 257 (defcustom face-x-resources
 258   (mapcar
 259    (lambda (arg)
 260      ;; FIXME; can we purecopy some of the conses too?
 261      (cons (car arg)
 262            (cons (purecopy (car (cdr arg))) (purecopy (cdr (cdr arg))))))
 263   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 264     (:foundry (".attributeFoundry" . "Face.AttributeFoundry"))
 265     (:width (".attributeWidth" . "Face.AttributeWidth"))
 266     (:height (".attributeHeight" . "Face.AttributeHeight"))
 267     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 268     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 269     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 270     (:background (".attributeBackground" . "Face.AttributeBackground"))
 271     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 272     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 273     (:box (".attributeBox" . "Face.AttributeBox"))
 274     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 275     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 276     (:stipple
 277      (".attributeStipple" . "Face.AttributeStipple")
 278      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 279     (:bold (".attributeBold" . "Face.AttributeBold"))
 280     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 281     (:font (".attributeFont" . "Face.AttributeFont"))
 282     (:inherit (".attributeInherit" . "Face.AttributeInherit"))))
 283   "List of X resources and classes for face attributes.
 284 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 285 the name of a face attribute, and each ENTRY is a cons of the form
 286 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 287 X resource class for the attribute."
 288   :type '(repeat (cons symbol (repeat (cons string string))))
 289   :group 'faces)
 290
 291
 292 (declare-function internal-face-x-get-resource "xfaces.c"
 293                   (resource class frame))
 294
 295 (declare-function internal-set-lisp-face-attribute-from-resource "xfaces.c"
 296                   (face attr value &optional frame))
 297
 298 (defun set-face-attribute-from-resource (face attribute resource class frame)
 299   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 300 Value is the attribute value specified by the resource, or nil
 301 if not present.  This function displays a message if the resource
 302 specifies an invalid attribute."
 303   (let* ((face-name (face-name face))
 304          (value (internal-face-x-get-resource (concat face-name resource)
 305                                               class frame)))
 306     (when value
 307       (condition-case ()
 308           (internal-set-lisp-face-attribute-from-resource
 309            face attribute (downcase value) frame)
 310         (error
 311          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 312                   face-name frame attribute value))))
 313     value))
 314
 315
 316 (defun set-face-attributes-from-resources (face frame)
 317   "Set attributes of FACE from X resources for FRAME."
 318   (when (memq (framep frame) '(x w32))
 319     (dolist (definition face-x-resources)
 320       (let ((attribute (car definition)))
 321         (dolist (entry (cdr definition))
 322           (set-face-attribute-from-resource face attribute (car entry)
 323                                             (cdr entry) frame))))))
 324
 325
 326 (defun make-face-x-resource-internal (face &optional frame)
 327   "Fill frame-local FACE on FRAME from X resources.
 328 FRAME nil or not specified means do it for all frames."
 329   (if (null frame)
 330       (dolist (frame (frame-list))
 331         (set-face-attributes-from-resources face frame))
 332     (set-face-attributes-from-resources face frame)))
 333
 334
 335 \f
 336 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 337 ;;; Retrieving face attributes.
 338 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 339
 340 (defun face-name (face)
 341   "Return the name of face FACE."
 342   (symbol-name (check-face face)))
 343
 344
 345 (defun face-all-attributes (face &optional frame)
 346   "Return an alist stating the attributes of FACE.
 347 Each element of the result has the form (ATTR-NAME . ATTR-VALUE).
 348 If FRAME is omitted or nil the value describes the default attributes,
 349 but if you specify FRAME, the value describes the attributes
 350 of FACE on FRAME."
 351   (mapcar (lambda (pair)
 352             (let ((attr (car pair)))
 353               (cons attr (face-attribute face attr (or frame t)))))
 354           face-attribute-name-alist))
 355
 356 (defun face-attribute (face attribute &optional frame inherit)
 357   "Return the value of FACE's ATTRIBUTE on FRAME.
 358 If the optional argument FRAME is given, report on face FACE in that frame.
 359 If FRAME is t, report on the defaults for face FACE (for new frames).
 360 If FRAME is omitted or nil, use the selected frame.
 361
 362 If INHERIT is nil, only attributes directly defined by FACE are considered,
 363   so the return value may be `unspecified', or a relative value.
 364 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 365   faces specified by its `:inherit' attribute; however the return value
 366   may still be `unspecified' or relative.
 367 If INHERIT is a face or a list of faces, then the result is further merged
 368   with that face (or faces), until it becomes specified and absolute.
 369
 370 To ensure that the return value is always specified and absolute, use a
 371 value of `default' for INHERIT; this will resolve any unspecified or
 372 relative values by merging with the `default' face (which is always
 373 completely specified)."
 374   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 375     (when (and inherit (face-attribute-relative-p attribute value))
 376       ;; VALUE is relative, so merge with inherited faces
 377       (let ((inh-from (face-attribute face :inherit frame)))
 378         (unless (or (null inh-from) (eq inh-from 'unspecified))
 379           (condition-case nil
 380               (setq value
 381                     (face-attribute-merged-with attribute value inh-from frame))
 382             ;; The `inherit' attribute may point to non existent faces.
 383             (error nil)))))
 384     (when (and inherit
 385                (not (eq inherit t))
 386                (face-attribute-relative-p attribute value))
 387       ;; We should merge with INHERIT as well
 388       (setq value (face-attribute-merged-with attribute value inherit frame)))
 389     value))
 390
 391 (defun face-attribute-merged-with (attribute value faces &optional frame)
 392   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 393 FACES may be either a single face or a list of faces.
 394 \[This is an internal function.]"
 395   (cond ((not (face-attribute-relative-p attribute value))
 396          value)
 397         ((null faces)
 398          value)
 399         ((consp faces)
 400          (face-attribute-merged-with
 401           attribute
 402           (face-attribute-merged-with attribute value (car faces) frame)
 403           (cdr faces)
 404           frame))
 405         (t
 406          (merge-face-attribute attribute
 407                                value
 408                                (face-attribute faces attribute frame t)))))
 409
 410
 411 (defmacro face-attribute-specified-or (value &rest body)
 412   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 413   (let ((temp (make-symbol "value")))
 414     `(let ((,temp ,value))
 415        (if (not (eq ,temp 'unspecified))
 416            ,temp
 417          ,@body))))
 418
 419 (defun face-foreground (face &optional frame inherit)
 420   "Return the foreground color name of FACE, or nil if unspecified.
 421 If the optional argument FRAME is given, report on face FACE in that frame.
 422 If FRAME is t, report on the defaults for face FACE (for new frames).
 423 If FRAME is omitted or nil, use the selected frame.
 424
 425 If INHERIT is nil, only a foreground color directly defined by FACE is
 426   considered, so the return value may be nil.
 427 If INHERIT is t, and FACE doesn't define a foreground color, then any
 428   foreground color that FACE inherits through its `:inherit' attribute
 429   is considered as well; however the return value may still be nil.
 430 If INHERIT is a face or a list of faces, then it is used to try to
 431   resolve an unspecified foreground color.
 432
 433 To ensure that a valid color is always returned, use a value of
 434 `default' for INHERIT; this will resolve any unspecified values by
 435 merging with the `default' face (which is always completely specified)."
 436   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 437                                nil))
 438
 439 (defun face-background (face &optional frame inherit)
 440   "Return the background color name of FACE, or nil if unspecified.
 441 If the optional argument FRAME is given, report on face FACE in that frame.
 442 If FRAME is t, report on the defaults for face FACE (for new frames).
 443 If FRAME is omitted or nil, use the selected frame.
 444
 445 If INHERIT is nil, only a background color directly defined by FACE is
 446   considered, so the return value may be nil.
 447 If INHERIT is t, and FACE doesn't define a background color, then any
 448   background color that FACE inherits through its `:inherit' attribute
 449   is considered as well; however the return value may still be nil.
 450 If INHERIT is a face or a list of faces, then it is used to try to
 451   resolve an unspecified background color.
 452
 453 To ensure that a valid color is always returned, use a value of
 454 `default' for INHERIT; this will resolve any unspecified values by
 455 merging with the `default' face (which is always completely specified)."
 456   (face-attribute-specified-or (face-attribute face :background frame inherit)
 457                                nil))
 458
 459 (defun face-stipple (face &optional frame inherit)
 460  "Return the stipple pixmap name of FACE, or nil if unspecified.
 461 If the optional argument FRAME is given, report on face FACE in that frame.
 462 If FRAME is t, report on the defaults for face FACE (for new frames).
 463 If FRAME is omitted or nil, use the selected frame.
 464
 465 If INHERIT is nil, only a stipple directly defined by FACE is
 466   considered, so the return value may be nil.
 467 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 468   that FACE inherits through its `:inherit' attribute is considered as
 469   well; however the return value may still be nil.
 470 If INHERIT is a face or a list of faces, then it is used to try to
 471   resolve an unspecified stipple.
 472
 473 To ensure that a valid stipple or nil is always returned, use a value of
 474 `default' for INHERIT; this will resolve any unspecified values by merging
 475 with the `default' face (which is always completely specified)."
 476   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 477                                nil))
 478
 479
 480 (defalias 'face-background-pixmap 'face-stipple)
 481
 482
 483 (defun face-underline-p (face &optional frame)
 484  "Return non-nil if FACE is underlined.
 485 If the optional argument FRAME is given, report on face FACE in that frame.
 486 If FRAME is t, report on the defaults for face FACE (for new frames).
 487 If FRAME is omitted or nil, use the selected frame."
 488  (eq (face-attribute face :underline frame) t))
 489
 490
 491 (defun face-inverse-video-p (face &optional frame)
 492  "Return non-nil if FACE is in inverse video on FRAME.
 493 If the optional argument FRAME is given, report on face FACE in that frame.
 494 If FRAME is t, report on the defaults for face FACE (for new frames).
 495 If FRAME is omitted or nil, use the selected frame."
 496  (eq (face-attribute face :inverse-video frame) t))
 497
 498
 499 (defun face-bold-p (face &optional frame)
 500   "Return non-nil if the font of FACE is bold on FRAME.
 501 If the optional argument FRAME is given, report on face FACE in that frame.
 502 If FRAME is t, report on the defaults for face FACE (for new frames).
 503 If FRAME is omitted or nil, use the selected frame.
 504 Use `face-attribute' for finer control."
 505   (let ((bold (face-attribute face :weight frame)))
 506     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 507
 508
 509 (defun face-italic-p (face &optional frame)
 510   "Return non-nil if the font of FACE is italic on FRAME.
 511 If the optional argument FRAME is given, report on face FACE in that frame.
 512 If FRAME is t, report on the defaults for face FACE (for new frames).
 513 If FRAME is omitted or nil, use the selected frame.
 514 Use `face-attribute' for finer control."
 515   (let ((italic (face-attribute face :slant frame)))
 516     (memq italic '(italic oblique))))
 517
 518
 519 \f
 520 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 521 ;;; Face documentation.
 522 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 523
 524 (defun face-documentation (face)
 525   "Get the documentation string for FACE.
 526 If FACE is a face-alias, get the documentation for the target face."
 527   (let ((alias (get face 'face-alias))
 528         doc)
 529     (if alias
 530         (progn
 531           (setq doc (get alias 'face-documentation))
 532           (format "%s is an alias for the face `%s'.%s" face alias
 533                   (if doc (format "\n%s" doc)
 534                     "")))
 535       (get face 'face-documentation))))
 536
 537
 538 (defun set-face-documentation (face string)
 539   "Set the documentation string for FACE to STRING."
 540   ;; Perhaps the text should go in DOC.
 541   (put face 'face-documentation (purecopy string)))
 542
 543
 544 (defalias 'face-doc-string 'face-documentation)
 545 (defalias 'set-face-doc-string 'set-face-documentation)
 546
 547
 548 \f
 549 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 550 ;; Setting face attributes.
 551 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 552
 553
 554 (defun set-face-attribute (face frame &rest args)
 555   "Set attributes of FACE on FRAME from ARGS.
 556
 557 If FRAME is nil this function sets the attributes for all
 558 existing frames, and the default for new frames.  If FRAME is t,
 559 change the default for new frames (this is done automatically
 560 each time an attribute is changed on all frames).
 561
 562 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 563 face attribute name.  All attributes can be set to `unspecified';
 564 this fact is not further mentioned below.
 565
 566 The following attributes are recognized:
 567
 568 `:family'
 569
 570 VALUE must be a string specifying the font family, e.g. ``monospace'',
 571 or a fontset alias name.  If a font family is specified, wild-cards `*'
 572 and `?' are allowed.
 573
 574 `:foundry'
 575
 576 VALUE must be a string specifying the font foundry,
 577 e.g. ``adobe''.  If a font foundry is specified, wild-cards `*'
 578 and `?' are allowed.
 579
 580 `:width'
 581
 582 VALUE specifies the relative proportionate width of the font to use.
 583 It must be one of the symbols `ultra-condensed', `extra-condensed',
 584 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 585 `extra-expanded', or `ultra-expanded'.
 586
 587 `:height'
 588
 589 VALUE specifies the height of the font, in either absolute or relative
 590 terms.  An absolute height is an integer, and specifies font height in
 591 units of 1/10 pt.  A relative height is either a floating point number,
 592 which specifies a scaling factor for the underlying face height;
 593 or a function that takes a single argument (the underlying face height)
 594 and returns the new height.  Note that for the `default' face,
 595 you can only specify an absolute height (since there is nothing
 596 for it to be relative to).
 597
 598 `:weight'
 599
 600 VALUE specifies the weight of the font to use.  It must be one of the
 601 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 602 `semi-light', `light', `extra-light', `ultra-light'.
 603
 604 `:slant'
 605
 606 VALUE specifies the slant of the font to use.  It must be one of the
 607 symbols `italic', `oblique', `normal', `reverse-italic', or
 608 `reverse-oblique'.
 609
 610 `:foreground', `:background'
 611
 612 VALUE must be a color name, a string.
 613
 614 `:underline'
 615
 616 VALUE specifies whether characters in FACE should be underlined.  If
 617 VALUE is t, underline with foreground color of the face.  If VALUE is
 618 a string, underline with that color.  If VALUE is nil, explicitly
 619 don't underline.
 620
 621 `:overline'
 622
 623 VALUE specifies whether characters in FACE should be overlined.  If
 624 VALUE is t, overline with foreground color of the face.  If VALUE is a
 625 string, overline with that color.  If VALUE is nil, explicitly don't
 626 overline.
 627
 628 `:strike-through'
 629
 630 VALUE specifies whether characters in FACE should be drawn with a line
 631 striking through them.  If VALUE is t, use the foreground color of the
 632 face.  If VALUE is a string, strike-through with that color.  If VALUE
 633 is nil, explicitly don't strike through.
 634
 635 `:box'
 636
 637 VALUE specifies whether characters in FACE should have a box drawn
 638 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 639 VALUE is t, draw a box with lines of width 1 in the foreground color
 640 of the face.  If VALUE is a string, the string must be a color name,
 641 and the box is drawn in that color with a line width of 1.  Otherwise,
 642 VALUE must be a property list of the form `(:line-width WIDTH
 643 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 644 the property list, a default value will be used for the value, as
 645 specified below.  WIDTH specifies the width of the lines to draw; it
 646 defaults to 1.  If WIDTH is negative, the absolute value is the width
 647 of the lines, and draw top/bottom lines inside the characters area,
 648 not around it.  COLOR is the name of the color to draw in, default is
 649 the foreground color of the face for simple boxes, and the background
 650 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 651 should be draw.  If STYLE is `released-button', draw a box looking
 652 like a released 3D button.  If STYLE is `pressed-button' draw a box
 653 that appears like a pressed button.  If STYLE is nil, the default if
 654 the property list doesn't contain a style specification, draw a 2D
 655 box.
 656
 657 `:inverse-video'
 658
 659 VALUE specifies whether characters in FACE should be displayed in
 660 inverse video.  VALUE must be one of t or nil.
 661
 662 `:stipple'
 663
 664 If VALUE is a string, it must be the name of a file of pixmap data.
 665 The directories listed in the `x-bitmap-file-path' variable are
 666 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 667 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 668 is a string containing the raw bits of the bitmap.  VALUE nil means
 669 explicitly don't use a stipple pattern.
 670
 671 For convenience, attributes `:family', `:foundry', `:width',
 672 `:height', `:weight', and `:slant' may also be set in one step
 673 from an X font name:
 674
 675 `:font'
 676
 677 Set font-related face attributes from VALUE.  VALUE must be a valid
 678 XLFD font name.  If it is a font name pattern, the first matching font
 679 will be used.
 680
 681 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 682 be used to specify that a bold or italic font should be used.  VALUE
 683 must be t or nil in that case.  A value of `unspecified' is not allowed.
 684
 685 `:inherit'
 686
 687 VALUE is the name of a face from which to inherit attributes, or a list
 688 of face names.  Attributes from inherited faces are merged into the face
 689 like an underlying face would be, with higher priority than underlying faces."
 690   (setq args (purecopy args))
 691   (let ((where (if (null frame) 0 frame))
 692         (spec args)
 693         family foundry)
 694     ;; If we set the new-frame defaults, this face is modified outside Custom.
 695     (if (memq where '(0 t))
 696         (put (or (get face 'face-alias) face) 'face-modified t))
 697     ;; If family and/or foundry are specified, set it first.  Certain
 698     ;; face attributes, e.g. :weight semi-condensed, are not supported
 699     ;; in every font.  See bug#1127.
 700     (while spec
 701       (cond ((eq (car spec) :family)
 702              (setq family (cadr spec)))
 703             ((eq (car spec) :foundry)
 704              (setq foundry (cadr spec))))
 705       (setq spec (cddr spec)))
 706     (when (or family foundry)
 707       (when (and (stringp family)
 708                  (string-match "\\([^-]*\\)-\\([^-]*\\)" family))
 709         (unless foundry
 710           (setq foundry (match-string 1 family)))
 711         (setq family (match-string 2 family)))
 712       (when (or (stringp family) (eq family 'unspecified))
 713         (internal-set-lisp-face-attribute face :family (purecopy family)
 714                                           where))
 715       (when (or (stringp foundry) (eq foundry 'unspecified))
 716         (internal-set-lisp-face-attribute face :foundry (purecopy foundry)
 717                                           where)))
 718     (while args
 719       (unless (memq (car args) '(:family :foundry))
 720         (internal-set-lisp-face-attribute face (car args)
 721                                           (purecopy (cadr args))
 722                                           where))
 723       (setq args (cddr args)))))
 724
 725 (defun make-face-bold (face &optional frame _noerror)
 726   "Make the font of FACE be bold, if possible.
 727 FRAME nil or not specified means change face on all frames.
 728 Argument NOERROR is ignored and retained for compatibility.
 729 Use `set-face-attribute' for finer control of the font weight."
 730   (interactive (list (read-face-name "Make which face bold")))
 731   (set-face-attribute face frame :weight 'bold))
 732
 733
 734 (defun make-face-unbold (face &optional frame _noerror)
 735   "Make the font of FACE be non-bold, if possible.
 736 FRAME nil or not specified means change face on all frames.
 737 Argument NOERROR is ignored and retained for compatibility."
 738   (interactive (list (read-face-name "Make which face non-bold")))
 739   (set-face-attribute face frame :weight 'normal))
 740
 741
 742 (defun make-face-italic (face &optional frame _noerror)
 743   "Make the font of FACE be italic, if possible.
 744 FRAME nil or not specified means change face on all frames.
 745 Argument NOERROR is ignored and retained for compatibility.
 746 Use `set-face-attribute' for finer control of the font slant."
 747   (interactive (list (read-face-name "Make which face italic")))
 748   (set-face-attribute face frame :slant 'italic))
 749
 750
 751 (defun make-face-unitalic (face &optional frame _noerror)
 752   "Make the font of FACE be non-italic, if possible.
 753 FRAME nil or not specified means change face on all frames.
 754 Argument NOERROR is ignored and retained for compatibility."
 755   (interactive (list (read-face-name "Make which face non-italic")))
 756   (set-face-attribute face frame :slant 'normal))
 757
 758
 759 (defun make-face-bold-italic (face &optional frame _noerror)
 760   "Make the font of FACE be bold and italic, if possible.
 761 FRAME nil or not specified means change face on all frames.
 762 Argument NOERROR is ignored and retained for compatibility.
 763 Use `set-face-attribute' for finer control of font weight and slant."
 764   (interactive (list (read-face-name "Make which face bold-italic")))
 765   (set-face-attribute face frame :weight 'bold :slant 'italic))
 766
 767
 768 (defun set-face-font (face font &optional frame)
 769   "Change font-related attributes of FACE to those of FONT (a string).
 770 FRAME nil or not specified means change face on all frames.
 771 This sets the attributes `:family', `:foundry', `:width',
 772 `:height', `:weight', and `:slant'.  When called interactively,
 773 prompt for the face and font."
 774   (interactive (read-face-and-attribute :font))
 775   (set-face-attribute face frame :font font))
 776
 777
 778 ;; Implementation note: Emulating gray background colors with a
 779 ;; stipple pattern is now part of the face realization process, and is
 780 ;; done in C depending on the frame on which the face is realized.
 781
 782 (defun set-face-background (face color &optional frame)
 783   "Change the background color of face FACE to COLOR (a string).
 784 FRAME nil or not specified means change face on all frames.
 785 COLOR can be a system-defined color name (see `list-colors-display')
 786 or a hex spec of the form #RRGGBB.
 787 When called interactively, prompts for the face and color."
 788   (interactive (read-face-and-attribute :background))
 789   (set-face-attribute face frame :background (or color 'unspecified)))
 790
 791
 792 (defun set-face-foreground (face color &optional frame)
 793   "Change the foreground color of face FACE to COLOR (a string).
 794 FRAME nil or not specified means change face on all frames.
 795 COLOR can be a system-defined color name (see `list-colors-display')
 796 or a hex spec of the form #RRGGBB.
 797 When called interactively, prompts for the face and color."
 798   (interactive (read-face-and-attribute :foreground))
 799   (set-face-attribute face frame :foreground (or color 'unspecified)))
 800
 801
 802 (defun set-face-stipple (face stipple &optional frame)
 803   "Change the stipple pixmap of face FACE to STIPPLE.
 804 FRAME nil or not specified means change face on all frames.
 805 STIPPLE should be a string, the name of a file of pixmap data.
 806 The directories listed in the `x-bitmap-file-path' variable are searched.
 807
 808 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 809 where WIDTH and HEIGHT are the size in pixels,
 810 and DATA is a string, containing the raw bits of the bitmap."
 811   (interactive (read-face-and-attribute :stipple))
 812   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 813
 814
 815 (defun set-face-underline-p (face underline &optional frame)
 816   "Specify whether face FACE is underlined.
 817 UNDERLINE nil means FACE explicitly doesn't underline.
 818 UNDERLINE non-nil means FACE explicitly does underlining
 819 with the same of the foreground color.
 820 If UNDERLINE is a string, underline with the color named UNDERLINE.
 821 FRAME nil or not specified means change face on all frames.
 822 Use `set-face-attribute' to ``unspecify'' underlining."
 823   (interactive
 824    (let ((list (read-face-and-attribute :underline)))
 825      (list (car list) (eq (car (cdr list)) t))))
 826   (set-face-attribute face frame :underline underline))
 827
 828 (define-obsolete-function-alias 'set-face-underline
 829                                 'set-face-underline-p "22.1")
 830
 831
 832 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 833   "Specify whether face FACE is in inverse video.
 834 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 835 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 836 FRAME nil or not specified means change face on all frames.
 837 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 838   (interactive
 839    (let ((list (read-face-and-attribute :inverse-video)))
 840      (list (car list) (eq (car (cdr list)) t))))
 841   (set-face-attribute face frame :inverse-video inverse-video-p))
 842
 843
 844 (defun set-face-bold-p (face bold-p &optional frame)
 845   "Specify whether face FACE is bold.
 846 BOLD-P non-nil means FACE should explicitly display bold.
 847 BOLD-P nil means FACE should explicitly display non-bold.
 848 FRAME nil or not specified means change face on all frames.
 849 Use `set-face-attribute' or `modify-face' for finer control."
 850   (if (null bold-p)
 851       (make-face-unbold face frame)
 852     (make-face-bold face frame)))
 853
 854
 855 (defun set-face-italic-p (face italic-p &optional frame)
 856   "Specify whether face FACE is italic.
 857 ITALIC-P non-nil means FACE should explicitly display italic.
 858 ITALIC-P nil means FACE should explicitly display non-italic.
 859 FRAME nil or not specified means change face on all frames.
 860 Use `set-face-attribute' or `modify-face' for finer control."
 861   (if (null italic-p)
 862       (make-face-unitalic face frame)
 863     (make-face-italic face frame)))
 864
 865
 866 (defalias 'set-face-background-pixmap 'set-face-stipple)
 867
 868
 869 (defun invert-face (face &optional frame)
 870   "Swap the foreground and background colors of FACE.
 871 If FRAME is omitted or nil, it means change face on all frames.
 872 If FACE specifies neither foreground nor background color,
 873 set its foreground and background to the background and foreground
 874 of the default face.  Value is FACE."
 875   (interactive (list (read-face-name "Invert face")))
 876   (let ((fg (face-attribute face :foreground frame))
 877         (bg (face-attribute face :background frame)))
 878     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 879         (set-face-attribute face frame :foreground bg :background fg)
 880       (set-face-attribute face frame
 881                           :foreground
 882                           (face-attribute 'default :background frame)
 883                           :background
 884                           (face-attribute 'default :foreground frame))))
 885   face)
 886
 887 \f
 888 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 889 ;;; Interactively modifying faces.
 890 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 891
 892 (defun read-face-name (prompt &optional default multiple)
 893   "Read a face, defaulting to the face or faces on the char after point.
 894 If it has the property `read-face-name', that overrides the `face' property.
 895 PROMPT should be a string that describes what the caller will do with the face;
 896 it should not end in a space.
 897 The optional argument DEFAULT provides the value to display in the
 898 minibuffer prompt that is returned if the user just types RET
 899 unless DEFAULT is a string (in which case nil is returned).
 900 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 901 Otherwise, return a single face."
 902   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 903                       (get-char-property (point) 'face)))
 904         (aliasfaces nil)
 905         (nonaliasfaces nil)
 906         faces)
 907     ;; Try to get a face name from the buffer.
 908     (if (memq (intern-soft (thing-at-point 'symbol)) (face-list))
 909         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 910     ;; Add the named faces that the `face' property uses.
 911     (if (and (listp faceprop)
 912              ;; Don't treat an attribute spec as a list of faces.
 913              (not (keywordp (car faceprop)))
 914              (not (memq (car faceprop) '(foreground-color background-color))))
 915         (dolist (f faceprop)
 916           (if (symbolp f)
 917               (push f faces)))
 918       (if (symbolp faceprop)
 919           (push faceprop faces)))
 920     (delete-dups faces)
 921
 922     ;; Build up the completion tables.
 923     (mapatoms (lambda (s)
 924                 (if (custom-facep s)
 925                     (if (get s 'face-alias)
 926                         (push (symbol-name s) aliasfaces)
 927                       (push (symbol-name s) nonaliasfaces)))))
 928
 929     ;; If we only want one, and the default is more than one,
 930     ;; discard the unwanted ones now.
 931     (unless multiple
 932       (if faces
 933           (setq faces (list (car faces)))))
 934     (require 'crm)
 935     (let* ((input
 936             ;; Read the input.
 937             (completing-read-multiple
 938              (if (or faces default)
 939                  (format "%s (default `%s'): " prompt
 940                          (if faces (mapconcat 'symbol-name faces ",")
 941                            default))
 942                (format "%s: " prompt))
 943              (completion-table-in-turn nonaliasfaces aliasfaces)
 944              nil t nil 'face-name-history
 945              (if faces (mapconcat 'symbol-name faces ","))))
 946            ;; Canonicalize the output.
 947            (output
 948             (cond ((or (equal input "") (equal input '("")))
 949                    (or faces (unless (stringp default) default)))
 950                   ((stringp input)
 951                    (mapcar 'intern (split-string input ", *" t)))
 952                   ((listp input)
 953                    (mapcar 'intern input))
 954                   (input))))
 955       ;; Return either a list of faces or just one face.
 956       (if multiple
 957           output
 958         (car output)))))
 959
 960 ;; Not defined without X, but behind window-system test.
 961 (defvar x-bitmap-file-path)
 962
 963 (defun face-valid-attribute-values (attribute &optional frame)
 964   "Return valid values for face attribute ATTRIBUTE.
 965 The optional argument FRAME is used to determine available fonts
 966 and colors.  If it is nil or not specified, the selected frame is used.
 967 Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value out
 968 of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 969 an integer value."
 970   (let ((valid
 971          (case attribute
 972            (:family
 973             (if (window-system frame)
 974                 (mapcar (lambda (x) (cons x x))
 975                         (font-family-list))
 976               ;; Only one font on TTYs.
 977               (list (cons "default" "default"))))
 978            (:foundry
 979             (list nil))
 980            (:width
 981             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
 982                     font-width-table))
 983            (:weight
 984             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
 985                     font-weight-table))
 986            (:slant
 987             (mapcar #'(lambda (x) (cons (symbol-name (aref x 1)) (aref x 1)))
 988                     font-slant-table))
 989            (:inverse-video
 990             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 991                     (internal-lisp-face-attribute-values attribute)))
 992            ((:underline :overline :strike-through :box)
 993             (if (window-system frame)
 994                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 995                                (internal-lisp-face-attribute-values attribute))
 996                        (mapcar #'(lambda (c) (cons c c))
 997                                (defined-colors frame)))
 998               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 999                       (internal-lisp-face-attribute-values attribute))))
1000            ((:foreground :background)
1001             (mapcar #'(lambda (c) (cons c c))
1002                     (defined-colors frame)))
1003            ((:height)
1004             'integerp)
1005            (:stipple
1006             (and (memq (window-system frame) '(x ns)) ; No stipple on w32
1007                  (mapcar #'list
1008                          (apply #'nconc
1009                                 (mapcar (lambda (dir)
1010                                           (and (file-readable-p dir)
1011                                                (file-directory-p dir)
1012                                                (directory-files dir)))
1013                                         x-bitmap-file-path)))))
1014            (:inherit
1015             (cons '("none" . nil)
1016                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
1017                           (face-list))))
1018            (t
1019             (error "Internal error")))))
1020     (if (and (listp valid) (not (memq attribute '(:inherit))))
1021         (nconc (list (cons "unspecified" 'unspecified)) valid)
1022       valid)))
1023
1024
1025 (defconst face-attribute-name-alist
1026   '((:family . "font family")
1027     (:foundry . "font foundry")
1028     (:width . "character set width")
1029     (:height . "height in 1/10 pt")
1030     (:weight . "weight")
1031     (:slant . "slant")
1032     (:underline . "underline")
1033     (:overline . "overline")
1034     (:strike-through . "strike-through")
1035     (:box . "box")
1036     (:inverse-video . "inverse-video display")
1037     (:foreground . "foreground color")
1038     (:background . "background color")
1039     (:stipple . "background stipple")
1040     (:inherit . "inheritance"))
1041   "An alist of descriptive names for face attributes.
1042 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
1043 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
1044 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
1045
1046
1047 (defun face-descriptive-attribute-name (attribute)
1048   "Return a descriptive name for ATTRIBUTE."
1049   (cdr (assq attribute face-attribute-name-alist)))
1050
1051
1052 (defun face-read-string (face default name &optional completion-alist)
1053   "Interactively read a face attribute string value.
1054 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
1055 default string to return if no new value is entered.  NAME is a
1056 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
1057 alist of valid values, if non-nil.
1058
1059 Entering nothing accepts the default string DEFAULT.
1060 Value is the new attribute value."
1061   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
1062   ;; each word in a string separately).
1063   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
1064   (let* ((completion-ignore-case t)
1065          (value (completing-read
1066                  (if default
1067                      (format "%s for face `%s' (default %s): "
1068                              name face default)
1069                    (format "%s for face `%s': " name face))
1070                  completion-alist nil nil nil nil default)))
1071     (if (equal value "") default value)))
1072
1073
1074 (defun face-read-integer (face default name)
1075   "Interactively read an integer face attribute value.
1076 FACE is the face whose attribute is read.  DEFAULT is the default
1077 value to return if no new value is entered.  NAME is a descriptive
1078 name of the attribute for prompting.  Value is the new attribute value."
1079   (let ((new-value
1080          (face-read-string face
1081                            (format "%s" default)
1082                            name
1083                            (list (cons "unspecified" 'unspecified)))))
1084     (cond ((equal new-value "unspecified")
1085            'unspecified)
1086           ((member new-value '("unspecified-fg" "unspecified-bg"))
1087            new-value)
1088           (t
1089            (string-to-number new-value)))))
1090
1091
1092 (defun read-face-attribute (face attribute &optional frame)
1093   "Interactively read a new value for FACE's ATTRIBUTE.
1094 Optional argument FRAME nil or unspecified means read an attribute value
1095 of a global face.  Value is the new attribute value."
1096   (let* ((old-value (face-attribute face attribute frame))
1097          (attribute-name (face-descriptive-attribute-name attribute))
1098          (valid (face-valid-attribute-values attribute frame))
1099          new-value)
1100     ;; Represent complex attribute values as strings by printing them
1101     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1102     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1103     ;; SHADOW)'.
1104     (when (and (or (eq attribute :stipple)
1105                    (eq attribute :box))
1106                (or (consp old-value)
1107                    (vectorp old-value)))
1108       (setq old-value (prin1-to-string old-value)))
1109     (cond ((listp valid)
1110            (let ((default
1111                    (or (car (rassoc old-value valid))
1112                        (format "%s" old-value))))
1113              (setq new-value
1114                    (face-read-string face default attribute-name valid))
1115              (if (equal new-value default)
1116                  ;; Nothing changed, so don't bother with all the stuff
1117                  ;; below.  In particular, this avoids a non-tty color
1118                  ;; from being canonicalized for a tty when the user
1119                  ;; just uses the default.
1120                  (setq new-value old-value)
1121                ;; Terminal frames can support colors that don't appear
1122                ;; explicitly in VALID, using color approximation code
1123                ;; in tty-colors.el.
1124                (when (and (memq attribute '(:foreground :background))
1125                           (not (memq (window-system frame) '(x w32 ns)))
1126                           (not (member new-value
1127                                        '("unspecified"
1128                                          "unspecified-fg" "unspecified-bg"))))
1129                  (setq new-value (car (tty-color-desc new-value frame))))
1130                (when (assoc new-value valid)
1131                  (setq new-value (cdr (assoc new-value valid)))))))
1132           ((eq valid 'integerp)
1133            (setq new-value (face-read-integer face old-value attribute-name)))
1134           (t (error "Internal error")))
1135     ;; Convert stipple and box value text we read back to a list or
1136     ;; vector if it looks like one.  This makes the assumption that a
1137     ;; pixmap file name won't start with an open-paren.
1138     (when (and (or (eq attribute :stipple)
1139                    (eq attribute :box))
1140                (stringp new-value)
1141                (string-match "^[[(]" new-value))
1142       (setq new-value (read new-value)))
1143     new-value))
1144
1145 (declare-function fontset-list "fontset.c" ())
1146 (declare-function x-list-fonts "xfaces.c"
1147                   (pattern &optional face frame maximum width))
1148
1149 (defun read-face-font (face &optional frame)
1150   "Read the name of a font for FACE on FRAME.
1151 If optional argument FRAME is nil or omitted, use the selected frame."
1152   (let ((completion-ignore-case t))
1153     (completing-read (format "Set font attributes of face `%s' from font: " face)
1154                      (append (fontset-list) (x-list-fonts "*" nil frame)))))
1155
1156
1157 (defun read-all-face-attributes (face &optional frame)
1158   "Interactively read all attributes for FACE.
1159 If optional argument FRAME is nil or omitted, use the selected frame.
1160 Value is a property list of attribute names and new values."
1161   (let (result)
1162     (dolist (attribute face-attribute-name-alist result)
1163       (setq result (cons (car attribute)
1164                          (cons (read-face-attribute face (car attribute) frame)
1165                                result))))))
1166
1167 (defun modify-face (&optional face foreground background stipple
1168                               bold-p italic-p underline inverse-p frame)
1169   "Modify attributes of faces interactively.
1170 If optional argument FRAME is nil or omitted, modify the face used
1171 for newly created frame, i.e. the global face.
1172 For non-interactive use, `set-face-attribute' is preferred.
1173 When called from Lisp, if FACE is nil, all arguments but FRAME are ignored
1174 and the face and its settings are obtained by querying the user."
1175   (interactive)
1176   (if face
1177       (set-face-attribute face frame
1178                           :foreground (or foreground 'unspecified)
1179                           :background (or background 'unspecified)
1180                           :stipple stipple
1181                           :bold bold-p
1182                           :italic italic-p
1183                           :underline underline
1184                           :inverse-video inverse-p)
1185     (setq face (read-face-name "Modify face"))
1186     (apply #'set-face-attribute face frame
1187            (read-all-face-attributes face frame))))
1188
1189 (defun read-face-and-attribute (attribute &optional frame)
1190   "Read face name and face attribute value.
1191 ATTRIBUTE is the attribute whose new value is read.
1192 FRAME nil or unspecified means read attribute value of global face.
1193 Value is a list (FACE NEW-VALUE) where FACE is the face read
1194 \(a symbol), and NEW-VALUE is value read."
1195   (cond ((eq attribute :font)
1196          (let* ((prompt "Set font-related attributes of face")
1197                 (face (read-face-name prompt))
1198                 (font (read-face-font face frame)))
1199            (list face font)))
1200         (t
1201          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1202                 (prompt (format "Set %s of face" attribute-name))
1203                 (face (read-face-name prompt))
1204                 (new-value (read-face-attribute face attribute frame)))
1205            (list face new-value)))))
1206
1207
1208 \f
1209 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1210 ;;; Listing faces.
1211 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1212
1213 (defconst list-faces-sample-text
1214   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1215   "*Text string to display as the sample text for `list-faces-display'.")
1216
1217
1218 ;; The name list-faces would be more consistent, but let's avoid a
1219 ;; conflict with Lucid, which uses that name differently.
1220
1221 (defvar help-xref-stack)
1222 (defun list-faces-display (&optional regexp)
1223   "List all faces, using the same sample text in each.
1224 The sample text is a string that comes from the variable
1225 `list-faces-sample-text'.
1226
1227 If REGEXP is non-nil, list only those faces with names matching
1228 this regular expression.  When called interactively with a prefix
1229 arg, prompt for a regular expression."
1230   (interactive (list (and current-prefix-arg
1231                           (read-regexp "List faces matching regexp"))))
1232   (let ((all-faces (zerop (length regexp)))
1233         (frame (selected-frame))
1234         (max-length 0)
1235         faces line-format
1236         disp-frame window face-name)
1237     ;; We filter and take the max length in one pass
1238     (setq faces
1239           (delq nil
1240                 (mapcar (lambda (f)
1241                           (let ((s (symbol-name f)))
1242                             (when (or all-faces (string-match regexp s))
1243                               (setq max-length (max (length s) max-length))
1244                               f)))
1245                         (sort (face-list) #'string-lessp))))
1246     (unless faces
1247       (error "No faces matching \"%s\"" regexp))
1248     (setq max-length (1+ max-length)
1249           line-format (format "%%-%ds" max-length))
1250     (with-help-window "*Faces*"
1251       (with-current-buffer standard-output
1252         (setq truncate-lines t)
1253         (insert
1254          (substitute-command-keys
1255           (concat
1256            "\\<help-mode-map>Use "
1257            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1258            "\\[help-follow] on a face name to customize it\n"
1259            "or on its sample text for a description of the face.\n\n")))
1260         (setq help-xref-stack nil)
1261         (dolist (face faces)
1262           (setq face-name (symbol-name face))
1263           (insert (format line-format face-name))
1264           ;; Hyperlink to a customization buffer for the face.  Using
1265           ;; the help xref mechanism may not be the best way.
1266           (save-excursion
1267             (save-match-data
1268               (search-backward face-name)
1269               (setq help-xref-stack-item `(list-faces-display ,regexp))
1270               (help-xref-button 0 'help-customize-face face)))
1271           (let ((beg (point))
1272                 (line-beg (line-beginning-position)))
1273             (insert list-faces-sample-text)
1274             ;; Hyperlink to a help buffer for the face.
1275             (save-excursion
1276               (save-match-data
1277                 (search-backward list-faces-sample-text)
1278                 (help-xref-button 0 'help-face face)))
1279             (insert "\n")
1280             (put-text-property beg (1- (point)) 'face face)
1281             ;; Make all face commands default to the proper face
1282             ;; anywhere in the line.
1283             (put-text-property line-beg (1- (point)) 'read-face-name face)
1284             ;; If the sample text has multiple lines, line up all of them.
1285             (goto-char beg)
1286             (forward-line 1)
1287             (while (not (eobp))
1288               (insert-char ?\s max-length)
1289               (forward-line 1))))
1290         (goto-char (point-min))))
1291     ;; If the *Faces* buffer appears in a different frame,
1292     ;; copy all the face definitions from FRAME,
1293     ;; so that the display will reflect the frame that was selected.
1294     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1295     (setq disp-frame (if window (window-frame window)
1296                        (car (frame-list))))
1297     (or (eq frame disp-frame)
1298         (let ((faces (face-list)))
1299           (while faces
1300             (copy-face (car faces) (car faces) frame disp-frame)
1301             (setq faces (cdr faces)))))))
1302
1303
1304 (defun describe-face (face &optional frame)
1305   "Display the properties of face FACE on FRAME.
1306 Interactively, FACE defaults to the faces of the character after point
1307 and FRAME defaults to the selected frame.
1308
1309 If the optional argument FRAME is given, report on face FACE in that frame.
1310 If FRAME is t, report on the defaults for face FACE (for new frames).
1311 If FRAME is omitted or nil, use the selected frame."
1312   (interactive (list (read-face-name "Describe face" 'default t)))
1313   (let* ((attrs '((:family . "Family")
1314                   (:foundry . "Foundry")
1315                   (:width . "Width")
1316                   (:height . "Height")
1317                   (:weight . "Weight")
1318                   (:slant . "Slant")
1319                   (:foreground . "Foreground")
1320                   (:background . "Background")
1321                   (:underline . "Underline")
1322                   (:overline . "Overline")
1323                   (:strike-through . "Strike-through")
1324                   (:box . "Box")
1325                   (:inverse-video . "Inverse")
1326                   (:stipple . "Stipple")
1327                   (:font . "Font")
1328                   (:fontset . "Fontset")
1329                   (:inherit . "Inherit")))
1330         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1331                                         attrs))))
1332     (help-setup-xref (list #'describe-face face)
1333                      (called-interactively-p 'interactive))
1334     (unless face
1335       (setq face 'default))
1336     (if (not (listp face))
1337         (setq face (list face)))
1338     (with-help-window (help-buffer)
1339       (with-current-buffer standard-output
1340         (dolist (f face)
1341           (if (stringp f) (setq f (intern f)))
1342           ;; We may get called for anonymous faces (i.e., faces
1343           ;; expressed using prop-value plists).  Those can't be
1344           ;; usefully customized, so ignore them.
1345           (when (symbolp f)
1346             (insert "Face: " (symbol-name f))
1347             (if (not (facep f))
1348                 (insert "   undefined face.\n")
1349               (let ((customize-label "customize this face")
1350                     file-name)
1351                 (insert (concat " (" (propertize "sample" 'font-lock-face f) ")"))
1352                 (princ (concat " (" customize-label ")\n"))
1353                 ;; FIXME not sure how much of this belongs here, and
1354                 ;; how much in `face-documentation'.  The latter is
1355                 ;; not used much, but needs to return nil for
1356                 ;; undocumented faces.
1357                 (let ((alias (get f 'face-alias))
1358                       (face f)
1359                       obsolete)
1360                   (when alias
1361                     (setq face alias)
1362                     (insert
1363                      (format "\n  %s is an alias for the face `%s'.\n%s"
1364                              f alias
1365                              (if (setq obsolete (get f 'obsolete-face))
1366                                  (format "  This face is obsolete%s; use `%s' instead.\n"
1367                                          (if (stringp obsolete)
1368                                              (format " since %s" obsolete)
1369                                            "")
1370                                          alias)
1371                                ""))))
1372                   (insert "\nDocumentation:\n"
1373                           (or (face-documentation face)
1374                               "Not documented as a face.")
1375                           "\n\n"))
1376                 (with-current-buffer standard-output
1377                   (save-excursion
1378                     (re-search-backward
1379                      (concat "\\(" customize-label "\\)") nil t)
1380                     (help-xref-button 1 'help-customize-face f)))
1381                 (setq file-name (find-lisp-object-file-name f 'defface))
1382                 (when file-name
1383                   (princ "Defined in `")
1384                   (princ (file-name-nondirectory file-name))
1385                   (princ "'")
1386                   ;; Make a hyperlink to the library.
1387                   (save-excursion
1388                     (re-search-backward "`\\([^`']+\\)'" nil t)
1389                     (help-xref-button 1 'help-face-def f file-name))
1390                   (princ ".")
1391                   (terpri)
1392                   (terpri))
1393                 (dolist (a attrs)
1394                   (let ((attr (face-attribute f (car a) frame)))
1395                     (insert (make-string (- max-width (length (cdr a))) ?\s)
1396                             (cdr a) ": " (format "%s" attr))
1397                     (if (and (eq (car a) :inherit)
1398                              (not (eq attr 'unspecified)))
1399                         ;; Make a hyperlink to the parent face.
1400                         (save-excursion
1401                           (re-search-backward ": \\([^:]+\\)" nil t)
1402                           (help-xref-button 1 'help-face attr)))
1403                     (insert "\n")))))
1404             (terpri)))))))
1405
1406 \f
1407 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1408 ;;; Face specifications (defface).
1409 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1410
1411 ;; Parameter FRAME Is kept for call compatibility to with previous
1412 ;; face implementation.
1413
1414 (defun face-attr-construct (face &optional _frame)
1415   "Return a `defface'-style attribute list for FACE.
1416 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1417 face attributes of FACE where ATTRIBUTE is the attribute name and
1418 VALUE is the specified value of that attribute.
1419 Argument FRAME is ignored and retained for compatibility."
1420   (let (result)
1421     (dolist (entry face-attribute-name-alist result)
1422       (let* ((attribute (car entry))
1423              (value (face-attribute face attribute)))
1424         (unless (eq value 'unspecified)
1425           (setq result (nconc (list attribute value) result)))))))
1426
1427
1428 (defun face-spec-set-match-display (display frame)
1429   "Non-nil if DISPLAY matches FRAME.
1430 DISPLAY is part of a spec such as can be used in `defface'.
1431 If FRAME is nil, the current FRAME is used."
1432   (let* ((conjuncts display)
1433          conjunct req options
1434          ;; t means we have succeeded against all the conjuncts in
1435          ;; DISPLAY that have been tested so far.
1436          (match t))
1437     (if (eq conjuncts t)
1438         (setq conjuncts nil))
1439     (while (and conjuncts match)
1440       (setq conjunct (car conjuncts)
1441             conjuncts (cdr conjuncts)
1442             req (car conjunct)
1443             options (cdr conjunct)
1444             match (cond ((eq req 'type)
1445                          (or (memq (window-system frame) options)
1446                              (and (memq 'graphic options)
1447                                   (memq (window-system frame) '(x w32 ns)))
1448                              ;; FIXME: This should be revisited to use
1449                              ;; display-graphic-p, provided that the
1450                              ;; color selection depends on the number
1451                              ;; of supported colors, and all defface's
1452                              ;; are changed to look at number of colors
1453                              ;; instead of (type graphic) etc.
1454                              (if (null (window-system frame))
1455                                  (memq 'tty options)
1456                                (or (and (memq 'motif options)
1457                                         (featurep 'motif))
1458                                    (and (memq 'gtk options)
1459                                         (featurep 'gtk))
1460                                    (and (memq 'lucid options)
1461                                         (featurep 'x-toolkit)
1462                                         (not (featurep 'motif))
1463                                         (not (featurep 'gtk)))
1464                                    (and (memq 'x-toolkit options)
1465                                         (featurep 'x-toolkit))))))
1466                         ((eq req 'min-colors)
1467                          (>= (display-color-cells frame) (car options)))
1468                         ((eq req 'class)
1469                          (memq (frame-parameter frame 'display-type) options))
1470                         ((eq req 'background)
1471                          (memq (frame-parameter frame 'background-mode)
1472                                options))
1473                         ((eq req 'supports)
1474                          (display-supports-face-attributes-p options frame))
1475                         (t (error "Unknown req `%S' with options `%S'"
1476                                   req options)))))
1477     match))
1478
1479
1480 (defun face-spec-choose (spec &optional frame)
1481   "Choose the proper attributes for FRAME, out of SPEC.
1482 If SPEC is nil, return nil."
1483   (unless frame
1484     (setq frame (selected-frame)))
1485   (let ((tail spec)
1486         result defaults)
1487     (while tail
1488       (let* ((entry (pop tail))
1489              (display (car entry))
1490              (attrs (cdr entry))
1491              thisval)
1492         ;; Get the attributes as actually specified by this alternative.
1493         (setq thisval
1494               (if (null (cdr attrs)) ;; was (listp (car attrs))
1495                   ;; Old-style entry, the attribute list is the
1496                   ;; first element.
1497                   (car attrs)
1498                 attrs))
1499
1500         ;; If the condition is `default', that sets the default
1501         ;; for following conditions.
1502         (if (eq display 'default)
1503             (setq defaults thisval)
1504           ;; Otherwise, if it matches, use it.
1505           (when (face-spec-set-match-display display frame)
1506             (setq result thisval)
1507             (setq tail nil)))))
1508     (if defaults (append result defaults) result)))
1509
1510
1511 (defun face-spec-reset-face (face &optional frame)
1512   "Reset all attributes of FACE on FRAME to unspecified."
1513   (apply 'set-face-attribute face frame
1514          (if (eq face 'default)
1515              ;; For the default face, avoid making any attribute
1516              ;; unspecified.  Instead, set attributes to default values
1517              ;; (see also realize_default_face in xfaces.c).
1518              (append
1519               '(:underline nil :overline nil :strike-through nil
1520                 :box nil :inverse-video nil :stipple nil :inherit nil)
1521               ;; `display-graphic-p' is unavailable when running
1522               ;; temacs, prior to loading frame.el.
1523               (unless (and (fboundp 'display-graphic-p)
1524                            (display-graphic-p frame))
1525                 '(:family "default" :foundry "default" :width normal
1526                   :height 1 :weight normal :slant normal
1527                   :foreground "unspecified-fg"
1528                   :background "unspecified-bg")))
1529            ;; For all other faces, unspecify all attributes.
1530            (apply 'append
1531                   (mapcar (lambda (x) (list (car x) 'unspecified))
1532                           face-attribute-name-alist)))))
1533
1534 (defun face-spec-set (face spec &optional for-defface)
1535   "Set FACE's face spec, which controls its appearance, to SPEC.
1536 If FOR-DEFFACE is t, set the base spec, the one that `defface'
1537   and Custom set.  (In that case, the caller must put it in the
1538   appropriate property, because that depends on the caller.)
1539 If FOR-DEFFACE is nil, set the overriding spec (and store it
1540   in the `face-override-spec' property of FACE).
1541
1542 The appearance of FACE is controlled by the base spec,
1543 by any custom theme specs on top of that, and by the
1544 overriding spec on top of all the rest.
1545
1546 FOR-DEFFACE can also be a frame, in which case we set the
1547 frame-specific attributes of FACE for that frame based on SPEC.
1548 That usage is deprecated.
1549
1550 See `defface' for information about the format and meaning of SPEC."
1551   (if (framep for-defface)
1552       ;; Handle the deprecated case where third arg is a frame.
1553       (face-spec-set-2 face for-defface spec)
1554     (if for-defface
1555         ;; When we reset the face based on its custom spec, then it is
1556         ;; unmodified as far as Custom is concerned.
1557         (put (or (get face 'face-alias) face) 'face-modified nil)
1558       ;; When we change a face based on a spec from outside custom,
1559       ;; record it for future frames.
1560       (put (or (get face 'face-alias) face) 'face-override-spec spec))
1561     ;; Reset each frame according to the rules implied by all its specs.
1562     (dolist (frame (frame-list))
1563       (face-spec-recalc face frame))))
1564
1565 (defun face-spec-recalc (face frame)
1566   "Reset the face attributes of FACE on FRAME according to its specs.
1567 This applies the defface/custom spec first, then the custom theme specs,
1568 then the override spec."
1569   (face-spec-reset-face face frame)
1570   (let ((face-sym (or (get face 'face-alias) face)))
1571     (or (get face 'customized-face)
1572         (get face 'saved-face)
1573         (face-spec-set-2 face frame (face-default-spec face)))
1574     (let ((theme-faces (reverse (get face-sym 'theme-face))))
1575       (dolist (spec theme-faces)
1576         (face-spec-set-2 face frame (cadr spec))))
1577     (face-spec-set-2 face frame (get face-sym 'face-override-spec))))
1578
1579 (defun face-spec-set-2 (face frame spec)
1580   "Set the face attributes of FACE on FRAME according to SPEC."
1581   (let* ((spec (face-spec-choose spec frame))
1582          attrs)
1583     (while spec
1584       (when (assq (car spec) face-x-resources)
1585         (push (car spec) attrs)
1586         (push (cadr spec) attrs))
1587       (setq spec (cddr spec)))
1588     (apply 'set-face-attribute face frame (nreverse attrs))))
1589
1590 (defun face-attr-match-p (face attrs &optional frame)
1591   "Return t if attributes of FACE match values in plist ATTRS.
1592 Optional parameter FRAME is the frame whose definition of FACE
1593 is used.  If nil or omitted, use the selected frame."
1594   (unless frame
1595     (setq frame (selected-frame)))
1596   (let* ((list face-attribute-name-alist)
1597          (match t)
1598          (bold (and (plist-member attrs :bold)
1599                     (not (plist-member attrs :weight))))
1600          (italic (and (plist-member attrs :italic)
1601                       (not (plist-member attrs :slant))))
1602          (plist (if (or bold italic)
1603                     (copy-sequence attrs)
1604                   attrs)))
1605     ;; Handle the Emacs 20 :bold and :italic properties.
1606     (if bold
1607         (plist-put plist :weight (if bold 'bold 'normal)))
1608     (if italic
1609         (plist-put plist :slant (if italic 'italic 'normal)))
1610     (while (and match list)
1611       (let* ((attr (caar list))
1612              (specified-value
1613               (if (plist-member plist attr)
1614                   (plist-get plist attr)
1615                 'unspecified))
1616              (value-now (face-attribute face attr frame)))
1617         (setq match (equal specified-value value-now))
1618         (setq list (cdr list))))
1619     match))
1620
1621 (defsubst face-spec-match-p (face spec &optional frame)
1622   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1623   (face-attr-match-p face (face-spec-choose spec frame) frame))
1624
1625 (defsubst face-default-spec (face)
1626   "Return the default face-spec for FACE, ignoring any user customization.
1627 If there is no default for FACE, return nil."
1628   (get face 'face-defface-spec))
1629
1630 (defsubst face-user-default-spec (face)
1631   "Return the user's customized face-spec for FACE, or the default if none.
1632 If there is neither a user setting nor a default for FACE, return nil."
1633   (or (get face 'customized-face)
1634       (get face 'saved-face)
1635       (face-default-spec face)))
1636
1637 \f
1638 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1639 ;;; Frame-type independent color support.
1640 ;;; We keep the old x-* names as aliases for back-compatibility.
1641 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1642
1643 (defun defined-colors (&optional frame)
1644   "Return a list of colors supported for a particular frame.
1645 The argument FRAME specifies which frame to try.
1646 The value may be different for frames on different display types.
1647 If FRAME doesn't support colors, the value is nil.
1648 If FRAME is nil, that stands for the selected frame."
1649   (if (memq (framep (or frame (selected-frame))) '(x w32 ns))
1650       (xw-defined-colors frame)
1651     (mapcar 'car (tty-color-alist frame))))
1652 (defalias 'x-defined-colors 'defined-colors)
1653
1654 (declare-function xw-color-defined-p "xfns.c" (color &optional frame))
1655
1656 (defun color-defined-p (color &optional frame)
1657   "Return non-nil if color COLOR is supported on frame FRAME.
1658 If FRAME is omitted or nil, use the selected frame.
1659 If COLOR is the symbol `unspecified' or one of the strings
1660 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1661   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1662       nil
1663     (if (member (framep (or frame (selected-frame))) '(x w32 ns))
1664         (xw-color-defined-p color frame)
1665       (numberp (tty-color-translate color frame)))))
1666 (defalias 'x-color-defined-p 'color-defined-p)
1667
1668 (declare-function xw-color-values "xfns.c" (color &optional frame))
1669
1670 (defun color-values (color &optional frame)
1671   "Return a description of the color named COLOR on frame FRAME.
1672 COLOR should be a string naming a color (e.g. \"white\"), or a
1673 string specifying a color's RGB components (e.g. \"#ff12ec\").
1674
1675 Return a list of three integers, (RED GREEN BLUE), each between 0
1676 and either 65280 or 65535 (the maximum depends on the system).
1677 Use `color-name-to-rgb' if you want RGB floating-point values
1678 normalized to 1.0.
1679
1680 If FRAME is omitted or nil, use the selected frame.
1681 If FRAME cannot display COLOR, the value is nil.
1682
1683 COLOR can also be the symbol `unspecified' or one of the strings
1684 \"unspecified-fg\" or \"unspecified-bg\", in which case the
1685 return value is nil."
1686   (cond
1687    ((member color '(unspecified "unspecified-fg" "unspecified-bg"))
1688     nil)
1689    ((memq (framep (or frame (selected-frame))) '(x w32 ns))
1690     (xw-color-values color frame))
1691    (t
1692     (tty-color-values color frame))))
1693
1694 (defalias 'x-color-values 'color-values)
1695
1696 (declare-function xw-display-color-p "xfns.c" (&optional terminal))
1697
1698 (defun display-color-p (&optional display)
1699   "Return t if DISPLAY supports color.
1700 The optional argument DISPLAY specifies which display to ask about.
1701 DISPLAY should be either a frame or a display name (a string).
1702 If omitted or nil, that stands for the selected frame's display."
1703   (if (memq (framep-on-display display) '(x w32 ns))
1704       (xw-display-color-p display)
1705     (tty-display-color-p display)))
1706 (defalias 'x-display-color-p 'display-color-p)
1707
1708 (declare-function x-display-grayscale-p "xfns.c" (&optional terminal))
1709
1710 (defun display-grayscale-p (&optional display)
1711   "Return non-nil if frames on DISPLAY can display shades of gray."
1712   (let ((frame-type (framep-on-display display)))
1713     (cond
1714      ((memq frame-type '(x w32 ns))
1715       (x-display-grayscale-p display))
1716      (t
1717       (> (tty-color-gray-shades display) 2)))))
1718
1719 (defun read-color (&optional prompt convert-to-RGB allow-empty-name msg)
1720   "Read a color name or RGB triplet.
1721 Completion is available for color names, but not for RGB triplets.
1722
1723 RGB triplets have the form \"#RRGGBB\".  Each of the R, G, and B
1724 components can have one to four digits, but all three components
1725 must have the same number of digits.  Each digit is a hex value
1726 between 0 and F; either upper case or lower case for A through F
1727 are acceptable.
1728
1729 In addition to standard color names and RGB hex values, the
1730 following are available as color candidates.  In each case, the
1731 corresponding color is used.
1732
1733  * `foreground at point'   - foreground under the cursor
1734  * `background at point'   - background under the cursor
1735
1736 Optional arg PROMPT is the prompt; if nil, use a default prompt.
1737
1738 Interactively, or with optional arg CONVERT-TO-RGB-P non-nil,
1739 convert an input color name to an RGB hex string.  Return the RGB
1740 hex string.
1741
1742 If optional arg ALLOW-EMPTY-NAME is non-nil, the user is allowed
1743 to enter an empty color name (the empty string).
1744
1745 Interactively, or with optional arg MSG non-nil, print the
1746 resulting color name in the echo area."
1747   (interactive "i\np\ni\np")    ; Always convert to RGB interactively.
1748   (let* ((completion-ignore-case t)
1749          (colors (or facemenu-color-alist
1750                      (append '("foreground at point" "background at point")
1751                              (if allow-empty-name '(""))
1752                              (defined-colors))))
1753          (color (completing-read
1754                  (or prompt "Color (name or #RGB triplet): ")
1755                  ;; Completing function for reading colors, accepting
1756                  ;; both color names and RGB triplets.
1757                  (lambda (string pred flag)
1758                    (cond
1759                     ((null flag) ; Try completion.
1760                      (or (try-completion string colors pred)
1761                          (if (color-defined-p string)
1762                              string)))
1763                     ((eq flag t) ; List all completions.
1764                      (or (all-completions string colors pred)
1765                          (if (color-defined-p string)
1766                              (list string))))
1767                     ((eq flag 'lambda) ; Test completion.
1768                      (or (memq string colors)
1769                          (color-defined-p string)))))
1770                  nil t)))
1771
1772     ;; Process named colors.
1773     (when (member color colors)
1774       (cond ((string-equal color "foreground at point")
1775              (setq color (foreground-color-at-point)))
1776             ((string-equal color "background at point")
1777              (setq color (background-color-at-point))))
1778       (when (and convert-to-RGB
1779                  (not (string-equal color "")))
1780         (let ((components (x-color-values color)))
1781           (unless (string-match "^#\\([a-fA-F0-9][a-fA-F0-9][a-fA-F0-9]\\)+$" color)
1782             (setq color (format "#%04X%04X%04X"
1783                                 (logand 65535 (nth 0 components))
1784                                 (logand 65535 (nth 1 components))
1785                                 (logand 65535 (nth 2 components))))))))
1786     (when msg (message "Color: `%s'" color))
1787     color))
1788
1789
1790 (defun face-at-point ()
1791   "Return the face of the character after point.
1792 If it has more than one face, return the first one.
1793 Return nil if it has no specified face."
1794   (let* ((faceprop (or (get-char-property (point) 'read-face-name)
1795                        (get-char-property (point) 'face)
1796                        'default))
1797          (face (cond ((symbolp faceprop) faceprop)
1798                      ;; List of faces (don't treat an attribute spec).
1799                      ;; Just use the first face.
1800                      ((and (consp faceprop) (not (keywordp (car faceprop)))
1801                            (not (memq (car faceprop)
1802                                       '(foreground-color background-color))))
1803                       (car faceprop))
1804                      (t nil))))         ; Invalid face value.
1805     (if (facep face) face nil)))
1806
1807 (defun foreground-color-at-point ()
1808   "Return the foreground color of the character after point."
1809   ;; `face-at-point' alone is not sufficient.  It only gets named faces.
1810   ;; Need also pick up any face properties that are not associated with named faces.
1811   (let ((face (or (face-at-point)
1812                   (get-char-property (point) 'read-face-name)
1813                   (get-char-property (point) 'face))))
1814     (cond ((and face (symbolp face))
1815            (let ((value (face-foreground face nil 'default)))
1816              (if (member value '("unspecified-fg" "unspecified-bg"))
1817                  nil
1818                value)))
1819           ((consp face)
1820            (cond ((memq 'foreground-color face) (cdr (memq 'foreground-color face)))
1821                  ((memq ':foreground face) (cadr (memq ':foreground face)))))
1822           (t nil))))                    ; Invalid face value.
1823
1824 (defun background-color-at-point ()
1825   "Return the background color of the character after point."
1826   ;; `face-at-point' alone is not sufficient.  It only gets named faces.
1827   ;; Need also pick up any face properties that are not associated with named faces.
1828   (let ((face (or (face-at-point)
1829                   (get-char-property (point) 'read-face-name)
1830                   (get-char-property (point) 'face))))
1831     (cond ((and face (symbolp face))
1832            (let ((value (face-background face nil 'default)))
1833              (if (member value '("unspecified-fg" "unspecified-bg"))
1834                  nil
1835                value)))
1836           ((consp face)
1837            (cond ((memq 'background-color face) (cdr (memq 'background-color face)))
1838                  ((memq ':background face) (cadr (memq ':background face)))))
1839           (t nil))))                    ; Invalid face value.
1840
1841 \f
1842 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1843 ;;; Frame creation.
1844 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1845
1846 (declare-function x-parse-geometry "frame.c" (string))
1847
1848 (defun x-handle-named-frame-geometry (parameters)
1849   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1850 Value is the new parameter list."
1851   ;; Note that `x-resource-name' has a global meaning.
1852   (let ((x-resource-name (cdr (assq 'name parameters))))
1853     (when x-resource-name
1854       ;; Before checking X resources, we must have an X connection.
1855       (or (window-system)
1856           (x-display-list)
1857           (x-open-connection (or (cdr (assq 'display parameters))
1858                                  x-display-name)))
1859       (let (res-geometry parsed)
1860         (and (setq res-geometry (x-get-resource "geometry" "Geometry"))
1861              (setq parsed (x-parse-geometry res-geometry))
1862              (setq parameters
1863                    (append parameters parsed
1864                            ;; If the resource specifies a position,
1865                            ;; take note of that.
1866                            (if (or (assq 'top parsed) (assq 'left parsed))
1867                                '((user-position . t) (user-size . t)))))))))
1868   parameters)
1869
1870
1871 (defun x-handle-reverse-video (frame parameters)
1872   "Handle the reverse-video frame parameter and X resource.
1873 `x-create-frame' does not handle this one."
1874   (when (cdr (or (assq 'reverse parameters)
1875                  (let ((resource (x-get-resource "reverseVideo"
1876                                                  "ReverseVideo")))
1877                    (if resource
1878                        (cons nil (member (downcase resource)
1879                                          '("on" "true")))))))
1880       (let* ((params (frame-parameters frame))
1881              (bg (cdr (assq 'foreground-color params)))
1882              (fg (cdr (assq 'background-color params))))
1883         (modify-frame-parameters frame
1884                                  (list (cons 'foreground-color fg)
1885                                        (cons 'background-color bg)))
1886         (if (equal bg (cdr (assq 'border-color params)))
1887             (modify-frame-parameters frame
1888                                      (list (cons 'border-color fg))))
1889         (if (equal bg (cdr (assq 'mouse-color params)))
1890             (modify-frame-parameters frame
1891                                      (list (cons 'mouse-color fg))))
1892         (if (equal bg (cdr (assq 'cursor-color params)))
1893             (modify-frame-parameters frame
1894                                      (list (cons 'cursor-color fg)))))))
1895
1896 (declare-function x-create-frame "xfns.c" (parms))
1897 (declare-function x-setup-function-keys "term/common-win" (frame))
1898
1899 (defun x-create-frame-with-faces (&optional parameters)
1900   "Create and return a frame with frame parameters PARAMETERS.
1901 If PARAMETERS specify a frame name, handle X geometry resources
1902 for that name.  If PARAMETERS includes a `reverse' parameter, or
1903 the X resource ``reverseVideo'' is present, handle that."
1904   (setq parameters (x-handle-named-frame-geometry parameters))
1905   (let* ((params (copy-tree parameters))
1906          (visibility-spec (assq 'visibility parameters))
1907          (delayed-params '(foreground-color background-color font
1908                            border-color cursor-color mouse-color
1909                            visibility scroll-bar-foreground
1910                            scroll-bar-background))
1911          frame success)
1912     (dolist (param delayed-params)
1913       (setq params (assq-delete-all param params)))
1914     (setq frame (x-create-frame `((visibility . nil) . ,params)))
1915     (unwind-protect
1916         (progn
1917           (x-setup-function-keys frame)
1918           (x-handle-reverse-video frame parameters)
1919           (frame-set-background-mode frame t)
1920           (face-set-after-frame-default frame parameters)
1921           (if (null visibility-spec)
1922               (make-frame-visible frame)
1923             (modify-frame-parameters frame (list visibility-spec)))
1924           (setq success t))
1925       (unless success
1926         (delete-frame frame)))
1927     frame))
1928
1929 (defun face-set-after-frame-default (frame &optional parameters)
1930   "Initialize the frame-local faces of FRAME.
1931 Calculate the face definitions using the face specs, custom theme
1932 settings, X resources, and `face-new-frame-defaults'.
1933 Finally, apply any relevant face attributes found amongst the
1934 frame parameters in PARAMETERS."
1935   (let ((window-system-p (memq (window-system frame) '(x w32))))
1936     ;; The `reverse' is so that `default' goes first.
1937     (dolist (face (nreverse (face-list)))
1938       (condition-case ()
1939           (progn
1940             ;; Initialize faces from face spec and custom theme.
1941             (face-spec-recalc face frame)
1942             ;; X resources for the default face are applied during
1943             ;; `x-create-frame'.
1944             (and (not (eq face 'default)) window-system-p
1945                  (make-face-x-resource-internal face frame))
1946             ;; Apply attributes specified by face-new-frame-defaults
1947             (internal-merge-in-global-face face frame))
1948         ;; Don't let invalid specs prevent frame creation.
1949         (error nil))))
1950
1951   ;; Apply attributes specified by frame parameters.
1952   (let ((face-params '((foreground-color default :foreground)
1953                        (background-color default :background)
1954                        (font default :font)
1955                        (border-color border :background)
1956                        (cursor-color cursor :background)
1957                        (scroll-bar-foreground scroll-bar :foreground)
1958                        (scroll-bar-background scroll-bar :background)
1959                        (mouse-color mouse :background))))
1960     (dolist (param face-params)
1961       (let* ((param-name (nth 0 param))
1962              (value (cdr (assq param-name parameters))))
1963         (if value
1964             (set-face-attribute (nth 1 param) frame
1965                                 (nth 2 param) value))))))
1966
1967 (defun tty-handle-reverse-video (frame parameters)
1968   "Handle the reverse-video frame parameter for terminal frames."
1969   (when (cdr (assq 'reverse parameters))
1970     (let* ((params (frame-parameters frame))
1971            (bg (cdr (assq 'foreground-color params)))
1972            (fg (cdr (assq 'background-color params))))
1973       (modify-frame-parameters frame
1974                                (list (cons 'foreground-color fg)
1975                                      (cons 'background-color bg)))
1976       (if (equal bg (cdr (assq 'mouse-color params)))
1977           (modify-frame-parameters frame
1978                                    (list (cons 'mouse-color fg))))
1979       (if (equal bg (cdr (assq 'cursor-color params)))
1980           (modify-frame-parameters frame
1981                                    (list (cons 'cursor-color fg)))))))
1982
1983
1984 (defun tty-create-frame-with-faces (&optional parameters)
1985   "Create and return a frame from optional frame parameters PARAMETERS.
1986 If PARAMETERS contains a `reverse' parameter, handle that."
1987   (let ((frame (make-terminal-frame parameters))
1988         success)
1989     (unwind-protect
1990         (with-selected-frame frame
1991           (tty-handle-reverse-video frame (frame-parameters frame))
1992
1993           (unless (terminal-parameter frame 'terminal-initted)
1994             (set-terminal-parameter frame 'terminal-initted t)
1995             (set-locale-environment nil frame)
1996             (tty-run-terminal-initialization frame))
1997           (frame-set-background-mode frame t)
1998           (face-set-after-frame-default frame parameters)
1999           (setq success t))
2000       (unless success
2001         (delete-frame frame)))
2002     frame))
2003
2004 (defun tty-find-type (pred type)
2005   "Return the longest prefix of TYPE to which PRED returns non-nil.
2006 TYPE should be a tty type name such as \"xterm-16color\".
2007
2008 The function tries only those prefixes that are followed by a
2009 dash or underscore in the original type name, like \"xterm\" in
2010 the above example."
2011   (let (hyphend)
2012     (while (and type
2013                 (not (funcall pred type)))
2014       ;; Strip off last hyphen and what follows, then try again
2015       (setq type
2016             (if (setq hyphend (string-match "[-_][^-_]+$" type))
2017                 (substring type 0 hyphend)
2018               nil))))
2019   type)
2020
2021 (defun tty-run-terminal-initialization (frame &optional type)
2022   "Run the special initialization code for the terminal type of FRAME.
2023 The optional TYPE parameter may be used to override the autodetected
2024 terminal type to a different value."
2025   (setq type (or type (tty-type frame)))
2026   ;; Load library for our terminal type.
2027   ;; User init file can set term-file-prefix to nil to prevent this.
2028   (with-selected-frame frame
2029     (unless (null term-file-prefix)
2030       (let* (term-init-func)
2031         ;; First, load the terminal initialization file, if it is
2032         ;; available and it hasn't been loaded already.
2033         (tty-find-type #'(lambda (type)
2034                            (let ((file (locate-library (concat term-file-prefix type))))
2035                              (and file
2036                                   (or (assoc file load-history)
2037                                       (load file t t)))))
2038                        type)
2039         ;; Next, try to find a matching initialization function, and call it.
2040         (tty-find-type #'(lambda (type)
2041                            (fboundp (setq term-init-func
2042                                           (intern (concat "terminal-init-" type)))))
2043                        type)
2044         (when (fboundp term-init-func)
2045           (funcall term-init-func))
2046         (set-terminal-parameter frame 'terminal-initted term-init-func)))))
2047
2048 ;; Called from C function init_display to initialize faces of the
2049 ;; dumped terminal frame on startup.
2050
2051 (defun tty-set-up-initial-frame-faces ()
2052   (let ((frame (selected-frame)))
2053     (frame-set-background-mode frame t)
2054     (face-set-after-frame-default frame)))
2055
2056
2057 \f
2058 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2059 ;;; Standard faces.
2060 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2061
2062 (defgroup basic-faces nil
2063   "The standard faces of Emacs."
2064   :group 'faces)
2065
2066 (defface default
2067   '((t nil)) ; If this were nil, face-defface-spec would not be set.
2068   "Basic default face."
2069   :group 'basic-faces)
2070
2071 (defface bold
2072   '((t :weight bold))
2073   "Basic bold face."
2074   :group 'basic-faces)
2075
2076 (defface italic
2077   '((((supports :slant italic))
2078      :slant italic)
2079     (((supports :underline t))
2080      :underline t)
2081     (t
2082      ;; Default to italic, even if it doesn't appear to be supported,
2083      ;; because in some cases the display engine will do its own
2084      ;; workaround (to `dim' on ttys).
2085      :slant italic))
2086   "Basic italic face."
2087   :group 'basic-faces)
2088
2089 (defface bold-italic
2090   '((t :weight bold :slant italic))
2091   "Basic bold-italic face."
2092   :group 'basic-faces)
2093
2094 (defface underline
2095   '((((supports :underline t))
2096      :underline t)
2097     (((supports :weight bold))
2098      :weight bold)
2099     (t :underline t))
2100   "Basic underlined face."
2101   :group 'basic-faces)
2102
2103 (defface fixed-pitch
2104   '((t :family "Monospace"))
2105   "The basic fixed-pitch face."
2106   :group 'basic-faces)
2107
2108 (defface variable-pitch
2109   '((t :family "Sans Serif"))
2110   "The basic variable-pitch face."
2111   :group 'basic-faces)
2112
2113 (defface shadow
2114   '((((class color grayscale) (min-colors 88) (background light))
2115      :foreground "grey50")
2116     (((class color grayscale) (min-colors 88) (background dark))
2117      :foreground "grey70")
2118     (((class color) (min-colors 8) (background light))
2119      :foreground "green")
2120     (((class color) (min-colors 8) (background dark))
2121      :foreground "yellow"))
2122   "Basic face for shadowed text."
2123   :group 'basic-faces
2124   :version "22.1")
2125
2126 (defface link
2127   '((((class color) (min-colors 88) (background light))
2128      :foreground "RoyalBlue3" :underline t)
2129     (((class color) (background light))
2130      :foreground "blue" :underline t)
2131     (((class color) (min-colors 88) (background dark))
2132      :foreground "cyan1" :underline t)
2133     (((class color) (background dark))
2134      :foreground "cyan" :underline t)
2135     (t :inherit underline))
2136   "Basic face for unvisited links."
2137   :group 'basic-faces
2138   :version "22.1")
2139
2140 (defface link-visited
2141   '((default :inherit link)
2142     (((class color) (background light)) :foreground "magenta4")
2143     (((class color) (background dark)) :foreground "violet"))
2144   "Basic face for visited links."
2145   :group 'basic-faces
2146   :version "22.1")
2147
2148 (defface highlight
2149   '((((class color) (min-colors 88) (background light))
2150      :background "darkseagreen2")
2151     (((class color) (min-colors 88) (background dark))
2152      :background "darkolivegreen")
2153     (((class color) (min-colors 16) (background light))
2154      :background "darkseagreen2")
2155     (((class color) (min-colors 16) (background dark))
2156      :background "darkolivegreen")
2157     (((class color) (min-colors 8))
2158      :background "green" :foreground "black")
2159     (t :inverse-video t))
2160   "Basic face for highlighting."
2161   :group 'basic-faces)
2162
2163 ;; Region face: under NS, default to the system-defined selection
2164 ;; color (optimized for the fixed white background of other apps),
2165 ;; if background is light.
2166 (defface region
2167   '((((class color) (min-colors 88) (background dark))
2168      :background "blue3")
2169     (((class color) (min-colors 88) (background light) (type gtk))
2170      :foreground "gtk_selection_fg_color"
2171      :background "gtk_selection_bg_color")
2172     (((class color) (min-colors 88) (background light) (type ns))
2173      :background "ns_selection_color")
2174     (((class color) (min-colors 88) (background light))
2175      :background "lightgoldenrod2")
2176     (((class color) (min-colors 16) (background dark))
2177      :background "blue3")
2178     (((class color) (min-colors 16) (background light))
2179      :background "lightgoldenrod2")
2180     (((class color) (min-colors 8))
2181      :background "blue" :foreground "white")
2182     (((type tty) (class mono))
2183      :inverse-video t)
2184     (t :background "gray"))
2185   "Basic face for highlighting the region."
2186   :version "21.1"
2187   :group 'basic-faces)
2188
2189 (defface secondary-selection
2190   '((((class color) (min-colors 88) (background light))
2191      :background "yellow1")
2192     (((class color) (min-colors 88) (background dark))
2193      :background "SkyBlue4")
2194     (((class color) (min-colors 16) (background light))
2195      :background "yellow")
2196     (((class color) (min-colors 16) (background dark))
2197      :background "SkyBlue4")
2198     (((class color) (min-colors 8))
2199      :background "cyan" :foreground "black")
2200     (t :inverse-video t))
2201   "Basic face for displaying the secondary selection."
2202   :group 'basic-faces)
2203
2204 (defface trailing-whitespace
2205   '((((class color) (background light))
2206      :background "red1")
2207     (((class color) (background dark))
2208      :background "red1")
2209     (t :inverse-video t))
2210   "Basic face for highlighting trailing whitespace."
2211   :version "21.1"
2212   :group 'whitespace-faces      ; like `show-trailing-whitespace'
2213   :group 'basic-faces)
2214
2215 (defface escape-glyph
2216   '((((background dark)) :foreground "cyan")
2217     ;; See the comment in minibuffer-prompt for
2218     ;; the reason not to use blue on MS-DOS.
2219     (((type pc)) :foreground "magenta")
2220     ;; red4 is too dark, but some say blue is too loud.
2221     ;; brown seems to work ok. -- rms.
2222     (t :foreground "brown"))
2223   "Face for characters displayed as sequences using `^' or `\\'."
2224   :group 'basic-faces
2225   :version "22.1")
2226
2227 (defface nobreak-space
2228   '((((class color) (min-colors 88)) :inherit escape-glyph :underline t)
2229     (((class color) (min-colors 8)) :background "magenta")
2230     (t :inverse-video t))
2231   "Face for displaying nobreak space."
2232   :group 'basic-faces
2233   :version "22.1")
2234
2235 (defgroup mode-line-faces nil
2236   "Faces used in the mode line."
2237   :group 'mode-line
2238   :group 'faces
2239   :version "22.1")
2240
2241 (defface mode-line
2242   '((((class color) (min-colors 88))
2243      :box (:line-width -1 :style released-button)
2244      :background "grey75" :foreground "black")
2245     (t
2246      :inverse-video t))
2247   "Basic mode line face for selected window."
2248   :version "21.1"
2249   :group 'mode-line-faces
2250   :group 'basic-faces)
2251 ;; No need to define aliases of this form for new faces.
2252 (define-obsolete-face-alias 'modeline 'mode-line "21.1")
2253
2254 (defface mode-line-inactive
2255   '((default
2256      :inherit mode-line)
2257     (((class color) (min-colors 88) (background light))
2258      :weight light
2259      :box (:line-width -1 :color "grey75" :style nil)
2260      :foreground "grey20" :background "grey90")
2261     (((class color) (min-colors 88) (background dark) )
2262      :weight light
2263      :box (:line-width -1 :color "grey40" :style nil)
2264      :foreground "grey80" :background "grey30"))
2265   "Basic mode line face for non-selected windows."
2266   :version "22.1"
2267   :group 'mode-line-faces
2268   :group 'basic-faces)
2269 (define-obsolete-face-alias 'modeline-inactive 'mode-line-inactive "22.1")
2270
2271 (defface mode-line-highlight
2272   '((((class color) (min-colors 88))
2273      :box (:line-width 2 :color "grey40" :style released-button))
2274     (t
2275      :inherit highlight))
2276   "Basic mode line face for highlighting."
2277   :version "22.1"
2278   :group 'mode-line-faces
2279   :group 'basic-faces)
2280 (define-obsolete-face-alias 'modeline-highlight 'mode-line-highlight "22.1")
2281
2282 (defface mode-line-emphasis
2283   '((t (:weight bold)))
2284   "Face used to emphasize certain mode line features.
2285 Use the face `mode-line-highlight' for features that can be selected."
2286   :version "23.1"
2287   :group 'mode-line-faces
2288   :group 'basic-faces)
2289
2290 (defface mode-line-buffer-id
2291   '((t (:weight bold)))
2292   "Face used for buffer identification parts of the mode line."
2293   :version "22.1"
2294   :group 'mode-line-faces
2295   :group 'basic-faces)
2296 (define-obsolete-face-alias 'modeline-buffer-id 'mode-line-buffer-id "22.1")
2297
2298 (defface header-line
2299   '((default
2300      :inherit mode-line)
2301     (((type tty))
2302      ;; This used to be `:inverse-video t', but that doesn't look very
2303      ;; good when combined with inverse-video mode-lines and multiple
2304      ;; windows.  Underlining looks better, and is more consistent with
2305      ;; the window-system face variants, which deemphasize the
2306      ;; header-line in relation to the mode-line face.  If a terminal
2307      ;; can't underline, then the header-line will end up without any
2308      ;; highlighting; this may be too confusing in general, although it
2309      ;; happens to look good with the only current use of header-lines,
2310      ;; the info browser. XXX
2311      :inverse-video nil        ;Override the value inherited from mode-line.
2312      :underline t)
2313     (((class color grayscale) (background light))
2314      :background "grey90" :foreground "grey20"
2315      :box nil)
2316     (((class color grayscale) (background dark))
2317      :background "grey20" :foreground "grey90"
2318      :box nil)
2319     (((class mono) (background light))
2320      :background "white" :foreground "black"
2321      :inverse-video nil
2322      :box nil
2323      :underline t)
2324     (((class mono) (background dark))
2325      :background "black" :foreground "white"
2326      :inverse-video nil
2327      :box nil
2328      :underline t))
2329   "Basic header-line face."
2330   :version "21.1"
2331   :group 'basic-faces)
2332
2333 (defface vertical-border
2334   '((((type tty)) :inherit mode-line-inactive))
2335   "Face used for vertical window dividers on ttys."
2336   :version "22.1"
2337   :group 'basic-faces)
2338
2339 (defface minibuffer-prompt
2340   '((((background dark)) :foreground "cyan")
2341     ;; Don't use blue because many users of the MS-DOS port customize
2342     ;; their foreground color to be blue.
2343     (((type pc)) :foreground "magenta")
2344     (t :foreground "medium blue"))
2345   "Face for minibuffer prompts.
2346 By default, Emacs automatically adds this face to the value of
2347 `minibuffer-prompt-properties', which is a list of text properties
2348 used to display the prompt text."
2349   :version "22.1"
2350   :group 'basic-faces)
2351
2352 (setq minibuffer-prompt-properties
2353       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
2354
2355 (defface fringe
2356   '((((class color) (background light))
2357      :background "grey95")
2358     (((class color) (background dark))
2359      :background "grey10")
2360     (t
2361      :background "gray"))
2362   "Basic face for the fringes to the left and right of windows under X."
2363   :version "21.1"
2364   :group 'frames
2365   :group 'basic-faces)
2366
2367 (defface scroll-bar '((t nil))
2368   "Basic face for the scroll bar colors under X."
2369   :version "21.1"
2370   :group 'frames
2371   :group 'basic-faces)
2372
2373 (defface border '((t nil))
2374   "Basic face for the frame border under X."
2375   :version "21.1"
2376   :group 'frames
2377   :group 'basic-faces)
2378
2379 (defface cursor
2380   '((((background light)) :background "black")
2381     (((background dark))  :background "white"))
2382   "Basic face for the cursor color under X.
2383 Currently, only the `:background' attribute is meaningful; all
2384 other attributes are ignored.  The cursor foreground color is
2385 taken from the background color of the underlying text.
2386
2387 Note: Other faces cannot inherit from the cursor face."
2388   :version "21.1"
2389   :group 'cursor
2390   :group 'basic-faces)
2391
2392 (put 'cursor 'face-no-inherit t)
2393
2394 (defface mouse '((t nil))
2395   "Basic face for the mouse color under X."
2396   :version "21.1"
2397   :group 'mouse
2398   :group 'basic-faces)
2399
2400 (defface tool-bar
2401   '((default
2402      :box (:line-width 1 :style released-button)
2403      :foreground "black")
2404     (((type x w32 ns) (class color))
2405      :background "grey75")
2406     (((type x) (class mono))
2407      :background "grey"))
2408   "Basic tool-bar face."
2409   :version "21.1"
2410   :group 'basic-faces)
2411
2412 (defface menu
2413   '((((type tty))
2414      :inverse-video t)
2415     (((type x-toolkit))
2416      )
2417     (t
2418      :inverse-video t))
2419   "Basic face for the font and colors of the menu bar and popup menus."
2420   :version "21.1"
2421   :group 'menu
2422   :group 'basic-faces)
2423
2424 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
2425   "Face to highlight argument names in *Help* buffers."
2426   :group 'help)
2427
2428 (defface glyphless-char
2429   '((((type tty)) :inherit underline)
2430     (((type pc)) :inherit escape-glyph)
2431     (t :height 0.6))
2432   "Face for displaying non-graphic characters (e.g. U+202A (LRE)).
2433 It is used for characters of no fonts too."
2434   :version "24.1"
2435   :group 'basic-faces)
2436
2437 (defface error
2438   '((((class color) (min-colors 88) (background light)) (:foreground "Red1" :weight bold))
2439     (((class color) (min-colors 88) (background dark)) (:foreground "Pink" :weight bold))
2440     (((class color) (min-colors 16) (background light)) (:foreground "Red1" :weight bold))
2441     (((class color) (min-colors 16) (background dark)) (:foreground "Pink" :weight bold))
2442     (((class color) (min-colors 8)) (:foreground "red"))
2443     (t (:inverse-video t :weight bold)))
2444   "Basic face used to highlight errors and to denote failure."
2445   :version "24.1"
2446   :group 'basic-faces)
2447
2448 (defface warning
2449   '((((class color) (min-colors 16)) (:foreground "DarkOrange" :weight bold))
2450     (((class color)) (:foreground "yellow" :weight bold))
2451     (t (:weight bold)))
2452   "Basic face used to highlight warnings."
2453   :version "24.1"
2454   :group 'basic-faces)
2455
2456 (defface success
2457   '((((class color) (min-colors 16) (background light))
2458      (:foreground "ForestGreen" :weight bold))
2459     (((class color) (min-colors 88) (background dark))
2460      (:foreground "Green1" :weight bold))
2461     (((class color) (min-colors 16) (background dark))
2462      (:foreground "Green" :weight bold))
2463     (((class color)) (:foreground "green" :weight bold))
2464     (t (:weight bold)))
2465   "Basic face used to indicate successful operation."
2466   :version "24.1"
2467   :group 'basic-faces)
2468
2469 \f
2470 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2471 ;;; Manipulating font names.
2472 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2473
2474 ;; This is here for compatibility with Emacs 20.2.  For example,
2475 ;; international/fontset.el uses x-resolve-font-name.  The following
2476 ;; functions are not used in the face implementation itself.
2477
2478 (defvar x-font-regexp nil)
2479 (defvar x-font-regexp-head nil)
2480 (defvar x-font-regexp-weight nil)
2481 (defvar x-font-regexp-slant nil)
2482
2483 (defconst x-font-regexp-weight-subnum 1)
2484 (defconst x-font-regexp-slant-subnum 2)
2485 (defconst x-font-regexp-swidth-subnum 3)
2486 (defconst x-font-regexp-adstyle-subnum 4)
2487
2488 ;;; Regexps matching font names in "Host Portable Character Representation."
2489 ;;;
2490 (let ((-                "[-?]")
2491       (foundry          "[^-]+")
2492       (family           "[^-]+")
2493       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2494 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2495       (weight\?         "\\([^-]*\\)")                                  ; 1
2496       (slant            "\\([ior]\\)")                                  ; 2
2497 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2498       (slant\?          "\\([^-]?\\)")                                  ; 2
2499 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2500       (swidth           "\\([^-]*\\)")                                  ; 3
2501 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2502       (adstyle          "\\([^-]*\\)")                                  ; 4
2503       (pixelsize        "[0-9]+")
2504       (pointsize        "[0-9][0-9]+")
2505       (resx             "[0-9][0-9]+")
2506       (resy             "[0-9][0-9]+")
2507       (spacing          "[cmp?*]")
2508       (avgwidth         "[0-9]+")
2509       (registry         "[^-]+")
2510       (encoding         "[^-]+")
2511       )
2512   (setq x-font-regexp
2513         (purecopy (concat "\\`\\*?[-?*]"
2514                 foundry - family - weight\? - slant\? - swidth - adstyle -
2515                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2516                 registry - encoding "\\*?\\'"
2517                 )))
2518   (setq x-font-regexp-head
2519         (purecopy (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2520                 "\\([-*?]\\|\\'\\)")))
2521   (setq x-font-regexp-slant (purecopy (concat - slant -)))
2522   (setq x-font-regexp-weight (purecopy (concat - weight -)))
2523   nil)
2524
2525
2526 (defun x-resolve-font-name (pattern &optional face frame)
2527   "Return a font name matching PATTERN.
2528 All wildcards in PATTERN are instantiated.
2529 If PATTERN is nil, return the name of the frame's base font, which never
2530 contains wildcards.
2531 Given optional arguments FACE and FRAME, return a font which is
2532 also the same size as FACE on FRAME, or fail."
2533   (or (symbolp face)
2534       (setq face (face-name face)))
2535   (and (eq frame t)
2536        (setq frame nil))
2537   (if pattern
2538       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2539       (let ((fonts (x-list-fonts pattern face frame 1)))
2540         (or fonts
2541             (if face
2542                 (if (string-match "\\*" pattern)
2543                     (if (null (face-font face))
2544                         (error "No matching fonts are the same height as the frame default font")
2545                       (error "No matching fonts are the same height as face `%s'" face))
2546                   (if (null (face-font face))
2547                       (error "Height of font `%s' doesn't match the frame default font"
2548                              pattern)
2549                     (error "Height of font `%s' doesn't match face `%s'"
2550                            pattern face)))
2551               (error "No fonts match `%s'" pattern)))
2552         (car fonts))
2553     (cdr (assq 'font (frame-parameters (selected-frame))))))
2554
2555 (provide 'faces)
2556
2557 ;;; faces.el ends here