lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993, 1994, 2000, 2004 Free  Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For those who are annoyed by the mouse pointer obscuring text,
  28 ;; this mode moves the mouse pointer - either just a little out of
  29 ;; the way, or all the way to the corner of the frame.
  30 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  31 ;; To set up permanently, put the following in your .emacs:
  32 ;;
  33 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  34 ;;
  35 ;; Other legitimate alternatives include
  36 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  37 ;; They do somewhat different things.
  38 ;; See the documentation for function `mouse-avoidance-mode' for
  39 ;; details of the different modes.
  40 ;;
  41 ;; For added silliness, make the animatee animate...
  42 ;; put something similar to the following into your .emacs:
  43 ;;
  44 ;; (if (eq window-system 'x)
  45 ;;     (mouse-avoidance-set-pointer-shape
  46 ;;           (eval (nth (random 4)
  47 ;;                      '(x-pointer-man x-pointer-spider
  48 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  49 ;;
  50 ;; For completely random pointer shape, replace the setq above with:
  51 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  52 ;;
  53 ;; Bugs / Warnings / To-Do:
  54 ;;
  55 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  56 ;;   be too bad, and on my workstation even "animate" is reasonable.
  57 ;;
  58 ;; - It ought to find out where any overlapping frames are and avoid them,
  59 ;;   rather than always raising the frame.
  60
  61 ;; Credits:
  62 ;; This code was helped by all those who contributed suggestions,
  63 ;;   fixes, and additions
  64 ;; Joe Harrington (and his advisor), for the original inspiration.
  65 ;; Ken Manheimer, for dreaming up the Protean mode.
  66 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  67 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  68 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  69
  70 ;;; Code:
  71
  72 (provide 'avoid)
  73
  74 (defgroup avoid nil
  75   "Make mouse pointer stay out of the way of editing."
  76   :prefix "mouse-avoidance-"
  77   :group 'mouse)
  78
  79 ;;;###autoload
  80 (defcustom mouse-avoidance-mode nil
  81   "Activate mouse avoidance mode.
  82 See function `mouse-avoidance-mode' for possible values.
  83 Setting this variable directly does not take effect;
  84 use either \\[customize] or the function `mouse-avoidance-mode'."
  85   :set (lambda (symbol value)
  86          ;; 'none below prevents toggling when value is nil.
  87          (mouse-avoidance-mode (or value 'none)))
  88   :initialize 'custom-initialize-default
  89   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  90                  (const animate) (const exile) (const proteus)
  91                  )
  92   :group 'avoid
  93   :require 'avoid
  94   :version "20.3")
  95
  96
  97 (defcustom mouse-avoidance-nudge-dist 15
  98   "*Average distance that mouse will be moved when approached by cursor.
  99 Only applies in Mouse-Avoidance mode `jump' and its derivatives.
 100 For best results make this larger than `mouse-avoidance-threshold'."
 101   :type 'integer
 102   :group 'avoid)
 103
 104 (defcustom mouse-avoidance-nudge-var 10
 105   "*Variability of `mouse-avoidance-nudge-dist' (which see)."
 106   :type 'integer
 107   :group 'avoid)
 108
 109 (defcustom mouse-avoidance-animation-delay .01
 110   "Delay between animation steps, in seconds."
 111   :type 'number
 112   :group 'avoid)
 113
 114 (defcustom mouse-avoidance-threshold 5
 115   "*Mouse-pointer's flight distance.
 116 If the cursor gets closer than this, the mouse pointer will move away.
 117 Only applies in mouse-avoidance-modes `animate' and `jump'."
 118   :type 'integer
 119   :group 'avoid)
 120
 121 ;; Internal variables
 122 (defvar mouse-avoidance-state nil)
 123 (defvar mouse-avoidance-pointer-shapes nil)
 124 (defvar mouse-avoidance-n-pointer-shapes 0)
 125 (defvar mouse-avoidance-old-pointer-shape nil)
 126
 127 ;; This timer is used to run something when Emacs is idle.
 128 (defvar mouse-avoidance-timer nil)
 129
 130 ;;; Functions:
 131
 132 (defsubst mouse-avoidance-set-pointer-shape (shape)
 133   "Set the shape of the mouse pointer to SHAPE."
 134   (when (boundp 'x-pointer-shape)
 135     (setq x-pointer-shape shape)
 136     (set-mouse-color nil)))
 137
 138 (defun mouse-avoidance-point-position ()
 139   "Return the position of point as (FRAME X . Y).
 140 Analogous to `mouse-position'."
 141   (let* ((w (selected-window))
 142          (edges (window-inside-edges w))
 143          (list
 144           (compute-motion (max (window-start w) (point-min))   ; start pos
 145                           ;; window-start can be < point-min if the
 146                           ;; latter has changed since the last redisplay
 147                           '(0 . 0)                             ; start XY
 148                           (point)                              ; stop pos
 149                           nil                                  ; stop XY: none
 150                           nil                                  ; width
 151                           (cons (window-hscroll w) 0)          ; 0 may not be right?
 152                           (selected-window))))
 153     ;; compute-motion returns (pos HPOS VPOS prevhpos contin)
 154     ;; we want:               (frame hpos . vpos)
 155     (cons (selected-frame)
 156           (cons (+ (car edges)       (car (cdr list)))
 157                 (+ (car (cdr edges)) (car (cdr (cdr list))))))))
 158
 159 ;(defun mouse-avoidance-point-position-test ()
 160 ;  (interactive)
 161 ;  (message (format "point=%s mouse=%s"
 162 ;                  (cdr (mouse-avoidance-point-position))
 163 ;                  (cdr (mouse-position)))))
 164
 165 (defun mouse-avoidance-set-mouse-position (pos)
 166   ;; Carefully set mouse position to given position (X . Y)
 167   ;; Ideally, should check if X,Y is in the current frame, and if not,
 168   ;; leave the mouse where it was.  However, this is currently
 169   ;; difficult to do, so we just raise the frame to avoid frame switches.
 170   ;; Returns t if it moved the mouse.
 171   (let ((f (selected-frame)))
 172     (raise-frame f)
 173     (set-mouse-position f (car pos) (cdr pos))
 174     t))
 175
 176 (defun mouse-avoidance-too-close-p (mouse)
 177   "Return t if mouse pointer and point cursor are too close.
 178 MOUSE is the current mouse position as returned by `mouse-position'.
 179 Acceptable distance is defined by `mouse-avoidance-threshold'."
 180   (let* ((frame (car mouse))
 181          (mouse-y (cdr (cdr mouse)))
 182          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 183     (or tool-bar-lines
 184         (setq tool-bar-lines 0))
 185     (if (and mouse-y (< mouse-y tool-bar-lines))
 186         nil
 187       (let ((point (mouse-avoidance-point-position))
 188             (mouse-x (car (cdr mouse))))
 189         (and (eq frame (car point))
 190              (not (null mouse-x))
 191              (< (abs (- mouse-x (car (cdr point))))
 192                 mouse-avoidance-threshold)
 193              (< (abs (- mouse-y (cdr (cdr point))))
 194                 mouse-avoidance-threshold))))))
 195
 196 (defun mouse-avoidance-banish-destination ()
 197   "The position to which Mouse-Avoidance mode `banish' moves the mouse.
 198 You can redefine this if you want the mouse banished to a different corner."
 199   (let* ((pos (window-edges)))
 200     (cons (- (nth 2 pos) 2)
 201           (nth 1 pos))))
 202
 203 (defun mouse-avoidance-banish-mouse ()
 204   ;; Put the mouse pointer in the upper-right corner of the current frame.
 205   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 206
 207 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 208   ;; Decide how far to move in either dimension.
 209   ;; Args are the CURRENT location, the desired DELTA for
 210   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 211   ;; in distance allowed, and the MIN and MAX possible window positions.
 212   ;; Returns something as close to DELTA as possible within the constraints.
 213   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 214         (R1                  (+ (- dist)    var ))
 215         (L2                  (+    dist  (- var)))
 216         (R2 (min (- max cur) (+    dist     var))))
 217     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 218     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 219     (cond ((and L1 (< delta L1)) L1)
 220           ((and R1 (< delta R1)) delta)
 221           ((and R1 (< delta 0)) R1)
 222           ((and L2 (< delta L2)) L2)
 223           ((and R2 (< delta R2)) delta)
 224           (R2)
 225           ((or R1 L2))
 226           (t 0))))
 227
 228 (defun mouse-avoidance-nudge-mouse ()
 229   ;; Push the mouse a little way away, possibly animating the move.
 230   ;; For these modes, state keeps track of the total offset that we've
 231   ;; accumulated, and tries to keep it close to zero.
 232   (let* ((cur (mouse-position))
 233          (cur-frame (car cur))
 234          (cur-pos (cdr cur))
 235          (pos (window-edges))
 236          (wleft (pop pos))
 237          (wtop (pop pos))
 238          (wright (pop pos))
 239          (wbot (pop pos))
 240          (deltax (mouse-avoidance-delta
 241                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 242                                    (car mouse-avoidance-state))
 243                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 244                   wleft (1- wright)))
 245          (deltay (mouse-avoidance-delta
 246                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 247                                    (cdr mouse-avoidance-state))
 248                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 249                   wtop (1- wbot))))
 250     (setq mouse-avoidance-state
 251           (cons (+ (car mouse-avoidance-state) deltax)
 252                 (+ (cdr mouse-avoidance-state) deltay)))
 253     (if (or (eq mouse-avoidance-mode 'animate)
 254             (eq mouse-avoidance-mode 'proteus))
 255         (let ((i 0.0))
 256           (while (<= i 1)
 257             (mouse-avoidance-set-mouse-position
 258              (cons (+ (car cur-pos) (round (* i deltax)))
 259                    (+ (cdr cur-pos) (round (* i deltay)))))
 260             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 261             (if (eq mouse-avoidance-mode 'proteus)
 262                 (mouse-avoidance-set-pointer-shape
 263                  (mouse-avoidance-random-shape)))
 264             (sit-for mouse-avoidance-animation-delay)))
 265       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 266                                                 (+ (cdr (cdr cur)) deltay))))))
 267
 268 (defun mouse-avoidance-random-shape ()
 269   "Return a random cursor shape.
 270 This assumes that any variable whose name begins with x-pointer- and
 271 has an integer value is a valid cursor shape.  You might want to
 272 redefine this function to suit your own tastes."
 273   (if (null mouse-avoidance-pointer-shapes)
 274       (progn
 275         (setq mouse-avoidance-pointer-shapes
 276               (mapcar (lambda (x) (symbol-value (intern x)))
 277                       (all-completions "x-pointer-" obarray
 278                                        (lambda (x)
 279                                           (and (boundp x)
 280                                                (integerp (symbol-value x)))))))
 281         (setq mouse-avoidance-n-pointer-shapes
 282               (length mouse-avoidance-pointer-shapes))))
 283   (nth (random mouse-avoidance-n-pointer-shapes)
 284        mouse-avoidance-pointer-shapes))
 285
 286 (defun mouse-avoidance-ignore-p ()
 287   (let ((mp (mouse-position)))
 288     (or executing-kbd-macro            ; don't check inside macro
 289         (null (cadr mp))               ; don't move unless in an Emacs frame
 290         (not (eq (car mp) (selected-frame)))
 291         ;; Don't do anything if last event was a mouse event.
 292         ;; FIXME: this code fails in the case where the mouse was moved
 293         ;; since the last key-press but without generating any event.
 294         (and (consp last-input-event)
 295              (symbolp (car last-input-event))
 296              (let ((modifiers (event-modifiers (car last-input-event))))
 297                (or (memq (car last-input-event)
 298                          '(mouse-movement scroll-bar-movement
 299                            select-window switch-frame))
 300                    (memq 'click modifiers)
 301                    (memq 'double modifiers)
 302                    (memq 'triple modifiers)
 303                    (memq 'drag modifiers)
 304                    (memq 'down modifiers)))))))
 305
 306 (defun mouse-avoidance-banish-hook ()
 307   (if (not (mouse-avoidance-ignore-p))
 308       (mouse-avoidance-banish-mouse)))
 309
 310 (defun mouse-avoidance-exile-hook ()
 311   ;; For exile mode, the state is nil when the mouse is in its normal
 312   ;; position, and set to the old mouse-position when the mouse is in exile.
 313   (if (not (mouse-avoidance-ignore-p))
 314       (let ((mp (mouse-position)))
 315         (cond ((and (not mouse-avoidance-state)
 316                     (mouse-avoidance-too-close-p mp))
 317                (setq mouse-avoidance-state mp)
 318                (mouse-avoidance-banish-mouse))
 319               ((and mouse-avoidance-state
 320                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 321                (if (and (eq (car mp) (selected-frame))
 322                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 323                    (mouse-avoidance-set-mouse-position
 324                     ;; move back only if user has not moved mouse
 325                     (cdr mouse-avoidance-state)))
 326                ;; but clear state anyway, to be ready for another move
 327                (setq mouse-avoidance-state nil))))))
 328
 329 (defun mouse-avoidance-fancy-hook ()
 330   ;; Used for the "fancy" modes, ie jump et al.
 331   (if (and (not (mouse-avoidance-ignore-p))
 332            (mouse-avoidance-too-close-p (mouse-position)))
 333       (let ((old-pos (mouse-position)))
 334         (mouse-avoidance-nudge-mouse)
 335         (if (not (eq (selected-frame) (car old-pos)))
 336             ;; This should never happen.
 337             (apply 'set-mouse-position old-pos)))))
 338
 339 ;;;###autoload
 340 (defun mouse-avoidance-mode (&optional mode)
 341   "Set cursor avoidance mode to MODE.
 342 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 343 `cat-and-mouse', `proteus', or `none'.
 344
 345 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 346 modes.  Positive numbers and symbols other than the above are treated
 347 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 348
 349 Effects of the different modes:
 350  * banish: Move the mouse to the upper-right corner on any keypress.
 351  * exile: Move the mouse to the corner only if the cursor gets too close,
 352      and allow it to return once the cursor is out of the way.
 353  * jump: If the cursor gets too close to the mouse, displace the mouse
 354      a random distance & direction.
 355  * animate: As `jump', but shows steps along the way for illusion of motion.
 356  * cat-and-mouse: Same as `animate'.
 357  * proteus: As `animate', but changes the shape of the mouse pointer too.
 358
 359 Whenever the mouse is moved, the frame is also raised.
 360
 361 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 362 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 363 definition of \"random distance\".)"
 364   (interactive
 365    (list (intern (completing-read
 366                   "Select cursor avoidance technique (SPACE for list): "
 367                   '(("banish") ("exile") ("jump") ("animate")
 368                     ("cat-and-mouse") ("proteus") ("none"))
 369                   nil t))))
 370   (if (eq mode 'cat-and-mouse)
 371       (setq mode 'animate))
 372   (if mouse-avoidance-timer
 373       (cancel-timer mouse-avoidance-timer))
 374   (setq mouse-avoidance-timer nil)
 375
 376   ;; Restore pointer shape if necessary
 377   (if (eq mouse-avoidance-mode 'proteus)
 378       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 379
 380   ;; Do additional setup depending on version of mode requested
 381   (cond ((eq mode 'none)
 382          (setq mouse-avoidance-mode nil))
 383         ((or (eq mode 'jump)
 384              (eq mode 'animate)
 385              (eq mode 'proteus))
 386          (setq mouse-avoidance-timer
 387                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy-hook))
 388          (setq mouse-avoidance-mode mode
 389                mouse-avoidance-state (cons 0 0)
 390                mouse-avoidance-old-pointer-shape
 391                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 392         ((eq mode 'exile)
 393          (setq mouse-avoidance-timer
 394                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile-hook))
 395          (setq mouse-avoidance-mode mode
 396                mouse-avoidance-state nil))
 397         ((or (eq mode 'banish)
 398              (eq mode t)
 399              (and (null mode) (null mouse-avoidance-mode))
 400              (and mode (> (prefix-numeric-value mode) 0)))
 401          (setq mouse-avoidance-timer
 402                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish-hook))
 403          (setq mouse-avoidance-mode 'banish))
 404         (t (setq mouse-avoidance-mode nil)))
 405   (force-mode-line-update))
 406
 407 ;; Most people who use avoid mode leave it on all the time, so it's not
 408 ;; very informative to announce it in the mode line.
 409 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 410 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 411 ;;                               minor-mode-alist)))
 412
 413 ;; Needed for custom.
 414 (if mouse-avoidance-mode
 415     (mouse-avoidance-mode mouse-avoidance-mode))
 416
 417 ;; arch-tag: 64ad4ef8-a870-4183-8d96-3aa93b7a6800
 418 ;;; avoid.el ends here