lisp/ediff-merg.el

   1 ;;; ediff-merg.el --- merging utilities
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Kifer <kifer@cs.sunysb.edu>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Code:
  25
  26 (provide 'ediff-merg)
  27
  28 (defgroup ediff-merge nil
  29   "Merging utilities"
  30   :prefix "ediff-"
  31   :group 'ediff)
  32
  33
  34 ;; compiler pacifier
  35 (defvar ediff-window-A)
  36 (defvar ediff-window-B)
  37 (defvar ediff-window-C)
  38 (defvar ediff-merge-window-share)
  39 (defvar ediff-window-config-saved)
  40
  41 (eval-when-compile
  42   (let ((load-path (cons (expand-file-name ".") load-path)))
  43     (or (featurep 'ediff-init)
  44         (load "ediff-init.el" nil nil 'nosuffix))
  45     (or (featurep 'ediff-util)
  46         (load "ediff-util.el" nil nil 'nosuffix))
  47     ))
  48 ;; end pacifier
  49
  50 (require 'ediff-init)
  51
  52 (defcustom ediff-quit-merge-hook 'ediff-maybe-save-and-delete-merge
  53   "*Hooks to run before quitting a merge job.
  54 The most common use is to save and delete the merge buffer."
  55   :type 'hook
  56   :group 'ediff-merge)
  57
  58
  59 (defcustom ediff-default-variant 'combined
  60   "*The variant to be used as a default for buffer C in merging.
  61 Valid values are the symbols `default-A', `default-B', and `combined'."
  62   :type '(radio (const default-A) (const default-B) (const combined))
  63   :group 'ediff-merge)
  64
  65 (defcustom ediff-combination-pattern
  66   '("<<<<<<<<<<<<<< variant A" ">>>>>>>>>>>>>> variant B" "======= end of combination")
  67   "*Pattern to be used for combining difference regions in buffers A and B.
  68 The value is (STRING1 STRING2 STRING3). The combined text will look like this:
  69
  70 STRING1
  71 diff region from variant A
  72 STRING2
  73 diff region from variant B
  74 STRING3
  75 "
  76   :type '(list string string string)
  77   :group 'ediff-merge)
  78
  79 (ediff-defvar-local ediff-show-clashes-only  nil
  80   "*If t, show only those diff regions where both buffers disagree with the ancestor.
  81 This means that regions that have status prefer-A or prefer-B will be
  82 skiped over. Nil means show all regions.")
  83
  84
  85 (defsubst ediff-get-combined-region (n)
  86   (concat (nth 0 ediff-combination-pattern) "\n"
  87           (ediff-get-region-contents n 'A ediff-control-buffer)
  88           (nth 1 ediff-combination-pattern) "\n"
  89           (ediff-get-region-contents n 'B ediff-control-buffer)
  90           (nth 2 ediff-combination-pattern) "\n"))
  91
  92 (defsubst ediff-make-combined-diff (regA regB)
  93   (concat (nth 0 ediff-combination-pattern) "\n"
  94           regA
  95           (nth 1 ediff-combination-pattern) "\n"
  96           regB
  97           (nth 2 ediff-combination-pattern) "\n"))
  98
  99 (defsubst ediff-set-state-of-all-diffs-in-all-buffers (ctl-buf)
 100   (let ((n 0))
 101     (while (< n ediff-number-of-differences)
 102       (ediff-set-state-of-diff-in-all-buffers n ctl-buf)
 103       (setq n (1+ n)))))
 104
 105 (defun ediff-set-state-of-diff-in-all-buffers (n ctl-buf)
 106   (let ((regA (ediff-get-region-contents n 'A ctl-buf))
 107         (regB (ediff-get-region-contents n 'B ctl-buf))
 108         (regC (ediff-get-region-contents n 'C ctl-buf)))
 109     (cond ((and (string= regA regB) (string= regA  regC))
 110            (ediff-set-state-of-diff n 'A "=diff(B)")
 111            (ediff-set-state-of-diff n 'B "=diff(C)")
 112            (ediff-set-state-of-diff n 'C "=diff(A)"))
 113           ((string= regA regB)
 114            (ediff-set-state-of-diff n 'A "=diff(B)")
 115            (ediff-set-state-of-diff n 'B "=diff(A)")
 116            (ediff-set-state-of-diff n 'C nil))
 117           ((string= regA regC)
 118            (ediff-set-state-of-diff n 'A "=diff(C)")
 119            (ediff-set-state-of-diff n 'C "=diff(A)")
 120            (ediff-set-state-of-diff n 'B nil))
 121           ((string= regB regC)
 122            (ediff-set-state-of-diff n 'C "=diff(B)")
 123            (ediff-set-state-of-diff n 'B "=diff(C)")
 124            (ediff-set-state-of-diff n 'A nil))
 125           ((string= regC (ediff-get-combined-region n))
 126            (ediff-set-state-of-diff n 'A nil)
 127              (ediff-set-state-of-diff n 'B nil)
 128              (ediff-set-state-of-diff n 'C "=diff(A+B)"))
 129           (t (ediff-set-state-of-diff n 'A nil)
 130              (ediff-set-state-of-diff n 'B nil)
 131              (ediff-set-state-of-diff n 'C nil)))
 132     ))
 133
 134 (defun ediff-set-merge-mode ()
 135   ;; by Stig@hackvan.com
 136   (normal-mode t)
 137   (remove-hook 'local-write-file-hooks 'ediff-set-merge-mode))
 138
 139
 140 ;; Go over all diffs starting with DIFF-NUM and copy regions into buffer C
 141 ;; according to the state of the difference.
 142 ;; Since ediff-copy-diff refuses to copy identical diff regions, there is
 143 ;; no need to optimize ediff-do-merge any further.
 144 ;;
 145 ;; If re-merging, change state of merge in all diffs starting with
 146 ;; DIFF-NUM, except those where the state is prefer-* or where it is
 147 ;; `default-*' or `combined' but the buf C region appears to be modified
 148 ;; since last set by default.
 149 (defun ediff-do-merge (diff-num &optional remerging)
 150   (if (< diff-num 0) (setq diff-num 0))
 151   (let ((n diff-num)
 152         ;;(default-state-of-merge (format "%S" ediff-default-variant))
 153         do-not-copy state-of-merge)
 154     (while (< n ediff-number-of-differences)
 155       (setq do-not-copy nil) ; reset after each cycle
 156       (if (= (mod n 10) 0)
 157           (message "%s buffers A & B into C ... region %d of %d"
 158                    (if remerging "Re-merging" "Merging")
 159                    n
 160                    ediff-number-of-differences))
 161
 162       (setq state-of-merge (ediff-get-state-of-merge n))
 163
 164       (if remerging
 165           (let ((reg-A (ediff-get-region-contents n 'A ediff-control-buffer))
 166                 (reg-B (ediff-get-region-contents n 'B ediff-control-buffer))
 167                 (reg-C (ediff-get-region-contents n 'C ediff-control-buffer)))
 168
 169             ;; if region was edited since it was first set by default
 170             (if (or (and (string= state-of-merge "default-A")
 171                          (not (string= reg-A reg-C)))
 172                     ;; was edited since first set by default
 173                     (and (string= state-of-merge "default-B")
 174                          (not (string= reg-B reg-C)))
 175                     ;; was edited since first set by default
 176                     (and (string= state-of-merge "combined")
 177                          (not (string=
 178                                (ediff-make-combined-diff reg-A reg-B) reg-C)))
 179                     ;; was preferred--ignore
 180                     (string-match "prefer" state-of-merge))
 181                 (setq do-not-copy t))
 182
 183             ;; change state of merge for this diff, if necessary
 184             (if (and (string-match "\\(default\\|combined\\)" state-of-merge)
 185                      (not do-not-copy))
 186                 (ediff-set-state-of-merge
 187                  n (format "%S" ediff-default-variant)))
 188             ))
 189
 190       ;; state-of-merge may have changed via ediff-set-state-of-merge, so
 191       ;; check it once again
 192       (setq state-of-merge (ediff-get-state-of-merge n))
 193
 194       (or do-not-copy
 195           (if (string= state-of-merge "combined")
 196               ;; use n+1 because ediff-combine-diffs works via user numbering
 197               ;; of diffs, which is 1+ to what ediff uses internally
 198               (ediff-combine-diffs (1+ n) 'batch)
 199             (ediff-copy-diff
 200              n (if (string-match "-A" state-of-merge) 'A 'B) 'C 'batch)))
 201       (setq n (1+ n)))
 202     (message "Merging buffers A & B into C ... Done")
 203     ))
 204
 205
 206 (defun ediff-re-merge ()
 207   "Remerge unmodified diff regions using a new default. Start with the current region."
 208   (interactive)
 209   (let* ((default-variant-alist
 210            (list '("default-A") '("default-B") '("combined")))
 211          (actual-alist
 212           (delete (list (symbol-name ediff-default-variant))
 213                   default-variant-alist)))
 214     (setq ediff-default-variant
 215           (intern
 216            (completing-read
 217             (format "Current merge default is `%S'. New default: "
 218                     ediff-default-variant)
 219             actual-alist nil 'must-match)))
 220     (ediff-do-merge ediff-current-difference 'remerge)
 221     (ediff-recenter)
 222   ))
 223
 224 (defun ediff-shrink-window-C (arg)
 225   "Shrink window C to just one line.
 226 With a prefix argument, returns window C to its normal size.
 227 Used only for merging jobs."
 228   (interactive "P")
 229   (if (not ediff-merge-job)
 230       (error "ediff-shrink-window-C can be used only for merging jobs"))
 231   (cond ((eq arg '-) (setq arg -1))
 232         ((not (numberp arg)) (setq arg nil)))
 233   (cond ((null arg)
 234          (let ((ediff-merge-window-share
 235                 (if (< (window-height ediff-window-C) 3)
 236                     ediff-merge-window-share 0)))
 237            (setq ediff-window-config-saved "") ; force redisplay
 238            (ediff-recenter 'no-rehighlight)))
 239         ((and (< arg 0) (> (window-height ediff-window-C) 2))
 240          (setq ediff-merge-window-share (* ediff-merge-window-share 0.9))
 241          (setq ediff-window-config-saved "") ; force redisplay
 242          (ediff-recenter 'no-rehighlight))
 243         ((and (> arg 0) (> (window-height ediff-window-A) 2))
 244          (setq ediff-merge-window-share (* ediff-merge-window-share 1.1))
 245          (setq ediff-window-config-saved "") ; force redisplay
 246          (ediff-recenter 'no-rehighlight))))
 247
 248
 249 ;; N here is the user's region number. It is 1+ what Ediff uses internally.
 250 (defun ediff-combine-diffs (n &optional batch-invocation)
 251   "Combine Nth diff regions of buffers A and B and place the combination in C.
 252 N is a prefix argument. If nil, combine the current difference regions.
 253 Combining is done according to the specifications in variable
 254 `ediff-combination-pattern'."
 255   (interactive "P")
 256   (setq n (if (numberp n) (1- n) ediff-current-difference))
 257
 258   (let (regA regB reg-combined)
 259     (setq regA (ediff-get-region-contents n 'A ediff-control-buffer)
 260           regB (ediff-get-region-contents n 'B ediff-control-buffer))
 261
 262     (setq reg-combined (ediff-make-combined-diff regA regB))
 263
 264     (ediff-copy-diff n nil 'C batch-invocation reg-combined))
 265     (or batch-invocation (ediff-jump-to-difference (1+ n))))
 266
 267
 268 ;; Checks if the region in buff C looks like a combination of the regions
 269 ;; in buffers A and B. Returns a list (reg-a-beg reg-a-end reg-b-beg reg-b-end)
 270 ;; These refer to where the copies of region A and B start and end in buffer C
 271 (defun ediff-looks-like-combined-merge (region-num)
 272   (if ediff-merge-job
 273       (let ((combined (string-match (regexp-quote "(A+B)")
 274                                     (or (ediff-get-state-of-diff region-num 'C)
 275                                         "")))
 276             (reg-beg (ediff-get-diff-posn 'C 'beg region-num))
 277             (reg-end (ediff-get-diff-posn 'C 'end region-num))
 278             (pat1 (nth 0 ediff-combination-pattern))
 279             (pat2 (nth 1 ediff-combination-pattern))
 280             (pat3 (nth 2 ediff-combination-pattern))
 281             reg-a-beg reg-a-end reg-b-beg reg-b-end reg-c-beg reg-c-end)
 282
 283         (if combined
 284             (ediff-with-current-buffer ediff-buffer-C
 285               (goto-char reg-beg)
 286               (search-forward pat1 reg-end 'noerror)
 287               (setq reg-a-beg (match-beginning 0))
 288               (setq reg-a-end (match-end 0))
 289               (search-forward pat2 reg-end 'noerror)
 290               (setq reg-b-beg (match-beginning 0))
 291               (setq reg-b-end (match-end 0))
 292               (search-forward pat3 reg-end 'noerror)
 293               (setq reg-c-beg (match-beginning 0))
 294               (setq reg-c-end (match-end 0))))
 295
 296         (if (and reg-a-beg reg-a-end reg-b-beg reg-b-end)
 297             (list reg-a-beg reg-a-end reg-b-beg reg-b-end reg-c-beg reg-c-end))
 298         )))
 299
 300
 301 ;;; Local Variables:
 302 ;;; eval: (put 'ediff-defvar-local 'lisp-indent-hook 'defun)
 303 ;;; eval: (put 'ediff-with-current-buffer 'lisp-indent-hook 1)
 304 ;;; eval: (put 'ediff-with-current-buffer 'edebug-form-spec '(form body))
 305 ;;; End:
 306
 307 ;; ediff-merg.el ends here