m4/signal_h.m4

   1 # signal_h.m4 serial 18
   2 dnl Copyright (C) 2007-2014 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_SIGNAL_H],
   8 [
   9   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  10   AC_REQUIRE([gl_CHECK_TYPE_SIGSET_T])
  11   gl_NEXT_HEADERS([signal.h])
  12
  13 # AIX declares sig_atomic_t to already include volatile, and C89 compilers
  14 # then choke on 'volatile sig_atomic_t'.  C99 requires that it compile.
  15   AC_CHECK_TYPE([volatile sig_atomic_t], [],
  16     [HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=0], [[
  17 #include <signal.h>
  18     ]])
  19
  20   dnl Ensure the type pid_t gets defined.
  21   AC_REQUIRE([AC_TYPE_PID_T])
  22
  23   AC_REQUIRE([AC_TYPE_UID_T])
  24
  25   dnl Persuade glibc <signal.h> to define sighandler_t.
  26   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  27   AC_CHECK_TYPE([sighandler_t], [], [HAVE_SIGHANDLER_T=0], [[
  28 #include <signal.h>
  29     ]])
  30
  31   dnl Check for declarations of anything we want to poison if the
  32   dnl corresponding gnulib module is not in use.
  33   gl_WARN_ON_USE_PREPARE([[#include <signal.h>
  34     ]], [pthread_sigmask sigaction
  35     sigaddset sigdelset sigemptyset sigfillset sigismember
  36     sigpending sigprocmask])
  37 ])
  38
  39 AC_DEFUN([gl_CHECK_TYPE_SIGSET_T],
  40 [
  41   AC_CHECK_TYPES([sigset_t],
  42     [gl_cv_type_sigset_t=yes], [gl_cv_type_sigset_t=no],
  43     [[
  44       #include <signal.h>
  45       /* Mingw defines sigset_t not in <signal.h>, but in <sys/types.h>.  */
  46       #include <sys/types.h>
  47     ]])
  48   if test $gl_cv_type_sigset_t != yes; then
  49     HAVE_SIGSET_T=0
  50   fi
  51 ])
  52
  53 AC_DEFUN([gl_SIGNAL_MODULE_INDICATOR],
  54 [
  55   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  56   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
  57   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  58   dnl Define it also as a C macro, for the benefit of the unit tests.
  59   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  60 ])
  61
  62 AC_DEFUN([gl_SIGNAL_H_DEFAULTS],
  63 [
  64   GNULIB_PTHREAD_SIGMASK=0;    AC_SUBST([GNULIB_PTHREAD_SIGMASK])
  65   GNULIB_RAISE=0;              AC_SUBST([GNULIB_RAISE])
  66   GNULIB_SIGNAL_H_SIGPIPE=0;   AC_SUBST([GNULIB_SIGNAL_H_SIGPIPE])
  67   GNULIB_SIGPROCMASK=0;        AC_SUBST([GNULIB_SIGPROCMASK])
  68   GNULIB_SIGACTION=0;          AC_SUBST([GNULIB_SIGACTION])
  69   dnl Assume proper GNU behavior unless another module says otherwise.
  70   HAVE_POSIX_SIGNALBLOCKING=1; AC_SUBST([HAVE_POSIX_SIGNALBLOCKING])
  71   HAVE_PTHREAD_SIGMASK=1;      AC_SUBST([HAVE_PTHREAD_SIGMASK])
  72   HAVE_RAISE=1;                AC_SUBST([HAVE_RAISE])
  73   HAVE_SIGSET_T=1;             AC_SUBST([HAVE_SIGSET_T])
  74   HAVE_SIGINFO_T=1;            AC_SUBST([HAVE_SIGINFO_T])
  75   HAVE_SIGACTION=1;            AC_SUBST([HAVE_SIGACTION])
  76   HAVE_STRUCT_SIGACTION_SA_SIGACTION=1;
  77                                AC_SUBST([HAVE_STRUCT_SIGACTION_SA_SIGACTION])
  78   HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=1;
  79                                AC_SUBST([HAVE_TYPE_VOLATILE_SIG_ATOMIC_T])
  80   HAVE_SIGHANDLER_T=1;         AC_SUBST([HAVE_SIGHANDLER_T])
  81   REPLACE_PTHREAD_SIGMASK=0;   AC_SUBST([REPLACE_PTHREAD_SIGMASK])
  82   REPLACE_RAISE=0;             AC_SUBST([REPLACE_RAISE])
  83 ])