lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package is a major mode for editing nroff source code.  It knows
  28 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  29 ;; and indent paragraphs properly in their presence.  It also includes
  30 ;; a command to count text lines (excluding nroff constructs), a command
  31 ;; to center a line, and movement commands that know how to skip macros.
  32
  33 ;; Paragraph filling and line-counting currently don't respect comments,
  34 ;; as they should.
  35
  36 ;;; Code:
  37
  38 (defgroup nroff nil
  39   "Nroff mode."
  40   :group 'wp
  41   :prefix "nroff-")
  42
  43 (defvar nroff-mode-abbrev-table nil
  44   "Abbrev table used while in nroff mode.")
  45 (define-abbrev-table 'nroff-mode-abbrev-table ())
  46
  47 (defcustom nroff-electric-mode nil
  48   "*Non-nil means automatically closing requests when you insert an open."
  49   :group 'nroff
  50   :type 'boolean)
  51
  52 (defvar nroff-mode-map nil
  53      "Major mode keymap for nroff mode.")
  54 (if (not nroff-mode-map)
  55     (progn
  56       (setq nroff-mode-map (make-sparse-keymap))
  57       (define-key nroff-mode-map "\t"  'tab-to-tab-stop)
  58       (define-key nroff-mode-map "\es" 'center-line)
  59       (define-key nroff-mode-map "\e?" 'count-text-lines)
  60       (define-key nroff-mode-map "\n"  'electric-nroff-newline)
  61       (define-key nroff-mode-map "\en" 'forward-text-line)
  62       (define-key nroff-mode-map "\ep" 'backward-text-line)))
  63
  64 (defvar nroff-mode-syntax-table nil
  65   "Syntax table used while in nroff mode.")
  66
  67 (defcustom nroff-font-lock-keywords
  68   (list
  69    ;; Directives are . or ' at start of line, followed by
  70    ;; optional whitespace, then command (which my be longer than
  71    ;; 2 characters in groff).  Perhaps the arguments should be
  72    ;; fontified as well.
  73    "^[.']\\s-*\\sw+"
  74    ;; There are numerous groff escapes; the following get things
  75    ;; like \-, \(em (standard troff) and \f[bar] (groff
  76    ;; variants).  This won't currently do groff's \A'foo' and
  77    ;; the like properly.  One might expect it to highlight an escape's
  78    ;; arguments in common cases, like \f.
  79    (concat "\\\\"                     ; backslash
  80          "\\("                        ; followed by various possibilities
  81          (mapconcat 'identity
  82                     '("[f*n]*\\[.+]"  ; some groff extensions
  83                       "(.."           ; two chars after (
  84                       "[^(\"]"        ; single char escape
  85                       ) "\\|")
  86          "\\)")
  87    )
  88   "Font-lock highlighting control in nroff-mode."
  89   :group 'nroff
  90   :type '(repeat regexp))
  91
  92 ;;;###autoload
  93 (defun nroff-mode ()
  94   "Major mode for editing text intended for nroff to format.
  95 \\{nroff-mode-map}
  96 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
  97 Also, try `nroff-electric-mode', for automatically inserting
  98 closing requests for requests that are used in matched pairs."
  99   (interactive)
 100   (kill-all-local-variables)
 101   (use-local-map nroff-mode-map)
 102   (setq mode-name "Nroff")
 103   (setq major-mode 'nroff-mode)
 104   (if nroff-mode-syntax-table
 105       ()
 106     (setq nroff-mode-syntax-table (copy-syntax-table text-mode-syntax-table))
 107     ;; " isn't given string quote syntax in text-mode but it
 108     ;; (arguably) should be for use round nroff arguments (with ` and
 109     ;; ' used otherwise).
 110     (modify-syntax-entry ?\" "\"  2" nroff-mode-syntax-table)
 111     ;; Comments are delimited by \" and newline.
 112     (modify-syntax-entry ?\\ "\\  1" nroff-mode-syntax-table)
 113     (modify-syntax-entry ?\n ">  1" nroff-mode-syntax-table))
 114   (set-syntax-table nroff-mode-syntax-table)
 115   (make-local-variable 'font-lock-defaults)
 116   (setq font-lock-defaults '(nroff-font-lock-keywords nil t))
 117   (setq local-abbrev-table nroff-mode-abbrev-table)
 118   (make-local-variable 'nroff-electric-mode)
 119   (setq nroff-electric-mode nil)
 120   (make-local-variable 'outline-regexp)
 121   (setq outline-regexp "\\.H[ ]+[1-7]+ ")
 122   (make-local-variable 'outline-level)
 123   (setq outline-level 'nroff-outline-level)
 124   ;; now define a bunch of variables for use by commands in this mode
 125   (make-local-variable 'page-delimiter)
 126   (setq page-delimiter "^\\.\\(bp\\|SK\\|OP\\)")
 127   (make-local-variable 'paragraph-start)
 128   (setq paragraph-start (concat "[.']\\|" paragraph-start))
 129   (make-local-variable 'paragraph-separate)
 130   (setq paragraph-separate (concat "[.']\\|" paragraph-separate))
 131   ;; comment syntax added by mit-erl!gildea 18 Apr 86
 132   (make-local-variable 'comment-start)
 133   (setq comment-start "\\\" ")
 134   (make-local-variable 'comment-start-skip)
 135   (setq comment-start-skip "\\\\\"[ \t]*")
 136   (make-local-variable 'comment-column)
 137   (setq comment-column 24)
 138   (make-local-variable 'comment-indent-function)
 139   (setq comment-indent-function 'nroff-comment-indent)
 140   (run-hooks 'text-mode-hook 'nroff-mode-hook))
 141
 142 (defun nroff-outline-level ()
 143   (save-excursion
 144     (looking-at outline-regexp)
 145     (skip-chars-forward ".H ")
 146     (string-to-int (buffer-substring (point) (+ 1 (point))))))
 147
 148 ;;; Compute how much to indent a comment in nroff/troff source.
 149 ;;; By mit-erl!gildea April 86
 150 (defun nroff-comment-indent ()
 151   "Compute indent for an nroff/troff comment.
 152 Puts a full-stop before comments on a line by themselves."
 153   (let ((pt (point)))
 154     (unwind-protect
 155         (progn
 156           (skip-chars-backward " \t")
 157           (if (bolp)
 158               (progn
 159                 (setq pt (1+ pt))
 160                 (insert ?.)
 161                 1)
 162             (if (save-excursion
 163                   (backward-char 1)
 164                   (looking-at "^[.']"))
 165                 1
 166               (max comment-column
 167                    (* 8 (/ (+ (current-column)
 168                               9) 8)))))) ; add 9 to ensure at least two blanks
 169       (goto-char pt))))
 170
 171 (defun count-text-lines (start end &optional print)
 172   "Count lines in region, except for nroff request lines.
 173 All lines not starting with a period are counted up.
 174 Interactively, print result in echo area.
 175 Noninteractively, return number of non-request lines from START to END."
 176   (interactive "r\np")
 177   (if print
 178       (message "Region has %d text lines" (count-text-lines start end))
 179     (save-excursion
 180       (save-restriction
 181         (narrow-to-region start end)
 182         (goto-char (point-min))
 183         (- (buffer-size) (forward-text-line (buffer-size)))))))
 184
 185 (defun forward-text-line (&optional cnt)
 186   "Go forward one nroff text line, skipping lines of nroff requests.
 187 An argument is a repeat count; if negative, move backward."
 188   (interactive "p")
 189   (if (not cnt) (setq cnt 1))
 190   (while (and (> cnt 0) (not (eobp)))
 191     (forward-line 1)
 192     (while (and (not (eobp)) (looking-at "[.']."))
 193       (forward-line 1))
 194     (setq cnt (- cnt 1)))
 195   (while (and (< cnt 0) (not (bobp)))
 196     (forward-line -1)
 197     (while (and (not (bobp))
 198                 (looking-at "[.']."))
 199       (forward-line -1))
 200     (setq cnt (+ cnt 1)))
 201   cnt)
 202
 203 (defun backward-text-line (&optional cnt)
 204   "Go backward one nroff text line, skipping lines of nroff requests.
 205 An argument is a repeat count; negative means move forward."
 206   (interactive "p")
 207   (forward-text-line (- cnt)))
 208
 209 (defconst nroff-brace-table
 210   '((".(b" . ".)b")
 211     (".(l" . ".)l")
 212     (".(q" . ".)q")
 213     (".(c" . ".)c")
 214     (".(x" . ".)x")
 215     (".(z" . ".)z")
 216     (".(d" . ".)d")
 217     (".(f" . ".)f")
 218     (".LG" . ".NL")
 219     (".SM" . ".NL")
 220     (".LD" . ".DE")
 221     (".CD" . ".DE")
 222     (".BD" . ".DE")
 223     (".DS" . ".DE")
 224     (".DF" . ".DE")
 225     (".FS" . ".FE")
 226     (".KS" . ".KE")
 227     (".KF" . ".KE")
 228     (".LB" . ".LE")
 229     (".AL" . ".LE")
 230     (".BL" . ".LE")
 231     (".DL" . ".LE")
 232     (".ML" . ".LE")
 233     (".RL" . ".LE")
 234     (".VL" . ".LE")
 235     (".RS" . ".RE")
 236     (".TS" . ".TE")
 237     (".EQ" . ".EN")
 238     (".PS" . ".PE")
 239     (".BS" . ".BE")
 240     (".G1" . ".G2")                     ; grap
 241     (".na" . ".ad b")
 242     (".nf" . ".fi")
 243     (".de" . "..")))
 244
 245 (defun electric-nroff-newline (arg)
 246   "Insert newline for nroff mode; special if electric-nroff mode.
 247 In `electric-nroff-mode', if ending a line containing an nroff opening request,
 248 automatically inserts the matching closing request after point."
 249   (interactive "P")
 250   (let ((completion (save-excursion
 251                       (beginning-of-line)
 252                       (and (null arg)
 253                            nroff-electric-mode
 254                            (<= (point) (- (point-max) 3))
 255                            (cdr (assoc (buffer-substring (point)
 256                                                          (+ 3 (point)))
 257                                        nroff-brace-table)))))
 258         (needs-nl (not (looking-at "[ \t]*$"))))
 259     (if (null completion)
 260         (newline (prefix-numeric-value arg))
 261       (save-excursion
 262         (insert "\n\n" completion)
 263         (if needs-nl (insert "\n")))
 264       (forward-char 1))))
 265
 266 (defun electric-nroff-mode (&optional arg)
 267   "Toggle `nroff-electric-newline' minor mode.
 268 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 269 beginning of the line, and insert the matching closing request if necessary.
 270 This command toggles that mode (off->on, on->off), with an argument,
 271 turns it on iff arg is positive, otherwise off."
 272   (interactive "P")
 273   (or (eq major-mode 'nroff-mode) (error "Must be in nroff mode"))
 274   (or (assq 'nroff-electric-mode minor-mode-alist)
 275       (setq minor-mode-alist (append minor-mode-alist
 276                                      (list '(nroff-electric-mode
 277                                              " Electric")))))
 278   (setq nroff-electric-mode
 279         (cond ((null arg) (null nroff-electric-mode))
 280               (t (> (prefix-numeric-value arg) 0)))))
 281
 282 (provide 'nroff-mode)
 283
 284 ;;; nroff-mode.el ends here