lisp/wid-edit.el

   1 ;;; wid-edit.el --- Functions for creating and using widgets.
   2 ;;
   3 ;; Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: extensions
   7 ;; Version: 1.9951
   8 ;; X-URL: http://www.dina.kvl.dk/~abraham/custom/
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; See `widget.el'.
  30
  31 ;;; Code:
  32
  33 (require 'widget)
  34 (eval-when-compile (require 'cl))
  35
  36 ;;; Compatibility.
  37
  38 (eval-and-compile
  39   (autoload 'pp-to-string "pp")
  40   (autoload 'Info-goto-node "info")
  41   (autoload 'finder-commentary "finder" nil t)
  42
  43   (when (string-match "XEmacs" emacs-version)
  44     (condition-case nil
  45         (require 'overlay)
  46       (error (load-library "x-overlay"))))
  47
  48   (if (string-match "XEmacs" emacs-version)
  49       (defun widget-event-point (event)
  50         "Character position of the end of event if that exists, or nil."
  51         (if (mouse-event-p event)
  52             (event-point event)
  53           nil))
  54     (defun widget-event-point (event)
  55       "Character position of the end of event if that exists, or nil."
  56       (posn-point (event-end event))))
  57
  58   (defalias 'widget-read-event (if (string-match "XEmacs" emacs-version)
  59                                    'next-event
  60                                  'read-event))
  61
  62   ;; The following should go away when bundled with Emacs.
  63   (condition-case ()
  64       (require 'custom)
  65     (error nil))
  66
  67   (unless (and (featurep 'custom) (fboundp 'custom-declare-variable))
  68     ;; We have the old custom-library, hack around it!
  69     (defmacro defgroup (&rest args) nil)
  70     (defmacro defcustom (var value doc &rest args)
  71       (` (defvar (, var) (, value) (, doc))))
  72     (defmacro defface (&rest args) nil)
  73     (define-widget-keywords :prefix :tag :load :link :options :type :group)
  74     (when (fboundp 'copy-face)
  75       (copy-face 'default 'widget-documentation-face)
  76       (copy-face 'bold 'widget-button-face)
  77       (copy-face 'italic 'widget-field-face)))
  78
  79   (unless (fboundp 'button-release-event-p)
  80     ;; XEmacs function missing from Emacs.
  81     (defun button-release-event-p (event)
  82       "Non-nil if EVENT is a mouse-button-release event object."
  83       (and (eventp event)
  84            (memq (event-basic-type event) '(mouse-1 mouse-2 mouse-3))
  85            (or (memq 'click (event-modifiers event))
  86                (memq  'drag (event-modifiers event))))))
  87
  88   (unless (fboundp 'functionp)
  89     ;; Missing from Emacs 19.34 and earlier.
  90     (defun functionp (object)
  91       "Non-nil of OBJECT is a type of object that can be called as a function."
  92       (or (subrp object) (byte-code-function-p object)
  93           (eq (car-safe object) 'lambda)
  94           (and (symbolp object) (fboundp object)))))
  95
  96   (unless (fboundp 'error-message-string)
  97     ;; Emacs function missing in XEmacs.
  98     (defun error-message-string (obj)
  99       "Convert an error value to an error message."
 100       (let ((buf (get-buffer-create " *error-message*")))
 101         (erase-buffer buf)
 102         (display-error obj buf)
 103         (buffer-string buf)))))
 104
 105 ;;; Customization.
 106
 107 (defgroup widgets nil
 108   "Customization support for the Widget Library."
 109   :link '(custom-manual "(widget)Top")
 110   :link '(url-link :tag "Development Page"
 111                    "http://www.dina.kvl.dk/~abraham/custom/")
 112   :link '(emacs-library-link :tag "Lisp File" "widget.el")
 113   :prefix "widget-"
 114   :group 'extensions
 115   :group 'hypermedia)
 116
 117 (defgroup widget-documentation nil
 118   "Options controling the display of documentation strings."
 119   :group 'widgets)
 120
 121 (defgroup widget-faces nil
 122   "Faces used by the widget library."
 123   :group 'widgets
 124   :group 'faces)
 125
 126 (defvar widget-documentation-face 'widget-documentation-face
 127   "Face used for documentation strings in widges.
 128 This exists as a variable so it can be set locally in certain buffers.")
 129
 130 (defface widget-documentation-face '((((class color)
 131                                        (background dark))
 132                                       (:foreground "lime green"))
 133                                      (((class color)
 134                                        (background light))
 135                                       (:foreground "dark green"))
 136                                      (t nil))
 137   "Face used for documentation text."
 138   :group 'widget-documentation
 139   :group 'widget-faces)
 140
 141 (defvar widget-button-face 'widget-button-face
 142   "Face used for buttons in widges.
 143 This exists as a variable so it can be set locally in certain buffers.")
 144
 145 (defface widget-button-face '((t (:bold t)))
 146   "Face used for widget buttons."
 147   :group 'widget-faces)
 148
 149 (defcustom widget-mouse-face 'highlight
 150   "Face used for widget buttons when the mouse is above them."
 151   :type 'face
 152   :group 'widget-faces)
 153
 154 (defface widget-field-face '((((class grayscale color)
 155                                (background light))
 156                               (:background "gray85"))
 157                              (((class grayscale color)
 158                                (background dark))
 159                               (:background "dim gray"))
 160                              (t
 161                               (:italic t)))
 162   "Face used for editable fields."
 163   :group 'widget-faces)
 164
 165 (defface widget-single-line-field-face '((((class grayscale color)
 166                                            (background light))
 167                                           (:background "gray85"))
 168                                          (((class grayscale color)
 169                                            (background dark))
 170                                           (:background "dim gray"))
 171                                          (t
 172                                           (:italic t)))
 173   "Face used for editable fields spanning only a single line."
 174   :group 'widget-faces)
 175
 176 ;;; This causes display-table to be loaded, and not usefully.
 177 ;;;(defvar widget-single-line-display-table
 178 ;;;  (let ((table (make-display-table)))
 179 ;;;    (aset table 9  "^I")
 180 ;;;    (aset table 10 "^J")
 181 ;;;    table)
 182 ;;;  "Display table used for single-line editable fields.")
 183
 184 ;;;(when (fboundp 'set-face-display-table)
 185 ;;;  (set-face-display-table 'widget-single-line-field-face
 186 ;;;                       widget-single-line-display-table))
 187
 188 ;;; Utility functions.
 189 ;;
 190 ;; These are not really widget specific.
 191
 192 (defsubst widget-plist-member (plist prop)
 193   ;; Return non-nil if PLIST has the property PROP.
 194   ;; PLIST is a property list, which is a list of the form
 195   ;; (PROP1 VALUE1 PROP2 VALUE2 ...).  PROP is a symbol.
 196   ;; Unlike `plist-get', this allows you to distinguish between a missing
 197   ;; property and a property with the value nil.
 198   ;; The value is actually the tail of PLIST whose car is PROP.
 199   (while (and plist (not (eq (car plist) prop)))
 200     (setq plist (cdr (cdr plist))))
 201   plist)
 202
 203 (defun widget-princ-to-string (object)
 204   ;; Return string representation of OBJECT, any Lisp object.
 205   ;; No quoting characters are used; no delimiters are printed around
 206   ;; the contents of strings.
 207   (save-excursion
 208     (set-buffer (get-buffer-create " *widget-tmp*"))
 209     (erase-buffer)
 210     (let ((standard-output (current-buffer)))
 211       (princ object))
 212     (buffer-string)))
 213
 214 (defun widget-clear-undo ()
 215   "Clear all undo information."
 216   (buffer-disable-undo (current-buffer))
 217   (buffer-enable-undo))
 218
 219 (defcustom widget-menu-max-size 40
 220   "Largest number of items allowed in a popup-menu.
 221 Larger menus are read through the minibuffer."
 222   :group 'widgets
 223   :type 'integer)
 224
 225 (defcustom widget-menu-minibuffer-flag (string-match "XEmacs" emacs-version)
 226   "*Control how to ask for a choice from the keyboard.
 227 Non-nil means use the minibuffer;
 228 nil means read a single character."
 229   :group 'widgets
 230   :type 'boolean)
 231
 232 (defun widget-choose (title items &optional event)
 233   "Choose an item from a list.
 234
 235 First argument TITLE is the name of the list.
 236 Second argument ITEMS is an list whose members are either
 237  (NAME . VALUE), to indicate selectable items, or just strings to
 238  indicate unselectable items.
 239 Optional third argument EVENT is an input event.
 240
 241 The user is asked to choose between each NAME from the items alist,
 242 and the VALUE of the chosen element will be returned.  If EVENT is a
 243 mouse event, and the number of elements in items is less than
 244 `widget-menu-max-size', a popup menu will be used, otherwise the
 245 minibuffer."
 246   (cond ((and (< (length items) widget-menu-max-size)
 247               event (fboundp 'x-popup-menu) window-system)
 248          ;; We are in Emacs-19, pressed by the mouse
 249          (x-popup-menu event
 250                        (list title (cons "" items))))
 251         ((and (< (length items) widget-menu-max-size)
 252               event (fboundp 'popup-menu) window-system)
 253          ;; We are in XEmacs, pressed by the mouse
 254          (let ((val (get-popup-menu-response
 255                      (cons title
 256                            (mapcar
 257                             (function
 258                              (lambda (x)
 259                                (if (stringp x)
 260                                    (vector x nil nil)
 261                                  (vector (car x) (list (car x)) t))))
 262                             items)))))
 263            (setq val (and val
 264                           (listp (event-object val))
 265                           (stringp (car-safe (event-object val)))
 266                           (car (event-object val))))
 267            (cdr (assoc val items))))
 268         (widget-menu-minibuffer-flag
 269          ;; Read the choice of name from the minibuffer.
 270          (setq items (widget-remove-if 'stringp items))
 271          (let ((val (completing-read (concat title ": ") items nil t)))
 272            (if (stringp val)
 273                (let ((try (try-completion val items)))
 274                  (when (stringp try)
 275                    (setq val try))
 276                  (cdr (assoc val items)))
 277              nil)))
 278         (t
 279          ;; Construct a menu of the choices
 280          ;; and then use it for prompting for a single character.
 281          (let* ((overriding-terminal-local-map
 282                  (make-sparse-keymap))
 283                 map choice (next-digit ?0)
 284                 some-choice-enabled
 285                 value)
 286            ;; Define SPC as a prefix char to get to this menu.
 287            (define-key overriding-terminal-local-map " "
 288              (setq map (make-sparse-keymap title)))
 289            (save-excursion
 290              (set-buffer (get-buffer-create " widget-choose"))
 291              (erase-buffer)
 292              (insert "Available choices:\n\n")
 293              (while items
 294                (setq choice (car items) items (cdr items))
 295                (if (consp choice)
 296                    (let* ((name (car choice))
 297                          (function (cdr choice)))
 298                      (insert (format "%c = %s\n" next-digit name))
 299                      (define-key map (vector next-digit) function)
 300                      (setq some-choice-enabled t)))
 301                ;; Allocate digits to disabled alternatives
 302                ;; so that the digit of a given alternative never varies.
 303                (setq next-digit (1+ next-digit)))
 304              (insert "\nC-g = Quit"))
 305            (or some-choice-enabled
 306                (error "None of the choices is currently meaningful"))
 307            (define-key map [?\C-g] 'keyboard-quit)
 308            (define-key map [t] 'keyboard-quit)
 309            (setcdr map (nreverse (cdr map)))
 310            ;; Unread a SPC to lead to our new menu.
 311            (setq unread-command-events (cons ?\ unread-command-events))
 312            ;; Read a char with the menu, and return the result
 313            ;; that corresponds to it.
 314            (save-window-excursion
 315              (display-buffer (get-buffer " widget-choose"))
 316              (let ((cursor-in-echo-area t))
 317                (setq value
 318                      (lookup-key overriding-terminal-local-map
 319                                  (read-key-sequence title) t))))
 320            (when (eq value 'keyboard-quit)
 321              (error "Canceled"))
 322            value))))
 323
 324 (defun widget-remove-if (predictate list)
 325   (let (result (tail list))
 326     (while tail
 327       (or (funcall predictate (car tail))
 328           (setq result (cons (car tail) result)))
 329       (setq tail (cdr tail)))
 330     (nreverse result)))
 331
 332 ;;; Widget text specifications.
 333 ;;
 334 ;; These functions are for specifying text properties.
 335
 336 (defcustom widget-field-add-space
 337   (or (< emacs-major-version 20)
 338       (and (eq emacs-major-version 20)
 339            (< emacs-minor-version 3))
 340       (not (string-match "XEmacs" emacs-version)))
 341   "Non-nil means add extra space at the end of editable text fields.
 342
 343 This is needed on all versions of Emacs, and on XEmacs before 20.3.
 344 If you don't add the space, it will become impossible to edit a zero
 345 size field."
 346   :type 'boolean
 347   :group 'widgets)
 348
 349 (defcustom widget-field-use-before-change
 350   (and (or (> emacs-minor-version 34)
 351            (> emacs-major-version 19))
 352        (not (string-match "XEmacs" emacs-version)))
 353   "Non-nil means use `before-change-functions' to track editable fields.
 354 This enables the use of undo, but doesn't work on Emacs 19.34 and earlier.
 355 Using before hooks also means that the :notify function can't know the
 356 new value."
 357   :type 'boolean
 358   :group 'widgets)
 359
 360 (defun widget-specify-field (widget from to)
 361   "Specify editable button for WIDGET between FROM and TO."
 362   ;; Terminating space is not part of the field, but necessary in
 363   ;; order for local-map to work.  Remove next sexp if local-map works
 364   ;; at the end of the overlay.
 365   (save-excursion
 366     (goto-char to)
 367     (cond ((null (widget-get widget :size))
 368            (forward-char 1))
 369           (widget-field-add-space
 370            (insert-and-inherit " ")))
 371     (setq to (point)))
 372   (let ((map (widget-get widget :keymap))
 373         (face (or (widget-get widget :value-face) 'widget-field-face))
 374         (help-echo (widget-get widget :help-echo))
 375         (overlay (make-overlay from to nil
 376                                nil (or (not widget-field-add-space)
 377                                        (widget-get widget :size)))))
 378     (unless (or (stringp help-echo) (null help-echo))
 379       (setq help-echo 'widget-mouse-help))
 380     (widget-put widget :field-overlay overlay)
 381     (overlay-put overlay 'detachable nil)
 382     (overlay-put overlay 'field widget)
 383     (overlay-put overlay 'local-map map)
 384     (overlay-put overlay 'keymap map)
 385     (overlay-put overlay 'face face)
 386     (overlay-put overlay 'balloon-help help-echo)
 387     (overlay-put overlay 'help-echo help-echo)))
 388
 389 (defun widget-specify-button (widget from to)
 390   "Specify button for WIDGET between FROM and TO."
 391   (let ((face (widget-apply widget :button-face-get))
 392         (help-echo (widget-get widget :help-echo))
 393         (overlay (make-overlay from to nil t nil)))
 394     (widget-put widget :button-overlay overlay)
 395     (unless (or (null help-echo) (stringp help-echo))
 396       (setq help-echo 'widget-mouse-help))
 397     (overlay-put overlay 'button widget)
 398     (overlay-put overlay 'mouse-face widget-mouse-face)
 399     (overlay-put overlay 'balloon-help help-echo)
 400     (overlay-put overlay 'help-echo help-echo)
 401     (overlay-put overlay 'face face)))
 402
 403 (defun widget-mouse-help (extent)
 404   "Find mouse help string for button in extent."
 405   (let* ((widget (widget-at (extent-start-position extent)))
 406          (help-echo (and widget (widget-get widget :help-echo))))
 407     (cond ((stringp help-echo)
 408            help-echo)
 409           ((and (symbolp help-echo) (fboundp help-echo)
 410                 (stringp (setq help-echo (funcall help-echo widget))))
 411            help-echo)
 412           (t
 413            (format "(widget %S :help-echo %S)" widget help-echo)))))
 414
 415 (defun widget-specify-sample (widget from to)
 416   ;; Specify sample for WIDGET between FROM and TO.
 417   (let ((face (widget-apply widget :sample-face-get))
 418         (overlay (make-overlay from to nil t nil)))
 419     (overlay-put overlay 'face face)
 420     (widget-put widget :sample-overlay overlay)))
 421
 422 (defun widget-specify-doc (widget from to)
 423   ;; Specify documentation for WIDGET between FROM and TO.
 424   (let ((overlay (make-overlay from to nil t nil)))
 425     (overlay-put overlay 'widget-doc widget)
 426     (overlay-put overlay 'face widget-documentation-face)
 427     (widget-put widget :doc-overlay overlay)))
 428
 429 (defmacro widget-specify-insert (&rest form)
 430   ;; Execute FORM without inheriting any text properties.
 431   (`
 432    (save-restriction
 433      (let ((inhibit-read-only t)
 434            result
 435            before-change-functions
 436            after-change-functions)
 437        (insert "<>")
 438        (narrow-to-region (- (point) 2) (point))
 439        (goto-char (1+ (point-min)))
 440        (setq result (progn (,@ form)))
 441        (delete-region (point-min) (1+ (point-min)))
 442        (delete-region (1- (point-max)) (point-max))
 443        (goto-char (point-max))
 444        result))))
 445
 446 (defface widget-inactive-face '((((class grayscale color)
 447                                   (background dark))
 448                                  (:foreground "light gray"))
 449                                 (((class grayscale color)
 450                                   (background light))
 451                                  (:foreground "dim gray"))
 452                                 (t
 453                                  (:italic t)))
 454   "Face used for inactive widgets."
 455   :group 'widget-faces)
 456
 457 (defun widget-specify-inactive (widget from to)
 458   "Make WIDGET inactive for user modifications."
 459   (unless (widget-get widget :inactive)
 460     (let ((overlay (make-overlay from to nil t nil)))
 461       (overlay-put overlay 'face 'widget-inactive-face)
 462       ;; This is disabled, as it makes the mouse cursor change shape.
 463       ;; (overlay-put overlay 'mouse-face 'widget-inactive-face)
 464       (overlay-put overlay 'evaporate t)
 465       (overlay-put overlay 'priority 100)
 466       (overlay-put overlay (if (string-match "XEmacs" emacs-version)
 467                                'read-only
 468                              'modification-hooks) '(widget-overlay-inactive))
 469       (widget-put widget :inactive overlay))))
 470
 471 (defun widget-overlay-inactive (&rest junk)
 472   "Ignoring the arguments, signal an error."
 473   (unless inhibit-read-only
 474     (error "Attempt to modify inactive widget")))
 475
 476
 477 (defun widget-specify-active (widget)
 478   "Make WIDGET active for user modifications."
 479   (let ((inactive (widget-get widget :inactive)))
 480     (when inactive
 481       (delete-overlay inactive)
 482       (widget-put widget :inactive nil))))
 483
 484 ;;; Widget Properties.
 485
 486 (defsubst widget-type (widget)
 487   "Return the type of WIDGET, a symbol."
 488   (car widget))
 489
 490 (defun widget-put (widget property value)
 491   "In WIDGET set PROPERTY to VALUE.
 492 The value can later be retrived with `widget-get'."
 493   (setcdr widget (plist-put (cdr widget) property value)))
 494
 495 (defun widget-get (widget property)
 496   "In WIDGET, get the value of PROPERTY.
 497 The value could either be specified when the widget was created, or
 498 later with `widget-put'."
 499   (let ((missing t)
 500         value tmp)
 501     (while missing
 502       (cond ((setq tmp (widget-plist-member (cdr widget) property))
 503              (setq value (car (cdr tmp))
 504                    missing nil))
 505             ((setq tmp (car widget))
 506              (setq widget (get tmp 'widget-type)))
 507             (t
 508              (setq missing nil))))
 509     value))
 510
 511 (defun widget-get-indirect (widget property)
 512   "In WIDGET, get the value of PROPERTY.
 513 If the value is a symbol, return its binding.
 514 Otherwise, just return the value."
 515   (let ((value (widget-get widget property)))
 516     (if (symbolp value)
 517         (symbol-value value)
 518       value)))
 519
 520 (defun widget-member (widget property)
 521   "Non-nil iff there is a definition in WIDGET for PROPERTY."
 522   (cond ((widget-plist-member (cdr widget) property)
 523          t)
 524         ((car widget)
 525          (widget-member (get (car widget) 'widget-type) property))
 526         (t nil)))
 527
 528 ;;;###autoload
 529 (defun widget-apply (widget property &rest args)
 530   "Apply the value of WIDGET's PROPERTY to the widget itself.
 531 ARGS are passed as extra arguments to the function."
 532   (apply (widget-get widget property) widget args))
 533
 534 (defun widget-value (widget)
 535   "Extract the current value of WIDGET."
 536   (widget-apply widget
 537                 :value-to-external (widget-apply widget :value-get)))
 538
 539 (defun widget-value-set (widget value)
 540   "Set the current value of WIDGET to VALUE."
 541   (widget-apply widget
 542                 :value-set (widget-apply widget
 543                                          :value-to-internal value)))
 544
 545 (defun widget-match-inline (widget vals)
 546   ;; In WIDGET, match the start of VALS.
 547   (cond ((widget-get widget :inline)
 548          (widget-apply widget :match-inline vals))
 549         ((and vals
 550               (widget-apply widget :match (car vals)))
 551          (cons (list (car vals)) (cdr vals)))
 552         (t nil)))
 553
 554 (defun widget-apply-action (widget &optional event)
 555   "Apply :action in WIDGET in response to EVENT."
 556   (if (widget-apply widget :active)
 557       (widget-apply widget :action event)
 558     (error "Attempt to perform action on inactive widget")))
 559
 560 ;;; Helper functions.
 561 ;;
 562 ;; These are widget specific.
 563
 564 ;;;###autoload
 565 (defun widget-prompt-value (widget prompt &optional value unbound)
 566   "Prompt for a value matching WIDGET, using PROMPT.
 567 The current value is assumed to be VALUE, unless UNBOUND is non-nil."
 568   (unless (listp widget)
 569     (setq widget (list widget)))
 570   (setq prompt (format "[%s] %s" (widget-type widget) prompt))
 571   (setq widget (widget-convert widget))
 572   (let ((answer (widget-apply widget :prompt-value prompt value unbound)))
 573     (unless (widget-apply widget :match answer)
 574       (error "Value does not match %S type." (car widget)))
 575     answer))
 576
 577 (defun widget-get-sibling (widget)
 578   "Get the item WIDGET is assumed to toggle.
 579 This is only meaningful for radio buttons or checkboxes in a list."
 580   (let* ((parent (widget-get widget :parent))
 581          (children (widget-get parent :children))
 582          child)
 583     (catch 'child
 584       (while children
 585         (setq child (car children)
 586               children (cdr children))
 587         (when (eq (widget-get child :button) widget)
 588           (throw 'child child)))
 589       nil)))
 590
 591 (defun widget-map-buttons (function &optional buffer maparg)
 592   "Map FUNCTION over the buttons in BUFFER.
 593 FUNCTION is called with the arguments WIDGET and MAPARG.
 594
 595 If FUNCTION returns non-nil, the walk is cancelled.
 596
 597 The arguments MAPARG, and BUFFER default to nil and (current-buffer),
 598 respectively."
 599   (let ((cur (point-min))
 600         (widget nil)
 601         (parent nil)
 602         (overlays (if buffer
 603                       (save-excursion (set-buffer buffer) (overlay-lists))
 604                     (overlay-lists))))
 605     (setq overlays (append (car overlays) (cdr overlays)))
 606     (while (setq cur (pop overlays))
 607       (setq widget (overlay-get cur 'button))
 608       (if (and widget (funcall function widget maparg))
 609           (setq overlays nil)))))
 610
 611 ;;; Glyphs.
 612
 613 (defcustom widget-glyph-directory (concat data-directory "custom/")
 614   "Where widget glyphs are located.
 615 If this variable is nil, widget will try to locate the directory
 616 automatically."
 617   :group 'widgets
 618   :type 'directory)
 619
 620 (defcustom widget-glyph-enable t
 621   "If non nil, use glyphs in images when available."
 622   :group 'widgets
 623   :type 'boolean)
 624
 625 (defcustom widget-image-conversion
 626   '((xpm ".xpm") (gif ".gif") (png ".png") (jpeg ".jpg" ".jpeg")
 627     (xbm ".xbm"))
 628   "Conversion alist from image formats to file name suffixes."
 629   :group 'widgets
 630   :type '(repeat (cons :format "%v"
 631                        (symbol :tag "Image Format" unknown)
 632                        (repeat :tag "Suffixes"
 633                                (string :format "%v")))))
 634
 635 (defun widget-glyph-find (image tag)
 636   "Create a glyph corresponding to IMAGE with string TAG as fallback.
 637 IMAGE should either already be a glyph, or be a file name sans
 638 extension (xpm, xbm, gif, jpg, or png) located in
 639 `widget-glyph-directory'."
 640   (cond ((not (and image
 641                    (string-match "XEmacs" emacs-version)
 642                    widget-glyph-enable
 643                    (fboundp 'make-glyph)
 644                    (fboundp 'locate-file)
 645                    image))
 646          ;; We don't want or can't use glyphs.
 647          nil)
 648         ((and (fboundp 'glyphp)
 649               (glyphp image))
 650          ;; Already a glyph.  Use it.
 651          image)
 652         ((stringp image)
 653          ;; A string.  Look it up in relevant directories.
 654          (let* ((dirlist (list (or widget-glyph-directory
 655                                    (concat data-directory
 656                                            "custom/"))
 657                                data-directory))
 658                 (formats widget-image-conversion)
 659                 file)
 660            (while (and formats (not file))
 661              (when (valid-image-instantiator-format-p (car (car formats)))
 662                (setq file (locate-file image dirlist
 663                                        (mapconcat 'identity
 664                                                   (cdr (car formats))
 665                                                   ":"))))
 666              (unless file
 667                (setq formats (cdr formats))))
 668            (and file
 669                 ;; We create a glyph with the file as the default image
 670                 ;; instantiator, and the TAG fallback
 671                 (make-glyph (list (vector (car (car formats)) ':file file)
 672                                   (vector 'string ':data tag))))))
 673         ((valid-instantiator-p image 'image)
 674          ;; A valid image instantiator (e.g. [gif :file "somefile"] etc.)
 675          (make-glyph (list image
 676                            (vector 'string ':data tag))))
 677         ((consp image)
 678          ;; This could be virtually anything.  Let `make-glyph' sort it out.
 679          (make-glyph image))
 680         (t
 681          ;; Oh well.
 682          nil)))
 683
 684 (defun widget-glyph-insert (widget tag image &optional down inactive)
 685   "In WIDGET, insert the text TAG or, if supported, IMAGE.
 686 IMAGE should either be a glyph, an image instantiator, or an image file
 687 name sans extension (xpm, xbm, gif, jpg, or png) located in
 688 `widget-glyph-directory'.
 689
 690 Optional arguments DOWN and INACTIVE is used instead of IMAGE when the
 691 glyph is pressed or inactive, respectively.
 692
 693 WARNING: If you call this with a glyph, and you want the user to be
 694 able to invoke the glyph, make sure it is unique.  If you use the
 695 same glyph for multiple widgets, invoking any of the glyphs will
 696 cause the last created widget to be invoked.
 697
 698 Instead of an instantiator, you can also use a list of instantiators,
 699 or whatever `make-glyph' will accept.  However, in that case you must
 700 provide the fallback TAG as a part of the instantiator yourself."
 701   (let ((glyph (widget-glyph-find image tag)))
 702     (if glyph
 703         (widget-glyph-insert-glyph widget
 704                                    glyph
 705                                    (widget-glyph-find down tag)
 706                                    (widget-glyph-find inactive tag))
 707       (insert tag))))
 708
 709 (defun widget-glyph-insert-glyph (widget glyph &optional down inactive)
 710   "In WIDGET, insert GLYPH.
 711 If optional arguments DOWN and INACTIVE are given, they should be
 712 glyphs used when the widget is pushed and inactive, respectively."
 713   (when widget
 714     (set-glyph-property glyph 'widget widget)
 715     (when down
 716       (set-glyph-property down 'widget widget))
 717     (when inactive
 718       (set-glyph-property inactive 'widget widget)))
 719   (insert "*")
 720   (let ((ext (make-extent (point) (1- (point))))
 721         (help-echo (and widget (widget-get widget :help-echo))))
 722     (set-extent-property ext 'invisible t)
 723     (set-extent-property ext 'start-open t)
 724     (set-extent-property ext 'end-open t)
 725     (set-extent-end-glyph ext glyph)
 726     (when help-echo
 727       (set-extent-property ext 'balloon-help help-echo)
 728       (set-extent-property ext 'help-echo help-echo)))
 729   (when widget
 730     (widget-put widget :glyph-up glyph)
 731     (when down (widget-put widget :glyph-down down))
 732     (when inactive (widget-put widget :glyph-inactive inactive))))
 733
 734 ;;; Buttons.
 735
 736 (defgroup widget-button nil
 737   "The look of various kinds of buttons."
 738   :group 'widgets)
 739
 740 (defcustom widget-button-prefix ""
 741   "String used as prefix for buttons."
 742   :type 'string
 743   :group 'widget-button)
 744
 745 (defcustom widget-button-suffix ""
 746   "String used as suffix for buttons."
 747   :type 'string
 748   :group 'widget-button)
 749
 750 ;;; Creating Widgets.
 751
 752 ;;;###autoload
 753 (defun widget-create (type &rest args)
 754   "Create widget of TYPE.
 755 The optional ARGS are additional keyword arguments."
 756   (let ((widget (apply 'widget-convert type args)))
 757     (widget-apply widget :create)
 758     widget))
 759
 760 (defun widget-create-child-and-convert (parent type &rest args)
 761   "As part of the widget PARENT, create a child widget TYPE.
 762 The child is converted, using the keyword arguments ARGS."
 763   (let ((widget (apply 'widget-convert type args)))
 764     (widget-put widget :parent parent)
 765     (unless (widget-get widget :indent)
 766       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 767                                     (or (widget-get widget :extra-offset) 0)
 768                                     (widget-get parent :offset))))
 769     (widget-apply widget :create)
 770     widget))
 771
 772 (defun widget-create-child (parent type)
 773   "Create widget of TYPE."
 774   (let ((widget (copy-sequence type)))
 775     (widget-put widget :parent parent)
 776     (unless (widget-get widget :indent)
 777       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 778                                     (or (widget-get widget :extra-offset) 0)
 779                                     (widget-get parent :offset))))
 780     (widget-apply widget :create)
 781     widget))
 782
 783 (defun widget-create-child-value (parent type value)
 784   "Create widget of TYPE with value VALUE."
 785   (let ((widget (copy-sequence type)))
 786     (widget-put widget :value (widget-apply widget :value-to-internal value))
 787     (widget-put widget :parent parent)
 788     (unless (widget-get widget :indent)
 789       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 790                                     (or (widget-get widget :extra-offset) 0)
 791                                     (widget-get parent :offset))))
 792     (widget-apply widget :create)
 793     widget))
 794
 795 ;;;###autoload
 796 (defun widget-delete (widget)
 797   "Delete WIDGET."
 798   (widget-apply widget :delete))
 799
 800 (defun widget-convert (type &rest args)
 801   "Convert TYPE to a widget without inserting it in the buffer.
 802 The optional ARGS are additional keyword arguments."
 803   ;; Don't touch the type.
 804   (let* ((widget (if (symbolp type)
 805                      (list type)
 806                    (copy-sequence type)))
 807          (current widget)
 808          (keys args))
 809     ;; First set the :args keyword.
 810     (while (cdr current)                ;Look in the type.
 811       (let ((next (car (cdr current))))
 812         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 813             (setq current (cdr (cdr current)))
 814           (setcdr current (list :args (cdr current)))
 815           (setq current nil))))
 816     (while args                         ;Look in the args.
 817       (let ((next (nth 0 args)))
 818         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 819             (setq args (nthcdr 2 args))
 820           (widget-put widget :args args)
 821           (setq args nil))))
 822     ;; Then Convert the widget.
 823     (setq type widget)
 824     (while type
 825       (let ((convert-widget (plist-get (cdr type) :convert-widget)))
 826         (if convert-widget
 827             (setq widget (funcall convert-widget widget))))
 828       (setq type (get (car type) 'widget-type)))
 829     ;; Finally set the keyword args.
 830     (while keys
 831       (let ((next (nth 0 keys)))
 832         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 833             (progn
 834               (widget-put widget next (nth 1 keys))
 835               (setq keys (nthcdr 2 keys)))
 836           (setq keys nil))))
 837     ;; Convert the :value to internal format.
 838     (if (widget-member widget :value)
 839         (let ((value (widget-get widget :value)))
 840           (widget-put widget
 841                       :value (widget-apply widget :value-to-internal value))))
 842     ;; Return the newly create widget.
 843     widget))
 844
 845 (defun widget-insert (&rest args)
 846   "Call `insert' with ARGS and make the text read only."
 847   (let ((inhibit-read-only t)
 848         before-change-functions
 849         after-change-functions
 850         (from (point)))
 851     (apply 'insert args)))
 852
 853 (defun widget-convert-text (type from to
 854                                  &optional button-from button-to
 855                                  &rest args)
 856   "Return a widget of type TYPE with endpoint FROM TO.
 857 Optional ARGS are extra keyword arguments for TYPE.
 858 and TO will be used as the widgets end points. If optional arguments
 859 BUTTON-FROM and BUTTON-TO are given, these will be used as the widgets
 860 button end points.
 861 Optional ARGS are extra keyword arguments for TYPE."
 862   (let ((widget (apply 'widget-convert type :delete 'widget-leave-text args))
 863         (from (copy-marker from))
 864         (to (copy-marker to)))
 865     (set-marker-insertion-type from t)
 866     (set-marker-insertion-type to nil)
 867     (widget-put widget :from from)
 868     (widget-put widget :to to)
 869     (when button-from
 870       (widget-specify-button widget button-from button-to))
 871     widget))
 872
 873 (defun widget-convert-button (type from to &rest args)
 874   "Return a widget of type TYPE with endpoint FROM TO.
 875 Optional ARGS are extra keyword arguments for TYPE.
 876 No text will be inserted to the buffer, instead the text between FROM
 877 and TO will be used as the widgets end points, as well as the widgets
 878 button end points."
 879   (apply 'widget-convert-text type from to from to args))
 880
 881 (defun widget-leave-text (widget)
 882   "Remove markers and overlays from WIDGET and its children."
 883   (let ((from (widget-get widget :from))
 884         (to (widget-get widget :to))
 885         (button (widget-get widget :button-overlay))
 886         (sample (widget-get widget :sample-overlay))
 887         (doc (widget-get widget :doc-overlay))
 888         (field (widget-get widget :field-overlay))
 889         (children (widget-get widget :children)))
 890     (set-marker from nil)
 891     (set-marker to nil)
 892     (when button
 893       (delete-overlay button))
 894     (when sample
 895       (delete-overlay sample))
 896     (when doc
 897       (delete-overlay doc))
 898     (when field
 899       (delete-overlay field))
 900     (mapcar 'widget-leave-text children)))
 901
 902 ;;; Keymap and Commands.
 903
 904 (defvar widget-keymap nil
 905   "Keymap containing useful binding for buffers containing widgets.
 906 Recommended as a parent keymap for modes using widgets.")
 907
 908 (unless widget-keymap
 909   (setq widget-keymap (make-sparse-keymap))
 910   (define-key widget-keymap "\t" 'widget-forward)
 911   (define-key widget-keymap [(shift tab)] 'widget-backward)
 912   (define-key widget-keymap [backtab] 'widget-backward)
 913   (if (string-match "XEmacs" emacs-version)
 914       (progn
 915         ;;Glyph support.
 916         (define-key widget-keymap [button1] 'widget-button1-click)
 917         (define-key widget-keymap [button2] 'widget-button-click))
 918     (define-key widget-keymap [down-mouse-2] 'widget-button-click))
 919   (define-key widget-keymap "\C-m" 'widget-button-press))
 920
 921 (defvar widget-global-map global-map
 922   "Keymap used for events the widget does not handle themselves.")
 923 (make-variable-buffer-local 'widget-global-map)
 924
 925 (defvar widget-field-keymap nil
 926   "Keymap used inside an editable field.")
 927
 928 (unless widget-field-keymap
 929   (setq widget-field-keymap (copy-keymap widget-keymap))
 930   (unless (string-match "XEmacs" (emacs-version))
 931     (define-key widget-field-keymap [menu-bar] 'nil))
 932   (define-key widget-field-keymap "\C-k" 'widget-kill-line)
 933   (define-key widget-field-keymap "\M-\t" 'widget-complete)
 934   (define-key widget-field-keymap "\C-m" 'widget-field-activate)
 935   (define-key widget-field-keymap "\C-a" 'widget-beginning-of-line)
 936   (define-key widget-field-keymap "\C-e" 'widget-end-of-line)
 937   (set-keymap-parent widget-field-keymap global-map))
 938
 939 (defvar widget-text-keymap nil
 940   "Keymap used inside a text field.")
 941
 942 (unless widget-text-keymap
 943   (setq widget-text-keymap (copy-keymap widget-keymap))
 944   (unless (string-match "XEmacs" (emacs-version))
 945     (define-key widget-text-keymap [menu-bar] 'nil))
 946   (define-key widget-text-keymap "\C-a" 'widget-beginning-of-line)
 947   (define-key widget-text-keymap "\C-e" 'widget-end-of-line)
 948   (set-keymap-parent widget-text-keymap global-map))
 949
 950 (defun widget-field-activate (pos &optional event)
 951   "Invoke the ediable field at point."
 952   (interactive "@d")
 953   (let ((field (get-char-property pos 'field)))
 954     (if field
 955         (widget-apply-action field event)
 956       (call-interactively
 957        (lookup-key widget-global-map (this-command-keys))))))
 958
 959 (defface widget-button-pressed-face
 960   '((((class color))
 961      (:foreground "red"))
 962     (t
 963      (:bold t :underline t)))
 964   "Face used for pressed buttons."
 965   :group 'widget-faces)
 966
 967 (defun widget-button-click (event)
 968   "Invoke button below mouse pointer."
 969   (interactive "@e")
 970   (cond ((and (fboundp 'event-glyph)
 971               (event-glyph event))
 972          (widget-glyph-click event))
 973         ((widget-event-point event)
 974          (let* ((pos (widget-event-point event))
 975                 (button (get-char-property pos 'button)))
 976            (if button
 977                (let* ((overlay (widget-get button :button-overlay))
 978                       (face (overlay-get overlay 'face))
 979                       (mouse-face (overlay-get overlay 'mouse-face)))
 980                  (unwind-protect
 981                      (let ((track-mouse t))
 982                        (overlay-put overlay
 983                                     'face 'widget-button-pressed-face)
 984                        (overlay-put overlay
 985                                     'mouse-face 'widget-button-pressed-face)
 986                        (unless (widget-apply button :mouse-down-action event)
 987                          (while (not (button-release-event-p event))
 988                            (setq event (widget-read-event)
 989                                  pos (widget-event-point event))
 990                            (if (and pos
 991                                     (eq (get-char-property pos 'button)
 992                                         button))
 993                                (progn
 994                                  (overlay-put overlay
 995                                               'face
 996                                               'widget-button-pressed-face)
 997                                  (overlay-put overlay
 998                                               'mouse-face
 999                                               'widget-button-pressed-face))
1000                              (overlay-put overlay 'face face)
1001                              (overlay-put overlay 'mouse-face mouse-face))))
1002                        (when (and pos
1003                                   (eq (get-char-property pos 'button) button))
1004                          (widget-apply-action button event)))
1005                    (overlay-put overlay 'face face)
1006                    (overlay-put overlay 'mouse-face mouse-face)))
1007              (let ((up t)
1008                    command)
1009                ;; Find the global command to run, and check whether it
1010                ;; is bound to an up event.
1011                (cond ((setq command     ;down event
1012                             (lookup-key widget-global-map [ button2 ]))
1013                       (setq up nil))
1014                      ((setq command     ;down event
1015                             (lookup-key widget-global-map [ down-mouse-2 ]))
1016                       (setq up nil))
1017                      ((setq command     ;up event
1018                             (lookup-key widget-global-map [ button2up ])))
1019                      ((setq command     ;up event
1020                             (lookup-key widget-global-map [ mouse-2]))))
1021                (when up
1022                  ;; Don't execute up events twice.
1023                  (while (not (button-release-event-p event))
1024                    (setq event (widget-read-event))))
1025                (when command
1026                  (call-interactively command))))))
1027         (t
1028          (message "You clicked somewhere weird."))))
1029
1030 (defun widget-button1-click (event)
1031   "Invoke glyph below mouse pointer."
1032   (interactive "@e")
1033   (if (and (fboundp 'event-glyph)
1034            (event-glyph event))
1035       (widget-glyph-click event)
1036     (call-interactively (lookup-key widget-global-map (this-command-keys)))))
1037
1038 (defun widget-glyph-click (event)
1039   "Handle click on a glyph."
1040   (let* ((glyph (event-glyph event))
1041          (widget (glyph-property glyph 'widget))
1042          (extent (event-glyph-extent event))
1043          (down-glyph (or (and widget (widget-get widget :glyph-down)) glyph))
1044          (up-glyph (or (and widget (widget-get widget :glyph-up)) glyph))
1045          (last event))
1046     ;; Wait for the release.
1047     (while (not (button-release-event-p last))
1048       (if (eq extent (event-glyph-extent last))
1049           (set-extent-property extent 'end-glyph down-glyph)
1050         (set-extent-property extent 'end-glyph up-glyph))
1051       (setq last (next-event event)))
1052     ;; Release glyph.
1053     (when down-glyph
1054       (set-extent-property extent 'end-glyph up-glyph))
1055     ;; Apply widget action.
1056     (when (eq extent (event-glyph-extent last))
1057       (let ((widget (glyph-property (event-glyph event) 'widget)))
1058         (cond ((null widget)
1059                (message "You clicked on a glyph."))
1060               ((not (widget-apply widget :active))
1061                (message "This glyph is inactive."))
1062               (t
1063                (widget-apply-action widget event)))))))
1064
1065 (defun widget-button-press (pos &optional event)
1066   "Invoke button at POS."
1067   (interactive "@d")
1068   (let ((button (get-char-property pos 'button)))
1069     (if button
1070         (widget-apply-action button event)
1071       (let ((command (lookup-key widget-global-map (this-command-keys))))
1072         (when (commandp command)
1073           (call-interactively command))))))
1074
1075 (defun widget-tabable-at (&optional pos)
1076   "Return the tabable widget at POS, or nil.
1077 POS defaults to the value of (point)."
1078   (unless pos
1079     (setq pos (point)))
1080   (let ((widget (or (get-char-property (point) 'button)
1081                     (get-char-property (point) 'field))))
1082     (if widget
1083         (let ((order (widget-get widget :tab-order)))
1084           (if order
1085               (if (>= order 0)
1086                   widget
1087                 nil)
1088             widget))
1089       nil)))
1090
1091 (defcustom widget-use-overlay-change (string-match "XEmacs" emacs-version)
1092   "If non-nil, use overlay change functions to tab around in the buffer.
1093 This is much faster, but doesn't work reliably on Emacs 19.34."
1094   :type 'boolean
1095   :group 'widgets)
1096
1097 (defun widget-move (arg)
1098   "Move point to the ARG next field or button.
1099 ARG may be negative to move backward."
1100   (or (bobp) (> arg 0) (backward-char))
1101   (let ((pos (point))
1102         (number arg)
1103         (old (widget-tabable-at))
1104         new)
1105     ;; Forward.
1106     (while (> arg 0)
1107       (cond ((eobp)
1108              (goto-char (point-min)))
1109             (widget-use-overlay-change
1110              (goto-char (next-overlay-change (point))))
1111             (t
1112              (forward-char 1)))
1113       (and (eq pos (point))
1114            (eq arg number)
1115            (error "No buttons or fields found"))
1116       (let ((new (widget-tabable-at)))
1117         (when new
1118           (unless (eq new old)
1119             (setq arg (1- arg))
1120             (setq old new)))))
1121     ;; Backward.
1122     (while (< arg 0)
1123       (cond ((bobp)
1124              (goto-char (point-max)))
1125             (widget-use-overlay-change
1126              (goto-char (previous-overlay-change (point))))
1127             (t
1128              (backward-char 1)))
1129       (and (eq pos (point))
1130            (eq arg number)
1131            (error "No buttons or fields found"))
1132       (let ((new (widget-tabable-at)))
1133         (when new
1134           (unless (eq new old)
1135             (setq arg (1+ arg))))))
1136     (let ((new (widget-tabable-at)))
1137       (while (eq (widget-tabable-at) new)
1138         (backward-char)))
1139     (forward-char))
1140   (widget-echo-help (point))
1141   (run-hooks 'widget-move-hook))
1142
1143 (defun widget-forward (arg)
1144   "Move point to the next field or button.
1145 With optional ARG, move across that many fields."
1146   (interactive "p")
1147   (run-hooks 'widget-forward-hook)
1148   (widget-move arg))
1149
1150 (defun widget-backward (arg)
1151   "Move point to the previous field or button.
1152 With optional ARG, move across that many fields."
1153   (interactive "p")
1154   (run-hooks 'widget-backward-hook)
1155   (widget-move (- arg)))
1156
1157 (defun widget-beginning-of-line ()
1158   "Go to beginning of field or beginning of line, whichever is first."
1159   (interactive)
1160   (let* ((field (widget-field-find (point)))
1161          (start (and field (widget-field-start field))))
1162     (if (and start (not (eq start (point))))
1163         (goto-char start)
1164       (call-interactively 'beginning-of-line)))
1165   ;; XEmacs: preserve the region
1166   (setq zmacs-region-stays t))
1167
1168 (defun widget-end-of-line ()
1169   "Go to end of field or end of line, whichever is first."
1170   (interactive)
1171   (let* ((field (widget-field-find (point)))
1172          (end (and field (widget-field-end field))))
1173     (if (and end (not (eq end (point))))
1174         (goto-char end)
1175       (call-interactively 'end-of-line)))
1176   ;; XEmacs: preserve the region
1177   (setq zmacs-region-stays t))
1178
1179 (defun widget-kill-line ()
1180   "Kill to end of field or end of line, whichever is first."
1181   (interactive)
1182   (let* ((field (widget-field-find (point)))
1183          (newline (save-excursion (forward-line 1) (point)))
1184          (end (and field (widget-field-end field))))
1185     (if (and field (> newline end))
1186         (kill-region (point) end)
1187       (call-interactively 'kill-line))))
1188
1189 (defcustom widget-complete-field (lookup-key global-map "\M-\t")
1190   "Default function to call for completion inside fields."
1191   :options '(ispell-complete-word complete-tag lisp-complete-symbol)
1192   :type 'function
1193   :group 'widgets)
1194
1195 (defun widget-complete ()
1196   "Complete content of editable field from point.
1197 When not inside a field, move to the previous button or field."
1198   (interactive)
1199   (let ((field (widget-field-find (point))))
1200     (if field
1201         (widget-apply field :complete)
1202       (error "Not in an editable field"))))
1203
1204 ;;; Setting up the buffer.
1205
1206 (defvar widget-field-new nil)
1207 ;; List of all newly created editable fields in the buffer.
1208 (make-variable-buffer-local 'widget-field-new)
1209
1210 (defvar widget-field-list nil)
1211 ;; List of all editable fields in the buffer.
1212 (make-variable-buffer-local 'widget-field-list)
1213
1214 (defun widget-setup ()
1215   "Setup current buffer so editing string widgets works."
1216   (let ((inhibit-read-only t)
1217         (after-change-functions nil)
1218         before-change-functions
1219         field)
1220     (while widget-field-new
1221       (setq field (car widget-field-new)
1222             widget-field-new (cdr widget-field-new)
1223             widget-field-list (cons field widget-field-list))
1224       (let ((from (car (widget-get field :field-overlay)))
1225             (to (cdr (widget-get field :field-overlay))))
1226         (widget-specify-field field
1227                               (marker-position from) (marker-position to))
1228         (set-marker from nil)
1229         (set-marker to nil))))
1230   (widget-clear-undo)
1231   (widget-add-change))
1232
1233 (defvar widget-field-last nil)
1234 ;; Last field containing point.
1235 (make-variable-buffer-local 'widget-field-last)
1236
1237 (defvar widget-field-was nil)
1238 ;; The widget data before the change.
1239 (make-variable-buffer-local 'widget-field-was)
1240
1241 (defun widget-field-buffer (widget)
1242   "Return the start of WIDGET's editing field."
1243   (let ((overlay (widget-get widget :field-overlay)))
1244     (and overlay (overlay-buffer overlay))))
1245
1246 (defun widget-field-start (widget)
1247   "Return the start of WIDGET's editing field."
1248   (let ((overlay (widget-get widget :field-overlay)))
1249     (and overlay (overlay-start overlay))))
1250
1251 (defun widget-field-end (widget)
1252   "Return the end of WIDGET's editing field."
1253   (let ((overlay (widget-get widget :field-overlay)))
1254     ;; Don't subtract one if local-map works at the end of the overlay.
1255     (and overlay (if (or widget-field-add-space
1256                          (null (widget-get widget :size)))
1257                      (1- (overlay-end overlay))
1258                    (overlay-end overlay)))))
1259
1260 (defun widget-field-find (pos)
1261   "Return the field at POS.
1262 Unlike (get-char-property POS 'field) this, works with empty fields too."
1263   (let ((fields widget-field-list)
1264         field found)
1265     (while fields
1266       (setq field (car fields)
1267             fields (cdr fields))
1268       (let ((start (widget-field-start field))
1269             (end (widget-field-end field)))
1270         (when (and (<= start pos) (<= pos end))
1271           (when found
1272             (debug "Overlapping fields"))
1273           (setq found field))))
1274     found))
1275
1276 (defun widget-before-change (from to)
1277   ;; This is how, for example, a variable changes its state to `modified'.
1278   ;; when it is being edited.
1279   (unless inhibit-read-only
1280     (let ((from-field (widget-field-find from))
1281           (to-field (widget-field-find to)))
1282       (cond ((not (eq from-field to-field))
1283              (add-hook 'post-command-hook 'widget-add-change nil t)
1284              (error "Change should be restricted to a single field"))
1285             ((null from-field)
1286              (add-hook 'post-command-hook 'widget-add-change nil t)
1287              (error "Attempt to change text outside editable field"))
1288             (widget-field-use-before-change
1289              (condition-case nil
1290                  (widget-apply from-field :notify from-field)
1291                (error (debug "Before Change"))))))))
1292
1293 (defun widget-add-change ()
1294   (make-local-hook 'post-command-hook)
1295   (remove-hook 'post-command-hook 'widget-add-change t)
1296   (make-local-hook 'before-change-functions)
1297   (add-hook 'before-change-functions 'widget-before-change nil t)
1298   (make-local-hook 'after-change-functions)
1299   (add-hook 'after-change-functions 'widget-after-change nil t))
1300
1301 (defun widget-after-change (from to old)
1302   ;; Adjust field size and text properties.
1303   (condition-case nil
1304       (let ((field (widget-field-find from))
1305             (other (widget-field-find to)))
1306         (when field
1307           (unless (eq field other)
1308             (debug "Change in different fields"))
1309           (let ((size (widget-get field :size))
1310                 (secret (widget-get field :secret)))
1311             (when size
1312               (let ((begin (widget-field-start field))
1313                     (end (widget-field-end field)))
1314                 (cond ((< (- end begin) size)
1315                        ;; Field too small.
1316                        (save-excursion
1317                          (goto-char end)
1318                          (insert-char ?\  (- (+ begin size) end))))
1319                       ((> (- end begin) size)
1320                        ;; Field too large and
1321                        (if (or (< (point) (+ begin size))
1322                                (> (point) end))
1323                            ;; Point is outside extra space.
1324                            (setq begin (+ begin size))
1325                          ;; Point is within the extra space.
1326                          (setq begin (point)))
1327                        (save-excursion
1328                          (goto-char end)
1329                          (while (and (eq (preceding-char) ?\ )
1330                                      (> (point) begin))
1331                            (delete-backward-char 1)))))))
1332             (when secret
1333               (let ((begin (widget-field-start field))
1334                     (end (widget-field-end field)))
1335                 (when size
1336                   (while (and (> end begin)
1337                               (eq (char-after (1- end)) ?\ ))
1338                     (setq end (1- end))))
1339                 (while (< begin end)
1340                   (let ((old (char-after begin)))
1341                     (unless (eq old secret)
1342                       (subst-char-in-region begin (1+ begin) old secret)
1343                       (put-text-property begin (1+ begin) 'secret old))
1344                     (setq begin (1+ begin)))))))
1345           (widget-apply field :notify field)))
1346     (error (debug "After Change"))))
1347
1348 ;;; Widget Functions
1349 ;;
1350 ;; These functions are used in the definition of multiple widgets.
1351
1352 (defun widget-parent-action (widget &optional event)
1353   "Tell :parent of WIDGET to handle the :action.
1354 Optional EVENT is the event that triggered the action."
1355   (widget-apply (widget-get widget :parent) :action event))
1356
1357 (defun widget-children-value-delete (widget)
1358   "Delete all :children and :buttons in WIDGET."
1359   (mapcar 'widget-delete (widget-get widget :children))
1360   (widget-put widget :children nil)
1361   (mapcar 'widget-delete (widget-get widget :buttons))
1362   (widget-put widget :buttons nil))
1363
1364 (defun widget-children-validate (widget)
1365   "All the :children must be valid."
1366   (let ((children (widget-get widget :children))
1367         child found)
1368     (while (and children (not found))
1369       (setq child (car children)
1370             children (cdr children)
1371             found (widget-apply child :validate)))
1372     found))
1373
1374 (defun widget-types-convert-widget (widget)
1375   "Convert :args as widget types in WIDGET."
1376   (widget-put widget :args (mapcar 'widget-convert (widget-get widget :args)))
1377   widget)
1378
1379 (defun widget-value-convert-widget (widget)
1380   "Initialize :value from :args in WIDGET."
1381   (let ((args (widget-get widget :args)))
1382     (when args
1383       (widget-put widget :value (car args))
1384       ;; Don't convert :value here, as this is done in `widget-convert'.
1385       ;; (widget-put widget :value (widget-apply widget
1386       ;;                                      :value-to-internal (car args)))
1387       (widget-put widget :args nil)))
1388   widget)
1389
1390 (defun widget-value-value-get (widget)
1391   "Return the :value property of WIDGET."
1392   (widget-get widget :value))
1393
1394 ;;; The `default' Widget.
1395
1396 (define-widget 'default nil
1397   "Basic widget other widgets are derived from."
1398   :value-to-internal (lambda (widget value) value)
1399   :value-to-external (lambda (widget value) value)
1400   :button-prefix 'widget-button-prefix
1401   :button-suffix 'widget-button-suffix
1402   :complete 'widget-default-complete
1403   :create 'widget-default-create
1404   :indent nil
1405   :offset 0
1406   :format-handler 'widget-default-format-handler
1407   :button-face-get 'widget-default-button-face-get
1408   :sample-face-get 'widget-default-sample-face-get
1409   :delete 'widget-default-delete
1410   :value-set 'widget-default-value-set
1411   :value-inline 'widget-default-value-inline
1412   :menu-tag-get 'widget-default-menu-tag-get
1413   :validate (lambda (widget) nil)
1414   :active 'widget-default-active
1415   :activate 'widget-specify-active
1416   :deactivate 'widget-default-deactivate
1417   :mouse-down-action (lambda (widget event) nil)
1418   :action 'widget-default-action
1419   :notify 'widget-default-notify
1420   :prompt-value 'widget-default-prompt-value)
1421
1422 (defun widget-default-complete (widget)
1423   "Call the value of the :complete-function property of WIDGET.
1424 If that does not exists, call the value of `widget-complete-field'."
1425   (let ((fun (widget-get widget :complete-function)))
1426     (call-interactively (or fun widget-complete-field))))
1427
1428 (defun widget-default-create (widget)
1429   "Create WIDGET at point in the current buffer."
1430   (widget-specify-insert
1431    (let ((from (point))
1432          button-begin button-end
1433          sample-begin sample-end
1434          doc-begin doc-end
1435          value-pos)
1436      (insert (widget-get widget :format))
1437      (goto-char from)
1438      ;; Parse escapes in format.
1439      (while (re-search-forward "%\\(.\\)" nil t)
1440        (let ((escape (aref (match-string 1) 0)))
1441          (replace-match "" t t)
1442          (cond ((eq escape ?%)
1443                 (insert "%"))
1444                ((eq escape ?\[)
1445                 (setq button-begin (point))
1446                 (insert (widget-get-indirect widget :button-prefix)))
1447                ((eq escape ?\])
1448                 (insert (widget-get-indirect widget :button-suffix))
1449                 (setq button-end (point)))
1450                ((eq escape ?\{)
1451                 (setq sample-begin (point)))
1452                ((eq escape ?\})
1453                 (setq sample-end (point)))
1454                ((eq escape ?n)
1455                 (when (widget-get widget :indent)
1456                   (insert "\n")
1457                   (insert-char ?  (widget-get widget :indent))))
1458                ((eq escape ?t)
1459                 (let ((glyph (widget-get widget :tag-glyph))
1460                       (tag (widget-get widget :tag)))
1461                   (cond (glyph
1462                          (widget-glyph-insert widget (or tag "image") glyph))
1463                         (tag
1464                          (insert tag))
1465                         (t
1466                          (let ((standard-output (current-buffer)))
1467                            (princ (widget-get widget :value)))))))
1468                ((eq escape ?d)
1469                 (let ((doc (widget-get widget :doc)))
1470                   (when doc
1471                     (setq doc-begin (point))
1472                     (insert doc)
1473                     (while (eq (preceding-char) ?\n)
1474                       (delete-backward-char 1))
1475                     (insert "\n")
1476                     (setq doc-end (point)))))
1477                ((eq escape ?v)
1478                 (if (and button-begin (not button-end))
1479                     (widget-apply widget :value-create)
1480                   (setq value-pos (point))))
1481                (t
1482                 (widget-apply widget :format-handler escape)))))
1483      ;; Specify button, sample, and doc, and insert value.
1484      (and button-begin button-end
1485           (widget-specify-button widget button-begin button-end))
1486      (and sample-begin sample-end
1487           (widget-specify-sample widget sample-begin sample-end))
1488      (and doc-begin doc-end
1489           (widget-specify-doc widget doc-begin doc-end))
1490      (when value-pos
1491        (goto-char value-pos)
1492        (widget-apply widget :value-create)))
1493    (let ((from (copy-marker (point-min)))
1494          (to (copy-marker (point-max))))
1495      (set-marker-insertion-type from t)
1496      (set-marker-insertion-type to nil)
1497      (widget-put widget :from from)
1498      (widget-put widget :to to)))
1499   (widget-clear-undo))
1500
1501 (defun widget-default-format-handler (widget escape)
1502   ;; We recognize the %h escape by default.
1503   (let* ((buttons (widget-get widget :buttons)))
1504     (cond ((eq escape ?h)
1505            (let* ((doc-property (widget-get widget :documentation-property))
1506                   (doc-try (cond ((widget-get widget :doc))
1507                                  ((symbolp doc-property)
1508                                   (documentation-property
1509                                    (widget-get widget :value)
1510                                    doc-property))
1511                                  (t
1512                                   (funcall doc-property
1513                                            (widget-get widget :value)))))
1514                   (doc-text (and (stringp doc-try)
1515                                  (> (length doc-try) 1)
1516                                  doc-try))
1517                   (doc-indent (widget-get widget :documentation-indent)))
1518              (when doc-text
1519                (and (eq (preceding-char) ?\n)
1520                     (widget-get widget :indent)
1521                     (insert-char ?  (widget-get widget :indent)))
1522                ;; The `*' in the beginning is redundant.
1523                (when (eq (aref doc-text  0) ?*)
1524                  (setq doc-text (substring doc-text 1)))
1525                ;; Get rid of trailing newlines.
1526                (when (string-match "\n+\\'" doc-text)
1527                  (setq doc-text (substring doc-text 0 (match-beginning 0))))
1528                (push (widget-create-child-and-convert
1529                       widget 'documentation-string
1530                       :indent (cond ((numberp doc-indent )
1531                                      doc-indent)
1532                                     ((null doc-indent)
1533                                      nil)
1534                                     (t 0))
1535                       doc-text)
1536                      buttons))))
1537           (t
1538            (error "Unknown escape `%c'" escape)))
1539     (widget-put widget :buttons buttons)))
1540
1541 (defun widget-default-button-face-get (widget)
1542   ;; Use :button-face or widget-button-face
1543   (or (widget-get widget :button-face)
1544       (let ((parent (widget-get widget :parent)))
1545         (if parent
1546             (widget-apply parent :button-face-get)
1547           widget-button-face))))
1548
1549 (defun widget-default-sample-face-get (widget)
1550   ;; Use :sample-face.
1551   (widget-get widget :sample-face))
1552
1553 (defun widget-default-delete (widget)
1554   ;; Remove widget from the buffer.
1555   (let ((from (widget-get widget :from))
1556         (to (widget-get widget :to))
1557         (inactive-overlay (widget-get widget :inactive))
1558         (button-overlay (widget-get widget :button-overlay))
1559         (sample-overlay (widget-get widget :sample-overlay))
1560         (doc-overlay (widget-get widget :doc-overlay))
1561         before-change-functions
1562         after-change-functions
1563         (inhibit-read-only t))
1564     (widget-apply widget :value-delete)
1565     (when inactive-overlay
1566       (delete-overlay inactive-overlay))
1567     (when button-overlay
1568       (delete-overlay button-overlay))
1569     (when sample-overlay
1570       (delete-overlay sample-overlay))
1571     (when doc-overlay
1572       (delete-overlay doc-overlay))
1573     (when (< from to)
1574       ;; Kludge: this doesn't need to be true for empty formats.
1575       (delete-region from to))
1576     (set-marker from nil)
1577     (set-marker to nil))
1578   (widget-clear-undo))
1579
1580 (defun widget-default-value-set (widget value)
1581   ;; Recreate widget with new value.
1582   (let* ((old-pos (point))
1583          (from (copy-marker (widget-get widget :from)))
1584          (to (copy-marker (widget-get widget :to)))
1585          (offset (if (and (<= from old-pos) (<= old-pos to))
1586                      (if (>= old-pos (1- to))
1587                          (- old-pos to 1)
1588                        (- old-pos from)))))
1589     ;;??? Bug: this ought to insert the new value before deleting the old one,
1590     ;; so that markers on either side of the value automatically
1591     ;; stay on the same side.  -- rms.
1592     (save-excursion
1593       (goto-char (widget-get widget :from))
1594       (widget-apply widget :delete)
1595       (widget-put widget :value value)
1596       (widget-apply widget :create))
1597     (if offset
1598         (if (< offset 0)
1599             (goto-char (+ (widget-get widget :to) offset 1))
1600           (goto-char (min (+ from offset) (1- (widget-get widget :to))))))))
1601
1602 (defun widget-default-value-inline (widget)
1603   ;; Wrap value in a list unless it is inline.
1604   (if (widget-get widget :inline)
1605       (widget-value widget)
1606     (list (widget-value widget))))
1607
1608 (defun widget-default-menu-tag-get (widget)
1609   ;; Use tag or value for menus.
1610   (or (widget-get widget :menu-tag)
1611       (widget-get widget :tag)
1612       (widget-princ-to-string (widget-get widget :value))))
1613
1614 (defun widget-default-active (widget)
1615   "Return t iff this widget active (user modifiable)."
1616   (and (not (widget-get widget :inactive))
1617        (let ((parent (widget-get widget :parent)))
1618          (or (null parent)
1619              (widget-apply parent :active)))))
1620
1621 (defun widget-default-deactivate (widget)
1622   "Make WIDGET inactive for user modifications."
1623   (widget-specify-inactive widget
1624                            (widget-get widget :from)
1625                            (widget-get widget :to)))
1626
1627 (defun widget-default-action (widget &optional event)
1628   ;; Notify the parent when a widget change
1629   (let ((parent (widget-get widget :parent)))
1630     (when parent
1631       (widget-apply parent :notify widget event))))
1632
1633 (defun widget-default-notify (widget child &optional event)
1634   ;; Pass notification to parent.
1635   (widget-default-action widget event))
1636
1637 (defun widget-default-prompt-value (widget prompt value unbound)
1638   ;; Read an arbitrary value.  Stolen from `set-variable'.
1639 ;;  (let ((initial (if unbound
1640 ;;                   nil
1641 ;;                 ;; It would be nice if we could do a `(cons val 1)' here.
1642 ;;                 (prin1-to-string (custom-quote value))))))
1643   (eval-minibuffer prompt ))
1644
1645 ;;; The `item' Widget.
1646
1647 (define-widget 'item 'default
1648   "Constant items for inclusion in other widgets."
1649   :convert-widget 'widget-value-convert-widget
1650   :value-create 'widget-item-value-create
1651   :value-delete 'ignore
1652   :value-get 'widget-value-value-get
1653   :match 'widget-item-match
1654   :match-inline 'widget-item-match-inline
1655   :action 'widget-item-action
1656   :format "%t\n")
1657
1658 (defun widget-item-value-create (widget)
1659   ;; Insert the printed representation of the value.
1660   (let ((standard-output (current-buffer)))
1661     (princ (widget-get widget :value))))
1662
1663 (defun widget-item-match (widget value)
1664   ;; Match if the value is the same.
1665   (equal (widget-get widget :value) value))
1666
1667 (defun widget-item-match-inline (widget values)
1668   ;; Match if the value is the same.
1669   (let ((value (widget-get widget :value)))
1670     (and (listp value)
1671          (<= (length value) (length values))
1672          (let ((head (widget-sublist values 0 (length value))))
1673            (and (equal head value)
1674                 (cons head (widget-sublist values (length value))))))))
1675
1676 (defun widget-sublist (list start &optional end)
1677   "Return the sublist of LIST from START to END.
1678 If END is omitted, it defaults to the length of LIST."
1679   (if (> start 0) (setq list (nthcdr start list)))
1680   (if end
1681       (if (<= end start)
1682           nil
1683         (setq list (copy-sequence list))
1684         (setcdr (nthcdr (- end start 1) list) nil)
1685         list)
1686     (copy-sequence list)))
1687
1688 (defun widget-item-action (widget &optional event)
1689   ;; Just notify itself.
1690   (widget-apply widget :notify widget event))
1691
1692 ;;; The `push-button' Widget.
1693
1694 (defcustom widget-push-button-gui t
1695   "If non nil, use GUI push buttons when available."
1696   :group 'widgets
1697   :type 'boolean)
1698
1699 ;; Cache already created GUI objects.
1700 (defvar widget-push-button-cache nil)
1701
1702 (defcustom widget-push-button-prefix "["
1703   "String used as prefix for buttons."
1704   :type 'string
1705   :group 'widget-button)
1706
1707 (defcustom widget-push-button-suffix "]"
1708   "String used as suffix for buttons."
1709   :type 'string
1710   :group 'widget-button)
1711
1712 (define-widget 'push-button 'item
1713   "A pushable button."
1714   :button-prefix ""
1715   :button-suffix ""
1716   :value-create 'widget-push-button-value-create
1717   :format "%[%v%]")
1718
1719 (defun widget-push-button-value-create (widget)
1720   ;; Insert text representing the `on' and `off' states.
1721   (let* ((tag (or (widget-get widget :tag)
1722                   (widget-get widget :value)))
1723          (tag-glyph (widget-get widget :tag-glyph))
1724          (text (concat widget-push-button-prefix
1725                        tag widget-push-button-suffix))
1726          (gui (cdr (assoc tag widget-push-button-cache))))
1727     (cond (tag-glyph
1728            (widget-glyph-insert widget text tag-glyph))
1729           ((and (fboundp 'make-gui-button)
1730              (fboundp 'make-glyph)
1731              widget-push-button-gui
1732              (fboundp 'device-on-window-system-p)
1733              (device-on-window-system-p)
1734              (string-match "XEmacs" emacs-version))
1735            (unless gui
1736              (setq gui (make-gui-button tag 'widget-gui-action widget))
1737              (push (cons tag gui) widget-push-button-cache))
1738            (widget-glyph-insert-glyph widget
1739                                       (make-glyph
1740                                        (list (nth 0 (aref gui 1))
1741                                              (vector 'string ':data text)))
1742                                       (make-glyph
1743                                        (list (nth 1 (aref gui 1))
1744                                              (vector 'string ':data text)))
1745                                       (make-glyph
1746                                        (list (nth 2 (aref gui 1))
1747                                              (vector 'string ':data text)))))
1748           (t
1749            (insert text)))))
1750
1751 (defun widget-gui-action (widget)
1752   "Apply :action for WIDGET."
1753   (widget-apply-action widget (this-command-keys)))
1754
1755 ;;; The `link' Widget.
1756
1757 (defcustom widget-link-prefix "["
1758   "String used as prefix for links."
1759   :type 'string
1760   :group 'widget-button)
1761
1762 (defcustom widget-link-suffix "]"
1763   "String used as suffix for links."
1764   :type 'string
1765   :group 'widget-button)
1766
1767 (define-widget 'link 'item
1768   "An embedded link."
1769   :button-prefix 'widget-link-prefix
1770   :button-suffix 'widget-link-suffix
1771   :help-echo "Follow the link."
1772   :format "%[%t%]")
1773
1774 ;;; The `info-link' Widget.
1775
1776 (define-widget 'info-link 'link
1777   "A link to an info file."
1778   :action 'widget-info-link-action)
1779
1780 (defun widget-info-link-action (widget &optional event)
1781   "Open the info node specified by WIDGET."
1782   (Info-goto-node (widget-value widget)))
1783
1784 ;;; The `url-link' Widget.
1785
1786 (define-widget 'url-link 'link
1787   "A link to an www page."
1788   :action 'widget-url-link-action)
1789
1790 (defun widget-url-link-action (widget &optional event)
1791   "Open the url specified by WIDGET."
1792   (require 'browse-url)
1793   (funcall browse-url-browser-function (widget-value widget)))
1794
1795 ;;; The `file-link' Widget.
1796
1797 (define-widget 'file-link 'link
1798   "A link to a file."
1799   :action 'widget-file-link-action)
1800
1801 (defun widget-file-link-action (widget &optional event)
1802   "Find the file specified by WIDGET."
1803   (find-file (widget-value widget)))
1804
1805 ;;; The `emacs-library-link' Widget.
1806
1807 (define-widget 'emacs-library-link 'link
1808   "A link to an Emacs Lisp library file."
1809   :action 'widget-emacs-library-link-action)
1810
1811 (defun widget-emacs-library-link-action (widget &optional event)
1812   "Find the Emacs Library file specified by WIDGET."
1813   (find-file (locate-library (widget-value widget))))
1814
1815 ;;; The `emacs-commentary-link' Widget.
1816
1817 (define-widget 'emacs-commentary-link 'link
1818   "A link to Commentary in an Emacs Lisp library file."
1819   :action 'widget-emacs-commentary-link-action)
1820
1821 (defun widget-emacs-commentary-link-action (widget &optional event)
1822   "Find the Commentary section of the Emacs file specified by WIDGET."
1823   (finder-commentary (widget-value widget)))
1824
1825 ;;; The `editable-field' Widget.
1826
1827 (define-widget 'editable-field 'default
1828   "An editable text field."
1829   :convert-widget 'widget-value-convert-widget
1830   :keymap widget-field-keymap
1831   :format "%v"
1832   :value ""
1833   :prompt-internal 'widget-field-prompt-internal
1834   :prompt-history 'widget-field-history
1835   :prompt-value 'widget-field-prompt-value
1836   :action 'widget-field-action
1837   :validate 'widget-field-validate
1838   :valid-regexp ""
1839   :error "No match"
1840   :value-create 'widget-field-value-create
1841   :value-delete 'widget-field-value-delete
1842   :value-get 'widget-field-value-get
1843   :match 'widget-field-match)
1844
1845 (defvar widget-field-history nil
1846   "History of field minibuffer edits.")
1847
1848 (defun widget-field-prompt-internal (widget prompt initial history)
1849   ;; Read string for WIDGET promptinhg with PROMPT.
1850   ;; INITIAL is the initial input and HISTORY is a symbol containing
1851   ;; the earlier input.
1852   (read-string prompt initial history))
1853
1854 (defun widget-field-prompt-value (widget prompt value unbound)
1855   ;; Prompt for a string.
1856   (let ((initial (if unbound
1857                      nil
1858                    (cons (widget-apply widget :value-to-internal
1859                                        value) 0)))
1860         (history (widget-get widget :prompt-history)))
1861     (let ((answer (widget-apply widget
1862                                 :prompt-internal prompt initial history)))
1863       (widget-apply widget :value-to-external answer))))
1864
1865 (defvar widget-edit-functions nil)
1866
1867 (defun widget-field-action (widget &optional event)
1868   ;; Move to next field.
1869   (widget-forward 1)
1870   (run-hook-with-args 'widget-edit-functions widget))
1871
1872 (defun widget-field-validate (widget)
1873   ;; Valid if the content matches `:valid-regexp'.
1874   (save-excursion
1875     (let ((value (widget-apply widget :value-get))
1876           (regexp (widget-get widget :valid-regexp)))
1877       (if (string-match regexp value)
1878           nil
1879         widget))))
1880
1881 (defun widget-field-value-create (widget)
1882   ;; Create an editable text field.
1883   (let ((size (widget-get widget :size))
1884         (value (widget-get widget :value))
1885         (from (point))
1886         ;; This is changed to a real overlay in `widget-setup'.  We
1887         ;; need the end points to behave differently until
1888         ;; `widget-setup' is called.
1889         (overlay (cons (make-marker) (make-marker))))
1890     (widget-put widget :field-overlay overlay)
1891     (insert value)
1892     (and size
1893          (< (length value) size)
1894          (insert-char ?\  (- size (length value))))
1895     (unless (memq widget widget-field-list)
1896       (setq widget-field-new (cons widget widget-field-new)))
1897     (move-marker (cdr overlay) (point))
1898     (set-marker-insertion-type (cdr overlay) nil)
1899     (when (null size)
1900       (insert ?\n))
1901     (move-marker (car overlay) from)
1902     (set-marker-insertion-type (car overlay) t)))
1903
1904 (defun widget-field-value-delete (widget)
1905   ;; Remove the widget from the list of active editing fields.
1906   (setq widget-field-list (delq widget widget-field-list))
1907   ;; These are nil if the :format string doesn't contain `%v'.
1908   (let ((overlay (widget-get widget :field-overlay)))
1909     (when overlay
1910       (delete-overlay overlay))))
1911
1912 (defun widget-field-value-get (widget)
1913   ;; Return current text in editing field.
1914   (let ((from (widget-field-start widget))
1915         (to (widget-field-end widget))
1916         (buffer (widget-field-buffer widget))
1917         (size (widget-get widget :size))
1918         (secret (widget-get widget :secret))
1919         (old (current-buffer)))
1920     (if (and from to)
1921         (progn
1922           (set-buffer buffer)
1923           (while (and size
1924                       (not (zerop size))
1925                       (> to from)
1926                       (eq (char-after (1- to)) ?\ ))
1927             (setq to (1- to)))
1928           (let ((result (buffer-substring-no-properties from to)))
1929             (when secret
1930               (let ((index 0))
1931                 (while (< (+ from index) to)
1932                   (aset result index
1933                         (get-char-property (+ from index) 'secret))
1934                   (setq index (1+ index)))))
1935             (set-buffer old)
1936             result))
1937       (widget-get widget :value))))
1938
1939 (defun widget-field-match (widget value)
1940   ;; Match any string.
1941   (stringp value))
1942
1943 ;;; The `text' Widget.
1944
1945 (define-widget 'text 'editable-field
1946   :keymap widget-text-keymap
1947   "A multiline text area.")
1948
1949 ;;; The `menu-choice' Widget.
1950
1951 (define-widget 'menu-choice 'default
1952   "A menu of options."
1953   :convert-widget  'widget-types-convert-widget
1954   :format "%[%t%]: %v"
1955   :case-fold t
1956   :tag "choice"
1957   :void '(item :format "invalid (%t)\n")
1958   :value-create 'widget-choice-value-create
1959   :value-delete 'widget-children-value-delete
1960   :value-get 'widget-choice-value-get
1961   :value-inline 'widget-choice-value-inline
1962   :mouse-down-action 'widget-choice-mouse-down-action
1963   :action 'widget-choice-action
1964   :error "Make a choice"
1965   :validate 'widget-choice-validate
1966   :match 'widget-choice-match
1967   :match-inline 'widget-choice-match-inline)
1968
1969 (defun widget-choice-value-create (widget)
1970   ;; Insert the first choice that matches the value.
1971   (let ((value (widget-get widget :value))
1972         (args (widget-get widget :args))
1973         current)
1974     (while args
1975       (setq current (car args)
1976             args (cdr args))
1977       (when (widget-apply current :match value)
1978         (widget-put widget :children (list (widget-create-child-value
1979                                             widget current value)))
1980         (widget-put widget :choice current)
1981         (setq args nil
1982               current nil)))
1983     (when current
1984       (let ((void (widget-get widget :void)))
1985         (widget-put widget :children (list (widget-create-child-and-convert
1986                                             widget void :value value)))
1987         (widget-put widget :choice void)))))
1988
1989 (defun widget-choice-value-get (widget)
1990   ;; Get value of the child widget.
1991   (widget-value (car (widget-get widget :children))))
1992
1993 (defun widget-choice-value-inline (widget)
1994   ;; Get value of the child widget.
1995   (widget-apply (car (widget-get widget :children)) :value-inline))
1996
1997 (defcustom widget-choice-toggle nil
1998   "If non-nil, a binary choice will just toggle between the values.
1999 Otherwise, the user will explicitly have to choose between the values
2000 when he invoked the menu."
2001   :type 'boolean
2002   :group 'widgets)
2003
2004 (defun widget-choice-mouse-down-action (widget &optional event)
2005   ;; Return non-nil if we need a menu.
2006   (let ((args (widget-get widget :args))
2007         (old (widget-get widget :choice)))
2008     (cond ((not window-system)
2009            ;; No place to pop up a menu.
2010            nil)
2011           ((not (or (fboundp 'x-popup-menu) (fboundp 'popup-menu)))
2012            ;; No way to pop up a menu.
2013            nil)
2014           ((< (length args) 2)
2015            ;; Empty or singleton list, just return the value.
2016            nil)
2017           ((> (length args) widget-menu-max-size)
2018            ;; Too long, prompt.
2019            nil)
2020           ((> (length args) 2)
2021            ;; Reasonable sized list, use menu.
2022            t)
2023           ((and widget-choice-toggle (memq old args))
2024            ;; We toggle.
2025            nil)
2026           (t
2027            ;; Ask which of the two.
2028            t))))
2029
2030 (defun widget-choice-action (widget &optional event)
2031   ;; Make a choice.
2032   (let ((args (widget-get widget :args))
2033         (old (widget-get widget :choice))
2034         (tag (widget-apply widget :menu-tag-get))
2035         (completion-ignore-case (widget-get widget :case-fold))
2036         current choices)
2037     ;; Remember old value.
2038     (if (and old (not (widget-apply widget :validate)))
2039         (let* ((external (widget-value widget))
2040                (internal (widget-apply old :value-to-internal external)))
2041           (widget-put old :value internal)))
2042     ;; Find new choice.
2043     (setq current
2044           (cond ((= (length args) 0)
2045                  nil)
2046                 ((= (length args) 1)
2047                  (nth 0 args))
2048                 ((and widget-choice-toggle
2049                       (= (length args) 2)
2050                       (memq old args))
2051                  (if (eq old (nth 0 args))
2052                      (nth 1 args)
2053                    (nth 0 args)))
2054                 (t
2055                  (while args
2056                    (setq current (car args)
2057                          args (cdr args))
2058                    (setq choices
2059                          (cons (cons (widget-apply current :menu-tag-get)
2060                                      current)
2061                                choices)))
2062                  (widget-choose tag (reverse choices) event))))
2063     (when current
2064       (widget-value-set widget
2065                         (widget-apply current :value-to-external
2066                                       (widget-get current :value)))
2067       (widget-setup)
2068       (widget-apply widget :notify widget event)))
2069   (run-hook-with-args 'widget-edit-functions widget))
2070
2071 (defun widget-choice-validate (widget)
2072   ;; Valid if we have made a valid choice.
2073   (let ((void (widget-get widget :void))
2074         (choice (widget-get widget :choice))
2075         (child (car (widget-get widget :children))))
2076     (if (eq void choice)
2077         widget
2078       (widget-apply child :validate))))
2079
2080 (defun widget-choice-match (widget value)
2081   ;; Matches if one of the choices matches.
2082   (let ((args (widget-get widget :args))
2083         current found)
2084     (while (and args (not found))
2085       (setq current (car args)
2086             args (cdr args)
2087             found (widget-apply current :match value)))
2088     found))
2089
2090 (defun widget-choice-match-inline (widget values)
2091   ;; Matches if one of the choices matches.
2092   (let ((args (widget-get widget :args))
2093         current found)
2094     (while (and args (null found))
2095       (setq current (car args)
2096             args (cdr args)
2097             found (widget-match-inline current values)))
2098     found))
2099
2100 ;;; The `toggle' Widget.
2101
2102 (define-widget 'toggle 'item
2103   "Toggle between two states."
2104   :format "%[%v%]\n"
2105   :value-create 'widget-toggle-value-create
2106   :action 'widget-toggle-action
2107   :match (lambda (widget value) t)
2108   :on "on"
2109   :off "off")
2110
2111 (defun widget-toggle-value-create (widget)
2112   ;; Insert text representing the `on' and `off' states.
2113   (if (widget-value widget)
2114       (widget-glyph-insert widget
2115                            (widget-get widget :on)
2116                            (widget-get widget :on-glyph))
2117     (widget-glyph-insert widget
2118                          (widget-get widget :off)
2119                          (widget-get widget :off-glyph))))
2120
2121 (defun widget-toggle-action (widget &optional event)
2122   ;; Toggle value.
2123   (widget-value-set widget (not (widget-value widget)))
2124   (widget-apply widget :notify widget event)
2125   (run-hook-with-args 'widget-edit-functions widget))
2126
2127 ;;; The `checkbox' Widget.
2128
2129 (define-widget 'checkbox 'toggle
2130   "A checkbox toggle."
2131   :button-suffix ""
2132   :button-prefix ""
2133   :format "%[%v%]"
2134   :on "[X]"
2135   :on-glyph "check1"
2136   :off "[ ]"
2137   :off-glyph "check0"
2138   :action 'widget-checkbox-action)
2139
2140 (defun widget-checkbox-action (widget &optional event)
2141   "Toggle checkbox, notify parent, and set active state of sibling."
2142   (widget-toggle-action widget event)
2143   (let ((sibling (widget-get-sibling widget)))
2144     (when sibling
2145       (if (widget-value widget)
2146           (widget-apply sibling :activate)
2147         (widget-apply sibling :deactivate)))))
2148
2149 ;;; The `checklist' Widget.
2150
2151 (define-widget 'checklist 'default
2152   "A multiple choice widget."
2153   :convert-widget 'widget-types-convert-widget
2154   :format "%v"
2155   :offset 4
2156   :entry-format "%b %v"
2157   :menu-tag "checklist"
2158   :greedy nil
2159   :value-create 'widget-checklist-value-create
2160   :value-delete 'widget-children-value-delete
2161   :value-get 'widget-checklist-value-get
2162   :validate 'widget-checklist-validate
2163   :match 'widget-checklist-match
2164   :match-inline 'widget-checklist-match-inline)
2165
2166 (defun widget-checklist-value-create (widget)
2167   ;; Insert all values
2168   (let ((alist (widget-checklist-match-find widget (widget-get widget :value)))
2169         (args (widget-get widget :args)))
2170     (while args
2171       (widget-checklist-add-item widget (car args) (assq (car args) alist))
2172       (setq args (cdr args)))
2173     (widget-put widget :children (nreverse (widget-get widget :children)))))
2174
2175 (defun widget-checklist-add-item (widget type chosen)
2176   ;; Create checklist item in WIDGET of type TYPE.
2177   ;; If the item is checked, CHOSEN is a cons whose cdr is the value.
2178   (and (eq (preceding-char) ?\n)
2179        (widget-get widget :indent)
2180        (insert-char ?  (widget-get widget :indent)))
2181   (widget-specify-insert
2182    (let* ((children (widget-get widget :children))
2183           (buttons (widget-get widget :buttons))
2184           (button-args (or (widget-get type :sibling-args)
2185                            (widget-get widget :button-args)))
2186           (from (point))
2187           child button)
2188      (insert (widget-get widget :entry-format))
2189      (goto-char from)
2190      ;; Parse % escapes in format.
2191      (while (re-search-forward "%\\([bv%]\\)" nil t)
2192        (let ((escape (aref (match-string 1) 0)))
2193          (replace-match "" t t)
2194          (cond ((eq escape ?%)
2195                 (insert "%"))
2196                ((eq escape ?b)
2197                 (setq button (apply 'widget-create-child-and-convert
2198                                     widget 'checkbox
2199                                     :value (not (null chosen))
2200                                     button-args)))
2201                ((eq escape ?v)
2202                 (setq child
2203                       (cond ((not chosen)
2204                              (let ((child (widget-create-child widget type)))
2205                                (widget-apply child :deactivate)
2206                                child))
2207                             ((widget-get type :inline)
2208                              (widget-create-child-value
2209                               widget type (cdr chosen)))
2210                             (t
2211                              (widget-create-child-value
2212                               widget type (car (cdr chosen)))))))
2213                (t
2214                 (error "Unknown escape `%c'" escape)))))
2215      ;; Update properties.
2216      (and button child (widget-put child :button button))
2217      (and button (widget-put widget :buttons (cons button buttons)))
2218      (and child (widget-put widget :children (cons child children))))))
2219
2220 (defun widget-checklist-match (widget values)
2221   ;; All values must match a type in the checklist.
2222   (and (listp values)
2223        (null (cdr (widget-checklist-match-inline widget values)))))
2224
2225 (defun widget-checklist-match-inline (widget values)
2226   ;; Find the values which match a type in the checklist.
2227   (let ((greedy (widget-get widget :greedy))
2228         (args (copy-sequence (widget-get widget :args)))
2229         found rest)
2230     (while values
2231       (let ((answer (widget-checklist-match-up args values)))
2232         (cond (answer
2233                (let ((vals (widget-match-inline answer values)))
2234                  (setq found (append found (car vals))
2235                        values (cdr vals)
2236                        args (delq answer args))))
2237               (greedy
2238                (setq rest (append rest (list (car values)))
2239                      values (cdr values)))
2240               (t
2241                (setq rest (append rest values)
2242                      values nil)))))
2243     (cons found rest)))
2244
2245 (defun widget-checklist-match-find (widget vals)
2246   ;; Find the vals which match a type in the checklist.
2247   ;; Return an alist of (TYPE MATCH).
2248   (let ((greedy (widget-get widget :greedy))
2249         (args (copy-sequence (widget-get widget :args)))
2250         found)
2251     (while vals
2252       (let ((answer (widget-checklist-match-up args vals)))
2253         (cond (answer
2254                (let ((match (widget-match-inline answer vals)))
2255                  (setq found (cons (cons answer (car match)) found)
2256                        vals (cdr match)
2257                        args (delq answer args))))
2258               (greedy
2259                (setq vals (cdr vals)))
2260               (t
2261                (setq vals nil)))))
2262     found))
2263
2264 (defun widget-checklist-match-up (args vals)
2265   ;; Rerturn the first type from ARGS that matches VALS.
2266   (let (current found)
2267     (while (and args (null found))
2268       (setq current (car args)
2269             args (cdr args)
2270             found (widget-match-inline current vals)))
2271     (if found
2272         current
2273       nil)))
2274
2275 (defun widget-checklist-value-get (widget)
2276   ;; The values of all selected items.
2277   (let ((children (widget-get widget :children))
2278         child result)
2279     (while children
2280       (setq child (car children)
2281             children (cdr children))
2282       (if (widget-value (widget-get child :button))
2283           (setq result (append result (widget-apply child :value-inline)))))
2284     result))
2285
2286 (defun widget-checklist-validate (widget)
2287   ;; Ticked chilren must be valid.
2288   (let ((children (widget-get widget :children))
2289         child button found)
2290     (while (and children (not found))
2291       (setq child (car children)
2292             children (cdr children)
2293             button (widget-get child :button)
2294             found (and (widget-value button)
2295                        (widget-apply child :validate))))
2296     found))
2297
2298 ;;; The `option' Widget
2299
2300 (define-widget 'option 'checklist
2301   "An widget with an optional item."
2302   :inline t)
2303
2304 ;;; The `choice-item' Widget.
2305
2306 (define-widget 'choice-item 'item
2307   "Button items that delegate action events to their parents."
2308   :action 'widget-parent-action
2309   :format "%[%t%] \n")
2310
2311 ;;; The `radio-button' Widget.
2312
2313 (define-widget 'radio-button 'toggle
2314   "A radio button for use in the `radio' widget."
2315   :notify 'widget-radio-button-notify
2316   :format "%[%v%]"
2317   :button-suffix ""
2318   :button-prefix ""
2319   :on "(*)"
2320   :on-glyph "radio1"
2321   :off "( )"
2322   :off-glyph "radio0")
2323
2324 (defun widget-radio-button-notify (widget child &optional event)
2325   ;; Tell daddy.
2326   (widget-apply (widget-get widget :parent) :action widget event))
2327
2328 ;;; The `radio-button-choice' Widget.
2329
2330 (define-widget 'radio-button-choice 'default
2331   "Select one of multiple options."
2332   :convert-widget 'widget-types-convert-widget
2333   :offset 4
2334   :format "%v"
2335   :entry-format "%b %v"
2336   :menu-tag "radio"
2337   :value-create 'widget-radio-value-create
2338   :value-delete 'widget-children-value-delete
2339   :value-get 'widget-radio-value-get
2340   :value-inline 'widget-radio-value-inline
2341   :value-set 'widget-radio-value-set
2342   :error "You must push one of the buttons"
2343   :validate 'widget-radio-validate
2344   :match 'widget-choice-match
2345   :match-inline 'widget-choice-match-inline
2346   :action 'widget-radio-action)
2347
2348 (defun widget-radio-value-create (widget)
2349   ;; Insert all values
2350   (let ((args (widget-get widget :args))
2351         arg)
2352     (while args
2353       (setq arg (car args)
2354             args (cdr args))
2355       (widget-radio-add-item widget arg))))
2356
2357 (defun widget-radio-add-item (widget type)
2358   "Add to radio widget WIDGET a new radio button item of type TYPE."
2359   ;; (setq type (widget-convert type))
2360   (and (eq (preceding-char) ?\n)
2361        (widget-get widget :indent)
2362        (insert-char ?  (widget-get widget :indent)))
2363   (widget-specify-insert
2364    (let* ((value (widget-get widget :value))
2365           (children (widget-get widget :children))
2366           (buttons (widget-get widget :buttons))
2367           (button-args (or (widget-get type :sibling-args)
2368                            (widget-get widget :button-args)))
2369           (from (point))
2370           (chosen (and (null (widget-get widget :choice))
2371                        (widget-apply type :match value)))
2372           child button)
2373      (insert (widget-get widget :entry-format))
2374      (goto-char from)
2375      ;; Parse % escapes in format.
2376      (while (re-search-forward "%\\([bv%]\\)" nil t)
2377        (let ((escape (aref (match-string 1) 0)))
2378          (replace-match "" t t)
2379          (cond ((eq escape ?%)
2380                 (insert "%"))
2381                ((eq escape ?b)
2382                 (setq button (apply 'widget-create-child-and-convert
2383                                     widget 'radio-button
2384                                     :value (not (null chosen))
2385                                     button-args)))
2386                ((eq escape ?v)
2387                 (setq child (if chosen
2388                                 (widget-create-child-value
2389                                  widget type value)
2390                               (widget-create-child widget type)))
2391                 (unless chosen
2392                   (widget-apply child :deactivate)))
2393                (t
2394                 (error "Unknown escape `%c'" escape)))))
2395      ;; Update properties.
2396      (when chosen
2397        (widget-put widget :choice type))
2398      (when button
2399        (widget-put child :button button)
2400        (widget-put widget :buttons (nconc buttons (list button))))
2401      (when child
2402        (widget-put widget :children (nconc children (list child))))
2403      child)))
2404
2405 (defun widget-radio-value-get (widget)
2406   ;; Get value of the child widget.
2407   (let ((chosen (widget-radio-chosen widget)))
2408     (and chosen (widget-value chosen))))
2409
2410 (defun widget-radio-chosen (widget)
2411   "Return the widget representing the chosen radio button."
2412   (let ((children (widget-get widget :children))
2413         current found)
2414     (while children
2415       (setq current (car children)
2416             children (cdr children))
2417       (let* ((button (widget-get current :button))
2418              (value (widget-apply button :value-get)))
2419         (when value
2420           (setq found current
2421                 children nil))))
2422     found))
2423
2424 (defun widget-radio-value-inline (widget)
2425   ;; Get value of the child widget.
2426   (let ((children (widget-get widget :children))
2427         current found)
2428     (while children
2429       (setq current (car children)
2430             children (cdr children))
2431       (let* ((button (widget-get current :button))
2432              (value (widget-apply button :value-get)))
2433         (when value
2434           (setq found (widget-apply current :value-inline)
2435                 children nil))))
2436     found))
2437
2438 (defun widget-radio-value-set (widget value)
2439   ;; We can't just delete and recreate a radio widget, since children
2440   ;; can be added after the original creation and won't be recreated
2441   ;; by `:create'.
2442   (let ((children (widget-get widget :children))
2443         current found)
2444     (while children
2445       (setq current (car children)
2446             children (cdr children))
2447       (let* ((button (widget-get current :button))
2448              (match (and (not found)
2449                          (widget-apply current :match value))))
2450         (widget-value-set button match)
2451         (if match
2452             (progn
2453               (widget-value-set current value)
2454               (widget-apply current :activate))
2455           (widget-apply current :deactivate))
2456         (setq found (or found match))))))
2457
2458 (defun widget-radio-validate (widget)
2459   ;; Valid if we have made a valid choice.
2460   (let ((children (widget-get widget :children))
2461         current found button)
2462     (while (and children (not found))
2463       (setq current (car children)
2464             children (cdr children)
2465             button (widget-get current :button)
2466             found (widget-apply button :value-get)))
2467     (if found
2468         (widget-apply current :validate)
2469       widget)))
2470
2471 (defun widget-radio-action (widget child event)
2472   ;; Check if a radio button was pressed.
2473   (let ((children (widget-get widget :children))
2474         (buttons (widget-get widget :buttons))
2475         current)
2476     (when (memq child buttons)
2477       (while children
2478         (setq current (car children)
2479               children (cdr children))
2480         (let* ((button (widget-get current :button)))
2481           (cond ((eq child button)
2482                  (widget-value-set button t)
2483                  (widget-apply current :activate))
2484                 ((widget-value button)
2485                  (widget-value-set button nil)
2486                  (widget-apply current :deactivate)))))))
2487   ;; Pass notification to parent.
2488   (widget-apply widget :notify child event))
2489
2490 ;;; The `insert-button' Widget.
2491
2492 (define-widget 'insert-button 'push-button
2493   "An insert button for the `editable-list' widget."
2494   :tag "INS"
2495   :help-echo "Insert a new item into the list at this position."
2496   :action 'widget-insert-button-action)
2497
2498 (defun widget-insert-button-action (widget &optional event)
2499   ;; Ask the parent to insert a new item.
2500   (widget-apply (widget-get widget :parent)
2501                 :insert-before (widget-get widget :widget)))
2502
2503 ;;; The `delete-button' Widget.
2504
2505 (define-widget 'delete-button 'push-button
2506   "A delete button for the `editable-list' widget."
2507   :tag "DEL"
2508   :help-echo "Delete this item from the list."
2509   :action 'widget-delete-button-action)
2510
2511 (defun widget-delete-button-action (widget &optional event)
2512   ;; Ask the parent to insert a new item.
2513   (widget-apply (widget-get widget :parent)
2514                 :delete-at (widget-get widget :widget)))
2515
2516 ;;; The `editable-list' Widget.
2517
2518 (defcustom widget-editable-list-gui nil
2519   "If non nil, use GUI push-buttons in editable list when available."
2520   :type 'boolean
2521   :group 'widgets)
2522
2523 (define-widget 'editable-list 'default
2524   "A variable list of widgets of the same type."
2525   :convert-widget 'widget-types-convert-widget
2526   :offset 12
2527   :format "%v%i\n"
2528   :format-handler 'widget-editable-list-format-handler
2529   :entry-format "%i %d %v"
2530   :menu-tag "editable-list"
2531   :value-create 'widget-editable-list-value-create
2532   :value-delete 'widget-children-value-delete
2533   :value-get 'widget-editable-list-value-get
2534   :validate 'widget-children-validate
2535   :match 'widget-editable-list-match
2536   :match-inline 'widget-editable-list-match-inline
2537   :insert-before 'widget-editable-list-insert-before
2538   :delete-at 'widget-editable-list-delete-at)
2539
2540 (defun widget-editable-list-format-handler (widget escape)
2541   ;; We recognize the insert button.
2542   (let ((widget-push-button-gui widget-editable-list-gui))
2543     (cond ((eq escape ?i)
2544            (and (widget-get widget :indent)
2545                 (insert-char ?  (widget-get widget :indent)))
2546            (apply 'widget-create-child-and-convert
2547                   widget 'insert-button
2548                   (widget-get widget :append-button-args)))
2549           (t
2550            (widget-default-format-handler widget escape)))))
2551
2552 (defun widget-editable-list-value-create (widget)
2553   ;; Insert all values
2554   (let* ((value (widget-get widget :value))
2555          (type (nth 0 (widget-get widget :args)))
2556          (inlinep (widget-get type :inline))
2557          children)
2558     (widget-put widget :value-pos (copy-marker (point)))
2559     (set-marker-insertion-type (widget-get widget :value-pos) t)
2560     (while value
2561       (let ((answer (widget-match-inline type value)))
2562         (if answer
2563             (setq children (cons (widget-editable-list-entry-create
2564                                   widget
2565                                   (if inlinep
2566                                       (car answer)
2567                                     (car (car answer)))
2568                                   t)
2569                                  children)
2570                   value (cdr answer))
2571           (setq value nil))))
2572     (widget-put widget :children (nreverse children))))
2573
2574 (defun widget-editable-list-value-get (widget)
2575   ;; Get value of the child widget.
2576   (apply 'append (mapcar (lambda (child) (widget-apply child :value-inline))
2577                          (widget-get widget :children))))
2578
2579 (defun widget-editable-list-match (widget value)
2580   ;; Value must be a list and all the members must match the type.
2581   (and (listp value)
2582        (null (cdr (widget-editable-list-match-inline widget value)))))
2583
2584 (defun widget-editable-list-match-inline (widget value)
2585   (let ((type (nth 0 (widget-get widget :args)))
2586         (ok t)
2587         found)
2588     (while (and value ok)
2589       (let ((answer (widget-match-inline type value)))
2590         (if answer
2591             (setq found (append found (car answer))
2592                   value (cdr answer))
2593           (setq ok nil))))
2594     (cons found value)))
2595
2596 (defun widget-editable-list-insert-before (widget before)
2597   ;; Insert a new child in the list of children.
2598   (save-excursion
2599     (let ((children (widget-get widget :children))
2600           (inhibit-read-only t)
2601           before-change-functions
2602           after-change-functions)
2603       (cond (before
2604              (goto-char (widget-get before :entry-from)))
2605             (t
2606              (goto-char (widget-get widget :value-pos))))
2607       (let ((child (widget-editable-list-entry-create
2608                     widget nil nil)))
2609         (when (< (widget-get child :entry-from) (widget-get widget :from))
2610           (set-marker (widget-get widget :from)
2611                       (widget-get child :entry-from)))
2612         (if (eq (car children) before)
2613             (widget-put widget :children (cons child children))
2614           (while (not (eq (car (cdr children)) before))
2615             (setq children (cdr children)))
2616           (setcdr children (cons child (cdr children)))))))
2617   (widget-setup)
2618   (widget-apply widget :notify widget))
2619
2620 (defun widget-editable-list-delete-at (widget child)
2621   ;; Delete child from list of children.
2622   (save-excursion
2623     (let ((buttons (copy-sequence (widget-get widget :buttons)))
2624           button
2625           (inhibit-read-only t)
2626           before-change-functions
2627           after-change-functions)
2628       (while buttons
2629         (setq button (car buttons)
2630               buttons (cdr buttons))
2631         (when (eq (widget-get button :widget) child)
2632           (widget-put widget
2633                       :buttons (delq button (widget-get widget :buttons)))
2634           (widget-delete button))))
2635     (let ((entry-from (widget-get child :entry-from))
2636           (entry-to (widget-get child :entry-to))
2637           (inhibit-read-only t)
2638           before-change-functions
2639           after-change-functions)
2640       (widget-delete child)
2641       (delete-region entry-from entry-to)
2642       (set-marker entry-from nil)
2643       (set-marker entry-to nil))
2644     (widget-put widget :children (delq child (widget-get widget :children))))
2645   (widget-setup)
2646   (widget-apply widget :notify widget))
2647
2648 (defun widget-editable-list-entry-create (widget value conv)
2649   ;; Create a new entry to the list.
2650   (let ((type (nth 0 (widget-get widget :args)))
2651         (widget-push-button-gui widget-editable-list-gui)
2652         child delete insert)
2653     (widget-specify-insert
2654      (save-excursion
2655        (and (widget-get widget :indent)
2656             (insert-char ?  (widget-get widget :indent)))
2657        (insert (widget-get widget :entry-format)))
2658      ;; Parse % escapes in format.
2659      (while (re-search-forward "%\\(.\\)" nil t)
2660        (let ((escape (aref (match-string 1) 0)))
2661          (replace-match "" t t)
2662          (cond ((eq escape ?%)
2663                 (insert "%"))
2664                ((eq escape ?i)
2665                 (setq insert (apply 'widget-create-child-and-convert
2666                                     widget 'insert-button
2667                                     (widget-get widget :insert-button-args))))
2668                ((eq escape ?d)
2669                 (setq delete (apply 'widget-create-child-and-convert
2670                                     widget 'delete-button
2671                                     (widget-get widget :delete-button-args))))
2672                ((eq escape ?v)
2673                 (if conv
2674                     (setq child (widget-create-child-value
2675                                  widget type value))
2676                   (setq child (widget-create-child widget type))))
2677                (t
2678                 (error "Unknown escape `%c'" escape)))))
2679      (widget-put widget
2680                  :buttons (cons delete
2681                                 (cons insert
2682                                       (widget-get widget :buttons))))
2683      (let ((entry-from (copy-marker (point-min)))
2684            (entry-to (copy-marker (point-max))))
2685        (set-marker-insertion-type entry-from t)
2686        (set-marker-insertion-type entry-to nil)
2687        (widget-put child :entry-from entry-from)
2688        (widget-put child :entry-to entry-to)))
2689     (widget-put insert :widget child)
2690     (widget-put delete :widget child)
2691     child))
2692
2693 ;;; The `group' Widget.
2694
2695 (define-widget 'group 'default
2696   "A widget which group other widgets inside."
2697   :convert-widget 'widget-types-convert-widget
2698   :format "%v"
2699   :value-create 'widget-group-value-create
2700   :value-delete 'widget-children-value-delete
2701   :value-get 'widget-editable-list-value-get
2702   :validate 'widget-children-validate
2703   :match 'widget-group-match
2704   :match-inline 'widget-group-match-inline)
2705
2706 (defun widget-group-value-create (widget)
2707   ;; Create each component.
2708   (let ((args (widget-get widget :args))
2709         (value (widget-get widget :value))
2710         arg answer children)
2711     (while args
2712       (setq arg (car args)
2713             args (cdr args)
2714             answer (widget-match-inline arg value)
2715             value (cdr answer))
2716       (and (eq (preceding-char) ?\n)
2717            (widget-get widget :indent)
2718            (insert-char ?  (widget-get widget :indent)))
2719       (push (cond ((null answer)
2720                    (widget-create-child widget arg))
2721                   ((widget-get arg :inline)
2722                    (widget-create-child-value widget arg  (car answer)))
2723                   (t
2724                    (widget-create-child-value widget arg  (car (car answer)))))
2725             children))
2726     (widget-put widget :children (nreverse children))))
2727
2728 (defun widget-group-match (widget values)
2729   ;; Match if the components match.
2730   (and (listp values)
2731        (let ((match (widget-group-match-inline widget values)))
2732          (and match (null (cdr match))))))
2733
2734 (defun widget-group-match-inline (widget vals)
2735   ;; Match if the components match.
2736   (let ((args (widget-get widget :args))
2737         argument answer found)
2738     (while args
2739       (setq argument (car args)
2740             args (cdr args)
2741             answer (widget-match-inline argument vals))
2742       (if answer
2743           (setq vals (cdr answer)
2744                 found (append found (car answer)))
2745         (setq vals nil
2746               args nil)))
2747     (if answer
2748         (cons found vals)
2749       nil)))
2750
2751 ;;; The `visibility' Widget.
2752
2753 (define-widget 'visibility 'item
2754   "An indicator and manipulator for hidden items."
2755   :format "%[%v%]"
2756   :button-prefix ""
2757   :button-suffix ""
2758   :on "Hide"
2759   :off "Show"
2760   :value-create 'widget-visibility-value-create
2761   :action 'widget-toggle-action
2762   :match (lambda (widget value) t))
2763
2764 (defun widget-visibility-value-create (widget)
2765   ;; Insert text representing the `on' and `off' states.
2766   (let ((on (widget-get widget :on))
2767         (off (widget-get widget :off)))
2768     (if on
2769         (setq on (concat widget-push-button-prefix
2770                          on
2771                          widget-push-button-suffix))
2772       (setq on ""))
2773     (if off
2774         (setq off (concat widget-push-button-prefix
2775                           off
2776                           widget-push-button-suffix))
2777       (setq off ""))
2778     (if (widget-value widget)
2779         (widget-glyph-insert widget on "down" "down-pushed")
2780       (widget-glyph-insert widget off "right" "right-pushed"))))
2781
2782 ;;; The `documentation-link' Widget.
2783 ;;
2784 ;; This is a helper widget for `documentation-string'.
2785
2786 (define-widget 'documentation-link 'link
2787   "Link type used in documentation strings."
2788   :tab-order -1
2789   :help-echo 'widget-documentation-link-echo-help
2790   :action 'widget-documentation-link-action)
2791
2792 (defun widget-documentation-link-echo-help (widget)
2793   "Tell what this link will describe."
2794   (concat "Describe the `" (widget-get widget :value) "' symbol."))
2795
2796 (defun widget-documentation-link-action (widget &optional event)
2797   "Display documentation for WIDGET's value.  Ignore optional argument EVENT."
2798   (let* ((string (widget-get widget :value))
2799          (symbol (intern string)))
2800     (if (and (fboundp symbol) (boundp symbol))
2801         ;; If there are two doc strings, give the user a way to pick one.
2802         (apropos (concat "\\`" (regexp-quote string) "\\'"))
2803       (if (fboundp symbol)
2804           (describe-function symbol)
2805         (describe-variable symbol)))))
2806
2807 (defcustom widget-documentation-links t
2808   "Add hyperlinks to documentation strings when non-nil."
2809   :type 'boolean
2810   :group 'widget-documentation)
2811
2812 (defcustom widget-documentation-link-regexp "`\\([^\n`' ]+\\)'"
2813   "Regexp for matching potential links in documentation strings.
2814 The first group should be the link itself."
2815   :type 'regexp
2816   :group 'widget-documentation)
2817
2818 (defcustom widget-documentation-link-p 'intern-soft
2819   "Predicate used to test if a string is useful as a link.
2820 The value should be a function.  The function will be called one
2821 argument, a string, and should return non-nil if there should be a
2822 link for that string."
2823   :type 'function
2824   :options '(widget-documentation-link-p)
2825   :group 'widget-documentation)
2826
2827 (defcustom widget-documentation-link-type 'documentation-link
2828   "Widget type used for links in documentation strings."
2829   :type 'symbol
2830   :group 'widget-documentation)
2831
2832 (defun widget-documentation-link-add (widget from to)
2833   (widget-specify-doc widget from to)
2834   (when widget-documentation-links
2835     (let ((regexp widget-documentation-link-regexp)
2836           (predicate widget-documentation-link-p)
2837           (type widget-documentation-link-type)
2838           (buttons (widget-get widget :buttons)))
2839       (save-excursion
2840         (goto-char from)
2841         (while (re-search-forward regexp to t)
2842           (let ((name (match-string 1))
2843                 (begin (match-beginning 1))
2844                 (end (match-end 1)))
2845             (when (funcall predicate name)
2846               (push (widget-convert-button type begin end :value name)
2847                     buttons)))))
2848       (widget-put widget :buttons buttons)))
2849   (let ((indent (widget-get widget :indent)))
2850     (when (and indent (not (zerop indent)))
2851       (save-excursion
2852         (save-restriction
2853           (narrow-to-region from to)
2854           (goto-char (point-min))
2855           (while (search-forward "\n" nil t)
2856             (insert-char ?\  indent)))))))
2857
2858 ;;; The `documentation-string' Widget.
2859
2860 (define-widget 'documentation-string 'item
2861   "A documentation string."
2862   :format "%v"
2863   :action 'widget-documentation-string-action
2864   :value-delete 'widget-children-value-delete
2865   :value-create 'widget-documentation-string-value-create)
2866
2867 (defun widget-documentation-string-value-create (widget)
2868   ;; Insert documentation string.
2869   (let ((doc (widget-value widget))
2870         (indent (widget-get widget :indent))
2871         (shown (widget-get (widget-get widget :parent) :documentation-shown))
2872         (start (point)))
2873     (if (string-match "\n" doc)
2874         (let ((before (substring doc 0 (match-beginning 0)))
2875               (after (substring doc (match-beginning 0)))
2876               buttons)
2877           (insert before " ")
2878           (widget-documentation-link-add widget start (point))
2879           (push (widget-create-child-and-convert
2880                  widget 'visibility
2881                  :help-echo "Show or hide rest of the documentation."
2882                  :off "More"
2883                  :action 'widget-parent-action
2884                  shown)
2885                 buttons)
2886           (when shown
2887             (setq start (point))
2888             (when (and indent (not (zerop indent)))
2889               (insert-char ?\  indent))
2890             (insert after)
2891             (widget-documentation-link-add widget start (point)))
2892           (widget-put widget :buttons buttons))
2893       (insert doc)
2894       (widget-documentation-link-add widget start (point))))
2895   (insert "\n"))
2896
2897 (defun widget-documentation-string-action (widget &rest ignore)
2898   ;; Toggle documentation.
2899   (let ((parent (widget-get widget :parent)))
2900     (widget-put parent :documentation-shown
2901                 (not (widget-get parent :documentation-shown))))
2902   ;; Redraw.
2903   (widget-value-set widget (widget-value widget)))
2904
2905 ;;; The Sexp Widgets.
2906
2907 (define-widget 'const 'item
2908   "An immutable sexp."
2909   :prompt-value 'widget-const-prompt-value
2910   :format "%t\n%d")
2911
2912 (defun widget-const-prompt-value (widget prompt value unbound)
2913   ;; Return the value of the const.
2914   (widget-value widget))
2915
2916 (define-widget 'function-item 'const
2917   "An immutable function name."
2918   :format "%v\n%h"
2919   :documentation-property (lambda (symbol)
2920                             (condition-case nil
2921                                 (documentation symbol t)
2922                               (error nil))))
2923
2924 (define-widget 'variable-item 'const
2925   "An immutable variable name."
2926   :format "%v\n%h"
2927   :documentation-property 'variable-documentation)
2928
2929 (defvar widget-string-prompt-value-history nil
2930   "History of input to `widget-string-prompt-value'.")
2931
2932 (define-widget 'string 'editable-field
2933   "A string"
2934   :tag "String"
2935   :format "%{%t%}: %v"
2936   :complete-function 'ispell-complete-word
2937   :prompt-history 'widget-string-prompt-value-history)
2938
2939 (define-widget 'regexp 'string
2940   "A regular expression."
2941   :match 'widget-regexp-match
2942   :validate 'widget-regexp-validate
2943   ;; Doesn't work well with terminating newline.
2944   ;; :value-face 'widget-single-line-field-face
2945   :tag "Regexp")
2946
2947 (defun widget-regexp-match (widget value)
2948   ;; Match valid regexps.
2949   (and (stringp value)
2950        (condition-case nil
2951            (prog1 t
2952              (string-match value ""))
2953          (error nil))))
2954
2955 (defun widget-regexp-validate (widget)
2956   "Check that the value of WIDGET is a valid regexp."
2957   (let ((val (widget-value widget)))
2958     (condition-case data
2959         (prog1 nil
2960           (string-match val ""))
2961       (error (widget-put widget :error (error-message-string data))
2962              widget))))
2963
2964 (define-widget 'file 'string
2965   "A file widget.
2966 It will read a file name from the minibuffer when invoked."
2967   :complete-function 'widget-file-complete
2968   :prompt-value 'widget-file-prompt-value
2969   :format "%{%t%}: %v"
2970   ;; Doesn't work well with terminating newline.
2971   ;; :value-face 'widget-single-line-field-face
2972   :tag "File")
2973
2974 (defun widget-file-complete ()
2975   "Perform completion on file name preceding point."
2976   (interactive)
2977   (let* ((end (point))
2978          (beg (save-excursion
2979                 (skip-chars-backward "^ ")
2980                 (point)))
2981          (pattern (buffer-substring beg end))
2982          (name-part (file-name-nondirectory pattern))
2983          (directory (file-name-directory pattern))
2984          (completion (file-name-completion name-part directory)))
2985     (cond ((eq completion t))
2986           ((null completion)
2987            (message "Can't find completion for \"%s\"" pattern)
2988            (ding))
2989           ((not (string= name-part completion))
2990            (delete-region beg end)
2991            (insert (expand-file-name completion directory)))
2992           (t
2993            (message "Making completion list...")
2994            (let ((list (file-name-all-completions name-part directory)))
2995              (setq list (sort list 'string<))
2996              (with-output-to-temp-buffer "*Completions*"
2997                (display-completion-list list)))
2998            (message "Making completion list...%s" "done")))))
2999
3000 (defun widget-file-prompt-value (widget prompt value unbound)
3001   ;; Read file from minibuffer.
3002   (abbreviate-file-name
3003    (if unbound
3004        (read-file-name prompt)
3005      (let ((prompt2 (format "%s (default %s) " prompt value))
3006            (dir (file-name-directory value))
3007            (file (file-name-nondirectory value))
3008            (must-match (widget-get widget :must-match)))
3009        (read-file-name prompt2 dir nil must-match file)))))
3010
3011 ;;;(defun widget-file-action (widget &optional event)
3012 ;;;  ;; Read a file name from the minibuffer.
3013 ;;;  (let* ((value (widget-value widget))
3014 ;;;      (dir (file-name-directory value))
3015 ;;;      (file (file-name-nondirectory value))
3016 ;;;      (menu-tag (widget-apply widget :menu-tag-get))
3017 ;;;      (must-match (widget-get widget :must-match))
3018 ;;;      (answer (read-file-name (concat menu-tag ": (default `" value "') ")
3019 ;;;                              dir nil must-match file)))
3020 ;;;    (widget-value-set widget (abbreviate-file-name answer))
3021 ;;;    (widget-setup)
3022 ;;;    (widget-apply widget :notify widget event)))
3023
3024 (define-widget 'directory 'file
3025   "A directory widget.
3026 It will read a directory name from the minibuffer when invoked."
3027   :tag "Directory")
3028
3029 (defvar widget-symbol-prompt-value-history nil
3030   "History of input to `widget-symbol-prompt-value'.")
3031
3032 (define-widget 'symbol 'editable-field
3033   "A lisp symbol."
3034   :value nil
3035   :tag "Symbol"
3036   :format "%{%t%}: %v"
3037   :match (lambda (widget value) (symbolp value))
3038   :complete-function 'lisp-complete-symbol
3039   :prompt-internal 'widget-symbol-prompt-internal
3040   :prompt-match 'symbolp
3041   :prompt-history 'widget-symbol-prompt-value-history
3042   :value-to-internal (lambda (widget value)
3043                        (if (symbolp value)
3044                            (symbol-name value)
3045                          value))
3046   :value-to-external (lambda (widget value)
3047                        (if (stringp value)
3048                            (intern value)
3049                          value)))
3050
3051 (defun widget-symbol-prompt-internal (widget prompt initial history)
3052   ;; Read file from minibuffer.
3053   (let ((answer (completing-read prompt obarray
3054                                  (widget-get widget :prompt-match)
3055                                  nil initial history)))
3056     (if (and (stringp answer)
3057              (not (zerop (length answer))))
3058         answer
3059       (error "No value"))))
3060
3061 (defvar widget-function-prompt-value-history nil
3062   "History of input to `widget-function-prompt-value'.")
3063
3064 (define-widget 'function 'sexp
3065   "A lisp function."
3066   :complete-function 'lisp-complete-symbol
3067   :prompt-value 'widget-field-prompt-value
3068   :prompt-internal 'widget-symbol-prompt-internal
3069   :prompt-match 'fboundp
3070   :prompt-history 'widget-function-prompt-value-history
3071   :action 'widget-field-action
3072   :tag "Function")
3073
3074 (defvar widget-variable-prompt-value-history nil
3075   "History of input to `widget-variable-prompt-value'.")
3076
3077 (define-widget 'variable 'symbol
3078   ;; Should complete on variables.
3079   "A lisp variable."
3080   :prompt-match 'boundp
3081   :prompt-history 'widget-variable-prompt-value-history
3082   :tag "Variable")
3083
3084 (when (featurep 'mule)
3085   (defvar widget-coding-system-prompt-value-history nil
3086     "History of input to `widget-coding-system-prompt-value'.")
3087
3088   (define-widget 'coding-system 'symbol
3089     "A MULE coding-system."
3090     :format "%{%t%}: %v"
3091     :tag "Coding system"
3092     :prompt-history 'widget-coding-system-prompt-value-history
3093     :prompt-value 'widget-coding-system-prompt-value
3094     :action 'widget-coding-system-action)
3095
3096   (defun widget-coding-system-prompt-value (widget prompt value unbound)
3097     ;; Read coding-system from minibuffer.
3098     (intern
3099      (completing-read (format "%s (default %s) " prompt value)
3100                       (mapcar (function
3101                                (lambda (sym)
3102                                  (list (symbol-name sym))
3103                                  ))
3104                               (coding-system-list)))))
3105
3106   (defun widget-coding-system-action (widget &optional event)
3107     ;; Read a file name from the minibuffer.
3108     (let ((answer
3109            (widget-coding-system-prompt-value
3110             widget
3111             (widget-apply widget :menu-tag-get)
3112             (widget-value widget)
3113             t)))
3114       (widget-value-set widget answer)
3115       (widget-apply widget :notify widget event)
3116       (widget-setup)))
3117   )
3118
3119 (define-widget 'sexp 'editable-field
3120   "An arbitrary lisp expression."
3121   :tag "Lisp expression"
3122   :format "%{%t%}: %v"
3123   :value nil
3124   :validate 'widget-sexp-validate
3125   :match (lambda (widget value) t)
3126   :value-to-internal 'widget-sexp-value-to-internal
3127   :value-to-external (lambda (widget value) (read value))
3128   :prompt-history 'widget-sexp-prompt-value-history
3129   :prompt-value 'widget-sexp-prompt-value)
3130
3131 (defun widget-sexp-value-to-internal (widget value)
3132   ;; Use pp for printer representation.
3133   (let ((pp (if (symbolp value)
3134                 (prin1-to-string value)
3135               (pp-to-string value))))
3136     (while (string-match "\n\\'" pp)
3137       (setq pp (substring pp 0 -1)))
3138     (if (or (string-match "\n\\'" pp)
3139             (> (length pp) 40))
3140         (concat "\n" pp)
3141       pp)))
3142
3143 (defun widget-sexp-validate (widget)
3144   ;; Valid if we can read the string and there is no junk left after it.
3145   (save-excursion
3146     (let ((buffer (set-buffer (get-buffer-create " *Widget Scratch*"))))
3147       (erase-buffer)
3148       (insert (widget-apply widget :value-get))
3149       (goto-char (point-min))
3150       (condition-case data
3151           (let ((value (read buffer)))
3152             (if (eobp)
3153                 (if (widget-apply widget :match value)
3154                     nil
3155                   (widget-put widget :error (widget-get widget :type-error))
3156                   widget)
3157               (widget-put widget
3158                           :error (format "Junk at end of expression: %s"
3159                                          (buffer-substring (point)
3160                                                            (point-max))))
3161               widget))
3162         (error (widget-put widget :error (error-message-string data))
3163                widget)))))
3164
3165 (defvar widget-sexp-prompt-value-history nil
3166   "History of input to `widget-sexp-prompt-value'.")
3167
3168 (defun widget-sexp-prompt-value (widget prompt value unbound)
3169   ;; Read an arbitrary sexp.
3170   (let ((found (read-string prompt
3171                             (if unbound nil (cons (prin1-to-string value) 0))
3172                             (widget-get widget :prompt-history))))
3173     (save-excursion
3174       (let ((buffer (set-buffer (get-buffer-create " *Widget Scratch*"))))
3175         (erase-buffer)
3176         (insert found)
3177         (goto-char (point-min))
3178         (let ((answer (read buffer)))
3179           (unless (eobp)
3180             (error "Junk at end of expression: %s"
3181                    (buffer-substring (point) (point-max))))
3182           answer)))))
3183
3184 (define-widget 'restricted-sexp 'sexp
3185   "A Lisp expression restricted to values that match.
3186 To use this type, you must define :match or :match-alternatives."
3187   :type-error "The specified value is not valid"
3188   :match 'widget-restricted-sexp-match
3189   :value-to-internal (lambda (widget value)
3190                        (if (widget-apply widget :match value)
3191                            (prin1-to-string value)
3192                          value)))
3193
3194 (defun widget-restricted-sexp-match (widget value)
3195   (let ((alternatives (widget-get widget :match-alternatives))
3196         matched)
3197     (while (and alternatives (not matched))
3198       (if (cond ((functionp (car alternatives))
3199                  (funcall (car alternatives) value))
3200                 ((and (consp (car alternatives))
3201                       (eq (car (car alternatives)) 'quote))
3202                  (eq value (nth 1 (car alternatives)))))
3203           (setq matched t))
3204       (setq alternatives (cdr alternatives)))
3205     matched))
3206
3207 (define-widget 'integer 'restricted-sexp
3208   "An integer."
3209   :tag "Integer"
3210   :value 0
3211   :type-error "This field should contain an integer"
3212   :match-alternatives '(integerp))
3213
3214 (define-widget 'number 'restricted-sexp
3215   "A floating point number."
3216   :tag "Number"
3217   :value 0.0
3218   :type-error "This field should contain a number"
3219   :match-alternatives '(numberp))
3220
3221 (define-widget 'character 'editable-field
3222   "A character."
3223   :tag "Character"
3224   :value 0
3225   :size 1
3226   :format "%{%t%}: %v\n"
3227   :valid-regexp "\\`.\\'"
3228   :error "This field should contain a single character"
3229   :value-to-internal (lambda (widget value)
3230                        (if (stringp value)
3231                            value
3232                          (char-to-string value)))
3233   :value-to-external (lambda (widget value)
3234                        (if (stringp value)
3235                            (aref value 0)
3236                          value))
3237   :match (lambda (widget value)
3238            (if (fboundp 'characterp)
3239                (characterp value)
3240              (integerp value))))
3241
3242 (define-widget 'list 'group
3243   "A lisp list."
3244   :tag "List"
3245   :format "%{%t%}:\n%v")
3246
3247 (define-widget 'vector 'group
3248   "A lisp vector."
3249   :tag "Vector"
3250   :format "%{%t%}:\n%v"
3251   :match 'widget-vector-match
3252   :value-to-internal (lambda (widget value) (append value nil))
3253   :value-to-external (lambda (widget value) (apply 'vector value)))
3254
3255 (defun widget-vector-match (widget value)
3256   (and (vectorp value)
3257        (widget-group-match widget
3258                            (widget-apply widget :value-to-internal value))))
3259
3260 (define-widget 'cons 'group
3261   "A cons-cell."
3262   :tag "Cons-cell"
3263   :format "%{%t%}:\n%v"
3264   :match 'widget-cons-match
3265   :value-to-internal (lambda (widget value)
3266                        (list (car value) (cdr value)))
3267   :value-to-external (lambda (widget value)
3268                        (cons (nth 0 value) (nth 1 value))))
3269
3270 (defun widget-cons-match (widget value)
3271   (and (consp value)
3272        (widget-group-match widget
3273                            (widget-apply widget :value-to-internal value))))
3274
3275 (define-widget 'choice 'menu-choice
3276   "A union of several sexp types."
3277   :tag "Choice"
3278   :format "%{%t%}: %[Value Menu%] %v"
3279   :button-prefix 'widget-push-button-prefix
3280   :button-suffix 'widget-push-button-suffix
3281   :prompt-value 'widget-choice-prompt-value)
3282
3283 (defun widget-choice-prompt-value (widget prompt value unbound)
3284   "Make a choice."
3285   (let ((args (widget-get widget :args))
3286         (completion-ignore-case (widget-get widget :case-fold))
3287         current choices old)
3288     ;; Find the first arg that match VALUE.
3289     (let ((look args))
3290       (while look
3291         (if (widget-apply (car look) :match value)
3292             (setq old (car look)
3293                   look nil)
3294           (setq look (cdr look)))))
3295     ;; Find new choice.
3296     (setq current
3297           (cond ((= (length args) 0)
3298                  nil)
3299                 ((= (length args) 1)
3300                  (nth 0 args))
3301                 ((and (= (length args) 2)
3302                       (memq old args))
3303                  (if (eq old (nth 0 args))
3304                      (nth 1 args)
3305                    (nth 0 args)))
3306                 (t
3307                  (while args
3308                    (setq current (car args)
3309                          args (cdr args))
3310                    (setq choices
3311                          (cons (cons (widget-apply current :menu-tag-get)
3312                                      current)
3313                                choices)))
3314                  (let ((val (completing-read prompt choices nil t)))
3315                    (if (stringp val)
3316                        (let ((try (try-completion val choices)))
3317                          (when (stringp try)
3318                            (setq val try))
3319                          (cdr (assoc val choices)))
3320                      nil)))))
3321     (if current
3322         (widget-prompt-value current prompt nil t)
3323       value)))
3324
3325 (define-widget 'radio 'radio-button-choice
3326   "A union of several sexp types."
3327   :tag "Choice"
3328   :format "%{%t%}:\n%v"
3329   :prompt-value 'widget-choice-prompt-value)
3330
3331 (define-widget 'repeat 'editable-list
3332   "A variable length homogeneous list."
3333   :tag "Repeat"
3334   :format "%{%t%}:\n%v%i\n")
3335
3336 (define-widget 'set 'checklist
3337   "A list of members from a fixed set."
3338   :tag "Set"
3339   :format "%{%t%}:\n%v")
3340
3341 (define-widget 'boolean 'toggle
3342   "To be nil or non-nil, that is the question."
3343   :tag "Boolean"
3344   :prompt-value 'widget-boolean-prompt-value
3345   :button-prefix 'widget-push-button-prefix
3346   :button-suffix 'widget-push-button-suffix
3347   :format "%{%t%}: %[Toggle%]  %v\n"
3348   :on "on (non-nil)"
3349   :off "off (nil)")
3350
3351 (defun widget-boolean-prompt-value (widget prompt value unbound)
3352   ;; Toggle a boolean.
3353   (y-or-n-p prompt))
3354
3355 ;;; The `color' Widget.
3356
3357 (define-widget 'color 'editable-field
3358   "Choose a color name (with sample)."
3359   :format "%t: %v (%{sample%})\n"
3360   :size 10
3361   :tag "Color"
3362   :value "black"
3363   :complete 'widget-color-complete
3364   :sample-face-get 'widget-color-sample-face-get
3365   :notify 'widget-color-notify
3366   :action 'widget-color-action)
3367
3368 (defun widget-color-complete (widget)
3369   "Complete the color in WIDGET."
3370   (let* ((prefix (buffer-substring-no-properties (widget-field-start widget)
3371                                                  (point)))
3372          (list (widget-color-choice-list))
3373          (completion (try-completion prefix list)))
3374     (cond ((eq completion t)
3375            (message "Exact match."))
3376           ((null completion)
3377            (error "Can't find completion for \"%s\"" prefix))
3378           ((not (string-equal prefix completion))
3379            (insert-and-inherit (substring completion (length prefix))))
3380           (t
3381            (message "Making completion list...")
3382            (let ((list (all-completions prefix list nil)))
3383              (with-output-to-temp-buffer "*Completions*"
3384                (display-completion-list list)))
3385            (message "Making completion list...done")))))
3386
3387 (defun widget-color-sample-face-get (widget)
3388   (let* ((value (condition-case nil
3389                     (widget-value widget)
3390                   (error (widget-get widget :value))))
3391          (symbol (intern (concat "fg:" value))))
3392     (if (string-match "XEmacs" emacs-version)
3393         (prog1 symbol
3394           (or (find-face symbol)
3395               (set-face-foreground (make-face symbol) value)))
3396       (condition-case nil
3397           (facemenu-get-face symbol)
3398         (error 'default)))))
3399
3400 (defvar widget-color-choice-list nil)
3401 ;; Variable holding the possible colors.
3402
3403 (defun widget-color-choice-list ()
3404   (unless widget-color-choice-list
3405     (setq widget-color-choice-list
3406           (if (fboundp 'read-color-completion-table)
3407               (read-color-completion-table)
3408             (mapcar '(lambda (color) (list color))
3409                     (x-defined-colors)))))
3410   widget-color-choice-list)
3411
3412 (defvar widget-color-history nil
3413   "History of entered colors")
3414
3415 (defun widget-color-action (widget &optional event)
3416   ;; Prompt for a color.
3417   (let* ((tag (widget-apply widget :menu-tag-get))
3418          (prompt (concat tag ": "))
3419          (value (widget-value widget))
3420          (start (widget-field-start widget))
3421          (pos (cond ((< (point) start)
3422                      0)
3423                     ((> (point) (+ start (length value)))
3424                      (length value))
3425                     (t
3426                      (- (point) start))))
3427          (answer (if (commandp 'read-color)
3428                      (read-color prompt)
3429                    (completing-read (concat tag ": ")
3430                                     (widget-color-choice-list)
3431                                     nil nil
3432                                     (cons value pos)
3433                                     'widget-color-history))))
3434     (unless (zerop (length answer))
3435       (widget-value-set widget answer)
3436       (widget-setup)
3437       (widget-apply widget :notify widget event))))
3438
3439 (defun widget-color-notify (widget child &optional event)
3440   "Update the sample, and notofy the parent."
3441   (overlay-put (widget-get widget :sample-overlay)
3442                'face (widget-apply widget :sample-face-get))
3443   (widget-default-notify widget child event))
3444
3445 ;;; The Help Echo
3446
3447 (defun widget-echo-help-mouse ()
3448   "Display the help message for the widget under the mouse.
3449 Enable with (run-with-idle-timer 1 t 'widget-echo-help-mouse)"
3450   (let* ((pos (mouse-position))
3451          (frame (car pos))
3452          (x (car (cdr pos)))
3453          (y (cdr (cdr pos)))
3454          (win (window-at x y frame))
3455          (where (coordinates-in-window-p (cons x y) win)))
3456     (when (consp where)
3457       (save-window-excursion
3458         (progn ; save-excursion
3459           (select-window win)
3460           (let* ((result (compute-motion (window-start win)
3461                                          '(0 . 0)
3462                                          (window-end win)
3463                                          where
3464                                          (window-width win)
3465                                          (cons (window-hscroll) 0)
3466                                          win)))
3467             (when (and (eq (nth 1 result) x)
3468                        (eq (nth 2 result) y))
3469               (widget-echo-help (nth 0 result))))))))
3470   (unless track-mouse
3471     (setq track-mouse t)
3472     (add-hook 'post-command-hook 'widget-stop-mouse-tracking)))
3473
3474 (defun widget-stop-mouse-tracking (&rest args)
3475   "Stop the mouse tracking done while idle."
3476   (remove-hook 'post-command-hook 'widget-stop-mouse-tracking)
3477   (setq track-mouse nil))
3478
3479 (defun widget-at (pos)
3480   "The button or field at POS."
3481   (or (get-char-property pos 'button)
3482       (get-char-property pos 'field)))
3483
3484 (defun widget-echo-help (pos)
3485   "Display the help echo for widget at POS."
3486   (let* ((widget (widget-at pos))
3487          (help-echo (and widget (widget-get widget :help-echo))))
3488     (cond ((stringp help-echo)
3489            (message "%s" help-echo))
3490           ((and (symbolp help-echo) (fboundp help-echo)
3491                 (stringp (setq help-echo (funcall help-echo widget))))
3492            (message "%s" help-echo)))))
3493
3494 ;;; The End:
3495
3496 (provide 'wid-edit)
3497
3498 ;; wid-edit.el ends here