lisp/paren.el

   1 ;;; paren.el --- highlight matching paren
   2
   3 ;; Copyright (C) 1993, 1996, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: rms@gnu.org
   6 ;; Maintainer: FSF
   7 ;; Keywords: languages, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Put this into your ~/.emacs:
  29
  30 ;;  (show-paren-mode t)
  31
  32 ;; It will display highlighting on whatever paren matches the one
  33 ;; before or after point.
  34
  35 ;;; Code:
  36
  37 (defgroup paren-showing nil
  38   "Showing (un)matching of parens and expressions."
  39   :prefix "show-paren-"
  40   :group 'paren-matching)
  41
  42 ;; This is the overlay used to highlight the matching paren.
  43 (defvar show-paren-overlay nil)
  44 ;; This is the overlay used to highlight the closeparen right before point.
  45 (defvar show-paren-overlay-1 nil)
  46
  47 (defcustom show-paren-style 'parenthesis
  48   "*Style used when showing a matching paren.
  49 Valid styles are `parenthesis' (meaning show the matching paren),
  50 `expression' (meaning show the entire expression enclosed by the paren) and
  51 `mixed' (meaning show the matching paren if it is visible, and the expression
  52 otherwise)."
  53   :type '(choice (const parenthesis) (const expression) (const mixed))
  54   :group 'paren-showing)
  55
  56 (defcustom show-paren-delay
  57   (if (featurep 'lisp-float-type) (/ (float 1) (float 8)) 1)
  58   "*Time in seconds to delay before showing a matching paren."
  59   :type '(number :tag "seconds")
  60   :group 'paren-showing)
  61
  62 (defcustom show-paren-priority 1000
  63   "*Priority of paren highlighting overlays."
  64   :type 'integer
  65   :group 'paren-showing
  66   :version "21.1")
  67
  68 (defcustom show-paren-ring-bell-on-mismatch nil
  69   "*If non-nil, beep if mismatched paren is detected."
  70   :type 'boolean
  71   :group 'paren-showing
  72   :version "20.3")
  73
  74 (defface show-paren-match-face
  75   '((((class color) (background light))
  76      :background "turquoise")           ; looks OK on tty (becomes cyan)
  77     (((class color) (background dark))
  78      :background "steelblue3")          ; looks OK on tty (becomes blue)
  79     (((background dark))
  80      :background "grey50")
  81     (t
  82      :background "gray"))
  83   "Show Paren mode face used for a matching paren."
  84   :group 'faces
  85   :group 'paren-showing)
  86
  87 (defface show-paren-mismatch-face
  88   '((((class color)) (:foreground "white" :background "purple"))
  89     (t (:reverse-video t)))
  90   "Show Paren mode face used for a mismatching paren."
  91   :group 'faces
  92   :group 'paren-showing)
  93
  94 (defvar show-paren-idle-timer nil)
  95
  96 ;;;###autoload
  97 (define-minor-mode show-paren-mode
  98   "Toggle Show Paren mode.
  99 With prefix ARG, turn Show Paren mode on if and only if ARG is positive.
 100 Returns the new status of Show Paren mode (non-nil means on).
 101
 102 When Show Paren mode is enabled, any matching parenthesis is highlighted
 103 in `show-paren-style' after `show-paren-delay' seconds of Emacs idle time."
 104   :global t :group 'paren-showing
 105     ;; Turn off the usual paren-matching method
 106     ;; when this one is turned on.
 107     (if (local-variable-p 'show-paren-mode)
 108         (make-local-variable 'blink-matching-paren-on-screen)
 109       (kill-local-variable 'blink-matching-paren-on-screen))
 110     (setq blink-matching-paren-on-screen (not show-paren-mode))
 111
 112     ;; Now enable or disable the mechanism.
 113     ;; First get rid of the old idle timer.
 114     (if show-paren-idle-timer
 115         (cancel-timer show-paren-idle-timer))
 116     (setq show-paren-idle-timer nil)
 117     ;; If show-paren-mode is enabled in some buffer now,
 118     ;; set up a new timer.
 119     (when (memq t (mapcar (lambda (buffer)
 120                             (with-current-buffer buffer
 121                               show-paren-mode))
 122                           (buffer-list)))
 123       (setq show-paren-idle-timer (run-with-idle-timer
 124                                    show-paren-delay t
 125                                    'show-paren-function)))
 126     (unless show-paren-mode
 127       (and show-paren-overlay
 128            (eq (overlay-buffer show-paren-overlay) (current-buffer))
 129            (delete-overlay show-paren-overlay))
 130       (and show-paren-overlay-1
 131            (eq (overlay-buffer show-paren-overlay-1) (current-buffer))
 132            (delete-overlay show-paren-overlay-1))))
 133
 134 ;; Find the place to show, if there is one,
 135 ;; and show it until input arrives.
 136 (defun show-paren-function ()
 137   (if show-paren-mode
 138       (let (pos dir mismatch face (oldpos (point)))
 139         (cond ((eq (char-syntax (preceding-char)) ?\))
 140                (setq dir -1))
 141               ((eq (char-syntax (following-char)) ?\()
 142                (setq dir 1)))
 143         ;;
 144         ;; Find the other end of the sexp.
 145         (when dir
 146           (save-excursion
 147             (save-restriction
 148               ;; Determine the range within which to look for a match.
 149               (when blink-matching-paren-distance
 150                 (narrow-to-region
 151                  (max (point-min) (- (point) blink-matching-paren-distance))
 152                  (min (point-max) (+ (point) blink-matching-paren-distance))))
 153               ;; Scan across one sexp within that range.
 154               ;; Errors or nil mean there is a mismatch.
 155               (condition-case ()
 156                   (setq pos (scan-sexps (point) dir))
 157                 (error (setq pos t mismatch t)))
 158               ;; If found a "matching" paren, see if it is the right
 159               ;; kind of paren to match the one we started at.
 160               (when (integerp pos)
 161                 (let ((beg (min pos oldpos)) (end (max pos oldpos)))
 162                   (when (/= (char-syntax (char-after beg)) ?\$)
 163                     (setq mismatch
 164                           (not (eq (char-before end)
 165                                    ;; This can give nil.
 166                                    (matching-paren (char-after beg)))))))))))
 167         ;;
 168         ;; Highlight the other end of the sexp, or unhighlight if none.
 169         (if (not pos)
 170             (progn
 171               ;; If not at a paren that has a match,
 172               ;; turn off any previous paren highlighting.
 173               (and show-paren-overlay (overlay-buffer show-paren-overlay)
 174                    (delete-overlay show-paren-overlay))
 175               (and show-paren-overlay-1 (overlay-buffer show-paren-overlay-1)
 176                    (delete-overlay show-paren-overlay-1)))
 177           ;;
 178           ;; Use the correct face.
 179           (if mismatch
 180               (progn
 181                 (if show-paren-ring-bell-on-mismatch
 182                     (beep))
 183                 (setq face 'show-paren-mismatch-face))
 184             (setq face 'show-paren-match-face))
 185           ;;
 186           ;; If matching backwards, highlight the closeparen
 187           ;; before point as well as its matching open.
 188           ;; If matching forward, and the openparen is unbalanced,
 189           ;; highlight the paren at point to indicate misbalance.
 190           ;; Otherwise, turn off any such highlighting.
 191           (if (and (= dir 1) (integerp pos))
 192               (when (and show-paren-overlay-1
 193                          (overlay-buffer show-paren-overlay-1))
 194                 (delete-overlay show-paren-overlay-1))
 195             (let ((from (if (= dir 1)
 196                             (point)
 197                           (forward-point -1)))
 198                   (to (if (= dir 1)
 199                           (forward-point 1)
 200                         (point))))
 201               (if show-paren-overlay-1
 202                   (move-overlay show-paren-overlay-1 from to (current-buffer))
 203                 (setq show-paren-overlay-1 (make-overlay from to)))
 204               ;; Always set the overlay face, since it varies.
 205               (overlay-put show-paren-overlay-1 'priority show-paren-priority)
 206               (overlay-put show-paren-overlay-1 'face face)))
 207           ;;
 208           ;; Turn on highlighting for the matching paren, if found.
 209           ;; If it's an unmatched paren, turn off any such highlighting.
 210           (unless (integerp pos)
 211             (delete-overlay show-paren-overlay))
 212           (let ((to (if (or (eq show-paren-style 'expression)
 213                             (and (eq show-paren-style 'mixed)
 214                                  (not (pos-visible-in-window-p pos))))
 215                         (point)
 216                       pos))
 217                 (from (if (or (eq show-paren-style 'expression)
 218                               (and (eq show-paren-style 'mixed)
 219                                    (not (pos-visible-in-window-p pos))))
 220                           pos
 221                         (save-excursion
 222                           (goto-char pos)
 223                           (forward-point (- dir))))))
 224             (if show-paren-overlay
 225                 (move-overlay show-paren-overlay from to (current-buffer))
 226               (setq show-paren-overlay (make-overlay from to))))
 227           ;;
 228           ;; Always set the overlay face, since it varies.
 229           (overlay-put show-paren-overlay 'priority show-paren-priority)
 230           (overlay-put show-paren-overlay 'face face)))
 231     ;; show-paren-mode is nil in this buffer.
 232     (and show-paren-overlay
 233          (delete-overlay show-paren-overlay))
 234     (and show-paren-overlay-1
 235          (delete-overlay show-paren-overlay-1))))
 236
 237 (provide 'paren)
 238
 239 ;;; paren.el ends here