lisp/help-macro.el

   1 ;;; help-macro.el --- makes command line help such as help-for-help
   2
   3 ;; Copyright (C) 1993, 1994, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Lynn Slater <lrs@indetech.com>
   7 ;; Maintainer: FSF
   8 ;; Created: Mon Oct  1 11:42:39 1990
   9 ;; Adapted-By: ESR
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This file supplies the macro make-help-screen which constructs
  31 ;; single character dispatching with browsable help such as that provided
  32 ;; by help-for-help. This can be used to make many modes easier to use; for
  33 ;; example, the GNU Emacs Empire Tool uses this for every "nested" mode map
  34 ;; called from the main mode map.
  35
  36 ;;       The name of this package was changed from help-screen.el to
  37 ;; help-macro.el in order to fit in a 14-character limit.
  38
  39 ;;-> ***********************  Example of use *********************************
  40
  41 ;;->(make-help-screen help-for-empire-redistribute-map
  42 ;;->              "c:civ m:mil p:population f:food ?"
  43 ;;->              "You have discovered the GEET redistribution commands
  44 ;;->   From here, you can use the following options:
  45 ;;->
  46 ;;->c   Redistribute civs from overfull sectors into connected underfull ones
  47 ;;->      The functions typically named by empire-ideal-civ-fcn control
  48 ;;->          based in part on empire-sector-civ-threshold
  49 ;;->m   Redistribute military using levels given by empire-ideal-mil-fcn
  50 ;;->p   Redistribute excess population to highways for max pop growth
  51 ;;->      Excess is any sector so full babies will not be born.
  52 ;;->f   Even out food on highways to highway min and leave levels
  53 ;;->      This is good to pump max food to all warehouses/dist pts
  54 ;;->
  55 ;;->
  56 ;;->Use \\[help-for-empire-redistribute-map] for help on redistribution.
  57 ;;->Use \\[help-for-empire-extract-map] for help on data extraction.
  58 ;;->Please use \\[describe-key] to find out more about any of the other keys."
  59 ;;->              empire-shell-redistribute-map)
  60
  61 ;;->  (define-key c-mp "\C-h" 'help-for-empire-redistribute-map)
  62 ;;->  (define-key c-mp help-character 'help-for-empire-redistribute-map)
  63
  64 ;;; Change Log:
  65 ;;
  66 ;; 22-Jan-1991          Lynn Slater x2048
  67 ;;    Last Modified: Mon Oct  1 11:43:52 1990 #3 (Lynn Slater)
  68 ;;    documented better
  69
  70 ;;; Code:
  71
  72 (require 'backquote)
  73
  74 ;;;###autoload
  75 (defcustom three-step-help nil
  76   "*Non-nil means give more info about Help command in three steps.
  77 The three steps are simple prompt, prompt with all options,
  78 and window listing and describing the options.
  79 A value of nil means skip the middle step, so that
  80 \\[help-command] \\[help-command] gives the window that lists the options."
  81   :type 'boolean
  82   :group 'help)
  83
  84 (defmacro make-help-screen (fname help-line help-text helped-map)
  85   "Construct help-menu function name FNAME.
  86 When invoked, FNAME shows HELP-LINE and reads a command using HELPED-MAP.
  87 If the command is the help character, FNAME displays HELP-TEXT
  88 and continues trying to read a command using HELPED-MAP.
  89 If HELP-TEXT contains the sequence `%THIS-KEY%', that is replaced
  90 with the key sequence that invoked FNAME.
  91 When FNAME finally does get a command, it executes that command
  92 and then returns."
  93  (let ((doc-fn (intern (concat (symbol-name fname) "-doc"))))
  94   `(progn
  95     (defun ,doc-fn () ,help-text)
  96     (defun ,fname ()
  97            "Help command."
  98            (interactive)
  99            (let ((line-prompt
 100                   (substitute-command-keys ,help-line)))
 101              (if three-step-help
 102                  (message "%s" line-prompt))
 103              (let* ((help-screen (documentation (quote ,doc-fn)))
 104                     ;; We bind overriding-local-map for very small
 105                     ;; sections, *excluding* where we switch buffers
 106                     ;; and where we execute the chosen help command.
 107                     (local-map (make-sparse-keymap))
 108                     (minor-mode-map-alist nil)
 109                     (prev-frame (selected-frame))
 110                     config new-frame key char)
 111                (if (string-match "%THIS-KEY%" help-screen)
 112                    (setq help-screen
 113                          (replace-match (key-description (substring (this-command-keys) 0 -1))
 114                                         t t help-screen)))
 115                (unwind-protect
 116                    (progn
 117                      (setcdr local-map ,helped-map)
 118                      (define-key local-map [t] 'undefined)
 119                      ;; Make the scroll bar keep working normally.
 120                      (define-key local-map [vertical-scroll-bar]
 121                        (lookup-key global-map [vertical-scroll-bar]))
 122                      (if three-step-help
 123                          (progn
 124                            (setq key (let ((overriding-local-map local-map))
 125                                        (read-key-sequence nil)))
 126                            ;; Make the HELP key translate to C-h.
 127                            (if (lookup-key function-key-map key)
 128                                (setq key (lookup-key function-key-map key)))
 129                            (setq char (aref key 0)))
 130                        (setq char ??))
 131                      (if (or (eq char ??) (eq char help-char)
 132                              (memq char help-event-list))
 133                          (progn
 134                            (setq config (current-window-configuration))
 135                            (switch-to-buffer-other-window "*Help*")
 136                            (and (fboundp 'make-frame)
 137                                 (not (eq (window-frame (selected-window))
 138                                          prev-frame))
 139                                 (setq new-frame (window-frame (selected-window))
 140                                       config nil))
 141                            (setq buffer-read-only nil)
 142                            (let ((inhibit-read-only t))
 143                              (erase-buffer)
 144                              (insert help-screen))
 145                            (help-mode)
 146                            (goto-char (point-min))
 147                            (while (or (memq char (append help-event-list
 148                                                          (cons help-char '(?? ?\C-v ?\s ?\177 delete backspace vertical-scroll-bar ?\M-v))))
 149                                       (eq (car-safe char) 'switch-frame)
 150                                       (equal key "\M-v"))
 151                              (condition-case nil
 152                                  (progn
 153                                    (if (eq (car-safe char) 'switch-frame)
 154                                        (handle-switch-frame char))
 155                                    (if (memq char '(?\C-v ?\ ))
 156                                        (scroll-up))
 157                                    (if (or (memq char '(?\177 ?\M-v
 158                                                         delete backspace))
 159                                            (equal key "\M-v"))
 160                                        (scroll-down)))
 161                                (error nil))
 162                              (let ((cursor-in-echo-area t)
 163                                    (overriding-local-map local-map))
 164                                (setq key (read-key-sequence
 165                                           (format "Type one of the options listed%s: "
 166                                                   (if (pos-visible-in-window-p
 167                                                        (point-max))
 168                                                       "" ", or SPACE or DEL to scroll")))
 169                                      char (aref key 0)))
 170
 171                              ;; If this is a scroll bar command, just run it.
 172                              (when (eq char 'vertical-scroll-bar)
 173                                (command-execute (lookup-key local-map key) nil key)))))
 174                      ;; We don't need the prompt any more.
 175                      (message "")
 176                      ;; Mouse clicks are not part of the help feature,
 177                      ;; so reexecute them in the standard environment.
 178                      (if (listp char)
 179                          (setq unread-command-events
 180                                (cons char unread-command-events)
 181                                config nil)
 182                        (let ((defn (lookup-key local-map key)))
 183                          (if defn
 184                              (progn
 185                                (if config
 186                                    (progn
 187                                      (set-window-configuration config)
 188                                      (setq config nil)))
 189                                (if new-frame
 190                                    (progn (iconify-frame new-frame)
 191                                           (setq new-frame nil)))
 192                                (call-interactively defn))
 193                            (ding)))))
 194                  (if new-frame (iconify-frame new-frame))
 195                  (if config
 196                      (set-window-configuration config))))))
 197      )))
 198
 199 (provide 'help-macro)
 200
 201 ;;; arch-tag: 59fee949-1686-485a-8a05-83418073e257
 202 ;;; help-macro.el ends here