lisp/font-core.el

   1 ;;; font-core.el --- Core interface to font-lock
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: languages, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Code:
  25
  26 ;; This variable is used by mode packages that support Font Lock mode by
  27 ;; defining their own keywords to use for `font-lock-keywords'.  (The mode
  28 ;; command should make it buffer-local and set it to provide the set up.)
  29 (defvar font-lock-defaults nil
  30   "Defaults for Font Lock mode specified by the major mode.
  31 Defaults should be of the form:
  32
  33  (KEYWORDS [KEYWORDS-ONLY [CASE-FOLD [SYNTAX-ALIST [SYNTAX-BEGIN ...]]]])
  34
  35 KEYWORDS may be a symbol (a variable or function whose value is the keywords
  36 to use for fontification) or a list of symbols (specifying different levels
  37 of fontification).
  38
  39 If KEYWORDS-ONLY is non-nil, syntactic fontification (strings and
  40 comments) is not performed.
  41
  42 If CASE-FOLD is non-nil, the case of the keywords is ignored when fontifying.
  43
  44 If SYNTAX-ALIST is non-nil, it should be a list of cons pairs of the form
  45 \(CHAR-OR-STRING . STRING) used to set the local Font Lock syntax table, for
  46 keyword and syntactic fontification (see `modify-syntax-entry').
  47
  48 If SYNTAX-BEGIN is non-nil, it should be a function with no args used to move
  49 backwards outside any enclosing syntactic block, for syntactic fontification.
  50 Typical values are `beginning-of-line' (i.e., the start of the line is known to
  51 be outside a syntactic block), or `beginning-of-defun' for programming modes or
  52 `backward-paragraph' for textual modes (i.e., the mode-dependent function is
  53 known to move outside a syntactic block).  If nil, the beginning of the buffer
  54 is used as a position outside of a syntactic block, in the worst case.
  55
  56 \(See also Info node `(elisp)Font Lock Basics'.)
  57
  58 These item elements are used by Font Lock mode to set the variables
  59 `font-lock-keywords', `font-lock-keywords-only',
  60 `font-lock-keywords-case-fold-search', `font-lock-syntax-table' and
  61 `font-lock-beginning-of-syntax-function', respectively.
  62
  63 Further item elements are alists of the form (VARIABLE . VALUE) and are in no
  64 particular order.  Each VARIABLE is made buffer-local before set to VALUE.
  65
  66 Currently, appropriate variables include `font-lock-mark-block-function'.
  67 If this is non-nil, it should be a function with no args used to mark any
  68 enclosing block of text, for fontification via \\[font-lock-fontify-block].
  69 Typical values are `mark-defun' for programming modes or `mark-paragraph' for
  70 textual modes (i.e., the mode-dependent function is known to put point and mark
  71 around a text block relevant to that mode).
  72
  73 Other variables include that for syntactic keyword fontification,
  74 `font-lock-syntactic-keywords' and those for buffer-specialized fontification
  75 functions, `font-lock-fontify-buffer-function',
  76 `font-lock-unfontify-buffer-function', `font-lock-fontify-region-function',
  77 `font-lock-unfontify-region-function', and `font-lock-inhibit-thing-lock'.")
  78 (make-variable-buffer-local 'font-lock-defaults)
  79
  80 (defvar font-lock-defaults-alist nil
  81   "Alist of fall-back Font Lock defaults for major modes.
  82
  83 Each item should be a list of the form:
  84
  85  (MAJOR-MODE . FONT-LOCK-DEFAULTS)
  86
  87 where MAJOR-MODE is a symbol and FONT-LOCK-DEFAULTS is a list of default
  88 settings.  See the variable `font-lock-defaults', which takes precedence.")
  89 (make-obsolete-variable 'font-lock-defaults-alist 'font-lock-defaults "21.1")
  90
  91 (defvar font-lock-function 'font-lock-default-function
  92   "A function which is called when `font-lock-mode' is toggled.
  93 It will be passed one argument, which is the current value of
  94 `font-lock-mode'.")
  95
  96 ;; The mode for which font-lock was initialized, or nil if none.
  97 (defvar font-lock-mode-major-mode)
  98 (define-minor-mode font-lock-mode
  99   "Toggle Font Lock mode.
 100 With arg, turn Font Lock mode off if and only if arg is a non-positive
 101 number; if arg is nil, toggle Font Lock mode; anything else turns Font
 102 Lock on.
 103 \(Font Lock is also known as \"syntax highlighting\".)
 104
 105 When Font Lock mode is enabled, text is fontified as you type it:
 106
 107  - Comments are displayed in `font-lock-comment-face';
 108  - Strings are displayed in `font-lock-string-face';
 109  - Certain other expressions are displayed in other faces according to the
 110    value of the variable `font-lock-keywords'.
 111
 112 To customize the faces (colors, fonts, etc.) used by Font Lock for
 113 fontifying different parts of buffer text, use \\[customize-face].
 114
 115 You can enable Font Lock mode in any major mode automatically by turning on in
 116 the major mode's hook.  For example, put in your ~/.emacs:
 117
 118  (add-hook 'c-mode-hook 'turn-on-font-lock)
 119
 120 Alternatively, you can use Global Font Lock mode to automagically turn on Font
 121 Lock mode in buffers whose major mode supports it and whose major mode is one
 122 of `font-lock-global-modes'.  For example, put in your ~/.emacs:
 123
 124  (global-font-lock-mode t)
 125
 126 Where major modes support different levels of fontification, you can use
 127 the variable `font-lock-maximum-decoration' to specify which level you
 128 generally prefer.  When you turn Font Lock mode on/off the buffer is
 129 fontified/defontified, though fontification occurs only if the buffer is
 130 less than `font-lock-maximum-size'.
 131
 132 To add your own highlighting for some major mode, and modify the highlighting
 133 selected automatically via the variable `font-lock-maximum-decoration', you can
 134 use `font-lock-add-keywords'.
 135
 136 To fontify a buffer, without turning on Font Lock mode and regardless of buffer
 137 size, you can use \\[font-lock-fontify-buffer].
 138
 139 To fontify a block (the function or paragraph containing point, or a number of
 140 lines around point), perhaps because modification on the current line caused
 141 syntactic change on other lines, you can use \\[font-lock-fontify-block].
 142
 143 See the variable `font-lock-defaults-alist' for the Font Lock mode default
 144 settings.  You can set your own default settings for some mode, by setting a
 145 buffer local value for `font-lock-defaults', via its mode hook.
 146
 147 The above is the default behavior of `font-lock-mode'; you may specify
 148 your own function which is called when `font-lock-mode' is toggled via
 149 `font-lock-function'. "
 150   nil nil nil
 151   ;; Don't turn on Font Lock mode if we don't have a display (we're running a
 152   ;; batch job) or if the buffer is invisible (the name starts with a space).
 153   (when (or noninteractive (eq (aref (buffer-name) 0) ?\s))
 154     (setq font-lock-mode nil))
 155   (funcall font-lock-function font-lock-mode)
 156   ;; Arrange to unfontify this buffer if we change major mode later.
 157   (if font-lock-mode
 158       (add-hook 'change-major-mode-hook 'font-lock-change-mode nil t)
 159     (remove-hook 'change-major-mode-hook 'font-lock-change-mode t))
 160   (when font-lock-mode
 161     (setq font-lock-mode-major-mode major-mode)))
 162
 163 ;; Get rid of fontification for the old major mode.
 164 ;; We do this when changing major modes.
 165 (defun font-lock-change-mode ()
 166   (font-lock-mode -1))
 167
 168 (defun font-lock-defontify ()
 169   "Clear out all `font-lock-face' properties in current buffer.
 170 A major mode that uses `font-lock-face' properties might want to put
 171 this function onto `change-major-mode-hook'."
 172   (let ((modp (buffer-modified-p))
 173         (inhibit-read-only t))
 174     (save-restriction
 175       (widen)
 176       (remove-list-of-text-properties (point-min) (point-max)
 177                                       '(font-lock-face)))
 178     (restore-buffer-modified-p modp)))
 179
 180 (defvar font-lock-set-defaults)
 181 (defun font-lock-default-function (mode)
 182   ;; Turn on Font Lock mode.
 183   (when mode
 184     (set (make-local-variable 'char-property-alias-alist)
 185          (copy-tree char-property-alias-alist))
 186     ;; Add `font-lock-face' as an alias for the `face' property.
 187     (let ((elt (assq 'face char-property-alias-alist)))
 188       (if elt
 189           (unless (memq 'font-lock-face (cdr elt))
 190             (setcdr elt (nconc (cdr elt) (list 'font-lock-face))))
 191         (push (list 'face 'font-lock-face) char-property-alias-alist))))
 192   ;; Turn off Font Lock mode.
 193   (unless mode
 194     ;; Remove `font-lock-face' as an alias for the `face' property.
 195     (set (make-local-variable 'char-property-alias-alist)
 196          (copy-tree char-property-alias-alist))
 197     (let ((elt (assq 'face char-property-alias-alist)))
 198       (when elt
 199         (setcdr elt (remq 'font-lock-face (cdr elt)))
 200         (when (null (cdr elt))
 201           (setq char-property-alias-alist
 202                 (delq elt char-property-alias-alist))))))
 203
 204   ;; Only do hard work if the mode has specified stuff in
 205   ;; `font-lock-defaults'.
 206   (when (or font-lock-defaults
 207             (if (boundp 'font-lock-keywords) font-lock-keywords)
 208             (with-no-warnings
 209               (cdr (assq major-mode font-lock-defaults-alist)))
 210             (and mode
 211                  (boundp 'font-lock-set-defaults)
 212                  font-lock-set-defaults
 213                  font-lock-mode-major-mode
 214                  (not (eq font-lock-mode-major-mode major-mode))))
 215     (font-lock-mode-internal mode)))
 216
 217 (defun turn-on-font-lock ()
 218   "Turn on Font Lock mode (only if the terminal can display it)."
 219   (unless font-lock-mode
 220     (font-lock-mode)))
 221
 222 ;;; Global Font Lock mode.
 223
 224 ;; A few people have hassled in the past for a way to make it easier to turn on
 225 ;; Font Lock mode, without the user needing to know for which modes s/he has to
 226 ;; turn it on, perhaps the same way hilit19.el/hl319.el does.  I've always
 227 ;; balked at that way, as I see it as just re-moulding the same problem in
 228 ;; another form.  That is; some person would still have to keep track of which
 229 ;; modes (which may not even be distributed with Emacs) support Font Lock mode.
 230 ;; The list would always be out of date.  And that person might have to be me.
 231
 232 ;; Implementation.
 233 ;;
 234 ;; In a previous discussion the following hack came to mind.  It is a gross
 235 ;; hack, but it generally works.  We use the convention that major modes start
 236 ;; by calling the function `kill-all-local-variables', which in turn runs
 237 ;; functions on the hook variable `change-major-mode-hook'.  We attach our
 238 ;; function `font-lock-change-major-mode' to that hook.  Of course, when this
 239 ;; hook is run, the major mode is in the process of being changed and we do not
 240 ;; know what the final major mode will be.  So, `font-lock-change-major-mode'
 241 ;; only (a) notes the name of the current buffer, and (b) adds our function
 242 ;; `turn-on-font-lock-if-desired' to the hook variables
 243 ;; `after-change-major-mode-hook' and `post-command-hook' (for modes
 244 ;; that do not yet run `after-change-major-mode-hook').  By the time
 245 ;; the functions on the first of these hooks to be run are run, the new major
 246 ;; mode is assumed to be in place.  This way we get a Font Lock function run
 247 ;; when a major mode is turned on, without knowing major modes or their hooks.
 248 ;;
 249 ;; Naturally this requires that major modes run `kill-all-local-variables'
 250 ;; and `after-change-major-mode-hook', as they are supposed to.  For modes
 251 ;; that do not run `after-change-major-mode-hook' yet, `post-command-hook'
 252 ;; takes care of things if the mode is set directly or indirectly by
 253 ;; an interactive command; however, problems can occur if the mode is
 254 ;; set by a timer or process: in that case, proper handling of Font Lock mode
 255 ;; may be delayed until the next interactive command.
 256
 257 ;; User interface.
 258 ;;
 259 ;; Although Global Font Lock mode is a pseudo-mode, I think that the user
 260 ;; interface should conform to the usual Emacs convention for modes, i.e., a
 261 ;; command to toggle the feature (`global-font-lock-mode') with a variable for
 262 ;; finer control of the mode's behavior (`font-lock-global-modes').
 263 ;;
 264 ;; The feature should not be enabled by loading font-lock.el, since other
 265 ;; mechanisms for turning on Font Lock mode, such as M-x font-lock-mode RET or
 266 ;; (add-hook 'c-mode-hook 'turn-on-font-lock), would cause Font Lock mode to be
 267 ;; turned on everywhere.  That would not be intuitive or informative because
 268 ;; loading a file tells you nothing about the feature or how to control it.  It
 269 ;; would also be contrary to the Principle of Least Surprise.  sm.
 270
 271 (defcustom font-lock-global-modes t
 272   "Modes for which Font Lock mode is automagically turned on.
 273 Global Font Lock mode is controlled by the command `global-font-lock-mode'.
 274 If nil, means no modes have Font Lock mode automatically turned on.
 275 If t, all modes that support Font Lock mode have it automatically turned on.
 276 If a list, it should be a list of `major-mode' symbol names for which Font Lock
 277 mode should be automatically turned on.  The sense of the list is negated if it
 278 begins with `not'.  For example:
 279  (c-mode c++-mode)
 280 means that Font Lock mode is turned on for buffers in C and C++ modes only."
 281   :type '(choice (const :tag "none" nil)
 282                  (const :tag "all" t)
 283                  (set :menu-tag "mode specific" :tag "modes"
 284                       :value (not)
 285                       (const :tag "Except" not)
 286                       (repeat :inline t (symbol :tag "mode"))))
 287   :group 'font-lock)
 288
 289 (defun turn-on-font-lock-if-desired ()
 290   (when (cond ((eq font-lock-global-modes t)
 291                t)
 292               ((eq (car-safe font-lock-global-modes) 'not)
 293                (not (memq major-mode (cdr font-lock-global-modes))))
 294               (t (memq major-mode (cdr font-lock-global-modes))))
 295     (let (inhibit-quit)
 296       (turn-on-font-lock))))
 297
 298 (define-globalized-minor-mode global-font-lock-mode
 299   font-lock-mode turn-on-font-lock-if-desired
 300   :extra-args (dummy)
 301   :initialize 'custom-initialize-safe-default
 302   :init-value (not (or noninteractive emacs-basic-display))
 303   :group 'font-lock
 304   :version "22.1")
 305
 306 ;;; End of Global Font Lock mode.
 307
 308 (provide 'font-core)
 309
 310 ;; arch-tag: f8c286e1-02f7-41d9-b89b-1b67780aed71
 311 ;;; font-core.el ends here