lisp/calendar/time-date.el

   1 ;;; time-date.el --- Date and time handling functions
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009  Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      Masanobu Umeda <umerin@mse.kyutech.ac.jp>
   8 ;; Keywords: mail news util
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Time values come in three formats.  The oldest format is a cons
  28 ;; cell of the form (HIGH . LOW).  This format is obsolete, but still
  29 ;; supported.  The two other formats are the lists (HIGH LOW) and
  30 ;; (HIGH LOW MICRO).  The first two formats specify HIGH * 2^16 + LOW
  31 ;; seconds; the third format specifies HIGH * 2^16 + LOW + MICRO /
  32 ;; 1000000 seconds.  We should have 0 <= MICRO < 1000000 and 0 <= LOW
  33 ;; < 2^16.  If the time value represents a point in time, then HIGH is
  34 ;; nonnegative.  If the time value is a time difference, then HIGH can
  35 ;; be negative as well.  The macro `with-decoded-time-value' and the
  36 ;; function `encode-time-value' make it easier to deal with these
  37 ;; three formats.  See `time-subtract' for an example of how to use
  38 ;; them.
  39
  40 ;;; Code:
  41
  42 ;; Only necessary for `declare' when compiling Gnus with Emacs 21.
  43 (eval-when-compile (require 'cl))
  44
  45 (defmacro with-decoded-time-value (varlist &rest body)
  46   "Decode a time value and bind it according to VARLIST, then eval BODY.
  47
  48 The value of the last form in BODY is returned.
  49
  50 Each element of the list VARLIST is a list of the form
  51 \(HIGH-SYMBOL LOW-SYMBOL MICRO-SYMBOL [TYPE-SYMBOL] TIME-VALUE).
  52 The time value TIME-VALUE is decoded and the result it bound to
  53 the symbols HIGH-SYMBOL, LOW-SYMBOL and MICRO-SYMBOL.
  54
  55 The optional TYPE-SYMBOL is bound to the type of the time value.
  56 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH
  57 LOW), and type 2 is the list (HIGH LOW MICRO)."
  58   (declare (indent 1)
  59            (debug ((&rest (symbolp symbolp symbolp &or [symbolp form] form))
  60                    body)))
  61   (if varlist
  62       (let* ((elt (pop varlist))
  63              (high (pop elt))
  64              (low (pop elt))
  65              (micro (pop elt))
  66              (type (unless (eq (length elt) 1)
  67                      (pop elt)))
  68              (time-value (car elt))
  69              (gensym (make-symbol "time")))
  70         `(let* ,(append `((,gensym ,time-value)
  71                           (,high (pop ,gensym))
  72                           ,low ,micro)
  73                         (when type `(,type)))
  74            (if (consp ,gensym)
  75                (progn
  76                  (setq ,low (pop ,gensym))
  77                  (if ,gensym
  78                      ,(append `(setq ,micro (car ,gensym))
  79                               (when type `(,type 2)))
  80                    ,(append `(setq ,micro 0)
  81                             (when type `(,type 1)))))
  82              ,(append `(setq ,low ,gensym ,micro 0)
  83                       (when type `(,type 0))))
  84            (with-decoded-time-value ,varlist ,@body)))
  85     `(progn ,@body)))
  86
  87 (defun encode-time-value (high low micro type)
  88   "Encode HIGH, LOW, and MICRO into a time value of type TYPE.
  89 Type 0 is the cons cell (HIGH . LOW), type 1 is the list (HIGH LOW),
  90 and type 2 is the list (HIGH LOW MICRO)."
  91   (cond
  92    ((eq type 0) (cons high low))
  93    ((eq type 1) (list high low))
  94    ((eq type 2) (list high low micro))))
  95
  96 (autoload 'parse-time-string "parse-time")
  97 (autoload 'timezone-make-date-arpa-standard "timezone")
  98
  99 ;;;###autoload
 100 (defun date-to-time (date)
 101   "Parse a string DATE that represents a date-time and return a time value."
 102   (condition-case ()
 103       (apply 'encode-time
 104              (parse-time-string
 105               ;; `parse-time-string' isn't sufficiently general or
 106               ;; robust.  It fails to grok some of the formats that
 107               ;; timezone does (e.g. dodgy post-2000 stuff from some
 108               ;; Elms) and either fails or returns bogus values.  Lars
 109               ;; reverted this change, but that loses non-trivially
 110               ;; often for me.  -- fx
 111               (timezone-make-date-arpa-standard date)))
 112     (error (error "Invalid date: %s" date))))
 113
 114 ;;;###autoload
 115 (defun time-to-seconds (time)
 116   "Convert time value TIME to a floating point number.
 117 You can use `float-time' instead."
 118   (with-decoded-time-value ((high low micro time))
 119     (+ (* 1.0 high 65536)
 120        low
 121        (/ micro 1000000.0))))
 122
 123 ;;;###autoload
 124 (defun seconds-to-time (seconds)
 125   "Convert SECONDS (a floating point number) to a time value."
 126   (list (floor seconds 65536)
 127         (floor (mod seconds 65536))
 128         (floor (* (- seconds (ffloor seconds)) 1000000))))
 129
 130 ;;;###autoload
 131 (defun time-less-p (t1 t2)
 132   "Say whether time value T1 is less than time value T2."
 133   (with-decoded-time-value ((high1 low1 micro1 t1)
 134                             (high2 low2 micro2 t2))
 135     (or (< high1 high2)
 136         (and (= high1 high2)
 137              (or (< low1 low2)
 138                  (and (= low1 low2)
 139                       (< micro1 micro2)))))))
 140
 141 ;;;###autoload
 142 (defun days-to-time (days)
 143   "Convert DAYS into a time value."
 144   (let* ((seconds (* 1.0 days 60 60 24))
 145          (high (condition-case nil (floor (/ seconds 65536))
 146                  (range-error most-positive-fixnum))))
 147     (list high (condition-case nil (floor (- seconds (* 1.0 high 65536)))
 148                  (range-error 65535)))))
 149
 150 ;;;###autoload
 151 (defun time-since (time)
 152   "Return the time elapsed since TIME.
 153 TIME should be either a time value or a date-time string."
 154   (when (stringp time)
 155     ;; Convert date strings to internal time.
 156     (setq time (date-to-time time)))
 157   (time-subtract (current-time) time))
 158
 159 ;;;###autoload
 160 (defalias 'subtract-time 'time-subtract)
 161
 162 ;;;###autoload
 163 (defun time-subtract (t1 t2)
 164   "Subtract two time values, T1 minus T2.
 165 Return the difference in the format of a time value."
 166   (with-decoded-time-value ((high low micro type t1)
 167                             (high2 low2 micro2 type2 t2))
 168     (setq high (- high high2)
 169           low (- low low2)
 170           micro (- micro micro2)
 171           type (max type type2))
 172     (when (< micro 0)
 173       (setq low (1- low)
 174             micro (+ micro 1000000)))
 175     (when (< low 0)
 176       (setq high (1- high)
 177             low (+ low 65536)))
 178     (encode-time-value high low micro type)))
 179
 180 ;;;###autoload
 181 (defun time-add (t1 t2)
 182   "Add two time values T1 and T2.  One should represent a time difference."
 183   (with-decoded-time-value ((high low micro type t1)
 184                             (high2 low2 micro2 type2 t2))
 185     (setq high (+ high high2)
 186           low (+ low low2)
 187           micro (+ micro micro2)
 188           type (max type type2))
 189     (when (>= micro 1000000)
 190       (setq low (1+ low)
 191             micro (- micro 1000000)))
 192     (when (>= low 65536)
 193       (setq high (1+ high)
 194             low (- low 65536)))
 195     (encode-time-value high low micro type)))
 196
 197 ;;;###autoload
 198 (defun date-to-day (date)
 199   "Return the number of days between year 1 and DATE.
 200 DATE should be a date-time string."
 201   (time-to-days (date-to-time date)))
 202
 203 ;;;###autoload
 204 (defun days-between (date1 date2)
 205   "Return the number of days between DATE1 and DATE2.
 206 DATE1 and DATE2 should be date-time strings."
 207   (- (date-to-day date1) (date-to-day date2)))
 208
 209 ;;;###autoload
 210 (defun date-leap-year-p (year)
 211   "Return t if YEAR is a leap year."
 212   (or (and (zerop (% year 4))
 213            (not (zerop (% year 100))))
 214       (zerop (% year 400))))
 215
 216 ;;;###autoload
 217 (defun time-to-day-in-year (time)
 218   "Return the day number within the year corresponding to TIME."
 219   (let* ((tim (decode-time time))
 220          (month (nth 4 tim))
 221          (day (nth 3 tim))
 222          (year (nth 5 tim))
 223          (day-of-year (+ day (* 31 (1- month)))))
 224     (when (> month 2)
 225       (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 226       (when (date-leap-year-p year)
 227         (setq day-of-year (1+ day-of-year))))
 228     day-of-year))
 229
 230 ;;;###autoload
 231 (defun time-to-days (time)
 232   "The number of days between the Gregorian date 0001-12-31bce and TIME.
 233 TIME should be a time value.
 234 The Gregorian date Sunday, December 31, 1bce is imaginary."
 235   (let* ((tim (decode-time time))
 236          (month (nth 4 tim))
 237          (day (nth 3 tim))
 238          (year (nth 5 tim)))
 239     (+ (time-to-day-in-year time)       ;       Days this year
 240        (* 365 (1- year))                ;       + Days in prior years
 241        (/ (1- year) 4)                  ;       + Julian leap years
 242        (- (/ (1- year) 100))            ;       - century years
 243        (/ (1- year) 400))))             ;       + Gregorian leap years
 244
 245 (defun time-to-number-of-days (time)
 246   "Return the number of days represented by TIME.
 247 The number of days will be returned as a floating point number."
 248   (/ (time-to-seconds time) (* 60 60 24)))
 249
 250 ;;;###autoload
 251 (defun safe-date-to-time (date)
 252   "Parse a string DATE that represents a date-time and return a time value.
 253 If DATE is malformed, return a time value of zeros."
 254   (condition-case ()
 255       (date-to-time date)
 256     (error '(0 0))))
 257
 258 \f
 259 ;;;###autoload
 260 (defun format-seconds (string seconds)
 261   "Use format control STRING to format the number SECONDS.
 262 The valid format specifiers are:
 263 %y is the number of (365-day) years.
 264 %d is the number of days.
 265 %h is the number of hours.
 266 %m is the number of minutes.
 267 %s is the number of seconds.
 268 %z is a non-printing control flag (see below).
 269 %% is a literal \"%\".
 270
 271 Upper-case specifiers are followed by the unit-name (e.g. \"years\").
 272 Lower-case specifiers return only the unit.
 273
 274 \"%\" may be followed by a number specifying a width, with an
 275 optional leading \".\" for zero-padding.  For example, \"%.3Y\" will
 276 return something of the form \"001 year\".
 277
 278 The \"%z\" specifier does not print anything.  When it is used, specifiers
 279 must be given in order of decreasing size.  To the left of \"%z\", nothing
 280 is output until the first non-zero unit is encountered.
 281
 282 This function does not work for SECONDS greater than `most-positive-fixnum'."
 283   (let ((start 0)
 284         (units '(("y" "year"   31536000)
 285                  ("d" "day"       86400)
 286                  ("h" "hour"       3600)
 287                  ("m" "minute"       60)
 288                  ("s" "second"        1)
 289                  ("z")))
 290         (case-fold-search t)
 291         spec match usedunits zeroflag larger prev name unit num zeropos)
 292     (while (string-match "%\\.?[0-9]*\\(.\\)" string start)
 293       (setq start (match-end 0)
 294             spec (match-string 1 string))
 295       (unless (string-equal spec "%")
 296         ;; `assoc-string' is not available in Emacs 21.  So when compiling
 297         ;; Gnus (`time-date.el' is part of Gnus) with Emacs 21, we get a
 298         ;; warning here.  But `format-seconds' is not used anywhere in Gnus so
 299         ;; it's not a real problem. --rsteib
 300         (or (setq match (assoc-string spec units t))
 301             (error "Bad format specifier: `%s'" spec))
 302         (if (assoc-string spec usedunits t)
 303             (error "Multiple instances of specifier: `%s'" spec))
 304         (if (string-equal (car match) "z")
 305             (setq zeroflag t)
 306           (unless larger
 307             (setq unit (nth 2 match)
 308                   larger (and prev (> unit prev))
 309                   prev unit)))
 310         (push match usedunits)))
 311     (and zeroflag larger
 312          (error "Units are not in decreasing order of size"))
 313     (dolist (u units)
 314       (setq spec (car u)
 315             name (cadr u)
 316             unit (nth 2 u))
 317       (when (string-match (format "%%\\(\\.?[0-9]+\\)?\\(%s\\)" spec) string)
 318         (if (string-equal spec "z")     ; must be last in units
 319             (setq string
 320                   (replace-regexp-in-string
 321                    "%z" ""
 322                    (substring string (min (or zeropos (match-end 0))
 323                                           (match-beginning 0)))))
 324           ;; Cf article-make-date-line in gnus-art.
 325           (setq num (floor seconds unit)
 326                 seconds (- seconds (* num unit)))
 327           ;; Start position of the first non-zero unit.
 328           (or zeropos
 329               (setq zeropos (unless (zerop num) (match-beginning 0))))
 330           (setq string
 331                 (replace-match
 332                  (format (concat "%" (match-string 1 string) "d%s") num
 333                          (if (string-equal (match-string 2 string) spec)
 334                              ""       ; lower-case, no unit-name
 335                            (format " %s%s" name
 336                                    (if (= num 1) "" "s"))))
 337                  t t string))))))
 338   (replace-regexp-in-string "%%" "%" string))
 339
 340
 341 (provide 'time-date)
 342
 343 ;; arch-tag: addcf07b-b20a-465b-af72-550b8ac5190f
 344 ;;; time-date.el ends here