lisp/emulation/tpu-extras.el

   1 ;;; tpu-extras.el --- scroll margins and free cursor mode for TPU-edt
   2
   3 ;; Copyright (C) 1993-1995, 2000-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Rob Riepel <riepel@networking.stanford.edu>
   6 ;; Maintainer: Rob Riepel <riepel@networking.stanford.edu>
   7 ;; Keywords: emulations
   8 ;; Package: tpu-edt
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;  Use the functions defined here to customize TPU-edt to your tastes by
  28 ;;  setting scroll margins and/or turning on free cursor mode.  Here's an
  29 ;;  example for your .emacs file.
  30
  31 ;;     (tpu-set-cursor-free)                   ; Set cursor free.
  32 ;;     (tpu-set-scroll-margins "10%" "15%")    ; Set scroll margins.
  33
  34 ;;  Scroll margins and cursor binding can be changed from within emacs using
  35 ;;  the following commands:
  36
  37 ;;     tpu-set-scroll-margins  or   set scroll margins
  38 ;;     tpu-set-cursor-bound    or   set cursor bound
  39 ;;     tpu-set-cursor-free     or   set cursor free
  40
  41 ;;  Additionally, Gold-F toggles between bound and free cursor modes.
  42
  43 ;;  Note that switching out of free cursor mode or exiting TPU-edt while in
  44 ;;  free cursor mode strips trailing whitespace from every line in the file.
  45
  46
  47 ;;; Details:
  48
  49 ;;  The functions contained in this file implement scroll margins and free
  50 ;;  cursor mode.  The following keys and commands are affected.
  51
  52 ;;       key/command   function                        scroll   cursor
  53
  54 ;;       Up-Arrow      previous line                     x        x
  55 ;;       Down-Arrow    next line                         x        x
  56 ;;       Right-Arrow   next character                             x
  57 ;;       Left-Arrow    previous character                         x
  58 ;;       KP0           next or previous line             x
  59 ;;       KP7           next or previous page             x
  60 ;;       KP8           next or previous screen           x
  61 ;;       KP2           next or previous end-of-line      x        x
  62 ;;       Control-e     current end-of-line                        x
  63 ;;       Control-h     previous beginning-of-line        x
  64 ;;       Next Scr      next screen                       x
  65 ;;       Prev Scr      previous screen                   x
  66 ;;       Search        find a string                     x
  67 ;;       Replace       find and replace a string         x
  68 ;;       Newline       insert a newline                  x
  69 ;;       Paragraph     next or previous paragraph        x
  70 ;;       Auto-Fill     break lines on spaces             x
  71
  72 ;;  These functions are not part of the base TPU-edt for the following
  73 ;;  reasons:
  74
  75 ;;  Free cursor mode is implemented with the emacs picture-mode functions.
  76 ;;  These functions support moving the cursor all over the screen, however,
  77 ;;  when the cursor is moved past the end of a line, spaces or tabs are
  78 ;;  appended to the line - even if no text is entered in that area.  In
  79 ;;  order for a free cursor mode to work exactly like TPU/edt, this trailing
  80 ;;  whitespace needs to be dealt with in every function that might encounter
  81 ;;  it.  Such global changes are impractical, however, free cursor mode is
  82 ;;  too valuable to abandon completely, so it has been implemented in those
  83 ;;  functions where it serves best.
  84
  85 ;;  The implementation of scroll margins adds overhead to previously
  86 ;;  simple and often used commands.  These commands are now responsible
  87 ;;  for their normal operation and part of the display function.  There
  88 ;;  is a possibility that this display overhead could adversely affect the
  89 ;;  performance of TPU-edt on slower computers.  In order to support the
  90 ;;  widest range of computers, scroll margin support is optional.
  91
  92 ;;  It's actually not known whether the overhead associated with scroll
  93 ;;  margin support is significant.  If you find that it is, please send
  94 ;;  a note describing the extent of the performance degradation.  Be sure
  95 ;;  to include a description of the platform where you're running TPU-edt.
  96 ;;  Send your note to the address provided by Gold-V.
  97
  98 ;;  Even with these differences and limitations, these functions implement
  99 ;;  important aspects of the real TPU/edt.  Those who miss free cursor mode
 100 ;;  and/or scroll margins will appreciate these implementations.
 101
 102 ;;; Code:
 103
 104
 105 ;;;  Gotta have tpu-edt
 106
 107 (require 'tpu-edt)
 108
 109
 110 ;;;  Customization variables
 111
 112 (defcustom tpu-top-scroll-margin 0
 113   "Scroll margin at the top of the screen.
 114 Interpreted as a percent of the current window size."
 115   :type 'integer
 116   :group 'tpu)
 117 (defcustom tpu-bottom-scroll-margin 0
 118   "Scroll margin at the bottom of the screen.
 119 Interpreted as a percent of the current window size."
 120   :type 'integer
 121   :group 'tpu)
 122
 123 (defcustom tpu-backward-char-like-tpu t
 124   "If non-nil, in free cursor mode backward-char (left-arrow) works
 125 just like TPU/edt.  Otherwise, backward-char will move to the end of
 126 the previous line when starting from a line beginning."
 127   :type 'boolean
 128   :group 'tpu)
 129
 130
 131 ;;;  Global variables
 132
 133 ;;;###autoload
 134 (define-minor-mode tpu-cursor-free-mode
 135   "Minor mode to allow the cursor to move freely about the screen."
 136   :init-value nil
 137   (if (not tpu-cursor-free-mode)
 138       (tpu-trim-line-ends))
 139   (if (not tpu-cursor-free-mode)
 140       (message "The cursor is now bound to the flow of your text.")
 141     (message "The cursor will now move freely about the screen.")))
 142
 143
 144 ;;;  Hooks  --  Set cursor free in picture mode.
 145 ;;;             Clean up when writing a file from cursor free mode.
 146
 147 (add-hook 'picture-mode-hook 'tpu-set-cursor-free)
 148
 149 (defun tpu-trim-line-ends-if-needed ()
 150   "Eliminate whitespace at ends of lines, if the cursor is free."
 151   (if (and (buffer-modified-p) tpu-cursor-free-mode) (tpu-trim-line-ends)))
 152 (add-hook 'before-save-hook 'tpu-trim-line-ends-if-needed)
 153
 154
 155 ;;;  Utility routines for implementing scroll margins
 156
 157 (defun tpu-top-check (beg lines)
 158   "Enforce scroll margin at the top of screen."
 159   (let ((margin  (/ (* (window-height) tpu-top-scroll-margin) 100)))
 160     (cond ((< beg margin) (recenter beg))
 161           ((< (- beg lines) margin) (recenter margin)))))
 162
 163 (defun tpu-bottom-check (beg lines)
 164   "Enforce scroll margin at the bottom of screen."
 165   (let* ((height (window-height))
 166          (margin (+ 1 (/ (* height tpu-bottom-scroll-margin) 100)))
 167          ;; subtract 1 from height because it includes mode line
 168          (difference (- height margin 1)))
 169     (cond ((> beg difference) (recenter beg))
 170           ((> (+ beg lines) difference) (recenter (- margin))))))
 171
 172
 173 ;;;  Movement by character
 174
 175 (defun tpu-forward-char (num)
 176   "Move right ARG characters (left if ARG is negative)."
 177   (interactive "p")
 178   (if tpu-cursor-free-mode (picture-forward-column num) (forward-char num)))
 179
 180 (defun tpu-backward-char (num)
 181   "Move left ARG characters (right if ARG is negative)."
 182   (interactive "p")
 183   (cond ((not tpu-cursor-free-mode)
 184          (backward-char num))
 185         (tpu-backward-char-like-tpu
 186          (picture-backward-column num))
 187         ((bolp)
 188          (backward-char 1)
 189          (picture-end-of-line)
 190          (picture-backward-column (1- num)))
 191         (t
 192          (picture-backward-column num))))
 193
 194
 195 ;;;  Movement by line
 196
 197 (defun tpu-next-line (num)
 198   "Move to next line.
 199 Prefix argument serves as a repeat count."
 200   (interactive "p")
 201   (let ((beg (tpu-current-line)))
 202     (if tpu-cursor-free-mode (or (eobp) (picture-move-down num))
 203       (line-move num))
 204     (tpu-bottom-check beg num)
 205     (setq this-command 'next-line)))
 206
 207 (defun tpu-previous-line (num)
 208   "Move to previous line.
 209 Prefix argument serves as a repeat count."
 210   (interactive "p")
 211   (let ((beg (tpu-current-line)))
 212     (if tpu-cursor-free-mode (picture-move-up num) (line-move (- num)))
 213     (tpu-top-check beg num)
 214     (setq this-command 'previous-line)))
 215
 216 (defun tpu-next-beginning-of-line (num)
 217   "Move to beginning of line; if at beginning, move to beginning of next line.
 218 Accepts a prefix argument for the number of lines to move."
 219   (interactive "p")
 220   (let ((beg (tpu-current-line)))
 221     (backward-char 1)
 222     (forward-visible-line (- 1 num))
 223     (tpu-top-check beg num)))
 224
 225 (defun tpu-next-end-of-line (num)
 226   "Move to end of line; if at end, move to end of next line.
 227 Accepts a prefix argument for the number of lines to move."
 228   (interactive "p")
 229   (let ((beg (tpu-current-line)))
 230     (cond (tpu-cursor-free-mode
 231            (let ((beg (point)))
 232              (if (< 1 num) (forward-line num))
 233              (picture-end-of-line)
 234              (if (<= (point) beg) (progn (forward-line) (picture-end-of-line)))))
 235           (t
 236            (forward-char)
 237            (end-of-line num)))
 238     (tpu-bottom-check beg num)))
 239
 240 (defun tpu-previous-end-of-line (num)
 241   "Move EOL upward.
 242 Accepts a prefix argument for the number of lines to move."
 243   (interactive "p")
 244   (let ((beg (tpu-current-line)))
 245     (cond (tpu-cursor-free-mode
 246            (picture-end-of-line (- 1 num)))
 247           (t
 248            (end-of-line (- 1 num))))
 249     (tpu-top-check beg num)))
 250
 251 (defun tpu-current-end-of-line ()
 252   "Move point to end of current line."
 253   (interactive)
 254   (let ((beg (point)))
 255     (if tpu-cursor-free-mode (picture-end-of-line) (end-of-line))
 256     (if (= beg (point)) (message "You are already at the end of a line."))))
 257
 258 (defun tpu-forward-line (num)
 259   "Move to beginning of next line.
 260 Prefix argument serves as a repeat count."
 261   (interactive "p")
 262   (let ((beg (tpu-current-line)))
 263     (forward-line num)
 264     (tpu-bottom-check beg num)))
 265
 266 (defun tpu-backward-line (num)
 267   "Move to beginning of previous line.
 268 Prefix argument serves as repeat count."
 269   (interactive "p")
 270   (let ((beg (tpu-current-line)))
 271     (or (bolp) (>= 0 num) (setq num (- num 1)))
 272     (forward-line (- num))
 273     (tpu-top-check beg num)))
 274
 275
 276 ;;;  Movement by paragraph
 277
 278 ;; Cf edt-with-position.
 279 (defmacro tpu-with-position (&rest body)
 280   "Execute BODY with some position-related variables bound."
 281   `(let* ((left nil)
 282           (beg (tpu-current-line))
 283           (height (window-height))
 284           (top-percent
 285            (if (zerop tpu-top-scroll-margin) 10 tpu-top-scroll-margin))
 286           (bottom-percent
 287            (if (zerop tpu-bottom-scroll-margin) 15 tpu-bottom-scroll-margin))
 288           (top-margin (/ (* height top-percent) 100))
 289           (bottom-up-margin (1+ (/ (* height bottom-percent) 100)))
 290           (bottom-margin (max beg (- height bottom-up-margin 1)))
 291           (top (save-excursion (move-to-window-line top-margin) (point)))
 292           (bottom (save-excursion (move-to-window-line bottom-margin) (point)))
 293           (far (save-excursion
 294                  (goto-char bottom)
 295                  (point-at-bol (1- height)))))
 296      ,@body))
 297
 298 (defun tpu-paragraph (num)
 299   "Move to the next paragraph in the current direction.
 300 A repeat count means move that many paragraphs."
 301   (interactive "p")
 302   (tpu-with-position
 303    (if tpu-advance
 304        (progn
 305          (tpu-next-paragraph num)
 306          (if (> (point) far)
 307              (if (zerop (setq left (save-excursion (forward-line height))))
 308                  (recenter top-margin)
 309                (recenter (- left bottom-up-margin)))
 310            (and (> (point) bottom) (recenter bottom-margin))))
 311      (tpu-previous-paragraph num)
 312      (and (< (point) top) (recenter (min beg top-margin))))))
 313
 314 ;;;  Movement by page
 315
 316 (defun tpu-page (num)
 317   "Move to the next page in the current direction.
 318 A repeat count means move that many pages."
 319   (interactive "p")
 320   (tpu-with-position
 321    (if tpu-advance
 322        (progn
 323          (forward-page num)
 324          (if (> (point) far)
 325                (if (zerop (setq left (save-excursion (forward-line height))))
 326                    (recenter top-margin)
 327                  (recenter (- left bottom-up-margin)))
 328            (and (> (point) bottom) (recenter bottom-margin))))
 329      (backward-page num)
 330      (and (< (point) top) (recenter (min beg top-margin))))))
 331
 332 ;;;  Scrolling
 333
 334 (defun tpu-scroll-window-down (num)
 335   "Scroll the display down to the next section.
 336 A repeat count means scroll that many sections."
 337   (interactive "p")
 338   (let* ((beg (tpu-current-line))
 339          (height (1- (window-height)))
 340          (lines (* num (/ (* height tpu-percent-scroll) 100))))
 341     (line-move (- lines))
 342     (tpu-top-check beg lines)))
 343
 344 (defun tpu-scroll-window-up (num)
 345   "Scroll the display up to the next section.
 346 A repeat count means scroll that many sections."
 347   (interactive "p")
 348   (let* ((beg (tpu-current-line))
 349          (height (1- (window-height)))
 350          (lines (* num (/ (* height tpu-percent-scroll) 100))))
 351     (line-move lines)
 352     (tpu-bottom-check beg lines)))
 353
 354
 355 ;;;  Replace the TPU-edt internal search function
 356
 357 (defun tpu-search-internal (pat &optional quiet)
 358   "Search for a string or regular expression."
 359   (tpu-with-position
 360    (tpu-search-internal-core pat quiet)
 361    (if tpu-searching-forward
 362        (progn
 363          (if (> (point) far)
 364              (if (zerop (setq left (save-excursion (forward-line height))))
 365                  (recenter top-margin)
 366                (recenter (- left bottom-up-margin)))
 367            (and (> (point) bottom) (recenter bottom-margin))))
 368      (and (< (point) top) (recenter (min beg top-margin))))))
 369
 370 ;; Advise the newline, newline-and-indent, and do-auto-fill functions.
 371 (defadvice newline (around tpu-respect-bottom-scroll-margin activate disable)
 372   "Respect `tpu-bottom-scroll-margin'."
 373   (let ((beg (tpu-current-line))
 374         (num (prefix-numeric-value (ad-get-arg 0))))
 375     ad-do-it
 376     (tpu-bottom-check beg num)))
 377
 378 (defadvice newline-and-indent (around tpu-respect-bottom-scroll-margin)
 379   "Respect `tpu-bottom-scroll-margin'."
 380   (let ((beg (tpu-current-line)))
 381     ad-do-it
 382     (tpu-bottom-check beg 1)))
 383
 384 (defadvice do-auto-fill (around tpu-respect-bottom-scroll-margin)
 385   "Respect `tpu-bottom-scroll-margin'."
 386   (let ((beg (tpu-current-line)))
 387     ad-do-it
 388     (tpu-bottom-check beg 1)))
 389
 390
 391 ;;;  Function to set scroll margins
 392
 393 ;;;###autoload
 394 (defun tpu-set-scroll-margins (top bottom)
 395   "Set scroll margins."
 396   (interactive
 397    "sEnter top scroll margin (N lines or N%% or RETURN for current value): \
 398 \nsEnter bottom scroll margin (N lines or N%% or RETURN for current value): ")
 399   ;; set top scroll margin
 400   (or (string= top "")
 401       (setq tpu-top-scroll-margin
 402             (if (string= "%" (substring top -1))
 403                 (string-to-number top)
 404               (/ (1- (+ (* (string-to-number top) 100) (window-height)))
 405                  (window-height)))))
 406   ;; set bottom scroll margin
 407   (or (string= bottom "")
 408       (setq tpu-bottom-scroll-margin
 409             (if (string= "%" (substring bottom -1))
 410                 (string-to-number bottom)
 411               (/ (1- (+ (* (string-to-number bottom) 100) (window-height)))
 412                  (window-height)))))
 413   (dolist (f '(newline newline-and-indent do-auto-fill))
 414     (ad-enable-advice f 'around 'tpu-respect-bottom-scroll-margin)
 415     (ad-activate f))
 416   ;; report scroll margin settings if running interactively
 417   (and (called-interactively-p 'interactive)
 418        (message "Scroll margins set.  Top = %s%%, Bottom = %s%%"
 419                 tpu-top-scroll-margin tpu-bottom-scroll-margin)))
 420
 421
 422 ;;;  Functions to set cursor bound or free
 423
 424 ;;;###autoload
 425 (defun tpu-set-cursor-free ()
 426   "Allow the cursor to move freely about the screen."
 427   (interactive)
 428   (tpu-cursor-free-mode 1))
 429
 430 ;;;###autoload
 431 (defun tpu-set-cursor-bound ()
 432   "Constrain the cursor to the flow of the text."
 433   (interactive)
 434   (tpu-cursor-free-mode -1))
 435
 436 ;; Local Variables:
 437 ;; generated-autoload-file: "tpu-edt.el"
 438 ;; End:
 439
 440 ;;; tpu-extras.el ends here