lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998-2012  Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: multimedia
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28
  29 (defgroup image ()
  30   "Image support."
  31   :group 'multimedia)
  32
  33 (defalias 'image-refresh 'image-flush)
  34
  35 (defconst image-type-header-regexps
  36   `(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  37     ("\\`P[1-6][[:space:]]+\\(?:#.*[[:space:]]+\\)*[0-9]+[[:space:]]+[0-9]+" . pbm)
  38     ("\\`GIF8[79]a" . gif)
  39     ("\\`\x89PNG\r\n\x1a\n" . png)
  40     ("\\`[\t\n\r ]*#define \\([a-z0-9_]+\\)_width [0-9]+\n\
  41 #define \\1_height [0-9]+\n\\(\
  42 #define \\1_x_hot [0-9]+\n\
  43 #define \\1_y_hot [0-9]+\n\\)?\
  44 static \\(unsigned \\)?char \\1_bits" . xbm)
  45     ("\\`\\(?:MM\0\\*\\|II\\*\0\\)" . tiff)
  46     ("\\`[\t\n\r ]*%!PS" . postscript)
  47     ("\\`\xff\xd8" . jpeg)    ; used to be (image-jpeg-p . jpeg)
  48     (,(let* ((incomment-re "\\(?:[^-]\\|-[^-]\\)")
  49              (comment-re (concat "\\(?:!--" incomment-re "*-->[ \t\r\n]*<\\)")))
  50         (concat "\\(?:<\\?xml[ \t\r\n]+[^>]*>\\)?[ \t\r\n]*<"
  51                 comment-re "*"
  52                 "\\(?:!DOCTYPE[ \t\r\n]+[^>]*>[ \t\r\n]*<[ \t\r\n]*" comment-re "*\\)?"
  53                 "[Ss][Vv][Gg]"))
  54      . svg)
  55     )
  56   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  57 When the first bytes of an image file match REGEXP, it is assumed to
  58 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  59 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  60 with one argument, a string containing the image data.  If PREDICATE returns
  61 a non-nil value, TYPE is the image's type.")
  62
  63 (defvar image-type-file-name-regexps
  64   '(("\\.png\\'" . png)
  65     ("\\.gif\\'" . gif)
  66     ("\\.jpe?g\\'" . jpeg)
  67     ("\\.bmp\\'" . bmp)
  68     ("\\.xpm\\'" . xpm)
  69     ("\\.pbm\\'" . pbm)
  70     ("\\.xbm\\'" . xbm)
  71     ("\\.ps\\'" . postscript)
  72     ("\\.tiff?\\'" . tiff)
  73     ("\\.svgz?\\'" . svg)
  74     )
  75   "Alist of (REGEXP . IMAGE-TYPE) pairs used to identify image files.
  76 When the name of an image file match REGEXP, it is assumed to
  77 be of image type IMAGE-TYPE.")
  78
  79 ;; We rely on `auto-mode-alist' to detect xbm and xpm files, instead
  80 ;; of content autodetection.  Their contents are just C code, so it is
  81 ;; easy to generate false matches.
  82 (defvar image-type-auto-detectable
  83   '((pbm . t)
  84     (xbm . nil)
  85     (bmp . maybe)
  86     (gif . maybe)
  87     (png . maybe)
  88     (xpm . nil)
  89     (jpeg . maybe)
  90     (tiff . maybe)
  91     (svg . maybe)
  92     (postscript . nil))
  93   "Alist of (IMAGE-TYPE . AUTODETECT) pairs used to auto-detect image files.
  94 \(See `image-type-auto-detected-p').
  95
  96 AUTODETECT can be
  97  - t      always auto-detect.
  98  - nil    never auto-detect.
  99  - maybe  auto-detect only if the image type is available
 100             (see `image-type-available-p').")
 101
 102 (defcustom image-load-path
 103   (list (file-name-as-directory (expand-file-name "images" data-directory))
 104         'data-directory 'load-path)
 105   "List of locations in which to search for image files.
 106 If an element is a string, it defines a directory to search.
 107 If an element is a variable symbol whose value is a string, that
 108 value defines a directory to search.
 109 If an element is a variable symbol whose value is a list, the
 110 value is used as a list of directories to search."
 111   :type '(repeat (choice directory variable))
 112   :initialize 'custom-initialize-delay)
 113
 114
 115 (defun image-load-path-for-library (library image &optional path no-error)
 116   "Return a suitable search path for images used by LIBRARY.
 117
 118 It searches for IMAGE in `image-load-path' (excluding
 119 \"`data-directory'/images\") and `load-path', followed by a path
 120 suitable for LIBRARY, which includes \"../../etc/images\" and
 121 \"../etc/images\" relative to the library file itself, and then
 122 in \"`data-directory'/images\".
 123
 124 Then this function returns a list of directories which contains
 125 first the directory in which IMAGE was found, followed by the
 126 value of `load-path'.  If PATH is given, it is used instead of
 127 `load-path'.
 128
 129 If NO-ERROR is non-nil and a suitable path can't be found, don't
 130 signal an error.  Instead, return a list of directories as before,
 131 except that nil appears in place of the image directory.
 132
 133 Here is an example that uses a common idiom to provide
 134 compatibility with versions of Emacs that lack the variable
 135 `image-load-path':
 136
 137     ;; Shush compiler.
 138     (defvar image-load-path)
 139
 140     (let* ((load-path (image-load-path-for-library \"mh-e\" \"mh-logo.xpm\"))
 141            (image-load-path (cons (car load-path)
 142                                   (when (boundp 'image-load-path)
 143                                     image-load-path))))
 144       (mh-tool-bar-folder-buttons-init))"
 145   (unless library (error "No library specified"))
 146   (unless image   (error "No image specified"))
 147   (let (image-directory image-directory-load-path)
 148     ;; Check for images in image-load-path or load-path.
 149     (let ((img image)
 150           (dir (or
 151                 ;; Images in image-load-path.
 152                 (image-search-load-path image)
 153                 ;; Images in load-path.
 154                 (locate-library image)))
 155           parent)
 156       ;; Since the image might be in a nested directory (for
 157       ;; example, mail/attach.pbm), adjust `image-directory'
 158       ;; accordingly.
 159       (when dir
 160         (setq dir (file-name-directory dir))
 161         (while (setq parent (file-name-directory img))
 162           (setq img (directory-file-name parent)
 163                 dir (expand-file-name "../" dir))))
 164       (setq image-directory-load-path dir))
 165
 166     ;; If `image-directory-load-path' isn't Emacs' image directory,
 167     ;; it's probably a user preference, so use it. Then use a
 168     ;; relative setting if possible; otherwise, use
 169     ;; `image-directory-load-path'.
 170     (cond
 171      ;; User-modified image-load-path?
 172      ((and image-directory-load-path
 173            (not (equal image-directory-load-path
 174                        (file-name-as-directory
 175                         (expand-file-name "images" data-directory)))))
 176       (setq image-directory image-directory-load-path))
 177      ;; Try relative setting.
 178      ((let (library-name d1ei d2ei)
 179         ;; First, find library in the load-path.
 180         (setq library-name (locate-library library))
 181         (if (not library-name)
 182             (error "Cannot find library %s in load-path" library))
 183         ;; And then set image-directory relative to that.
 184         (setq
 185          ;; Go down 2 levels.
 186          d2ei (file-name-as-directory
 187                (expand-file-name
 188                 (concat (file-name-directory library-name) "../../etc/images")))
 189          ;; Go down 1 level.
 190          d1ei (file-name-as-directory
 191                (expand-file-name
 192                 (concat (file-name-directory library-name) "../etc/images"))))
 193         (setq image-directory
 194               ;; Set it to nil if image is not found.
 195               (cond ((file-exists-p (expand-file-name image d2ei)) d2ei)
 196                     ((file-exists-p (expand-file-name image d1ei)) d1ei)))))
 197      ;; Use Emacs' image directory.
 198      (image-directory-load-path
 199       (setq image-directory image-directory-load-path))
 200      (no-error
 201       (message "Could not find image %s for library %s" image library))
 202      (t
 203       (error "Could not find image %s for library %s" image library)))
 204
 205     ;; Return an augmented `path' or `load-path'.
 206     (nconc (list image-directory)
 207            (delete image-directory (copy-sequence (or path load-path))))))
 208
 209
 210 (defun image-jpeg-p (data)
 211   "Value is non-nil if DATA, a string, consists of JFIF image data.
 212 We accept the tag Exif because that is the same format."
 213   (setq data (ignore-errors (string-to-unibyte data)))
 214   (when (and data (string-match-p "\\`\xff\xd8" data))
 215     (catch 'jfif
 216       (let ((len (length data)) (i 2))
 217         (while (< i len)
 218           (when (/= (aref data i) #xff)
 219             (throw 'jfif nil))
 220           (setq i (1+ i))
 221           (when (>= (+ i 2) len)
 222             (throw 'jfif nil))
 223           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
 224                            (aref data (+ i 2))))
 225                 (code (aref data i)))
 226             (when (and (>= code #xe0) (<= code #xef))
 227               ;; APP0 LEN1 LEN2 "JFIF\0"
 228               (throw 'jfif
 229                      (string-match-p "JFIF\\|Exif"
 230                                      (substring data i (min (+ i nbytes) len)))))
 231             (setq i (+ i 1 nbytes))))))))
 232
 233
 234 ;;;###autoload
 235 (defun image-type-from-data (data)
 236   "Determine the image type from image data DATA.
 237 Value is a symbol specifying the image type or nil if type cannot
 238 be determined."
 239   (let ((types image-type-header-regexps)
 240         type)
 241     (while types
 242       (let ((regexp (car (car types)))
 243             (image-type (cdr (car types))))
 244         (if (or (and (symbolp image-type)
 245                      (string-match-p regexp data))
 246                 (and (consp image-type)
 247                      (funcall (car image-type) data)
 248                      (setq image-type (cdr image-type))))
 249             (setq type image-type
 250                   types nil)
 251           (setq types (cdr types)))))
 252     type))
 253
 254
 255 ;;;###autoload
 256 (defun image-type-from-buffer ()
 257   "Determine the image type from data in the current buffer.
 258 Value is a symbol specifying the image type or nil if type cannot
 259 be determined."
 260   (let ((types image-type-header-regexps)
 261         type
 262         (opoint (point)))
 263     (goto-char (point-min))
 264     (while types
 265       (let ((regexp (car (car types)))
 266             (image-type (cdr (car types)))
 267             data)
 268         (if (or (and (symbolp image-type)
 269                      (looking-at-p regexp))
 270                 (and (consp image-type)
 271                      (funcall (car image-type)
 272                               (or data
 273                                   (setq data
 274                                         (buffer-substring
 275                                          (point-min)
 276                                          (min (point-max)
 277                                               (+ (point-min) 256))))))
 278                      (setq image-type (cdr image-type))))
 279             (setq type image-type
 280                   types nil)
 281           (setq types (cdr types)))))
 282     (goto-char opoint)
 283     type))
 284
 285
 286 ;;;###autoload
 287 (defun image-type-from-file-header (file)
 288   "Determine the type of image file FILE from its first few bytes.
 289 Value is a symbol specifying the image type, or nil if type cannot
 290 be determined."
 291   (unless (or (file-readable-p file)
 292               (file-name-absolute-p file))
 293     (setq file (image-search-load-path file)))
 294   (and file
 295        (file-readable-p file)
 296        (with-temp-buffer
 297          (set-buffer-multibyte nil)
 298          (insert-file-contents-literally file nil 0 256)
 299          (image-type-from-buffer))))
 300
 301
 302 ;;;###autoload
 303 (defun image-type-from-file-name (file)
 304   "Determine the type of image file FILE from its name.
 305 Value is a symbol specifying the image type, or nil if type cannot
 306 be determined."
 307   (assoc-default file image-type-file-name-regexps 'string-match-p))
 308
 309
 310 ;;;###autoload
 311 (defun image-type (source &optional type data-p)
 312   "Determine and return image type.
 313 SOURCE is an image file name or image data.
 314 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 315 or nil, try to determine the image type from its first few bytes
 316 of image data.  If that doesn't work, and SOURCE is a file name,
 317 use its file extension as image type.
 318 Optional DATA-P non-nil means SOURCE is a string containing image data."
 319   (when (and (not data-p) (not (stringp source)))
 320     (error "Invalid image file name `%s'" source))
 321   (unless type
 322     (setq type (if data-p
 323                    (image-type-from-data source)
 324                  (or (image-type-from-file-header source)
 325                      (image-type-from-file-name source))))
 326     (or type (error "Cannot determine image type")))
 327   (or (memq type (and (boundp 'image-types) image-types))
 328       (error "Invalid image type `%s'" type))
 329   type)
 330
 331
 332 (if (fboundp 'image-metadata)           ; eg not --without-x
 333     (define-obsolete-function-alias 'image-extension-data
 334       'image-metadata' "24.1"))
 335
 336 (define-obsolete-variable-alias
 337     'image-library-alist
 338     'dynamic-library-alist "24.1")
 339
 340 ;;;###autoload
 341 (defun image-type-available-p (type)
 342   "Return non-nil if image type TYPE is available.
 343 Image types are symbols like `xbm' or `jpeg'."
 344   (and (fboundp 'init-image-library)
 345        (init-image-library type dynamic-library-alist)))
 346
 347
 348 ;;;###autoload
 349 (defun image-type-auto-detected-p ()
 350   "Return t if the current buffer contains an auto-detectable image.
 351 This function is intended to be used from `magic-fallback-mode-alist'.
 352
 353 The buffer is considered to contain an auto-detectable image if
 354 its beginning matches an image type in `image-type-header-regexps',
 355 and that image type is present in `image-type-auto-detectable' with a
 356 non-nil value.  If that value is non-nil, but not t, then the image type
 357 must be available."
 358   (let* ((type (image-type-from-buffer))
 359          (auto (and type (cdr (assq type image-type-auto-detectable)))))
 360     (and auto
 361          (or (eq auto t) (image-type-available-p type)))))
 362
 363
 364 ;;;###autoload
 365 (defun create-image (file-or-data &optional type data-p &rest props)
 366   "Create an image.
 367 FILE-OR-DATA is an image file name or image data.
 368 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 369 or nil, try to determine the image type from its first few bytes
 370 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 371 use its file extension as image type.
 372 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 373 Optional PROPS are additional image attributes to assign to the image,
 374 like, e.g. `:mask MASK'.
 375 Value is the image created, or nil if images of type TYPE are not supported.
 376
 377 Images should not be larger than specified by `max-image-size'.
 378
 379 Image file names that are not absolute are searched for in the
 380 \"images\" sub-directory of `data-directory' and
 381 `x-bitmap-file-path' (in that order)."
 382   ;; It is x_find_image_file in image.c that sets the search path.
 383   (setq type (image-type file-or-data type data-p))
 384   (when (image-type-available-p type)
 385     (append (list 'image :type type (if data-p :data :file) file-or-data)
 386             props)))
 387
 388
 389 ;;;###autoload
 390 (defun put-image (image pos &optional string area)
 391   "Put image IMAGE in front of POS in the current buffer.
 392 IMAGE must be an image created with `create-image' or `defimage'.
 393 IMAGE is displayed by putting an overlay into the current buffer with a
 394 `before-string' STRING that has a `display' property whose value is the
 395 image.  STRING is defaulted if you omit it.
 396 The overlay created will have the `put-image' property set to t.
 397 POS may be an integer or marker.
 398 AREA is where to display the image.  AREA nil or omitted means
 399 display it in the text area, a value of `left-margin' means
 400 display it in the left marginal area, a value of `right-margin'
 401 means display it in the right marginal area."
 402   (unless string (setq string "x"))
 403   (let ((buffer (current-buffer)))
 404     (unless (eq (car-safe image) 'image)
 405       (error "Not an image: %s" image))
 406     (unless (or (null area) (memq area '(left-margin right-margin)))
 407       (error "Invalid area %s" area))
 408     (setq string (copy-sequence string))
 409     (let ((overlay (make-overlay pos pos buffer))
 410           (prop (if (null area) image (list (list 'margin area) image))))
 411       (put-text-property 0 (length string) 'display prop string)
 412       (overlay-put overlay 'put-image t)
 413       (overlay-put overlay 'before-string string))))
 414
 415
 416 ;;;###autoload
 417 (defun insert-image (image &optional string area slice)
 418   "Insert IMAGE into current buffer at point.
 419 IMAGE is displayed by inserting STRING into the current buffer
 420 with a `display' property whose value is the image.  STRING
 421 defaults to the empty string if you omit it.
 422 AREA is where to display the image.  AREA nil or omitted means
 423 display it in the text area, a value of `left-margin' means
 424 display it in the left marginal area, a value of `right-margin'
 425 means display it in the right marginal area.
 426 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 427 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 428 specifying the X and Y positions and WIDTH and HEIGHT of image area
 429 to insert.  A float value 0.0 - 1.0 means relative to the width or
 430 height of the image; integer values are taken as pixel values."
 431   ;; Use a space as least likely to cause trouble when it's a hidden
 432   ;; character in the buffer.
 433   (unless string (setq string " "))
 434   (unless (eq (car-safe image) 'image)
 435     (error "Not an image: %s" image))
 436   (unless (or (null area) (memq area '(left-margin right-margin)))
 437     (error "Invalid area %s" area))
 438   (if area
 439       (setq image (list (list 'margin area) image))
 440     ;; Cons up a new spec equal but not eq to `image' so that
 441     ;; inserting it twice in a row (adjacently) displays two copies of
 442     ;; the image.  Don't try to avoid this by looking at the display
 443     ;; properties on either side so that we DTRT more often with
 444     ;; cut-and-paste.  (Yanking killed image text next to another copy
 445     ;; of it loses anyway.)
 446     (setq image (cons 'image (cdr image))))
 447   (let ((start (point)))
 448     (insert string)
 449     (add-text-properties start (point)
 450                          `(display ,(if slice
 451                                         (list (cons 'slice slice) image)
 452                                       image) rear-nonsticky (display)))))
 453
 454
 455 ;;;###autoload
 456 (defun insert-sliced-image (image &optional string area rows cols)
 457   "Insert IMAGE into current buffer at point.
 458 IMAGE is displayed by inserting STRING into the current buffer
 459 with a `display' property whose value is the image.  STRING is
 460 defaulted if you omit it.
 461 AREA is where to display the image.  AREA nil or omitted means
 462 display it in the text area, a value of `left-margin' means
 463 display it in the left marginal area, a value of `right-margin'
 464 means display it in the right marginal area.
 465 The image is automatically split into ROWS x COLS slices."
 466   (unless string (setq string " "))
 467   (unless (eq (car-safe image) 'image)
 468     (error "Not an image: %s" image))
 469   (unless (or (null area) (memq area '(left-margin right-margin)))
 470     (error "Invalid area %s" area))
 471   (if area
 472       (setq image (list (list 'margin area) image))
 473     ;; Cons up a new spec equal but not eq to `image' so that
 474     ;; inserting it twice in a row (adjacently) displays two copies of
 475     ;; the image.  Don't try to avoid this by looking at the display
 476     ;; properties on either side so that we DTRT more often with
 477     ;; cut-and-paste.  (Yanking killed image text next to another copy
 478     ;; of it loses anyway.)
 479     (setq image (cons 'image (cdr image))))
 480   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 481          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 482     (while (< y 1.0)
 483       (while (< x 1.0)
 484         (let ((start (point)))
 485           (insert string)
 486           (add-text-properties start (point)
 487                                `(display ,(list (list 'slice x y dx dy) image)
 488                                          rear-nonsticky (display)))
 489           (setq x (+ x dx))))
 490       (setq x 0.0
 491             y (+ y dy))
 492       (insert (propertize "\n" 'line-height t)))))
 493
 494
 495
 496 ;;;###autoload
 497 (defun remove-images (start end &optional buffer)
 498   "Remove images between START and END in BUFFER.
 499 Remove only images that were put in BUFFER with calls to `put-image'.
 500 BUFFER nil or omitted means use the current buffer."
 501   (unless buffer
 502     (setq buffer (current-buffer)))
 503   (let ((overlays (overlays-in start end)))
 504     (while overlays
 505       (let ((overlay (car overlays)))
 506         (when (overlay-get overlay 'put-image)
 507           (delete-overlay overlay)))
 508       (setq overlays (cdr overlays)))))
 509
 510 (defun image-search-load-path (file &optional path)
 511   (unless path
 512     (setq path image-load-path))
 513   (let (element found filename)
 514     (while (and (not found) (consp path))
 515       (setq element (car path))
 516       (cond
 517        ((stringp element)
 518         (setq found
 519               (file-readable-p
 520                (setq filename (expand-file-name file element)))))
 521        ((and (symbolp element) (boundp element))
 522         (setq element (symbol-value element))
 523         (cond
 524          ((stringp element)
 525           (setq found
 526                 (file-readable-p
 527                  (setq filename (expand-file-name file element)))))
 528          ((consp element)
 529           (if (setq filename (image-search-load-path file element))
 530               (setq found t))))))
 531       (setq path (cdr path)))
 532     (if found filename)))
 533
 534 ;;;###autoload
 535 (defun find-image (specs)
 536   "Find an image, choosing one of a list of image specifications.
 537
 538 SPECS is a list of image specifications.
 539
 540 Each image specification in SPECS is a property list.  The contents of
 541 a specification are image type dependent.  All specifications must at
 542 least contain the properties `:type TYPE' and either `:file FILE' or
 543 `:data DATA', where TYPE is a symbol specifying the image type,
 544 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 545 string containing the actual image data.  The specification whose TYPE
 546 is supported, and FILE exists, is used to construct the image
 547 specification to be returned.  Return nil if no specification is
 548 satisfied.
 549
 550 The image is looked for in `image-load-path'.
 551
 552 Image files should not be larger than specified by `max-image-size'."
 553   (let (image)
 554     (while (and specs (null image))
 555       (let* ((spec (car specs))
 556              (type (plist-get spec :type))
 557              (data (plist-get spec :data))
 558              (file (plist-get spec :file))
 559              found)
 560         (when (image-type-available-p type)
 561           (cond ((stringp file)
 562                  (if (setq found (image-search-load-path file))
 563                      (setq image
 564                            (cons 'image (plist-put (copy-sequence spec)
 565                                                    :file found)))))
 566                 ((not (null data))
 567                  (setq image (cons 'image spec)))))
 568         (setq specs (cdr specs))))
 569     image))
 570
 571
 572 ;;;###autoload
 573 (defmacro defimage (symbol specs &optional doc)
 574   "Define SYMBOL as an image.
 575
 576 SPECS is a list of image specifications.  DOC is an optional
 577 documentation string.
 578
 579 Each image specification in SPECS is a property list.  The contents of
 580 a specification are image type dependent.  All specifications must at
 581 least contain the properties `:type TYPE' and either `:file FILE' or
 582 `:data DATA', where TYPE is a symbol specifying the image type,
 583 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 584 string containing the actual image data.  The first image
 585 specification whose TYPE is supported, and FILE exists, is used to
 586 define SYMBOL.
 587
 588 Example:
 589
 590    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 591                          (:type xbm :file \"~/test1.xbm\")))"
 592   (declare (doc-string 3))
 593   `(defvar ,symbol (find-image ',specs) ,doc))
 594
 595 \f
 596 ;;; Animated image API
 597
 598 (defconst image-animated-types '(gif)
 599   "List of supported animated image types.")
 600
 601 (defun image-animated-p (image)
 602   "Return non-nil if IMAGE can be animated.
 603 To be capable of being animated, an image must be of a type
 604 listed in `image-animated-types', and contain more than one
 605 sub-image, with a specified animation delay.  The actual return
 606 value is a cons (NIMAGES . DELAY), where NIMAGES is the number
 607 of sub-images in the animated image and DELAY is the delay in
 608 seconds until the next sub-image should be displayed."
 609   (cond
 610    ((memq (plist-get (cdr image) :type) image-animated-types)
 611     (let* ((metadata (image-metadata image))
 612            (images (plist-get metadata 'count))
 613            (delay (plist-get metadata 'delay)))
 614       (when (and images (> images 1) (numberp delay))
 615         (if (< delay 0) (setq delay 0.1))
 616         (cons images delay))))))
 617
 618 ;; "Destructively"?
 619 (defun image-animate (image &optional index limit)
 620   "Start animating IMAGE.
 621 Animation occurs by destructively altering the IMAGE spec list.
 622
 623 With optional INDEX, begin animating from that animation frame.
 624 LIMIT specifies how long to animate the image.  If omitted or
 625 nil, play the animation until the end.  If t, loop forever.  If a
 626 number, play until that number of seconds has elapsed."
 627   (let ((animation (image-animated-p image))
 628         timer)
 629     (when animation
 630       (if (setq timer (image-animate-timer image))
 631           (cancel-timer timer))
 632       (run-with-timer 0.2 nil 'image-animate-timeout
 633                       image (or index 0) (car animation)
 634                       0 limit))))
 635
 636 (defun image-animate-timer (image)
 637   "Return the animation timer for image IMAGE."
 638   ;; See cancel-function-timers
 639   (let ((tail timer-list) timer)
 640     (while tail
 641       (setq timer (car tail)
 642             tail (cdr tail))
 643       (if (and (eq (aref timer 5) 'image-animate-timeout)
 644                (eq (car-safe (aref timer 6)) image))
 645           (setq tail nil)
 646         (setq timer nil)))
 647     timer))
 648
 649 ;; FIXME? The delay may not be the same for different sub-images,
 650 ;; hence we need to call image-animated-p to return it.
 651 ;; But it also returns count, so why do we bother passing that as an
 652 ;; argument?
 653 (defun image-animate-timeout (image n count time-elapsed limit)
 654   "Display animation frame N of IMAGE.
 655 N=0 refers to the initial animation frame.
 656 COUNT is the total number of frames in the animation.
 657 TIME-ELAPSED is the total time that has elapsed since
 658 `image-animate-start' was called.
 659 LIMIT determines when to stop.  If t, loop forever.  If nil, stop
 660  after displaying the last animation frame.  Otherwise, stop
 661  after LIMIT seconds have elapsed.
 662 The minimum delay between successive frames is 0.01s."
 663   (plist-put (cdr image) :index n)
 664   (force-window-update)
 665   (setq n (1+ n))
 666   (let* ((time (float-time))
 667          (animation (image-animated-p image))
 668          ;; Subtract off the time we took to load the image from the
 669          ;; stated delay time.
 670          (delay (max (+ (cdr animation) time (- (float-time)))
 671                      0.01))
 672          done)
 673     (if (>= n count)
 674         (if limit
 675             (setq n 0)
 676           (setq done t)))
 677     (setq time-elapsed (+ delay time-elapsed))
 678     (if (numberp limit)
 679         (setq done (>= time-elapsed limit)))
 680     (unless done
 681       (run-with-timer delay nil 'image-animate-timeout
 682                       image n count time-elapsed limit))))
 683
 684 \f
 685 (defcustom imagemagick-types-inhibit
 686   '(C HTML HTM TXT PDF)
 687   "ImageMagick types that Emacs should not use ImageMagick to handle.
 688 This should be a list of symbols, each of which has the same
 689 names as one of the format tags used internally by ImageMagick;
 690 see `imagemagick-types'.  Entries in this list are excluded from
 691 being registered by `imagemagick-register-types'.
 692
 693 If Emacs is compiled without ImageMagick, this variable has no effect."
 694   :type '(choice (const :tag "Let ImageMagick handle all types it can" nil)
 695                  (repeat symbol))
 696   :version "24.1"
 697   :group 'image)
 698
 699 ;;;###autoload
 700 (defun imagemagick-register-types ()
 701   "Register file types that can be handled by ImageMagick.
 702 This adds the file types returned by `imagemagick-types'
 703 \(excluding the ones in `imagemagick-types-inhibit') to
 704 `auto-mode-alist' and `image-type-file-name-regexps', so that
 705 Emacs visits them in Image mode.
 706
 707 If Emacs is compiled without ImageMagick support, do nothing."
 708   (when (fboundp 'imagemagick-types)
 709     (let ((im-types '()))
 710       (dolist (im-type (imagemagick-types))
 711         (unless (memq im-type imagemagick-types-inhibit)
 712           (push (downcase (symbol-name im-type)) im-types)))
 713       (let ((extension (concat "\\." (regexp-opt im-types) "\\'")))
 714         (push (cons extension 'image-mode) auto-mode-alist)
 715         (push (cons extension 'imagemagick)
 716               image-type-file-name-regexps)))))
 717
 718 (provide 'image)
 719
 720 ;;; image.el ends here