lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  28 ;; associated support machinery, such as adding hyperlinks, etc.,
  29
  30 ;;; Code:
  31
  32 (require 'button)
  33 (require 'view)
  34 (eval-when-compile (require 'easymenu))
  35
  36 (defvar help-mode-map
  37   (let ((map (make-sparse-keymap)))
  38     (set-keymap-parent map button-buffer-map)
  39
  40     (define-key map [mouse-2] 'help-follow-mouse)
  41     (define-key map "\C-c\C-b" 'help-go-back)
  42     (define-key map "\C-c\C-f" 'help-go-forward)
  43     (define-key map "\C-c\C-c" 'help-follow-symbol)
  44     ;; Documentation only, since we use minor-mode-overriding-map-alist.
  45     (define-key map "\r" 'help-follow)
  46     map)
  47   "Keymap for help mode.")
  48
  49 (easy-menu-define help-mode-menu help-mode-map
  50   "Menu for Help Mode."
  51   '("Help-Mode"
  52     ["Show Help for Symbol" help-follow-symbol
  53      :help "Show the docs for the symbol at point"]
  54     ["Previous Topic" help-go-back
  55      :help "Go back to previous topic in this help buffer"]
  56     ["Next Topic" help-go-forward
  57      :help "Go back to next topic in this help buffer"]
  58     ["Move to Previous Button" backward-button
  59      :help "Move to the Next Button in the help buffer"]
  60     ["Move to Next Button" forward-button
  61       :help "Move to the Next Button in the help buffer"]))
  62
  63 (defvar help-xref-stack nil
  64   "A stack of ways by which to return to help buffers after following xrefs.
  65 Used by `help-follow' and `help-xref-go-back'.
  66 An element looks like (POSITION FUNCTION ARGS...).
  67 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  68 (put 'help-xref-stack 'permanent-local t)
  69 (make-variable-buffer-local 'help-xref-stack)
  70
  71 (defvar help-xref-forward-stack nil
  72   "A stack used to navigate help forwards after using the back button.
  73 Used by `help-follow' and `help-xref-go-forward'.
  74 An element looks like (POSITION FUNCTION ARGS...).
  75 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  76 (put 'help-xref-forward-stack 'permanent-local t)
  77 (make-variable-buffer-local 'help-xref-forward-stack)
  78
  79 (defvar help-xref-stack-item nil
  80   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  81 The format is (FUNCTION ARGS...).")
  82 (put 'help-xref-stack-item 'permanent-local t)
  83 (make-variable-buffer-local 'help-xref-stack-item)
  84
  85 (defvar help-xref-stack-forward-item nil
  86   "An item for `help-go-back' to push onto `help-xref-forward-stack'.
  87 The format is (FUNCTION ARGS...).")
  88 (put 'help-xref-stack-forward-item 'permanent-local t)
  89 (make-variable-buffer-local 'help-xref-stack-forward-item)
  90
  91 (setq-default help-xref-stack nil help-xref-stack-item nil)
  92 (setq-default help-xref-forward-stack nil help-xref-forward-stack-item nil)
  93
  94 (defcustom help-mode-hook nil
  95   "Hook run by `help-mode'."
  96   :type 'hook
  97   :group 'help)
  98 \f
  99 ;; Button types used by help
 100
 101 (define-button-type 'help-xref
 102   'follow-link t
 103   'action #'help-button-action)
 104
 105 (defun help-button-action (button)
 106   "Call BUTTON's help function."
 107   (help-do-xref (button-start button)
 108                 (button-get button 'help-function)
 109                 (button-get button 'help-args)))
 110
 111 ;; These 6 calls to define-button-type were generated in a dolist
 112 ;; loop, but that is bad because it means these button types don't
 113 ;; have an easily found definition.
 114
 115 (define-button-type 'help-function
 116   :supertype 'help-xref
 117   'help-function 'describe-function
 118   'help-echo (purecopy "mouse-2, RET: describe this function"))
 119
 120 (define-button-type 'help-variable
 121   :supertype 'help-xref
 122   'help-function 'describe-variable
 123   'help-echo (purecopy "mouse-2, RET: describe this variable"))
 124
 125 (define-button-type 'help-face
 126   :supertype 'help-xref
 127   'help-function 'describe-face
 128   'help-echo (purecopy "mouse-2, RET: describe this face"))
 129
 130 (define-button-type 'help-coding-system
 131   :supertype 'help-xref
 132   'help-function 'describe-coding-system
 133   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 134
 135 (define-button-type 'help-input-method
 136   :supertype 'help-xref
 137   'help-function 'describe-input-method
 138   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 139
 140 (define-button-type 'help-character-set
 141   :supertype 'help-xref
 142   'help-function 'describe-character-set
 143   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 144
 145 ;; make some more ideosyncratic button types
 146
 147 (define-button-type 'help-symbol
 148   :supertype 'help-xref
 149   'help-function #'help-xref-interned
 150   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 151
 152 (define-button-type 'help-back
 153   :supertype 'help-xref
 154   'help-function #'help-xref-go-back
 155   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 156
 157 (define-button-type 'help-forward
 158   :supertype 'help-xref
 159   'help-function #'help-xref-go-forward
 160   'help-echo (purecopy "mouse-2, RET: move forward to next help buffer"))
 161
 162 (define-button-type 'help-info-variable
 163   :supertype 'help-xref
 164   ;; the name of the variable is put before the argument to Info
 165   'help-function (lambda (a v) (info v))
 166   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 167
 168 (define-button-type 'help-info
 169   :supertype 'help-xref
 170   'help-function #'info
 171   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 172
 173 (define-button-type 'help-url
 174   :supertype 'help-xref
 175   'help-function #'browse-url
 176   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 177
 178 (define-button-type 'help-customize-variable
 179   :supertype 'help-xref
 180   'help-function (lambda (v)
 181                    (customize-variable v))
 182   'help-echo (purecopy "mouse-2, RET: customize variable"))
 183
 184 (define-button-type 'help-customize-face
 185   :supertype 'help-xref
 186   'help-function (lambda (v)
 187                    (customize-face v))
 188   'help-echo (purecopy "mouse-2, RET: customize face"))
 189
 190 (define-button-type 'help-function-def
 191   :supertype 'help-xref
 192   'help-function (lambda (fun file)
 193                    (require 'find-func)
 194                    (when (eq file 'C-source)
 195                      (setq file
 196                            (help-C-file-name (indirect-function fun) 'fun)))
 197                    ;; Don't use find-function-noselect because it follows
 198                    ;; aliases (which fails for built-in functions).
 199                    (let ((location
 200                           (find-function-search-for-symbol fun nil file)))
 201                      (pop-to-buffer (car location))
 202                      (if (cdr location)
 203                          (goto-char (cdr location))
 204                        (message "Unable to find location in file"))))
 205   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 206
 207 (define-button-type 'help-function-cmacro
 208   :supertype 'help-xref
 209   'help-function (lambda (fun file)
 210                    (setq file (locate-library file t))
 211                    (if (and file (file-readable-p file))
 212                        (progn
 213                          (pop-to-buffer (find-file-noselect file))
 214                          (goto-char (point-min))
 215                          (if (re-search-forward
 216                               (format "^[ \t]*(define-compiler-macro[ \t]+%s"
 217                                       (regexp-quote (symbol-name fun))) nil t)
 218                              (forward-line 0)
 219                            (message "Unable to find location in file")))
 220                      (message "Unable to find file")))
 221   'help-echo (purecopy "mouse-2, RET: find function's compiler macro"))
 222
 223 (define-button-type 'help-variable-def
 224   :supertype 'help-xref
 225   'help-function (lambda (var &optional file)
 226                    (when (eq file 'C-source)
 227                      (setq file (help-C-file-name var 'var)))
 228                    (let ((location (find-variable-noselect var file)))
 229                      (pop-to-buffer (car location))
 230                      (if (cdr location)
 231                        (goto-char (cdr location))
 232                        (message "Unable to find location in file"))))
 233   'help-echo (purecopy "mouse-2, RET: find variable's definition"))
 234
 235 (define-button-type 'help-face-def
 236   :supertype 'help-xref
 237   'help-function (lambda (fun file)
 238                    (require 'find-func)
 239                    ;; Don't use find-function-noselect because it follows
 240                    ;; aliases (which fails for built-in functions).
 241                    (let ((location
 242                           (find-function-search-for-symbol fun 'defface file)))
 243                      (pop-to-buffer (car location))
 244                      (if (cdr location)
 245                          (goto-char (cdr location))
 246                        (message "Unable to find location in file"))))
 247   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 248
 249 (define-button-type 'help-package
 250   :supertype 'help-xref
 251   'help-function 'describe-package
 252   'help-echo (purecopy "mouse-2, RET: Describe package"))
 253
 254 (define-button-type 'help-package-def
 255   :supertype 'help-xref
 256   'help-function (lambda (file) (dired file))
 257   'help-echo (purecopy "mouse-2, RET: visit package directory"))
 258
 259 (define-button-type 'help-theme-def
 260   :supertype 'help-xref
 261   'help-function 'find-file
 262   'help-echo (purecopy "mouse-2, RET: visit theme file"))
 263
 264 (define-button-type 'help-theme-edit
 265   :supertype 'help-xref
 266   'help-function 'customize-create-theme
 267   'help-echo (purecopy "mouse-2, RET: edit this theme file"))
 268 \f
 269 ;;;###autoload
 270 (defun help-mode ()
 271   "Major mode for viewing help text and navigating references in it.
 272 Entry to this mode runs the normal hook `help-mode-hook'.
 273 Commands:
 274 \\{help-mode-map}"
 275   (interactive)
 276   (kill-all-local-variables)
 277   (use-local-map help-mode-map)
 278   (setq mode-name "Help")
 279   (setq major-mode 'help-mode)
 280
 281   (view-mode)
 282   (set (make-local-variable 'view-no-disable-on-exit) t)
 283   ;; With Emacs 22 `view-exit-action' could delete the selected window
 284   ;; disregarding whether the help buffer was shown in that window at
 285   ;; all.  Since `view-exit-action' is called with the help buffer as
 286   ;; argument it seems more appropriate to have it work on the buffer
 287   ;; only and leave it to `view-mode-exit' to delete any associated
 288   ;; window(s).
 289   (setq view-exit-action
 290         (lambda (buffer)
 291           ;; Use `with-current-buffer' to make sure that `bury-buffer'
 292           ;; also removes BUFFER from the selected window.
 293           (with-current-buffer buffer
 294             (bury-buffer))))
 295
 296   (set (make-local-variable 'revert-buffer-function)
 297        'help-mode-revert-buffer)
 298
 299   (run-mode-hooks 'help-mode-hook))
 300
 301 ;;;###autoload
 302 (defun help-mode-setup ()
 303   (help-mode)
 304   (setq buffer-read-only nil))
 305
 306 ;;;###autoload
 307 (defun help-mode-finish ()
 308   (if (eq help-window t)
 309       ;; If `help-window' is t, `view-return-to-alist' is handled by
 310       ;; `with-help-window'.  In this case set `help-window' to the
 311       ;; selected window since now is the only moment where we can
 312       ;; unambiguously identify it.
 313       (setq help-window (selected-window))
 314     (let ((entry (assq (selected-window) view-return-to-alist)))
 315       (if entry
 316           ;; When entering Help mode from the Help window,
 317           ;; such as by following a link, preserve the same
 318           ;; meaning for the q command.
 319           ;; (setcdr entry (cons (selected-window) help-return-method))
 320           nil
 321         (setq view-return-to-alist
 322               (cons (cons (selected-window) help-return-method)
 323                     view-return-to-alist)))))
 324
 325   (when (eq major-mode 'help-mode)
 326     ;; View mode's read-only status of existing *Help* buffer is lost
 327     ;; by with-output-to-temp-buffer.
 328     (toggle-read-only 1)
 329
 330     (save-excursion
 331       (goto-char (point-min))
 332       (let ((inhibit-read-only t))
 333         (when (re-search-forward "^This \\w+ is advised.$" nil t)
 334           (put-text-property (match-beginning 0)
 335                              (match-end 0)
 336                              'face 'font-lock-warning-face))))
 337
 338     (help-make-xrefs (current-buffer))))
 339 \f
 340 ;; Grokking cross-reference information in doc strings and
 341 ;; hyperlinking it.
 342
 343 ;; This may have some scope for extension and the same or something
 344 ;; similar should be done for widget doc strings, which currently use
 345 ;; another mechanism.
 346
 347 (defvar help-back-label (purecopy "[back]")
 348   "Label to use by `help-make-xrefs' for the go-back reference.")
 349
 350 (defvar help-forward-label (purecopy "[forward]")
 351   "Label to use by `help-make-xrefs' for the go-forward reference.")
 352
 353 (defconst help-xref-symbol-regexp
 354   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"  ; Link to var
 355                     "\\(function\\|command\\)\\|"          ; Link to function
 356                     "\\(face\\)\\|"                        ; Link to face
 357                     "\\(symbol\\|program\\|property\\)\\|" ; Don't link
 358                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 359                     "[ \t\n]+\\)?"
 360                     ;; Note starting with word-syntax character:
 361                     "`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
 362   "Regexp matching doc string references to symbols.
 363
 364 The words preceding the quoted symbol can be used in doc strings to
 365 distinguish references to variables, functions and symbols.")
 366
 367 (defvar help-xref-mule-regexp nil
 368   "Regexp matching doc string references to MULE-related keywords.
 369
 370 It is usually nil, and is temporarily bound to an appropriate regexp
 371 when help commands related to multilingual environment (e.g.,
 372 `describe-coding-system') are invoked.")
 373
 374
 375 (defconst help-xref-info-regexp
 376   (purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
 377   "Regexp matching doc string references to an Info node.")
 378
 379 (defconst help-xref-url-regexp
 380   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+`\\([^']+\\)'")
 381   "Regexp matching doc string references to a URL.")
 382
 383 ;;;###autoload
 384 (defun help-setup-xref (item interactive-p)
 385   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 386
 387 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 388 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 389 calling command was invoked interactively.  In this case the stack of
 390 items for help buffer \"back\" buttons is cleared.
 391
 392 This should be called very early, before the output buffer is cleared,
 393 because we want to record the \"previous\" position of point so we can
 394 restore it properly when going back."
 395   (with-current-buffer (help-buffer)
 396     (when help-xref-stack-item
 397       (push (cons (point) help-xref-stack-item) help-xref-stack)
 398       (setq help-xref-forward-stack nil))
 399     (when interactive-p
 400       (let ((tail (nthcdr 10 help-xref-stack)))
 401         ;; Truncate the stack.
 402         (if tail (setcdr tail nil))))
 403     (setq help-xref-stack-item item)))
 404
 405 (defvar help-xref-following nil
 406   "Non-nil when following a help cross-reference.")
 407
 408 ;;;###autoload
 409 (defun help-buffer ()
 410   "Return the name of a buffer for inserting help.
 411 If `help-xref-following' is non-nil, this is the name of the
 412 current buffer.
 413 Otherwise, it is *Help*; if no buffer with that name currently
 414 exists, it is created."
 415   (buffer-name                          ;for with-output-to-temp-buffer
 416    (if help-xref-following
 417        (current-buffer)
 418      (get-buffer-create "*Help*"))))
 419
 420 (defvar help-xref-override-view-map
 421   (let ((map (make-sparse-keymap)))
 422     (set-keymap-parent map view-mode-map)
 423     (define-key map "\r" nil)
 424     map)
 425   "Replacement keymap for `view-mode' in help buffers.")
 426
 427 ;;;###autoload
 428 (defun help-make-xrefs (&optional buffer)
 429   "Parse and hyperlink documentation cross-references in the given BUFFER.
 430
 431 Find cross-reference information in a buffer and activate such cross
 432 references for selection with `help-follow'.  Cross-references have
 433 the canonical form `...'  and the type of reference may be
 434 disambiguated by the preceding word(s) used in
 435 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 436 preceded or followed by the word `face'.  Variables without
 437 variable documentation do not get cross-referenced, unless
 438 preceded by the word `variable' or `option'.
 439
 440 If the variable `help-xref-mule-regexp' is non-nil, find also
 441 cross-reference information related to multilingual environment
 442 \(e.g., coding-systems).  This variable is also used to disambiguate
 443 the type of reference as the same way as `help-xref-symbol-regexp'.
 444
 445 A special reference `back' is made to return back through a stack of
 446 help buffers.  Variable `help-back-label' specifies the text for
 447 that."
 448   (interactive "b")
 449   (with-current-buffer (or buffer (current-buffer))
 450     (save-excursion
 451       (goto-char (point-min))
 452       ;; Skip the header-type info, though it might be useful to parse
 453       ;; it at some stage (e.g. "function in `library'").
 454       (forward-paragraph)
 455       (let ((old-modified (buffer-modified-p)))
 456         (let ((stab (syntax-table))
 457               (case-fold-search t)
 458               (inhibit-read-only t))
 459           (set-syntax-table emacs-lisp-mode-syntax-table)
 460           ;; The following should probably be abstracted out.
 461           (unwind-protect
 462               (progn
 463                 ;; Info references
 464                 (save-excursion
 465                   (while (re-search-forward help-xref-info-regexp nil t)
 466                     (let ((data (match-string 2)))
 467                       (save-match-data
 468                         (unless (string-match "^([^)]+)" data)
 469                           (setq data (concat "(emacs)" data)))
 470                         (setq data ;; possible newlines if para filled
 471                               (replace-regexp-in-string "[ \t\n]+" " " data t t)))
 472                       (help-xref-button 2 'help-info data))))
 473                 ;; URLs
 474                 (save-excursion
 475                   (while (re-search-forward help-xref-url-regexp nil t)
 476                     (let ((data (match-string 1)))
 477                       (help-xref-button 1 'help-url data))))
 478                 ;; Mule related keywords.  Do this before trying
 479                 ;; `help-xref-symbol-regexp' because some of Mule
 480                 ;; keywords have variable or function definitions.
 481                 (if help-xref-mule-regexp
 482                     (save-excursion
 483                       (while (re-search-forward help-xref-mule-regexp nil t)
 484                         (let* ((data (match-string 7))
 485                                (sym (intern-soft data)))
 486                           (cond
 487                            ((match-string 3) ; coding system
 488                             (and sym (coding-system-p sym)
 489                                  (help-xref-button 6 'help-coding-system sym)))
 490                            ((match-string 4) ; input method
 491                             (and (assoc data input-method-alist)
 492                                  (help-xref-button 7 'help-input-method data)))
 493                            ((or (match-string 5) (match-string 6)) ; charset
 494                             (and sym (charsetp sym)
 495                                  (help-xref-button 7 'help-character-set sym)))
 496                            ((assoc data input-method-alist)
 497                             (help-xref-button 7 'help-character-set data))
 498                            ((and sym (coding-system-p sym))
 499                             (help-xref-button 7 'help-coding-system sym))
 500                            ((and sym (charsetp sym))
 501                             (help-xref-button 7 'help-character-set sym)))))))
 502                 ;; Quoted symbols
 503                 (save-excursion
 504                   (while (re-search-forward help-xref-symbol-regexp nil t)
 505                     (let* ((data (match-string 8))
 506                            (sym (intern-soft data)))
 507                       (if sym
 508                           (cond
 509                            ((match-string 3) ; `variable' &c
 510                             (and (or (boundp sym) ; `variable' doesn't ensure
 511                                         ; it's actually bound
 512                                      (get sym 'variable-documentation))
 513                                  (help-xref-button 8 'help-variable sym)))
 514                            ((match-string 4) ; `function' &c
 515                             (and (fboundp sym) ; similarly
 516                                  (help-xref-button 8 'help-function sym)))
 517                            ((match-string 5) ; `face'
 518                             (and (facep sym)
 519                                  (help-xref-button 8 'help-face sym)))
 520                            ((match-string 6)) ; nothing for `symbol'
 521                            ((match-string 7)
 522                             ;; this used:
 523                             ;; #'(lambda (arg)
 524                             ;;     (let ((location
 525                             ;;            (find-function-noselect arg)))
 526                             ;;       (pop-to-buffer (car location))
 527                             ;;  (goto-char (cdr location))))
 528                             (help-xref-button 8 'help-function-def sym))
 529                            ((and
 530                              (facep sym)
 531                              (save-match-data (looking-at "[ \t\n]+face\\W")))
 532                             (help-xref-button 8 'help-face sym))
 533                            ((and (or (boundp sym)
 534                                      (get sym 'variable-documentation))
 535                                  (fboundp sym))
 536                             ;; We can't intuit whether to use the
 537                             ;; variable or function doc -- supply both.
 538                             (help-xref-button 8 'help-symbol sym))
 539                            ((and
 540                              (or (boundp sym)
 541                                  (get sym 'variable-documentation))
 542                              (or
 543                               (documentation-property
 544                                sym 'variable-documentation)
 545                               (condition-case nil
 546                                   (documentation-property
 547                                    (indirect-variable sym)
 548                                    'variable-documentation)
 549                                 (cyclic-variable-indirection nil))))
 550                             (help-xref-button 8 'help-variable sym))
 551                            ((fboundp sym)
 552                             (help-xref-button 8 'help-function sym)))))))
 553                 ;; An obvious case of a key substitution:
 554                 (save-excursion
 555                   (while (re-search-forward
 556                           ;; Assume command name is only word and symbol
 557                           ;; characters to get things like `use M-x foo->bar'.
 558                           ;; Command required to end with word constituent
 559                           ;; to avoid `.' at end of a sentence.
 560                           "\\<M-x\\s-+\\(\\sw\\(\\sw\\|\\s_\\)*\\sw\\)" nil t)
 561                     (let ((sym (intern-soft (match-string 1))))
 562                       (if (fboundp sym)
 563                           (help-xref-button 1 'help-function sym)))))
 564                 ;; Look for commands in whole keymap substitutions:
 565                 (save-excursion
 566                   ;; Make sure to find the first keymap.
 567                   (goto-char (point-min))
 568                   ;; Find a header and the column at which the command
 569                   ;; name will be found.
 570
 571                   ;; If the keymap substitution isn't the last thing in
 572                   ;; the doc string, and if there is anything on the same
 573                   ;; line after it, this code won't recognize the end of it.
 574                   (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 575                                             nil t)
 576                     (let ((col (- (match-end 1) (match-beginning 1))))
 577                       (while
 578                           (and (not (eobp))
 579                                ;; Stop at a pair of blank lines.
 580                                (not (looking-at "\n\\s-*\n")))
 581                         ;; Skip a single blank line.
 582                         (and (eolp) (forward-line))
 583                         (end-of-line)
 584                         (skip-chars-backward "^ \t\n")
 585                         (if (and (>= (current-column) col)
 586                                  (looking-at "\\(\\sw\\|\\s_\\)+$"))
 587                             (let ((sym (intern-soft (match-string 0))))
 588                               (if (fboundp sym)
 589                                   (help-xref-button 0 'help-function sym))))
 590                         (forward-line))))))
 591             (set-syntax-table stab))
 592           ;; Delete extraneous newlines at the end of the docstring
 593           (goto-char (point-max))
 594           (while (and (not (bobp)) (bolp))
 595             (delete-char -1))
 596           (insert "\n")
 597           (when (or help-xref-stack help-xref-forward-stack)
 598             (insert "\n"))
 599           ;; Make a back-reference in this buffer if appropriate.
 600           (when help-xref-stack
 601             (help-insert-xref-button help-back-label 'help-back
 602                                      (current-buffer)))
 603           ;; Make a forward-reference in this buffer if appropriate.
 604           (when help-xref-forward-stack
 605             (when help-xref-stack
 606               (insert "\t"))
 607             (help-insert-xref-button help-forward-label 'help-forward
 608                                      (current-buffer)))
 609           (when (or help-xref-stack help-xref-forward-stack)
 610             (insert "\n")))
 611         ;; View mode steals RET from us.
 612         (set (make-local-variable 'minor-mode-overriding-map-alist)
 613              (list (cons 'view-mode help-xref-override-view-map)))
 614         (set-buffer-modified-p old-modified)))))
 615
 616 ;;;###autoload
 617 (defun help-xref-button (match-number type &rest args)
 618   "Make a hyperlink for cross-reference text previously matched.
 619 MATCH-NUMBER is the subexpression of interest in the last matched
 620 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 621 passed to the button's help-function when it is invoked.
 622 See `help-make-xrefs'."
 623   ;; Don't mung properties we've added specially in some instances.
 624   (unless (button-at (match-beginning match-number))
 625     (make-text-button (match-beginning match-number)
 626                       (match-end match-number)
 627                       'type type 'help-args args)))
 628
 629 ;;;###autoload
 630 (defun help-insert-xref-button (string type &rest args)
 631   "Insert STRING and make a hyperlink from cross-reference text on it.
 632 TYPE is the type of button to use.  Any remaining arguments are passed
 633 to the button's help-function when it is invoked.
 634 See `help-make-xrefs'."
 635   (unless (button-at (point))
 636     (insert-text-button string 'type type 'help-args args)))
 637
 638 ;;;###autoload
 639 (defun help-xref-on-pp (from to)
 640   "Add xrefs for symbols in `pp's output between FROM and TO."
 641   (if (> (- to from) 5000) nil
 642     (with-syntax-table emacs-lisp-mode-syntax-table
 643       (save-excursion
 644         (save-restriction
 645           (narrow-to-region from to)
 646           (goto-char (point-min))
 647           (condition-case nil
 648               (while (not (eobp))
 649                 (cond
 650                  ((looking-at "\"") (forward-sexp 1))
 651                  ((looking-at "#<") (search-forward ">" nil 'move))
 652                  ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 653                   (let* ((sym (intern-soft (match-string 1)))
 654                          (type (cond ((fboundp sym) 'help-function)
 655                                      ((or (memq sym '(t nil))
 656                                           (keywordp sym))
 657                                       nil)
 658                                      ((and sym
 659                                            (or (boundp sym)
 660                                                (get sym
 661                                                     'variable-documentation)))
 662                                       'help-variable))))
 663                     (when type (help-xref-button 1 type sym)))
 664                   (goto-char (match-end 1)))
 665                  (t (forward-char 1))))
 666             (error nil)))))))
 667
 668 \f
 669 ;; Additional functions for (re-)creating types of help buffers.
 670 (defun help-xref-interned (symbol)
 671   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 672 Both variable, function and face documentation are extracted into a single
 673 help buffer."
 674   (with-current-buffer (help-buffer)
 675     ;; Push the previous item on the stack before clobbering the output buffer.
 676     (help-setup-xref nil nil)
 677     (let ((facedoc (when (facep symbol)
 678                      ;; Don't record the current entry in the stack.
 679                      (setq help-xref-stack-item nil)
 680                      (describe-face symbol)))
 681           (fdoc (when (fboundp symbol)
 682                   ;; Don't record the current entry in the stack.
 683                   (setq help-xref-stack-item nil)
 684                   (describe-function symbol)))
 685           (sdoc (when (or (boundp symbol)
 686                           (get symbol 'variable-documentation))
 687                   ;; Don't record the current entry in the stack.
 688                   (setq help-xref-stack-item nil)
 689                   (describe-variable symbol))))
 690       (cond
 691        (sdoc
 692         ;; We now have a help buffer on the variable.
 693         ;; Insert the function and face text before it.
 694         (when (or fdoc facedoc)
 695           (goto-char (point-min))
 696           (let ((inhibit-read-only t))
 697             (when fdoc
 698               (insert fdoc "\n\n")
 699               (when facedoc
 700                 (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 701                         " is also a " "face." "\n\n")))
 702             (when facedoc
 703               (insert facedoc "\n\n"))
 704             (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 705                     " is also a " "variable." "\n\n"))
 706           ;; Don't record the `describe-variable' item in the stack.
 707           (setq help-xref-stack-item nil)
 708           (help-setup-xref (list #'help-xref-interned symbol) nil)))
 709        (fdoc
 710         ;; We now have a help buffer on the function.
 711         ;; Insert face text before it.
 712         (when facedoc
 713           (goto-char (point-max))
 714           (let ((inhibit-read-only t))
 715             (insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
 716                     " is also a " "face." "\n\n" facedoc))
 717           ;; Don't record the `describe-function' item in the stack.
 718           (setq help-xref-stack-item nil)
 719           (help-setup-xref (list #'help-xref-interned symbol) nil)))))))
 720
 721 \f
 722 ;; Navigation/hyperlinking with xrefs
 723
 724 (defun help-xref-go-back (buffer)
 725   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 726   (let (item position method args)
 727     (with-current-buffer buffer
 728       (push (cons (point) help-xref-stack-item) help-xref-forward-stack)
 729       (when help-xref-stack
 730         (setq item (pop help-xref-stack)
 731               ;; Clear the current item so that it won't get pushed
 732               ;; by the function we're about to call.  TODO: We could also
 733               ;; push it onto a "forward" stack and add a `forw' button.
 734               help-xref-stack-item nil
 735               position (car item)
 736               method (cadr item)
 737               args (cddr item))))
 738     (apply method args)
 739     (with-current-buffer buffer
 740       (if (get-buffer-window buffer)
 741           (set-window-point (get-buffer-window buffer) position)
 742         (goto-char position)))))
 743
 744 (defun help-xref-go-forward (buffer)
 745   "From BUFFER, go forward to next help buffer."
 746   (let (item position method args)
 747     (with-current-buffer buffer
 748       (push (cons (point) help-xref-stack-item) help-xref-stack)
 749       (when help-xref-forward-stack
 750         (setq item (pop help-xref-forward-stack)
 751               ;; Clear the current item so that it won't get pushed
 752               ;; by the function we're about to call.  TODO: We could also
 753               ;; push it onto a "forward" stack and add a `forw' button.
 754               help-xref-stack-item nil
 755               position (car item)
 756               method (cadr item)
 757               args (cddr item))))
 758     (apply method args)
 759     (with-current-buffer buffer
 760       (if (get-buffer-window buffer)
 761           (set-window-point (get-buffer-window buffer) position)
 762         (goto-char position)))))
 763
 764 (defun help-go-back ()
 765   "Go back to previous topic in this help buffer."
 766   (interactive)
 767   (if help-xref-stack
 768       (help-xref-go-back (current-buffer))
 769     (error "No previous help buffer")))
 770
 771 (defun help-go-forward ()
 772   "Go back to next topic in this help buffer."
 773   (interactive)
 774   (if help-xref-forward-stack
 775       (help-xref-go-forward (current-buffer))
 776     (error "No next help buffer")))
 777
 778 (defun help-do-xref (pos function args)
 779   "Call the help cross-reference function FUNCTION with args ARGS.
 780 Things are set up properly so that the resulting help-buffer has
 781 a proper [back] button."
 782   ;; There is a reference at point.  Follow it.
 783   (let ((help-xref-following t))
 784     (apply function args)))
 785
 786 ;; The doc string is meant to explain what buttons do.
 787 (defun help-follow-mouse ()
 788   "Follow the cross-reference that you click on."
 789   (interactive)
 790   (error "No cross-reference here"))
 791
 792 ;; The doc string is meant to explain what buttons do.
 793 (defun help-follow ()
 794   "Follow cross-reference at point.
 795
 796 For the cross-reference format, see `help-make-xrefs'."
 797   (interactive)
 798   (error "No cross-reference here"))
 799
 800 (defun help-follow-symbol (&optional pos)
 801   "In help buffer, show docs for symbol at POS, defaulting to point.
 802 Show all docs for that symbol as either a variable, function or face."
 803   (interactive "d")
 804   (unless pos
 805     (setq pos (point)))
 806   ;; check if the symbol under point is a function, variable or face
 807   (let ((sym
 808          (intern
 809           (save-excursion
 810             (goto-char pos) (skip-syntax-backward "w_")
 811             (buffer-substring (point)
 812                               (progn (skip-syntax-forward "w_")
 813                                      (point)))))))
 814     (when (or (boundp sym)
 815               (get sym 'variable-documentation)
 816               (fboundp sym) (facep sym))
 817       (help-do-xref pos #'help-xref-interned (list sym)))))
 818
 819 (defun help-mode-revert-buffer (ignore-auto noconfirm)
 820   (when (or noconfirm (yes-or-no-p "Revert help buffer? "))
 821     (let ((pos (point))
 822           (item help-xref-stack-item)
 823           ;; Pretend there is no current item to add to the history.
 824           (help-xref-stack-item nil)
 825           ;; Use the current buffer.
 826           (help-xref-following t))
 827       (apply (car item) (cdr item))
 828       (goto-char pos))))
 829
 830 (defun help-insert-string (string)
 831   "Insert STRING to the help buffer and install xref info for it.
 832 This function can be used to restore the old contents of the help buffer
 833 when going back to the previous topic in the xref stack.  It is needed
 834 in case when it is impossible to recompute the old contents of the
 835 help buffer by other means."
 836   (setq help-xref-stack-item (list #'help-insert-string string))
 837   (with-output-to-temp-buffer (help-buffer)
 838     (insert string)))
 839
 840 (provide 'help-mode)
 841
 842 ;;; help-mode.el ends here