lisp/dired-aux.el

   1 ;;; dired-aux.el --- all of dired except what people usually use
   2
   3 ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>.
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; The parts of dired mode not normally used.  This is a space-saving hack
  26 ;; to avoid having to load a large mode when all that's wanted are a few
  27 ;; functions.
  28
  29 ;; Rewritten in 1990/1991 to add tree features, file marking and
  30 ;; sorting by Sebastian Kremer <sk@thp.uni-koeln.de>.
  31 ;; Finished up by rms in 1992.
  32
  33 ;;; Code:
  34
  35 ;; We need macros in dired.el to compile properly.
  36 (eval-when-compile (require 'dired))
  37
  38 ;;; 15K
  39 ;;;###begin dired-cmd.el
  40 ;; Diffing and compressing
  41
  42 ;;;###autoload
  43 (defun dired-diff (file &optional switches)
  44   "Compare file at point with file FILE using `diff'.
  45 FILE defaults to the file at the mark.
  46 The prompted-for file is the first file given to `diff'.
  47 With prefix arg, prompt for second argument SWITCHES,
  48  which is options for `diff'."
  49   (interactive
  50    (let ((default (if (mark t)
  51                       (save-excursion (goto-char (mark t))
  52                                       (dired-get-filename t t)))))
  53      (require 'diff)
  54      (list (read-file-name (format "Diff %s with: %s"
  55                                    (dired-get-filename t)
  56                                    (if default
  57                                        (concat "(default " default ") ")
  58                                      ""))
  59                            (dired-current-directory) default t)
  60            (if current-prefix-arg
  61                (read-string "Options for diff: "
  62                             (if (stringp diff-switches)
  63                                 diff-switches
  64                               (mapconcat 'identity diff-switches " ")))))))
  65   (diff file (dired-get-filename t) switches))
  66
  67 ;;;###autoload
  68 (defun dired-backup-diff (&optional switches)
  69   "Diff this file with its backup file or vice versa.
  70 Uses the latest backup, if there are several numerical backups.
  71 If this file is a backup, diff it with its original.
  72 The backup file is the first file given to `diff'.
  73 With prefix arg, prompt for argument SWITCHES which is options for `diff'."
  74   (interactive
  75     (if current-prefix-arg
  76         (list (read-string "Options for diff: "
  77                            (if (stringp diff-switches)
  78                                diff-switches
  79                              (mapconcat 'identity diff-switches " "))))
  80       nil))
  81   (diff-backup (dired-get-filename) switches))
  82
  83 (defun dired-do-chxxx (attribute-name program op-symbol arg)
  84   ;; Change file attributes (mode, group, owner) of marked files and
  85   ;; refresh their file lines.
  86   ;; ATTRIBUTE-NAME is a string describing the attribute to the user.
  87   ;; PROGRAM is the program used to change the attribute.
  88   ;; OP-SYMBOL is the type of operation (for use in dired-mark-pop-up).
  89   ;; ARG describes which files to use, as in dired-get-marked-files.
  90   (let* ((files (dired-get-marked-files t arg))
  91          (new-attribute
  92           (dired-mark-read-string
  93            (concat "Change " attribute-name " of %s to: ")
  94            nil op-symbol arg files))
  95          (operation (concat program " " new-attribute))
  96          failures)
  97     (setq failures
  98           (dired-bunch-files 10000
  99                              (function dired-check-process)
 100                              (list operation program new-attribute)
 101                              files))
 102     (dired-do-redisplay arg);; moves point if ARG is an integer
 103     (if failures
 104         (dired-log-summary
 105          (format "%s: error" operation)
 106          nil))))
 107
 108 ;;;###autoload
 109 (defun dired-do-chmod (&optional arg)
 110   "Change the mode of the marked (or next ARG) files.
 111 This calls chmod, thus symbolic modes like `g+w' are allowed."
 112   (interactive "P")
 113   (dired-do-chxxx "Mode" "chmod" 'chmod arg))
 114
 115 ;;;###autoload
 116 (defun dired-do-chgrp (&optional arg)
 117   "Change the group of the marked (or next ARG) files."
 118   (interactive "P")
 119   (dired-do-chxxx "Group" "chgrp" 'chgrp arg))
 120
 121 ;;;###autoload
 122 (defun dired-do-chown (&optional arg)
 123   "Change the owner of the marked (or next ARG) files."
 124   (interactive "P")
 125   (dired-do-chxxx "Owner" dired-chown-program 'chown arg))
 126
 127 ;; Process all the files in FILES in batches of a convenient size,
 128 ;; by means of (FUNCALL FUNCTION ARGS... SOME-FILES...).
 129 ;; Batches are chosen to need less than MAX chars for the file names,
 130 ;; allowing 3 extra characters of separator per file name.
 131 (defun dired-bunch-files (max function args files)
 132   (let (pending
 133         (pending-length 0)
 134         failures)
 135     ;; Accumulate files as long as they fit in MAX chars,
 136     ;; then process the ones accumulated so far.
 137     (while files
 138       (let* ((thisfile (car files))
 139              (thislength (+ (length thisfile) 3))
 140              (rest (cdr files)))
 141         ;; If we have at least 1 pending file
 142         ;; and this file won't fit in the length limit, process now.
 143         (if (and pending (> (+ thislength pending-length) max))
 144             (setq failures
 145                   (nconc (apply function (append args pending))
 146                          failures)
 147                   pending nil
 148                   pending-length 0))
 149         ;; Do (setq pending (cons thisfile pending))
 150         ;; but reuse the cons that was in `files'.
 151         (setcdr files pending)
 152         (setq pending files)
 153         (setq pending-length (+ thislength pending-length))
 154         (setq files rest)))
 155     (nconc (apply function (append args pending))
 156            failures)))
 157
 158 ;;;###autoload
 159 (defun dired-do-print (&optional arg)
 160   "Print the marked (or next ARG) files.
 161 Uses the shell command coming from variables `lpr-command' and
 162 `lpr-switches' as default."
 163   (interactive "P")
 164   (let* ((file-list (dired-get-marked-files t arg))
 165          (command (dired-mark-read-string
 166                    "Print %s with: "
 167                    (apply 'concat lpr-command " " lpr-switches)
 168                    'print arg file-list)))
 169     (dired-run-shell-command (dired-shell-stuff-it command file-list nil))))
 170
 171 ;; Read arguments for a marked-files command that wants a string
 172 ;; that is not a file name,
 173 ;; perhaps popping up the list of marked files.
 174 ;; ARG is the prefix arg and indicates whether the files came from
 175 ;; marks (ARG=nil) or a repeat factor (integerp ARG).
 176 ;; If the current file was used, the list has but one element and ARG
 177 ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)).
 178
 179 (defun dired-mark-read-string (prompt initial op-symbol arg files)
 180   ;; PROMPT for a string, with INITIAL input.
 181   ;; Other args are used to give user feedback and pop-up:
 182   ;; OP-SYMBOL of command, prefix ARG, marked FILES.
 183   (dired-mark-pop-up
 184    nil op-symbol files
 185    (function read-string)
 186    (format prompt (dired-mark-prompt arg files)) initial))
 187 \f
 188 ;;; Cleaning a directory: flagging some backups for deletion.
 189
 190 (defvar dired-file-version-alist)
 191
 192 (defun dired-clean-directory (keep)
 193   "Flag numerical backups for deletion.
 194 Spares `dired-kept-versions' latest versions, and `kept-old-versions' oldest.
 195 Positive prefix arg KEEP overrides `dired-kept-versions';
 196 Negative prefix arg KEEP overrides `kept-old-versions' with KEEP made positive.
 197
 198 To clear the flags on these files, you can use \\[dired-flag-backup-files]
 199 with a prefix argument."
 200   (interactive "P")
 201   (setq keep (if keep (prefix-numeric-value keep) dired-kept-versions))
 202   (let ((early-retention (if (< keep 0) (- keep) kept-old-versions))
 203         (late-retention (if (<= keep 0) dired-kept-versions keep))
 204         (dired-file-version-alist ()))
 205     (message "Cleaning numerical backups (keeping %d late, %d old)..."
 206              late-retention early-retention)
 207     ;; Look at each file.
 208     ;; If the file has numeric backup versions,
 209     ;; put on dired-file-version-alist an element of the form
 210     ;; (FILENAME . VERSION-NUMBER-LIST)
 211     (dired-map-dired-file-lines (function dired-collect-file-versions))
 212     ;; Sort each VERSION-NUMBER-LIST,
 213     ;; and remove the versions not to be deleted.
 214     (let ((fval dired-file-version-alist))
 215       (while fval
 216         (let* ((sorted-v-list (cons 'q (sort (cdr (car fval)) '<)))
 217                (v-count (length sorted-v-list)))
 218           (if (> v-count (+ early-retention late-retention))
 219               (rplacd (nthcdr early-retention sorted-v-list)
 220                       (nthcdr (- v-count late-retention)
 221                               sorted-v-list)))
 222           (rplacd (car fval)
 223                   (cdr sorted-v-list)))
 224         (setq fval (cdr fval))))
 225     ;; Look at each file.  If it is a numeric backup file,
 226     ;; find it in a VERSION-NUMBER-LIST and maybe flag it for deletion.
 227     (dired-map-dired-file-lines (function dired-trample-file-versions))
 228     (message "Cleaning numerical backups...done")))
 229
 230 ;;; Subroutines of dired-clean-directory.
 231
 232 (defun dired-map-dired-file-lines (fun)
 233   ;; Perform FUN with point at the end of each non-directory line.
 234   ;; FUN takes one argument, the filename (complete pathname).
 235   (save-excursion
 236     (let (file buffer-read-only)
 237       (goto-char (point-min))
 238       (while (not (eobp))
 239         (save-excursion
 240           (and (not (looking-at dired-re-dir))
 241                (not (eolp))
 242                (setq file (dired-get-filename nil t)) ; nil on non-file
 243                (progn (end-of-line)
 244                       (funcall fun file))))
 245         (forward-line 1)))))
 246
 247 (defun dired-collect-file-versions (fn)
 248   ;;  "If it looks like file FN has versions, return a list of the versions.
 249   ;;That is a list of strings which are file names.
 250   ;;The caller may want to flag some of these files for deletion."
 251     (let* ((base-versions
 252             (concat (file-name-nondirectory fn) ".~"))
 253            (bv-length (length base-versions))
 254            (possibilities (file-name-all-completions
 255                            base-versions
 256                            (file-name-directory fn)))
 257            (versions (mapcar 'backup-extract-version possibilities)))
 258       (if versions
 259           (setq dired-file-version-alist (cons (cons fn versions)
 260                                                dired-file-version-alist)))))
 261
 262 (defun dired-trample-file-versions (fn)
 263   (let* ((start-vn (string-match "\\.~[0-9]+~$" fn))
 264          base-version-list)
 265     (and start-vn
 266          (setq base-version-list        ; there was a base version to which
 267                (assoc (substring fn 0 start-vn) ; this looks like a
 268                       dired-file-version-alist))        ; subversion
 269          (not (memq (string-to-int (substring fn (+ 2 start-vn)))
 270                     base-version-list)) ; this one doesn't make the cut
 271          (progn (beginning-of-line)
 272                 (delete-char 1)
 273                 (insert dired-del-marker)))))
 274 \f
 275 ;;; Shell commands
 276 ;;>>> install (move this function into simple.el)
 277 (defun dired-shell-quote (filename)
 278   "Quote a file name for inferior shell (see variable `shell-file-name')."
 279   ;; Quote everything except POSIX filename characters.
 280   ;; This should be safe enough even for really weird shells.
 281   (let ((result "") (start 0) end)
 282     (while (string-match "[^-0-9a-zA-Z_./]" filename start)
 283       (setq end (match-beginning 0)
 284             result (concat result (substring filename start end)
 285                            "\\" (substring filename end (1+ end)))
 286             start (1+ end)))
 287     (concat result (substring filename start))))
 288
 289 (defun dired-read-shell-command (prompt arg files)
 290 ;;  "Read a dired shell command prompting with PROMPT (using read-string).
 291 ;;ARG is the prefix arg and may be used to indicate in the prompt which
 292 ;;  files are affected.
 293 ;;This is an extra function so that you can redefine it, e.g., to use gmhist."
 294   (dired-mark-pop-up
 295    nil 'shell files
 296    (function read-string)
 297    (format prompt (dired-mark-prompt arg files))))
 298
 299 ;; The in-background argument is only needed in Emacs 18 where
 300 ;; shell-command doesn't understand an appended ampersand `&'.
 301 ;;;###autoload
 302 (defun dired-do-shell-command (command &optional arg)
 303   "Run a shell command COMMAND on the marked files.
 304 If no files are marked or a specific numeric prefix arg is given,
 305 the next ARG files are used.  Just \\[universal-argument] means the current file.
 306 The prompt mentions the file(s) or the marker, as appropriate.
 307
 308 If there is output, it goes to a separate buffer.
 309
 310 Normally the command is run on each file individually.
 311 However, if there is a `*' in the command then it is run
 312 just once with the entire file list substituted there.
 313
 314 No automatic redisplay of dired buffers is attempted, as there's no
 315 telling what files the command may have changed.  Type
 316 \\[dired-do-redisplay] to redisplay the marked files.
 317
 318 The shell command has the top level directory as working directory, so
 319 output files usually are created there instead of in a subdir."
 320 ;;Functions dired-run-shell-command and dired-shell-stuff-it do the
 321 ;;actual work and can be redefined for customization.
 322   (interactive (list
 323                 ;; Want to give feedback whether this file or marked files are used:
 324                 (dired-read-shell-command (concat "! on "
 325                                                   "%s: ")
 326                                           current-prefix-arg
 327                                           (dired-get-marked-files
 328                                            t current-prefix-arg))
 329                 current-prefix-arg))
 330   (let* ((on-each (not (string-match "\\*" command)))
 331          (file-list (dired-get-marked-files t arg)))
 332     (if on-each
 333         (dired-bunch-files
 334          (- 10000 (length command))
 335          (function (lambda (&rest files)
 336                      (dired-run-shell-command
 337                       (dired-shell-stuff-it command files t arg))))
 338          nil
 339          file-list)
 340       ;; execute the shell command
 341       (dired-run-shell-command
 342        (dired-shell-stuff-it command file-list nil arg)))))
 343
 344 ;; Might use {,} for bash or csh:
 345 (defvar dired-mark-prefix ""
 346   "Prepended to marked files in dired shell commands.")
 347 (defvar dired-mark-postfix ""
 348   "Appended to marked files in dired shell commands.")
 349 (defvar dired-mark-separator " "
 350   "Separates marked files in dired shell commands.")
 351
 352 (defun dired-shell-stuff-it (command file-list on-each &optional raw-arg)
 353 ;; "Make up a shell command line from COMMAND and FILE-LIST.
 354 ;; If ON-EACH is t, COMMAND should be applied to each file, else
 355 ;; simply concat all files and apply COMMAND to this.
 356 ;; FILE-LIST's elements will be quoted for the shell."
 357 ;; Might be redefined for smarter things and could then use RAW-ARG
 358 ;; (coming from interactive P and currently ignored) to decide what to do.
 359 ;; Smart would be a way to access basename or extension of file names.
 360 ;; See dired-trns.el for an approach to this.
 361   ;; Bug: There is no way to quote a *
 362   ;; On the other hand, you can never accidentally get a * into your cmd.
 363   (let ((stuff-it
 364          (if (string-match "\\*" command)
 365              (function (lambda (x)
 366                          (dired-replace-in-string "\\*" x command)))
 367            (function (lambda (x) (concat command " " x))))))
 368     (if on-each
 369         (mapconcat stuff-it (mapcar 'dired-shell-quote file-list) ";")
 370       (let ((fns (mapconcat 'dired-shell-quote
 371                             file-list dired-mark-separator)))
 372         (if (> (length file-list) 1)
 373             (setq fns (concat dired-mark-prefix fns dired-mark-postfix)))
 374         (funcall stuff-it fns)))))
 375
 376 ;; This is an extra function so that it can be redefined by ange-ftp.
 377 (defun dired-run-shell-command (command)
 378   (shell-command command)
 379   ;; Return nil for sake of nconc in dired-bunch-files.
 380   nil)
 381 \f
 382 ;; In Emacs 19 this will return program's exit status.
 383 ;; This is a separate function so that ange-ftp can redefine it.
 384 (defun dired-call-process (program discard &rest arguments)
 385 ;  "Run PROGRAM with output to current buffer unless DISCARD is t.
 386 ;Remaining arguments are strings passed as command arguments to PROGRAM."
 387   (apply 'call-process program nil (not discard) nil arguments))
 388
 389 (defun dired-check-process (msg program &rest arguments)
 390 ;  "Display MSG while running PROGRAM, and check for output.
 391 ;Remaining arguments are strings passed as command arguments to PROGRAM.
 392 ; On error, insert output
 393 ; in a log buffer and return the offending ARGUMENTS or PROGRAM.
 394 ; Caller can cons up a list of failed args.
 395 ;Else returns nil for success."
 396   (let (err-buffer err (dir default-directory))
 397     (message "%s..." msg)
 398     (save-excursion
 399       ;; Get a clean buffer for error output:
 400       (setq err-buffer (get-buffer-create " *dired-check-process output*"))
 401       (set-buffer err-buffer)
 402       (erase-buffer)
 403       (setq default-directory dir       ; caller's default-directory
 404             err (/= 0
 405                  (apply (function dired-call-process) program nil arguments)))
 406       (if err
 407           (progn
 408             (dired-log (concat program " " (prin1-to-string arguments) "\n"))
 409             (dired-log err-buffer)
 410             (or arguments program t))
 411         (kill-buffer err-buffer)
 412         (message "%s...done" msg)
 413         nil))))
 414 \f
 415 ;; Commands that delete or redisplay part of the dired buffer.
 416
 417 (defun dired-kill-line (&optional arg)
 418   (interactive "P")
 419   (setq arg (prefix-numeric-value arg))
 420   (let (buffer-read-only file)
 421     (while (/= 0 arg)
 422       (setq file (dired-get-filename nil t))
 423       (if (not file)
 424           (error "Can only kill file lines.")
 425         (save-excursion (and file
 426                              (dired-goto-subdir file)
 427                              (dired-kill-subdir)))
 428         (delete-region (progn (beginning-of-line) (point))
 429                        (progn (forward-line 1) (point)))
 430         (if (> arg 0)
 431             (setq arg (1- arg))
 432           (setq arg (1+ arg))
 433           (forward-line -1))))
 434     (dired-move-to-filename)))
 435
 436 ;;;###autoload
 437 (defun dired-do-kill-lines (&optional arg fmt)
 438   "Kill all marked lines (not the files).
 439 With a prefix argument, kill that many lines starting with the current line.
 440 \(A negative argument kills lines before the current line.)
 441 To kill an entire subdirectory, go to its directory header line
 442 and use this command with a prefix argument (the value does not matter)."
 443   ;; Returns count of killed lines.  FMT="" suppresses message.
 444   (interactive "P")
 445   (if arg
 446       (if (dired-get-subdir)
 447           (dired-kill-subdir)
 448         (dired-kill-line arg))
 449     (save-excursion
 450       (goto-char (point-min))
 451       (let (buffer-read-only (count 0))
 452         (if (not arg)                   ; kill marked lines
 453             (let ((regexp (dired-marker-regexp)))
 454               (while (and (not (eobp))
 455                           (re-search-forward regexp nil t))
 456                 (setq count (1+ count))
 457                 (delete-region (progn (beginning-of-line) (point))
 458                                (progn (forward-line 1) (point)))))
 459           ;; else kill unmarked lines
 460           (while (not (eobp))
 461             (if (or (dired-between-files)
 462                     (not (looking-at "^  ")))
 463                 (forward-line 1)
 464               (setq count (1+ count))
 465               (delete-region (point) (save-excursion
 466                                        (forward-line 1)
 467                                        (point))))))
 468         (or (equal "" fmt)
 469             (message (or fmt "Killed %d line%s.") count (dired-plural-s count)))
 470         count))))
 471
 472 ;;;###end dired-cmd.el
 473 \f
 474 ;;; 30K
 475 ;;;###begin dired-cp.el
 476
 477 (defun dired-compress ()
 478   ;; Compress or uncompress the current file.
 479   ;; Return nil for success, offending filename else.
 480   (let* (buffer-read-only
 481          (from-file (dired-get-filename))
 482          (new-file (dired-compress-file from-file)))
 483     (if new-file
 484         (let ((start (point)))
 485           ;; Remove any preexisting entry for the name NEW-FILE.
 486           (condition-case nil
 487               (dired-remove-entry new-file)
 488             (error nil))
 489           (goto-char start)
 490           ;; Now replace the current line with an entry for NEW-FILE.
 491           (dired-update-file-line new-file) nil)
 492       (dired-log (concat "Failed to compress" from-file))
 493       from-file)))
 494
 495 ;;;###autoload
 496 (defun dired-compress-file (file)
 497   ;; Compress or uncompress FILE.
 498   ;; Return the name of the compressed or uncompressed file.
 499   ;; Return nil if no change in files.
 500   (let ((handler (find-file-name-handler file)))
 501     (cond (handler
 502            (funcall handler 'dired-compress-file file))
 503           ((file-symlink-p file)
 504            nil)
 505           ((let (case-fold-search)
 506              (string-match "\\.Z$" file))
 507            (if (not (dired-check-process (concat "Uncompressing " file)
 508                                          "uncompress" file))
 509                (substring file 0 -2)))
 510           ((let (case-fold-search)
 511              (string-match "\\.gz$" file))
 512            (if (not (dired-check-process (concat "Uncompressing " file)
 513                                          "gunzip" file))
 514                (substring file 0 -3)))
 515           ;; For .z, try gunzip.  It might be an old gzip file,
 516           ;; or it might be from compact? pack? (which?) but gunzip handles
 517           ;; both.
 518           ((let (case-fold-search)
 519              (string-match "\\.z$" file))
 520            (if (not (dired-check-process (concat "Uncompressing " file)
 521                                          "gunzip" file))
 522                (substring file 0 -2)))
 523           (t
 524            ;;; Try gzip; if we don't have that, use compress.
 525            (condition-case nil
 526                (if (not (dired-check-process (concat "Compressing " file)
 527                                              "gzip" "-f" file))
 528                    (cond ((file-exists-p (concat file ".gz"))
 529                           (concat file ".gz"))
 530                          (t (concat file ".z"))))
 531              (file-error
 532               (if (not (dired-check-process (concat "Compressing " file)
 533                                             "compress" "-f" file))
 534                   (concat file ".Z"))))))))
 535 \f
 536 (defun dired-mark-confirm (op-symbol arg)
 537   ;; Request confirmation from the user that the operation described
 538   ;; by OP-SYMBOL is to be performed on the marked files.
 539   ;; Confirmation consists in a y-or-n question with a file list
 540   ;; pop-up unless OP-SYMBOL is a member of `dired-no-confirm'.
 541   ;; The files used are determined by ARG (as in dired-get-marked-files).
 542   (or (memq op-symbol dired-no-confirm)
 543       (let ((files (dired-get-marked-files t arg))
 544             (string (if (eq op-symbol 'compress) "Compress or uncompress"
 545                       (capitalize (symbol-name op-symbol)))))
 546         (dired-mark-pop-up nil op-symbol files (function y-or-n-p)
 547                            (concat string " "
 548                                    (dired-mark-prompt arg files) "? ")))))
 549
 550 (defun dired-map-over-marks-check (fun arg op-symbol &optional show-progress)
 551 ;  "Map FUN over marked files (with second ARG like in dired-map-over-marks)
 552 ; and display failures.
 553
 554 ; FUN takes zero args.  It returns non-nil (the offending object, e.g.
 555 ; the short form of the filename) for a failure and probably logs a
 556 ; detailed error explanation using function `dired-log'.
 557
 558 ; OP-SYMBOL is a symbol describing the operation performed (e.g.
 559 ; `compress').  It is used with `dired-mark-pop-up' to prompt the user
 560 ; (e.g. with `Compress * [2 files]? ') and to display errors (e.g.
 561 ; `Failed to compress 1 of 2 files - type W to see why ("foo")')
 562
 563 ; SHOW-PROGRESS if non-nil means redisplay dired after each file."
 564   (if (dired-mark-confirm op-symbol arg)
 565       (let* ((total-list;; all of FUN's return values
 566               (dired-map-over-marks (funcall fun) arg show-progress))
 567              (total (length total-list))
 568              (failures (delq nil total-list))
 569              (count (length failures))
 570              (string (if (eq op-symbol 'compress) "Compress or uncompress"
 571                        (capitalize (symbol-name op-symbol)))))
 572         (if (not failures)
 573             (message "%s: %d file%s."
 574                      string total (dired-plural-s total))
 575           ;; end this bunch of errors:
 576           (dired-log-summary
 577            (format "Failed to %s %d of %d file%s"
 578                    (downcase string) count total (dired-plural-s total))
 579            failures)))))
 580
 581 (defvar dired-query-alist
 582   '((?\y . y) (?\040 . y)               ; `y' or SPC means accept once
 583     (?n . n) (?\177 . n)                ; `n' or DEL skips once
 584     (?! . yes)                          ; `!' accepts rest
 585     (?q. no) (?\e . no)                 ; `q' or ESC skips rest
 586     ;; None of these keys quit - use C-g for that.
 587     ))
 588
 589 (defun dired-query (qs-var qs-prompt &rest qs-args)
 590   ;; Query user and return nil or t.
 591   ;; Store answer in symbol VAR (which must initially be bound to nil).
 592   ;; Format PROMPT with ARGS.
 593   ;; Binding variable help-form will help the user who types the help key.
 594   (let* ((char (symbol-value qs-var))
 595          (action (cdr (assoc char dired-query-alist))))
 596     (cond ((eq 'yes action)
 597            t)                           ; accept, and don't ask again
 598           ((eq 'no action)
 599            nil)                         ; skip, and don't ask again
 600           (t;; no lasting effects from last time we asked - ask now
 601            (let ((qprompt (concat qs-prompt
 602                                   (if help-form
 603                                       (format " [Type yn!q or %s] "
 604                                               (key-description
 605                                                (char-to-string help-char)))
 606                                     " [Type y, n, q or !] ")))
 607                  result elt)
 608              ;; Actually it looks nicer without cursor-in-echo-area - you can
 609              ;; look at the dired buffer instead of at the prompt to decide.
 610              (apply 'message qprompt qs-args)
 611              (setq char (set qs-var (read-char)))
 612              (while (not (setq elt (assoc char dired-query-alist)))
 613                (message "Invalid char - type %c for help." help-char)
 614                (ding)
 615                (sit-for 1)
 616                (apply 'message qprompt qs-args)
 617                (setq char (set qs-var (read-char))))
 618              (memq (cdr elt) '(t y yes)))))))
 619 \f
 620 ;;;###autoload
 621 (defun dired-do-compress (&optional arg)
 622   "Compress or uncompress marked (or next ARG) files."
 623   (interactive "P")
 624   (dired-map-over-marks-check (function dired-compress) arg 'compress t))
 625
 626 ;; Commands for Emacs Lisp files - load and byte compile
 627
 628 (defun dired-byte-compile ()
 629   ;; Return nil for success, offending file name else.
 630   (let* ((filename (dired-get-filename))
 631          (elc-file
 632           (if (eq system-type 'vax-vms)
 633               (concat (substring filename 0 (string-match ";" filename)) "c")
 634             (concat filename "c")))
 635          buffer-read-only failure)
 636     (condition-case err
 637         (save-excursion (byte-compile-file filename))
 638       (error
 639        (setq failure err)))
 640     (if failure
 641         (progn
 642           (dired-log "Byte compile error for %s:\n%s\n" filename failure)
 643           (dired-make-relative filename))
 644       (dired-remove-file elc-file)
 645       (forward-line)                    ; insert .elc after its .el file
 646       (dired-add-file elc-file)
 647       nil)))
 648
 649 ;;;###autoload
 650 (defun dired-do-byte-compile (&optional arg)
 651   "Byte compile marked (or next ARG) Emacs Lisp files."
 652   (interactive "P")
 653   (dired-map-over-marks-check (function dired-byte-compile) arg 'byte-compile t))
 654
 655 (defun dired-load ()
 656   ;; Return nil for success, offending file name else.
 657   (let ((file (dired-get-filename)) failure)
 658     (condition-case err
 659       (load file nil nil t)
 660       (error (setq failure err)))
 661     (if (not failure)
 662         nil
 663       (dired-log "Load error for %s:\n%s\n" file failure)
 664       (dired-make-relative file))))
 665
 666 ;;;###autoload
 667 (defun dired-do-load (&optional arg)
 668   "Load the marked (or next ARG) Emacs Lisp files."
 669   (interactive "P")
 670   (dired-map-over-marks-check (function dired-load) arg 'load t))
 671
 672 ;;;###autoload
 673 (defun dired-do-redisplay (&optional arg test-for-subdir)
 674   "Redisplay all marked (or next ARG) files.
 675 If on a subdir line, redisplay that subdirectory.  In that case,
 676 a prefix arg lets you edit the `ls' switches used for the new listing."
 677   ;; Moves point if the next ARG files are redisplayed.
 678   (interactive "P\np")
 679   (if (and test-for-subdir (dired-get-subdir))
 680       (dired-insert-subdir
 681        (dired-get-subdir)
 682        (if arg (read-string "Switches for listing: " dired-actual-switches)))
 683     (message "Redisplaying...")
 684     ;; message much faster than making dired-map-over-marks show progress
 685     (dired-map-over-marks (let ((fname (dired-get-filename)))
 686                             (message "Redisplaying... %s" fname)
 687                             (dired-update-file-line fname))
 688                           arg)
 689     (dired-move-to-filename)
 690     (message "Redisplaying...done")))
 691 \f
 692 (defun dired-update-file-line (file)
 693   ;; Delete the current line, and insert an entry for FILE.
 694   ;; If FILE is nil, then just delete the current line.
 695   ;; Keeps any marks that may be present in column one (doing this
 696   ;; here is faster than with dired-add-entry's optional arg).
 697   ;; Does not update other dired buffers.  Use dired-relist-entry for that.
 698   (beginning-of-line)
 699   (let ((char (following-char)) (opoint (point))
 700         (buffer-read-only))
 701     (delete-region (point) (progn (forward-line 1) (point)))
 702     (if file
 703         (progn
 704           (dired-add-entry file)
 705           ;; Replace space by old marker without moving point.
 706           ;; Faster than goto+insdel inside a save-excursion?
 707           (subst-char-in-region opoint (1+ opoint) ?\040 char))))
 708   (dired-move-to-filename))
 709
 710 (defun dired-fun-in-all-buffers (directory fun &rest args)
 711   ;; In all buffers dired'ing DIRECTORY, run FUN with ARGS.
 712   ;; Return list of buffers where FUN succeeded (i.e., returned non-nil).
 713   (let ((buf-list (dired-buffers-for-dir directory))
 714         (obuf (current-buffer))
 715         buf success-list)
 716     (while buf-list
 717       (setq buf (car buf-list)
 718             buf-list (cdr buf-list))
 719       (unwind-protect
 720           (progn
 721             (set-buffer buf)
 722             (if (apply fun args)
 723                 (setq success-list (cons (buffer-name buf) success-list))))
 724         (set-buffer obuf)))
 725     success-list))
 726
 727 ;;;###autoload
 728 (defun dired-add-file (filename &optional marker-char)
 729   (dired-fun-in-all-buffers
 730    (file-name-directory filename)
 731    (function dired-add-entry) filename marker-char))
 732
 733 (defun dired-add-entry (filename &optional marker-char)
 734   ;; Add a new entry for FILENAME, optionally marking it
 735   ;; with MARKER-CHAR (a character, else dired-marker-char is used).
 736   ;; Note that this adds the entry `out of order' if files sorted by
 737   ;; time, etc.
 738   ;; At least this version inserts in the right subdirectory (if present).
 739   ;; And it skips "." or ".." (see `dired-trivial-filenames').
 740   ;; Hidden subdirs are exposed if a file is added there.
 741   (setq filename (directory-file-name filename))
 742   ;; Entry is always for files, even if they happen to also be directories
 743   (let ((opoint (point))
 744         (cur-dir (dired-current-directory))
 745         (directory (file-name-directory filename))
 746         reason)
 747     (setq filename (file-name-nondirectory filename)
 748           reason
 749           (catch 'not-found
 750             (if (string= directory cur-dir)
 751                 (progn
 752                   (skip-chars-forward "^\r\n")
 753                   (if (eq (following-char) ?\r)
 754                       (dired-unhide-subdir))
 755                   ;; We are already where we should be, except when
 756                   ;; point is before the subdir line or its total line.
 757                   (let ((p (dired-after-subdir-garbage cur-dir)))
 758                     (if (< (point) p)
 759                         (goto-char p))))
 760               ;; else try to find correct place to insert
 761               (if (dired-goto-subdir directory)
 762                   (progn;; unhide if necessary
 763                     (if (looking-at "\r");; point is at end of subdir line
 764                         (dired-unhide-subdir))
 765                     ;; found - skip subdir and `total' line
 766                     ;; and uninteresting files like . and ..
 767                     ;; This better not moves into the next subdir!
 768                     (dired-goto-next-nontrivial-file))
 769                 ;; not found
 770                 (throw 'not-found "Subdir not found")))
 771             ;; found and point is at The Right Place:
 772             (let (buffer-read-only (opoint (point)))
 773               (beginning-of-line)
 774               (dired-add-entry-do-indentation marker-char)
 775               ;; don't expand `.' !
 776               (let ((default-directory directory))
 777                 (insert-directory filename
 778                                   (concat dired-actual-switches "d")))
 779               (dired-insert-set-properties opoint (point))
 780               (forward-line -1)
 781               ;; We want to have the non-directory part, only:
 782               (let* ((beg (dired-move-to-filename t)) ; error for strange output
 783                      (end (dired-move-to-end-of-filename)))
 784                 (setq filename (buffer-substring beg end))
 785                 (delete-region beg end)
 786                 (insert (file-name-nondirectory filename)))
 787               (if dired-after-readin-hook;; the subdir-alist is not affected...
 788                   (save-excursion;; ...so we can run it right now:
 789                     (save-restriction
 790                       (beginning-of-line)
 791                       (narrow-to-region (point) (save-excursion
 792                                                   (forward-line 1) (point)))
 793                       (run-hooks 'dired-after-readin-hook))))
 794               (dired-move-to-filename))
 795             ;; return nil if all went well
 796             nil))
 797     (if reason                          ; don't move away on failure
 798         (goto-char opoint))
 799     (not reason)))                      ; return t on success, nil else
 800
 801 ;; This is a separate function for the sake of nested dired format.
 802 (defun dired-add-entry-do-indentation (marker-char)
 803   ;; two spaces or a marker plus a space:
 804   (insert (if marker-char
 805               (if (integerp marker-char) marker-char dired-marker-char)
 806             ?\040)
 807           ?\040))
 808
 809 (defun dired-after-subdir-garbage (dir)
 810   ;; Return pos of first file line of DIR, skipping header and total
 811   ;; or wildcard lines.
 812   ;; Important: never moves into the next subdir.
 813   ;; DIR is assumed to be unhidden.
 814   ;; Will probably be redefined for VMS etc.
 815   (save-excursion
 816     (or (dired-goto-subdir dir) (error "This cannot happen"))
 817     (forward-line 1)
 818     (while (and (not (eolp))            ; don't cross subdir boundary
 819                 (not (dired-move-to-filename)))
 820         (forward-line 1))
 821     (point)))
 822
 823 ;;;###autoload
 824 (defun dired-remove-file (file)
 825   (dired-fun-in-all-buffers
 826    (file-name-directory file) (function dired-remove-entry) file))
 827
 828 (defun dired-remove-entry (file)
 829   (save-excursion
 830     (and (dired-goto-file file)
 831          (let (buffer-read-only)
 832            (delete-region (progn (beginning-of-line) (point))
 833                           (save-excursion (forward-line 1) (point)))))))
 834
 835 ;;;###autoload
 836 (defun dired-relist-file (file)
 837   (dired-fun-in-all-buffers (file-name-directory file)
 838                             (function dired-relist-entry) file))
 839
 840 (defun dired-relist-entry (file)
 841   ;; Relist the line for FILE, or just add it if it did not exist.
 842   ;; FILE must be an absolute pathname.
 843   (let (buffer-read-only marker)
 844     ;; If cursor is already on FILE's line delete-region will cause
 845     ;; save-excursion to fail because of floating makers,
 846     ;; moving point to beginning of line.  Sigh.
 847     (save-excursion
 848       (and (dired-goto-file file)
 849            (delete-region (progn (beginning-of-line)
 850                                  (setq marker (following-char))
 851                                  (point))
 852                           (save-excursion (forward-line 1) (point))))
 853       (setq file (directory-file-name file))
 854       (dired-add-entry file (if (eq ?\040 marker) nil marker)))))
 855 \f
 856 ;;; Copy, move/rename, making hard and symbolic links
 857
 858 (defvar dired-backup-overwrite nil
 859   "*Non-nil if Dired should ask about making backups before overwriting files.
 860 Special value `always' suppresses confirmation.")
 861
 862 (defvar dired-overwrite-confirmed)
 863
 864 (defun dired-handle-overwrite (to)
 865   ;; Save old version of a to be overwritten file TO.
 866   ;; `dired-overwrite-confirmed' and `overwrite-backup-query' are fluid vars
 867   ;; from dired-create-files.
 868   (if (and dired-backup-overwrite
 869            dired-overwrite-confirmed
 870            (or (eq 'always dired-backup-overwrite)
 871                (dired-query 'overwrite-backup-query
 872                         (format "Make backup for existing file `%s'? " to))))
 873       (let ((backup (car (find-backup-file-name to))))
 874         (rename-file to backup 0)       ; confirm overwrite of old backup
 875         (dired-relist-entry backup))))
 876
 877 ;;;###autoload
 878 (defun dired-copy-file (from to ok-flag)
 879   (dired-handle-overwrite to)
 880   (copy-file from to ok-flag dired-copy-preserve-time))
 881
 882 ;;;###autoload
 883 (defun dired-rename-file (from to ok-flag)
 884   (dired-handle-overwrite to)
 885   (rename-file from to ok-flag)         ; error is caught in -create-files
 886   ;; Silently rename the visited file of any buffer visiting this file.
 887   (and (get-file-buffer from)
 888        (save-excursion
 889          (set-buffer (get-file-buffer from))
 890          (let ((modflag (buffer-modified-p)))
 891            (set-visited-file-name to)
 892            (set-buffer-modified-p modflag))))
 893   (dired-remove-file from)
 894   ;; See if it's an inserted subdir, and rename that, too.
 895   (dired-rename-subdir from to))
 896
 897 (defun dired-rename-subdir (from-dir to-dir)
 898   (setq from-dir (file-name-as-directory from-dir)
 899         to-dir (file-name-as-directory to-dir))
 900   (dired-fun-in-all-buffers from-dir
 901                             (function dired-rename-subdir-1) from-dir to-dir)
 902   ;; Update visited file name of all affected buffers
 903   (let ((blist (buffer-list)))
 904     (while blist
 905       (save-excursion
 906         (set-buffer (car blist))
 907         (if (and buffer-file-name
 908                  (dired-in-this-tree buffer-file-name from-dir))
 909             (let ((modflag (buffer-modified-p))
 910                   (to-file (dired-replace-in-string
 911                             (concat "^" (regexp-quote from-dir))
 912                             to-dir
 913                             buffer-file-name)))
 914               (set-visited-file-name to-file)
 915               (set-buffer-modified-p modflag))))
 916       (setq blist (cdr blist)))))
 917
 918 (defun dired-rename-subdir-1 (dir to)
 919   ;; Rename DIR to TO in headerlines and dired-subdir-alist, if DIR or
 920   ;; one of its subdirectories is expanded in this buffer.
 921   (let ((alist dired-subdir-alist)
 922         (elt nil))
 923     (while alist
 924       (setq elt (car alist)
 925             alist (cdr alist))
 926       (if (dired-in-this-tree (car elt) dir)
 927           ;; ELT's subdir is affected by the rename
 928           (dired-rename-subdir-2 elt dir to)))
 929     (if (equal dir default-directory)
 930         ;; if top level directory was renamed, lots of things have to be
 931         ;; updated:
 932         (progn
 933           (dired-unadvertise dir)       ; we no longer dired DIR...
 934           (setq default-directory to
 935                 dired-directory (expand-file-name;; this is correct
 936                                  ;; with and without wildcards
 937                                  (file-name-nondirectory dired-directory)
 938                                  to))
 939           (let ((new-name (file-name-nondirectory
 940                            (directory-file-name dired-directory))))
 941             ;; try to rename buffer, but just leave old name if new
 942             ;; name would already exist (don't try appending "<%d>")
 943             (or (get-buffer new-name)
 944                 (rename-buffer new-name)))
 945           ;; ... we dired TO now:
 946           (dired-advertise)))))
 947
 948 (defun dired-rename-subdir-2 (elt dir to)
 949   ;; Update the headerline and dired-subdir-alist element of directory
 950   ;; described by alist-element ELT to reflect the moving of DIR to TO.
 951   ;; Thus, ELT describes either DIR itself or a subdir of DIR.
 952   (save-excursion
 953     (let ((regexp (regexp-quote (directory-file-name dir)))
 954           (newtext (directory-file-name to))
 955           buffer-read-only)
 956       (goto-char (dired-get-subdir-min elt))
 957       ;; Update subdir headerline in buffer
 958       (if (not (looking-at dired-subdir-regexp))
 959           (error "%s not found where expected - dired-subdir-alist broken?"
 960                  dir)
 961         (goto-char (match-beginning 1))
 962         (if (re-search-forward regexp (match-end 1) t)
 963             (replace-match newtext t t)
 964           (error "Expected to find `%s' in headerline of %s" dir (car elt))))
 965       ;; Update buffer-local dired-subdir-alist
 966       (setcar elt
 967               (dired-normalize-subdir
 968                (dired-replace-in-string regexp newtext (car elt)))))))
 969 \f
 970 ;; Cloning replace-match to work on strings instead of in buffer:
 971 ;; The FIXEDCASE parameter of replace-match is not implemented.
 972 ;;;###autoload
 973 (defun dired-string-replace-match (regexp string newtext
 974                                           &optional literal global)
 975   "Replace first match of REGEXP in STRING with NEWTEXT.
 976 If it does not match, nil is returned instead of the new string.
 977 Optional arg LITERAL means to take NEWTEXT literally.
 978 Optional arg GLOBAL means to replace all matches."
 979   (if global
 980         (let ((result "") (start 0) mb me)
 981           (while (string-match regexp string start)
 982             (setq mb (match-beginning 0)
 983                   me (match-end 0)
 984                   result (concat result
 985                                  (substring string start mb)
 986                                  (if literal
 987                                      newtext
 988                                    (dired-expand-newtext string newtext)))
 989                   start me))
 990           (if mb                        ; matched at least once
 991               (concat result (substring string start))
 992             nil))
 993     ;; not GLOBAL
 994     (if (not (string-match regexp string 0))
 995         nil
 996       (concat (substring string 0 (match-beginning 0))
 997               (if literal newtext (dired-expand-newtext string newtext))
 998               (substring string (match-end 0))))))
 999
1000 (defun dired-expand-newtext (string newtext)
1001   ;; Expand \& and \1..\9 (referring to STRING) in NEWTEXT, using match data.
1002   ;; Note that in Emacs 18 match data are clipped to current buffer
1003   ;; size...so the buffer should better not be smaller than STRING.
1004   (let ((pos 0)
1005         (len (length newtext))
1006         (expanded-newtext ""))
1007     (while (< pos len)
1008       (setq expanded-newtext
1009             (concat expanded-newtext
1010                     (let ((c (aref newtext pos)))
1011                       (if (= ?\\ c)
1012                           (cond ((= ?\& (setq c
1013                                               (aref newtext
1014                                                     (setq pos (1+ pos)))))
1015                                  (substring string
1016                                             (match-beginning 0)
1017                                             (match-end 0)))
1018                                 ((and (>= c ?1) (<= c ?9))
1019                                  ;; return empty string if N'th
1020                                  ;; sub-regexp did not match:
1021                                  (let ((n (- c ?0)))
1022                                    (if (match-beginning n)
1023                                        (substring string
1024                                                   (match-beginning n)
1025                                                   (match-end n))
1026                                      "")))
1027                                 (t
1028                                  (char-to-string c)))
1029                         (char-to-string c)))))
1030       (setq pos (1+ pos)))
1031     expanded-newtext))
1032 \f
1033 ;; The basic function for half a dozen variations on cp/mv/ln/ln -s.
1034 (defun dired-create-files (file-creator operation fn-list name-constructor
1035                                         &optional marker-char)
1036
1037 ;; Create a new file for each from a list of existing files.  The user
1038 ;; is queried, dired buffers are updated, and at the end a success or
1039 ;; failure message is displayed
1040
1041 ;; FILE-CREATOR must accept three args: oldfile newfile ok-if-already-exists
1042
1043 ;; It is called for each file and must create newfile, the entry of
1044 ;; which will be added.  The user will be queried if the file already
1045 ;; exists.  If oldfile is removed by FILE-CREATOR (i.e, it is a
1046 ;; rename), it is FILE-CREATOR's responsibility to update dired
1047 ;; buffers.  FILE-CREATOR must abort by signalling a file-error if it
1048 ;; could not create newfile.  The error is caught and logged.
1049
1050 ;; OPERATION (a capitalized string, e.g. `Copy') describes the
1051 ;; operation performed.  It is used for error logging.
1052
1053 ;; FN-LIST is the list of files to copy (full absolute pathnames).
1054
1055 ;; NAME-CONSTRUCTOR returns a newfile for every oldfile, or nil to
1056 ;; skip.  If it skips files for other reasons than a direct user
1057 ;; query, it is supposed to tell why (using dired-log).
1058
1059 ;; Optional MARKER-CHAR is a character with which to mark every
1060 ;; newfile's entry, or t to use the current marker character if the
1061 ;; oldfile was marked.
1062
1063   (let (failures skipped (success-count 0) (total (length fn-list)))
1064     (let (to overwrite-query
1065              overwrite-backup-query)    ; for dired-handle-overwrite
1066       (mapcar
1067        (function
1068         (lambda (from)
1069           (setq to (funcall name-constructor from))
1070           (if (equal to from)
1071               (progn
1072                 (setq to nil)
1073                 (dired-log "Cannot %s to same file: %s\n"
1074                            (downcase operation) from)))
1075           (if (not to)
1076               (setq skipped (cons (dired-make-relative from) skipped))
1077             (let* ((overwrite (file-exists-p to))
1078                    (dired-overwrite-confirmed   ; for dired-handle-overwrite
1079                     (and overwrite
1080                          (let ((help-form '(format "\
1081 Type SPC or `y' to overwrite file `%s',
1082 DEL or `n' to skip to next,
1083 ESC or `q' to not overwrite any of the remaining files,
1084 `!' to overwrite all remaining files with no more questions." to)))
1085                            (dired-query 'overwrite-query
1086                                         "Overwrite `%s'?" to))))
1087                    ;; must determine if FROM is marked before file-creator
1088                    ;; gets a chance to delete it (in case of a move).
1089                    (actual-marker-char
1090                     (cond  ((integerp marker-char) marker-char)
1091                            (marker-char (dired-file-marker from)) ; slow
1092                            (t nil))))
1093               (condition-case err
1094                   (progn
1095                     (funcall file-creator from to dired-overwrite-confirmed)
1096                     (if overwrite
1097                         ;; If we get here, file-creator hasn't been aborted
1098                         ;; and the old entry (if any) has to be deleted
1099                         ;; before adding the new entry.
1100                         (dired-remove-file to))
1101                     (setq success-count (1+ success-count))
1102                     (message "%s: %d of %d" operation success-count total)
1103                     (dired-add-file to actual-marker-char))
1104                 (file-error             ; FILE-CREATOR aborted
1105                  (progn
1106                    (setq failures (cons (dired-make-relative from) failures))
1107                    (dired-log "%s `%s' to `%s' failed:\n%s\n"
1108                               operation from to err))))))))
1109        fn-list))
1110     (cond
1111      (failures
1112       (dired-log-summary
1113        (format "%s failed for %d of %d file%s"
1114                 operation (length failures) total
1115                 (dired-plural-s total))
1116        failures))
1117      (skipped
1118       (dired-log-summary
1119        (format "%s: %d of %d file%s skipped"
1120                 operation (length skipped) total
1121                 (dired-plural-s total))
1122        skipped))
1123      (t
1124       (message "%s: %s file%s"
1125                operation success-count (dired-plural-s success-count)))))
1126   (dired-move-to-filename))
1127 \f
1128 (defun dired-do-create-files (op-symbol file-creator operation arg
1129                                              &optional marker-char op1
1130                                              how-to)
1131   ;; Create a new file for each marked file.
1132   ;; Prompts user for target, which is a directory in which to create
1133   ;;   the new files.  Target may be a plain file if only one marked
1134   ;;   file exists.
1135   ;; OP-SYMBOL is the symbol for the operation.  Function `dired-mark-pop-up'
1136   ;;   will determine whether pop-ups are appropriate for this OP-SYMBOL.
1137   ;; FILE-CREATOR and OPERATION as in dired-create-files.
1138   ;; ARG as in dired-get-marked-files.
1139   ;; Optional arg OP1 is an alternate form for OPERATION if there is
1140   ;;   only one file.
1141   ;; Optional arg MARKER-CHAR as in dired-create-files.
1142   ;; Optional arg HOW-TO determines how to treat target:
1143   ;;   If HOW-TO is not given (or nil), and target is a directory, the
1144   ;;     file(s) are created inside the target directory.  If target
1145   ;;     is not a directory, there must be exactly one marked file,
1146   ;;     else error.
1147   ;;   If HOW-TO is t, then target is not modified.  There must be
1148   ;;     exactly one marked file, else error.
1149   ;; Else HOW-TO is assumed to be a function of one argument, target,
1150   ;;     that looks at target and returns a value for the into-dir
1151   ;;     variable.  The function dired-into-dir-with-symlinks is provided
1152   ;;     for the case (common when creating symlinks) that symbolic
1153   ;;     links to directories are not to be considered as directories
1154   ;;     (as file-directory-p would if HOW-TO had been nil).
1155   (or op1 (setq op1 operation))
1156   (let* ((fn-list (dired-get-marked-files nil arg))
1157          (fn-count (length fn-list))
1158          (target (expand-file-name
1159                    (dired-mark-read-file-name
1160                     (concat (if (= 1 fn-count) op1 operation) " %s to: ")
1161                     (dired-dwim-target-directory)
1162                     op-symbol arg (mapcar (function dired-make-relative) fn-list))))
1163          (into-dir (cond ((null how-to) (file-directory-p target))
1164                          ((eq how-to t) nil)
1165                          (t (funcall how-to target)))))
1166     (if (and (> fn-count 1)
1167              (not into-dir))
1168         (error "Marked %s: target must be a directory: %s" operation target))
1169     ;; rename-file bombs when moving directories unless we do this:
1170     (or into-dir (setq target (directory-file-name target)))
1171     (dired-create-files
1172      file-creator operation fn-list
1173      (if into-dir                       ; target is a directory
1174          ;; This function uses fluid vars into-dir and target when called
1175          ;; inside dired-create-files:
1176          (function (lambda (from)
1177                      (expand-file-name (file-name-nondirectory from) target)))
1178        (function (lambda (from) target)))
1179      marker-char)))
1180
1181 ;; Read arguments for a marked-files command that wants a file name,
1182 ;; perhaps popping up the list of marked files.
1183 ;; ARG is the prefix arg and indicates whether the files came from
1184 ;; marks (ARG=nil) or a repeat factor (integerp ARG).
1185 ;; If the current file was used, the list has but one element and ARG
1186 ;; does not matter. (It is non-nil, non-integer in that case, namely '(4)).
1187
1188 (defun dired-mark-read-file-name (prompt dir op-symbol arg files)
1189   (dired-mark-pop-up
1190    nil op-symbol files
1191    (function read-file-name)
1192    (format prompt (dired-mark-prompt arg files)) dir))
1193
1194 (defun dired-dwim-target-directory ()
1195   ;; Try to guess which target directory the user may want.
1196   ;; If there is a dired buffer displayed in the next window, use
1197   ;; its current subdir, else use current subdir of this dired buffer.
1198   (let ((this-dir (and (eq major-mode 'dired-mode)
1199                        (dired-current-directory))))
1200     ;; non-dired buffer may want to profit from this function, e.g. vm-uudecode
1201     (if dired-dwim-target
1202         (let* ((other-buf (window-buffer (next-window)))
1203                (other-dir (save-excursion
1204                             (set-buffer other-buf)
1205                             (and (eq major-mode 'dired-mode)
1206                                  (dired-current-directory)))))
1207           (or other-dir this-dir))
1208       this-dir)))
1209 \f
1210 ;;;###autoload
1211 (defun dired-create-directory (directory)
1212   "Create a directory called DIRECTORY."
1213   (interactive
1214    (list (read-file-name "Create directory: " (dired-current-directory))))
1215   (let ((expanded (directory-file-name (expand-file-name directory))))
1216     (make-directory expanded)
1217     (dired-add-file expanded)
1218     (dired-move-to-filename)))
1219
1220 (defun dired-into-dir-with-symlinks (target)
1221   (and (file-directory-p target)
1222        (not (file-symlink-p target))))
1223 ;; This may not always be what you want, especially if target is your
1224 ;; home directory and it happens to be a symbolic link, as is often the
1225 ;; case with NFS and automounters.  Or if you want to make symlinks
1226 ;; into directories that themselves are only symlinks, also quite
1227 ;; common.
1228
1229 ;; So we don't use this function as value for HOW-TO in
1230 ;; dired-do-symlink, which has the minor disadvantage of
1231 ;; making links *into* a symlinked-dir, when you really wanted to
1232 ;; *overwrite* that symlink.  In that (rare, I guess) case, you'll
1233 ;; just have to remove that symlink by hand before making your marked
1234 ;; symlinks.
1235
1236 ;;;###autoload
1237 (defun dired-do-copy (&optional arg)
1238   "Copy all marked (or next ARG) files, or copy the current file.
1239 This normally preserves the last-modified date when copying.
1240 When operating on just the current file, you specify the new name.
1241 When operating on multiple or marked files, you specify a directory
1242 and new symbolic links are made in that directory
1243 with the same names that the files currently have."
1244   (interactive "P")
1245   (dired-do-create-files 'copy (function dired-copy-file)
1246                            (if dired-copy-preserve-time "Copy [-p]" "Copy")
1247                            arg dired-keep-marker-copy))
1248
1249 ;;;###autoload
1250 (defun dired-do-symlink (&optional arg)
1251   "Make symbolic links to current file or all marked (or next ARG) files.
1252 When operating on just the current file, you specify the new name.
1253 When operating on multiple or marked files, you specify a directory
1254 and new symbolic links are made in that directory
1255 with the same names that the files currently have."
1256   (interactive "P")
1257   (dired-do-create-files 'symlink (function make-symbolic-link)
1258                            "Symlink" arg dired-keep-marker-symlink))
1259
1260 ;;;###autoload
1261 (defun dired-do-hardlink (&optional arg)
1262   "Add names (hard links) current file or all marked (or next ARG) files.
1263 When operating on just the current file, you specify the new name.
1264 When operating on multiple or marked files, you specify a directory
1265 and new hard links are made in that directory
1266 with the same names that the files currently have."
1267   (interactive "P")
1268   (dired-do-create-files 'hardlink (function add-name-to-file)
1269                            "Hardlink" arg dired-keep-marker-hardlink))
1270
1271 ;;;###autoload
1272 (defun dired-do-rename (&optional arg)
1273   "Rename current file or all marked (or next ARG) files.
1274 When renaming just the current file, you specify the new name.
1275 When renaming multiple or marked files, you specify a directory."
1276   (interactive "P")
1277   (dired-do-create-files 'move (function dired-rename-file)
1278                          "Move" arg dired-keep-marker-rename "Rename"))
1279 ;;;###end dired-cp.el
1280 \f
1281 ;;; 5K
1282 ;;;###begin dired-re.el
1283 (defun dired-do-create-files-regexp
1284   (file-creator operation arg regexp newname &optional whole-path marker-char)
1285   ;; Create a new file for each marked file using regexps.
1286   ;; FILE-CREATOR and OPERATION as in dired-create-files.
1287   ;; ARG as in dired-get-marked-files.
1288   ;; Matches each marked file against REGEXP and constructs the new
1289   ;;   filename from NEWNAME (like in function replace-match).
1290   ;; Optional arg WHOLE-PATH means match/replace the whole pathname
1291   ;;   instead of only the non-directory part of the file.
1292   ;; Optional arg MARKER-CHAR as in dired-create-files.
1293   (let* ((fn-list (dired-get-marked-files nil arg))
1294          (fn-count (length fn-list))
1295          (operation-prompt (concat operation " `%s' to `%s'?"))
1296          (rename-regexp-help-form (format "\
1297 Type SPC or `y' to %s one match, DEL or `n' to skip to next,
1298 `!' to %s all remaining matches with no more questions."
1299                                           (downcase operation)
1300                                           (downcase operation)))
1301          (regexp-name-constructor
1302           ;; Function to construct new filename using REGEXP and NEWNAME:
1303           (if whole-path                ; easy (but rare) case
1304               (function
1305                (lambda (from)
1306                  (let ((to (dired-string-replace-match regexp from newname))
1307                        ;; must bind help-form directly around call to
1308                        ;; dired-query
1309                        (help-form rename-regexp-help-form))
1310                    (if to
1311                        (and (dired-query 'rename-regexp-query
1312                                          operation-prompt
1313                                          from
1314                                          to)
1315                             to)
1316                      (dired-log "%s: %s did not match regexp %s\n"
1317                                 operation from regexp)))))
1318             ;; not whole-path, replace non-directory part only
1319             (function
1320              (lambda (from)
1321                (let* ((new (dired-string-replace-match
1322                             regexp (file-name-nondirectory from) newname))
1323                       (to (and new      ; nil means there was no match
1324                                (expand-file-name new
1325                                                  (file-name-directory from))))
1326                       (help-form rename-regexp-help-form))
1327                  (if to
1328                      (and (dired-query 'rename-regexp-query
1329                                        operation-prompt
1330                                        (dired-make-relative from)
1331                                        (dired-make-relative to))
1332                           to)
1333                    (dired-log "%s: %s did not match regexp %s\n"
1334                               operation (file-name-nondirectory from) regexp)))))))
1335          rename-regexp-query)
1336     (dired-create-files
1337      file-creator operation fn-list regexp-name-constructor marker-char)))
1338
1339 (defun dired-mark-read-regexp (operation)
1340   ;; Prompt user about performing OPERATION.
1341   ;; Read and return list of: regexp newname arg whole-path.
1342   (let* ((whole-path
1343           (equal 0 (prefix-numeric-value current-prefix-arg)))
1344          (arg
1345           (if whole-path nil current-prefix-arg))
1346          (regexp
1347           (dired-read-regexp
1348            (concat (if whole-path "Path " "") operation " from (regexp): ")))
1349          (newname
1350           (read-string
1351            (concat (if whole-path "Path " "") operation " " regexp " to: "))))
1352     (list regexp newname arg whole-path)))
1353
1354 ;;;###autoload
1355 (defun dired-do-rename-regexp (regexp newname &optional arg whole-path)
1356   "Rename marked files containing REGEXP to NEWNAME.
1357 As each match is found, the user must type a character saying
1358   what to do with it.  For directions, type \\[help-command] at that time.
1359 NEWNAME may contain \\=\\<n> or \\& as in `query-replace-regexp'.
1360 REGEXP defaults to the last regexp used.
1361 With a zero prefix arg, renaming by regexp affects the complete
1362   pathname - usually only the non-directory part of file names is used
1363   and changed."
1364   (interactive (dired-mark-read-regexp "Rename"))
1365   (dired-do-create-files-regexp
1366    (function dired-rename-file)
1367    "Rename" arg regexp newname whole-path dired-keep-marker-rename))
1368
1369 ;;;###autoload
1370 (defun dired-do-copy-regexp (regexp newname &optional arg whole-path)
1371   "Copy all marked files containing REGEXP to NEWNAME.
1372 See function `dired-rename-regexp' for more info."
1373   (interactive (dired-mark-read-regexp "Copy"))
1374   (dired-do-create-files-regexp
1375    (function dired-copy-file)
1376    (if dired-copy-preserve-time "Copy [-p]" "Copy")
1377    arg regexp newname whole-path dired-keep-marker-copy))
1378
1379 ;;;###autoload
1380 (defun dired-do-hardlink-regexp (regexp newname &optional arg whole-path)
1381   "Hardlink all marked files containing REGEXP to NEWNAME.
1382 See function `dired-rename-regexp' for more info."
1383   (interactive (dired-mark-read-regexp "HardLink"))
1384   (dired-do-create-files-regexp
1385    (function add-name-to-file)
1386    "HardLink" arg regexp newname whole-path dired-keep-marker-hardlink))
1387
1388 ;;;###autoload
1389 (defun dired-do-symlink-regexp (regexp newname &optional arg whole-path)
1390   "Symlink all marked files containing REGEXP to NEWNAME.
1391 See function `dired-rename-regexp' for more info."
1392   (interactive (dired-mark-read-regexp "SymLink"))
1393   (dired-do-create-files-regexp
1394    (function make-symbolic-link)
1395    "SymLink" arg regexp newname whole-path dired-keep-marker-symlink))
1396
1397 (defun dired-create-files-non-directory
1398   (file-creator basename-constructor operation arg)
1399   ;; Perform FILE-CREATOR on the non-directory part of marked files
1400   ;; using function BASENAME-CONSTRUCTOR, with query for each file.
1401   ;; OPERATION like in dired-create-files, ARG as in dired-get-marked-files.
1402   (let (rename-non-directory-query)
1403     (dired-create-files
1404      file-creator
1405      operation
1406      (dired-get-marked-files nil arg)
1407      (function
1408       (lambda (from)
1409         (let ((to (concat (file-name-directory from)
1410                           (funcall basename-constructor
1411                                    (file-name-nondirectory from)))))
1412           (and (let ((help-form (format "\
1413 Type SPC or `y' to %s one file, DEL or `n' to skip to next,
1414 `!' to %s all remaining matches with no more questions."
1415                                         (downcase operation)
1416                                         (downcase operation))))
1417                  (dired-query 'rename-non-directory-query
1418                               (concat operation " `%s' to `%s'")
1419                               (dired-make-relative from)
1420                               (dired-make-relative to)))
1421                to))))
1422      dired-keep-marker-rename)))
1423
1424 (defun dired-rename-non-directory (basename-constructor operation arg)
1425   (dired-create-files-non-directory
1426    (function dired-rename-file)
1427    basename-constructor operation arg))
1428
1429 ;;;###autoload
1430 (defun dired-upcase (&optional arg)
1431   "Rename all marked (or next ARG) files to upper case."
1432   (interactive "P")
1433   (dired-rename-non-directory (function upcase) "Rename upcase" arg))
1434
1435 ;;;###autoload
1436 (defun dired-downcase (&optional arg)
1437   "Rename all marked (or next ARG) files to lower case."
1438   (interactive "P")
1439   (dired-rename-non-directory (function downcase) "Rename downcase" arg))
1440
1441 ;;;###end dired-re.el
1442 \f
1443 ;;; 13K
1444 ;;;###begin dired-ins.el
1445
1446 ;;;###autoload
1447 (defun dired-maybe-insert-subdir (dirname &optional
1448                                           switches no-error-if-not-dir-p)
1449   "Insert this subdirectory into the same dired buffer.
1450 If it is already present, just move to it (type \\[dired-do-redisplay] to refresh),
1451   else inserts it at its natural place (as `ls -lR' would have done).
1452 With a prefix arg, you may edit the ls switches used for this listing.
1453   You can add `R' to the switches to expand the whole tree starting at
1454   this subdirectory.
1455 This function takes some pains to conform to `ls -lR' output."
1456   (interactive
1457    (list (dired-get-filename)
1458          (if current-prefix-arg
1459              (read-string "Switches for listing: " dired-actual-switches))))
1460   (let ((opoint (point)))
1461     ;; We don't need a marker for opoint as the subdir is always
1462     ;; inserted *after* opoint.
1463     (setq dirname (file-name-as-directory dirname))
1464     (or (and (not switches)
1465              (dired-goto-subdir dirname))
1466         (dired-insert-subdir dirname switches no-error-if-not-dir-p))
1467     ;; Push mark so that it's easy to find back.  Do this after the
1468     ;; insert message so that the user sees the `Mark set' message.
1469     (push-mark opoint)))
1470
1471 (defun dired-insert-subdir (dirname &optional switches no-error-if-not-dir-p)
1472   "Insert this subdirectory into the same dired buffer.
1473 If it is already present, overwrites previous entry,
1474   else inserts it at its natural place (as `ls -lR' would have done).
1475 With a prefix arg, you may edit the `ls' switches used for this listing.
1476   You can add `R' to the switches to expand the whole tree starting at
1477   this subdirectory.
1478 This function takes some pains to conform to `ls -lR' output."
1479   ;; NO-ERROR-IF-NOT-DIR-P needed for special filesystems like
1480   ;; Prospero where dired-ls does the right thing, but
1481   ;; file-directory-p has not been redefined.
1482   (interactive
1483    (list (dired-get-filename)
1484          (if current-prefix-arg
1485              (read-string "Switches for listing: " dired-actual-switches))))
1486   (setq dirname (file-name-as-directory (expand-file-name dirname)))
1487   (dired-insert-subdir-validate dirname switches)
1488   (or no-error-if-not-dir-p
1489       (file-directory-p dirname)
1490       (error  "Attempt to insert a non-directory: %s" dirname))
1491   (let ((elt (assoc dirname dired-subdir-alist))
1492          switches-have-R mark-alist case-fold-search buffer-read-only)
1493     ;; case-fold-search is nil now, so we can test for capital `R':
1494     (if (setq switches-have-R (and switches (string-match "R" switches)))
1495         ;; avoid duplicated subdirs
1496         (setq mark-alist (dired-kill-tree dirname t)))
1497     (if elt
1498         ;; If subdir is already present, remove it and remember its marks
1499         (setq mark-alist (nconc (dired-insert-subdir-del elt) mark-alist))
1500       (dired-insert-subdir-newpos dirname)) ; else compute new position
1501     (dired-insert-subdir-doupdate
1502      dirname elt (dired-insert-subdir-doinsert dirname switches))
1503     (if switches-have-R (dired-build-subdir-alist))
1504     (dired-initial-position dirname)
1505     (save-excursion (dired-mark-remembered mark-alist))))
1506
1507 ;; This is a separate function for dired-vms.
1508 (defun dired-insert-subdir-validate (dirname &optional switches)
1509   ;; Check that it is valid to insert DIRNAME with SWITCHES.
1510   ;; Signal an error if invalid (e.g. user typed `i' on `..').
1511   (or (dired-in-this-tree dirname (expand-file-name default-directory))
1512       (error  "%s: not in this directory tree" dirname))
1513   (if switches
1514       (let (case-fold-search)
1515         (mapcar
1516          (function
1517           (lambda (x)
1518             (or (eq (null (string-match x switches))
1519                     (null (string-match x dired-actual-switches)))
1520                 (error "Can't have dirs with and without -%s switches together"
1521                        x))))
1522          ;; all switches that make a difference to dired-get-filename:
1523          '("F" "b")))))
1524
1525 (defun dired-alist-add (dir new-marker)
1526   ;; Add new DIR at NEW-MARKER.  Sort alist.
1527   (dired-alist-add-1 dir new-marker)
1528   (dired-alist-sort))
1529
1530 (defun dired-alist-sort ()
1531   ;; Keep the alist sorted on buffer position.
1532   (setq dired-subdir-alist
1533         (sort dired-subdir-alist
1534               (function (lambda (elt1 elt2)
1535                           (> (dired-get-subdir-min elt1)
1536                              (dired-get-subdir-min elt2)))))))
1537
1538 (defun dired-kill-tree (dirname &optional remember-marks)
1539   ;;"Kill all proper subdirs of DIRNAME, excluding DIRNAME itself.
1540   ;; With optional arg REMEMBER-MARKS, return an alist of marked files."
1541   (interactive "DKill tree below directory: ")
1542   (let ((s-alist dired-subdir-alist) dir m-alist)
1543     (while s-alist
1544       (setq dir (car (car s-alist))
1545             s-alist (cdr s-alist))
1546       (if (and (not (string-equal dir dirname))
1547                (dired-in-this-tree dir dirname)
1548                (dired-goto-subdir dir))
1549           (setq m-alist (nconc (dired-kill-subdir remember-marks) m-alist))))
1550     m-alist))
1551
1552 (defun dired-insert-subdir-newpos (new-dir)
1553   ;; Find pos for new subdir, according to tree order.
1554   ;;(goto-char (point-max))
1555   (let ((alist dired-subdir-alist) elt dir pos new-pos)
1556     (while alist
1557       (setq elt (car alist)
1558             alist (cdr alist)
1559             dir (car elt)
1560             pos (dired-get-subdir-min elt))
1561       (if (dired-tree-lessp dir new-dir)
1562           ;; Insert NEW-DIR after DIR
1563           (setq new-pos (dired-get-subdir-max elt)
1564                 alist nil)))
1565     (goto-char new-pos))
1566   ;; want a separating newline between subdirs
1567   (or (eobp)
1568       (forward-line -1))
1569   (insert "\n")
1570   (point))
1571
1572 (defun dired-insert-subdir-del (element)
1573   ;; Erase an already present subdir (given by ELEMENT) from buffer.
1574   ;; Move to that buffer position.  Return a mark-alist.
1575   (let ((begin-marker (dired-get-subdir-min element)))
1576     (goto-char begin-marker)
1577     ;; Are at beginning of subdir (and inside it!).  Now determine its end:
1578     (goto-char (dired-subdir-max))
1579     (or (eobp);; want a separating newline _between_ subdirs:
1580         (forward-char -1))
1581     (prog1
1582         (dired-remember-marks begin-marker (point))
1583       (delete-region begin-marker (point)))))
1584
1585 (defun dired-insert-subdir-doinsert (dirname switches)
1586   ;; Insert ls output after point and put point on the correct
1587   ;; position for the subdir alist.
1588   ;; Return the boundary of the inserted text (as list of BEG and END).
1589   (let ((begin (point)) end)
1590     (message "Reading directory %s..." dirname)
1591     (let ((dired-actual-switches
1592            (or switches
1593                (dired-replace-in-string "R" "" dired-actual-switches))))
1594       (if (equal dirname (car (car (reverse dired-subdir-alist))))
1595           ;; top level directory may contain wildcards:
1596           (dired-readin-insert dired-directory)
1597         (let ((opoint (point)))
1598           (insert-directory dirname dired-actual-switches nil t)
1599           (dired-insert-set-properties opoint (point)))))
1600     (message "Reading directory %s...done" dirname)
1601     (setq end (point-marker))
1602     (indent-rigidly begin end 2)
1603     ;;  call dired-insert-headerline afterwards, as under VMS dired-ls
1604     ;;  does insert the headerline itself and the insert function just
1605     ;;  moves point.
1606     ;;  Need a marker for END as this inserts text.
1607     (goto-char begin)
1608     (dired-insert-headerline dirname)
1609     ;; point is now like in dired-build-subdir-alist
1610     (prog1
1611         (list begin (marker-position end))
1612       (set-marker end nil))))
1613
1614 (defun dired-insert-subdir-doupdate (dirname elt beg-end)
1615   ;; Point is at the correct subdir alist position for ELT,
1616   ;; BEG-END is the subdir-region (as list of begin and end).
1617   (if elt                               ; subdir was already present
1618       ;; update its position (should actually be unchanged)
1619       (set-marker (dired-get-subdir-min elt) (point-marker))
1620     (dired-alist-add dirname (point-marker)))
1621   ;; The hook may depend on the subdir-alist containing the just
1622   ;; inserted subdir, so run it after dired-alist-add:
1623   (if dired-after-readin-hook
1624       (save-excursion
1625         (let ((begin (nth 0 beg-end))
1626               (end (nth 1 beg-end)))
1627           (goto-char begin)
1628           (save-restriction
1629             (narrow-to-region begin end)
1630             ;; hook may add or delete lines, but the subdir boundary
1631             ;; marker floats
1632             (run-hooks 'dired-after-readin-hook))))))
1633
1634 (defun dired-tree-lessp (dir1 dir2)
1635   ;; Lexicographic order on pathname components, like `ls -lR':
1636   ;; DIR1 < DIR2 iff DIR1 comes *before* DIR2 in an `ls -lR' listing,
1637   ;;   i.e., iff DIR1 is a (grand)parent dir of DIR2,
1638   ;;   or DIR1 and DIR2 are in the same parentdir and their last
1639   ;;   components are string-lessp.
1640   ;; Thus ("/usr/" "/usr/bin") and ("/usr/a/" "/usr/b/") are tree-lessp.
1641   ;; string-lessp could arguably be replaced by file-newer-than-file-p
1642   ;;   if dired-actual-switches contained `t'.
1643   (setq dir1 (file-name-as-directory dir1)
1644         dir2 (file-name-as-directory dir2))
1645   (let ((components-1 (dired-split "/" dir1))
1646         (components-2 (dired-split "/" dir2)))
1647     (while (and components-1
1648                 components-2
1649                 (equal (car components-1) (car components-2)))
1650       (setq components-1 (cdr components-1)
1651             components-2 (cdr components-2)))
1652     (let ((c1 (car components-1))
1653           (c2 (car components-2)))
1654
1655       (cond ((and c1 c2)
1656              (string-lessp c1 c2))
1657             ((and (null c1) (null c2))
1658              nil)                       ; they are equal, not lessp
1659             ((null c1)                  ; c2 is a subdir of c1: c1<c2
1660              t)
1661             ((null c2)                  ; c1 is a subdir of c2: c1>c2
1662              nil)
1663             (t (error "This can't happen"))))))
1664
1665 ;; There should be a builtin split function - inverse to mapconcat.
1666 (defun dired-split (pat str &optional limit)
1667   "Splitting on regexp PAT, turn string STR into a list of substrings.
1668 Optional third arg LIMIT (>= 1) is a limit to the length of the
1669 resulting list.
1670 Thus, if SEP is a regexp that only matches itself,
1671
1672    (mapconcat 'identity (dired-split SEP STRING) SEP)
1673
1674 is always equal to STRING."
1675   (let* ((start (string-match pat str))
1676          (result (list (substring str 0 start)))
1677          (count 1)
1678          (end (if start (match-end 0))))
1679     (if end                             ; else nothing left
1680         (while (and (or (not (integerp limit))
1681                         (< count limit))
1682                     (string-match pat str end))
1683           (setq start (match-beginning 0)
1684                 count (1+ count)
1685                 result (cons (substring str end start) result)
1686                 end (match-end 0)
1687                 start end)
1688           ))
1689     (if (and (or (not (integerp limit))
1690                  (< count limit))
1691              end)                       ; else nothing left
1692         (setq result
1693               (cons (substring str end) result)))
1694     (nreverse result)))
1695 \f
1696 ;;; moving by subdirectories
1697
1698 ;;;###autoload
1699 (defun dired-prev-subdir (arg &optional no-error-if-not-found no-skip)
1700   "Go to previous subdirectory, regardless of level.
1701 When called interactively and not on a subdir line, go to this subdir's line."
1702   ;;(interactive "p")
1703   (interactive
1704    (list (if current-prefix-arg
1705              (prefix-numeric-value current-prefix-arg)
1706            ;; if on subdir start already, don't stay there!
1707            (if (dired-get-subdir) 1 0))))
1708   (dired-next-subdir (- arg) no-error-if-not-found no-skip))
1709
1710 (defun dired-subdir-min ()
1711   (save-excursion
1712     (if (not (dired-prev-subdir 0 t t))
1713         (error "Not in a subdir!")
1714       (point))))
1715
1716 ;;;###autoload
1717 (defun dired-goto-subdir (dir)
1718   "Go to end of header line of DIR in this dired buffer.
1719 Return value of point on success, otherwise return nil.
1720 The next char is either \\n, or \\r if DIR is hidden."
1721   (interactive
1722    (prog1                               ; let push-mark display its message
1723        (list (expand-file-name
1724               (completing-read "Goto in situ directory: " ; prompt
1725                                dired-subdir-alist ; table
1726                                nil      ; predicate
1727                                t        ; require-match
1728                                (dired-current-directory))))
1729      (push-mark)))
1730   (setq dir (file-name-as-directory dir))
1731   (let ((elt (assoc dir dired-subdir-alist)))
1732     (and elt
1733          (goto-char (dired-get-subdir-min elt))
1734          ;; dired-subdir-hidden-p and dired-add-entry depend on point being
1735          ;; at either \r or \n after this function succeeds.
1736          (progn (skip-chars-forward "^\r\n")
1737                 (point)))))
1738 \f
1739 ;;;###autoload
1740 (defun dired-mark-subdir-files ()
1741   "Mark all files except `.' and `..'."
1742   (interactive "P")
1743   (let ((p-min (dired-subdir-min)))
1744     (dired-mark-files-in-region p-min (dired-subdir-max))))
1745
1746 ;;;###autoload
1747 (defun dired-kill-subdir (&optional remember-marks)
1748   "Remove all lines of current subdirectory.
1749 Lower levels are unaffected."
1750   ;; With optional REMEMBER-MARKS, return a mark-alist.
1751   (interactive)
1752   (let ((beg (dired-subdir-min))
1753         (end (dired-subdir-max))
1754         buffer-read-only cur-dir)
1755     (setq cur-dir (dired-current-directory))
1756     (if (equal cur-dir default-directory)
1757         (error "Attempt to kill top level directory"))
1758     (prog1
1759         (if remember-marks (dired-remember-marks beg end))
1760       (delete-region beg end)
1761       (if (eobp)                        ; don't leave final blank line
1762           (delete-char -1))
1763       (dired-unsubdir cur-dir))))
1764
1765 (defun dired-unsubdir (dir)
1766   ;; Remove DIR from the alist
1767   (setq dired-subdir-alist
1768         (delq (assoc dir dired-subdir-alist) dired-subdir-alist)))
1769
1770 ;;;###autoload
1771 (defun dired-tree-up (arg)
1772   "Go up ARG levels in the dired tree."
1773   (interactive "p")
1774   (let ((dir (dired-current-directory)))
1775     (while (>= arg 1)
1776       (setq arg (1- arg)
1777             dir (file-name-directory (directory-file-name dir))))
1778     ;;(setq dir (expand-file-name dir))
1779     (or (dired-goto-subdir dir)
1780         (error "Cannot go up to %s - not in this tree." dir))))
1781
1782 ;;;###autoload
1783 (defun dired-tree-down ()
1784   "Go down in the dired tree."
1785   (interactive)
1786   (let ((dir (dired-current-directory)) ; has slash
1787         pos case-fold-search)           ; filenames are case sensitive
1788     (let ((rest (reverse dired-subdir-alist)) elt)
1789       (while rest
1790         (setq elt (car rest)
1791               rest (cdr rest))
1792         (if (dired-in-this-tree (directory-file-name (car elt)) dir)
1793             (setq rest nil
1794                   pos (dired-goto-subdir (car elt))))))
1795     (if pos
1796         (goto-char pos)
1797       (error "At the bottom"))))
1798 \f
1799 ;;; hiding
1800
1801 (defun dired-unhide-subdir ()
1802   (let (buffer-read-only)
1803     (subst-char-in-region (dired-subdir-min) (dired-subdir-max) ?\r ?\n)))
1804
1805 (defun dired-hide-check ()
1806   (or selective-display
1807       (error "selective-display must be t for subdir hiding to work!")))
1808
1809 (defun dired-subdir-hidden-p (dir)
1810   (and selective-display
1811        (save-excursion
1812          (dired-goto-subdir dir)
1813          (looking-at "\r"))))
1814
1815 ;;;###autoload
1816 (defun dired-hide-subdir (arg)
1817   "Hide or unhide the current subdirectory and move to next directory.
1818 Optional prefix arg is a repeat factor.
1819 Use \\[dired-hide-all] to (un)hide all directories."
1820   (interactive "p")
1821   (dired-hide-check)
1822   (while (>=  (setq arg (1- arg)) 0)
1823     (let* ((cur-dir (dired-current-directory))
1824            (hidden-p (dired-subdir-hidden-p cur-dir))
1825            (elt (assoc cur-dir dired-subdir-alist))
1826            (end-pos (1- (dired-get-subdir-max elt)))
1827            buffer-read-only)
1828       ;; keep header line visible, hide rest
1829       (goto-char (dired-get-subdir-min elt))
1830       (skip-chars-forward "^\n\r")
1831       (if hidden-p
1832           (subst-char-in-region (point) end-pos ?\r ?\n)
1833         (subst-char-in-region (point) end-pos ?\n ?\r)))
1834     (dired-next-subdir 1 t)))
1835
1836 ;;;###autoload
1837 (defun dired-hide-all (arg)
1838   "Hide all subdirectories, leaving only their header lines.
1839 If there is already something hidden, make everything visible again.
1840 Use \\[dired-hide-subdir] to (un)hide a particular subdirectory."
1841   (interactive "P")
1842   (dired-hide-check)
1843   (let (buffer-read-only)
1844     (if (save-excursion
1845           (goto-char (point-min))
1846           (search-forward "\r" nil t))
1847         ;; unhide - bombs on \r in filenames
1848         (subst-char-in-region (point-min) (point-max) ?\r ?\n)
1849       ;; hide
1850       (let ((pos (point-max))           ; pos of end of last directory
1851             (alist dired-subdir-alist))
1852         (while alist                    ; while there are dirs before pos
1853           (subst-char-in-region (dired-get-subdir-min (car alist)) ; pos of prev dir
1854                                 (save-excursion
1855                                   (goto-char pos) ; current dir
1856                                   ;; we're somewhere on current dir's line
1857                                   (forward-line -1)
1858                                   (point))
1859                                 ?\n ?\r)
1860           (setq pos (dired-get-subdir-min (car alist))) ; prev dir gets current dir
1861           (setq alist (cdr alist)))))))
1862
1863 ;;;###end dired-ins.el
1864
1865 ;;; dired-aux.el ends here