lisp/ls-lisp.el

   1 ;;; ls-lisp.el --- emulate insert-directory completely in Emacs Lisp
   2
   3 ;; Copyright (C) 1992, 1994, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;; Modified by: Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>
   8 ;; Maintainer: FSF
   9 ;; Keywords: unix, dired
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; OVERVIEW ==========================================================
  29
  30 ;; This file redefines the function `insert-directory' to implement it
  31 ;; directly from Emacs lisp, without running ls in a subprocess.  It
  32 ;; is useful if you cannot afford to fork Emacs on a real memory UNIX,
  33 ;; or other non-UNIX platforms if you don't have the ls
  34 ;; program, or if you want a different format from what ls offers.
  35
  36 ;; This function can use regexps instead of shell wildcards.  If you
  37 ;; enter regexps remember to double each $ sign.  For example, to
  38 ;; include files *.el, enter `.*\.el$$', resulting in the regexp
  39 ;; `.*\.el$'.
  40
  41 ;; RESTRICTIONS ======================================================
  42
  43 ;; * A few obscure ls switches are still ignored: see the docstring of
  44 ;; `insert-directory'.
  45
  46 ;; TO DO =============================================================
  47
  48 ;; Complete handling of F switch (if/when possible).
  49
  50 ;; FJW: May be able to sort much faster by consing the sort key onto
  51 ;; the front of each list element, sorting and then stripping the key
  52 ;; off again!
  53
  54 ;;; History:
  55
  56 ;; Written originally by Sebastian Kremer <sk@thp.uni-koeln.de>
  57 ;; Revised by Andrew Innes and Geoff Volker (and maybe others).
  58
  59 ;; Modified by Francis J. Wright <F.J.Wright@maths.qmw.ac.uk>, mainly
  60 ;; to support many more ls options, "platform emulation" and more
  61 ;; robust sorting.
  62
  63 ;;; Code:
  64
  65 (eval-when-compile (require 'cl))
  66
  67 (defgroup ls-lisp nil
  68   "Emulate the ls program completely in Emacs Lisp."
  69   :version "21.1"
  70   :group 'dired)
  71
  72 (defcustom ls-lisp-emulation
  73   (cond ((eq system-type 'macos) 'MacOS)
  74         ;; ((eq system-type 'windows-nt) 'MS-Windows)
  75         ((memq system-type
  76                '(hpux usg-unix-v unisoft-unix irix berkeley-unix))
  77          'UNIX))                        ; very similar to GNU
  78   ;; Anything else defaults to nil, meaning GNU.
  79   "Platform to emulate: GNU (default), MacOS, MS-Windows, UNIX.
  80 Corresponding value is one of the atoms: nil, MacOS, MS-Windows, UNIX.
  81 Sets default values for: `ls-lisp-ignore-case', `ls-lisp-dirs-first',
  82 `ls-lisp-verbosity'.  Need not match actual platform.  Changing this
  83 option will have no effect until you restart Emacs."
  84   :type '(choice (const :tag "GNU" nil)
  85                  (const MacOS)
  86                  (const MS-Windows)
  87                  (const UNIX))
  88   :group 'ls-lisp)
  89
  90 (defcustom ls-lisp-ignore-case
  91   ;; Name change for consistency with other option names.
  92   (or (memq ls-lisp-emulation '(MS-Windows MacOS))
  93       (and (boundp 'ls-lisp-dired-ignore-case) ls-lisp-dired-ignore-case))
  94   "Non-nil causes ls-lisp alphabetic sorting to ignore case."
  95   :type 'boolean
  96   :group 'ls-lisp)
  97
  98 (defcustom ls-lisp-dirs-first (eq ls-lisp-emulation 'MS-Windows)
  99   "Non-nil causes ls-lisp to sort directories first in any ordering.
 100 \(Or last if it is reversed.)  Follows Microsoft Windows Explorer."
 101   ;; Functionality suggested by Chris McMahan <cmcmahan@one.net>
 102   :type 'boolean
 103   :group 'ls-lisp)
 104
 105 (defcustom ls-lisp-verbosity
 106   (cond ((eq ls-lisp-emulation 'MacOS) nil)
 107         ((eq ls-lisp-emulation 'MS-Windows)
 108          (if (and (fboundp 'w32-using-nt) (w32-using-nt))
 109              '(links)))                 ; distinguish NT/2K from 9x
 110         ((eq ls-lisp-emulation 'UNIX) '(links uid)) ; UNIX ls
 111         (t '(links uid gid)))           ; GNU ls
 112   "A list of optional file attributes that ls-lisp should display.
 113 It should contain none or more of the symbols: links, uid, gid.
 114 A value of nil (or an empty list) means display none of them.
 115
 116 Concepts come from UNIX: `links' means count of names associated with
 117 the file\; `uid' means user (owner) identifier\; `gid' means group
 118 identifier.
 119
 120 If emulation is MacOS then default is nil\;
 121 if emulation is MS-Windows then default is `(links)' if platform is
 122 Windows NT/2K, nil otherwise\;
 123 if emulation is UNIX then default is `(links uid)'\;
 124 if emulation is GNU then default is `(links uid gid)'."
 125   ;; Functionality suggested by Howard Melman <howard@silverstream.com>
 126   :type '(set (const :tag "Show Link Count" links)
 127               (const :tag "Show User" uid)
 128               (const :tag "Show Group" gid))
 129   :group 'ls-lisp)
 130
 131 (defcustom ls-lisp-use-insert-directory-program
 132   (not (memq system-type '(macos ms-dos windows-nt)))
 133   "Non-nil causes ls-lisp to revert back to using `insert-directory-program'.
 134 This is useful on platforms where ls-lisp is dumped into Emacs, such as
 135 Microsoft Windows, but you would still like to use a program to list
 136 the contents of a directory."
 137   :type 'boolean
 138   :group 'ls-lisp)
 139
 140 ;;; Autoloaded because it is let-bound in `recover-session', `mail-recover-1'.
 141 ;;;###autoload
 142 (defcustom ls-lisp-support-shell-wildcards t
 143   "Non-nil means ls-lisp treats file patterns as shell wildcards.
 144 Otherwise they are treated as Emacs regexps (for backward compatibility)."
 145   :type 'boolean
 146   :group 'ls-lisp)
 147
 148 (defcustom ls-lisp-format-time-list
 149   '("%b %e %H:%M"
 150     "%b %e  %Y")
 151   "List of `format-time-string' specs to display file time stamps.
 152 These specs are used ONLY if a valid locale can not be determined.
 153
 154 If `ls-lisp-use-localized-time-format' is non-nil, these specs are used
 155 regardless of whether the locale can be determined.
 156
 157 Syntax:  (EARLY-TIME-FORMAT OLD-TIME-FORMAT)
 158
 159 The EARLY-TIME-FORMAT is used if file has been modified within the
 160 current year. The OLD-TIME-FORMAT is used for older files.  To use ISO
 161 8601 dates, you could set:
 162
 163 \(setq ls-lisp-format-time-list
 164        '(\"%Y-%m-%d %H:%M\"
 165          \"%Y-%m-%d      \"))"
 166   :type '(list (string :tag "Early time format")
 167                (string :tag "Old time format"))
 168   :group 'ls-lisp)
 169
 170 (defcustom ls-lisp-use-localized-time-format nil
 171   "Non-nil causes ls-lisp to use `ls-lisp-format-time-list' even if
 172 a valid locale is specified.
 173
 174 WARNING: Using localized date/time format might cause Dired columns
 175 to fail to lign up, e.g. if month names are not all of the same length."
 176   :type 'boolean
 177   :group 'ls-lisp)
 178
 179 (defvar original-insert-directory nil
 180   "This holds the original function definition of `insert-directory'.")
 181
 182 (defvar ls-lisp-uid-d-fmt "-%d"
 183   "Format to display integer UIDs.")
 184 (defvar ls-lisp-uid-s-fmt "-%s"
 185   "Format to display user names.")
 186 (defvar ls-lisp-gid-d-fmt "-%d"
 187   "Format to display integer GIDs.")
 188 (defvar ls-lisp-gid-s-fmt "-%s"
 189   "Format to display user group names.")
 190 (defvar ls-lisp-filesize-d-fmt "%d"
 191   "Format to display integer file sizes.")
 192 (defvar ls-lisp-filesize-f-fmt "%.0f"
 193   "Format to display float file sizes.")
 194
 195 ;; Remember the original insert-directory function
 196 (or (featurep 'ls-lisp)  ; FJW: unless this file is being reloaded!
 197     (setq original-insert-directory (symbol-function 'insert-directory)))
 198
 199 \f
 200 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 201
 202 (defun insert-directory (file switches &optional wildcard full-directory-p)
 203   "Insert directory listing for FILE, formatted according to SWITCHES.
 204 Leaves point after the inserted text.
 205 SWITCHES may be a string of options, or a list of strings.
 206 Optional third arg WILDCARD means treat FILE as shell wildcard.
 207 Optional fourth arg FULL-DIRECTORY-P means file is a directory and
 208 switches do not contain `d', so that a full listing is expected.
 209
 210 This version of the function comes from `ls-lisp.el'.
 211 If the value of `ls-lisp-use-insert-directory-program' is non-nil then
 212 it works exactly like the version from `files.el' and runs a directory
 213 listing program whose name is in the variable
 214 `insert-directory-program'; if also WILDCARD is non-nil then it runs
 215 the shell specified by `shell-file-name'.  If the value of
 216 `ls-lisp-use-insert-directory-program' is nil then it runs a Lisp
 217 emulation.
 218
 219 The Lisp emulation does not run any external programs or shells.  It
 220 supports ordinary shell wildcards if `ls-lisp-support-shell-wildcards'
 221 is non-nil; otherwise, it interprets wildcards as regular expressions
 222 to match file names.  It does not support all `ls' switches -- those
 223 that work are: A a c i r S s t u U X g G B C R n and F partly."
 224   (if ls-lisp-use-insert-directory-program
 225       (funcall original-insert-directory
 226                file switches wildcard full-directory-p)
 227     ;; We need the directory in order to find the right handler.
 228     (let ((handler (find-file-name-handler (expand-file-name file)
 229                                            'insert-directory))
 230           (orig-file file)
 231           wildcard-regexp)
 232       (if handler
 233           (funcall handler 'insert-directory file switches
 234                    wildcard full-directory-p)
 235         ;; Remove --dired switch
 236         (if (string-match "--dired " switches)
 237             (setq switches (replace-match "" nil nil switches)))
 238         ;; Convert SWITCHES to a list of characters.
 239         (setq switches (delete ?- (append switches nil)))
 240         ;; Sometimes we get ".../foo*/" as FILE.  While the shell and
 241         ;; `ls' don't mind, we certainly do, because it makes us think
 242         ;; there is no wildcard, only a directory name.
 243         (if (and ls-lisp-support-shell-wildcards
 244                  (string-match "[[?*]" file)
 245                  ;; Prefer an existing file to wildcards, like
 246                  ;; dired-noselect does.
 247                  (not (file-exists-p file)))
 248             (progn
 249               (or (not (eq (aref file (1- (length file))) ?/))
 250                   (setq file (substring file 0 (1- (length file)))))
 251               (setq wildcard t)))
 252         (if wildcard
 253             (setq wildcard-regexp
 254                   (if ls-lisp-support-shell-wildcards
 255                       (wildcard-to-regexp (file-name-nondirectory file))
 256                     (file-name-nondirectory file))
 257                   file (file-name-directory file))
 258           (if (memq ?B switches) (setq wildcard-regexp "[^~]\\'")))
 259         (condition-case err
 260             (ls-lisp-insert-directory
 261              file switches (ls-lisp-time-index switches)
 262              wildcard-regexp full-directory-p)
 263           (invalid-regexp
 264            ;; Maybe they wanted a literal file that just happens to
 265            ;; use characters special to shell wildcards.
 266            (if (equal (cadr err) "Unmatched [ or [^")
 267                (progn
 268                  (setq wildcard-regexp (if (memq ?B switches) "[^~]\\'")
 269                        file (file-relative-name orig-file))
 270                  (ls-lisp-insert-directory
 271                   file switches (ls-lisp-time-index switches)
 272                   nil full-directory-p))
 273              (signal (car err) (cdr err)))))
 274         ;; Try to insert the amount of free space.
 275         (save-excursion
 276           (goto-char (point-min))
 277           ;; First find the line to put it on.
 278           (when (re-search-forward "^total" nil t)
 279             (let ((available (get-free-disk-space ".")))
 280               (when available
 281                 ;; Replace "total" with "total used", to avoid confusion.
 282                 (replace-match "total used in directory")
 283                 (end-of-line)
 284                 (insert " available " available)))))))))
 285
 286 (defun ls-lisp-insert-directory
 287   (file switches time-index wildcard-regexp full-directory-p)
 288   "Insert directory listing for FILE, formatted according to SWITCHES.
 289 Leaves point after the inserted text.  This is an internal function
 290 optionally called by the `ls-lisp.el' version of `insert-directory'.
 291 It is called recursively if the -R switch is used.
 292 SWITCHES is a *list* of characters.  TIME-INDEX is the time index into
 293 file-attributes according to SWITCHES.  WILDCARD-REGEXP is nil or an *Emacs
 294 regexp*.  FULL-DIRECTORY-P means file is a directory and SWITCHES does
 295 not contain `d', so that a full listing is expected."
 296   (if (or wildcard-regexp full-directory-p)
 297       (let* ((dir (file-name-as-directory file))
 298              (default-directory dir)    ; so that file-attributes works
 299              (file-alist
 300               (directory-files-and-attributes dir nil wildcard-regexp t
 301                                               (if (memq ?n switches)
 302                                                   'integer
 303                                                 'string)))
 304              (now (current-time))
 305              (sum 0)
 306              (max-uid-len 0)
 307              (max-gid-len 0)
 308              (max-file-size 0)
 309              ;; do all bindings here for speed
 310              total-line files elt short file-size fil attr
 311              fuid fgid uid-len gid-len)
 312         (cond ((memq ?A switches)
 313                (setq file-alist
 314                      (ls-lisp-delete-matching "^\\.\\.?$" file-alist)))
 315               ((not (memq ?a switches))
 316                ;; if neither -A  nor -a, flush . files
 317                (setq file-alist
 318                      (ls-lisp-delete-matching "^\\." file-alist))))
 319         (setq file-alist
 320               (ls-lisp-handle-switches file-alist switches))
 321         (if (memq ?C switches)          ; column (-C) format
 322             (ls-lisp-column-format file-alist)
 323           (setq total-line (cons (point) (car-safe file-alist)))
 324           ;; Find the appropriate format for displaying uid, gid, and
 325           ;; file size, by finding the longest strings among all the
 326           ;; files we are about to display.
 327           (dolist (elt file-alist)
 328             (setq attr (cdr elt)
 329                   fuid (nth 2 attr)
 330                   uid-len (if (stringp fuid) (string-width fuid)
 331                             (length (format "%d" fuid)))
 332                   fgid (nth 3 attr)
 333                   gid-len (if (stringp fgid) (string-width fgid)
 334                             (length (format "%d" fgid)))
 335                   file-size (nth 7 attr))
 336             (if (> uid-len max-uid-len)
 337                 (setq max-uid-len uid-len))
 338             (if (> gid-len max-gid-len)
 339                 (setq max-gid-len gid-len))
 340             (if (> file-size max-file-size)
 341                 (setq max-file-size file-size)))
 342           (setq ls-lisp-uid-d-fmt (format " %%-%dd" max-uid-len))
 343           (setq ls-lisp-uid-s-fmt (format " %%-%ds" max-uid-len))
 344           (setq ls-lisp-gid-d-fmt (format " %%-%dd" max-gid-len))
 345           (setq ls-lisp-gid-s-fmt (format " %%-%ds" max-gid-len))
 346           (setq ls-lisp-filesize-d-fmt
 347                 (format " %%%dd"
 348                         (if (memq ?s switches)
 349                             (length (format "%.0f"
 350                                             (fceiling (/ max-file-size 1024.0))))
 351                           (length (format "%.0f" max-file-size)))))
 352           (setq ls-lisp-filesize-f-fmt
 353                 (format " %%%d.0f"
 354                         (if (memq ?s switches)
 355                             (length (format "%.0f"
 356                                             (fceiling (/ max-file-size 1024.0))))
 357                           (length (format "%.0f" max-file-size)))))
 358           (setq files file-alist)
 359           (while files                  ; long (-l) format
 360             (setq elt (car files)
 361                   files (cdr files)
 362                   short (car elt)
 363                   attr (cdr elt)
 364                   file-size (nth 7 attr))
 365             (and attr
 366                  (setq sum (+ file-size
 367                               ;; Even if neither SUM nor file's size
 368                               ;; overflow, their sum could.
 369                               (if (or (< sum (- 134217727 file-size))
 370                                       (floatp sum)
 371                                       (floatp file-size))
 372                                   sum
 373                                 (float sum))))
 374                  (insert (ls-lisp-format short attr file-size
 375                                          switches time-index now))))
 376           ;; Insert total size of all files:
 377           (save-excursion
 378             (goto-char (car total-line))
 379             (or (cdr total-line)
 380                 ;; Shell says ``No match'' if no files match
 381                 ;; the wildcard; let's say something similar.
 382                 (insert "(No match)\n"))
 383             (insert (format "total %.0f\n" (fceiling (/ sum 1024.0))))))
 384         (if (memq ?R switches)
 385             ;; List the contents of all directories recursively.
 386             ;; cadr of each element of `file-alist' is t for
 387             ;; directory, string (name linked to) for symbolic
 388             ;; link, or nil.
 389             (while file-alist
 390               (setq elt (car file-alist)
 391                     file-alist (cdr file-alist))
 392               (when (and (eq (cadr elt) t) ; directory
 393                          ;; Under -F, we have already decorated all
 394                          ;; directories, including "." and "..", with
 395                          ;; a /, so allow for that as well.
 396                          (not (string-match "\\`\\.\\.?/?\\'" (car elt))))
 397                 (setq elt (expand-file-name (car elt) dir))
 398                 (insert "\n" elt ":\n")
 399                 (ls-lisp-insert-directory
 400                  elt switches time-index wildcard-regexp full-directory-p)))))
 401     ;; If not full-directory-p, FILE *must not* end in /, as
 402     ;; file-attributes will not recognize a symlink to a directory,
 403     ;; so must make it a relative filename as ls does:
 404     (if (eq (aref file (1- (length file))) ?/)
 405         (setq file (substring file 0 -1)))
 406     (let ((fattr (file-attributes file 'string)))
 407       (if fattr
 408           (insert (ls-lisp-format file fattr (nth 7 fattr)
 409                                   switches time-index (current-time)))
 410         (message "%s: doesn't exist or is inaccessible" file)
 411         (ding) (sit-for 2)))))          ; to show user the message!
 412
 413 (defun ls-lisp-column-format (file-alist)
 414   "Insert the file names (only) in FILE-ALIST into the current buffer.
 415 Format in columns, sorted vertically, following GNU ls -C.
 416 Responds to the window width as ls should but may not!"
 417   (let (files fmt ncols collen (nfiles 0) (colwid 0))
 418     ;; Count number of files as `nfiles', build list of filenames as
 419     ;; `files', and find maximum filename length as `colwid':
 420     (let (file len)
 421       (while file-alist
 422         (setq nfiles (1+ nfiles)
 423               file (caar file-alist)
 424               files (cons file files)
 425               file-alist (cdr file-alist)
 426               len (length file))
 427         (if (> len colwid) (setq colwid len))))
 428     (setq files (nreverse files)
 429           colwid (+ 2 colwid)           ; 2 character column gap
 430           fmt (format "%%-%ds" colwid)  ; print format
 431           ncols (/ (window-width) colwid) ; no of columns
 432           collen (/ nfiles ncols))      ; floor of column length
 433     (if (> nfiles (* collen ncols)) (setq collen (1+ collen)))
 434     ;; Output the file names in columns, sorted vertically:
 435     (let ((i 0) j)
 436       (while (< i collen)
 437         (setq j i)
 438         (while (< j nfiles)
 439           (insert (format fmt (nth j files)))
 440           (setq j (+ j collen)))
 441         ;; FJW: This is completely unnecessary, but I don't like
 442         ;; trailing white space...
 443         (delete-region (point) (progn (skip-chars-backward " \t") (point)))
 444         (insert ?\n)
 445         (setq i (1+ i))))))
 446
 447 (defun ls-lisp-delete-matching (regexp list)
 448   "Delete all elements matching REGEXP from LIST, return new list."
 449   ;; Should perhaps use setcdr for efficiency.
 450   (let (result)
 451     (while list
 452       (or (string-match regexp (caar list))
 453           (setq result (cons (car list) result)))
 454       (setq list (cdr list)))
 455     result))
 456
 457 (defsubst ls-lisp-string-lessp (s1 s2)
 458   "Return t if string S1 is less than string S2 in lexicographic order.
 459 Case is significant if `ls-lisp-ignore-case' is nil.
 460 Unibyte strings are converted to multibyte for comparison."
 461   (let ((u (compare-strings s1 0 nil s2 0 nil ls-lisp-ignore-case)))
 462     (and (numberp u) (< u 0))))
 463
 464 (defun ls-lisp-handle-switches (file-alist switches)
 465   "Return new FILE-ALIST sorted according to SWITCHES.
 466 SWITCHES is a list of characters.  Default sorting is alphabetic."
 467   ;; FILE-ALIST's elements are (FILE . FILE-ATTRIBUTES).
 468   (or (memq ?U switches)                ; unsorted
 469       ;; Catch and ignore unexpected sorting errors
 470       (condition-case err
 471           (setq file-alist
 472                 (let (index)
 473                   ;; Copy file-alist in case of error
 474                   (sort (copy-sequence file-alist) ; modifies its argument!
 475                         (cond ((memq ?S switches)
 476                                (lambda (x y) ; sorted on size
 477                                  ;; 7th file attribute is file size
 478                                  ;; Make largest file come first
 479                                  (< (nth 7 (cdr y))
 480                                     (nth 7 (cdr x)))))
 481                               ((setq index (ls-lisp-time-index switches))
 482                                (lambda (x y) ; sorted on time
 483                                  (ls-lisp-time-lessp (nth index (cdr y))
 484                                                      (nth index (cdr x)))))
 485                               ((memq ?X switches)
 486                                (lambda (x y) ; sorted on extension
 487                                  (ls-lisp-string-lessp
 488                                   (ls-lisp-extension (car x))
 489                                   (ls-lisp-extension (car y)))))
 490                               (t
 491                                (lambda (x y) ; sorted alphabetically
 492                                  (ls-lisp-string-lessp (car x) (car y))))))))
 493         (error (message "Unsorted (ls-lisp sorting error) - %s"
 494                         (error-message-string err))
 495                (ding) (sit-for 2))))    ; to show user the message!
 496   (if (memq ?F switches)                ; classify switch
 497       (setq file-alist (mapcar 'ls-lisp-classify file-alist)))
 498   (if ls-lisp-dirs-first
 499   ;; Re-sort directories first, without otherwise changing the
 500   ;; ordering, and reverse whole list.  cadr of each element of
 501   ;; `file-alist' is t for directory, string (name linked to) for
 502   ;; symbolic link, or nil.
 503       (let (el dirs files)
 504         (while file-alist
 505           (if (or (eq (cadr (setq el (car file-alist))) t) ; directory
 506                   (and (stringp (cadr el))
 507                        (file-directory-p (cadr el)))) ; symlink to a directory
 508               (setq dirs (cons el dirs))
 509             (setq files (cons el files)))
 510           (setq file-alist (cdr file-alist)))
 511         (setq file-alist
 512               (if (memq ?U switches)    ; unsorted order is reversed
 513                   (nconc dirs files)
 514                 (nconc files dirs)
 515                 ))))
 516   ;; Finally reverse file alist if necessary.
 517   ;; (eq below MUST compare `(not (memq ...))' to force comparison of
 518   ;; `t' or `nil', rather than list tails!)
 519   (if (eq (eq (not (memq ?U switches))  ; unsorted order is reversed
 520               (not (memq ?r switches))) ; reversed sort order requested
 521           ls-lisp-dirs-first)           ; already reversed
 522       (nreverse file-alist)
 523     file-alist))
 524
 525 (defun ls-lisp-classify (filedata)
 526   "Append a character to each file name indicating the file type.
 527 Also, for regular files that are executable, append `*'.
 528 The file type indicators are `/' for directories, `@' for symbolic
 529 links, `|' for FIFOs, `=' for sockets, and nothing for regular files.
 530 \[But FIFOs and sockets are not recognized.]
 531 FILEDATA has the form (filename . `file-attributes').  Its `cadr' is t
 532 for directory, string (name linked to) for symbolic link, or nil."
 533   (let ((file-name (car filedata))
 534         (type (cadr filedata)))
 535     (cond (type
 536            (cons
 537             (concat (propertize file-name 'dired-filename t)
 538                     (if (eq type t) "/" "@"))
 539             (cdr filedata)))
 540           ((string-match "x" (nth 9 filedata))
 541            (cons
 542             (concat (propertize file-name 'dired-filename t) "*")
 543             (cdr filedata)))
 544           (t
 545            (cons
 546             (propertize file-name 'dired-filename t)
 547             (cdr filedata))))))
 548
 549 (defun ls-lisp-extension (filename)
 550   "Return extension of FILENAME (ignoring any version extension)
 551 FOLLOWED by null and full filename, SOLELY for full alpha sort."
 552   ;; Force extension sort order: `no ext' then `null ext' then `ext'
 553   ;; to agree with GNU ls.
 554   (concat
 555    (let* ((i (length filename)) end)
 556      (if (= (aref filename (1- i)) ?.) ; null extension
 557          "\0"
 558        (while (and (>= (setq i (1- i)) 0)
 559                    (/= (aref filename i) ?.)))
 560        (if (< i 0) "\0\0"               ; no extension
 561          (if (/= (aref filename (1+ i)) ?~)
 562              (substring filename (1+ i))
 563            ;; version extension found -- ignore it
 564            (setq end i)
 565            (while (and (>= (setq i (1- i)) 0)
 566                        (/= (aref filename i) ?.)))
 567            (if (< i 0) "\0\0"   ; no extension
 568              (substring filename (1+ i) end))))
 569        )) "\0" filename))
 570
 571 ;; From Roland McGrath.  Can use this to sort on time.
 572 (defun ls-lisp-time-lessp (time0 time1)
 573   "Return t if time TIME0 is earlier than time TIME1."
 574   (let ((hi0 (car time0)) (hi1 (car time1)))
 575     (or (< hi0 hi1)
 576         (and (= hi0 hi1)
 577              (< (cadr time0) (cadr time1))))))
 578
 579 (defun ls-lisp-format (file-name file-attr file-size switches time-index now)
 580   "Format one line of long ls output for file FILE-NAME.
 581 FILE-ATTR and FILE-SIZE give the file's attributes and size.
 582 SWITCHES, TIME-INDEX and NOW give the full switch list and time data."
 583   (let ((file-type (nth 0 file-attr))
 584         ;; t for directory, string (name linked to)
 585         ;; for symbolic link, or nil.
 586         (drwxrwxrwx (nth 8 file-attr))) ; attribute string ("drwxrwxrwx")
 587     (concat (if (memq ?i switches)      ; inode number
 588                 (let ((inode (nth 10 file-attr)))
 589                   (if (consp inode)
 590                       (if (consp (cdr inode))
 591                           ;; 2^(24+16) = 1099511627776.0, but
 592                           ;; multiplying by it and then adding the
 593                           ;; other members of the cons cell in one go
 594                           ;; loses precision, since a double does not
 595                           ;; have enough significant digits to hold a
 596                           ;; full 64-bit value.  So below we split
 597                           ;; 1099511627776 into high 13 and low 5
 598                           ;; digits and compute in two parts.
 599                           (let ((p1 (* (car inode) 10995116.0))
 600                                 (p2 (+ (* (car inode) 27776.0)
 601                                        (* (cadr inode) 65536.0)
 602                                        (cddr inode))))
 603                             (format " %13.0f%05.0f "
 604                                     ;; Use floor to emulate integer
 605                                     ;; division.
 606                                     (+ p1 (floor p2 100000.0))
 607                                     (mod p2 100000.0)))
 608                         (format " %18.0f "
 609                                 (+ (* (car inode) 65536.0)
 610                                    (cdr inode))))
 611                     (format " %18d " inode))))
 612             ;; nil is treated like "" in concat
 613             (if (memq ?s switches)      ; size in K
 614                 (format ls-lisp-filesize-f-fmt
 615                         (fceiling (/ file-size 1024.0))))
 616             drwxrwxrwx                  ; attribute string
 617             (if (memq 'links ls-lisp-verbosity)
 618                 (format "%3d" (nth 1 file-attr))) ; link count
 619             ;; Numeric uid/gid are more confusing than helpful;
 620             ;; Emacs should be able to make strings of them.
 621             ;; They tend to be bogus on non-UNIX platforms anyway so
 622             ;; optionally hide them.
 623             (if (memq 'uid ls-lisp-verbosity)
 624                 ;; uid can be a sting or an integer
 625                 (let ((uid (nth 2 file-attr)))
 626                   (format (if (stringp uid)
 627                               ls-lisp-uid-s-fmt
 628                             ls-lisp-uid-d-fmt)
 629                           uid)))
 630             (if (not (memq ?G switches)) ; GNU ls -- shows group by default
 631                 (if (or (memq ?g switches) ; UNIX ls -- no group by default
 632                         (memq 'gid ls-lisp-verbosity))
 633                     (let ((gid (nth 3 file-attr)))
 634                       (format (if (stringp gid)
 635                                   ls-lisp-gid-s-fmt
 636                                 ls-lisp-gid-d-fmt)
 637                               gid))))
 638             (ls-lisp-format-file-size file-size (memq ?h switches))
 639             " "
 640             (ls-lisp-format-time file-attr time-index now)
 641             " "
 642             (if (not (memq ?F switches)) ; ls-lisp-classify already did that
 643                 (propertize file-name 'dired-filename t)
 644               file-name)
 645             (if (stringp file-type)     ; is a symbolic link
 646                 (concat " -> " file-type))
 647             "\n"
 648             )))
 649
 650 (defun ls-lisp-time-index (switches)
 651   "Return time index into file-attributes according to ls SWITCHES list.
 652 Return nil if no time switch found."
 653   ;; FJW: Default of nil is IMPORTANT and used in `ls-lisp-handle-switches'!
 654   (cond ((memq ?c switches) 6)          ; last mode change
 655         ((memq ?t switches) 5)          ; last modtime
 656         ((memq ?u switches) 4)))        ; last access
 657
 658 (defun ls-lisp-time-to-seconds (time)
 659   "Convert TIME to a floating point number."
 660   (+ (* (car time) 65536.0)
 661      (cadr time)
 662      (/ (or (nth 2 time) 0) 1000000.0)))
 663
 664 (defun ls-lisp-format-time (file-attr time-index now)
 665   "Format time for file with attributes FILE-ATTR according to TIME-INDEX.
 666 Use the same method as ls to decide whether to show time-of-day or year,
 667 depending on distance between file date and NOW.
 668 All ls time options, namely c, t and u, are handled."
 669   (let* ((time (nth (or time-index 5) file-attr)) ; default is last modtime
 670          (diff (- (ls-lisp-time-to-seconds time)
 671                   (ls-lisp-time-to-seconds now)))
 672          ;; Consider a time to be recent if it is within the past six
 673          ;; months.  A Gregorian year has 365.2425 * 24 * 60 * 60 ==
 674          ;; 31556952 seconds on the average, and half of that is 15778476.
 675          ;; Write the constant explicitly to avoid roundoff error.
 676          (past-cutoff -15778476)) ; half a Gregorian year
 677     (condition-case nil
 678         ;; Use traditional time format in the C or POSIX locale,
 679         ;; ISO-style time format otherwise, so columns line up.
 680         (let ((locale system-time-locale))
 681           (if (not locale)
 682               (let ((vars '("LC_ALL" "LC_TIME" "LANG")))
 683                 (while (and vars (not (setq locale (getenv (car vars)))))
 684                   (setq vars (cdr vars)))))
 685           (if (member locale '("C" "POSIX"))
 686               (setq locale nil))
 687           (format-time-string
 688            (if (and (<= past-cutoff diff) (<= diff 0))
 689                (if (and locale (not ls-lisp-use-localized-time-format))
 690                    "%m-%d %H:%M"
 691                  (nth 0 ls-lisp-format-time-list))
 692              (if (and locale (not ls-lisp-use-localized-time-format))
 693                  "%Y-%m-%d "
 694                (nth 1 ls-lisp-format-time-list)))
 695            time))
 696       (error "Unk  0  0000"))))
 697
 698 (defun ls-lisp-format-file-size (file-size human-readable)
 699   (if (not human-readable)
 700       (format (if (floatp file-size)
 701                   ls-lisp-filesize-f-fmt
 702                 ls-lisp-filesize-d-fmt)
 703               file-size)
 704     (if (< file-size 1024)
 705         (format " %4d" file-size)
 706       (do ((file-size (/ file-size 1024.0) (/ file-size 1024.0))
 707            ;; kilo, mega, giga, tera, peta, exa
 708            (post-fixes (list "k" "M" "G" "T" "P" "E") (cdr post-fixes)))
 709           ((< file-size 1024)
 710            (format " %3.0f%s"  file-size (car post-fixes)))))))
 711
 712 (provide 'ls-lisp)
 713
 714 ;; arch-tag: e55f399b-05ec-425c-a6d5-f5e349c35ab4
 715 ;;; ls-lisp.el ends here