lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do `M-x describe-mode'.
  33 ;;
  34 ;; This may be useful in your .emacs:
  35 ;;
  36 ;;      (autoload 'hexl-find-file "hexl"
  37 ;;        "Edit file FILENAME in hexl-mode." t)
  38 ;;
  39 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  40 ;;
  41 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  42 ;;
  43 ;; Currently hexl only supports big endian hex output with 16 bit
  44 ;; grouping.
  45 ;;
  46 ;; -iso in `hexl-options' will allow iso characters to display in the
  47 ;; ASCII region of the screen (if your emacs supports this) instead of
  48 ;; changing them to dots.
  49
  50 ;;; Code:
  51
  52 ;;
  53 ;; vars here
  54 ;;
  55
  56 (defvar hexl-program "hexl"
  57   "The program that will hexlify and dehexlify its stdin.
  58 `hexl-program' will always be concatenated with `hexl-options'
  59 and \"-de\" when dehexlifying a buffer.")
  60
  61 (defvar hexl-iso ""
  62   "If your emacs can handle ISO characters, this should be set to
  63 \"-iso\" otherwise it should be \"\".")
  64
  65 (defvar hexl-options (format "-hex %s" hexl-iso)
  66   "Options to hexl-program that suit your needs.")
  67
  68 (defvar hexlify-command
  69   (format "%s%s %s" exec-directory hexl-program hexl-options)
  70   "The command to use to hexlify a buffer.")
  71
  72 (defvar dehexlify-command
  73   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  74   "The command to use to unhexlify a buffer.")
  75
  76 (defvar hexl-max-address 0
  77   "Maximum offset into hexl buffer.")
  78
  79 (defvar hexl-mode-map nil)
  80
  81 (defvar hexl-mode-old-local-map)
  82 (defvar hexl-mode-old-mode-name)
  83 (defvar hexl-mode-old-major-mode)
  84 (defvar hexl-mode-old-write-contents-hooks)
  85 (defvar hexl-mode-old-require-final-newline)
  86 (defvar hexl-mode-old-syntax-table)
  87
  88 ;; routines
  89
  90 ;;;###autoload
  91 (defun hexl-mode (&optional arg)
  92   "\\<hexl-mode-map>
  93 A major mode for editing binary files in hex dump format.
  94
  95 This function automatically converts a buffer into the hexl format
  96 using the function `hexlify-buffer'.
  97
  98 Each line in the buffer has an \"address\" (displayed in hexadecimal)
  99 representing the offset into the file that the characters on this line
 100 are at and 16 characters from the file (displayed as hexadecimal
 101 values grouped every 16 bits) and as their ASCII values.
 102
 103 If any of the characters (displayed as ASCII characters) are
 104 unprintable (control or meta characters) they will be replaced as
 105 periods.
 106
 107 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 108 in hexl format.
 109
 110 A sample format:
 111
 112   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 113   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 114   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 115   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 116   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 117   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 118   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 119   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 120   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 121   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 122   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 123   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 124   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 125   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 126   000000c0: 7265 6769 6f6e 2e0a                      region..
 127
 128 Movement is as simple as movement in a normal emacs text buffer.  Most
 129 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 130 to move the cursor left, right, down, and up).
 131
 132 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 133 also supported.
 134
 135 There are several ways to change text in hexl mode:
 136
 137 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 138 bound to self-insert so you can simply type the character and it will
 139 insert itself (actually overstrike) into the buffer.
 140
 141 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 142 it isn't bound to self-insert.  An octal number can be supplied in place
 143 of another key to insert the octal number's ASCII representation.
 144
 145 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 146 into the buffer at the current point.
 147
 148 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 149 into the buffer at the current point.
 150
 151 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 152 into the buffer at the current point.
 153
 154 \\[hexl-mode-exit] will exit hexl-mode.
 155
 156 Note: saving the file with any of the usual Emacs commands
 157 will actually convert it back to binary format while saving.
 158
 159 You can use \\[hexl-find-file] to visit a file in hexl-mode.
 160
 161 \\[describe-bindings] for advanced commands."
 162   (interactive "p")
 163   (if (eq major-mode 'hexl-mode)
 164       (error "You are already in hexl mode")
 165
 166     ;; We do not turn off the old major mode; instead we just
 167     ;; override most of it.  That way, we can restore it perfectly.
 168     (make-local-variable 'hexl-mode-old-local-map)
 169     (setq hexl-mode-old-local-map (current-local-map))
 170     (use-local-map hexl-mode-map)
 171
 172     (make-local-variable 'hexl-mode-old-mode-name)
 173     (setq hexl-mode-old-mode-name mode-name)
 174     (setq mode-name "Hexl")
 175
 176     (make-local-variable 'hexl-mode-old-major-mode)
 177     (setq hexl-mode-old-major-mode major-mode)
 178     (setq major-mode 'hexl-mode)
 179
 180     (make-local-variable 'hexl-mode-old-syntax-table)
 181     (setq hexl-mode-old-syntax-table (syntax-table))
 182     (set-syntax-table (standard-syntax-table))
 183
 184     (make-local-variable 'hexl-mode-old-write-contents-hooks)
 185     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
 186     (make-local-variable 'write-contents-hooks)
 187     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 188
 189     (make-local-variable 'hexl-mode-old-require-final-newline)
 190     (setq hexl-mode-old-require-final-newline require-final-newline)
 191     (make-local-variable 'require-final-newline)
 192     (setq require-final-newline nil)
 193
 194     ;; Add hooks to rehexlify or dehexlify on various events.
 195     (make-local-hook 'after-revert-hook)
 196     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 197
 198     (make-local-hook 'change-major-mode-hook)
 199     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 200
 201     (make-local-variable 'hexl-max-address)
 202
 203     (let ((modified (buffer-modified-p))
 204           (inhibit-read-only t)
 205           (original-point (1- (point))))
 206       (and (eobp) (not (bobp))
 207            (setq original-point (1- original-point)))
 208       (if (not (or (eq arg 1) (not arg)))
 209           ;; if no argument then we guess at hexl-max-address
 210           (setq hexl-max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 211         (setq hexl-max-address (1- (buffer-size)))
 212         (hexlify-buffer)
 213         (set-buffer-modified-p modified)
 214         (hexl-goto-address original-point)))))
 215
 216 (defun hexl-after-revert-hook ()
 217   (hexlify-buffer)
 218   (set-buffer-modified-p nil))
 219
 220 (defvar hexl-in-save-buffer nil)
 221
 222 (defun hexl-save-buffer ()
 223   "Save a hexl format buffer as binary in visited file if modified."
 224   (interactive)
 225   (if hexl-in-save-buffer nil
 226     (set-buffer-modified-p (if (buffer-modified-p)
 227                                (save-excursion
 228                                  (let ((buf (generate-new-buffer " hexl"))
 229                                        (name (buffer-name))
 230                                        (file-name (buffer-file-name))
 231                                        (start (point-min))
 232                                        (end (point-max))
 233                                        modified)
 234                                    (set-buffer buf)
 235                                    (insert-buffer-substring name start end)
 236                                    (set-buffer name)
 237                                    (dehexlify-buffer)
 238                                    ;; Prevent infinite recursion.
 239                                    (let ((hexl-in-save-buffer t)
 240                                          (buffer-file-type t)) ; for ms-dos
 241                                      (save-buffer))
 242                                    (setq modified (buffer-modified-p))
 243                                    (delete-region (point-min) (point-max))
 244                                    (insert-buffer-substring buf start end)
 245                                    (kill-buffer buf)
 246                                    modified))
 247                              (message "(No changes need to be saved)")
 248                              nil))
 249     ;; Return t to indicate we have saved t
 250     t))
 251
 252 ;;;###autoload
 253 (defun hexl-find-file (filename)
 254   "Edit file FILENAME in hexl-mode.
 255 Switch to a buffer visiting file FILENAME, creating one in none exists."
 256   (interactive "fFilename: ")
 257   (if (or (eq system-type 'ms-dos) (eq system-type 'windows-nt))
 258       (find-file-binary filename)
 259     (find-file filename))
 260   (if (not (eq major-mode 'hexl-mode))
 261       (hexl-mode)))
 262
 263 (defun hexl-mode-exit (&optional arg)
 264   "Exit Hexl mode, returning to previous mode.
 265 With arg, don't unhexlify buffer."
 266   (interactive "p")
 267   (if (or (eq arg 1) (not arg))
 268       (let ((modified (buffer-modified-p))
 269             (inhibit-read-only t)
 270             (original-point (1+ (hexl-current-address))))
 271         (dehexlify-buffer)
 272         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 273         (set-buffer-modified-p modified)
 274         (goto-char original-point)))
 275
 276   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 277   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 278
 279   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
 280   (setq require-final-newline hexl-mode-old-require-final-newline)
 281   (setq mode-name hexl-mode-old-mode-name)
 282   (use-local-map hexl-mode-old-local-map)
 283   (set-syntax-table hexl-mode-old-syntax-table)
 284   (setq major-mode hexl-mode-old-major-mode)
 285   (force-mode-line-update))
 286
 287 (defun hexl-maybe-dehexlify-buffer ()
 288   "Convert a hexl format buffer to binary.
 289 Ask the user for confirmation."
 290   (if (y-or-n-p "Convert contents back to binary format? ")
 291       (let ((modified (buffer-modified-p))
 292             (inhibit-read-only t)
 293             (original-point (1+ (hexl-current-address))))
 294         (dehexlify-buffer)
 295         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 296         (set-buffer-modified-p modified)
 297         (goto-char original-point))))
 298
 299 (defun hexl-current-address (&optional validate)
 300   "Return current hexl-address."
 301   (interactive)
 302   (let ((current-column (- (% (point) 68) 11))
 303         (hexl-address 0))
 304     (if (< current-column 0)
 305         (if validate
 306             (error "Point is not on a character in the file")
 307           (setq current-column 0)))
 308     (setq hexl-address
 309           (+ (* (/ (point) 68) 16)
 310              (if (>= current-column 41)
 311                  (- current-column 41)
 312                (/ (- current-column  (/ current-column 5)) 2))))
 313     hexl-address))
 314
 315 (defun hexl-address-to-marker (address)
 316   "Return marker for ADDRESS."
 317   (interactive "nAddress: ")
 318   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 319
 320 (defun hexl-goto-address (address)
 321   "Goto hexl-mode (decimal) address ADDRESS.
 322 Signal error if ADDRESS out of range."
 323   (interactive "nAddress: ")
 324   (if (or (< address 0) (> address hexl-max-address))
 325           (error "Out of hexl region."))
 326   (goto-char (hexl-address-to-marker address)))
 327
 328 (defun hexl-goto-hex-address (hex-address)
 329   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 330 Signal error if HEX-ADDRESS is out of range."
 331   (interactive "sHex Address: ")
 332   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 333
 334 (defun hexl-hex-string-to-integer (hex-string)
 335   "Return decimal integer for HEX-STRING."
 336   (interactive "sHex number: ")
 337   (let ((hex-num 0))
 338     (while (not (equal hex-string ""))
 339       (setq hex-num (+ (* hex-num 16)
 340                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 341       (setq hex-string (substring hex-string 1)))
 342     hex-num))
 343
 344 (defun hexl-octal-string-to-integer (octal-string)
 345   "Return decimal integer for OCTAL-STRING."
 346   (interactive "sOctal number: ")
 347   (let ((oct-num 0))
 348     (while (not (equal octal-string ""))
 349       (setq oct-num (+ (* oct-num 8)
 350                        (hexl-oct-char-to-integer
 351                         (string-to-char octal-string))))
 352       (setq octal-string (substring octal-string 1)))
 353     oct-num))
 354
 355 ;; move point functions
 356
 357 (defun hexl-backward-char (arg)
 358   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 359   (interactive "p")
 360   (hexl-goto-address (- (hexl-current-address) arg)))
 361
 362 (defun hexl-forward-char (arg)
 363   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 364   (interactive "p")
 365   (hexl-goto-address (+ (hexl-current-address) arg)))
 366
 367 (defun hexl-backward-short (arg)
 368   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 369   (interactive "p")
 370   (hexl-goto-address (let ((address (hexl-current-address)))
 371                        (if (< arg 0)
 372                            (progn
 373                              (setq arg (- arg))
 374                              (while (> arg 0)
 375                                (if (not (equal address (logior address 3)))
 376                                    (if (> address hexl-max-address)
 377                                        (progn
 378                                          (message "End of buffer.")
 379                                          (setq address hexl-max-address))
 380                                      (setq address (logior address 3)))
 381                                  (if (> address hexl-max-address)
 382                                      (progn
 383                                        (message "End of buffer.")
 384                                        (setq address hexl-max-address))
 385                                    (setq address (+ address 4))))
 386                                (setq arg (1- arg)))
 387                              (if (> address hexl-max-address)
 388                                  (progn
 389                                    (message "End of buffer.")
 390                                    (setq address hexl-max-address))
 391                                (setq address (logior address 3))))
 392                          (while (> arg 0)
 393                            (if (not (equal address (logand address -4)))
 394                                (setq address (logand address -4))
 395                              (if (not (equal address 0))
 396                                  (setq address (- address 4))
 397                                (message "Beginning of buffer.")))
 398                            (setq arg (1- arg))))
 399                        address)))
 400
 401 (defun hexl-forward-short (arg)
 402   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 403   (interactive "p")
 404   (hexl-backward-short (- arg)))
 405
 406 (defun hexl-backward-word (arg)
 407   "Move to left ARG words (right if ARG negative) in hexl-mode."
 408   (interactive "p")
 409   (hexl-goto-address (let ((address (hexl-current-address)))
 410                        (if (< arg 0)
 411                            (progn
 412                              (setq arg (- arg))
 413                              (while (> arg 0)
 414                                (if (not (equal address (logior address 7)))
 415                                    (if (> address hexl-max-address)
 416                                        (progn
 417                                          (message "End of buffer.")
 418                                          (setq address hexl-max-address))
 419                                      (setq address (logior address 7)))
 420                                  (if (> address hexl-max-address)
 421                                      (progn
 422                                        (message "End of buffer.")
 423                                        (setq address hexl-max-address))
 424                                    (setq address (+ address 8))))
 425                                (setq arg (1- arg)))
 426                              (if (> address hexl-max-address)
 427                                  (progn
 428                                    (message "End of buffer.")
 429                                    (setq address hexl-max-address))
 430                                (setq address (logior address 7))))
 431                          (while (> arg 0)
 432                            (if (not (equal address (logand address -8)))
 433                                (setq address (logand address -8))
 434                              (if (not (equal address 0))
 435                                  (setq address (- address 8))
 436                                (message "Beginning of buffer.")))
 437                            (setq arg (1- arg))))
 438                        address)))
 439
 440 (defun hexl-forward-word (arg)
 441   "Move right ARG words (left if ARG negative) in hexl-mode."
 442   (interactive "p")
 443   (hexl-backward-word (- arg)))
 444
 445 (defun hexl-previous-line (arg)
 446   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 447 If there is byte at the target address move to the last byte in that line."
 448   (interactive "p")
 449   (hexl-next-line (- arg)))
 450
 451 (defun hexl-next-line (arg)
 452   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 453 If there is no byte at the target address move to the last byte in that line."
 454   (interactive "p")
 455   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 456                        (if (and (< arg 0) (< address 0))
 457                                 (progn (message "Out of hexl region.")
 458                                        (setq address
 459                                              (% (hexl-current-address) 16)))
 460                          (if (and (> address hexl-max-address)
 461                                   (< (% hexl-max-address 16) (% address 16)))
 462                              (setq address hexl-max-address)
 463                            (if (> address hexl-max-address)
 464                                (progn (message "Out of hexl region.")
 465                                       (setq
 466                                        address
 467                                        (+ (logand hexl-max-address -16)
 468                                           (% (hexl-current-address) 16)))))))
 469                        address)))
 470
 471 (defun hexl-beginning-of-buffer (arg)
 472   "Move to the beginning of the hexl buffer.
 473 Leaves `hexl-mark' at previous position.
 474 With prefix arg N, puts point N bytes of the way from the true beginning."
 475   (interactive "p")
 476   (push-mark (point))
 477   (hexl-goto-address (+ 0 (1- arg))))
 478
 479 (defun hexl-end-of-buffer (arg)
 480   "Go to `hexl-max-address' minus ARG."
 481   (interactive "p")
 482   (push-mark (point))
 483   (hexl-goto-address (- hexl-max-address (1- arg))))
 484
 485 (defun hexl-beginning-of-line ()
 486   "Goto beginning of line in hexl mode."
 487   (interactive)
 488   (goto-char (+ (* (/ (point) 68) 68) 11)))
 489
 490 (defun hexl-end-of-line ()
 491   "Goto end of line in hexl mode."
 492   (interactive)
 493   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 494                        (if (> address hexl-max-address)
 495                            (setq address hexl-max-address))
 496                        address)))
 497
 498 (defun hexl-scroll-down (arg)
 499   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 500   (interactive "P")
 501   (if (null arg)
 502       (setq arg (1- (window-height)))
 503     (setq arg (prefix-numeric-value arg)))
 504   (hexl-scroll-up (- arg)))
 505
 506 (defun hexl-scroll-up (arg)
 507   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 508   (interactive "P")
 509   (if (null arg)
 510       (setq arg (1- (window-height)))
 511     (setq arg (prefix-numeric-value arg)))
 512   (let ((movement (* arg 16))
 513         (address (hexl-current-address)))
 514     (if (or (> (+ address movement) hexl-max-address)
 515             (< (+ address movement) 0))
 516         (message "Out of hexl region.")
 517       (hexl-goto-address (+ address movement))
 518       (recenter 0))))
 519
 520 (defun hexl-beginning-of-1k-page ()
 521   "Go to beginning of 1k boundary."
 522   (interactive)
 523   (hexl-goto-address (logand (hexl-current-address) -1024)))
 524
 525 (defun hexl-end-of-1k-page ()
 526   "Go to end of 1k boundary."
 527   (interactive)
 528   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 529                        (if (> address hexl-max-address)
 530                            (setq address hexl-max-address))
 531                        address)))
 532
 533 (defun hexl-beginning-of-512b-page ()
 534   "Go to beginning of 512 byte boundary."
 535   (interactive)
 536   (hexl-goto-address (logand (hexl-current-address) -512)))
 537
 538 (defun hexl-end-of-512b-page ()
 539   "Go to end of 512 byte boundary."
 540   (interactive)
 541   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 542                        (if (> address hexl-max-address)
 543                            (setq address hexl-max-address))
 544                        address)))
 545
 546 (defun hexl-quoted-insert (arg)
 547   "Read next input character and insert it.
 548 Useful for inserting control characters.
 549 You may also type up to 3 octal digits, to insert a character with that code"
 550   (interactive "p")
 551   (hexl-insert-char (read-quoted-char) arg))
 552
 553 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 554
 555 ;;;###autoload
 556 (defun hexlify-buffer ()
 557   "Convert a binary buffer to hexl format."
 558   (interactive)
 559   (let ((binary-process-output nil) ; for Ms-Dos
 560         (binary-process-input t))
 561     (shell-command-on-region (point-min) (point-max) hexlify-command t)))
 562
 563 (defun dehexlify-buffer ()
 564   "Convert a hexl format buffer to binary."
 565   (interactive)
 566   (let ((binary-process-output t) ; for Ms-Dos
 567         (binary-process-input nil))
 568     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 569
 570 (defun hexl-char-after-point ()
 571   "Return char for ASCII hex digits at point."
 572   (hexl-htoi (char-after (point))
 573              (char-after (1+ (point)))))
 574
 575 (defun hexl-htoi (lh rh)
 576   "Hex (char) LH (char) RH to integer."
 577     (+ (* (hexl-hex-char-to-integer lh) 16)
 578        (hexl-hex-char-to-integer rh)))
 579
 580 (defun hexl-hex-char-to-integer (character)
 581   "Take a char and return its value as if it was a hex digit."
 582   (if (and (>= character ?0) (<= character ?9))
 583       (- character ?0)
 584     (let ((ch (logior character 32)))
 585       (if (and (>= ch ?a) (<= ch ?f))
 586           (- ch (- ?a 10))
 587         (error "Invalid hex digit `%c'." ch)))))
 588
 589 (defun hexl-oct-char-to-integer (character)
 590   "Take a char and return its value as if it was a octal digit."
 591   (if (and (>= character ?0) (<= character ?7))
 592       (- character ?0)
 593     (error "Invalid octal digit `%c'." character)))
 594
 595 (defun hexl-printable-character (ch)
 596   "Return a displayable string for character CH."
 597   (format "%c" (if hexl-iso
 598                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 599                        46
 600                      ch)
 601                  (if (or (< ch 32) (>= ch 127))
 602                      46
 603                    ch))))
 604
 605 (defun hexl-self-insert-command (arg)
 606   "Insert this character."
 607   (interactive "p")
 608   (hexl-insert-char last-command-char arg))
 609
 610 (defun hexl-insert-char (ch num)
 611   "Insert a character in a hexl buffer."
 612   (let ((address (hexl-current-address t)))
 613     (while (> num 0)
 614       (let ((hex-position
 615              (+ (* (/ address 16) 68)
 616                 11
 617                 (* 2 (% address 16))
 618                 (/ (% address 16) 2)))
 619             (ascii-position
 620              (+ (* (/ address 16) 68) 52 (% address 16)))
 621             at-ascii-position)
 622         (if (= (point) ascii-position)
 623             (setq at-ascii-position t))
 624         (goto-char hex-position)
 625         (delete-char 2)
 626         (insert (format "%02x" ch))
 627         (goto-char ascii-position)
 628         (delete-char 1)
 629         (insert (hexl-printable-character ch))
 630         (or (eq address hexl-max-address)
 631             (setq address (1+ address)))
 632         (hexl-goto-address address)
 633         (if at-ascii-position
 634             (progn
 635               (beginning-of-line)
 636               (forward-char 51)
 637               (forward-char (% address 16)))))
 638       (setq num (1- num)))))
 639
 640 ;; hex conversion
 641
 642 (defun hexl-insert-hex-char (arg)
 643   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 644   (interactive "p")
 645   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 646     (if (or (> num 255) (< num 0))
 647         (error "Hex number out of range.")
 648       (hexl-insert-char num arg))))
 649
 650 (defun hexl-insert-decimal-char (arg)
 651   "Insert a ASCII char ARG times at point for a given decimal number."
 652   (interactive "p")
 653   (let ((num (string-to-int (read-string "Decimal Number: "))))
 654     (if (or (> num 255) (< num 0))
 655         (error "Decimal number out of range.")
 656       (hexl-insert-char num arg))))
 657
 658 (defun hexl-insert-octal-char (arg)
 659   "Insert a ASCII char ARG times at point for a given octal number."
 660   (interactive "p")
 661   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 662     (if (or (> num 255) (< num 0))
 663         (error "Decimal number out of range.")
 664       (hexl-insert-char num arg))))
 665
 666 ;; startup stuff.
 667
 668 (if hexl-mode-map
 669     nil
 670     (setq hexl-mode-map (make-sparse-keymap))
 671
 672     (define-key hexl-mode-map [left] 'hexl-backward-char)
 673     (define-key hexl-mode-map [right] 'hexl-forward-char)
 674     (define-key hexl-mode-map [up] 'hexl-previous-line)
 675     (define-key hexl-mode-map [down] 'hexl-next-line)
 676     (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 677     (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 678     (define-key hexl-mode-map [next] 'hexl-scroll-up)
 679     (define-key hexl-mode-map [prev] 'hexl-scroll-down)
 680
 681     (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 682     (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 683     (define-key hexl-mode-map "\C-d" 'undefined)
 684     (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 685     (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 686
 687     (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 688         (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 689
 690     (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 691     (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 692     (define-key hexl-mode-map "\C-k" 'undefined)
 693     (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 694     (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 695     (define-key hexl-mode-map "\C-o" 'undefined)
 696     (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 697     (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 698     (define-key hexl-mode-map "\C-t" 'undefined)
 699     (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 700     (define-key hexl-mode-map "\C-w" 'undefined)
 701     (define-key hexl-mode-map "\C-y" 'undefined)
 702
 703     (let ((ch 32))
 704       (while (< ch 127)
 705         (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 706         (setq ch (1+ ch))))
 707
 708     (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 709     (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 710     (define-key hexl-mode-map "\e\C-c" 'undefined)
 711     (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 712     (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 713     (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 714     (define-key hexl-mode-map "\e\C-g" 'undefined)
 715     (define-key hexl-mode-map "\e\C-h" 'undefined)
 716     (define-key hexl-mode-map "\e\C-i" 'undefined)
 717     (define-key hexl-mode-map "\e\C-j" 'undefined)
 718     (define-key hexl-mode-map "\e\C-k" 'undefined)
 719     (define-key hexl-mode-map "\e\C-l" 'undefined)
 720     (define-key hexl-mode-map "\e\C-m" 'undefined)
 721     (define-key hexl-mode-map "\e\C-n" 'undefined)
 722     (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 723     (define-key hexl-mode-map "\e\C-p" 'undefined)
 724     (define-key hexl-mode-map "\e\C-q" 'undefined)
 725     (define-key hexl-mode-map "\e\C-r" 'undefined)
 726     (define-key hexl-mode-map "\e\C-s" 'undefined)
 727     (define-key hexl-mode-map "\e\C-t" 'undefined)
 728     (define-key hexl-mode-map "\e\C-u" 'undefined)
 729
 730     (define-key hexl-mode-map "\e\C-w" 'undefined)
 731     (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 732     (define-key hexl-mode-map "\e\C-y" 'undefined)
 733
 734     (define-key hexl-mode-map "\ea" 'undefined)
 735     (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 736     (define-key hexl-mode-map "\ec" 'undefined)
 737     (define-key hexl-mode-map "\ed" 'undefined)
 738     (define-key hexl-mode-map "\ee" 'undefined)
 739     (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 740     (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 741     (define-key hexl-mode-map "\eh" 'undefined)
 742     (define-key hexl-mode-map "\ei" 'undefined)
 743     (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 744     (define-key hexl-mode-map "\ek" 'undefined)
 745     (define-key hexl-mode-map "\el" 'undefined)
 746     (define-key hexl-mode-map "\em" 'undefined)
 747     (define-key hexl-mode-map "\en" 'undefined)
 748     (define-key hexl-mode-map "\eo" 'undefined)
 749     (define-key hexl-mode-map "\ep" 'undefined)
 750     (define-key hexl-mode-map "\eq" 'undefined)
 751     (define-key hexl-mode-map "\er" 'undefined)
 752     (define-key hexl-mode-map "\es" 'undefined)
 753     (define-key hexl-mode-map "\et" 'undefined)
 754     (define-key hexl-mode-map "\eu" 'undefined)
 755     (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 756     (define-key hexl-mode-map "\ey" 'undefined)
 757     (define-key hexl-mode-map "\ez" 'undefined)
 758     (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 759     (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 760
 761     (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 762
 763     (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 764     (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 765     (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 766     (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 767     (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 768
 769 ;;; hexl.el ends here