lisp/browse-url.el

   1 ;;; browse-url.el --- Pass a URL to a WWW browser
   2
   3 ;; Copyright 1995, 1996, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Denis Howe <dbh@doc.ic.ac.uk>
   6 ;; Maintainer: Dave Love <d.love@dl.ac.uk>
   7 ;; Created: 03 Apr 1995
   8 ;; Keywords: hypertext, hypermedia, mouse
   9 ;; X-Home page: http://wombat.doc.ic.ac.uk/
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; The latest version of this package should be available from
  31 ;; <URL:http://wombat.doc.ic.ac.uk/emacs/browse-url.el>.
  32
  33 ;; This package provides functions which read a URL (Uniform Resource
  34 ;; Locator) from the minibuffer, defaulting to the URL around point,
  35 ;; and ask a World-Wide Web browser to load it.  It can also load the
  36 ;; URL associated with the current buffer.  Different browsers use
  37 ;; different methods of remote control so there is one function for
  38 ;; each supported browser.  If the chosen browser is not running, it
  39 ;; is started.  Currently there is support for:
  40
  41 ;; Function              Browser     Earliest version
  42 ;; browse-url-netscape   Netscape    1.1b1
  43 ;; browse-url-mosaic     XMosaic     <= 2.4
  44 ;; browse-url-cci        XMosaic     2.5
  45 ;; browse-url-w3         w3          0
  46 ;; browse-url-w3-gnudoit w3 remotely
  47 ;; browse-url-iximosaic  IXI Mosaic  ?
  48 ;; browse-url-lynx-*     Lynx        0
  49 ;; browse-url-grail      Grail       0.3b1
  50 ;; browse-url-mmm        MMM         ?
  51 ;; browse-url-generic    arbitrary
  52
  53 ;; Note that versions of Netscape before 1.1b1 did not have remote
  54 ;; control.  <URL:http://www.netscape.com/newsref/std/x-remote.html>.
  55
  56 ;; Netscape can cache Web pages so it may be necessary to tell it to
  57 ;; reload the current page if it has changed (e.g. if you have edited
  58 ;; it).  There is currently no perfect automatic solution to this.
  59
  60 ;; Netscape allows you to specify the id of the window you want to
  61 ;; control but which window DO you want to control and how do you
  62 ;; discover its id?
  63
  64 ;; If using XMosaic before version 2.5, check the definition of
  65 ;; browse-url-usr1-signal below.
  66 ;; <URL:http://www.ncsa.uiuc.edu/SDG/Software/XMosaic/remote-control.html>
  67
  68 ;; XMosaic version 2.5 introduced Common Client Interface allowing you
  69 ;; to control mosaic through Unix sockets.
  70 ;; <URL:http://www.ncsa.uiuc.edu/SDG/Software/XMosaic/CCI/cci-spec.html>
  71
  72 ;; William M. Perry's excellent "w3" WWW browser for
  73 ;; Emacs <URL:ftp://cs.indiana.edu/pub/elisp/w3/>
  74 ;; has a function w3-follow-url-at-point, but that
  75 ;; doesn't let you edit the URL like browse-url.
  76 ;; The `gnuserv' package that can be used to control it in another
  77 ;; Emacs process is available from
  78 ;; <URL:http://hplbwww.hpl.hp.com/people/ange/gnuserv/>.
  79
  80 ;; Grail is the freely available WWW browser implemented in Python, a
  81 ;; cool object-oriented freely available interpreted language.  Grail
  82 ;; 0.3b1 was the first version to have remote control as distributed.
  83 ;; For more information on Grail see
  84 ;; <URL:http://grail.cnri.reston.va.us/> and for more information on
  85 ;; Python see <url:http://www.python.org/>.  Grail support in
  86 ;; browse-url.el written by Barry Warsaw <bwarsaw@python.org>.
  87
  88 ;; MMM is the freely available WWW browser implemented in Caml Special
  89 ;; Light, a cool impure functional programming language, by Francois
  90 ;; Rouaix.  See the MMM home page
  91 ;; <URL:http://pauillac.inria.fr/%7Erouaix/mmm/>.
  92
  93 ;; Lynx is now distributed by the FSF.  See also
  94 ;; <URL:http://lynx.browser.org/>.
  95
  96 ;; Free graphical browsers that could be used by `browse-url-generic'
  97 ;; include Chimera <URL:ftp://ftp.cs.unlv.edu/pub/chimera>, Arena
  98 ;; <URL:ftp://ftp.yggdrasil.com/pub/dist/web/arena>, Amaya
  99 ;; <URL:ftp://ftp.w3.org/pub/amaya>, mMosaic
 100 ;; <URL:ftp://sig.enst.fr/pub/multicast/mMosaic/> (the latter with
 101 ;; development support for Java applets).
 102
 103 ;; I recommend Nelson Minar <nelson@santafe.edu>'s excellent
 104 ;; html-helper-mode.el for editing HTML and thank Nelson for
 105 ;; his many useful comments on this code.
 106 ;; <URL:http://www.santafe.edu/%7Enelson/hhm-beta/>
 107
 108 ;; This package generalises function html-previewer-process in Marc
 109 ;; Andreessen <marca@ncsa.uiuc.edu>'s html-mode (LCD
 110 ;; modes/html-mode.el.Z) and provides better versions of the URL
 111 ;; functions in Michelangelo Grigni <mic@cs.ucsd.edu>'s ffap.el
 112 ;; (find-file-at-point) <URL:ftp://cs.ucsd.edu:/pub/mic/>.  The huge
 113 ;; hyperbole package also contains similar functions.
 114
 115 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 116 ;; Help!
 117
 118 ;; Can you write and test some code for the Macintrash and Windoze
 119 ;; Netscape remote control APIs?  (See the URL above).
 120
 121 ;; Do any other browsers have remote control?
 122
 123 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 124 ;; Usage
 125
 126 ;; To display the URL at or before point:
 127 ;; M-x browse-url-at-point RET
 128 ;; or, similarly but with the opportunity to edit the URL extracted from
 129 ;; the buffer, use:
 130 ;; M-x browse-url
 131
 132 ;; To display a URL by shift-clicking on it, put this in your ~/.emacs
 133 ;; file:
 134 ;;      (global-set-key [S-mouse-2] 'browse-url-at-mouse)
 135 ;; (Note that using Shift-mouse-1 is not desirable because
 136 ;; that event has a standard meaning in Emacs.)
 137
 138 ;; To display the current buffer in a web browser:
 139 ;; M-x browse-url-of-buffer RET
 140
 141 ;; To display the current region in a web browser:
 142 ;; M-x browse-url-of-region RET
 143
 144 ;; In Dired, to display the file named on the current line:
 145 ;; M-x browse-url-of-dired-file RET
 146
 147 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 148 ;; Customisation (~/.emacs)
 149
 150 ;; To see what variables are available for customization, type
 151 ;; `M-x set-variable browse-url TAB'.
 152
 153 ;; Bind the browse-url commands to keys with the `C-c C-z' prefix
 154 ;; (as used by html-helper-mode):
 155 ;;      (global-set-key "\C-c\C-z." 'browse-url-at-point)
 156 ;;      (global-set-key "\C-c\C-zb" 'browse-url-of-buffer)
 157 ;;      (global-set-key "\C-c\C-zr" 'browse-url-of-region)
 158 ;;      (global-set-key "\C-c\C-zu" 'browse-url)
 159 ;;      (global-set-key "\C-c\C-zv" 'browse-url-of-file)
 160 ;;      (add-hook 'dired-mode-hook
 161 ;;                (function (lambda ()
 162 ;;                            (local-set-key "\C-c\C-zf" 'browse-url-of-dired-file))))
 163
 164 ;; Browse URLs in mail messages by clicking mouse-2:
 165 ;;      (add-hook 'rmail-mode-hook (function (lambda () ; rmail-mode startup
 166 ;;        (define-key rmail-mode-map [mouse-2] 'browse-url-at-mouse))))
 167
 168 ;; Browse URLs in Usenet messages by clicking mouse-2:
 169 ;;      (eval-after-load "gnus"
 170 ;;        '(define-key gnus-article-mode-map [mouse-2] 'browse-url-at-mouse))
 171
 172 ;; Use the Emacs w3 browser when not running under X11:
 173 ;;      (or (eq window-system 'x)
 174 ;;          (setq browse-url-browser-function 'browse-url-w3))
 175
 176 ;; To always save modified buffers before displaying the file in a browser:
 177 ;;      (setq browse-url-save-file t)
 178
 179 ;; To get round the Netscape caching problem, you could EITHER have
 180 ;; write-file in html-helper-mode make Netscape reload the document:
 181 ;;
 182 ;;      (autoload 'browse-url-netscape-reload "browse-url"
 183 ;;        "Ask a WWW browser to redisplay the current file." t)
 184 ;;      (add-hook 'html-helper-mode-hook
 185 ;;                (function (lambda ()
 186 ;;                   (add-hook 'local-write-file-hooks
 187 ;;                             (function (lambda ()
 188 ;;                                (let ((local-write-file-hooks))
 189 ;;                                  (save-buffer))
 190 ;;                                (browse-url-netscape-reload)
 191 ;;                                t))                   ; => file written by hook
 192 ;;                             t))))                    ; append to l-w-f-hooks
 193 ;;
 194 ;; OR have browse-url-of-file ask Netscape to load and then reload the
 195 ;; file:
 196 ;;
 197 ;;      (add-hook 'browse-url-of-file-hook 'browse-url-netscape-reload)
 198
 199 ;; You may also want to customise browse-url-netscape-arguments, e.g.
 200 ;;      (setq browse-url-netscape-arguments '("-install"))
 201 ;;
 202 ;; or similarly for the other browsers.
 203
 204 ;; To invoke different browsers for different URLs:
 205 ;;      (setq browse-url-browser-function '(("^mailto:" . browse-url-mail)
 206 ;;                                          ("." . browse-url-netscape)))
 207
 208 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 209 ;;; Code:
 210
 211 (eval-when-compile (require 'dired))
 212
 213 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 214 ;; Variables
 215
 216 ;;;###autoload
 217 (defgroup browse-url nil
 218   "Use a web browser to look at a URL."
 219   :group 'applications)
 220
 221 ;;;###autoload
 222 (defcustom browse-url-browser-function
 223   'browse-url-netscape
 224   "*Function to display the current buffer in a WWW browser.
 225 This is used by the `browse-url-at-point', `browse-url-at-mouse', and
 226 `browse-url-of-file' commands.
 227
 228 If the value is not a function it should be a list of pairs
 229 (REGEXP.FUNCTION).  In this case the function called will be the one
 230 associated with the first REGEXP which matches the current URL.  The
 231 function is passed the URL and any other args of `browse-url'.  The last
 232 regexp should probably be \".\" to specify a default browser."
 233   :type 'function
 234   :group 'browse-url)
 235
 236 (defcustom browse-url-netscape-program "netscape"
 237   "*The name by which to invoke Netscape."
 238   :type 'string
 239   :group 'browse-url)
 240
 241 (defcustom browse-url-netscape-arguments nil
 242   "*A list of strings to pass to Netscape as arguments."
 243   :type '(repeat (string :tag "Argument"))
 244   :group 'browse-url)
 245
 246 (defcustom browse-url-netscape-startup-arguments browse-url-netscape-arguments
 247   "*A list of strings to pass to Netscape when it starts up.
 248 Defaults to the value of `browse-url-netscape-arguments' at the time
 249 `browse-url' is loaded."
 250   :type '(repeat (string :tag "Argument"))
 251   :group 'browse-url)
 252
 253 (defcustom browse-url-new-window-p nil
 254   "*If non-nil, always open a new browser window.
 255 Passing an interactive argument to \\[browse-url-netscape] or
 256 \\[browse-url-cci] reverses the effect of this variable.  Requires
 257 Netscape version 1.1N or later or XMosaic version 2.5 or later."
 258   :type 'boolean
 259   :group 'browse-url)
 260
 261 (defcustom browse-url-netscape-display nil
 262   "*The X display on which Netscape is running if different from
 263   Emacs's display."
 264   :type 'string
 265   :group 'browse-url)
 266
 267 (defcustom browse-url-mosaic-arguments nil
 268   "*A list of strings to pass to Mosaic as arguments."
 269   :type '(repeat (string :tag "Argument"))
 270   :group 'browse-url)
 271
 272 (defvar browse-url-path-regexp
 273   "[^]\t\n \"'()<>[^`{}]*[^]\t\n \"'()<>[^`{}.,;]+"
 274   "A regular expression probably matching the host, path or e-mail part of a URL.")
 275
 276 (defvar browse-url-short-regexp
 277   (concat "[-A-Za-z0-9.]+" browse-url-path-regexp)
 278   "A regular expression probably matching a URL without an access scheme.
 279 Hostname matching is stricter in this case than for
 280 ``browse-url-regexp''.")
 281
 282 (defvar browse-url-regexp
 283   (concat
 284    "\\(https?://\\|ftp://\\|gopher://\\|telnet://\\|wais://\\|file:/\\|s?news:\\|mailto:\\)"
 285    browse-url-path-regexp)
 286   "A regular expression probably matching a complete URL.")
 287
 288 (defvar browse-url-markedup-regexp
 289   "<URL:[^>]+>"
 290   "A regular expression matching a URL marked up per RFC1738.
 291 This may be broken across lines.")
 292
 293 (defvar browse-url-filename-alist
 294   '(("^/+" . "file:/"))
 295   "An alist of (REGEXP . STRING) pairs.
 296 Any substring of a filename matching one of the REGEXPs is replaced by
 297 the corresponding STRING.  All pairs are applied in the order given.
 298 The default value prepends `file:' to any path beginning with `/'.
 299 Used by the `browse-url-of-file' command.
 300
 301 For example, to map EFS filenames to URLs:
 302
 303     (setq browse-url-filename-alist
 304           '((\"/webmaster@webserver:/home/www/html/\" .
 305              \"http://www.acme.co.uk/\")
 306             (\"^/+\" . \"file:/\")))
 307 ")
 308
 309 (defvar browse-url-save-file nil
 310   "If non-nil, save the buffer before displaying its file.
 311 Used by the `browse-url-of-file' command.")
 312
 313 (defvar browse-url-of-file-hook nil
 314   "A hook to be run with run-hook after `browse-url-of-file' has asked
 315 a browser to load a file.
 316
 317 Set this to `browse-url-netscape-reload' to force Netscape to load the
 318 file rather than displaying a cached copy.")
 319
 320 (defvar browse-url-usr1-signal
 321   (if (and (boundp 'emacs-major-version)
 322            (or (> emacs-major-version 19) (>= emacs-minor-version 29)))
 323       'SIGUSR1 ; Why did I think this was in lower case before?
 324     30)                                 ; Check /usr/include/signal.h.
 325   "The argument to `signal-process' for sending SIGUSR1 to XMosaic.
 326 Emacs 19.29 accepts 'SIGUSR1, earlier versions require an integer
 327 which is 30 on SunOS and 16 on HP-UX and Solaris.")
 328
 329 (defvar browse-url-CCI-port 3003
 330   "Port to access XMosaic via CCI.
 331 This can be any number between 1024 and 65535 but must correspond to
 332 the value set in the browser.")
 333
 334 (defvar browse-url-CCI-host "localhost"
 335   "*Host to access XMosaic via CCI.
 336 This should be the host name of the machine running XMosaic with CCI
 337 enabled.  The port number should be set in `browse-url-CCI-port'.")
 338
 339 (defvar browse-url-temp-file-name nil)
 340 (make-variable-buffer-local 'browse-url-temp-file-name)
 341
 342 (defcustom browse-url-xterm-program "xterm"
 343   "*The name of the terminal emulator used by `browse-url-lynx-xterm'.
 344 This might, for instance, be a separate colour version of xterm."
 345   :type 'string
 346   :group 'browse-url)
 347
 348 (defcustom browse-url-xterm-args nil
 349   "*A list of strings defining options for `browse-url-xterm-program'.
 350 These might set its size, for instance."
 351   :type '(repeat (string :tag "Argument"))
 352   :group 'browse-url)
 353
 354 (defcustom browse-url-gnudoit-program "gnudoit"
 355   "*The name of the `gnudoit' program used by `browse-url-w3-gnudoit'."
 356   :type 'string
 357   :group 'browse-url)
 358
 359 (defcustom browse-url-gnudoit-args '("-q")
 360   "*A list of strings defining options for `browse-url-gnudoit-program'.
 361 These might set the port, for instance."
 362   :type '(repeat (string :tag "Argument"))
 363   :group 'browse-url)
 364
 365 (defcustom browse-url-generic-program nil
 366   "*The name of the browser program used by `browse-url-generic'."
 367   :type 'string
 368   :group 'browse-url)
 369
 370 (defcustom browse-url-generic-args nil
 371   "*A list of strings defining options for `browse-url-generic-program'."
 372   :type '(repeat (string :tag "Argument"))
 373   :group 'browse-url)
 374
 375 (defvar browse-url-temp-file-list '())
 376
 377 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 378 ;; URL input
 379
 380 (defun browse-url-url-at-point ()
 381   "Return the URL around or before point.
 382 Search backwards for the start of a URL ending at or after
 383 point.  If no URL found, return the empty string.  The
 384 access scheme, `http://' will be prepended if absent."
 385   (let ((url "") short strip)
 386     (if (or (setq strip (browse-url-looking-at browse-url-markedup-regexp))
 387             (browse-url-looking-at browse-url-regexp)
 388             ;; Access scheme omitted?
 389             (setq short (browse-url-looking-at browse-url-short-regexp)))
 390         (progn
 391           (setq url (buffer-substring-no-properties (match-beginning 0)
 392                                                     (match-end 0)))
 393           (and strip (setq url (substring url 5 -1))) ; Drop "<URL:" & ">"
 394           ;; strip whitespace
 395           (while (string-match "\\s +\\|\n+" url)
 396             (setq url (replace-match "" t t url)))
 397           (and short (setq url (concat (if (string-match "@" url)
 398                                            "mailto:" "http://") url)))))
 399     url))
 400
 401 ;; thingatpt.el doesn't work for complex regexps.  This should work
 402 ;; for almost any regexp wherever we are in the match.  To do a
 403 ;; perfect job for any arbitrary regexp would mean testing every
 404 ;; position before point.  Regexp searches won't find matches that
 405 ;; straddle the start position so we search forwards once and then
 406 ;; back repeatedly and then back up a char at a time.
 407
 408 (defun browse-url-looking-at (regexp)
 409   "Return non-nil if point is in or just after a match for REGEXP.
 410 Set the match data from the earliest such match ending at or after
 411 point."
 412   (save-excursion
 413     (let ((old-point (point)) match)
 414       (and (looking-at regexp)
 415            (>= (match-end 0) old-point)
 416            (setq match (point)))
 417       ;; Search back repeatedly from end of next match.
 418       ;; This may fail if next match ends before this match does.
 419       (re-search-forward regexp nil 'limit)
 420       (while (and (re-search-backward regexp nil t)
 421                   (or (> (match-beginning 0) old-point)
 422                       (and (looking-at regexp)  ; Extend match-end past search start
 423                            (>= (match-end 0) old-point)
 424                            (setq match (point))))))
 425       (if (not match) nil
 426         (goto-char match)
 427         ;; Back up a char at a time in case search skipped
 428         ;; intermediate match straddling search start pos.
 429         (while (and (not (bobp))
 430                     (progn (backward-char 1) (looking-at regexp))
 431                     (>= (match-end 0) old-point)
 432                     (setq match (point))))
 433         (goto-char match)
 434         (looking-at regexp)))))
 435
 436 ;; Having this as a separate function called by the browser-specific
 437 ;; functions allows them to be stand-alone commands, making it easier
 438 ;; to switch between browsers.
 439
 440 (defun browse-url-interactive-arg (prompt)
 441   "Read a URL from the minibuffer, prompting with PROMPT.
 442 Default to the URL at or before point.  If invoke with a mouse button,
 443 set point to the position clicked first.  Return a list for use in
 444 `interactive' containing the URL and `browse-url-new-window-p' or its
 445 negation if a prefix argument was given."
 446   (let ((event (elt (this-command-keys) 0)))
 447     (and (listp event) (mouse-set-point event)))
 448   (list (read-string prompt (browse-url-url-at-point))
 449         (not (eq (null browse-url-new-window-p)
 450                  (null current-prefix-arg)))))
 451
 452 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 453 ;; Browse current buffer
 454
 455 ;;;###autoload
 456 (defun browse-url-of-file (&optional file)
 457   "Ask a WWW browser to display FILE.
 458 Display the current buffer's file if FILE is nil or if called
 459 interactively.  Turn the filename into a URL with function
 460 `browse-url-file-url'.  Pass the URL to a browser using the
 461 `browse-url' function then run `browse-url-of-file-hook'."
 462   (interactive)
 463   (or file
 464       (setq file (buffer-file-name))
 465       (error "Current buffer has no file"))
 466   (let ((buf (get-file-buffer file)))
 467     (if buf
 468         (save-excursion
 469           (set-buffer buf)
 470           (cond ((not (buffer-modified-p)))
 471                 (browse-url-save-file (save-buffer))
 472                 (t (message "%s modified since last save" file))))))
 473   (browse-url (browse-url-file-url file))
 474   (run-hooks 'browse-url-of-file-hook))
 475
 476 (defun browse-url-file-url (file)
 477   "Return the URL corresponding to FILE.
 478 Use variable `browse-url-filename-alist' to map filenames to URLs.
 479 Convert EFS file names of the form /USER@HOST:PATH to ftp://HOST/PATH."
 480   ;; URL-encode special chars, do % first
 481   (let ((s 0))
 482     (while (setq s (string-match "%" file s))
 483       (setq file (replace-match "%25" t t file)
 484             s (1+ s))))
 485   (while (string-match "[*\"()',=;? ]" file)
 486     (let ((enc (format "%%%x" (aref file (match-beginning 0)))))
 487       (setq file (replace-match enc t t file))))
 488   (let ((maps browse-url-filename-alist))
 489     (while maps
 490       (let* ((map (car maps))
 491              (from-re (car map))
 492              (to-string (cdr map)))
 493         (setq maps (cdr maps))
 494         (and (string-match from-re file)
 495              (setq file (replace-match to-string t t file))))))
 496   ;; Check for EFS path
 497   (and (string-match "^/\\([^:@]+@\\)?\\([^:]+\\):/*" file)
 498        (setq file (concat "ftp://"
 499                           (substring file (match-beginning 2) (match-end 2))
 500                           "/" (substring file (match-end 0)))))
 501   file)
 502
 503 ;;;###autoload
 504 (defun browse-url-of-buffer (&optional buffer)
 505   "Ask a WWW browser to display BUFFER.
 506 Display the current buffer if BUFFER is nil.  Display only the
 507 currently visible part of BUFFER (from a temporary file) if buffer is
 508 narrowed."
 509   (interactive)
 510   (save-excursion
 511     (and buffer (set-buffer buffer))
 512     (let ((file-name
 513            ;; Ignore real name if restricted
 514            (and (= (- (point-max) (point-min)) (buffer-size))
 515                 (or buffer-file-name
 516                     (and (boundp 'dired-directory) dired-directory)))))
 517       (or file-name
 518           (progn
 519             (or browse-url-temp-file-name
 520                 (setq browse-url-temp-file-name
 521                       (make-temp-name
 522                        (expand-file-name (buffer-name)
 523                                          (or (getenv "TMPDIR") "/tmp")))
 524                       browse-url-temp-file-list
 525                       (cons browse-url-temp-file-name
 526                             browse-url-temp-file-list)))
 527             (setq file-name browse-url-temp-file-name)
 528             (write-region (point-min) (point-max) file-name nil 'no-message)))
 529       (browse-url-of-file file-name))))
 530
 531 (defun browse-url-delete-temp-file (&optional temp-file-name)
 532   ;; Delete browse-url-temp-file-name from the file system and from
 533   ;; browse-url-temp-file-list.  If optional arg TEMP-FILE-NAME is
 534   ;; non-nil, delete it instead, but only from the file system --
 535   ;; browse-url-temp-file-list is not affected.
 536   (let ((file-name (or temp-file-name browse-url-temp-file-name)))
 537     (if (and file-name (file-exists-p file-name))
 538         (progn
 539           (delete-file file-name)
 540           (if (null temp-file-name)
 541               (setq browse-url-temp-file-list
 542                     (delete browse-url-temp-file-name
 543                             browse-url-temp-file-list)))))))
 544
 545 (defun browse-url-delete-temp-file-list ()
 546   ;; Delete all elements of browse-url-temp-file-list.
 547   (while browse-url-temp-file-list
 548     (browse-url-delete-temp-file (car browse-url-temp-file-list))
 549     (setq browse-url-temp-file-list
 550           (cdr browse-url-temp-file-list))))
 551
 552 (add-hook 'kill-buffer-hook 'browse-url-delete-temp-file)
 553 (add-hook 'kill-emacs-hook 'browse-url-delete-temp-file-list)
 554
 555 ;;;###autoload
 556 (defun browse-url-of-dired-file ()
 557   "In Dired, ask a WWW browser to display the file named on this line."
 558   (interactive)
 559   (browse-url-of-file (dired-get-filename)))
 560
 561 ;;;###autoload
 562 (defun browse-url-of-region (min max)
 563   "Ask a WWW browser to display the current region."
 564   (interactive "r")
 565   (save-excursion
 566     (save-restriction
 567       (narrow-to-region (mark) (point))
 568       (browse-url-of-buffer))))
 569
 570 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 571 ;; Browser-independent commands
 572
 573 ;; A generic command to call the current browse-url-browser-function
 574
 575 ;;;###autoload
 576 (defun browse-url (&rest args)
 577   "Ask a WWW browser to load URL.
 578 Prompts for a URL, defaulting to the URL at or before point.  Variable
 579 `browse-url-browser-function' says which browser to use."
 580   (interactive (browse-url-interactive-arg "URL: "))
 581   (if (consp browse-url-browser-function)
 582       (browse-url-choose-browser args)
 583     (apply browse-url-browser-function args)))
 584
 585 (defun browse-url-choose-browser (url &rest args)
 586   "Pass URL to a browser function chosen.
 587 This is done according to the association list in variable
 588 `browse-url-browser-function'."
 589   (let ((blist browse-url-browser-function)
 590         re bf)
 591     (while (consp blist)
 592       (setq re (car (car blist))
 593             bf (cdr (car blist))
 594             blist (cdr blist))
 595       (if (string-match re url)
 596           (progn (apply bf url args) (setq blist t))))
 597     (or blist
 598         (error "No browser in browse-url-browser-function matching URL %s" url))))
 599
 600 ;;;###autoload
 601 (defun browse-url-at-point ()
 602   "Ask a WWW browser to load the URL at or before point.
 603 Doesn't let you edit the URL like browse-url.  Variable
 604 `browse-url-browser-function' says which browser to use."
 605   (interactive)
 606   (browse-url (browse-url-url-at-point)))
 607
 608 (defun browse-url-event-buffer (event)
 609   (window-buffer (posn-window (event-start event))))
 610
 611 (defun browse-url-event-point (event)
 612   (posn-point (event-start event)))
 613
 614 ;;;###autoload
 615 (defun browse-url-at-mouse (event)
 616   "Ask a WWW browser to load a URL clicked with the mouse.
 617 The URL is the one around or before the position of the mouse click
 618 but point is not changed.  Doesn't let you edit the URL like
 619 browse-url.  Variable `browse-url-browser-function' says which browser
 620 to use."
 621   (interactive "e")
 622   (save-excursion
 623     (set-buffer (browse-url-event-buffer event))
 624     (goto-char (browse-url-event-point event))
 625     (let ((url (browse-url-url-at-point)))
 626       (if (string-equal url "")
 627           (error "No URL found"))
 628       (browse-url url))))
 629
 630 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 631 ;; Browser-specific commands
 632
 633 ;; --- Netscape ---
 634
 635 (defun browse-url-process-environment ()
 636   "Set DISPLAY in the environment to the X display Netscape is running on.
 637 This is either the value of variable `browse-url-netscape-display' if
 638 non-nil, or the same display as Emacs if different from the current
 639 environment, otherwise just use the current environment."
 640   (let ((display (or browse-url-netscape-display (browse-url-emacs-display))))
 641     (if display
 642         (cons (concat "DISPLAY=" display) process-environment)
 643       process-environment)))
 644
 645 (defun browse-url-emacs-display ()
 646   "Return the X display Emacs is running on.
 647 This nil if the display is the same as the DISPLAY environment variable.
 648
 649 Actually Emacs could be using several screens on several displays, as
 650 listed by (emacs-display-list) and (x-display-screens DISPLAY), this
 651 just returns the display showing the selected frame.  You got a
 652 problem with that?"
 653   (let (device display)
 654     (and (fboundp 'selected-device) (fboundp 'device-type) (fboundp 'device-connection)
 655          (setq device (selected-device))
 656          (eq (device-type device) 'x)
 657          (setq display (device-connection device))
 658          (not (equal display (getenv "DISPLAY")))
 659          display)))
 660
 661 ;;;###autoload
 662 (defun browse-url-netscape (url &optional new-window)
 663   "Ask the Netscape WWW browser to load URL.
 664
 665 Default to the URL around or before point.  The strings in variable
 666 `browse-url-netscape-arguments' are also passed to Netscape.
 667
 668 When called interactively, if variable `browse-url-new-window-p' is
 669 non-nil, load the document in a new Netscape window, otherwise use a
 670 random existing one.  A non-nil interactive prefix argument reverses
 671 the effect of `browse-url-new-window-p'.
 672
 673 When called non-interactively, optional second argument NEW-WINDOW is
 674 used instead of `browse-url-new-window-p'."
 675   (interactive (browse-url-interactive-arg "Netscape URL: "))
 676   ;; URL encode any commas in the URL
 677   (while (string-match "," url)
 678     (setq url (replace-match "%2C" t t url)))
 679   (let* ((process-environment (browse-url-process-environment))
 680          (process (apply 'start-process
 681                         (concat "netscape " url) nil
 682                         browse-url-netscape-program
 683                         (append browse-url-netscape-arguments
 684                                 (if (string-equal "win32" window-system)
 685                                     (list url)
 686                                   (if new-window '("-noraise"))
 687                                   (list "-remote"
 688                                         (concat "openURL(" url
 689                                                 (if new-window ",new-window")
 690                                                 ")")))))))
 691     (set-process-sentinel process
 692                           (list 'lambda '(process change)
 693                                 (list 'browse-url-netscape-sentinel 'process url)))))
 694
 695 (defun browse-url-netscape-sentinel (process url)
 696   "Handle a change to the process communicating with Netscape."
 697   (or (eq (process-exit-status process) 0)
 698       (let* ((process-environment (browse-url-process-environment)))
 699         ;; Netscape not running - start it
 700         (message "Starting Netscape...")
 701         (apply 'start-process (concat "netscape" url) nil
 702                browse-url-netscape-program
 703                (append browse-url-netscape-startup-arguments (list url))))))
 704
 705 (defun browse-url-netscape-reload ()
 706   "Ask Netscape to reload its current document."
 707   (interactive)
 708   (browse-url-netscape-send "reload"))
 709
 710 (defun browse-url-netscape-send (command)
 711   "Send a remote control command to Netscape."
 712   (let* ((process-environment (browse-url-process-environment)))
 713     (apply 'start-process "netscape" nil
 714            browse-url-netscape-program
 715            (append browse-url-netscape-arguments
 716                    (list "-remote" command)))))
 717
 718 ;; --- Mosaic ---
 719
 720 ;;;###autoload
 721 (defun browse-url-mosaic (url &optional new-window)
 722   ;; new-window ignored
 723   "Ask the XMosaic WWW browser to load URL.
 724 Default to the URL around or before point."
 725   (interactive (browse-url-interactive-arg "Mosaic URL: "))
 726   (let ((pidfile (expand-file-name "~/.mosaicpid"))
 727         pid pidbuf)
 728     (if (file-readable-p pidfile)
 729         (save-excursion
 730           (find-file pidfile)
 731           (goto-char (point-min))
 732           (setq pid (read (current-buffer)))
 733           (kill-buffer nil)))
 734     (if (and pid (zerop (signal-process pid 0))) ; Mosaic running
 735         (save-excursion
 736           (find-file (format "/tmp/Mosaic.%d" pid))
 737           (erase-buffer)
 738           (insert "goto\n" url "\n")
 739           (save-buffer)
 740           (kill-buffer nil)
 741           ;; Send signal SIGUSR to Mosaic
 742           (message "Signalling Mosaic...")
 743           (signal-process pid browse-url-usr1-signal)
 744           ;; Or you could try:
 745           ;; (call-process "kill" nil 0 nil "-USR1" (int-to-string pid))
 746           (message "Signalling Mosaic...done")
 747           )
 748       ;; Mosaic not running - start it
 749       (message "Starting Mosaic...")
 750       (apply 'start-process "xmosaic" nil "xmosaic"
 751              (append browse-url-mosaic-arguments (list url)))
 752       (message "Starting Mosaic...done"))))
 753
 754 ;; --- Grail ---
 755
 756 ;;;###autoload
 757 (defvar browse-url-grail
 758   (concat (or (getenv "GRAILDIR") "~/.grail") "/user/rcgrail.py")
 759   "*Location of Grail remote control client script `rcgrail.py'.
 760 Typically found in $GRAILDIR/rcgrail.py, or ~/.grail/user/rcgrail.py.")
 761
 762 ;;;###autoload
 763 (defun browse-url-grail (url &optional new-window)
 764   "Ask the Grail WWW browser to load URL.
 765 Default to the URL around or before point.  Runs the program in the
 766 variable `browse-url-grail'."
 767   (interactive (browse-url-interactive-arg "Grail URL: "))
 768   (message "Sending URL to Grail...")
 769   (save-excursion
 770     (set-buffer (get-buffer-create " *Shell Command Output*"))
 771     (erase-buffer)
 772     ;; don't worry about this failing.
 773     (call-process browse-url-grail nil 0 nil url)
 774     (message "Sending URL to Grail... done")))
 775
 776 ;; --- Mosaic using CCI ---
 777
 778 (defun browse-url-cci (url &optional new-window)
 779   "Ask the XMosaic WWW browser to load URL.
 780 Default to the URL around or before point.
 781
 782 This function only works for XMosaic version 2.5 or later.  You must
 783 select `CCI' from XMosaic's File menu, set the CCI Port Address to the
 784 value of variable `browse-url-CCI-port', and enable `Accept requests'.
 785
 786 When called interactively, if variable `browse-url-new-window-p' is
 787 non-nil, load the document in a new browser window, otherwise use a
 788 random existing one.  A non-nil interactive prefix argument reverses
 789 the effect of `browse-url-new-window-p'.
 790
 791 When called non-interactively, optional second argument NEW-WINDOW is
 792 used instead of `browse-url-new-window-p'."
 793   (interactive (browse-url-interactive-arg "Mosaic URL: "))
 794   (open-network-stream "browse-url" " *browse-url*"
 795                        browse-url-CCI-host browse-url-CCI-port)
 796   ;; Todo: start browser if fails
 797   (process-send-string "browse-url"
 798                        (concat "get url (" url ") output "
 799                                (if new-window "new" "current") "\r\n"))
 800   (process-send-string "browse-url" "disconnect\r\n")
 801   (delete-process "browse-url"))
 802
 803 ;; --- IXI Mosaic ---
 804
 805 ;;;###autoload
 806 (defun browse-url-iximosaic (url &optional new-window)
 807   ;; new-window ignored
 808   "Ask the IXIMosaic WWW browser to load URL.
 809 Default to the URL around or before point."
 810   (interactive (browse-url-interactive-arg "IXI Mosaic URL: "))
 811   (start-process "tellw3b" nil "tellw3b"
 812                  "-service WWW_BROWSER ixi_showurl " url))
 813
 814 ;; --- W3 ---
 815
 816 ;;;###autoload
 817 (defun browse-url-w3 (url &optional new-window)
 818   ;; new-window ignored
 819   "Ask the w3 WWW browser to load URL.
 820 Default to the URL around or before point."
 821   (interactive (browse-url-interactive-arg "W3 URL: "))
 822   (w3-fetch url))
 823
 824 ;;;###autoload
 825 (defun browse-url-w3-gnudoit (url &optional new-window)
 826   ;; new-window ignored
 827   "Ask another Emacs running gnuserv to load the URL using the W3 browser.
 828 The `browse-url-gnudoit-program' program is used with options given by
 829 `browse-url-gnudoit-args'.  Default to the URL around or before point."
 830   (interactive (browse-url-interactive-arg "W3 URL: "))
 831     (apply 'start-process (concat "gnudoit:" url) nil
 832            browse-url-gnudoit-program
 833            (append browse-url-gnudoit-args (list (concat "(w3-fetch \"" url "\")") "(raise-frame)"))))
 834
 835 ;; --- Lynx in an xterm ---
 836
 837 ;;;###autoload
 838 (defun browse-url-lynx-xterm (url &optional new-window)
 839   ;; new-window ignored
 840   "Ask the Lynx WWW browser to load URL.
 841 Default to the URL around or before point.  A new Lynx process is run
 842 in an Xterm window using the Xterm program named by `browse-url-xterm-program'
 843 with possible additional arguments `browse-url-xterm-args'."
 844   (interactive (browse-url-interactive-arg "Lynx URL: "))
 845   (apply 'start-process (concat "lynx" url) nil browse-url-xterm-program
 846              (append browse-url-xterm-args (list "-e" "lynx" url))))
 847
 848 ;; --- Lynx in an Emacs "term" window ---
 849
 850 ;;;###autoload
 851 (defun browse-url-lynx-emacs (url &optional new-window)
 852   ;; new-window ignored
 853   "Ask the Lynx WWW browser to load URL.
 854 Default to the URL around or before point.  Run a new Lynx process in
 855 an Emacs buffer."
 856   (interactive (browse-url-interactive-arg "Lynx URL: "))
 857   (let ((system-uses-terminfo t))       ; Lynx uses terminfo
 858     (if (fboundp 'make-term)
 859         (let ((term-term-name "vt100"))
 860           (set-buffer (make-term "browse-url" "lynx" nil url))
 861           (term-mode)
 862           (term-char-mode)
 863           (switch-to-buffer "*browse-url*"))
 864       (terminal-emulator "*browse-url*" "lynx" (list url)))))
 865
 866 ;; --- MMM ---
 867
 868 ;;;###autoload
 869 (defun browse-url-mmm (url &optional new-window)
 870   "Ask the MMM WWW browser to load URL.
 871 Default to the URL around or before point."
 872   (interactive (browse-url-interactive-arg "MMM URL: "))
 873   (message "Sending URL to MMM...")
 874   (save-excursion
 875     (set-buffer (get-buffer-create " *Shell Command Output*"))
 876     (erase-buffer)
 877     ;; mmm_remote just SEGVs if the file isn't there...
 878     (if (or (file-exists-p (expand-file-name "~/.mmm_remote"))
 879             ;; location in v 0.4:
 880             (file-exists-p (expand-file-name "~/.mmm/remote")))
 881         (call-process "mmm_remote" nil 0 nil url)
 882       (call-process "mmm" nil 0 nil "-external" url))
 883     (message "Sending URL to MMM... done")))
 884
 885 ;; --- mailto ---
 886
 887 ;;;###autoload
 888 (defun browse-url-mail (url)
 889   "Open a new mail message buffer within Emacs.
 890 Default to the mailto URL around or before point."
 891   (interactive (browse-url-interactive-arg "Mailto URL: "))
 892   (save-excursion
 893     ;; open mail buffer, specifying TO and REPLYBUFFER
 894     (mail nil (if (string-match "^mailto:" url)
 895                   (substring url 7)
 896                 url)
 897           nil nil nil
 898           (current-buffer))))
 899
 900 ;; --- Random browser ---
 901
 902 ;;;###autoload
 903 (defun browse-url-generic (url &optional new-window)
 904   ;; new-window ignored
 905   "Ask the WWW browser defined by `browse-url-generic-program' to load URL.
 906 Default to the URL around or before point.  A fresh copy of the
 907 browser is started up in a new process with possible additional arguments
 908 `browse-url-generic-args'.  This is appropriate for browsers which
 909 don't offer a form of remote control."
 910   (interactive (browse-url-interactive-arg "URL: "))
 911   (if (not browse-url-generic-program)
 912     (error "No browser defined (`browse-url-generic-program')"))
 913   (apply 'start-process (concat browse-url-generic-program url) nil
 914          browse-url-generic-program
 915          (append browse-url-generic-args (list url))))
 916
 917 (provide 'browse-url)
 918
 919 ;;; browse-url.el ends here