lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Morten Welinder <terra@diku.dk>
   6 ;; Keywords: archives msdog editing major-mode
   7 ;; Favourite-brand-of-beer: None, I hate beer.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  29 ;; to files whose name end in ".arc"
  30 ;;
  31 ;; This code does not decode any files internally, although it does
  32 ;; understand the directory level of the archives.  For this reason,
  33 ;; you should expect this code to need more fiddling than tar-mode.el
  34 ;; (although it at present has fewer bugs :-)  In particular, I have
  35 ;; not tested this under Ms-Dog myself.
  36 ;; -------------------------------------
  37 ;; INTERACTION: arc-mode.el should play together with
  38 ;;
  39 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  40 ;;                to you) are handled by doing all updates on a local
  41 ;;                copy.  When you make changes to a remote file the
  42 ;;                changes will first take effect when the archive buffer
  43 ;;                is saved.  You will be warned about this.
  44 ;;
  45 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  46 ;;                conversion.
  47 ;;
  48 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  49 ;; such this could be fixed (but wouldn't be useful) by declaring such
  50 ;; archives to be "remote".  For the members this is a general Emacs
  51 ;; problem that 19.29's file formats may fix.
  52 ;; -------------------------------------
  53 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  54 ;; structure for handling just about anything is in place.
  55 ;;
  56 ;;                        Arc     Lzh     Zip     Zoo
  57 ;;                        --------------------------------
  58 ;; View listing           Intern  Intern  Intern  Intern
  59 ;; Extract member         Y       Y       Y       Y
  60 ;; Save changed member    Y       Y       Y       Y
  61 ;; Add new member         N       N       N       N
  62 ;; Delete member          Y       Y       Y       Y
  63 ;; Rename member          Y       Y       N       N
  64 ;; Chmod                  -       Y       Y       -
  65 ;; Chown                  -       Y       -       -
  66 ;; Chgrp                  -       Y       -       -
  67 ;;
  68 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  69 ;; on the first released version of this package.
  70 ;;
  71 ;; This code is partly based on tar-mode.el from Emacs.
  72 ;; -------------------------------------
  73 ;; ARCHIVE STRUCTURES:
  74 ;; (This is mostly for myself.)
  75 ;;
  76 ;; ARC         A series of (header,file).  No interactions among members.
  77 ;;
  78 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  79 ;;             interaction among members.
  80 ;;
  81 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  82 ;;             which is a series of (cheader) followed by an end-of-
  83 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  84 ;;             links to c-d.  cheaders link to lheaders which are basically
  85 ;;             cut-down versions of the cheaders.
  86 ;;
  87 ;; ZOO         An archive header followed by a series of (header,file).
  88 ;;             Each member header points to the next.  The archive is
  89 ;;             terminated by a bogus header with a zero next link.
  90 ;; -------------------------------------
  91 ;; HOOKS: `foo' means one of the supported archive types.
  92 ;;
  93 ;; archive-mode-hook
  94 ;; archive-foo-mode-hook
  95 ;; archive-extract-hooks
  96
  97 ;;; Code:
  98
  99 ;; -------------------------------------------------------------------------
 100 ;; Section: Configuration.
 101
 102 (defgroup archive nil
 103   "Simple editing of archives."
 104   :group 'data)
 105
 106 (defgroup archive-arc nil
 107   "ARC-specific options to archive."
 108   :group 'archive)
 109
 110 (defgroup archive-lzh nil
 111   "LZH-specific options to archive."
 112   :group 'archive)
 113
 114 (defgroup archive-zip nil
 115   "ZIP-specific options to archive."
 116   :group 'archive)
 117
 118 (defgroup archive-zoo nil
 119   "ZOO-specific options to archive."
 120   :group 'archive)
 121
 122 (defcustom archive-tmpdir
 123   ;; make-temp-name is safe here because we use this name
 124   ;; to create a directory.
 125   (make-temp-name
 126    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 127                      temporary-file-directory))
 128   "*Directory for temporary files made by arc-mode.el"
 129   :type 'directory
 130   :group 'archive)
 131
 132 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 133   "*Regexp recognizing archive files names that are not local.
 134 A non-local file is one whose file name is not proper outside Emacs.
 135 A local copy of the archive will be used when updating."
 136   :type 'regexp
 137   :group 'archive)
 138
 139 (defcustom archive-extract-hooks nil
 140   "*Hooks to run when an archive member has been extracted."
 141   :type 'hook
 142   :group 'archive)
 143 ;; ------------------------------
 144 ;; Arc archive configuration
 145
 146 ;; We always go via a local file since there seems to be no reliable way
 147 ;; to extract to stdout without junk getting added.
 148 (defcustom archive-arc-extract
 149   '("arc" "x")
 150   "*Program and its options to run in order to extract an arc file member.
 151 Extraction should happen to the current directory.  Archive and member
 152 name will be added."
 153   :type '(list (string :tag "Program")
 154                 (repeat :tag "Options"
 155                         :inline t
 156                         (string :format "%v")))
 157   :group 'archive-arc)
 158
 159 (defcustom archive-arc-expunge
 160   '("arc" "d")
 161   "*Program and its options to run in order to delete arc file members.
 162 Archive and member names will be added."
 163   :type '(list (string :tag "Program")
 164                 (repeat :tag "Options"
 165                         :inline t
 166                         (string :format "%v")))
 167   :group 'archive-arc)
 168
 169 (defcustom archive-arc-write-file-member
 170   '("arc" "u")
 171   "*Program and its options to run in order to update an arc file member.
 172 Archive and member name will be added."
 173   :type '(list (string :tag "Program")
 174                 (repeat :tag "Options"
 175                         :inline t
 176                         (string :format "%v")))
 177   :group 'archive-arc)
 178 ;; ------------------------------
 179 ;; Lzh archive configuration
 180
 181 (defcustom archive-lzh-extract
 182   '("lha" "pq")
 183   "*Program and its options to run in order to extract an lzh file member.
 184 Extraction should happen to standard output.  Archive and member name will
 185 be added."
 186   :type '(list (string :tag "Program")
 187                 (repeat :tag "Options"
 188                         :inline t
 189                         (string :format "%v")))
 190   :group 'archive-lzh)
 191
 192 (defcustom archive-lzh-expunge
 193   '("lha" "d")
 194   "*Program and its options to run in order to delete lzh file members.
 195 Archive and member names will be added."
 196   :type '(list (string :tag "Program")
 197                 (repeat :tag "Options"
 198                         :inline t
 199                         (string :format "%v")))
 200   :group 'archive-lzh)
 201
 202 (defcustom archive-lzh-write-file-member
 203   '("lha" "a")
 204   "*Program and its options to run in order to update an lzh file member.
 205 Archive and member name will be added."
 206   :type '(list (string :tag "Program")
 207                 (repeat :tag "Options"
 208                         :inline t
 209                         (string :format "%v")))
 210   :group 'archive-lzh)
 211 ;; ------------------------------
 212 ;; Zip archive configuration
 213
 214 (defcustom archive-zip-extract
 215   (if (locate-file "unzip" nil 'file-executable-p)
 216       '("unzip" "-qq" "-c")
 217     (if (locate-file "pkunzip" nil 'file-executable-p)
 218         '("pkunzip" "-e" "-o-")
 219       '("unzip" "-qq" "-c")))
 220   "*Program and its options to run in order to extract a zip file member.
 221 Extraction should happen to standard output.  Archive and member name will
 222 be added.  If `archive-zip-use-pkzip' is non-nil then this program is
 223 expected to extract to a file junking the directory part of the name."
 224   :type '(list (string :tag "Program")
 225                 (repeat :tag "Options"
 226                         :inline t
 227                         (string :format "%v")))
 228   :group 'archive-zip)
 229
 230 ;; For several reasons the latter behaviour is not desirable in general.
 231 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 232 ;; existent.  (3) It tends to do funny things with other systems' file
 233 ;; names.
 234
 235 (defcustom archive-zip-expunge
 236   (if (locate-file "zip" nil 'file-executable-p)
 237       '("zip" "-d" "-q")
 238     (if (locate-file "pkzip" nil 'file-executable-p)
 239          '("pkzip" "-d")
 240       '("zip" "-d" "-q")))
 241   "*Program and its options to run in order to delete zip file members.
 242 Archive and member names will be added."
 243   :type '(list (string :tag "Program")
 244                 (repeat :tag "Options"
 245                         :inline t
 246                         (string :format "%v")))
 247   :group 'archive-zip)
 248
 249 (defcustom archive-zip-update
 250   (if (locate-file "zip" nil 'file-executable-p)
 251       '("zip" "-q")
 252     (if (locate-file "pkzip" nil 'file-executable-p)
 253          '("pkzip" "-u" "-P")
 254       '("zip" "-q")))
 255   "*Program and its options to run in order to update a zip file member.
 256 Options should ensure that specified directory will be put into the zip
 257 file.  Archive and member name will be added."
 258   :type '(list (string :tag "Program")
 259                 (repeat :tag "Options"
 260                         :inline t
 261                         (string :format "%v")))
 262   :group 'archive-zip)
 263
 264 (defcustom archive-zip-update-case
 265   (if (locate-file "zip" nil 'file-executable-p)
 266       '("zip" "-q" "-k")
 267     (if (locate-file "pkzip" nil 'file-executable-p)
 268          '("pkzip" "-u" "-P")
 269       '("zip" "-q" "-k")))
 270   "*Program and its options to run in order to update a case fiddled zip member.
 271 Options should ensure that specified directory will be put into the zip file.
 272 Archive and member name will be added."
 273   :type '(list (string :tag "Program")
 274                 (repeat :tag "Options"
 275                         :inline t
 276                         (string :format "%v")))
 277   :group 'archive-zip)
 278
 279 (defcustom archive-zip-case-fiddle t
 280   "*If non-nil then zip file members may be down-cased.
 281 This case fiddling will only happen for members created by a system
 282 that uses caseless file names."
 283   :type 'boolean
 284   :group 'archive-zip)
 285 ;; ------------------------------
 286 ;; Zoo archive configuration
 287
 288 (defcustom archive-zoo-extract
 289   '("zoo" "xpq")
 290   "*Program and its options to run in order to extract a zoo file member.
 291 Extraction should happen to standard output.  Archive and member name will
 292 be added."
 293   :type '(list (string :tag "Program")
 294                 (repeat :tag "Options"
 295                         :inline t
 296                         (string :format "%v")))
 297   :group 'archive-zoo)
 298
 299 (defcustom archive-zoo-expunge
 300   '("zoo" "DqPP")
 301   "*Program and its options to run in order to delete zoo file members.
 302 Archive and member names will be added."
 303   :type '(list (string :tag "Program")
 304                 (repeat :tag "Options"
 305                         :inline t
 306                         (string :format "%v")))
 307   :group 'archive-zoo)
 308
 309 (defcustom archive-zoo-write-file-member
 310   '("zoo" "a")
 311   "*Program and its options to run in order to update a zoo file member.
 312 Archive and member name will be added."
 313   :type '(list (string :tag "Program")
 314                 (repeat :tag "Options"
 315                         :inline t
 316                         (string :format "%v")))
 317   :group 'archive-zoo)
 318 ;; -------------------------------------------------------------------------
 319 ;; Section: Variables
 320
 321 (defvar archive-subtype nil "*Symbol describing archive type.")
 322 (defvar archive-file-list-start nil "*Position of first contents line.")
 323 (defvar archive-file-list-end nil "*Position just after last contents line.")
 324 (defvar archive-proper-file-start nil "*Position of real archive's start.")
 325 (defvar archive-read-only nil "*Non-nil if the archive is read-only on disk.")
 326 (defvar archive-local-name nil "*Name of local copy of remote archive.")
 327 (defvar archive-mode-map nil "*Local keymap for archive mode listings.")
 328 (defvar archive-file-name-indent nil "*Column where file names start.")
 329
 330 (defvar archive-remote nil "*Non-nil if the archive is outside file system.")
 331 (make-variable-buffer-local 'archive-remote)
 332 (put 'archive-remote 'permanent-local t)
 333
 334 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 335 (make-variable-buffer-local 'archive-member-coding-system)
 336
 337 (defvar archive-alternate-display nil
 338   "*Non-nil when alternate information is shown.")
 339 (make-variable-buffer-local 'archive-alternate-display)
 340 (put 'archive-alternate-display 'permanent-local t)
 341
 342 (defvar archive-superior-buffer nil "*In archive members, points to archive.")
 343 (put 'archive-superior-buffer 'permanent-local t)
 344
 345 (defvar archive-subfile-mode nil "*Non-nil in archive member buffers.")
 346 (make-variable-buffer-local 'archive-subfile-mode)
 347 (put 'archive-subfile-mode 'permanent-local t)
 348
 349 (defvar archive-files nil
 350   "Vector of file descriptors.
 351 Each descriptor is a vector of the form
 352  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 353 (make-variable-buffer-local 'archive-files)
 354
 355 (defvar archive-lemacs
 356   (string-match "\\(Lucid\\|Xemacs\\)" emacs-version)
 357   "*Non-nil when running under under Lucid Emacs or Xemacs.")
 358 ;; -------------------------------------------------------------------------
 359 ;; Section: Support functions.
 360
 361 (defsubst archive-name (suffix)
 362   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 363
 364 (defun archive-l-e (str &optional len)
 365   "Convert little endian string/vector to integer.
 366 Alternatively, first argument may be a buffer position in the current buffer
 367 in which case a second argument, length, should be supplied."
 368   (if (stringp str)
 369       (setq len (length str))
 370     (setq str (buffer-substring str (+ str len))))
 371   (let ((result 0)
 372         (i 0))
 373     (while (< i len)
 374       (setq i (1+ i)
 375             result (+ (ash result 8) (aref str (- len i)))))
 376     result))
 377
 378 (defun archive-int-to-mode (mode)
 379   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 380   ;; FIXME: merge with tar-grind-file-mode.
 381   (string
 382     (if (zerop (logand  8192 mode))
 383         (if (zerop (logand 16384 mode)) ?- ?d)
 384       ?c) ; completeness
 385     (if (zerop (logand   256 mode)) ?- ?r)
 386     (if (zerop (logand   128 mode)) ?- ?w)
 387     (if (zerop (logand    64 mode))
 388         (if (zerop (logand  1024 mode)) ?- ?S)
 389       (if (zerop (logand  1024 mode)) ?x ?s))
 390     (if (zerop (logand    32 mode)) ?- ?r)
 391     (if (zerop (logand    16 mode)) ?- ?w)
 392     (if (zerop (logand     8 mode))
 393         (if (zerop (logand  2048 mode)) ?- ?S)
 394       (if (zerop (logand  2048 mode)) ?x ?s))
 395     (if (zerop (logand     4 mode)) ?- ?r)
 396     (if (zerop (logand     2 mode)) ?- ?w)
 397     (if (zerop (logand     1 mode)) ?- ?x)))
 398
 399 (defun archive-calc-mode (oldmode newmode &optional error)
 400   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 401 NEWMODE may be an octal number including a leading zero in which case it
 402 will become the new mode.\n
 403 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 404 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 405 If optional third argument ERROR is non-nil an error will be signaled if
 406 the mode is invalid.  If ERROR is nil then nil will be returned."
 407   (cond ((string-match "^0[0-7]*$" newmode)
 408          (let ((result 0)
 409                (len (length newmode))
 410                (i 1))
 411            (while (< i len)
 412              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 413                    i (1+ i)))
 414            (logior (logand oldmode 65024) result)))
 415         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 416          (let ((who 0)
 417                (result oldmode)
 418                (op (aref newmode (match-beginning 2)))
 419                (bits 0)
 420                (i (match-beginning 3)))
 421            (while (< i (match-end 3))
 422              (let ((rwx (aref newmode i)))
 423                (setq bits (logior bits (cond ((= rwx ?r)  292)
 424                                              ((= rwx ?w)  146)
 425                                              ((= rwx ?x)   73)
 426                                              ((= rwx ?s) 3072)
 427                                              ((= rwx ?t)  512)))
 428                      i (1+ i))))
 429            (while (< who (match-end 1))
 430              (let* ((whoc (aref newmode who))
 431                     (whomask (cond ((= whoc ?a) 4095)
 432                                    ((= whoc ?u) 1472)
 433                                    ((= whoc ?g) 2104)
 434                                    ((= whoc ?o)    7))))
 435                (if (= op ?=)
 436                    (setq result (logand result (lognot whomask))))
 437                (if (= op ?-)
 438                    (setq result (logand result (lognot (logand whomask bits))))
 439                  (setq result (logior result (logand whomask bits)))))
 440              (setq who (1+ who)))
 441            result))
 442         (t
 443          (if error
 444              (error "Invalid mode specification: %s" newmode)))))
 445
 446 (defun archive-dosdate (date)
 447   "Stringify dos packed DATE record."
 448   (let ((year (+ 1980 (logand (ash date -9) 127)))
 449         (month (logand (ash date -5) 15))
 450         (day (logand date 31)))
 451     (if (or (> month 12) (< month 1))
 452         ""
 453       (format "%2d-%s-%d"
 454               day
 455               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 456                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 457               year))))
 458
 459 (defun archive-dostime (time)
 460   "Stringify dos packed TIME record."
 461   (let ((hour (logand (ash time -11) 31))
 462         (minute (logand (ash time -5) 63))
 463         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 464     (format "%02d:%02d:%02d" hour minute second)))
 465
 466 ;;(defun archive-unixdate (low high)
 467 ;;  "Stringify unix (LOW HIGH) date."
 468 ;;  (let ((str (current-time-string (cons high low))))
 469 ;;    (format "%s-%s-%s"
 470 ;;          (substring str 8 9)
 471 ;;          (substring str 4 7)
 472 ;;          (substring str 20 24))))
 473
 474 ;;(defun archive-unixtime (low high)
 475 ;;  "Stringify unix (LOW HIGH) time."
 476 ;;  (let ((str (current-time-string (cons high low))))
 477 ;;    (substring str 11 19)))
 478
 479 (defun archive-get-lineno ()
 480   (if (>= (point) archive-file-list-start)
 481       (count-lines archive-file-list-start
 482                    (save-excursion (beginning-of-line) (point)))
 483     0))
 484
 485 (defun archive-get-descr (&optional noerror)
 486   "Return the descriptor vector for file at point.
 487 Does not signal an error if optional second argument NOERROR is non-nil."
 488   (let ((no (archive-get-lineno)))
 489     (if (and (>= (point) archive-file-list-start)
 490              (< no (length archive-files)))
 491         (let ((item (aref archive-files no)))
 492           (if (vectorp item)
 493               item
 494             (if (not noerror)
 495                 (error "Entry is not a regular member of the archive"))))
 496       (if (not noerror)
 497           (error "Line does not describe a member of the archive")))))
 498 ;; -------------------------------------------------------------------------
 499 ;; Section: the mode definition
 500
 501 ;;;###autoload
 502 (defun archive-mode (&optional force)
 503   "Major mode for viewing an archive file in a dired-like way.
 504 You can move around using the usual cursor motion commands.
 505 Letters no longer insert themselves.
 506 Type `e' to pull a file out of the archive and into its own buffer;
 507 or click mouse-2 on the file's line in the archive mode buffer.
 508
 509 If you edit a sub-file of this archive (as with the `e' command) and
 510 save it, the contents of that buffer will be saved back into the
 511 archive.
 512
 513 \\{archive-mode-map}"
 514   ;; This is not interactive because you shouldn't be turning this
 515   ;; mode on and off.  You can corrupt things that way.
 516   (if (zerop (buffer-size))
 517       ;; At present we cannot create archives from scratch
 518       (funcall default-major-mode)
 519     (if (and (not force) archive-files) nil
 520       (let* ((type (archive-find-type))
 521              (typename (capitalize (symbol-name type))))
 522         (kill-all-local-variables)
 523         (make-local-variable 'archive-subtype)
 524         (setq archive-subtype type)
 525
 526         ;; Buffer contains treated image of file before the file contents
 527         (make-local-variable 'revert-buffer-function)
 528         (setq revert-buffer-function 'archive-mode-revert)
 529         (auto-save-mode 0)
 530
 531         ;; Remote archives are not written by a hook.
 532         (if archive-remote nil
 533           (make-local-variable 'write-contents-hooks)
 534           (add-hook 'write-contents-hooks 'archive-write-file))
 535
 536         (make-local-variable 'require-final-newline)
 537         (setq require-final-newline nil)
 538         (make-local-variable 'local-enable-local-variables)
 539         (setq local-enable-local-variables nil)
 540
 541         ;; Prevent loss of data when saving the file.
 542         (make-local-variable 'file-precious-flag)
 543         (setq file-precious-flag t)
 544
 545         (make-local-variable 'archive-read-only)
 546         ;; Archives which are inside other archives and whose
 547         ;; names are invalid for this OS, can't be written.
 548         (setq archive-read-only
 549               (or (not (file-writable-p (buffer-file-name)))
 550                   (and archive-subfile-mode
 551                        (string-match file-name-invalid-regexp
 552                                      (aref archive-subfile-mode 0)))))
 553
 554         ;; Should we use a local copy when accessing from outside Emacs?
 555         (make-local-variable 'archive-local-name)
 556
 557         ;; An archive can contain another archive whose name is invalid
 558         ;; on local filesystem.  Treat such archives as remote.
 559         (or archive-remote
 560             (setq archive-remote
 561                   (or (string-match archive-remote-regexp (buffer-file-name))
 562                       (string-match file-name-invalid-regexp
 563                                     (buffer-file-name)))))
 564
 565         (setq major-mode 'archive-mode)
 566         (setq mode-name (concat typename "-Archive"))
 567         ;; Run archive-foo-mode-hook and archive-mode-hook
 568         (run-hooks (archive-name "mode-hook") 'archive-mode-hook)
 569         (use-local-map archive-mode-map))
 570
 571       (make-local-variable 'archive-proper-file-start)
 572       (make-local-variable 'archive-file-list-start)
 573       (make-local-variable 'archive-file-list-end)
 574       (make-local-variable 'archive-file-name-indent)
 575       (archive-summarize nil)
 576       (setq buffer-read-only t))))
 577
 578 ;; Archive mode is suitable only for specially formatted data.
 579 (put 'archive-mode 'mode-class 'special)
 580 ;; -------------------------------------------------------------------------
 581 ;; Section: Key maps
 582
 583 (if archive-mode-map nil
 584   (setq archive-mode-map (make-keymap))
 585   (suppress-keymap archive-mode-map)
 586   (define-key archive-mode-map " " 'archive-next-line)
 587   (define-key archive-mode-map "a" 'archive-alternate-display)
 588   ;;(define-key archive-mode-map "c" 'archive-copy)
 589   (define-key archive-mode-map "d" 'archive-flag-deleted)
 590   (define-key archive-mode-map "\C-d" 'archive-flag-deleted)
 591   (define-key archive-mode-map "e" 'archive-extract)
 592   (define-key archive-mode-map "f" 'archive-extract)
 593   (define-key archive-mode-map "\C-m" 'archive-extract)
 594   (define-key archive-mode-map "g" 'revert-buffer)
 595   (define-key archive-mode-map "h" 'describe-mode)
 596   (define-key archive-mode-map "m" 'archive-mark)
 597   (define-key archive-mode-map "n" 'archive-next-line)
 598   (define-key archive-mode-map "\C-n" 'archive-next-line)
 599   (define-key archive-mode-map [down] 'archive-next-line)
 600   (define-key archive-mode-map "o" 'archive-extract-other-window)
 601   (define-key archive-mode-map "p" 'archive-previous-line)
 602   (define-key archive-mode-map "q" 'quit-window)
 603   (define-key archive-mode-map "\C-p" 'archive-previous-line)
 604   (define-key archive-mode-map [up] 'archive-previous-line)
 605   (define-key archive-mode-map "r" 'archive-rename-entry)
 606   (define-key archive-mode-map "u" 'archive-unflag)
 607   (define-key archive-mode-map "\M-\C-?" 'archive-unmark-all-files)
 608   (define-key archive-mode-map "v" 'archive-view)
 609   (define-key archive-mode-map "x" 'archive-expunge)
 610   (define-key archive-mode-map "\177" 'archive-unflag-backwards)
 611   (define-key archive-mode-map "E" 'archive-extract-other-window)
 612   (define-key archive-mode-map "M" 'archive-chmod-entry)
 613   (define-key archive-mode-map "G" 'archive-chgrp-entry)
 614   (define-key archive-mode-map "O" 'archive-chown-entry)
 615
 616   (if archive-lemacs
 617       (progn
 618         ;; Not a nice "solution" but it'll have to do
 619         (define-key archive-mode-map "\C-xu" 'archive-undo)
 620         (define-key archive-mode-map "\C-_" 'archive-undo))
 621     (substitute-key-definition 'undo 'archive-undo
 622                                archive-mode-map global-map))
 623
 624   (define-key archive-mode-map
 625     (if archive-lemacs 'button2 [mouse-2]) 'archive-mouse-extract)
 626
 627   (if archive-lemacs
 628       ()                                ; out of luck
 629
 630     (define-key archive-mode-map [menu-bar immediate]
 631       (cons "Immediate" (make-sparse-keymap "Immediate")))
 632     (define-key archive-mode-map [menu-bar immediate alternate]
 633       '(menu-item "Alternate Display" archive-alternate-display
 634                   :enable (boundp (archive-name "alternate-display"))
 635                   :help "Toggle alternate file info display"))
 636     (define-key archive-mode-map [menu-bar immediate view]
 637       '(menu-item "View This File" archive-view
 638                   :help "Display file at cursor in View Mode"))
 639     (define-key archive-mode-map [menu-bar immediate display]
 640       '(menu-item "Display in Other Window" archive-display-other-window
 641                   :help "Display file at cursor in another window"))
 642     (define-key archive-mode-map [menu-bar immediate find-file-other-window]
 643       '(menu-item "Find in Other Window" archive-extract-other-window
 644                   :help "Edit file at cursor in another window"))
 645     (define-key archive-mode-map [menu-bar immediate find-file]
 646       '(menu-item "Find This File" archive-extract
 647                   :help "Extract file at cursor and edit it"))
 648
 649     (define-key archive-mode-map [menu-bar mark]
 650       (cons "Mark" (make-sparse-keymap "Mark")))
 651     (define-key archive-mode-map [menu-bar mark unmark-all]
 652       '(menu-item "Unmark All" archive-unmark-all-files
 653                   :help "Unmark all marked files"))
 654     (define-key archive-mode-map [menu-bar mark deletion]
 655       '(menu-item "Flag" archive-flag-deleted
 656                   :help "Flag file at cursor for deletion"))
 657     (define-key archive-mode-map [menu-bar mark unmark]
 658       '(menu-item "Unflag" archive-unflag
 659                   :help "Unmark file at cursor"))
 660     (define-key archive-mode-map [menu-bar mark mark]
 661       '(menu-item "Mark" archive-mark
 662                   :help "Mark file at cursor"))
 663
 664     (define-key archive-mode-map [menu-bar operate]
 665       (cons "Operate" (make-sparse-keymap "Operate")))
 666     (define-key archive-mode-map [menu-bar operate chown]
 667       '(menu-item "Change Owner..." archive-chown-entry
 668                   :enable (fboundp (archive-name "chown-entry"))
 669                   :help "Change owner of marked files"))
 670     (define-key archive-mode-map [menu-bar operate chgrp]
 671       '(menu-item "Change Group..." archive-chgrp-entry
 672                   :enable (fboundp (archive-name "chgrp-entry"))
 673                   :help "Change group ownership of marked files"))
 674     (define-key archive-mode-map [menu-bar operate chmod]
 675       '(menu-item "Change Mode..." archive-chmod-entry
 676                   :enable (fboundp (archive-name "chmod-entry"))
 677                   :help "Change mode (permissions) of marked files"))
 678     (define-key archive-mode-map [menu-bar operate rename]
 679       '(menu-item "Rename to..." archive-rename-entry
 680                   :enable (fboundp (archive-name "rename-entry"))
 681                   :help "Rename marked files"))
 682     ;;(define-key archive-mode-map [menu-bar operate copy]
 683     ;;  '(menu-item "Copy to..." archive-copy))
 684     (define-key archive-mode-map [menu-bar operate expunge]
 685       '(menu-item "Expunge Marked Files" archive-expunge
 686                   :help "Delete all flagged files from archive"))
 687   ))
 688
 689 (let* ((item1 '(archive-subfile-mode " Archive"))
 690        (items (list item1)))
 691   (or (member item1 minor-mode-alist)
 692       (setq minor-mode-alist (append items minor-mode-alist))))
 693 ;; -------------------------------------------------------------------------
 694 (defun archive-find-type ()
 695   (widen)
 696   (goto-char (point-min))
 697   ;; The funny [] here make it unlikely that the .elc file will be treated
 698   ;; as an archive by other software.
 699   (let (case-fold-search)
 700     (cond ((looking-at "[P]K\003\004") 'zip)
 701           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 702           ((looking-at "....................[\334]\247\304\375") 'zoo)
 703           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 704                 (string-match "\\.[aA][rR][cC]$"
 705                               (or buffer-file-name (buffer-name))))
 706            'arc)
 707           (t (error "Buffer format not recognized")))))
 708 ;; -------------------------------------------------------------------------
 709 (defun archive-summarize (&optional shut-up)
 710   "Parse the contents of the archive file in the current buffer.
 711 Place a dired-like listing on the front;
 712 then narrow to it, so that only that listing
 713 is visible (and the real data of the buffer is hidden).
 714 Optional argument SHUT-UP, if non-nil, means don't print messages
 715 when parsing the archive."
 716   (widen)
 717   (set-buffer-multibyte nil)
 718   (let (buffer-read-only)
 719     (or shut-up
 720         (message "Parsing archive file..."))
 721     (buffer-disable-undo (current-buffer))
 722     (setq archive-files (funcall (archive-name "summarize")))
 723     (or shut-up
 724         (message "Parsing archive file...done."))
 725     (setq archive-proper-file-start (point-marker))
 726     (narrow-to-region (point-min) (point))
 727     (set-buffer-modified-p nil)
 728     (buffer-enable-undo))
 729   (goto-char archive-file-list-start)
 730   (archive-next-line 0))
 731
 732 (defun archive-resummarize ()
 733   "Recreate the contents listing of an archive."
 734   (let ((modified (buffer-modified-p))
 735         (no (archive-get-lineno))
 736         buffer-read-only)
 737     (widen)
 738     (delete-region (point-min) archive-proper-file-start)
 739     (archive-summarize t)
 740     (set-buffer-modified-p modified)
 741     (goto-char archive-file-list-start)
 742     (archive-next-line no)))
 743
 744 (defun archive-summarize-files (files)
 745   "Insert a description of a list of files annotated with proper mouse face."
 746   (setq archive-file-list-start (point-marker))
 747   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 748   ;; We don't want to do an insert for each element since that takes too
 749   ;; long when the archive -- which has to be moved in memory -- is large.
 750   (insert
 751    (apply
 752     (function concat)
 753     (mapcar
 754      (function
 755       (lambda (fil)
 756         ;; Using `concat' here copies the text also, so we can add
 757         ;; properties without problems.
 758         (let ((text (concat (aref fil 0) "\n")))
 759           (if archive-lemacs
 760               ()                        ; out of luck
 761             (add-text-properties
 762              (aref fil 1) (aref fil 2)
 763              '(mouse-face highlight
 764                help-echo "mouse-2: extract this file into a buffer")
 765              text))
 766           text)))
 767      files)))
 768   (setq archive-file-list-end (point-marker)))
 769
 770 (defun archive-alternate-display ()
 771   "Toggle alternative display.
 772 To avoid very long lines some archive mode don't show all information.
 773 This function changes the set of information shown for each files."
 774   (interactive)
 775   (setq archive-alternate-display (not archive-alternate-display))
 776   (archive-resummarize))
 777 ;; -------------------------------------------------------------------------
 778 ;; Section: Local archive copy handling
 779
 780 (defun archive-unique-fname (fname dir)
 781   "Make sure a file FNAME can be created uniquely in directory DIR.
 782
 783 If FNAME can be uniquely created in DIR, it is returned unaltered.
 784 If FNAME is something our underlying filesystem can't grok, or if another
 785 file by that name already exists in DIR, a unique new name is generated
 786 using `make-temp-file', and the generated name is returned."
 787   (let ((fullname (expand-file-name fname dir))
 788         (alien (string-match file-name-invalid-regexp fname)))
 789     (if (or alien (file-exists-p fullname))
 790         (make-temp-file
 791          (expand-file-name
 792           (if (and (fboundp 'msdos-long-file-names)
 793                    (not (msdos-long-file-names)))
 794               "am"
 795             "arc-mode.")
 796           dir))
 797       fullname)))
 798
 799 (defun archive-maybe-copy (archive)
 800   (let ((coding-system-for-write 'no-conversion))
 801     (if archive-remote
 802         (let ((start (point-max))
 803               ;; Sometimes ARCHIVE is invalid while its actual name, as
 804               ;; recorded in its parent archive, is not.  For example, an
 805               ;; archive bar.zip inside another archive foo.zip gets a name
 806               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 807               ;; So use the actual name if available.
 808               (archive-name
 809                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 810                    archive)))
 811           (make-directory archive-tmpdir t)
 812           (setq archive-local-name
 813                 (archive-unique-fname archive-name archive-tmpdir))
 814           (save-restriction
 815             (widen)
 816             (write-region start (point-max) archive-local-name nil 'nomessage))
 817           archive-local-name)
 818       (if (buffer-modified-p) (save-buffer))
 819       archive)))
 820
 821 (defun archive-maybe-update (unchanged)
 822   (if archive-remote
 823       (let ((name archive-local-name)
 824             (modified (buffer-modified-p))
 825             (coding-system-for-read 'no-conversion)
 826             (lno (archive-get-lineno))
 827             buffer-read-only)
 828         (if unchanged nil
 829           (setq archive-files nil)
 830           (erase-buffer)
 831           (insert-file-contents name)
 832           (archive-mode t)
 833           (goto-char archive-file-list-start)
 834           (archive-next-line lno))
 835         (archive-delete-local name)
 836         (if (not unchanged)
 837             (message
 838              "Buffer `%s' must be saved for changes to take effect"
 839              (buffer-name (current-buffer))))
 840         (set-buffer-modified-p (or modified (not unchanged))))))
 841
 842 (defun archive-delete-local (name)
 843   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 844   (let ((again t)
 845         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 846     (condition-case nil
 847         (delete-file name)
 848       (error nil))
 849     (while again
 850       (setq name (directory-file-name (file-name-directory name)))
 851       (condition-case nil
 852           (delete-directory name)
 853         (error nil))
 854       (if (string= name top) (setq again nil)))))
 855 ;; -------------------------------------------------------------------------
 856 ;; Section: Member extraction
 857
 858 (defun archive-file-name-handler (op &rest args)
 859   (or (eq op 'file-exists-p)
 860       (let ((file-name-handler-alist nil))
 861         (apply op args))))
 862
 863 (defun archive-set-buffer-as-visiting-file (filename)
 864   "Set the current buffer as if it were visiting FILENAME."
 865   (save-excursion
 866     (goto-char (point-min))
 867     (let ((coding
 868            (or coding-system-for-read
 869                (and set-auto-coding-function
 870                     (save-excursion
 871                       (funcall set-auto-coding-function
 872                                filename (- (point-max) (point-min)))))
 873                ;; dos-w32.el defines find-operation-coding-system for
 874                ;; DOS/Windows systems which preserves the coding-system
 875                ;; of existing files.  We want it to act here as if the
 876                ;; extracted file existed.
 877                (let ((file-name-handler-alist
 878                       '(("" . archive-file-name-handler))))
 879                  (car (find-operation-coding-system 'insert-file-contents
 880                                                     filename t))))))
 881       (if (and (not coding-system-for-read)
 882                (not enable-multibyte-characters))
 883           (setq coding
 884                 (coding-system-change-text-conversion coding 'raw-text)))
 885       (if (and coding
 886                (not (eq coding 'no-conversion)))
 887           (decode-coding-region (point-min) (point-max) coding)
 888         (setq last-coding-system-used coding))
 889       (set-buffer-modified-p nil)
 890       (kill-local-variable 'buffer-file-coding-system)
 891       (after-insert-file-set-buffer-file-coding-system (- (point-max)
 892                                                           (point-min))))))
 893
 894 (defun archive-mouse-extract (event)
 895   "Extract a file whose name you click on."
 896   (interactive "e")
 897   (mouse-set-point event)
 898   (switch-to-buffer
 899    (save-excursion
 900      (archive-extract)
 901      (current-buffer))))
 902
 903 (defun archive-extract (&optional other-window-p)
 904   "In archive mode, extract this entry of the archive into its own buffer."
 905   (interactive)
 906   (let* ((view-p (eq other-window-p 'view))
 907          (descr (archive-get-descr))
 908          (ename (aref descr 0))
 909          (iname (aref descr 1))
 910          (archive-buffer (current-buffer))
 911          (arcdir default-directory)
 912          (archive (buffer-file-name))
 913          (arcname (file-name-nondirectory archive))
 914          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 915          (extractor (archive-name "extract"))
 916          ;; Members with file names which aren't valid for the
 917          ;; underlying filesystem, are treated as read-only.
 918          (read-only-p (or archive-read-only
 919                           view-p
 920                           (string-match file-name-invalid-regexp ename)))
 921          (buffer (get-buffer bufname))
 922          (just-created nil))
 923       (if buffer
 924           nil
 925         (setq archive (archive-maybe-copy archive))
 926         (setq buffer (get-buffer-create bufname))
 927         (setq just-created t)
 928         (save-excursion
 929           (set-buffer buffer)
 930           (setq buffer-file-name
 931                 (expand-file-name (concat arcname ":" iname)))
 932           (setq buffer-file-truename
 933                 (abbreviate-file-name buffer-file-name))
 934           ;; Set the default-directory to the dir of the superior buffer.
 935           (setq default-directory arcdir)
 936           (make-local-variable 'archive-superior-buffer)
 937           (setq archive-superior-buffer archive-buffer)
 938           (make-local-variable 'local-write-file-hooks)
 939           (add-hook 'local-write-file-hooks 'archive-write-file-member)
 940           (setq archive-subfile-mode descr)
 941           (if (and
 942                (null
 943                 (let (;; We may have to encode file name arguement for
 944                       ;; external programs.
 945                       (coding-system-for-write
 946                        (and enable-multibyte-characters
 947                             file-name-coding-system))
 948                       ;; We read an archive member by no-conversion at
 949                       ;; first, then decode appropriately by calling
 950                       ;; archive-set-buffer-as-visiting-file later.
 951                       (coding-system-for-read 'no-conversion))
 952                   (condition-case err
 953                       (if (fboundp extractor)
 954                           (funcall extractor archive ename)
 955                         (archive-*-extract archive ename
 956                                            (symbol-value extractor)))
 957                     (error
 958                      (ding (message "%s" (error-message-string err)))
 959                      nil))))
 960                just-created)
 961               (progn
 962                 (set-buffer-modified-p nil)
 963                 (kill-buffer buffer))
 964             (archive-set-buffer-as-visiting-file ename)
 965             (goto-char (point-min))
 966             (rename-buffer bufname)
 967             (setq buffer-read-only read-only-p)
 968             (setq buffer-undo-list nil)
 969             (set-buffer-modified-p nil)
 970             (setq buffer-saved-size (buffer-size))
 971             (normal-mode)
 972             ;; Just in case an archive occurs inside another archive.
 973             (if (eq major-mode 'archive-mode)
 974                 (progn
 975                   (setq archive-remote t)
 976                   (if read-only-p (setq archive-read-only t))
 977                   ;; We will write out the archive ourselves if it is
 978                   ;; part of another archive.
 979                   (remove-hook 'write-contents-hooks 'archive-write-file t)))
 980             (run-hooks 'archive-extract-hooks)
 981             (if archive-read-only
 982                 (message "Note: altering this archive is not implemented."))))
 983         (archive-maybe-update t))
 984       (or (not (buffer-name buffer))
 985           (progn
 986             (if view-p
 987                 (view-buffer buffer (and just-created 'kill-buffer))
 988               (if (eq other-window-p 'display)
 989                   (display-buffer buffer)
 990                 (if other-window-p
 991                     (switch-to-buffer-other-window buffer)
 992                   (switch-to-buffer buffer))))))))
 993
 994 (defun archive-*-extract (archive name command)
 995   (let* ((default-directory (file-name-as-directory archive-tmpdir))
 996          (tmpfile (expand-file-name (file-name-nondirectory name)
 997                                     default-directory))
 998          exit-status success)
 999     (make-directory (directory-file-name default-directory) t)
1000     (setq exit-status
1001           (apply 'call-process
1002                  (car command)
1003                  nil
1004                  nil
1005                  nil
1006                  (append (cdr command) (list archive name))))
1007     (cond ((and (numberp exit-status) (= exit-status 0))
1008            (if (not (file-exists-p tmpfile))
1009                (ding (message "`%s': no such file or directory" tmpfile))
1010              (insert-file-contents tmpfile)
1011              (setq success t)))
1012           ((numberp exit-status)
1013            (ding
1014             (message "`%s' exited with status %d" (car command) exit-status)))
1015           ((stringp exit-status)
1016            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1017           (t
1018            (ding (message "`%s' failed" (car command)))))
1019     (archive-delete-local tmpfile)
1020     success))
1021
1022 (defun archive-extract-by-stdout (archive name command)
1023   (apply 'call-process
1024          (car command)
1025          nil
1026          t
1027          nil
1028          (append (cdr command) (list archive name))))
1029
1030 (defun archive-extract-other-window ()
1031   "In archive mode, find this member in another window."
1032   (interactive)
1033   (archive-extract t))
1034
1035 (defun archive-display-other-window ()
1036   "In archive mode, display this member in another window."
1037   (interactive)
1038   (archive-extract 'display))
1039
1040 (defun archive-view ()
1041   "In archive mode, view the member on this line."
1042   (interactive)
1043   (archive-extract 'view))
1044
1045 (defun archive-add-new-member (arcbuf name)
1046   "Add current buffer to the archive in ARCBUF naming it NAME."
1047   (interactive
1048    (list (get-buffer
1049           (read-buffer "Buffer containing archive: "
1050                        ;; Find first archive buffer and suggest that
1051                        (let ((bufs (buffer-list)))
1052                          (while (and bufs (not (eq (save-excursion
1053                                                      (set-buffer (car bufs))
1054                                                      major-mode)
1055                                                    'archive-mode)))
1056                            (setq bufs (cdr bufs)))
1057                          (if bufs
1058                              (car bufs)
1059                            (error "There are no archive buffers")))
1060                        t))
1061          (read-string "File name in archive: "
1062                       (if buffer-file-name
1063                           (file-name-nondirectory buffer-file-name)
1064                         ""))))
1065   (save-excursion
1066     (set-buffer arcbuf)
1067     (or (eq major-mode 'archive-mode)
1068         (error "Buffer is not an archive buffer"))
1069     (if archive-read-only
1070         (error "Archive is read-only")))
1071   (if (eq arcbuf (current-buffer))
1072       (error "An archive buffer cannot be added to itself"))
1073   (if (string= name "")
1074       (error "Archive members may not be given empty names"))
1075   (let ((func (save-excursion (set-buffer arcbuf)
1076                               (archive-name "add-new-member")))
1077         (membuf (current-buffer)))
1078     (if (fboundp func)
1079         (save-excursion
1080           (set-buffer arcbuf)
1081           (funcall func buffer-file-name membuf name))
1082       (error "Adding a new member is not supported for this archive type"))))
1083 ;; -------------------------------------------------------------------------
1084 ;; Section: IO stuff
1085
1086 (defun archive-write-file-member ()
1087   (save-excursion
1088     (save-restriction
1089       (message "Updating archive...")
1090       (widen)
1091       (let ((writer  (save-excursion (set-buffer archive-superior-buffer)
1092                                      (archive-name "write-file-member")))
1093             (archive (save-excursion (set-buffer archive-superior-buffer)
1094                                      (archive-maybe-copy (buffer-file-name)))))
1095         (if (fboundp writer)
1096             (funcall writer archive archive-subfile-mode)
1097           (archive-*-write-file-member archive
1098                                        archive-subfile-mode
1099                                        (symbol-value writer)))
1100         (set-buffer-modified-p nil)
1101         (message "Updating archive...done"))
1102       (set-buffer archive-superior-buffer)
1103       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1104   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1105   ;; won't reset the coding-system of this archive member.
1106   (if (local-variable-p 'archive-member-coding-system)
1107       (setq last-coding-system-used archive-member-coding-system))
1108   t)
1109
1110 (defun archive-*-write-file-member (archive descr command)
1111   (let* ((ename (aref descr 0))
1112          (tmpfile (expand-file-name ename archive-tmpdir))
1113          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1114          (default-directory (file-name-as-directory top)))
1115     (unwind-protect
1116         (progn
1117           (make-directory (file-name-directory tmpfile) t)
1118           ;; If the member is itself an archive, write it without
1119           ;; the dired-like listing we created.
1120           (if (eq major-mode 'archive-mode)
1121               (archive-write-file tmpfile)
1122             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1123           ;; basic-save-buffer needs last-coding-system-used to have
1124           ;; the value used to write the file, so save it before any
1125           ;; further processing clobbers it (we restore it in
1126           ;; archive-write-file-member, above).
1127           (setq archive-member-coding-system last-coding-system-used)
1128           (if (aref descr 3)
1129               ;; Set the file modes, but make sure we can read it.
1130               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1131           (if enable-multibyte-characters
1132               (setq ename
1133                     (encode-coding-string ename file-name-coding-system)))
1134           (let ((exitcode (apply 'call-process
1135                                  (car command)
1136                                  nil
1137                                  nil
1138                                  nil
1139                                  (append (cdr command) (list archive ename)))))
1140             (if (equal exitcode 0)
1141                 nil
1142               (error "Updating was unsuccessful (%S)" exitcode))))
1143       (archive-delete-local tmpfile))))
1144
1145 (defun archive-write-file (&optional file)
1146   (save-excursion
1147     (let ((coding-system-for-write 'no-conversion))
1148       (write-region archive-proper-file-start (point-max)
1149                     (or file buffer-file-name) nil t)
1150       (set-buffer-modified-p nil))
1151     t))
1152 ;; -------------------------------------------------------------------------
1153 ;; Section: Marking and unmarking.
1154
1155 (defun archive-flag-deleted (p &optional type)
1156   "In archive mode, mark this member to be deleted from the archive.
1157 With a prefix argument, mark that many files."
1158   (interactive "p")
1159   (or type (setq type ?D))
1160   (beginning-of-line)
1161   (let ((sign (if (>= p 0) +1 -1))
1162         (modified (buffer-modified-p))
1163         buffer-read-only)
1164     (while (not (zerop p))
1165       (if (archive-get-descr t)
1166           (progn
1167             (delete-char 1)
1168             (insert type)))
1169       (forward-line sign)
1170       (setq p (- p sign)))
1171     (set-buffer-modified-p modified))
1172   (archive-next-line 0))
1173
1174 (defun archive-unflag (p)
1175   "In archive mode, un-mark this member if it is marked to be deleted.
1176 With a prefix argument, un-mark that many files forward."
1177   (interactive "p")
1178   (archive-flag-deleted p ? ))
1179
1180 (defun archive-unflag-backwards (p)
1181   "In archive mode, un-mark this member if it is marked to be deleted.
1182 With a prefix argument, un-mark that many members backward."
1183   (interactive "p")
1184   (archive-flag-deleted (- p) ? ))
1185
1186 (defun archive-unmark-all-files ()
1187   "Remove all marks."
1188   (interactive)
1189   (let ((modified (buffer-modified-p))
1190         buffer-read-only)
1191     (save-excursion
1192       (goto-char archive-file-list-start)
1193       (while (< (point) archive-file-list-end)
1194         (or (= (following-char) ? )
1195             (progn (delete-char 1) (insert ? )))
1196         (forward-line 1)))
1197     (set-buffer-modified-p modified)))
1198
1199 (defun archive-mark (p)
1200   "In archive mode, mark this member for group operations.
1201 With a prefix argument, mark that many members.
1202 Use \\[archive-unmark-all-files] to remove all marks."
1203   (interactive "p")
1204   (archive-flag-deleted p ?*))
1205
1206 (defun archive-get-marked (mark &optional default)
1207   (let (files)
1208     (save-excursion
1209       (goto-char archive-file-list-start)
1210       (while (< (point) archive-file-list-end)
1211         (if (= (following-char) mark)
1212             (setq files (cons (archive-get-descr) files)))
1213         (forward-line 1)))
1214     (or (nreverse files)
1215         (and default
1216              (list (archive-get-descr))))))
1217 ;; -------------------------------------------------------------------------
1218 ;; Section: Operate
1219
1220 (defun archive-next-line (p)
1221   (interactive "p")
1222   (forward-line p)
1223   (or (eobp)
1224       (forward-char archive-file-name-indent)))
1225
1226 (defun archive-previous-line (p)
1227   (interactive "p")
1228   (archive-next-line (- p)))
1229
1230 (defun archive-chmod-entry (new-mode)
1231   "Change the protection bits associated with all marked or this member.
1232 The new protection bits can either be specified as an octal number or
1233 as a relative change like \"g+rw\" as for chmod(2)"
1234   (interactive "sNew mode (octal or relative): ")
1235   (if archive-read-only (error "Archive is read-only"))
1236   (let ((func (archive-name "chmod-entry")))
1237     (if (fboundp func)
1238         (progn
1239           (funcall func new-mode (archive-get-marked ?* t))
1240           (archive-resummarize))
1241       (error "Setting mode bits is not supported for this archive type"))))
1242
1243 (defun archive-chown-entry (new-uid)
1244   "Change the owner of all marked or this member."
1245   (interactive "nNew uid: ")
1246   (if archive-read-only (error "Archive is read-only"))
1247   (let ((func (archive-name "chown-entry")))
1248     (if (fboundp func)
1249         (progn
1250           (funcall func new-uid (archive-get-marked ?* t))
1251           (archive-resummarize))
1252       (error "Setting owner is not supported for this archive type"))))
1253
1254 (defun archive-chgrp-entry (new-gid)
1255   "Change the group of all marked or this member."
1256   (interactive "nNew gid: ")
1257   (if archive-read-only (error "Archive is read-only"))
1258   (let ((func (archive-name "chgrp-entry")))
1259     (if (fboundp func)
1260         (progn
1261           (funcall func new-gid (archive-get-marked ?* t))
1262           (archive-resummarize))
1263       (error "Setting group is not supported for this archive type"))))
1264
1265 (defun archive-expunge ()
1266   "Do the flagged deletions."
1267   (interactive)
1268   (let (files)
1269     (save-excursion
1270       (goto-char archive-file-list-start)
1271       (while (< (point) archive-file-list-end)
1272         (if (= (following-char) ?D)
1273             (setq files (cons (aref (archive-get-descr) 0) files)))
1274         (forward-line 1)))
1275     (setq files (nreverse files))
1276     (and files
1277          (or (not archive-read-only)
1278              (error "Archive is read-only"))
1279          (or (yes-or-no-p (format "Really delete %d member%s? "
1280                                   (length files)
1281                                   (if (null (cdr files)) "" "s")))
1282              (error "Operation aborted"))
1283          (let ((archive (archive-maybe-copy (buffer-file-name)))
1284                (expunger (archive-name "expunge")))
1285            (if (fboundp expunger)
1286                (funcall expunger archive files)
1287              (archive-*-expunge archive files (symbol-value expunger)))
1288            (archive-maybe-update nil)
1289            (if archive-remote
1290                (archive-resummarize)
1291              (revert-buffer))))))
1292
1293 (defun archive-*-expunge (archive files command)
1294   (apply 'call-process
1295          (car command)
1296          nil
1297          nil
1298          nil
1299          (append (cdr command) (cons archive files))))
1300
1301 (defun archive-rename-entry (newname)
1302   "Change the name associated with this entry in the tar file."
1303   (interactive "sNew name: ")
1304   (if archive-read-only (error "Archive is read-only"))
1305   (if (string= newname "")
1306       (error "Archive members may not be given empty names"))
1307   (let ((func (archive-name "rename-entry"))
1308         (descr (archive-get-descr)))
1309     (if (fboundp func)
1310         (progn
1311           (funcall func (buffer-file-name)
1312                    (if enable-multibyte-characters
1313                        (encode-coding-string newname file-name-coding-system)
1314                      newname)
1315                    descr)
1316           (archive-resummarize))
1317       (error "Renaming is not supported for this archive type"))))
1318
1319 ;; Revert the buffer and recompute the dired-like listing.
1320 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1321   (let ((no (archive-get-lineno)))
1322     (setq archive-files nil)
1323     (let ((revert-buffer-function nil)
1324           (coding-system-for-read 'no-conversion))
1325       (set-buffer-multibyte nil)
1326       (revert-buffer t t))
1327     (archive-mode)
1328     (goto-char archive-file-list-start)
1329     (archive-next-line no)))
1330
1331 (defun archive-undo ()
1332   "Undo in an archive buffer.
1333 This doesn't recover lost files, it just undoes changes in the buffer itself."
1334   (interactive)
1335   (let (buffer-read-only)
1336     (undo)))
1337 ;; -------------------------------------------------------------------------
1338 ;; Section: Arc Archives
1339
1340 (defun archive-arc-summarize ()
1341   (let ((p 1)
1342         (totalsize 0)
1343         (maxlen 8)
1344         files
1345         visual)
1346     (while (and (< (+ p 29) (point-max))
1347                 (= (char-after p) ?\C-z)
1348                 (> (char-after (1+ p)) 0))
1349       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1350              (fnlen   (or (string-match "\0" namefld) 13))
1351              (efnname (substring namefld 0 fnlen))
1352              (csize   (archive-l-e (+ p 15) 4))
1353              (moddate (archive-l-e (+ p 19) 2))
1354              (modtime (archive-l-e (+ p 21) 2))
1355              (ucsize  (archive-l-e (+ p 25) 4))
1356              (fiddle  (string= efnname (upcase efnname)))
1357              (ifnname (if fiddle (downcase efnname) efnname))
1358              (text    (format "  %8d  %-11s  %-8s  %s"
1359                               ucsize
1360                               (archive-dosdate moddate)
1361                               (archive-dostime modtime)
1362                               ifnname)))
1363         (setq maxlen (max maxlen fnlen)
1364               totalsize (+ totalsize ucsize)
1365               visual (cons (vector text
1366                                    (- (length text) (length ifnname))
1367                                    (length text))
1368                            visual)
1369               files (cons (vector efnname ifnname fiddle nil (1- p))
1370                           files)
1371               p (+ p 29 csize))))
1372     (goto-char (point-min))
1373     (let ((dash (concat "- --------  -----------  --------  "
1374                         (make-string maxlen ?-)
1375                         "\n")))
1376       (insert "M   Length  Date         Time      File\n"
1377               dash)
1378       (archive-summarize-files (nreverse visual))
1379       (insert dash
1380               (format "  %8d                         %d file%s"
1381                       totalsize
1382                       (length files)
1383                       (if (= 1 (length files)) "" "s"))
1384               "\n"))
1385     (apply 'vector (nreverse files))))
1386
1387 (defun archive-arc-rename-entry (archive newname descr)
1388   (if (string-match "[:\\\\/]" newname)
1389       (error "File names in arc files may not contain a path"))
1390   (if (> (length newname) 12)
1391       (error "File names in arc files are limited to 12 characters"))
1392   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1393                                          (length newname))))
1394         buffer-read-only)
1395     (save-restriction
1396       (save-excursion
1397         (widen)
1398         (set-buffer-multibyte nil)
1399         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1400         (delete-char 13)
1401         (insert name)))))
1402 ;; -------------------------------------------------------------------------
1403 ;; Section: Lzh Archives
1404
1405 (defun archive-lzh-summarize ()
1406   (let ((p 1)
1407         (totalsize 0)
1408         (maxlen 8)
1409         files
1410         visual)
1411     (while (progn (goto-char p)
1412                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1413       (let* ((hsize   (char-after p))
1414              (csize   (archive-l-e (+ p 7) 4))
1415              (ucsize  (archive-l-e (+ p 11) 4))
1416              (modtime (archive-l-e (+ p 15) 2))
1417              (moddate (archive-l-e (+ p 17) 2))
1418              (hdrlvl  (char-after (+ p 20)))
1419              (fnlen   (char-after (+ p 21)))
1420              (efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen))))
1421                         (if file-name-coding-system
1422                             (decode-coding-string str file-name-coding-system)
1423                           (string-as-multibyte str))))
1424              (fiddle  (string= efnname (upcase efnname)))
1425              (ifnname (if fiddle (downcase efnname) efnname))
1426              (width (string-width ifnname))
1427              (p2      (+ p 22 fnlen))
1428              (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1429              mode modestr uid gid text path prname
1430              )
1431         (if (= hdrlvl 0)
1432             (setq mode    (if (= creator ?U) (archive-l-e (+ p2 8) 2) ?\666)
1433                   uid     (if (= creator ?U) (archive-l-e (+ p2 10) 2))
1434                   gid     (if (= creator ?U) (archive-l-e (+ p2 12) 2)))
1435           (if (= creator ?U)
1436               (let* ((p3 (+ p2 3))
1437                      (hsize (archive-l-e p3 2))
1438                      (etype (char-after (+ p3 2))))
1439                 (while (not (= hsize 0))
1440                   (cond
1441                    ((= etype 2) (let ((i (+ p3 3)))
1442                                   (while (< i (+ p3 hsize))
1443                                     (setq path (concat path
1444                                                        (if (= (char-after i)
1445                                                               255)
1446                                                            "/"
1447                                                          (char-to-string
1448                                                           (char-after i)))))
1449                                     (setq i (1+ i)))))
1450                    ((= etype 80) (setq mode (archive-l-e (+ p3 3) 2)))
1451                    ((= etype 81) (progn (setq uid (archive-l-e (+ p3 3) 2))
1452                                         (setq gid (archive-l-e (+ p3 5) 2))))
1453                    )
1454                   (setq p3 (+ p3 hsize))
1455                   (setq hsize (archive-l-e p3 2))
1456                   (setq etype (char-after (+ p3 2)))))))
1457         (setq prname (if path (concat path ifnname) ifnname))
1458         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1459         (setq text    (if archive-alternate-display
1460                           (format "  %8d  %5S  %5S  %s"
1461                                   ucsize
1462                                   (or uid "?")
1463                                   (or gid "?")
1464                                   ifnname)
1465                         (format "  %10s  %8d  %-11s  %-8s  %s"
1466                                 modestr
1467                                 ucsize
1468                                 (archive-dosdate moddate)
1469                                 (archive-dostime modtime)
1470                                 ifnname)))
1471         (setq maxlen (max maxlen width)
1472               totalsize (+ totalsize ucsize)
1473               visual (cons (vector text
1474                                    (- (length text) (length ifnname))
1475                                    (length text))
1476                            visual)
1477               files (cons (vector prname ifnname fiddle mode (1- p))
1478                           files)
1479               p (+ p hsize 2 csize))))
1480     (goto-char (point-min))
1481     (set-buffer-multibyte default-enable-multibyte-characters)
1482     (let ((dash (concat (if archive-alternate-display
1483                             "- --------  -----  -----  "
1484                           "- ----------  --------  -----------  --------  ")
1485                         (make-string maxlen ?-)
1486                         "\n"))
1487           (header (if archive-alternate-display
1488                        "M   Length    Uid    Gid  File\n"
1489                     "M   Filemode    Length  Date         Time      File\n"))
1490           (sumline (if archive-alternate-display
1491                        "  %8d                %d file%s"
1492                      "              %8d                         %d file%s")))
1493       (insert header dash)
1494       (archive-summarize-files (nreverse visual))
1495       (insert dash
1496               (format sumline
1497                       totalsize
1498                       (length files)
1499                       (if (= 1 (length files)) "" "s"))
1500               "\n"))
1501     (apply 'vector (nreverse files))))
1502
1503 (defconst archive-lzh-alternate-display t)
1504
1505 (defun archive-lzh-extract (archive name)
1506   (archive-extract-by-stdout archive name archive-lzh-extract))
1507
1508 (defun archive-lzh-resum (p count)
1509   (let ((sum 0))
1510     (while (> count 0)
1511       (setq count (1- count)
1512             sum (+ sum (char-after p))
1513             p (1+ p)))
1514     (logand sum 255)))
1515
1516 (defun archive-lzh-rename-entry (archive newname descr)
1517   (save-restriction
1518     (save-excursion
1519       (widen)
1520       (set-buffer-multibyte nil)
1521       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1522              (oldhsize (char-after p))
1523              (oldfnlen (char-after (+ p 21)))
1524              (newfnlen (length newname))
1525              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1526              buffer-read-only)
1527         (if (> newhsize 255)
1528             (error "The file name is too long"))
1529         (goto-char (+ p 21))
1530         (delete-char (1+ oldfnlen))
1531         (insert newfnlen newname)
1532         (goto-char p)
1533         (delete-char 2)
1534         (insert newhsize (archive-lzh-resum p newhsize))))))
1535
1536 (defun archive-lzh-ogm (newval files errtxt ofs)
1537   (save-restriction
1538     (save-excursion
1539       (widen)
1540       (set-buffer-multibyte nil)
1541       (while files
1542         (let* ((fil (car files))
1543                (p (+ archive-proper-file-start (aref fil 4)))
1544                (hsize   (char-after p))
1545                (fnlen   (char-after (+ p 21)))
1546                (p2      (+ p 22 fnlen))
1547                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1548                buffer-read-only)
1549           (if (= creator ?U)
1550               (progn
1551                 (or (numberp newval)
1552                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1553                 (goto-char (+ p2 ofs))
1554                 (delete-char 2)
1555                 (insert (logand newval 255) (lsh newval -8))
1556                 (goto-char (1+ p))
1557                 (delete-char 1)
1558                 (insert (archive-lzh-resum (1+ p) hsize)))
1559             (message "Member %s does not have %s field"
1560                      (aref fil 1) errtxt)))
1561         (setq files (cdr files))))))
1562
1563 (defun archive-lzh-chown-entry (newuid files)
1564   (archive-lzh-ogm newuid files "an uid" 10))
1565
1566 (defun archive-lzh-chgrp-entry (newgid files)
1567   (archive-lzh-ogm newgid files "a gid" 12))
1568
1569 (defun archive-lzh-chmod-entry (newmode files)
1570   (archive-lzh-ogm
1571    ;; This should work even though newmode will be dynamically accessed.
1572    (function (lambda (old) (archive-calc-mode old newmode t)))
1573    files "a unix-style mode" 8))
1574 ;; -------------------------------------------------------------------------
1575 ;; Section: Zip Archives
1576
1577 (defun archive-zip-summarize ()
1578   (goto-char (- (point-max) (- 22 18)))
1579   (search-backward-regexp "[P]K\005\006")
1580   (let ((p (1+ (archive-l-e (+ (point) 16) 4)))
1581         (maxlen 8)
1582         (totalsize 0)
1583         files
1584         visual)
1585     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1586       (let* ((creator (char-after (+ p 5)))
1587              (method  (archive-l-e (+ p 10) 2))
1588              (modtime (archive-l-e (+ p 12) 2))
1589              (moddate (archive-l-e (+ p 14) 2))
1590              (ucsize  (archive-l-e (+ p 24) 4))
1591              (fnlen   (archive-l-e (+ p 28) 2))
1592              (exlen   (archive-l-e (+ p 30) 2))
1593              (fclen   (archive-l-e (+ p 32) 2))
1594              (lheader (archive-l-e (+ p 42) 4))
1595              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1596                         (if file-name-coding-system
1597                             (decode-coding-string str file-name-coding-system)
1598                           (string-as-multibyte str))))
1599              (isdir   (and (= ucsize 0)
1600                            (string= (file-name-nondirectory efnname) "")))
1601              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1602                              (archive-l-e (+ p 40) 2))
1603                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1604                              (logior ?\444
1605                                      (if isdir (logior 16384 ?\111) 0)
1606                                      (if (zerop
1607                                           (logand 1 (char-after (+ p 38))))
1608                                          ?\222 0)))
1609                             (t nil)))
1610              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1611              (fiddle  (and archive-zip-case-fiddle
1612                            (not (not (memq creator '(0 2 4 5 9))))
1613                            (string= (upcase efnname) efnname)))
1614              (ifnname (if fiddle (downcase efnname) efnname))
1615              (width (string-width ifnname))
1616              (text    (format "  %10s  %8d  %-11s  %-8s  %s"
1617                               modestr
1618                               ucsize
1619                               (archive-dosdate moddate)
1620                               (archive-dostime modtime)
1621                               ifnname)))
1622         (setq maxlen (max maxlen width)
1623               totalsize (+ totalsize ucsize)
1624               visual (cons (vector text
1625                                    (- (length text) (length ifnname))
1626                                    (length text))
1627                            visual)
1628               files (cons (if isdir
1629                               nil
1630                             (vector efnname ifnname fiddle mode
1631                                     (list (1- p) lheader)))
1632                           files)
1633               p (+ p 46 fnlen exlen fclen))))
1634     (goto-char (point-min))
1635     (let ((dash (concat "- ----------  --------  -----------  --------  "
1636                         (make-string maxlen ?-)
1637                         "\n")))
1638       (insert "M Filemode      Length  Date         Time      File\n"
1639               dash)
1640       (archive-summarize-files (nreverse visual))
1641       (insert dash
1642               (format "              %8d                         %d file%s"
1643                       totalsize
1644                       (length files)
1645                       (if (= 1 (length files)) "" "s"))
1646               "\n"))
1647     (apply 'vector (nreverse files))))
1648
1649 (defun archive-zip-extract (archive name)
1650   (if (equal (car archive-zip-extract) "pkzip")
1651       (archive-*-extract archive name archive-zip-extract)
1652     (archive-extract-by-stdout archive name archive-zip-extract)))
1653
1654 (defun archive-zip-write-file-member (archive descr)
1655   (archive-*-write-file-member
1656    archive
1657    descr
1658    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1659
1660 (defun archive-zip-chmod-entry (newmode files)
1661   (save-restriction
1662     (save-excursion
1663       (widen)
1664       (set-buffer-multibyte nil)
1665       (while files
1666         (let* ((fil (car files))
1667                (p (+ archive-proper-file-start (car (aref fil 4))))
1668                (creator (char-after (+ p 5)))
1669                (oldmode (aref fil 3))
1670                (newval  (archive-calc-mode oldmode newmode t))
1671                buffer-read-only)
1672           (cond ((memq creator '(2 3)) ; Unix + VMS
1673                  (goto-char (+ p 40))
1674                  (delete-char 2)
1675                  (insert (logand newval 255) (lsh newval -8)))
1676                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1677                  (goto-char (+ p 38))
1678                  (insert (logior (logand (char-after (point)) 254)
1679                                  (logand (logxor 1 (lsh newval -7)) 1)))
1680                  (delete-char 1))
1681                 (t (message "Don't know how to change mode for this member"))))
1682         (setq files (cdr files))))))
1683 ;; -------------------------------------------------------------------------
1684 ;; Section: Zoo Archives
1685
1686 (defun archive-zoo-summarize ()
1687   (let ((p (1+ (archive-l-e 25 4)))
1688         (maxlen 8)
1689         (totalsize 0)
1690         files
1691         visual)
1692     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1693                 (> (archive-l-e (+ p 6) 4) 0))
1694       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1695              (moddate (archive-l-e (+ p 14) 2))
1696              (modtime (archive-l-e (+ p 16) 2))
1697              (ucsize  (archive-l-e (+ p 20) 4))
1698              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1699              (dirtype (char-after (+ p 4)))
1700              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1701              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1702              (fnlen   (or (string-match "\0" namefld) 13))
1703              (efnname (let ((str
1704                              (concat
1705                               (if (> ldirlen 0)
1706                                   (concat (buffer-substring
1707                                            (+ p 58 lfnlen)
1708                                            (+ p 58 lfnlen ldirlen -1))
1709                                           "/")
1710                                 "")
1711                               (if (> lfnlen 0)
1712                                   (buffer-substring (+ p 58)
1713                                                     (+ p 58 lfnlen -1))
1714                                 (substring namefld 0 fnlen)))))
1715                         (if file-name-coding-system
1716                             (decode-coding-string str file-name-coding-system)
1717                           (string-as-multibyte str))))
1718              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1719              (ifnname (if fiddle (downcase efnname) efnname))
1720              (width (string-width ifnname))
1721              (text    (format "  %8d  %-11s  %-8s  %s"
1722                               ucsize
1723                               (archive-dosdate moddate)
1724                               (archive-dostime modtime)
1725                               ifnname)))
1726         (setq maxlen (max maxlen width)
1727               totalsize (+ totalsize ucsize)
1728               visual (cons (vector text
1729                                    (- (length text) (length ifnname))
1730                                    (length text))
1731                            visual)
1732               files (cons (vector efnname ifnname fiddle nil (1- p))
1733                           files)
1734               p next)))
1735     (goto-char (point-min))
1736     (let ((dash (concat "- --------  -----------  --------  "
1737                         (make-string maxlen ?-)
1738                         "\n")))
1739       (insert "M   Length  Date         Time      File\n"
1740               dash)
1741       (archive-summarize-files (nreverse visual))
1742       (insert dash
1743               (format "  %8d                         %d file%s"
1744                       totalsize
1745                       (length files)
1746                       (if (= 1 (length files)) "" "s"))
1747               "\n"))
1748     (apply 'vector (nreverse files))))
1749
1750 (defun archive-zoo-extract (archive name)
1751   (archive-extract-by-stdout archive name archive-zoo-extract))
1752 ;; -------------------------------------------------------------------------
1753 ;; This line was a mistake; it is kept now for compatibility.
1754 ;; rms  15 Oct 98
1755 (provide 'archive-mode)
1756
1757 (provide 'arc-mode)
1758
1759 ;;; arc-mode.el ends here