lisp/buff-menu.el

   1 ;;; buff-menu.el --- buffer menu main function and support functions.
   2
   3 ;; Copyright (C) 1985, 86, 87, 93, 94, 95 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Edit, delete, or change attributes of all currently active Emacs
  27 ;; buffers from a list summarizing their state.  A good way to browse
  28 ;; any special or scratch buffers you have loaded, since you can't find
  29 ;; them by filename.  The single entry point is `Buffer-menu-mode',
  30 ;; normally bound to C-x C-b.
  31
  32 ;;; Change Log:
  33
  34 ;; Merged by esr with recent mods to Emacs 19 buff-menu, 23 Mar 1993
  35 ;;
  36 ;; Modified by Bob Weiner, Motorola, Inc., 4/14/89
  37 ;;
  38 ;; Added optional backup argument to 'Buffer-menu-unmark' to make it undelete
  39 ;; current entry and then move to previous one.
  40 ;;
  41 ;; Based on FSF code dating back to 1985.
  42
  43 ;;; Code:
  44
  45 ;;;Trying to preserve the old window configuration works well in
  46 ;;;simple scenarios, when you enter the buffer menu, use it, and exit it.
  47 ;;;But it does strange things when you switch back to the buffer list buffer
  48 ;;;with C-x b, later on, when the window configuration is different.
  49 ;;;The choice seems to be, either restore the window configuration
  50 ;;;in all cases, or in no cases.
  51 ;;;I decided it was better not to restore the window config at all. -- rms.
  52
  53 ;;;But since then, I changed buffer-menu to use the selected window,
  54 ;;;so q now once again goes back to the previous window configuration.
  55
  56 ;;;(defvar Buffer-menu-window-config nil
  57 ;;;  "Window configuration saved from entry to `buffer-menu'.")
  58
  59 ; Put buffer *Buffer List* into proper mode right away
  60 ; so that from now on even list-buffers is enough to get a buffer menu.
  61
  62 (defvar Buffer-menu-buffer-column nil)
  63
  64 (defvar Buffer-menu-mode-map nil "")
  65
  66 (if Buffer-menu-mode-map
  67     ()
  68   (setq Buffer-menu-mode-map (make-keymap))
  69   (suppress-keymap Buffer-menu-mode-map t)
  70   (define-key Buffer-menu-mode-map "q" 'Buffer-menu-quit)
  71   (define-key Buffer-menu-mode-map "v" 'Buffer-menu-select)
  72   (define-key Buffer-menu-mode-map "2" 'Buffer-menu-2-window)
  73   (define-key Buffer-menu-mode-map "1" 'Buffer-menu-1-window)
  74   (define-key Buffer-menu-mode-map "f" 'Buffer-menu-this-window)
  75   (define-key Buffer-menu-mode-map "\C-m" 'Buffer-menu-this-window)
  76   (define-key Buffer-menu-mode-map "o" 'Buffer-menu-other-window)
  77   (define-key Buffer-menu-mode-map "\C-o" 'Buffer-menu-switch-other-window)
  78   (define-key Buffer-menu-mode-map "s" 'Buffer-menu-save)
  79   (define-key Buffer-menu-mode-map "d" 'Buffer-menu-delete)
  80   (define-key Buffer-menu-mode-map "k" 'Buffer-menu-delete)
  81   (define-key Buffer-menu-mode-map "\C-d" 'Buffer-menu-delete-backwards)
  82   (define-key Buffer-menu-mode-map "\C-k" 'Buffer-menu-delete)
  83   (define-key Buffer-menu-mode-map "x" 'Buffer-menu-execute)
  84   (define-key Buffer-menu-mode-map " " 'next-line)
  85   (define-key Buffer-menu-mode-map "n" 'next-line)
  86   (define-key Buffer-menu-mode-map "p" 'previous-line)
  87   (define-key Buffer-menu-mode-map "\177" 'Buffer-menu-backup-unmark)
  88   (define-key Buffer-menu-mode-map "~" 'Buffer-menu-not-modified)
  89   (define-key Buffer-menu-mode-map "?" 'describe-mode)
  90   (define-key Buffer-menu-mode-map "u" 'Buffer-menu-unmark)
  91   (define-key Buffer-menu-mode-map "m" 'Buffer-menu-mark)
  92   (define-key Buffer-menu-mode-map "t" 'Buffer-menu-visit-tags-table)
  93   (define-key Buffer-menu-mode-map "%" 'Buffer-menu-toggle-read-only)
  94   (define-key Buffer-menu-mode-map "b" 'Buffer-menu-bury)
  95   (define-key Buffer-menu-mode-map "g" 'Buffer-menu-revert)
  96   (define-key Buffer-menu-mode-map [mouse-2] 'Buffer-menu-mouse-select)
  97 )
  98
  99 ;; Buffer Menu mode is suitable only for specially formatted data.
 100 (put 'Buffer-menu-mode 'mode-class 'special)
 101
 102 (defun Buffer-menu-mode ()
 103   "Major mode for editing a list of buffers.
 104 Each line describes one of the buffers in Emacs.
 105 Letters do not insert themselves; instead, they are commands.
 106 \\<Buffer-menu-mode-map>
 107 \\[Buffer-menu-mouse-select] -- select buffer you click on, in place of the buffer menu.
 108 \\[Buffer-menu-this-window] -- select current line's buffer in place of the buffer menu.
 109 \\[Buffer-menu-other-window] -- select that buffer in another window,
 110   so the buffer menu buffer remains visible in its window.
 111 \\[Buffer-menu-switch-other-window] -- make another window display that buffer.
 112 \\[Buffer-menu-mark] -- mark current line's buffer to be displayed.
 113 \\[Buffer-menu-select] -- select current line's buffer.
 114   Also show buffers marked with m, in other windows.
 115 \\[Buffer-menu-1-window] -- select that buffer in full-frame window.
 116 \\[Buffer-menu-2-window] -- select that buffer in one window,
 117   together with buffer selected before this one in another window.
 118 \\[Buffer-menu-visit-tags-table] -- visit-tags-table this buffer.
 119 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 120 \\[Buffer-menu-save] -- mark that buffer to be saved, and move down.
 121 \\[Buffer-menu-delete] -- mark that buffer to be deleted, and move down.
 122 \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted, and move up.
 123 \\[Buffer-menu-execute] -- delete or save marked buffers.
 124 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 125   With prefix argument, also move up one line.
 126 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 127 \\[Buffer-menu-toggle-read-only] -- toggle read-only status of buffer on this line.
 128 \\[Buffer-menu-revert] -- update the list of buffers.
 129 \\[Buffer-menu-bury] -- bury the buffer listed on this line."
 130   (kill-all-local-variables)
 131   (use-local-map Buffer-menu-mode-map)
 132   (setq major-mode 'Buffer-menu-mode)
 133   (setq mode-name "Buffer Menu")
 134   (make-local-variable 'revert-buffer-function)
 135   (setq revert-buffer-function 'Buffer-menu-revert-function)
 136   (setq truncate-lines t)
 137   (setq buffer-read-only t)
 138   (run-hooks 'buffer-menu-mode-hook))
 139
 140 (defun Buffer-menu-revert ()
 141   "Update the list of buffers."
 142   (interactive)
 143   (revert-buffer))
 144
 145 (defun Buffer-menu-revert-function (ignore1 ignore2)
 146   (list-buffers))
 147 \f
 148 (defun Buffer-menu-buffer (error-if-non-existent-p)
 149   "Return buffer described by this line of buffer menu."
 150   (let* ((where (save-excursion
 151                   (beginning-of-line)
 152                   (+ (point) Buffer-menu-buffer-column)))
 153          (name (and (not (eobp)) (get-text-property where 'buffer-name))))
 154     (if name
 155         (or (get-buffer name)
 156             (if error-if-non-existent-p
 157                 (error "No buffer named `%s'" name)
 158               nil))
 159       (if error-if-non-existent-p
 160           (error "No buffer on this line")
 161         nil))))
 162 \f
 163 (defun buffer-menu (&optional arg)
 164   "Make a menu of buffers so you can save, delete or select them.
 165 With argument, show only buffers that are visiting files.
 166 Type ? after invocation to get help on commands available.
 167 Type q immediately to make the buffer menu go away."
 168   (interactive "P")
 169 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 170   (switch-to-buffer (list-buffers-noselect arg))
 171   (message
 172    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 173
 174 (defun buffer-menu-other-window (&optional arg)
 175   "Display a list of buffers in another window.
 176 With the buffer list buffer, you can save, delete or select the buffers.
 177 With argument, show only buffers that are visiting files.
 178 Type ? after invocation to get help on commands available.
 179 Type q immediately to make the buffer menu go away."
 180   (interactive "P")
 181 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 182   (switch-to-buffer-other-window (list-buffers-noselect arg))
 183   (message
 184    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 185
 186 (defun Buffer-menu-quit ()
 187   "Quit the buffer menu."
 188   (interactive)
 189   (let ((buffer (current-buffer)))
 190     ;; Switch away from the buffer menu and bury it.
 191     (switch-to-buffer (other-buffer))
 192     (bury-buffer buffer)))
 193
 194 (defun Buffer-menu-mark ()
 195   "Mark buffer on this line for being displayed by \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 196   (interactive)
 197   (beginning-of-line)
 198   (if (looking-at " [-M]")
 199       (ding)
 200     (let ((buffer-read-only nil))
 201       (delete-char 1)
 202       (insert ?>)
 203       (forward-line 1))))
 204
 205 (defun Buffer-menu-unmark (&optional backup)
 206   "Cancel all requested operations on buffer on this line and move down.
 207 Optional ARG means move up."
 208   (interactive "P")
 209   (beginning-of-line)
 210   (if (looking-at " [-M]")
 211       (ding)
 212     (let* ((buf (Buffer-menu-buffer t))
 213            (mod (buffer-modified-p buf))
 214            (readonly (save-excursion (set-buffer buf) buffer-read-only))
 215            (buffer-read-only nil))
 216       (delete-char 3)
 217       (insert (if readonly (if mod " *%" "  %") (if mod " * " "   ")))))
 218   (forward-line (if backup -1 1)))
 219
 220 (defun Buffer-menu-backup-unmark ()
 221   "Move up and cancel all requested operations on buffer on line above."
 222   (interactive)
 223   (forward-line -1)
 224   (Buffer-menu-unmark)
 225   (forward-line -1))
 226
 227 (defun Buffer-menu-delete (&optional arg)
 228   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command.
 229 Prefix arg is how many buffers to delete.
 230 Negative arg means delete backwards."
 231   (interactive "p")
 232   (beginning-of-line)
 233   (if (looking-at " [-M]")              ;header lines
 234       (ding)
 235     (let ((buffer-read-only nil))
 236       (if (or (null arg) (= arg 0))
 237           (setq arg 1))
 238       (while (> arg 0)
 239         (delete-char 1)
 240         (insert ?D)
 241         (forward-line 1)
 242         (setq arg (1- arg)))
 243       (while (< arg 0)
 244         (delete-char 1)
 245         (insert ?D)
 246         (forward-line -1)
 247         (setq arg (1+ arg))))))
 248
 249 (defun Buffer-menu-delete-backwards (&optional arg)
 250   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command
 251 and then move up one line.  Prefix arg means move that many lines."
 252   (interactive "p")
 253   (Buffer-menu-delete (- (or arg 1)))
 254   (while (looking-at " [-M]")
 255     (forward-line 1)))
 256
 257 (defun Buffer-menu-save ()
 258   "Mark buffer on this line to be saved by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 259   (interactive)
 260   (beginning-of-line)
 261   (if (looking-at " [-M]")              ;header lines
 262       (ding)
 263     (let ((buffer-read-only nil))
 264       (forward-char 1)
 265       (delete-char 1)
 266       (insert ?S)
 267       (forward-line 1))))
 268
 269 (defun Buffer-menu-not-modified (&optional arg)
 270   "Mark buffer on this line as unmodified (no changes to save)."
 271   (interactive "P")
 272   (save-excursion
 273     (set-buffer (Buffer-menu-buffer t))
 274     (set-buffer-modified-p arg))
 275   (save-excursion
 276    (beginning-of-line)
 277    (forward-char 1)
 278    (if (= (char-after (point)) (if arg ?  ?*))
 279        (let ((buffer-read-only nil))
 280          (delete-char 1)
 281          (insert (if arg ?* ? ))))))
 282
 283 (defun Buffer-menu-execute ()
 284   "Save and/or delete buffers marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-save] or \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
 285   (interactive)
 286   (save-excursion
 287     (goto-char (point-min))
 288     (forward-line 1)
 289     (while (re-search-forward "^.S" nil t)
 290       (let ((modp nil))
 291         (save-excursion
 292           (set-buffer (Buffer-menu-buffer t))
 293           (save-buffer)
 294           (setq modp (buffer-modified-p)))
 295         (let ((buffer-read-only nil))
 296           (delete-char -1)
 297           (insert (if modp ?* ? ))))))
 298   (save-excursion
 299     (goto-char (point-min))
 300     (forward-line 1)
 301     (let ((buff-menu-buffer (current-buffer))
 302           (buffer-read-only nil))
 303       (while (search-forward "\nD" nil t)
 304         (forward-char -1)
 305         (let ((buf (Buffer-menu-buffer nil)))
 306           (or (eq buf nil)
 307               (eq buf buff-menu-buffer)
 308               (save-excursion (kill-buffer buf))))
 309         (if (Buffer-menu-buffer nil)
 310             (progn (delete-char 1)
 311                    (insert ? ))
 312           (delete-region (point) (progn (forward-line 1) (point)))
 313           (forward-char -1))))))
 314
 315 (defun Buffer-menu-select ()
 316   "Select this line's buffer; also display buffers marked with `>'.
 317 You can mark buffers with the \\<Buffer-menu-mode-map>\\[Buffer-menu-mark] command.
 318 This command deletes and replaces all the previously existing windows
 319 in the selected frame."
 320   (interactive)
 321   (let ((buff (Buffer-menu-buffer t))
 322         (menu (current-buffer))
 323         (others ())
 324         tem)
 325     (goto-char (point-min))
 326     (while (search-forward "\n>" nil t)
 327       (setq tem (Buffer-menu-buffer t))
 328       (let ((buffer-read-only nil))
 329         (delete-char -1)
 330         (insert ?\ ))
 331       (or (eq tem buff) (memq tem others) (setq others (cons tem others))))
 332     (setq others (nreverse others)
 333           tem (/ (1- (frame-height)) (1+ (length others))))
 334     (delete-other-windows)
 335     (switch-to-buffer buff)
 336     (or (eq menu buff)
 337         (bury-buffer menu))
 338     (if (equal (length others) 0)
 339         (progn
 340 ;;;       ;; Restore previous window configuration before displaying
 341 ;;;       ;; selected buffers.
 342 ;;;       (if Buffer-menu-window-config
 343 ;;;           (progn
 344 ;;;             (set-window-configuration Buffer-menu-window-config)
 345 ;;;             (setq Buffer-menu-window-config nil)))
 346           (switch-to-buffer buff))
 347       (while others
 348         (split-window nil tem)
 349         (other-window 1)
 350         (switch-to-buffer (car others))
 351         (setq others (cdr others)))
 352       (other-window 1)                          ;back to the beginning!
 353 )))
 354
 355
 356 \f
 357 (defun Buffer-menu-visit-tags-table ()
 358   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 359   (interactive)
 360   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 361     (if file
 362         (visit-tags-table file)
 363       (error "Specified buffer has no file"))))
 364
 365 (defun Buffer-menu-1-window ()
 366   "Select this line's buffer, alone, in full frame."
 367   (interactive)
 368   (switch-to-buffer (Buffer-menu-buffer t))
 369   (bury-buffer (other-buffer))
 370   (delete-other-windows))
 371
 372 (defun Buffer-menu-mouse-select (event)
 373   "Select the buffer whose line you click on."
 374   (interactive "e")
 375   (let (buffer)
 376     (save-excursion
 377       (set-buffer (window-buffer (posn-window (event-end event))))
 378       (save-excursion
 379         (goto-char (posn-point (event-end event)))
 380         (setq buffer (Buffer-menu-buffer t))))
 381     (select-window (posn-window (event-end event)))
 382     (if (and (window-dedicated-p (selected-window))
 383              (eq (selected-window) (frame-root-window)))
 384         (switch-to-buffer-other-frame buffer)
 385       (switch-to-buffer buffer))))
 386
 387 (defun Buffer-menu-this-window ()
 388   "Select this line's buffer in this window."
 389   (interactive)
 390   (switch-to-buffer (Buffer-menu-buffer t)))
 391
 392 (defun Buffer-menu-other-window ()
 393   "Select this line's buffer in other window, leaving buffer menu visible."
 394   (interactive)
 395   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 396
 397 (defun Buffer-menu-switch-other-window ()
 398   "Make the other window select this line's buffer.
 399 The current window remains selected."
 400   (interactive)
 401   (display-buffer (Buffer-menu-buffer t)))
 402
 403 (defun Buffer-menu-2-window ()
 404   "Select this line's buffer, with previous buffer in second window."
 405   (interactive)
 406   (let ((buff (Buffer-menu-buffer t))
 407         (menu (current-buffer))
 408         (pop-up-windows t))
 409     (delete-other-windows)
 410     (switch-to-buffer (other-buffer))
 411     (pop-to-buffer buff)
 412     (bury-buffer menu)))
 413
 414 (defun Buffer-menu-toggle-read-only ()
 415   "Toggle read-only status of buffer on this line, perhaps via version control."
 416   (interactive)
 417   (let (char)
 418     (save-excursion
 419       (set-buffer (Buffer-menu-buffer t))
 420       (vc-toggle-read-only)
 421       (setq char (if buffer-read-only ?% ? )))
 422     (save-excursion
 423       (beginning-of-line)
 424       (forward-char 2)
 425       (if (/= (following-char) char)
 426           (let (buffer-read-only)
 427             (delete-char 1)
 428             (insert char))))))
 429
 430 (defun Buffer-menu-bury ()
 431   "Bury the buffer listed on this line."
 432   (interactive)
 433   (beginning-of-line)
 434   (if (looking-at " [-M]")              ;header lines
 435       (ding)
 436     (save-excursion
 437       (beginning-of-line)
 438       (bury-buffer (Buffer-menu-buffer t))
 439       (let ((line (buffer-substring (point) (progn (forward-line 1) (point))))
 440             (buffer-read-only nil))
 441         (delete-region (point) (progn (forward-line -1) (point)))
 442         (goto-char (point-max))
 443         (insert line))
 444       (message "Buried buffer moved to the end"))))
 445 \f
 446
 447 (define-key ctl-x-map "\C-b" 'list-buffers)
 448
 449 (defun list-buffers (&optional files-only)
 450   "Display a list of names of existing buffers.
 451 The list is displayed in a buffer named `*Buffer List*'.
 452 Note that buffers with names starting with spaces are omitted.
 453 Non-null optional arg FILES-ONLY means mention only file buffers.
 454
 455 The M column contains a * for buffers that are modified.
 456 The R column contains a % for buffers that are read-only."
 457   (interactive "P")
 458   (display-buffer (list-buffers-noselect files-only)))
 459
 460 (defun list-buffers-noselect (&optional files-only)
 461   "Create and return a buffer with a list of names of existing buffers.
 462 The buffer is named `*Buffer List*'.
 463 Note that buffers with names starting with spaces are omitted.
 464 Non-null optional arg FILES-ONLY means mention only file buffers.
 465
 466 The M column contains a * for buffers that are modified.
 467 The R column contains a % for buffers that are read-only."
 468   (let ((old-buffer (current-buffer))
 469         (standard-output standard-output)
 470         desired-point)
 471     (save-excursion
 472       (set-buffer (get-buffer-create "*Buffer List*"))
 473       (setq buffer-read-only nil)
 474       (erase-buffer)
 475       (setq standard-output (current-buffer))
 476       (princ "\
 477  MR Buffer           Size  Mode         File
 478  -- ------           ----  ----         ----
 479 ")
 480       ;; Record the column where buffer names start.
 481       (setq Buffer-menu-buffer-column 4)
 482       (let ((bl (buffer-list)))
 483         (while bl
 484           (let* ((buffer (car bl))
 485                  (name (buffer-name buffer))
 486                  (file (buffer-file-name buffer))
 487                  this-buffer-line-start
 488                  this-buffer-read-only
 489                  this-buffer-size
 490                  this-buffer-mode-name
 491                  this-buffer-directory)
 492             (save-excursion
 493               (set-buffer buffer)
 494               (setq this-buffer-read-only buffer-read-only)
 495               (setq this-buffer-size (buffer-size))
 496               (setq this-buffer-mode-name
 497                     (if (eq buffer standard-output)
 498                         "Buffer Menu" mode-name))
 499               (or file
 500                   ;; No visited file.  Check local value of
 501                   ;; list-buffers-directory.
 502                   (if (and (boundp 'list-buffers-directory)
 503                            list-buffers-directory)
 504                       (setq this-buffer-directory list-buffers-directory))))
 505             (cond
 506              ;; Don't mention internal buffers.
 507              ((string= (substring name 0 1) " "))
 508              ;; Maybe don't mention buffers without files.
 509              ((and files-only (not file)))
 510              ;; Otherwise output info.
 511              (t
 512               (setq this-buffer-line-start (point))
 513               ;; Identify current buffer.
 514               (if (eq buffer old-buffer)
 515                   (progn
 516                     (setq desired-point (point))
 517                     (princ "."))
 518                 (princ " "))
 519               ;; Identify modified buffers.
 520               (princ (if (buffer-modified-p buffer) "*" " "))
 521               ;; Handle readonly status.  The output buffer is special
 522               ;; cased to appear readonly; it is actually made so at a later
 523               ;; date.
 524               (princ (if (or (eq buffer standard-output)
 525                              this-buffer-read-only)
 526                          "% "
 527                        "  "))
 528               (princ name)
 529               ;; Put the buffer name into a text property
 530               ;; so we don't have to extract it from the text.
 531               ;; This way we avoid problems with unusual buffer names.
 532               (setq this-buffer-line-start
 533                     (+ this-buffer-line-start Buffer-menu-buffer-column))
 534               (let ((name-end (point)))
 535                 (indent-to 17 2)
 536                 (put-text-property this-buffer-line-start name-end
 537                                    'buffer-name name)
 538                 (put-text-property this-buffer-line-start name-end
 539                                    'mouse-face 'highlight))
 540               (let (size
 541                     mode
 542                     (excess (- (current-column) 17)))
 543                 (setq size (format "%8d" this-buffer-size))
 544                 ;; Ack -- if looking at the *Buffer List* buffer,
 545                 ;; always use "Buffer Menu" mode.  Otherwise the
 546                 ;; first time the buffer is created, the mode will be wrong.
 547                 (setq mode this-buffer-mode-name)
 548                 (while (and (> excess 0) (= (aref size 0) ?\ ))
 549                   (setq size (substring size 1))
 550                   (setq excess (1- excess)))
 551                 (princ size)
 552                 (indent-to 27 1)
 553                 (princ mode))
 554               (indent-to 40 1)
 555               (or file (setq file this-buffer-directory))
 556               (if file
 557                   (princ file))
 558               (princ "\n"))))
 559           (setq bl (cdr bl))))
 560       (Buffer-menu-mode)
 561       ;; DESIRED-POINT doesn't have to be set; it is not when the
 562       ;; current buffer is not displayed for some reason.
 563       (and desired-point
 564            (goto-char desired-point))
 565       (current-buffer))))
 566
 567 ;;; buff-menu.el ends here