lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: multimedia
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29
  30 (defgroup image ()
  31   "Image support."
  32   :group 'multimedia)
  33
  34
  35 (defconst image-type-regexps
  36   '(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  37     ("\\`P[1-6]" . pbm)
  38     ("\\`GIF8" . gif)
  39     ("\\`\211PNG\r\n" . png)
  40     ("\\`[\t\n\r ]*#define" . xbm)
  41     ("\\`\\(MM\0\\*\\|II\\*\0\\)" . tiff)
  42     ("\\`[\t\n\r ]*%!PS" . postscript)
  43     ("\\`\xff\xd8" . (image-jpeg-p . jpeg)))
  44   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  45 When the first bytes of an image file match REGEXP, it is assumed to
  46 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  47 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  48 with one argument, a string containing the image data.  If PREDICATE returns
  49 a non-nil value, TYPE is the image's type ")
  50
  51
  52 (defun image-jpeg-p (data)
  53   "Value is non-nil if DATA, a string, consists of JFIF image data."
  54   (when (string-match "\\`\xff\xd8" data)
  55     (catch 'jfif
  56       (let ((len (length data)) (i 2))
  57         (while (< i len)
  58           (when (/= (aref data i) #xff)
  59             (throw 'jfif nil))
  60           (setq i (1+ i))
  61           (when (>= (+ i 2) len)
  62             (throw 'jfif nil))
  63           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
  64                            (aref data (+ i 2))))
  65                 (code (aref data i)))
  66             (when (and (>= code #xe0) (<= code #xef))
  67               ;; APP0 LEN1 LEN2 "JFIF\0"
  68               (throw 'jfif
  69                      (string-match "JFIF" (substring data i (+ i nbytes)))))
  70             (setq i (+ i 1 nbytes))))))))
  71
  72
  73 ;;;###autoload
  74 (defun image-type-from-data (data)
  75   "Determine the image type from image data DATA.
  76 Value is a symbol specifying the image type or nil if type cannot
  77 be determined."
  78   (let ((types image-type-regexps)
  79         type)
  80     (while (and types (null type))
  81       (let ((regexp (car (car types)))
  82             (image-type (cdr (car types))))
  83         (when (or (and (symbolp image-type)
  84                        (string-match regexp data))
  85                   (and (consp image-type)
  86                        (funcall (car image-type) data)
  87                        (setq image-type (cdr image-type))))
  88           (setq type image-type))
  89         (setq types (cdr types))))
  90     type))
  91
  92
  93 ;;;###autoload
  94 (defun image-type-from-file-header (file)
  95   "Determine the type of image file FILE from its first few bytes.
  96 Value is a symbol specifying the image type, or nil if type cannot
  97 be determined."
  98   (unless (file-name-directory file)
  99     (setq file (expand-file-name file data-directory)))
 100   (setq file (expand-file-name file))
 101   (let ((header (with-temp-buffer
 102                   (insert-file-contents-literally file nil 0 256)
 103                   (buffer-string))))
 104     (image-type-from-data header)))
 105
 106
 107 ;;;###autoload
 108 (defun image-type-available-p (type)
 109   "Value is non-nil if image type TYPE is available.
 110 Image types are symbols like `xbm' or `jpeg'."
 111   (and (boundp 'image-types) (not (null (memq type image-types)))))
 112
 113
 114 ;;;###autoload
 115 (defun create-image (file-or-data &optional type data-p &rest props)
 116   "Create an image.
 117 FILE-OR-DATA is an image file name or image data.
 118 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 119 or nil, try to determine the image type from its first few bytes
 120 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 121 use its file extension as image type.
 122 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 123 Optional PROPS are additional image attributes to assign to the image,
 124 like, e.g. `:mask MASK'.
 125 Value is the image created, or nil if images of type TYPE are not supported."
 126   (when (and (not data-p) (not (stringp file-or-data)))
 127     (error "Invalid image file name `%s'" file-or-data))
 128   (cond ((null data-p)
 129          ;; FILE-OR-DATA is a file name.
 130          (unless (or type
 131                      (setq type (image-type-from-file-header file-or-data)))
 132            (let ((extension (file-name-extension file-or-data)))
 133              (unless extension
 134                (error "Cannot determine image type"))
 135              (setq type (intern extension)))))
 136         (t
 137          ;; FILE-OR-DATA contains image data.
 138          (unless type
 139            (setq type (image-type-from-data file-or-data)))))
 140   (unless type
 141     (error "Cannot determine image type"))
 142   (unless (symbolp type)
 143     (error "Invalid image type `%s'" type))
 144   (when (image-type-available-p type)
 145     (append (list 'image :type type (if data-p :data :file) file-or-data)
 146             props)))
 147
 148
 149 ;;;###autoload
 150 (defun put-image (image pos &optional string area)
 151   "Put image IMAGE in front of POS in the current buffer.
 152 IMAGE must be an image created with `create-image' or `defimage'.
 153 IMAGE is displayed by putting an overlay into the current buffer with a
 154 `before-string' STRING that has a `display' property whose value is the
 155 image.  STRING is defaulted if you omit it.
 156 POS may be an integer or marker.
 157 AREA is where to display the image.  AREA nil or omitted means
 158 display it in the text area, a value of `left-margin' means
 159 display it in the left marginal area, a value of `right-margin'
 160 means display it in the right marginal area."
 161   (unless string (setq string "x"))
 162   (let ((buffer (current-buffer)))
 163     (unless (eq (car-safe image) 'image)
 164       (error "Not an image: %s" image))
 165     (unless (or (null area) (memq area '(left-margin right-margin)))
 166       (error "Invalid area %s" area))
 167     (setq string (copy-sequence string))
 168     (let ((overlay (make-overlay pos pos buffer))
 169           (prop (if (null area) image (list (list 'margin area) image))))
 170       (put-text-property 0 (length string) 'display prop string)
 171       (overlay-put overlay 'put-image t)
 172       (overlay-put overlay 'before-string string))))
 173
 174
 175 ;;;###autoload
 176 (defun insert-image (image &optional string area)
 177   "Insert IMAGE into current buffer at point.
 178 IMAGE is displayed by inserting STRING into the current buffer
 179 with a `display' property whose value is the image.  STRING is
 180 defaulted if you omit it.
 181 AREA is where to display the image.  AREA nil or omitted means
 182 display it in the text area, a value of `left-margin' means
 183 display it in the left marginal area, a value of `right-margin'
 184 means display it in the right marginal area."
 185   ;; Use a space as least likely to cause trouble when it's a hidden
 186   ;; character in the buffer.
 187   (unless string (setq string " "))
 188   (unless (eq (car-safe image) 'image)
 189     (error "Not an image: %s" image))
 190   (unless (or (null area) (memq area '(left-margin right-margin)))
 191     (error "Invalid area %s" area))
 192   (if area
 193       (setq image (list (list 'margin area) image))
 194     ;; Cons up a new spec equal but not eq to `image' so that
 195     ;; inserting it twice in a row (adjacently) displays two copies of
 196     ;; the image.  Don't try to avoid this by looking at the display
 197     ;; properties on either side so that we DTRT more often with
 198     ;; cut-and-paste.  (Yanking killed image text next to another copy
 199     ;; of it loses anyway.)
 200     (setq image (cons 'image (cdr image))))
 201   (let ((start (point)))
 202     (insert string)
 203     (add-text-properties start (point)
 204                          (list 'display image
 205                                ;; `image' has the right properties to
 206                                ;; mark an intangible field.
 207                                'intangible image
 208                                'rear-nonsticky (list 'display)))))
 209
 210
 211 ;;;###autoload
 212 (defun remove-images (start end &optional buffer)
 213   "Remove images between START and END in BUFFER.
 214 Remove only images that were put in BUFFER with calls to `put-image'.
 215 BUFFER nil or omitted means use the current buffer."
 216   (unless buffer
 217     (setq buffer (current-buffer)))
 218   (let ((overlays (overlays-in start end)))
 219     (while overlays
 220       (let ((overlay (car overlays)))
 221         (when (overlay-get overlay 'put-image)
 222           (delete-overlay overlay)))
 223       (setq overlays (cdr overlays)))))
 224
 225
 226 ;;;###autoload
 227 (defun find-image (specs)
 228   "Find an image, choosing one of a list of image specifications.
 229
 230 SPECS is a list of image specifications.
 231
 232 Each image specification in SPECS is a property list.  The contents of
 233 a specification are image type dependent.  All specifications must at
 234 least contain the properties `:type TYPE' and either `:file FILE' or
 235 `:data DATA', where TYPE is a symbol specifying the image type,
 236 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 237 string containing the actual image data.  The specification whose TYPE
 238 is supported, and FILE exists, is used to construct the image
 239 specification to be returned.  Return nil if no specification is
 240 satisfied.
 241
 242 The image is looked for first on `load-path' and then in `data-directory'."
 243   (let (image)
 244     (while (and specs (null image))
 245       (let* ((spec (car specs))
 246              (type (plist-get spec :type))
 247              (data (plist-get spec :data))
 248              (file (plist-get spec :file))
 249              found)
 250         (when (image-type-available-p type)
 251           (cond ((stringp file)
 252                  (let ((path load-path))
 253                    (while (and (not found) path)
 254                      (let ((try-file (expand-file-name file (car path))))
 255                        (when (file-readable-p try-file)
 256                          (setq found try-file)))
 257                      (setq path (cdr path)))
 258                    (unless found
 259                      (let ((try-file (expand-file-name file data-directory)))
 260                        (if (file-readable-p try-file)
 261                            (setq found try-file))))
 262                    (if found
 263                        (setq image
 264                              (cons 'image (plist-put (copy-sequence spec)
 265                                                      :file found))))))
 266                 ((not (null data))
 267                  (setq image (cons 'image spec)))))
 268         (setq specs (cdr specs))))
 269     image))
 270
 271
 272 ;;;###autoload
 273 (defmacro defimage (symbol specs &optional doc)
 274   "Define SYMBOL as an image.
 275
 276 SPECS is a list of image specifications.  DOC is an optional
 277 documentation string.
 278
 279 Each image specification in SPECS is a property list.  The contents of
 280 a specification are image type dependent.  All specifications must at
 281 least contain the properties `:type TYPE' and either `:file FILE' or
 282 `:data DATA', where TYPE is a symbol specifying the image type,
 283 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 284 string containing the actual image data.  The first image
 285 specification whose TYPE is supported, and FILE exists, is used to
 286 define SYMBOL.
 287
 288 Example:
 289
 290    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 291                          (:type xbm :file \"~/test1.xbm\")))"
 292   `(defvar ,symbol (find-image ',specs) ,doc))
 293
 294
 295 (provide 'image)
 296
 297 ;;; image.el ends here