lisp/tar-mode.el

   1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
   2
   3 ;; Copyright (C) 1990,91,93,94,95,96,97,98,99,2000,2001
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 04 Apr 1990
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package attempts to make dealing with Unix 'tar' archives easier.
  31 ;; When this code is loaded, visiting a file whose name ends in '.tar' will
  32 ;; cause the contents of that archive file to be displayed in a Dired-like
  33 ;; listing.  It is then possible to use the customary Dired keybindings to
  34 ;; extract sub-files from that archive, either by reading them into their own
  35 ;; editor buffers, or by copying them directly to arbitrary files on disk.
  36 ;; It is also possible to delete sub-files from within the tar file and write
  37 ;; the modified archive back to disk, or to edit sub-files within the archive
  38 ;; and re-insert the modified files into the archive.  See the documentation
  39 ;; string of tar-mode for more info.
  40
  41 ;; This code now understands the extra fields that GNU tar adds to tar files.
  42
  43 ;; This interacts correctly with "uncompress.el" in the Emacs library,
  44 ;; which you get with
  45 ;;
  46 ;;  (autoload 'uncompress-while-visiting "uncompress")
  47 ;;  (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
  48 ;;                         auto-mode-alist))
  49 ;;
  50 ;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
  51
  52 ;;    ***************   TO DO   ***************
  53 ;;
  54 ;; o  chmod should understand "a+x,og-w".
  55 ;;
  56 ;; o  It's not possible to add a NEW file to a tar archive; not that
  57 ;;    important, but still...
  58 ;;
  59 ;; o  The code is less efficient that it could be - in a lot of places, I
  60 ;;    pull a 512-character string out of the buffer and parse it, when I could
  61 ;;    be parsing it in place, not garbaging a string.  Should redo that.
  62 ;;
  63 ;; o  I'd like a command that searches for a string/regexp in every subfile
  64 ;;    of an archive, where <esc> would leave you in a subfile-edit buffer.
  65 ;;    (Like the Meta-R command of the Zmacs mail reader.)
  66 ;;
  67 ;; o  Sometimes (but not always) reverting the tar-file buffer does not
  68 ;;    re-grind the listing, and you are staring at the binary tar data.
  69 ;;    Typing 'g' again immediately after that will always revert and re-grind
  70 ;;    it, though.  I have no idea why this happens.
  71 ;;
  72 ;; o  Tar-mode interacts poorly with crypt.el and zcat.el because the tar
  73 ;;    write-file-hook actually writes the file.  Instead it should remove the
  74 ;;    header (and conspire to put it back afterwards) so that other write-file
  75 ;;    hooks which frob the buffer have a chance to do their dirty work.  There
  76 ;;    might be a problem if the tar write-file-hook does not come *first* on
  77 ;;    the list.
  78 ;;
  79 ;; o  Block files, sparse files, continuation files, and the various header
  80 ;;    types aren't editable.  Actually I don't know that they work at all.
  81
  82 ;; Rationale:
  83
  84 ;; Why does tar-mode edit the file itself instead of using tar?
  85
  86 ;; That means that you can edit tar files which you don't have room for
  87 ;; on your local disk.
  88
  89 ;; I don't know about recent features in gnu tar, but old versions of tar
  90 ;; can't replace a file in the middle of a tar file with a new version.
  91 ;; Tar-mode can.  I don't think tar can do things like chmod the subfiles.
  92 ;; An implementation which involved unpacking and repacking the file into
  93 ;; some scratch directory would be very wasteful, and wouldn't be able to
  94 ;; preserve the file owners.
  95
  96 ;;; Code:
  97
  98 (defgroup tar nil
  99   "Simple editing of tar files."
 100   :prefix "tar-"
 101   :group 'data)
 102
 103 (defcustom tar-anal-blocksize 20
 104   "*The blocksize of tar files written by Emacs, or nil, meaning don't care.
 105 The blocksize of a tar file is not really the size of the blocks; rather, it is
 106 the number of blocks written with one system call.  When tarring to a tape,
 107 this is the size of the *tape* blocks, but when writing to a file, it doesn't
 108 matter much.  The only noticeable difference is that if a tar file does not
 109 have a blocksize of 20, tar will tell you that; all this really controls is
 110 how many null padding bytes go on the end of the tar file."
 111   :type '(choice integer (const nil))
 112   :group 'tar)
 113
 114 (defcustom tar-update-datestamp nil
 115   "*Non-nil means Tar mode should play fast and loose with sub-file datestamps.
 116 If this is true, then editing and saving a tar file entry back into its
 117 tar file will update its datestamp.  If false, the datestamp is unchanged.
 118 You may or may not want this - it is good in that you can tell when a file
 119 in a tar archive has been changed, but it is bad for the same reason that
 120 editing a file in the tar archive at all is bad - the changed version of
 121 the file never exists on disk."
 122   :type 'boolean
 123   :group 'tar)
 124
 125 (defcustom tar-mode-show-date nil
 126   "*Non-nil means Tar mode should show the date/time of each subfile.
 127 This information is useful, but it takes screen space away from file names."
 128   :type 'boolean
 129   :group 'tar)
 130
 131 (defvar tar-parse-info nil)
 132 ;; Be sure that this variable holds byte position, not char position.
 133 (defvar tar-header-offset nil)
 134 (defvar tar-superior-buffer nil)
 135 (defvar tar-superior-descriptor nil)
 136 (defvar tar-subfile-mode nil)
 137
 138 (put 'tar-parse-info 'permanent-local t)
 139 (put 'tar-header-offset 'permanent-local t)
 140 (put 'tar-superior-buffer 'permanent-local t)
 141 (put 'tar-superior-descriptor 'permanent-local t)
 142 \f
 143 (defmacro tar-setf (form val)
 144   "A mind-numbingly simple implementation of setf."
 145   (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
 146                                       byte-compile-macro-environment))))
 147     (cond ((symbolp mform) (list 'setq mform val))
 148           ((not (consp mform)) (error "can't setf %s" form))
 149           ((eq (car mform) 'aref)
 150            (list 'aset (nth 1 mform) (nth 2 mform) val))
 151           ((eq (car mform) 'car)
 152            (list 'setcar (nth 1 mform) val))
 153           ((eq (car mform) 'cdr)
 154            (list 'setcdr (nth 1 mform) val))
 155           (t (error "don't know how to setf %s" form)))))
 156 \f
 157 ;;; down to business.
 158
 159 (defmacro make-tar-header (name mode uid git size date ck lt ln
 160                            magic uname gname devmaj devmin)
 161   (list 'vector name mode uid git size date ck lt ln
 162         magic uname gname devmaj devmin))
 163
 164 (defmacro tar-header-name (x) (list 'aref x 0))
 165 (defmacro tar-header-mode (x) (list 'aref x 1))
 166 (defmacro tar-header-uid  (x) (list 'aref x 2))
 167 (defmacro tar-header-gid  (x) (list 'aref x 3))
 168 (defmacro tar-header-size (x) (list 'aref x 4))
 169 (defmacro tar-header-date (x) (list 'aref x 5))
 170 (defmacro tar-header-checksum  (x) (list 'aref x 6))
 171 (defmacro tar-header-link-type (x) (list 'aref x 7))
 172 (defmacro tar-header-link-name (x) (list 'aref x 8))
 173 (defmacro tar-header-magic (x) (list 'aref x 9))
 174 (defmacro tar-header-uname (x) (list 'aref x 10))
 175 (defmacro tar-header-gname (x) (list 'aref x 11))
 176 (defmacro tar-header-dmaj (x) (list 'aref x 12))
 177 (defmacro tar-header-dmin (x) (list 'aref x 13))
 178
 179 (defmacro make-tar-desc (data-start tokens)
 180   (list 'cons data-start tokens))
 181
 182 (defmacro tar-desc-data-start (x) (list 'car x))
 183 (defmacro tar-desc-tokens     (x) (list 'cdr x))
 184
 185 (defconst tar-name-offset 0)
 186 (defconst tar-mode-offset (+ tar-name-offset 100))
 187 (defconst tar-uid-offset  (+ tar-mode-offset 8))
 188 (defconst tar-gid-offset  (+ tar-uid-offset 8))
 189 (defconst tar-size-offset (+ tar-gid-offset 8))
 190 (defconst tar-time-offset (+ tar-size-offset 12))
 191 (defconst tar-chk-offset  (+ tar-time-offset 12))
 192 (defconst tar-linkp-offset (+ tar-chk-offset 8))
 193 (defconst tar-link-offset (+ tar-linkp-offset 1))
 194 ;;; GNU-tar specific slots.
 195 (defconst tar-magic-offset (+ tar-link-offset 100))
 196 (defconst tar-uname-offset (+ tar-magic-offset 8))
 197 (defconst tar-gname-offset (+ tar-uname-offset 32))
 198 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
 199 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
 200 (defconst tar-end-offset (+ tar-dmin-offset 8))
 201
 202 (defun tar-header-block-tokenize (string)
 203   "Return a `tar-header' structure.
 204 This is a list of name, mode, uid, gid, size,
 205 write-date, checksum, link-type, and link-name."
 206   (cond ((< (length string) 512) nil)
 207         (;(some 'plusp string)           ; <-- oops, massive cycle hog!
 208          (or (not (= 0 (aref string 0))) ; This will do.
 209              (not (= 0 (aref string 101))))
 210          (let* ((name-end (1- tar-mode-offset))
 211                 (link-end (1- tar-magic-offset))
 212                 (uname-end (1- tar-gname-offset))
 213                 (gname-end (1- tar-dmaj-offset))
 214                 (link-p (aref string tar-linkp-offset))
 215                 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
 216                 (uname-valid-p (or (string= "ustar  " magic-str) (string= "GNUtar " magic-str)))
 217                 name linkname
 218                 (nulsexp   "[^\000]*\000"))
 219            (when (string-match nulsexp string tar-name-offset)
 220              (setq name-end (min name-end (1- (match-end 0)))))
 221            (when (string-match nulsexp string tar-link-offset)
 222              (setq link-end (min link-end (1- (match-end 0)))))
 223            (when (string-match nulsexp string tar-uname-offset)
 224              (setq uname-end (min uname-end (1- (match-end 0)))))
 225            (when (string-match nulsexp string tar-gname-offset)
 226              (setq gname-end (min gname-end (1- (match-end 0)))))
 227            (setq name (substring string tar-name-offset name-end)
 228                  link-p (if (or (= link-p 0) (= link-p ?0))
 229                             nil
 230                           (- link-p ?0)))
 231            (setq linkname (substring string tar-link-offset link-end))
 232            (if default-enable-multibyte-characters
 233                (setq name
 234                      (decode-coding-string name (or file-name-coding-system
 235                                                     'undecided))
 236                      linkname
 237                      (decode-coding-string linkname (or file-name-coding-system
 238                                                         'undecided))))
 239            (if (and (null link-p) (string-match "/$" name)) (setq link-p 5)) ; directory
 240            (make-tar-header
 241              name
 242              (tar-parse-octal-integer string tar-mode-offset tar-uid-offset)
 243              (tar-parse-octal-integer string tar-uid-offset tar-gid-offset)
 244              (tar-parse-octal-integer string tar-gid-offset tar-size-offset)
 245              (tar-parse-octal-integer string tar-size-offset tar-time-offset)
 246              (tar-parse-octal-long-integer string tar-time-offset tar-chk-offset)
 247              (tar-parse-octal-integer string tar-chk-offset tar-linkp-offset)
 248              link-p
 249              linkname
 250              uname-valid-p
 251              (and uname-valid-p (substring string tar-uname-offset uname-end))
 252              (and uname-valid-p (substring string tar-gname-offset gname-end))
 253              (tar-parse-octal-integer string tar-dmaj-offset tar-dmin-offset)
 254              (tar-parse-octal-integer string tar-dmin-offset tar-end-offset)
 255              )))
 256         (t 'empty-tar-block)))
 257
 258
 259 (defun tar-parse-octal-integer (string &optional start end)
 260   (if (null start) (setq start 0))
 261   (if (null end) (setq end (length string)))
 262   (if (= (aref string start) 0)
 263       0
 264     (let ((n 0))
 265       (while (< start end)
 266         (setq n (if (< (aref string start) ?0) n
 267                   (+ (* n 8) (- (aref string start) ?0)))
 268               start (1+ start)))
 269       n)))
 270
 271 (defun tar-parse-octal-long-integer (string &optional start end)
 272   (if (null start) (setq start 0))
 273   (if (null end) (setq end (length string)))
 274   (if (= (aref string start) 0)
 275       (list 0 0)
 276     (let ((lo 0)
 277           (hi 0))
 278       (while (< start end)
 279         (if (>= (aref string start) ?0)
 280             (setq lo (+ (* lo 8) (- (aref string start) ?0))
 281                   hi (+ (* hi 8) (ash lo -16))
 282                   lo (logand lo 65535)))
 283         (setq start (1+ start)))
 284       (list hi lo))))
 285
 286 (defun tar-parse-octal-integer-safe (string)
 287   (let ((L (length string)))
 288     (if (= L 0) (error "empty string"))
 289     (dotimes (i L)
 290        (if (or (< (aref string i) ?0)
 291                (> (aref string i) ?7))
 292            (error "`%c' is not an octal digit"))))
 293   (tar-parse-octal-integer string))
 294
 295
 296 (defun tar-header-block-checksum (string)
 297   "Compute and return a tar-acceptable checksum for this block."
 298   (let* ((chk-field-start tar-chk-offset)
 299          (chk-field-end (+ chk-field-start 8))
 300          (sum 0)
 301          (i 0))
 302     ;; Add up all of the characters except the ones in the checksum field.
 303     ;; Add that field as if it were filled with spaces.
 304     (while (< i chk-field-start)
 305       (setq sum (+ sum (aref string i))
 306             i (1+ i)))
 307     (setq i chk-field-end)
 308     (while (< i 512)
 309       (setq sum (+ sum (aref string i))
 310             i (1+ i)))
 311     (+ sum (* 32 8))))
 312
 313 (defun tar-header-block-check-checksum (hblock desired-checksum file-name)
 314   "Beep and print a warning if the checksum doesn't match."
 315   (if (not (= desired-checksum (tar-header-block-checksum hblock)))
 316       (progn (beep) (message "Invalid checksum for file %s!" file-name))))
 317
 318 (defun tar-clip-time-string (time)
 319   (let ((str (current-time-string time)))
 320     (concat " " (substring str 4 16) (substring str 19 24))))
 321
 322 (defun tar-grind-file-mode (mode)
 323   "Construct a `-rw--r--r--' string indicating MODE.
 324 MODE should be an integer which is a file mode value."
 325   (string
 326    (if (zerop (logand 256 mode)) ?- ?r)
 327    (if (zerop (logand 128 mode)) ?- ?w)
 328    (if (zerop (logand 1024 mode)) (if (zerop (logand  64 mode)) ?- ?x) ?s)
 329    (if (zerop (logand  32 mode)) ?- ?r)
 330    (if (zerop (logand  16 mode)) ?- ?w)
 331    (if (zerop (logand 2048 mode)) (if (zerop (logand   8 mode)) ?- ?x) ?s)
 332    (if (zerop (logand   4 mode)) ?- ?r)
 333    (if (zerop (logand   2 mode)) ?- ?w)
 334    (if (zerop (logand   1 mode)) ?- ?x)))
 335
 336 (defun tar-header-block-summarize (tar-hblock &optional mod-p)
 337   "Return a line similar to the output of `tar -vtf'."
 338   (let ((name (tar-header-name tar-hblock))
 339         (mode (tar-header-mode tar-hblock))
 340         (uid (tar-header-uid tar-hblock))
 341         (gid (tar-header-gid tar-hblock))
 342         (uname (tar-header-uname tar-hblock))
 343         (gname (tar-header-gname tar-hblock))
 344         (size (tar-header-size tar-hblock))
 345         (time (tar-header-date tar-hblock))
 346         (ck (tar-header-checksum tar-hblock))
 347         (type (tar-header-link-type tar-hblock))
 348         (link-name (tar-header-link-name tar-hblock)))
 349     (format "%c%c%s%8s/%-8s%7s%s %s%s"
 350             (if mod-p ?* ? )
 351             (cond ((or (eq type nil) (eq type 0)) ?-)
 352                   ((eq type 1) ?l)      ; link
 353                   ((eq type 2) ?s)      ; symlink
 354                   ((eq type 3) ?c)      ; char special
 355                   ((eq type 4) ?b)      ; block special
 356                   ((eq type 5) ?d)      ; directory
 357                   ((eq type 6) ?p)      ; FIFO/pipe
 358                   ((eq type 20) ?*)     ; directory listing
 359                   ((eq type 28) ?L)     ; next has longname
 360                   ((eq type 29) ?M)     ; multivolume continuation
 361                   ((eq type 35) ?S)     ; sparse
 362                   ((eq type 38) ?V)     ; volume header
 363                   (t ?\ )
 364                   )
 365             (tar-grind-file-mode mode)
 366             (if (= 0 (length uname)) uid uname)
 367             (if (= 0 (length gname)) gid gname)
 368             size
 369             (if tar-mode-show-date (tar-clip-time-string time) "")
 370             (propertize name
 371                         'mouse-face 'highlight
 372                         'help-echo "mouse-2: extract this file into a buffer")
 373             (if (or (eq type 1) (eq type 2))
 374                 (concat (if (= type 1) " ==> " " --> ") link-name)
 375               ""))))
 376
 377 (defun tar-untar-buffer ()
 378   "Extract all archive members in the tar-file."
 379   (interactive)
 380   (let ((multibyte enable-multibyte-characters))
 381     (unwind-protect
 382         (save-restriction
 383           (widen)
 384           (set-buffer-multibyte nil)
 385           (dolist (descriptor tar-parse-info)
 386             (let* ((tokens (tar-desc-tokens descriptor))
 387                    (name (tar-header-name tokens))
 388                    (dir (file-name-directory name))
 389                    (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
 390                    (end (+ start (tar-header-size tokens))))
 391               (unless (file-directory-p name)
 392                 (message "Extracting %s" name)
 393                 (if (and dir (not (file-exists-p dir)))
 394                     (make-directory dir t))
 395                 (write-region start end name)
 396                 (set-file-modes name (tar-header-mode tokens))))))
 397       (set-buffer-multibyte multibyte))))
 398
 399 (defun tar-summarize-buffer ()
 400   "Parse the contents of the tar file in the current buffer.
 401 Place a dired-like listing on the front;
 402 then narrow to it, so that only that listing
 403 is visible (and the real data of the buffer is hidden)."
 404   (set-buffer-multibyte nil)
 405   (message "Parsing tar file...")
 406   (let* ((result '())
 407          (pos 1)
 408          (bs (max 1 (- (buffer-size) 1024))) ; always 2+ empty blocks at end.
 409          (bs100 (max 1 (/ bs 100)))
 410          tokens)
 411     (while (and (<= (+ pos 512) (point-max))
 412                 (not (eq 'empty-tar-block
 413                          (setq tokens
 414                                (tar-header-block-tokenize
 415                                 (buffer-substring pos (+ pos 512)))))))
 416       (setq pos (+ pos 512))
 417       (message "Parsing tar file...%d%%"
 418                ;(/ (* pos 100) bs)   ; this gets round-off lossage
 419                (/ pos bs100)         ; this doesn't
 420                )
 421       (if (eq (tar-header-link-type tokens) 20)
 422           ;; Foo.  There's an extra empty block after these.
 423           (setq pos (+ pos 512)))
 424       (let ((size (tar-header-size tokens)))
 425         (if (< size 0)
 426             (error "%s has size %s - corrupted"
 427                    (tar-header-name tokens) size))
 428         ;
 429         ; This is just too slow.  Don't really need it anyway....
 430         ;(tar-header-block-check-checksum
 431         ;  hblock (tar-header-block-checksum hblock)
 432         ;  (tar-header-name tokens))
 433
 434         (setq result (cons (make-tar-desc pos tokens) result))
 435
 436         (and (null (tar-header-link-type tokens))
 437              (> size 0)
 438              (setq pos
 439                    (+ pos 512 (ash (ash (1- size) -9) 9))        ; this works
 440                    ;(+ pos (+ size (- 512 (rem (1- size) 512)))) ; this doesn't
 441                    ))))
 442     (make-local-variable 'tar-parse-info)
 443     (setq tar-parse-info (nreverse result))
 444     ;; A tar file should end with a block or two of nulls,
 445     ;; but let's not get a fatal error if it doesn't.
 446     (if (eq tokens 'empty-tar-block)
 447         (message "Parsing tar file...done")
 448       (message "Warning: premature EOF parsing tar file")))
 449   (save-excursion
 450     (goto-char (point-min))
 451     (let ((buffer-read-only nil)
 452           (summaries nil))
 453       ;; Collect summary lines and insert them all at once since tar files
 454       ;; can be pretty big.
 455       (dolist (tar-desc (reverse tar-parse-info))
 456         (setq summaries
 457               (cons (tar-header-block-summarize (tar-desc-tokens tar-desc))
 458                     (cons "\n"
 459                           summaries))))
 460       (let ((total-summaries (apply 'concat summaries)))
 461         (if (multibyte-string-p total-summaries)
 462             (set-buffer-multibyte t))
 463         (insert total-summaries))
 464       (make-local-variable 'tar-header-offset)
 465       (setq tar-header-offset (point))
 466       (narrow-to-region 1 tar-header-offset)
 467       (if enable-multibyte-characters
 468           (setq tar-header-offset (position-bytes tar-header-offset)))
 469       (set-buffer-modified-p nil))))
 470 \f
 471 (defvar tar-mode-map nil "*Local keymap for Tar mode listings.")
 472
 473 (if tar-mode-map
 474     nil
 475   (setq tar-mode-map (make-keymap))
 476   (suppress-keymap tar-mode-map)
 477   (define-key tar-mode-map " " 'tar-next-line)
 478   (define-key tar-mode-map "C" 'tar-copy)
 479   (define-key tar-mode-map "d" 'tar-flag-deleted)
 480   (define-key tar-mode-map "\^D" 'tar-flag-deleted)
 481   (define-key tar-mode-map "e" 'tar-extract)
 482   (define-key tar-mode-map "f" 'tar-extract)
 483   (define-key tar-mode-map "\C-m" 'tar-extract)
 484   (define-key tar-mode-map [mouse-2] 'tar-mouse-extract)
 485   (define-key tar-mode-map "g" 'revert-buffer)
 486   (define-key tar-mode-map "h" 'describe-mode)
 487   (define-key tar-mode-map "n" 'tar-next-line)
 488   (define-key tar-mode-map "\^N" 'tar-next-line)
 489   (define-key tar-mode-map [down] 'tar-next-line)
 490   (define-key tar-mode-map "o" 'tar-extract-other-window)
 491   (define-key tar-mode-map "p" 'tar-previous-line)
 492   (define-key tar-mode-map "q" 'quit-window)
 493   (define-key tar-mode-map "\^P" 'tar-previous-line)
 494   (define-key tar-mode-map [up] 'tar-previous-line)
 495   (define-key tar-mode-map "R" 'tar-rename-entry)
 496   (define-key tar-mode-map "u" 'tar-unflag)
 497   (define-key tar-mode-map "v" 'tar-view)
 498   (define-key tar-mode-map "x" 'tar-expunge)
 499   (define-key tar-mode-map "\177" 'tar-unflag-backwards)
 500   (define-key tar-mode-map "E" 'tar-extract-other-window)
 501   (define-key tar-mode-map "M" 'tar-chmod-entry)
 502   (define-key tar-mode-map "G" 'tar-chgrp-entry)
 503   (define-key tar-mode-map "O" 'tar-chown-entry)
 504   )
 505 \f
 506 ;; Make menu bar items.
 507
 508 ;; Get rid of the Edit menu bar item to save space.
 509 (define-key tar-mode-map [menu-bar edit] 'undefined)
 510
 511 (define-key tar-mode-map [menu-bar immediate]
 512   (cons "Immediate" (make-sparse-keymap "Immediate")))
 513
 514 (define-key tar-mode-map [menu-bar immediate view]
 515   '("View This File" . tar-view))
 516 (define-key tar-mode-map [menu-bar immediate display]
 517   '("Display in Other Window" . tar-display-other-window))
 518 (define-key tar-mode-map [menu-bar immediate find-file-other-window]
 519   '("Find in Other Window" . tar-extract-other-window))
 520 (define-key tar-mode-map [menu-bar immediate find-file]
 521   '("Find This File" . tar-extract))
 522
 523 (define-key tar-mode-map [menu-bar mark]
 524   (cons "Mark" (make-sparse-keymap "Mark")))
 525
 526 (define-key tar-mode-map [menu-bar mark unmark-all]
 527   '("Unmark All" . tar-clear-modification-flags))
 528 (define-key tar-mode-map [menu-bar mark deletion]
 529   '("Flag" . tar-flag-deleted))
 530 (define-key tar-mode-map [menu-bar mark unmark]
 531   '("Unflag" . tar-unflag))
 532
 533 (define-key tar-mode-map [menu-bar operate]
 534   (cons "Operate" (make-sparse-keymap "Operate")))
 535
 536 (define-key tar-mode-map [menu-bar operate chown]
 537   '("Change Owner..." . tar-chown-entry))
 538 (define-key tar-mode-map [menu-bar operate chgrp]
 539   '("Change Group..." . tar-chgrp-entry))
 540 (define-key tar-mode-map [menu-bar operate chmod]
 541   '("Change Mode..." . tar-chmod-entry))
 542 (define-key tar-mode-map [menu-bar operate rename]
 543   '("Rename to..." . tar-rename-entry))
 544 (define-key tar-mode-map [menu-bar operate copy]
 545   '("Copy to..." . tar-copy))
 546 (define-key tar-mode-map [menu-bar operate expunge]
 547   '("Expunge Marked Files" . tar-expunge))
 548 \f
 549 ;; tar mode is suitable only for specially formatted data.
 550 (put 'tar-mode 'mode-class 'special)
 551 (put 'tar-subfile-mode 'mode-class 'special)
 552
 553 ;;;###autoload
 554 (define-derived-mode tar-mode nil "Tar"
 555   "Major mode for viewing a tar file as a dired-like listing of its contents.
 556 You can move around using the usual cursor motion commands.
 557 Letters no longer insert themselves.
 558 Type `e' to pull a file out of the tar file and into its own buffer;
 559 or click mouse-2 on the file's line in the Tar mode buffer.
 560 Type `c' to copy an entry from the tar file into another file on disk.
 561
 562 If you edit a sub-file of this archive (as with the `e' command) and
 563 save it with Control-x Control-s, the contents of that buffer will be
 564 saved back into the tar-file buffer; in this way you can edit a file
 565 inside of a tar archive without extracting it and re-archiving it.
 566
 567 See also: variables `tar-update-datestamp' and `tar-anal-blocksize'.
 568 \\{tar-mode-map}"
 569   ;; this is not interactive because you shouldn't be turning this
 570   ;; mode on and off.  You can corrupt things that way.
 571   ;; rms: with permanent locals, it should now be possible to make this work
 572   ;; interactively in some reasonable fashion.
 573   (make-local-variable 'tar-header-offset)
 574   (make-local-variable 'tar-parse-info)
 575   (set (make-local-variable 'require-final-newline) nil) ; binary data, dude...
 576   (set (make-local-variable 'revert-buffer-function) 'tar-mode-revert)
 577   (set (make-local-variable 'local-enable-local-variables) nil)
 578   (set (make-local-variable 'next-line-add-newlines) nil)
 579   ;; Prevent loss of data when saving the file.
 580   (set (make-local-variable 'file-precious-flag) t)
 581   (auto-save-mode 0)
 582   (set (make-local-variable 'write-contents-hooks) '(tar-mode-write-file))
 583   (widen)
 584   (if (and (boundp 'tar-header-offset) tar-header-offset)
 585       (narrow-to-region 1 (byte-to-position tar-header-offset))
 586     (tar-summarize-buffer)
 587     (tar-next-line 0)))
 588
 589
 590 (defun tar-subfile-mode (p)
 591   "Minor mode for editing an element of a tar-file.
 592 This mode arranges for \"saving\" this buffer to write the data
 593 into the tar-file buffer that it came from.  The changes will actually
 594 appear on disk when you save the tar-file's buffer."
 595   (interactive "P")
 596   (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
 597       (error "This buffer is not an element of a tar file"))
 598 ;;; Don't do this, because it is redundant and wastes mode line space.
 599 ;;;  (or (assq 'tar-subfile-mode minor-mode-alist)
 600 ;;;      (setq minor-mode-alist (append minor-mode-alist
 601 ;;;                                  (list '(tar-subfile-mode " TarFile")))))
 602   (make-local-variable 'tar-subfile-mode)
 603   (setq tar-subfile-mode
 604         (if (null p)
 605             (not tar-subfile-mode)
 606             (> (prefix-numeric-value p) 0)))
 607   (cond (tar-subfile-mode
 608          (add-hook 'write-file-functions 'tar-subfile-save-buffer nil t)
 609          ;; turn off auto-save.
 610          (auto-save-mode -1)
 611          (setq buffer-auto-save-file-name nil)
 612          (run-hooks 'tar-subfile-mode-hook))
 613         (t
 614          (remove-hook 'write-file-functions 'tar-subfile-save-buffer t))))
 615
 616
 617 ;; Revert the buffer and recompute the dired-like listing.
 618 (defun tar-mode-revert (&optional no-auto-save no-confirm)
 619   (let ((revert-buffer-function nil)
 620         (old-offset tar-header-offset)
 621         success)
 622     (setq tar-header-offset nil)
 623     (unwind-protect
 624         (and (revert-buffer t no-confirm)
 625              (progn (widen)
 626                     (setq success t)
 627                     (tar-mode)))
 628       ;; If the revert was canceled,
 629       ;; put back the old value of tar-header-offset.
 630       (or success
 631           (setq tar-header-offset old-offset)))))
 632
 633
 634 (defun tar-next-line (arg)
 635   "Move cursor vertically down ARG lines and to the start of the filename."
 636   (interactive "p")
 637   (forward-line arg)
 638   (if (eobp) nil (forward-char (if tar-mode-show-date 54 36))))
 639
 640 (defun tar-previous-line (arg)
 641   "Move cursor vertically up ARG lines and to the start of the filename."
 642   (interactive "p")
 643   (tar-next-line (- arg)))
 644
 645 (defun tar-current-descriptor (&optional noerror)
 646   "Return the tar-descriptor of the current line, or signals an error."
 647   ;; I wish lines had plists, like in ZMACS...
 648   (or (nth (count-lines (point-min)
 649                         (save-excursion (beginning-of-line) (point)))
 650            tar-parse-info)
 651       (if noerror
 652           nil
 653           (error "This line does not describe a tar-file entry"))))
 654
 655 (defun tar-get-descriptor ()
 656   (let* ((descriptor (tar-current-descriptor))
 657          (tokens (tar-desc-tokens descriptor))
 658          (size (tar-header-size tokens))
 659          (link-p (tar-header-link-type tokens)))
 660     (if link-p
 661         (error "This is a %s, not a real file"
 662                (cond ((eq link-p 5) "directory")
 663                      ((eq link-p 20) "tar directory header")
 664                      ((eq link-p 28) "next has longname")
 665                      ((eq link-p 29) "multivolume-continuation")
 666                      ((eq link-p 35) "sparse entry")
 667                      ((eq link-p 38) "volume header")
 668                      (t "link"))))
 669     (if (zerop size) (error "This is a zero-length file"))
 670     descriptor))
 671
 672 (defun tar-mouse-extract (event)
 673   "Extract a file whose tar directory line you click on."
 674   (interactive "e")
 675   (save-excursion
 676     (set-buffer (window-buffer (posn-window (event-end event))))
 677     (save-excursion
 678       (goto-char (posn-point (event-end event)))
 679       ;; Just make sure this doesn't get an error.
 680       (tar-get-descriptor)))
 681   (select-window (posn-window (event-end event)))
 682   (goto-char (posn-point (event-end event)))
 683   (tar-extract))
 684
 685 (defun tar-extract (&optional other-window-p)
 686   "In Tar mode, extract this entry of the tar file into its own buffer."
 687   (interactive)
 688   (let* ((view-p (eq other-window-p 'view))
 689          (descriptor (tar-get-descriptor))
 690          (tokens (tar-desc-tokens descriptor))
 691          (name (tar-header-name tokens))
 692          (size (tar-header-size tokens))
 693          (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
 694          (end (+ start size)))
 695     (let* ((tar-buffer (current-buffer))
 696            (tar-buffer-multibyte enable-multibyte-characters)
 697            (tarname (buffer-name))
 698            (bufname (concat (file-name-nondirectory name)
 699                             " ("
 700                              tarname
 701                              ")"))
 702            (read-only-p (or buffer-read-only view-p))
 703            (new-buffer-file-name (expand-file-name
 704                                   ;; `:' is not allowed on Windows
 705                                   (concat tarname "!" name)))
 706            (buffer (get-file-buffer new-buffer-file-name))
 707            (just-created nil))
 708       (unless buffer
 709         (setq buffer (generate-new-buffer bufname))
 710         (setq bufname (buffer-name buffer))
 711         (setq just-created t)
 712         (unwind-protect
 713             (progn
 714               (widen)
 715               (set-buffer-multibyte nil)
 716               (save-excursion
 717                 (set-buffer buffer)
 718                 (if enable-multibyte-characters
 719                     (progn
 720                       ;; We must avoid unibyte->multibyte conversion.
 721                       (set-buffer-multibyte nil)
 722                       (insert-buffer-substring tar-buffer start end)
 723                       (set-buffer-multibyte t))
 724                   (insert-buffer-substring tar-buffer start end))
 725                 (goto-char (point-min))
 726                 (setq buffer-file-name new-buffer-file-name)
 727                 (setq buffer-file-truename
 728                       (abbreviate-file-name buffer-file-name))
 729                 ;; We need to mimic the parts of insert-file-contents
 730                 ;; which determine the coding-system and decode the text.
 731                 (let ((coding
 732                        (or coding-system-for-read
 733                            (and set-auto-coding-function
 734                                 (save-excursion
 735                                   (funcall set-auto-coding-function
 736                                            name (- (point-max) (point)))))))
 737                       (multibyte enable-multibyte-characters)
 738                       (detected (detect-coding-region
 739                                  1 (min 16384 (point-max)) t)))
 740                   (if coding
 741                       (or (numberp (coding-system-eol-type coding))
 742                           (setq coding (coding-system-change-eol-conversion
 743                                         coding
 744                                         (coding-system-eol-type detected))))
 745                     (setq coding
 746                           (or (find-new-buffer-file-coding-system detected)
 747                               (let ((file-coding
 748                                      (find-operation-coding-system
 749                                       'insert-file-contents buffer-file-name)))
 750                                 (if (consp file-coding)
 751                                     (setq file-coding (car file-coding))
 752                                   file-coding)))))
 753                   (if (or (eq coding 'no-conversion)
 754                           (eq (coding-system-type coding) 5))
 755                       (setq multibyte (set-buffer-multibyte nil)))
 756                   (or multibyte
 757                       (setq coding
 758                             (coding-system-change-text-conversion
 759                              coding 'raw-text)))
 760                   (decode-coding-region 1 (point-max) coding)
 761                   (set-buffer-file-coding-system coding))
 762                 ;; Set the default-directory to the dir of the
 763                 ;; superior buffer.
 764                 (setq default-directory
 765                       (save-excursion
 766                         (set-buffer tar-buffer)
 767                         default-directory))
 768                 (normal-mode)  ; pick a mode.
 769                 (rename-buffer bufname)
 770                 (make-local-variable 'tar-superior-buffer)
 771                 (make-local-variable 'tar-superior-descriptor)
 772                 (setq tar-superior-buffer tar-buffer)
 773                 (setq tar-superior-descriptor descriptor)
 774                 (setq buffer-read-only read-only-p)
 775                 (set-buffer-modified-p nil)
 776                 (tar-subfile-mode 1))
 777               (set-buffer tar-buffer))
 778           (narrow-to-region 1 tar-header-offset)
 779           (set-buffer-multibyte tar-buffer-multibyte)))
 780       (if view-p
 781           (view-buffer buffer (and just-created 'kill-buffer))
 782         (if (eq other-window-p 'display)
 783             (display-buffer buffer)
 784           (if other-window-p
 785               (switch-to-buffer-other-window buffer)
 786             (switch-to-buffer buffer)))))))
 787
 788
 789 (defun tar-extract-other-window ()
 790   "*In Tar mode, find this entry of the tar file in another window."
 791   (interactive)
 792   (tar-extract t))
 793
 794 (defun tar-display-other-window ()
 795   "*In Tar mode, display this entry of the tar file in another window."
 796   (interactive)
 797   (tar-extract 'display))
 798
 799 (defun tar-view ()
 800   "*In Tar mode, view the tar file entry on this line."
 801   (interactive)
 802   (tar-extract 'view))
 803
 804
 805 (defun tar-read-file-name (&optional prompt)
 806   "Read a file name with this line's entry as the default."
 807   (or prompt (setq prompt "Copy to: "))
 808   (let* ((default-file (expand-file-name
 809                         (tar-header-name (tar-desc-tokens
 810                                           (tar-current-descriptor)))))
 811          (target (expand-file-name
 812                   (read-file-name prompt
 813                                   (file-name-directory default-file)
 814                                   default-file nil))))
 815     (if (or (string= "" (file-name-nondirectory target))
 816             (file-directory-p target))
 817         (setq target (concat (if (string-match "/$" target)
 818                                  (substring target 0 (1- (match-end 0)))
 819                                  target)
 820                              "/"
 821                              (file-name-nondirectory default-file))))
 822     target))
 823
 824
 825 (defun tar-copy (&optional to-file)
 826   "*In Tar mode, extract this entry of the tar file into a file on disk.
 827 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
 828 the current tar-entry."
 829   (interactive (list (tar-read-file-name)))
 830   (let* ((descriptor (tar-get-descriptor))
 831          (tokens (tar-desc-tokens descriptor))
 832          (name (tar-header-name tokens))
 833          (size (tar-header-size tokens))
 834          (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
 835          (end (+ start size))
 836          (multibyte enable-multibyte-characters)
 837          (inhibit-file-name-handlers inhibit-file-name-handlers)
 838          (inhibit-file-name-operation inhibit-file-name-operation))
 839     (save-restriction
 840       (widen)
 841       ;; Inhibit compressing a subfile again if *both* name and
 842       ;; to-file are handled by jka-compr
 843       (if (and (eq (find-file-name-handler name 'write-region) 'jka-compr-handler)
 844                (eq (find-file-name-handler to-file 'write-region) 'jka-compr-handler))
 845           (setq inhibit-file-name-handlers
 846                 (cons 'jka-compr-handler
 847                       (and (eq inhibit-file-name-operation 'write-region)
 848                            inhibit-file-name-handlers))
 849                 inhibit-file-name-operation 'write-region))
 850       (unwind-protect
 851           (let ((coding-system-for-write 'no-conversion))
 852             (set-buffer-multibyte nil)
 853             (write-region start end to-file nil nil nil t))
 854         (set-buffer-multibyte multibyte)))
 855     (message "Copied tar entry %s to %s" name to-file)))
 856
 857 (defun tar-flag-deleted (p &optional unflag)
 858   "*In Tar mode, mark this sub-file to be deleted from the tar file.
 859 With a prefix argument, mark that many files."
 860   (interactive "p")
 861   (beginning-of-line)
 862   (dotimes (i (if (< p 0) (- p) p))
 863     (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
 864         (progn
 865           (delete-char 1)
 866           (insert (if unflag " " "D"))))
 867     (forward-line (if (< p 0) -1 1)))
 868   (if (eobp) nil (forward-char 36)))
 869
 870 (defun tar-unflag (p)
 871   "*In Tar mode, un-mark this sub-file if it is marked to be deleted.
 872 With a prefix argument, un-mark that many files forward."
 873   (interactive "p")
 874   (tar-flag-deleted p t))
 875
 876 (defun tar-unflag-backwards (p)
 877   "*In Tar mode, un-mark this sub-file if it is marked to be deleted.
 878 With a prefix argument, un-mark that many files backward."
 879   (interactive "p")
 880   (tar-flag-deleted (- p) t))
 881
 882
 883 ;; When this function is called, it is sure that the buffer is unibyte.
 884 (defun tar-expunge-internal ()
 885   "Expunge the tar-entry specified by the current line."
 886   (let* ((descriptor (tar-current-descriptor))
 887          (tokens (tar-desc-tokens descriptor))
 888          (line (tar-desc-data-start descriptor))
 889          (name (tar-header-name tokens))
 890          (size (tar-header-size tokens))
 891          (link-p (tar-header-link-type tokens))
 892          (start (tar-desc-data-start descriptor))
 893          (following-descs (cdr (memq descriptor tar-parse-info))))
 894     (if link-p (setq size 0)) ; size lies for hard-links.
 895     ;;
 896     ;; delete the current line...
 897     (beginning-of-line)
 898     (let ((line-start (point)))
 899       (end-of-line) (forward-char)
 900       (let ((line-len (- (point) line-start)))
 901         (delete-region line-start (point))
 902         ;;
 903         ;; decrement the header-pointer to be in sync...
 904         (setq tar-header-offset (- tar-header-offset line-len))))
 905     ;;
 906     ;; delete the data pointer...
 907     (setq tar-parse-info (delq descriptor tar-parse-info))
 908     ;;
 909     ;; delete the data from inside the file...
 910     (widen)
 911     (let* ((data-start (+ start tar-header-offset -513))
 912            (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
 913       (delete-region data-start data-end)
 914       ;;
 915       ;; and finally, decrement the start-pointers of all following
 916       ;; entries in the archive.  This is a pig when deleting a bunch
 917       ;; of files at once - we could optimize this to only do the
 918       ;; iteration over the files that remain, or only iterate up to
 919       ;; the next file to be deleted.
 920       (let ((data-length (- data-end data-start)))
 921         (dolist (desc following-descs)
 922           (tar-setf (tar-desc-data-start desc)
 923                     (- (tar-desc-data-start desc) data-length))))
 924       ))
 925   (narrow-to-region 1 tar-header-offset))
 926
 927
 928 (defun tar-expunge (&optional noconfirm)
 929   "*In Tar mode, delete all the archived files flagged for deletion.
 930 This does not modify the disk image; you must save the tar file itself
 931 for this to be permanent."
 932   (interactive)
 933   (if (or noconfirm
 934           (y-or-n-p "Expunge files marked for deletion? "))
 935       (let ((n 0)
 936             (multibyte enable-multibyte-characters))
 937         (set-buffer-multibyte nil)
 938         (save-excursion
 939           (goto-char (point-min))
 940           (while (not (eobp))
 941             (if (looking-at "D")
 942                 (progn (tar-expunge-internal)
 943                        (setq n (1+ n)))
 944                 (forward-line 1)))
 945           ;; after doing the deletions, add any padding that may be necessary.
 946           (tar-pad-to-blocksize)
 947           (narrow-to-region 1 tar-header-offset))
 948         (set-buffer-multibyte multibyte)
 949         (if (zerop n)
 950             (message "Nothing to expunge.")
 951             (message "%s files expunged.  Be sure to save this buffer." n)))))
 952
 953
 954 (defun tar-clear-modification-flags ()
 955   "Remove the stars at the beginning of each line."
 956   (interactive)
 957   (save-excursion
 958     (goto-char (point-min))
 959     (while (< (position-bytes (point)) tar-header-offset)
 960       (if (not (eq (following-char) ?\ ))
 961           (progn (delete-char 1) (insert " ")))
 962       (forward-line 1))))
 963
 964
 965 (defun tar-chown-entry (new-uid)
 966   "*Change the user-id associated with this entry in the tar file.
 967 If this tar file was written by GNU tar, then you will be able to edit
 968 the user id as a string; otherwise, you must edit it as a number.
 969 You can force editing as a number by calling this with a prefix arg.
 970 This does not modify the disk image; you must save the tar file itself
 971 for this to be permanent."
 972   (interactive (list
 973                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 974                    (if (or current-prefix-arg
 975                            (not (tar-header-magic tokens)))
 976                        (let (n)
 977                          (while (not (numberp (setq n (read-minibuffer
 978                                                         "New UID number: "
 979                                                         (format "%s" (tar-header-uid tokens)))))))
 980                          n)
 981                        (read-string "New UID string: " (tar-header-uname tokens))))))
 982   (cond ((stringp new-uid)
 983          (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
 984                    new-uid)
 985          (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
 986         (t
 987          (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
 988                    new-uid)
 989          (tar-alter-one-field tar-uid-offset
 990            (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
 991
 992
 993 (defun tar-chgrp-entry (new-gid)
 994   "*Change the group-id associated with this entry in the tar file.
 995 If this tar file was written by GNU tar, then you will be able to edit
 996 the group id as a string; otherwise, you must edit it as a number.
 997 You can force editing as a number by calling this with a prefix arg.
 998 This does not modify the disk image; you must save the tar file itself
 999 for this to be permanent."
1000   (interactive (list
1001                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
1002                    (if (or current-prefix-arg
1003                            (not (tar-header-magic tokens)))
1004                        (let (n)
1005                          (while (not (numberp (setq n (read-minibuffer
1006                                                         "New GID number: "
1007                                                         (format "%s" (tar-header-gid tokens)))))))
1008                          n)
1009                        (read-string "New GID string: " (tar-header-gname tokens))))))
1010   (cond ((stringp new-gid)
1011          (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
1012                    new-gid)
1013          (tar-alter-one-field tar-gname-offset
1014            (concat new-gid "\000")))
1015         (t
1016          (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
1017                    new-gid)
1018          (tar-alter-one-field tar-gid-offset
1019            (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
1020
1021 (defun tar-rename-entry (new-name)
1022   "*Change the name associated with this entry in the tar file.
1023 This does not modify the disk image; you must save the tar file itself
1024 for this to be permanent."
1025   (interactive
1026     (list (read-string "New name: "
1027             (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
1028   (if (string= "" new-name) (error "zero length name"))
1029   (if (> (length new-name) 98) (error "name too long"))
1030   (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
1031             new-name)
1032   (tar-alter-one-field 0
1033     (substring (concat new-name (make-string 99 0)) 0 99)))
1034
1035
1036 (defun tar-chmod-entry (new-mode)
1037   "*Change the protection bits associated with this entry in the tar file.
1038 This does not modify the disk image; you must save the tar file itself
1039 for this to be permanent."
1040   (interactive (list (tar-parse-octal-integer-safe
1041                        (read-string "New protection (octal): "))))
1042   (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
1043             new-mode)
1044   (tar-alter-one-field tar-mode-offset
1045     (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
1046
1047
1048 (defun tar-alter-one-field (data-position new-data-string)
1049   (let* ((descriptor (tar-current-descriptor))
1050          (tokens (tar-desc-tokens descriptor))
1051          (multibyte enable-multibyte-characters))
1052     (unwind-protect
1053         (save-excursion
1054           ;;
1055           ;; update the header-line.
1056           (beginning-of-line)
1057           (let ((p (point)))
1058             (forward-line 1)
1059             (delete-region p (point))
1060             (insert (tar-header-block-summarize tokens) "\n")
1061             (setq tar-header-offset (position-bytes (point-max))))
1062
1063           (widen)
1064           (set-buffer-multibyte nil)
1065           (let* ((start (+ (tar-desc-data-start descriptor) tar-header-offset -513)))
1066             ;;
1067             ;; delete the old field and insert a new one.
1068             (goto-char (+ start data-position))
1069             (delete-region (point) (+ (point) (length new-data-string))) ; <--
1070             (insert new-data-string) ; <--
1071             ;;
1072             ;; compute a new checksum and insert it.
1073             (let ((chk (tar-header-block-checksum
1074                         (buffer-substring start (+ start 512)))))
1075               (goto-char (+ start tar-chk-offset))
1076               (delete-region (point) (+ (point) 8))
1077               (insert (format "%6o" chk))
1078               (insert 0)
1079               (insert ? )
1080               (tar-setf (tar-header-checksum tokens) chk)
1081               ;;
1082               ;; ok, make sure we didn't botch it.
1083               (tar-header-block-check-checksum
1084                 (buffer-substring start (+ start 512))
1085                 chk (tar-header-name tokens))
1086               )))
1087       (narrow-to-region 1 tar-header-offset)
1088       (set-buffer-multibyte multibyte)
1089       (tar-next-line 0))))
1090
1091
1092 (defun tar-octal-time (timeval)
1093   ;; Format a timestamp as 11 octal digits.  Ghod, I hope this works...
1094   (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
1095     (format "%05o%01o%05o"
1096             (lsh hibits -2)
1097             (logior (lsh (logand 3 hibits) 1)
1098                     (if (> (logand lobits 32768) 0) 1 0))
1099             (logand 32767 lobits)
1100             )))
1101
1102 (defun tar-subfile-save-buffer ()
1103   "In tar subfile mode, save this buffer into its parent tar-file buffer.
1104 This doesn't write anything to disk; you must save the parent tar-file buffer
1105 to make your changes permanent."
1106   (interactive)
1107   (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
1108     (error "This buffer has no superior tar file buffer"))
1109   (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
1110     (error "This buffer doesn't have an index into its superior tar file!"))
1111   (save-excursion
1112   (let ((subfile (current-buffer))
1113         (subfile-multibyte enable-multibyte-characters)
1114         (coding buffer-file-coding-system)
1115         (descriptor tar-superior-descriptor)
1116         subfile-size)
1117     ;; We must make the current buffer unibyte temporarily to avoid
1118     ;; multibyte->unibyte conversion in `insert-buffer'.
1119     (set-buffer-multibyte nil)
1120     (setq subfile-size (buffer-size))
1121     (set-buffer tar-superior-buffer)
1122     (let* ((tokens (tar-desc-tokens descriptor))
1123            (start (tar-desc-data-start descriptor))
1124            (name (tar-header-name tokens))
1125            (size (tar-header-size tokens))
1126            (size-pad (ash (ash (+ size 511) -9) 9))
1127            (head (memq descriptor tar-parse-info))
1128            (following-descs (cdr head))
1129            (tar-buffer-multibyte enable-multibyte-characters))
1130       (if (not head)
1131         (error "Can't find this tar file entry in its parent tar file!"))
1132       (unwind-protect
1133        (save-excursion
1134         (widen)
1135         (set-buffer-multibyte nil)
1136         ;; delete the old data...
1137         (let* ((data-start (+ start tar-header-offset -1))
1138                (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
1139           (delete-region data-start data-end)
1140           ;; insert the new data...
1141           (goto-char data-start)
1142           (insert-buffer subfile)
1143           (setq subfile-size
1144                 (encode-coding-region
1145                  data-start (+ data-start subfile-size) coding))
1146           ;;
1147           ;; pad the new data out to a multiple of 512...
1148           (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
1149             (goto-char (+ data-start subfile-size))
1150             (insert (make-string (- subfile-size-pad subfile-size) 0))
1151             ;;
1152             ;; update the data pointer of this and all following files...
1153             (tar-setf (tar-header-size tokens) subfile-size)
1154             (let ((difference (- subfile-size-pad size-pad)))
1155               (dolist (desc following-descs)
1156                 (tar-setf (tar-desc-data-start desc)
1157                           (+ (tar-desc-data-start desc) difference))))
1158             ;;
1159             ;; Update the size field in the header block.
1160             (let ((header-start (- data-start 512)))
1161               (goto-char (+ header-start tar-size-offset))
1162               (delete-region (point) (+ (point) 12))
1163               (insert (format "%11o" subfile-size))
1164               (insert ? )
1165               ;;
1166               ;; Maybe update the datestamp.
1167               (if (not tar-update-datestamp)
1168                   nil
1169                 (goto-char (+ header-start tar-time-offset))
1170                 (delete-region (point) (+ (point) 12))
1171                 (insert (tar-octal-time (current-time)))
1172                 (insert ? ))
1173               ;;
1174               ;; compute a new checksum and insert it.
1175               (let ((chk (tar-header-block-checksum
1176                           (buffer-substring header-start data-start))))
1177                 (goto-char (+ header-start tar-chk-offset))
1178                 (delete-region (point) (+ (point) 8))
1179                 (insert (format "%6o" chk))
1180                 (insert 0)
1181                 (insert ? )
1182                 (tar-setf (tar-header-checksum tokens) chk)))
1183             ;;
1184             ;; alter the descriptor-line...
1185             ;;
1186             (let ((position (- (length tar-parse-info) (length head))))
1187               (goto-char (point-min))
1188               (next-line position)
1189               (beginning-of-line)
1190               (let ((p (point))
1191                     after
1192                     (m (set-marker (make-marker) tar-header-offset)))
1193                 (forward-line 1)
1194                 (setq after (point))
1195                 ;; Insert the new text after the old, before deleting,
1196                 ;; to preserve the window start.
1197                 (let ((line (tar-header-block-summarize tokens t)))
1198                   (if (multibyte-string-p line)
1199                       (insert-before-markers (string-as-unibyte line) "\n")
1200                     (insert-before-markers line "\n")))
1201                 (delete-region p after)
1202                 (setq tar-header-offset (marker-position m)))
1203               )))
1204         ;; after doing the insertion, add any final padding that may be necessary.
1205         (tar-pad-to-blocksize))
1206        (narrow-to-region 1 tar-header-offset)
1207        (set-buffer-multibyte tar-buffer-multibyte)))
1208     (set-buffer-modified-p t)   ; mark the tar file as modified
1209     (tar-next-line 0)
1210     (set-buffer subfile)
1211     ;; Restore the buffer multibyteness.
1212     (set-buffer-multibyte subfile-multibyte)
1213     (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1214     (message "Saved into tar-buffer `%s'.  Be sure to save that buffer!"
1215              (buffer-name tar-superior-buffer))
1216     ;; Prevent basic-save-buffer from changing our coding-system.
1217     (setq last-coding-system-used buffer-file-coding-system)
1218     ;; Prevent ordinary saving from happening.
1219     t)))
1220
1221
1222 ;; When this function is called, it is sure that the buffer is unibyte.
1223 (defun tar-pad-to-blocksize ()
1224   "If we are being anal about tar file blocksizes, fix up the current buffer.
1225 Leaves the region wide."
1226   (if (null tar-anal-blocksize)
1227       nil
1228     (widen)
1229     (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1230            (start (tar-desc-data-start last-desc))
1231            (tokens (tar-desc-tokens last-desc))
1232            (link-p (tar-header-link-type tokens))
1233            (size (if link-p 0 (tar-header-size tokens)))
1234            (data-end (+ start size))
1235            (bbytes (ash tar-anal-blocksize 9))
1236            (pad-to (+ bbytes (* bbytes (/ (1- data-end) bbytes))))
1237            (inhibit-read-only t) ; ##
1238            )
1239       ;; If the padding after the last data is too long, delete some;
1240       ;; else insert some until we are padded out to the right number of blocks.
1241       ;;
1242       (goto-char (+ (or tar-header-offset 0) data-end))
1243       (if (> (1+ (buffer-size)) (+ (or tar-header-offset 0) pad-to))
1244           (delete-region (+ (or tar-header-offset 0) pad-to) (1+ (buffer-size)))
1245           (insert (make-string (- (+ (or tar-header-offset 0) pad-to)
1246                                   (1+ (buffer-size)))
1247                                0)))
1248       )))
1249
1250
1251 ;; Used in write-file-hook to write tar-files out correctly.
1252 (defun tar-mode-write-file ()
1253   (unwind-protect
1254       (save-excursion
1255         (widen)
1256         ;; Doing this here confuses things - the region gets left too wide!
1257         ;; I suppose this is run in a context where changing the buffer is bad.
1258         ;; (tar-pad-to-blocksize)
1259         ;; tar-header-offset turns out to be null for files fetched with W3,
1260         ;; at least.
1261         (let ((coding-system-for-write 'no-conversion))
1262           (write-region (if tar-header-offset
1263                             (byte-to-position tar-header-offset)
1264                           (point-min))
1265                         (point-max)
1266                         buffer-file-name nil t))
1267         (tar-clear-modification-flags)
1268         (set-buffer-modified-p nil))
1269     (narrow-to-region 1 (byte-to-position tar-header-offset)))
1270   ;; Return t because we've written the file.
1271   t)
1272 \f
1273 (provide 'tar-mode)
1274
1275 ;;; tar-mode.el ends here