lisp/emacs-lisp/timer.el

   1 ;;; timer.el --- run a function with args at some time in future
   2
   3 ;; Copyright (C) 1996, 2001-2012  Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Package: emacs
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This package gives you the capability to run Emacs Lisp commands at
  26 ;; specified times in the future, either as one-shots or periodically.
  27
  28 ;;; Code:
  29
  30 ;; Layout of a timer vector:
  31 ;; [triggered-p high-seconds low-seconds usecs repeat-delay
  32 ;;  function args idle-delay]
  33 ;; triggered-p is nil if the timer is active (waiting to be triggered),
  34 ;;  t if it is inactive ("already triggered", in theory)
  35
  36 (eval-when-compile (require 'cl))
  37
  38 (defstruct (timer
  39             (:constructor nil)
  40             (:copier nil)
  41             (:constructor timer-create ())
  42             (:type vector)
  43             (:conc-name timer--))
  44   (triggered t)
  45   high-seconds low-seconds usecs repeat-delay function args idle-delay)
  46
  47 (defun timerp (object)
  48   "Return t if OBJECT is a timer."
  49   (and (vectorp object) (= (length object) 8)))
  50
  51 ;; Pseudo field `time'.
  52 (defun timer--time (timer)
  53   (list (timer--high-seconds timer)
  54         (timer--low-seconds timer)
  55         (timer--usecs timer)))
  56
  57 (defsetf timer--time
  58   (lambda (timer time)
  59     (or (timerp timer) (error "Invalid timer"))
  60     (setf (timer--high-seconds timer) (pop time))
  61     (setf (timer--low-seconds timer)
  62           (if (consp time) (car time) time))
  63     (setf (timer--usecs timer) (or (and (consp time) (consp (cdr time))
  64                                         (cadr time))
  65                                    0))))
  66
  67
  68 (defun timer-set-time (timer time &optional delta)
  69   "Set the trigger time of TIMER to TIME.
  70 TIME must be in the internal format returned by, e.g., `current-time'.
  71 If optional third argument DELTA is a positive number, make the timer
  72 fire repeatedly that many seconds apart."
  73   (setf (timer--time timer) time)
  74   (setf (timer--repeat-delay timer) (and (numberp delta) (> delta 0) delta))
  75   timer)
  76
  77 (defun timer-set-idle-time (timer secs &optional repeat)
  78   "Set the trigger idle time of TIMER to SECS.
  79 SECS may be an integer, floating point number, or the internal
  80 time format (HIGH LOW USECS) returned by, e.g., `current-idle-time'.
  81 If optional third argument REPEAT is non-nil, make the timer
  82 fire each time Emacs is idle for that many seconds."
  83   (if (consp secs)
  84       (setf (timer--time timer) secs)
  85     (setf (timer--time timer) '(0 0 0))
  86     (timer-inc-time timer secs))
  87   (setf (timer--repeat-delay timer) repeat)
  88   timer)
  89
  90 (defun timer-next-integral-multiple-of-time (time secs)
  91   "Yield the next value after TIME that is an integral multiple of SECS.
  92 More precisely, the next value, after TIME, that is an integral multiple
  93 of SECS seconds since the epoch.  SECS may be a fraction."
  94   (let ((time-base (ash 1 16)))
  95     ;; Use floating point, taking care to not lose precision.
  96     (let* ((float-time-base (float time-base))
  97            (million 1000000.0)
  98            (time-usec (+ (* million
  99                             (+ (* float-time-base (nth 0 time))
 100                                (nth 1 time)))
 101                          (nth 2 time)))
 102            (secs-usec (* million secs))
 103            (mod-usec (mod time-usec secs-usec))
 104            (next-usec (+ (- time-usec mod-usec) secs-usec))
 105            (time-base-million (* float-time-base million)))
 106       (list (floor next-usec time-base-million)
 107             (floor (mod next-usec time-base-million) million)
 108             (floor (mod next-usec million))))))
 109
 110 (defun timer-relative-time (time secs &optional usecs)
 111   "Advance TIME by SECS seconds and optionally USECS microseconds.
 112 SECS may be either an integer or a floating point number."
 113   (let ((delta (if (floatp secs)
 114                    (seconds-to-time secs)
 115                  (list (floor secs 65536) (mod secs 65536)))))
 116     (if usecs
 117         (setq delta (time-add delta (list 0 0 usecs))))
 118     (time-add time delta)))
 119
 120 (defun timer--time-less-p (t1 t2)
 121   "Say whether time value T1 is less than time value T2."
 122   (time-less-p (timer--time t1) (timer--time t2)))
 123
 124 (defun timer-inc-time (timer secs &optional usecs)
 125   "Increment the time set in TIMER by SECS seconds and USECS microseconds.
 126 SECS may be a fraction.  If USECS is omitted, that means it is zero."
 127   (setf (timer--time timer)
 128         (timer-relative-time (timer--time timer) secs usecs)))
 129
 130 (defun timer-set-time-with-usecs (timer time usecs &optional delta)
 131   "Set the trigger time of TIMER to TIME plus USECS.
 132 TIME must be in the internal format returned by, e.g., `current-time'.
 133 The microsecond count from TIME is ignored, and USECS is used instead.
 134 If optional fourth argument DELTA is a positive number, make the timer
 135 fire repeatedly that many seconds apart."
 136   (setf (timer--time timer) time)
 137   (setf (timer--usecs timer) usecs)
 138   (setf (timer--repeat-delay timer) (and (numberp delta) (> delta 0) delta))
 139   timer)
 140 (make-obsolete 'timer-set-time-with-usecs
 141                "use `timer-set-time' and `timer-inc-time' instead."
 142                "22.1")
 143
 144 (defun timer-set-function (timer function &optional args)
 145   "Make TIMER call FUNCTION with optional ARGS when triggering."
 146   (or (timerp timer)
 147       (error "Invalid timer"))
 148   (setf (timer--function timer) function)
 149   (setf (timer--args timer) args)
 150   timer)
 151 \f
 152 (defun timer--activate (timer &optional triggered-p reuse-cell idle)
 153   (if (and (timerp timer)
 154            (integerp (timer--high-seconds timer))
 155            (integerp (timer--low-seconds timer))
 156            (integerp (timer--usecs timer))
 157            (timer--function timer))
 158       (let ((timers (if idle timer-idle-list timer-list))
 159             last)
 160         ;; Skip all timers to trigger before the new one.
 161         (while (and timers (timer--time-less-p (car timers) timer))
 162           (setq last timers
 163                 timers (cdr timers)))
 164         (if reuse-cell
 165             (progn
 166               (setcar reuse-cell timer)
 167               (setcdr reuse-cell timers))
 168           (setq reuse-cell (cons timer timers)))
 169         ;; Insert new timer after last which possibly means in front of queue.
 170         (cond (last (setcdr last reuse-cell))
 171               (idle (setq timer-idle-list reuse-cell))
 172               (t    (setq timer-list reuse-cell)))
 173         (setf (timer--triggered timer) triggered-p)
 174         (setf (timer--idle-delay timer) idle)
 175         nil)
 176     (error "Invalid or uninitialized timer")))
 177
 178 (defun timer-activate (timer &optional triggered-p reuse-cell)
 179   "Insert TIMER into `timer-list'.
 180 If TRIGGERED-P is t, make TIMER inactive (put it on the list, but
 181 mark it as already triggered).  To remove it, use `cancel-timer'.
 182
 183 REUSE-CELL, if non-nil, is a cons cell to reuse when inserting
 184 TIMER into `timer-list' (usually a cell removed from that list by
 185 `cancel-timer-internal'; using this reduces consing for repeat
 186 timers).  If nil, allocate a new cell."
 187   (timer--activate timer triggered-p reuse-cell nil))
 188
 189 (defun timer-activate-when-idle (timer &optional dont-wait reuse-cell)
 190   "Insert TIMER into `timer-idle-list'.
 191 This arranges to activate TIMER whenever Emacs is next idle.
 192 If optional argument DONT-WAIT is non-nil, set TIMER to activate
 193 immediately, or at the right time, if Emacs is already idle.
 194
 195 REUSE-CELL, if non-nil, is a cons cell to reuse when inserting
 196 TIMER into `timer-idle-list' (usually a cell removed from that
 197 list by `cancel-timer-internal'; using this reduces consing for
 198 repeat timers).  If nil, allocate a new cell."
 199   (timer--activate timer (not dont-wait) reuse-cell 'idle))
 200
 201 (defalias 'disable-timeout 'cancel-timer)
 202
 203 (defun cancel-timer (timer)
 204   "Remove TIMER from the list of active timers."
 205   (or (timerp timer)
 206       (error "Invalid timer"))
 207   (setq timer-list (delq timer timer-list))
 208   (setq timer-idle-list (delq timer timer-idle-list))
 209   nil)
 210
 211 (defun cancel-timer-internal (timer)
 212   "Remove TIMER from the list of active timers or idle timers.
 213 Only to be used in this file.  It returns the cons cell
 214 that was removed from the timer list."
 215   (let ((cell1 (memq timer timer-list))
 216         (cell2 (memq timer timer-idle-list)))
 217     (if cell1
 218         (setq timer-list (delq timer timer-list)))
 219     (if cell2
 220         (setq timer-idle-list (delq timer timer-idle-list)))
 221     (or cell1 cell2)))
 222
 223 (defun cancel-function-timers (function)
 224   "Cancel all timers which would run FUNCTION.
 225 This affects ordinary timers such as are scheduled by `run-at-time',
 226 and idle timers such as are scheduled by `run-with-idle-timer'."
 227   (interactive "aCancel timers of function: ")
 228   (dolist (timer timer-list)
 229     (if (eq (timer--function timer) function)
 230         (setq timer-list (delq timer timer-list))))
 231   (dolist (timer timer-idle-list)
 232     (if (eq (timer--function timer) function)
 233         (setq timer-idle-list (delq timer timer-idle-list)))))
 234 \f
 235 ;; Record the last few events, for debugging.
 236 (defvar timer-event-last nil
 237   "Last timer that was run.")
 238 (defvar timer-event-last-1 nil
 239   "Next-to-last timer that was run.")
 240 (defvar timer-event-last-2 nil
 241   "Third-to-last timer that was run.")
 242
 243 (defvar timer-max-repeats 10
 244   "*Maximum number of times to repeat a timer, if many repeats are delayed.
 245 Timer invocations can be delayed because Emacs is suspended or busy,
 246 or because the system's time changes.  If such an occurrence makes it
 247 appear that many invocations are overdue, this variable controls
 248 how many will really happen.")
 249
 250 (defun timer-until (timer time)
 251   "Calculate number of seconds from when TIMER will run, until TIME.
 252 TIMER is a timer, and stands for the time when its next repeat is scheduled.
 253 TIME is a time-list."
 254   (float-time (time-subtract time (timer--time timer))))
 255
 256 (defun timer-event-handler (timer)
 257   "Call the handler for the timer TIMER.
 258 This function is called, by name, directly by the C code."
 259   (setq timer-event-last-2 timer-event-last-1)
 260   (setq timer-event-last-1 timer-event-last)
 261   (setq timer-event-last timer)
 262   (let ((inhibit-quit t))
 263     (if (timerp timer)
 264         (let (retrigger cell)
 265           ;; Delete from queue.  Record the cons cell that was used.
 266           (setq cell (cancel-timer-internal timer))
 267           ;; Re-schedule if requested.
 268           (if (timer--repeat-delay timer)
 269               (if (timer--idle-delay timer)
 270                   (timer-activate-when-idle timer nil cell)
 271                 (timer-inc-time timer (timer--repeat-delay timer) 0)
 272                 ;; If real time has jumped forward,
 273                 ;; perhaps because Emacs was suspended for a long time,
 274                 ;; limit how many times things get repeated.
 275                 (if (and (numberp timer-max-repeats)
 276                          (< 0 (timer-until timer (current-time))))
 277                     (let ((repeats (/ (timer-until timer (current-time))
 278                                       (timer--repeat-delay timer))))
 279                       (if (> repeats timer-max-repeats)
 280                           (timer-inc-time timer (* (timer--repeat-delay timer)
 281                                                    repeats)))))
 282                 (timer-activate timer t cell)
 283                 (setq retrigger t)))
 284           ;; Run handler.
 285           ;; We do this after rescheduling so that the handler function
 286           ;; can cancel its own timer successfully with cancel-timer.
 287           (condition-case nil
 288               ;; Timer functions should not change the current buffer.
 289               ;; If they do, all kinds of nasty surprises can happen,
 290               ;; and it can be hellish to track down their source.
 291               (save-current-buffer
 292                 (apply (timer--function timer) (timer--args timer)))
 293             (error nil))
 294           (if retrigger
 295               (setf (timer--triggered timer) nil)))
 296       (error "Bogus timer event"))))
 297
 298 ;; This function is incompatible with the one in levents.el.
 299 (defun timeout-event-p (event)
 300   "Non-nil if EVENT is a timeout event."
 301   (and (listp event) (eq (car event) 'timer-event)))
 302 \f
 303
 304 (declare-function diary-entry-time "diary-lib" (s))
 305
 306 (defun run-at-time (time repeat function &rest args)
 307   "Perform an action at time TIME.
 308 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 309 TIME should be one of: a string giving an absolute time like
 310 \"11:23pm\" (the acceptable formats are those recognized by
 311 `diary-entry-time'; note that such times are interpreted as times
 312 today, even if in the past); a string giving a relative time like
 313 \"2 hours 35 minutes\" (the acceptable formats are those
 314 recognized by `timer-duration'); nil meaning now; a number of
 315 seconds from now; a value from `encode-time'; or t (with non-nil
 316 REPEAT) meaning the next integral multiple of REPEAT.  REPEAT may
 317 be an integer or floating point number.  The action is to call
 318 FUNCTION with arguments ARGS.
 319
 320 This function returns a timer object which you can use in `cancel-timer'."
 321   (interactive "sRun at time: \nNRepeat interval: \naFunction: ")
 322
 323   (or (null repeat)
 324       (and (numberp repeat) (< 0 repeat))
 325       (error "Invalid repetition interval"))
 326
 327   ;; Special case: nil means "now" and is useful when repeating.
 328   (if (null time)
 329       (setq time (current-time)))
 330
 331   ;; Special case: t means the next integral multiple of REPEAT.
 332   (if (and (eq time t) repeat)
 333       (setq time (timer-next-integral-multiple-of-time (current-time) repeat)))
 334
 335   ;; Handle numbers as relative times in seconds.
 336   (if (numberp time)
 337       (setq time (timer-relative-time (current-time) time)))
 338
 339   ;; Handle relative times like "2 hours 35 minutes"
 340   (if (stringp time)
 341       (let ((secs (timer-duration time)))
 342         (if secs
 343             (setq time (timer-relative-time (current-time) secs)))))
 344
 345   ;; Handle "11:23pm" and the like.  Interpret it as meaning today
 346   ;; which admittedly is rather stupid if we have passed that time
 347   ;; already.  (Though only Emacs hackers hack Emacs at that time.)
 348   (if (stringp time)
 349       (progn
 350         (require 'diary-lib)
 351         (let ((hhmm (diary-entry-time time))
 352               (now (decode-time)))
 353           (if (>= hhmm 0)
 354               (setq time
 355                     (encode-time 0 (% hhmm 100) (/ hhmm 100) (nth 3 now)
 356                                  (nth 4 now) (nth 5 now) (nth 8 now)))))))
 357
 358   (or (consp time)
 359       (error "Invalid time format"))
 360
 361   (let ((timer (timer-create)))
 362     (timer-set-time timer time repeat)
 363     (timer-set-function timer function args)
 364     (timer-activate timer)
 365     timer))
 366
 367 (defun run-with-timer (secs repeat function &rest args)
 368   "Perform an action after a delay of SECS seconds.
 369 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 370 SECS and REPEAT may be integers or floating point numbers.
 371 The action is to call FUNCTION with arguments ARGS.
 372
 373 This function returns a timer object which you can use in `cancel-timer'."
 374   (interactive "sRun after delay (seconds): \nNRepeat interval: \naFunction: ")
 375   (apply 'run-at-time secs repeat function args))
 376
 377 (defun add-timeout (secs function object &optional repeat)
 378   "Add a timer to run SECS seconds from now, to call FUNCTION on OBJECT.
 379 If REPEAT is non-nil, repeat the timer every REPEAT seconds.
 380 This function is for compatibility; see also `run-with-timer'."
 381   (run-with-timer secs repeat function object))
 382
 383 (defun run-with-idle-timer (secs repeat function &rest args)
 384   "Perform an action the next time Emacs is idle for SECS seconds.
 385 The action is to call FUNCTION with arguments ARGS.
 386 SECS may be an integer, a floating point number, or the internal
 387 time format (HIGH LOW USECS) returned by, e.g., `current-idle-time'.
 388 If Emacs is currently idle, and has been idle for N seconds (N < SECS),
 389 then it will call FUNCTION in SECS - N seconds from now.
 390
 391 If REPEAT is non-nil, do the action each time Emacs has been idle for
 392 exactly SECS seconds (that is, only once for each time Emacs becomes idle).
 393
 394 This function returns a timer object which you can use in `cancel-timer'."
 395   (interactive
 396    (list (read-from-minibuffer "Run after idle (seconds): " nil nil t)
 397          (y-or-n-p "Repeat each time Emacs is idle? ")
 398          (intern (completing-read "Function: " obarray 'fboundp t))))
 399   (let ((timer (timer-create)))
 400     (timer-set-function timer function args)
 401     (timer-set-idle-time timer secs repeat)
 402     (timer-activate-when-idle timer t)
 403     timer))
 404 \f
 405 (defvar with-timeout-timers nil
 406   "List of all timers used by currently pending `with-timeout' calls.")
 407
 408 (defmacro with-timeout (list &rest body)
 409   "Run BODY, but if it doesn't finish in SECONDS seconds, give up.
 410 If we give up, we run the TIMEOUT-FORMS and return the value of the last one.
 411 The timeout is checked whenever Emacs waits for some kind of external
 412 event (such as keyboard input, input from subprocesses, or a certain time);
 413 if the program loops without waiting in any way, the timeout will not
 414 be detected.
 415 \n(fn (SECONDS TIMEOUT-FORMS...) BODY)"
 416   (declare (indent 1) (debug ((form body) body)))
 417   (let ((seconds (car list))
 418         (timeout-forms (cdr list))
 419         (timeout (make-symbol "timeout")))
 420     `(let ((-with-timeout-value-
 421             (catch ',timeout
 422               (let* ((-with-timeout-timer-
 423                       (run-with-timer ,seconds nil
 424                                       (lambda () (throw ',timeout ',timeout))))
 425                      (with-timeout-timers
 426                          (cons -with-timeout-timer- with-timeout-timers)))
 427                 (unwind-protect
 428                     ,@body
 429                   (cancel-timer -with-timeout-timer-))))))
 430        ;; It is tempting to avoid the `if' altogether and instead run
 431        ;; timeout-forms in the timer, just before throwing `timeout'.
 432        ;; But that would mean that timeout-forms are run in the deeper
 433        ;; dynamic context of the timer, with inhibit-quit set etc...
 434        (if (eq -with-timeout-value- ',timeout)
 435            (progn ,@timeout-forms)
 436          -with-timeout-value-))))
 437
 438 (defun with-timeout-suspend ()
 439   "Stop the clock for `with-timeout'.  Used by debuggers.
 440 The idea is that the time you spend in the debugger should not
 441 count against these timeouts.
 442
 443 The value is a list that the debugger can pass to `with-timeout-unsuspend'
 444 when it exits, to make these timers start counting again."
 445   (mapcar (lambda (timer)
 446             (cancel-timer timer)
 447             (list timer (time-subtract (timer--time timer) (current-time))))
 448           with-timeout-timers))
 449
 450 (defun with-timeout-unsuspend (timer-spec-list)
 451   "Restart the clock for `with-timeout'.
 452 The argument should be a value previously returned by `with-timeout-suspend'."
 453   (dolist (elt timer-spec-list)
 454     (let ((timer (car elt))
 455           (delay (cadr elt)))
 456       (timer-set-time timer (time-add (current-time) delay))
 457       (timer-activate timer))))
 458
 459 (defun y-or-n-p-with-timeout (prompt seconds default-value)
 460   "Like (y-or-n-p PROMPT), with a timeout.
 461 If the user does not answer after SECONDS seconds, return DEFAULT-VALUE."
 462   (with-timeout (seconds default-value)
 463     (y-or-n-p prompt)))
 464 \f
 465 (defconst timer-duration-words
 466   (list (cons "microsec" 0.000001)
 467         (cons "microsecond" 0.000001)
 468         (cons "millisec" 0.001)
 469         (cons "millisecond" 0.001)
 470         (cons "sec" 1)
 471         (cons "second" 1)
 472         (cons "min" 60)
 473         (cons "minute" 60)
 474         (cons "hour" (* 60 60))
 475         (cons "day" (* 24 60 60))
 476         (cons "week" (* 7 24 60 60))
 477         (cons "fortnight" (* 14 24 60 60))
 478         (cons "month" (* 30 24 60 60))    ; Approximation
 479         (cons "year" (* 365.25 24 60 60)) ; Approximation
 480         )
 481   "Alist mapping temporal words to durations in seconds.")
 482
 483 (defun timer-duration (string)
 484   "Return number of seconds specified by STRING, or nil if parsing fails."
 485   (let ((secs 0)
 486         (start 0)
 487         (case-fold-search t))
 488     (while (string-match
 489             "[ \t]*\\([0-9.]+\\)?[ \t]*\\([a-z]+[a-rt-z]\\)s?[ \t]*"
 490             string start)
 491       (let ((count (if (match-beginning 1)
 492                        (string-to-number (match-string 1 string))
 493                      1))
 494             (itemsize (cdr (assoc (match-string 2 string)
 495                                   timer-duration-words))))
 496         (if itemsize
 497             (setq start (match-end 0)
 498                   secs (+ secs (* count itemsize)))
 499           (setq secs nil
 500                 start (length string)))))
 501     (if (= start (length string))
 502         secs
 503       (if (string-match-p "\\`[0-9.]+\\'" string)
 504           (string-to-number string)))))
 505 \f
 506 (provide 'timer)
 507
 508 ;;; timer.el ends here