lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs
   2
   3 ;; Copyright (C) 1985, 86, 87, 92, 94, 96, 1997, 2000, 2001, 2002
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package supplies the string and regular-expression replace functions
  28 ;; documented in the Emacs user's manual.
  29
  30 ;;; Code:
  31
  32 (defcustom case-replace t
  33   "*Non-nil means `query-replace' should preserve case in replacements."
  34   :type 'boolean
  35   :group 'matching)
  36
  37 (defvar query-replace-history nil)
  38
  39 (defvar query-replace-interactive nil
  40   "Non-nil means `query-replace' uses the last search string.
  41 That becomes the \"string to replace\".")
  42
  43 (defcustom query-replace-from-history-variable 'query-replace-history
  44   "History list to use for the FROM argument of `query-replace' commands.
  45 The value of this variable should be a symbol; that symbol
  46 is used as a variable to hold a history list for the strings
  47 or patterns to be replaced."
  48   :group 'matching
  49   :type 'symbol
  50   :version "20.3")
  51
  52 (defcustom query-replace-to-history-variable 'query-replace-history
  53   "History list to use for the TO argument of `query-replace' commands.
  54 The value of this variable should be a symbol; that symbol
  55 is used as a variable to hold a history list for replacement
  56 strings or patterns."
  57   :group 'matching
  58   :type 'symbol
  59   :version "20.3")
  60
  61 (defcustom query-replace-skip-read-only nil
  62   "*Non-nil means `query-replace' and friends ignore read-only matches."
  63   :type 'boolean
  64   :group 'matching
  65   :version "21.4")
  66
  67 (defun query-replace-read-args (string regexp-flag &optional noerror)
  68   (unless noerror
  69     (barf-if-buffer-read-only))
  70   (let (from to)
  71     (if query-replace-interactive
  72         (setq from (car (if regexp-flag regexp-search-ring search-ring)))
  73       (setq from (read-from-minibuffer (format "%s: " string)
  74                                        nil nil nil
  75                                        query-replace-from-history-variable
  76                                        nil t))
  77       ;; Warn if user types \n or \t, but don't reject the input.
  78       (if (string-match "\\\\[nt]" from)
  79           (let ((match (match-string 0 from)))
  80             (cond
  81              ((string= match "\\n")
  82               (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
  83              ((string= match "\\t")
  84               (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
  85             (sit-for 2))))
  86
  87     (setq to (read-from-minibuffer (format "%s %s with: " string from)
  88                                    nil nil nil
  89                                    query-replace-to-history-variable from t))
  90     (if (and transient-mark-mode mark-active)
  91         (list from to current-prefix-arg (region-beginning) (region-end))
  92       (list from to current-prefix-arg nil nil))))
  93
  94 (defun query-replace (from-string to-string &optional delimited start end)
  95   "Replace some occurrences of FROM-STRING with TO-STRING.
  96 As each match is found, the user must type a character saying
  97 what to do with it.  For directions, type \\[help-command] at that time.
  98
  99 In Transient Mark mode, if the mark is active, operate on the contents
 100 of the region.  Otherwise, operate from point to the end of the buffer.
 101
 102 If `query-replace-interactive' is non-nil, the last incremental search
 103 string is used as FROM-STRING--you don't have to specify it with the
 104 minibuffer.
 105
 106 Replacement transfers the case of the old text to the new text,
 107 if `case-replace' and `case-fold-search'
 108 are non-nil and FROM-STRING has no uppercase letters.
 109 \(Preserving case means that if the string matched is all caps, or capitalized,
 110 then its replacement is upcased or capitalized.)
 111
 112 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 113 only matches surrounded by word boundaries.
 114 Fourth and fifth arg START and END specify the region to operate on.
 115
 116 To customize possible responses, change the \"bindings\" in `query-replace-map'."
 117   (interactive (query-replace-read-args "Query replace" nil))
 118   (perform-replace from-string to-string t nil delimited nil nil start end))
 119
 120 (define-key esc-map "%" 'query-replace)
 121
 122 (defun query-replace-regexp (regexp to-string &optional delimited start end)
 123   "Replace some things after point matching REGEXP with TO-STRING.
 124 As each match is found, the user must type a character saying
 125 what to do with it.  For directions, type \\[help-command] at that time.
 126
 127 In Transient Mark mode, if the mark is active, operate on the contents
 128 of the region.  Otherwise, operate from point to the end of the buffer.
 129
 130 If `query-replace-interactive' is non-nil, the last incremental search
 131 regexp is used as REGEXP--you don't have to specify it with the
 132 minibuffer.
 133
 134 Preserves case in each replacement if `case-replace' and `case-fold-search'
 135 are non-nil and REGEXP has no uppercase letters.
 136
 137 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 138 only matches surrounded by word boundaries.
 139 Fourth and fifth arg START and END specify the region to operate on.
 140
 141 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 142 and `\\=\\N' (where N is a digit) stands for
 143  whatever what matched the Nth `\\(...\\)' in REGEXP."
 144   (interactive (query-replace-read-args "Query replace regexp" t))
 145   (perform-replace regexp to-string t t delimited nil nil start end))
 146 (define-key esc-map [?\C-%] 'query-replace-regexp)
 147
 148 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
 149   "Replace some things after point matching REGEXP with the result of TO-EXPR.
 150 As each match is found, the user must type a character saying
 151 what to do with it.  For directions, type \\[help-command] at that time.
 152
 153 TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
 154 reference `replace-count' to get the number of replacements already made.
 155 If the result of TO-EXPR is not a string, it is converted to one using
 156 `prin1-to-string' with the NOESCAPE argument (which see).
 157
 158 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
 159 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
 160 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
 161 Use `\\#&' or `\\#N' if you want a number instead of a string.
 162
 163 In Transient Mark mode, if the mark is active, operate on the contents
 164 of the region.  Otherwise, operate from point to the end of the buffer.
 165
 166 If `query-replace-interactive' is non-nil, the last incremental search
 167 regexp is used as REGEXP--you don't have to specify it with the
 168 minibuffer.
 169
 170 Preserves case in each replacement if `case-replace' and `case-fold-search'
 171 are non-nil and REGEXP has no uppercase letters.
 172
 173 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 174 only matches that are surrounded by word boundaries.
 175 Fourth and fifth arg START and END specify the region to operate on."
 176   (interactive
 177    (let (from to start end)
 178      (when (and transient-mark-mode mark-active)
 179        (setq start (region-beginning)
 180              end (region-end)))
 181      (if query-replace-interactive
 182          (setq from (car regexp-search-ring))
 183        (setq from (read-from-minibuffer "Query replace regexp: "
 184                                         nil nil nil
 185                                         query-replace-from-history-variable
 186                                         nil t)))
 187      (setq to (list (read-from-minibuffer
 188                      (format "Query replace regexp %s with eval: " from)
 189                      nil nil t query-replace-to-history-variable from t)))
 190      ;; We make TO a list because replace-match-string-symbols requires one,
 191      ;; and the user might enter a single token.
 192      (replace-match-string-symbols to)
 193      (list from (car to) current-prefix-arg start end)))
 194   (perform-replace regexp (cons 'replace-eval-replacement to-expr)
 195                    t t delimited nil nil start end))
 196
 197 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
 198   "Replace some matches for REGEXP with various strings, in rotation.
 199 The second argument TO-STRINGS contains the replacement strings,
 200 separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
 201 if non-nil, means replace only matches surrounded by word boundaries.
 202 This command works like `query-replace-regexp' except that each
 203 successive replacement uses the next successive replacement string,
 204 wrapping around from the last such string to the first.
 205
 206 In Transient Mark mode, if the mark is active, operate on the contents
 207 of the region.  Otherwise, operate from point to the end of the buffer.
 208
 209 Non-interactively, TO-STRINGS may be a list of replacement strings.
 210
 211 If `query-replace-interactive' is non-nil, the last incremental search
 212 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 213
 214 A prefix argument N says to use each replacement string N times
 215 before rotating to the next.
 216 Fourth and fifth arg START and END specify the region to operate on."
 217   (interactive
 218    (let (from to start end)
 219      (when (and transient-mark-mode mark-active)
 220        (setq start (region-beginning)
 221              end (region-end)))
 222      (setq from (if query-replace-interactive
 223                     (car regexp-search-ring)
 224                   (read-from-minibuffer "Map query replace (regexp): "
 225                                         nil nil nil
 226                                         'query-replace-history nil t)))
 227      (setq to (read-from-minibuffer
 228                (format "Query replace %s with (space-separated strings): "
 229                        from)
 230                nil nil nil
 231                'query-replace-history from t))
 232      (list from to start end current-prefix-arg)))
 233   (let (replacements)
 234     (if (listp to-strings)
 235         (setq replacements to-strings)
 236       (while (/= (length to-strings) 0)
 237         (if (string-match " " to-strings)
 238             (setq replacements
 239                   (append replacements
 240                           (list (substring to-strings 0
 241                                            (string-match " " to-strings))))
 242                   to-strings (substring to-strings
 243                                        (1+ (string-match " " to-strings))))
 244           (setq replacements (append replacements (list to-strings))
 245                 to-strings ""))))
 246     (perform-replace regexp replacements t t nil n nil start end)))
 247
 248 (defun replace-string (from-string to-string &optional delimited start end)
 249   "Replace occurrences of FROM-STRING with TO-STRING.
 250 Preserve case in each match if `case-replace' and `case-fold-search'
 251 are non-nil and FROM-STRING has no uppercase letters.
 252 \(Preserving case means that if the string matched is all caps, or capitalized,
 253 then its replacement is upcased or capitalized.)
 254
 255 In Transient Mark mode, if the mark is active, operate on the contents
 256 of the region.  Otherwise, operate from point to the end of the buffer.
 257
 258 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 259 only matches surrounded by word boundaries.
 260 Fourth and fifth arg START and END specify the region to operate on.
 261
 262 If `query-replace-interactive' is non-nil, the last incremental search
 263 string is used as FROM-STRING--you don't have to specify it with the
 264 minibuffer.
 265
 266 This function is usually the wrong thing to use in a Lisp program.
 267 What you probably want is a loop like this:
 268   (while (search-forward FROM-STRING nil t)
 269     (replace-match TO-STRING nil t))
 270 which will run faster and will not set the mark or print anything.
 271 \(You may need a more complex loop if FROM-STRING can match the null string
 272 and TO-STRING is also null.)"
 273   (interactive (query-replace-read-args "Replace string" nil))
 274   (perform-replace from-string to-string nil nil delimited nil nil start end))
 275
 276 (defun replace-regexp (regexp to-string &optional delimited start end)
 277   "Replace things after point matching REGEXP with TO-STRING.
 278 Preserve case in each match if `case-replace' and `case-fold-search'
 279 are non-nil and REGEXP has no uppercase letters.
 280
 281 In Transient Mark mode, if the mark is active, operate on the contents
 282 of the region.  Otherwise, operate from point to the end of the buffer.
 283
 284 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 285 only matches surrounded by word boundaries.
 286 Fourth and fifth arg START and END specify the region to operate on.
 287
 288 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 289 and `\\=\\N' (where N is a digit) stands for
 290  whatever what matched the Nth `\\(...\\)' in REGEXP.
 291
 292 If `query-replace-interactive' is non-nil, the last incremental search
 293 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 294
 295 This function is usually the wrong thing to use in a Lisp program.
 296 What you probably want is a loop like this:
 297   (while (re-search-forward REGEXP nil t)
 298     (replace-match TO-STRING nil nil))
 299 which will run faster and will not set the mark or print anything."
 300   (interactive (query-replace-read-args "Replace regexp" t))
 301   (perform-replace regexp to-string nil t delimited nil nil start end))
 302
 303 \f
 304 (defvar regexp-history nil
 305   "History list for some commands that read regular expressions.")
 306
 307
 308 (defalias 'delete-non-matching-lines 'keep-lines)
 309 (defalias 'delete-matching-lines 'flush-lines)
 310 (defalias 'count-matches 'how-many)
 311
 312
 313 (defun keep-lines-read-args (prompt)
 314   "Read arguments for `keep-lines' and friends.
 315 Prompt for a regexp with PROMPT.
 316 Value is a list, (REGEXP)."
 317   (list (read-from-minibuffer prompt nil nil nil
 318                               'regexp-history nil t)))
 319
 320 (defun keep-lines (regexp &optional rstart rend)
 321   "Delete all lines except those containing matches for REGEXP.
 322 A match split across lines preserves all the lines it lies in.
 323 Applies to all lines after point.
 324
 325 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 326 the matching is case-sensitive.
 327
 328 Second and third arg RSTART and REND specify the region to operate on.
 329
 330 Interactively, in Transient Mark mode when the mark is active, operate
 331 on the contents of the region.  Otherwise, operate from point to the
 332 end of the buffer."
 333
 334   (interactive
 335    (progn
 336      (barf-if-buffer-read-only)
 337      (keep-lines-read-args "Keep lines (containing match for regexp): ")))
 338   (if rstart
 339       (progn
 340         (goto-char (min rstart rend))
 341         (setq rend (copy-marker (max rstart rend))))
 342     (if (and transient-mark-mode mark-active)
 343         (setq rstart (region-beginning)
 344               rend (copy-marker (region-end)))
 345       (setq rstart (point)
 346             rend (point-max-marker)))
 347     (goto-char rstart))
 348   (save-excursion
 349     (or (bolp) (forward-line 1))
 350     (let ((start (point))
 351           (case-fold-search  (and case-fold-search
 352                                   (isearch-no-upper-case-p regexp t))))
 353       (while (< (point) rend)
 354         ;; Start is first char not preserved by previous match.
 355         (if (not (re-search-forward regexp rend 'move))
 356             (delete-region start rend)
 357           (let ((end (save-excursion (goto-char (match-beginning 0))
 358                                      (beginning-of-line)
 359                                      (point))))
 360             ;; Now end is first char preserved by the new match.
 361             (if (< start end)
 362                 (delete-region start end))))
 363
 364         (setq start (save-excursion (forward-line 1) (point)))
 365         ;; If the match was empty, avoid matching again at same place.
 366         (and (< (point) rend)
 367              (= (match-beginning 0) (match-end 0))
 368              (forward-char 1))))))
 369
 370
 371 (defun flush-lines (regexp &optional rstart rend)
 372   "Delete lines containing matches for REGEXP.
 373 If a match is split across lines, all the lines it lies in are deleted.
 374 Applies to lines after point.
 375
 376 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 377 the matching is case-sensitive.
 378
 379 Second and third arg RSTART and REND specify the region to operate on.
 380
 381 Interactively, in Transient Mark mode when the mark is active, operate
 382 on the contents of the region.  Otherwise, operate from point to the
 383 end of the buffer."
 384
 385   (interactive
 386    (progn
 387      (barf-if-buffer-read-only)
 388      (keep-lines-read-args "Flush lines (containing match for regexp): ")))
 389   (if rstart
 390       (progn
 391         (goto-char (min rstart rend))
 392         (setq rend (copy-marker (max rstart rend))))
 393     (if (and transient-mark-mode mark-active)
 394         (setq rstart (region-beginning)
 395               rend (copy-marker (region-end)))
 396       (setq rstart (point)
 397             rend (point-max-marker)))
 398     (goto-char rstart))
 399   (let ((case-fold-search (and case-fold-search
 400                                (isearch-no-upper-case-p regexp t))))
 401     (save-excursion
 402       (while (and (< (point) rend)
 403                   (re-search-forward regexp rend t))
 404         (delete-region (save-excursion (goto-char (match-beginning 0))
 405                                        (beginning-of-line)
 406                                        (point))
 407                        (progn (forward-line 1) (point)))))))
 408
 409
 410 (defun how-many (regexp &optional rstart rend)
 411   "Print number of matches for REGEXP following point.
 412
 413 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 414 the matching is case-sensitive.
 415
 416 Second and third arg RSTART and REND specify the region to operate on.
 417
 418 Interactively, in Transient Mark mode when the mark is active, operate
 419 on the contents of the region.  Otherwise, operate from point to the
 420 end of the buffer."
 421
 422   (interactive
 423    (keep-lines-read-args "How many matches for (regexp): "))
 424   (save-excursion
 425     (if rstart
 426         (goto-char (min rstart rend))
 427       (if (and transient-mark-mode mark-active)
 428           (setq rstart (region-beginning)
 429                 rend (copy-marker (region-end)))
 430         (setq rstart (point)
 431               rend (point-max-marker)))
 432       (goto-char rstart))
 433     (let ((count 0)
 434           opoint
 435           (case-fold-search (and case-fold-search
 436                                  (isearch-no-upper-case-p regexp t))))
 437       (while (and (< (point) rend)
 438                   (progn (setq opoint (point))
 439                          (re-search-forward regexp rend t)))
 440         (if (= opoint (point))
 441             (forward-char 1)
 442           (setq count (1+ count))))
 443       (message "%d occurrences" count))))
 444
 445 \f
 446 (defvar occur-mode-map
 447   (let ((map (make-sparse-keymap)))
 448     (define-key map [mouse-2] 'occur-mode-mouse-goto)
 449     (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
 450     (define-key map "\C-m" 'occur-mode-goto-occurrence)
 451     (define-key map "o" 'occur-mode-goto-occurrence-other-window)
 452     (define-key map "\C-o" 'occur-mode-display-occurrence)
 453     (define-key map "\M-n" 'occur-next)
 454     (define-key map "\M-p" 'occur-prev)
 455     (define-key map "r" 'occur-rename-buffer)
 456     (define-key map "c" 'clone-buffer)
 457     (define-key map "g" 'revert-buffer)
 458     (define-key map "q" 'quit-window)
 459     (define-key map "z" 'kill-this-buffer)
 460     map)
 461   "Keymap for `occur-mode'.")
 462
 463 (defvar occur-revert-arguments nil
 464   "Arguments to pass to `occur-1' to revert an Occur mode buffer.
 465 See `occur-revert-function'.")
 466
 467 (defcustom occur-mode-hook '(turn-on-font-lock)
 468   "Hook run when entering Occur mode."
 469   :type 'hook
 470   :group 'matching)
 471
 472 (defcustom occur-hook nil
 473   "Hook run when `occur' is called."
 474   :type 'hook
 475   :group 'matching)
 476
 477 (put 'occur-mode 'mode-class 'special)
 478 (defun occur-mode ()
 479   "Major mode for output from \\[occur].
 480 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 481 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 482 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 483
 484 \\{occur-mode-map}"
 485   (interactive)
 486   (kill-all-local-variables)
 487   (use-local-map occur-mode-map)
 488   (setq major-mode 'occur-mode)
 489   (setq mode-name "Occur")
 490   (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
 491   (make-local-variable 'occur-revert-arguments)
 492   (add-hook 'change-major-mode-hook 'font-lock-defontify nil t)
 493   (run-hooks 'occur-mode-hook))
 494
 495 (defun occur-revert-function (ignore1 ignore2)
 496   "Handle `revert-buffer' for Occur mode buffers."
 497   (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
 498
 499 (defun occur-mode-mouse-goto (event)
 500   "In Occur mode, go to the occurrence whose line you click on."
 501   (interactive "e")
 502   (let (pos)
 503     (save-excursion
 504       (set-buffer (window-buffer (posn-window (event-end event))))
 505       (save-excursion
 506         (goto-char (posn-point (event-end event)))
 507         (setq pos (occur-mode-find-occurrence))))
 508     (pop-to-buffer (marker-buffer pos))
 509     (goto-char pos)))
 510
 511 (defun occur-mode-find-occurrence ()
 512   (let ((pos (get-text-property (point) 'occur-target)))
 513     (unless pos
 514       (error "No occurrence on this line"))
 515     (unless (buffer-live-p (marker-buffer pos))
 516       (error "Buffer for this occurrence was killed"))
 517     pos))
 518
 519 (defun occur-mode-goto-occurrence ()
 520   "Go to the occurrence the current line describes."
 521   (interactive)
 522   (let ((pos (occur-mode-find-occurrence)))
 523     (pop-to-buffer (marker-buffer pos))
 524     (goto-char pos)))
 525
 526 (defun occur-mode-goto-occurrence-other-window ()
 527   "Go to the occurrence the current line describes, in another window."
 528   (interactive)
 529   (let ((pos (occur-mode-find-occurrence)))
 530     (switch-to-buffer-other-window (marker-buffer pos))
 531     (goto-char pos)))
 532
 533 (defun occur-mode-display-occurrence ()
 534   "Display in another window the occurrence the current line describes."
 535   (interactive)
 536   (let ((pos (occur-mode-find-occurrence))
 537         window
 538         ;; Bind these to ensure `display-buffer' puts it in another window.
 539         same-window-buffer-names
 540         same-window-regexps)
 541     (setq window (display-buffer (marker-buffer pos)))
 542     ;; This is the way to set point in the proper window.
 543     (save-selected-window
 544       (select-window window)
 545       (goto-char pos))))
 546
 547 (defun occur-next (&optional n)
 548   "Move to the Nth (default 1) next match in an Occur mode buffer."
 549   (interactive "p")
 550   (if (not n) (setq n 1))
 551   (let ((r))
 552     (while (> n 0)
 553       (if (get-text-property (point) 'occur-point)
 554           (forward-char 1))
 555       (setq r (next-single-property-change (point) 'occur-point))
 556       (if r
 557           (goto-char r)
 558         (error "No more matches"))
 559       (setq n (1- n)))))
 560
 561 (defun occur-prev (&optional n)
 562   "Move to the Nth (default 1) previous match in an Occur mode buffer."
 563   (interactive "p")
 564   (if (not n) (setq n 1))
 565   (let ((r))
 566     (while (> n 0)
 567
 568       (setq r (get-text-property (point) 'occur-point))
 569       (if r (forward-char -1))
 570
 571       (setq r (previous-single-property-change (point) 'occur-point))
 572       (if r
 573           (goto-char (- r 1))
 574         (error "No earlier matches"))
 575
 576       (setq n (1- n)))))
 577 \f
 578 (defcustom list-matching-lines-default-context-lines 0
 579   "*Default number of context lines included around `list-matching-lines' matches.
 580 A negative number means to include that many lines before the match.
 581 A positive number means to include that many lines both before and after."
 582   :type 'integer
 583   :group 'matching)
 584
 585 (defalias 'list-matching-lines 'occur)
 586
 587 (defcustom list-matching-lines-face 'bold
 588   "*Face used by \\[list-matching-lines] to show the text that matches.
 589 If the value is nil, don't highlight the matching portions specially."
 590   :type 'face
 591   :group 'matching)
 592
 593 (defcustom list-matching-lines-buffer-name-face 'underline
 594   "*Face used by \\[list-matching-lines] to show the names of buffers.
 595 If the value is nil, don't highlight the buffer names specially."
 596   :type 'face
 597   :group 'matching)
 598
 599 (defun occur-accumulate-lines (count &optional no-props)
 600   (save-excursion
 601     (let ((forwardp (> count 0))
 602           (result nil))
 603       (while (not (or (zerop count)
 604                       (if forwardp
 605                           (eobp)
 606                         (bobp))))
 607         (setq count (+ count (if forwardp -1 1)))
 608         (push
 609          (funcall (if no-props
 610                       #'buffer-substring-no-properties
 611                     #'buffer-substring)
 612           (line-beginning-position)
 613           (line-end-position))
 614          result)
 615         (forward-line (if forwardp 1 -1)))
 616       (nreverse result))))
 617
 618 (defun occur-read-primary-args ()
 619   (list (let* ((default (car regexp-history))
 620                (input
 621                 (read-from-minibuffer
 622                  (if default
 623                      (format "List lines matching regexp (default `%s'): "
 624                              default)
 625                    "List lines matching regexp: ")
 626                  nil
 627                  nil
 628                  nil
 629                  'regexp-history)))
 630           (if (equal input "")
 631               default
 632             input))
 633         (when current-prefix-arg
 634           (prefix-numeric-value current-prefix-arg))))
 635
 636 (defun occur-rename-buffer (&optional unique-p)
 637   "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
 638 Here `original-buffer-name' is the buffer name were occur was originally run.
 639 When given the prefix argument, the renaming will not clobber the existing
 640 buffer(s) of that name, but use `generate-new-buffer-name' instead.
 641 You can add this to `occur-hook' if you always want a separate *Occur*
 642 buffer for each buffer where you invoke `occur'."
 643   (interactive "P")
 644   (with-current-buffer
 645       (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
 646     (rename-buffer (concat "*Occur: "
 647                            (mapconcat #'buffer-name
 648                                       (car (cddr occur-revert-arguments)) "/")
 649                            "*")
 650                    unique-p)))
 651
 652 (defun occur (regexp &optional nlines)
 653   "Show all lines in the current buffer containing a match for REGEXP.
 654
 655 If a match spreads across multiple lines, all those lines are shown.
 656
 657 Each line is displayed with NLINES lines before and after, or -NLINES
 658 before if NLINES is negative.
 659 NLINES defaults to `list-matching-lines-default-context-lines'.
 660 Interactively it is the prefix arg.
 661
 662 The lines are shown in a buffer named `*Occur*'.
 663 It serves as a menu to find any of the occurrences in this buffer.
 664 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 665
 666 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 667 the matching is case-sensitive."
 668   (interactive (occur-read-primary-args))
 669   (occur-1 regexp nlines (list (current-buffer))))
 670
 671 (defun multi-occur (bufs regexp &optional nlines)
 672   "Show all lines in buffers BUFS containing a match for REGEXP.
 673 This function acts on multiple buffers; otherwise, it is exactly like
 674 `occur'."
 675   (interactive
 676    (cons
 677     (let* ((bufs (list (read-buffer "First buffer to search: "
 678                                     (current-buffer) t)))
 679            (buf nil)
 680            (ido-ignore-item-temp-list bufs))
 681       (while (not (string-equal
 682                    (setq buf (read-buffer
 683                               (if (eq read-buffer-function 'ido-read-buffer)
 684                                   "Next buffer to search (C-j to end): "
 685                                 "Next buffer to search (RET to end): ")
 686                               nil t))
 687                    ""))
 688         (add-to-list 'bufs buf)
 689         (setq ido-ignore-item-temp-list bufs))
 690       (nreverse (mapcar #'get-buffer bufs)))
 691     (occur-read-primary-args)))
 692   (occur-1 regexp nlines bufs))
 693
 694 (defun multi-occur-by-filename-regexp (bufregexp regexp &optional nlines)
 695   "Show all lines matching REGEXP in buffers named by BUFREGEXP.
 696 See also `multi-occur'."
 697   (interactive
 698    (cons
 699     (let* ((default (car regexp-history))
 700            (input
 701             (read-from-minibuffer
 702              "List lines in buffers whose filename matches regexp: "
 703              nil
 704              nil
 705              nil
 706              'regexp-history)))
 707       (if (equal input "")
 708           default
 709         input))
 710     (occur-read-primary-args)))
 711   (when bufregexp
 712     (occur-1 regexp nlines
 713              (delq nil
 714                    (mapcar (lambda (buf)
 715                              (when (and (buffer-file-name buf)
 716                                         (string-match bufregexp
 717                                                       (buffer-file-name buf)))
 718                                buf))
 719                            (buffer-list))))))
 720
 721 (defun occur-1 (regexp nlines bufs &optional buf-name)
 722   (unless buf-name
 723     (setq buf-name "*Occur*"))
 724   (let ((occur-buf (get-buffer-create buf-name))
 725         (made-temp-buf nil)
 726         (active-bufs (delq nil (mapcar #'(lambda (buf)
 727                                            (when (buffer-live-p buf) buf))
 728                                        bufs))))
 729     ;; Handle the case where one of the buffers we're searching is the
 730     ;; *Occur* buffer itself.
 731     (when (memq occur-buf bufs)
 732       (setq occur-buf (with-current-buffer occur-buf
 733                         (clone-buffer "*Occur-temp*"))
 734             made-temp-buf t))
 735     (with-current-buffer occur-buf
 736       (setq buffer-read-only nil)
 737       (occur-mode)
 738       (erase-buffer)
 739       (let ((count (occur-engine
 740                     regexp active-bufs occur-buf
 741                     (or nlines list-matching-lines-default-context-lines)
 742                     (and case-fold-search
 743                          (isearch-no-upper-case-p regexp t))
 744                     list-matching-lines-buffer-name-face
 745                     nil list-matching-lines-face nil)))
 746         (let* ((bufcount (length active-bufs))
 747                (diff (- (length bufs) bufcount)))
 748           (message "Searched %d buffer%s%s; %s match%s for `%s'"
 749                    bufcount (if (= bufcount 1) "" "s")
 750                    (if (zerop diff) "" (format " (%d killed)" diff))
 751                    (if (zerop count) "no" (format "%d" count))
 752                    (if (= count 1) "" "es")
 753                    regexp))
 754         ;; If we had to make a temporary buffer, make it the *Occur*
 755         ;; buffer now.
 756         (when made-temp-buf
 757           (with-current-buffer (get-buffer buf-name)
 758             (kill-buffer (current-buffer)))
 759           (rename-buffer buf-name))
 760         (setq occur-revert-arguments (list regexp nlines bufs)
 761               buffer-read-only t)
 762         (if (> count 0)
 763             (display-buffer occur-buf)
 764           (kill-buffer occur-buf)))
 765       (run-hooks 'occur-hook))))
 766
 767 (defun occur-engine-add-prefix (lines)
 768   (mapcar
 769    #'(lambda (line)
 770        (concat "      :" line "\n"))
 771    lines))
 772
 773 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
 774                             title-face prefix-face match-face keep-props)
 775   (with-current-buffer out-buf
 776     (setq buffer-read-only nil)
 777     (let ((globalcount 0))
 778       ;; Map over all the buffers
 779       (dolist (buf buffers)
 780         (when (buffer-live-p buf)
 781           (let ((matches 0)     ;; count of matched lines
 782                 (lines 1)       ;; line count
 783                 (matchbeg 0)
 784                 (matchend 0)
 785                 (origpt nil)
 786                 (begpt nil)
 787                 (endpt nil)
 788                 (marker nil)
 789                 (curstring "")
 790                 (headerpt (with-current-buffer out-buf (point))))
 791             (save-excursion
 792               (set-buffer buf)
 793               (save-excursion
 794                 (goto-char (point-min)) ;; begin searching in the buffer
 795                 (while (not (eobp))
 796                   (setq origpt (point))
 797                   (when (setq endpt (re-search-forward regexp nil t))
 798                     (setq matches (1+ matches)) ;; increment match count
 799                     (setq matchbeg (match-beginning 0)
 800                           matchend (match-end 0))
 801                     (setq begpt (save-excursion
 802                                   (goto-char matchbeg)
 803                                   (line-beginning-position)))
 804                     (setq lines (+ lines (1- (count-lines origpt endpt))))
 805                     (setq marker (make-marker))
 806                     (set-marker marker matchbeg)
 807                     (setq curstring (buffer-substring begpt
 808                                                       (line-end-position)))
 809                     ;; Depropertize the string, and maybe
 810                     ;; highlight the matches
 811                     (let ((len (length curstring))
 812                           (start 0))
 813                       (unless keep-props
 814                         (set-text-properties 0 len nil curstring))
 815                       (while (and (< start len)
 816                                   (string-match regexp curstring start))
 817                         (add-text-properties (match-beginning 0)
 818                                              (match-end 0)
 819                                              (append
 820                                               `(occur-match t)
 821                                               (when match-face
 822                                                 `(font-lock-face ,match-face)))
 823                                              curstring)
 824                         (setq start (match-end 0))))
 825                     ;; Generate the string to insert for this match
 826                     (let* ((out-line
 827                             (concat
 828                              (apply #'propertize (format "%6d:" lines)
 829                                     (append
 830                                      (when prefix-face
 831                                        `(font-lock-face prefix-face))
 832                                      '(occur-prefix t)))
 833                              curstring
 834                              "\n"))
 835                            (data
 836                             (if (= nlines 0)
 837                                 ;; The simple display style
 838                                 out-line
 839                               ;; The complex multi-line display
 840                               ;; style.  Generate a list of lines,
 841                               ;; concatenate them all together.
 842                               (apply #'concat
 843                                      (nconc
 844                                       (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ nlines)) keep-props))))
 845                                       (list out-line)
 846                                       (occur-engine-add-prefix (cdr (occur-accumulate-lines (1+ nlines) keep-props))))))))
 847                       ;; Actually insert the match display data
 848                       (with-current-buffer out-buf
 849                         (let ((beg (point))
 850                               (end (progn (insert data) (point))))
 851                           (unless (= nlines 0)
 852                             (insert "-------\n"))
 853                           (add-text-properties
 854                            beg end
 855                            `(occur-target ,marker help-echo "mouse-2: go to this occurrence"))
 856                           ;; We don't put `mouse-face' on the newline,
 857                           ;; because that loses.
 858                           (add-text-properties beg (1- end) '(mouse-face highlight)))))
 859                     (goto-char endpt))
 860                   (if endpt
 861                       (progn
 862                         (setq lines (1+ lines))
 863                         ;; On to the next match...
 864                         (forward-line 1))
 865                     (goto-char (point-max))))))
 866             (when (not (zerop matches)) ;; is the count zero?
 867               (setq globalcount (+ globalcount matches))
 868               (with-current-buffer out-buf
 869                 (goto-char headerpt)
 870                 (let ((beg (point))
 871                       end)
 872                   (insert (format "%d lines matching \"%s\" in buffer: %s\n"
 873                                   matches regexp (buffer-name buf)))
 874                   (setq end (point))
 875                   (add-text-properties beg end
 876                                        (append
 877                                         (when title-face
 878                                           `(font-lock-face ,title-face))
 879                                         `(occur-title ,buf))))
 880                 (goto-char (point-min)))))))
 881       ;; Return the number of matches
 882       globalcount)))
 883
 884 \f
 885 ;; It would be nice to use \\[...], but there is no reasonable way
 886 ;; to make that display both SPC and Y.
 887 (defconst query-replace-help
 888   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
 889 RET or `q' to exit, Period to replace one match and exit,
 890 Comma to replace but not move point immediately,
 891 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
 892 C-w to delete match and recursive edit,
 893 C-l to clear the screen, redisplay, and offer same replacement again,
 894 ! to replace all remaining matches with no more questions,
 895 ^ to move point back to previous match,
 896 E to edit the replacement string"
 897   "Help message while in `query-replace'.")
 898
 899 (defvar query-replace-map (make-sparse-keymap)
 900   "Keymap that defines the responses to questions in `query-replace'.
 901 The \"bindings\" in this map are not commands; they are answers.
 902 The valid answers include `act', `skip', `act-and-show',
 903 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
 904 `automatic', `backup', `exit-prefix', and `help'.")
 905
 906 (define-key query-replace-map " " 'act)
 907 (define-key query-replace-map "\d" 'skip)
 908 (define-key query-replace-map [delete] 'skip)
 909 (define-key query-replace-map [backspace] 'skip)
 910 (define-key query-replace-map "y" 'act)
 911 (define-key query-replace-map "n" 'skip)
 912 (define-key query-replace-map "Y" 'act)
 913 (define-key query-replace-map "N" 'skip)
 914 (define-key query-replace-map "e" 'edit-replacement)
 915 (define-key query-replace-map "E" 'edit-replacement)
 916 (define-key query-replace-map "," 'act-and-show)
 917 (define-key query-replace-map "q" 'exit)
 918 (define-key query-replace-map "\r" 'exit)
 919 (define-key query-replace-map [return] 'exit)
 920 (define-key query-replace-map "." 'act-and-exit)
 921 (define-key query-replace-map "\C-r" 'edit)
 922 (define-key query-replace-map "\C-w" 'delete-and-edit)
 923 (define-key query-replace-map "\C-l" 'recenter)
 924 (define-key query-replace-map "!" 'automatic)
 925 (define-key query-replace-map "^" 'backup)
 926 (define-key query-replace-map "\C-h" 'help)
 927 (define-key query-replace-map [f1] 'help)
 928 (define-key query-replace-map [help] 'help)
 929 (define-key query-replace-map "?" 'help)
 930 (define-key query-replace-map "\C-g" 'quit)
 931 (define-key query-replace-map "\C-]" 'quit)
 932 (define-key query-replace-map "\e" 'exit-prefix)
 933 (define-key query-replace-map [escape] 'exit-prefix)
 934
 935 (defun replace-match-string-symbols (n)
 936   "Process a list (and any sub-lists), expanding certain symbols.
 937 Symbol  Expands To
 938 N     (match-string N)           (where N is a string of digits)
 939 #N    (string-to-number (match-string N))
 940 &     (match-string 0)
 941 #&    (string-to-number (match-string 0))
 942
 943 Note that these symbols must be preceeded by a backslash in order to
 944 type them."
 945   (while n
 946     (cond
 947      ((consp (car n))
 948       (replace-match-string-symbols (car n))) ;Process sub-list
 949      ((symbolp (car n))
 950       (let ((name (symbol-name (car n))))
 951         (cond
 952          ((string-match "^[0-9]+$" name)
 953           (setcar n (list 'match-string (string-to-number name))))
 954          ((string-match "^#[0-9]+$" name)
 955           (setcar n (list 'string-to-number
 956                           (list 'match-string
 957                                 (string-to-number (substring name 1))))))
 958          ((string= "&" name)
 959           (setcar n '(match-string 0)))
 960          ((string= "#&" name)
 961           (setcar n '(string-to-number (match-string 0))))))))
 962     (setq n (cdr n))))
 963
 964 (defun replace-eval-replacement (expression replace-count)
 965   (let ((replacement (eval expression)))
 966     (if (stringp replacement)
 967         replacement
 968       (prin1-to-string replacement t))))
 969
 970 (defun replace-loop-through-replacements (data replace-count)
 971   ;; DATA is a vector contaning the following values:
 972   ;;   0 next-rotate-count
 973   ;;   1 repeat-count
 974   ;;   2 next-replacement
 975   ;;   3 replacements
 976   (if (= (aref data 0) replace-count)
 977       (progn
 978         (aset data 0 (+ replace-count (aref data 1)))
 979         (let ((next (cdr (aref data 2))))
 980           (aset data 2 (if (consp next) next (aref data 3))))))
 981   (car (aref data 2)))
 982
 983 (defun perform-replace (from-string replacements
 984                         query-flag regexp-flag delimited-flag
 985                         &optional repeat-count map start end)
 986   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
 987 Don't use this in your own program unless you want to query and set the mark
 988 just as `query-replace' does.  Instead, write a simple loop like this:
 989
 990   (while (re-search-forward \"foo[ \\t]+bar\" nil t)
 991     (replace-match \"foobar\" nil nil))
 992
 993 which will run faster and probably do exactly what you want.  Please
 994 see the documentation of `replace-match' to find out how to simulate
 995 `case-replace'.
 996
 997 This function returns nil if and only if there were no matches to
 998 make, or the user didn't cancel the call."
 999   (or map (setq map query-replace-map))
1000   (and query-flag minibuffer-auto-raise
1001        (raise-frame (window-frame (minibuffer-window))))
1002   (let ((nocasify (not (and case-fold-search case-replace
1003                             (string-equal from-string
1004                                           (downcase from-string)))))
1005         (case-fold-search (and case-fold-search
1006                                (string-equal from-string
1007                                              (downcase from-string))))
1008         (literal (not regexp-flag))
1009         (search-function (if regexp-flag 're-search-forward 'search-forward))
1010         (search-string from-string)
1011         (real-match-data nil)           ; the match data for the current match
1012         (next-replacement nil)
1013         (keep-going t)
1014         (stack nil)
1015         (replace-count 0)
1016         (nonempty-match nil)
1017
1018         ;; If non-nil, it is marker saying where in the buffer to stop.
1019         (limit nil)
1020
1021         ;; Data for the next match.  If a cons, it has the same format as
1022         ;; (match-data); otherwise it is t if a match is possible at point.
1023         (match-again t)
1024
1025         (message
1026          (if query-flag
1027              (substitute-command-keys
1028               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1029
1030     ;; If region is active, in Transient Mark mode, operate on region.
1031     (when start
1032       (setq limit (copy-marker (max start end)))
1033       (goto-char (min start end))
1034       (deactivate-mark))
1035
1036     ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1037     ;; containing a function and its first argument.  The function is
1038     ;; called to generate each replacement like this:
1039     ;;   (funcall (car replacements) (cdr replacements) replace-count)
1040     ;; It must return a string.
1041     (cond
1042      ((stringp replacements)
1043       (setq next-replacement replacements
1044             replacements     nil))
1045      ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1046       (or repeat-count (setq repeat-count 1))
1047       (setq replacements (cons 'replace-loop-through-replacements
1048                                (vector repeat-count repeat-count
1049                                        replacements replacements)))))
1050
1051     (if delimited-flag
1052         (setq search-function 're-search-forward
1053               search-string (concat "\\b"
1054                                     (if regexp-flag from-string
1055                                       (regexp-quote from-string))
1056                                     "\\b")))
1057     (push-mark)
1058     (undo-boundary)
1059     (unwind-protect
1060         ;; Loop finding occurrences that perhaps should be replaced.
1061         (while (and keep-going
1062                     (not (eobp))
1063                     ;; Use the next match if it is already known;
1064                     ;; otherwise, search for a match after moving forward
1065                     ;; one char if progress is required.
1066                     (setq real-match-data
1067                           (if (consp match-again)
1068                               (progn (goto-char (nth 1 match-again))
1069                                      match-again)
1070                             (and (or match-again
1071                                      ;; MATCH-AGAIN non-nil means we
1072                                      ;; accept an adjacent match.  If
1073                                      ;; we don't, move one char to the
1074                                      ;; right.  This takes us a
1075                                      ;; character too far at the end,
1076                                      ;; but this is undone after the
1077                                      ;; while-loop.
1078                                      (progn (forward-char 1) (not (eobp))))
1079                                  (funcall search-function search-string limit t)
1080                                  ;; For speed, use only integers and
1081                                  ;; reuse the list used last time.
1082                                  (match-data t real-match-data)))))
1083           ;; Optionally ignore matches that have a read-only property.
1084           (unless (and query-replace-skip-read-only
1085                        (text-property-not-all
1086                         (match-beginning 0) (match-end 0)
1087                         'read-only nil))
1088
1089             ;; Record whether the match is nonempty, to avoid an infinite loop
1090             ;; repeatedly matching the same empty string.
1091             (setq nonempty-match
1092                   (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1093
1094             ;; If the match is empty, record that the next one can't be
1095             ;; adjacent.
1096
1097             ;; Otherwise, if matching a regular expression, do the next
1098             ;; match now, since the replacement for this match may
1099             ;; affect whether the next match is adjacent to this one.
1100             ;; If that match is empty, don't use it.
1101             (setq match-again
1102                   (and nonempty-match
1103                        (or (not regexp-flag)
1104                            (and (looking-at search-string)
1105                                 (let ((match (match-data)))
1106                                   (and (/= (nth 0 match) (nth 1 match))
1107                                        match))))))
1108
1109             ;; Calculate the replacement string, if necessary.
1110             (when replacements
1111               (set-match-data real-match-data)
1112               (setq next-replacement
1113                     (funcall (car replacements) (cdr replacements)
1114                              replace-count)))
1115             (if (not query-flag)
1116                 (let ((inhibit-read-only query-replace-skip-read-only))
1117                   (set-match-data real-match-data)
1118                   (replace-match next-replacement nocasify literal)
1119                   (setq replace-count (1+ replace-count)))
1120               (undo-boundary)
1121               (let (done replaced key def)
1122                 ;; Loop reading commands until one of them sets done,
1123                 ;; which means it has finished handling this occurrence.
1124                 (while (not done)
1125                   (set-match-data real-match-data)
1126                   (replace-highlight (match-beginning 0) (match-end 0))
1127                   ;; Bind message-log-max so we don't fill up the message log
1128                   ;; with a bunch of identical messages.
1129                   (let ((message-log-max nil))
1130                     (message message from-string next-replacement))
1131                   (setq key (read-event))
1132                   ;; Necessary in case something happens during read-event
1133                   ;; that clobbers the match data.
1134                   (set-match-data real-match-data)
1135                   (setq key (vector key))
1136                   (setq def (lookup-key map key))
1137                   ;; Restore the match data while we process the command.
1138                   (cond ((eq def 'help)
1139                          (with-output-to-temp-buffer "*Help*"
1140                            (princ
1141                             (concat "Query replacing "
1142                                     (if regexp-flag "regexp " "")
1143                                     from-string " with "
1144                                     next-replacement ".\n\n"
1145                                     (substitute-command-keys
1146                                      query-replace-help)))
1147                            (with-current-buffer standard-output
1148                              (help-mode))))
1149                         ((eq def 'exit)
1150                          (setq keep-going nil)
1151                          (setq done t))
1152                         ((eq def 'backup)
1153                          (if stack
1154                              (let ((elt (pop stack)))
1155                                (goto-char (car elt))
1156                                (setq replaced (eq t (cdr elt)))
1157                                (or replaced
1158                                    (set-match-data (cdr elt))))
1159                            (message "No previous match")
1160                            (ding 'no-terminate)
1161                            (sit-for 1)))
1162                         ((eq def 'act)
1163                          (or replaced
1164                              (progn
1165                                (replace-match next-replacement nocasify literal)
1166                                (setq replace-count (1+ replace-count))))
1167                          (setq done t replaced t))
1168                         ((eq def 'act-and-exit)
1169                          (or replaced
1170                              (progn
1171                                (replace-match next-replacement nocasify literal)
1172                                (setq replace-count (1+ replace-count))))
1173                          (setq keep-going nil)
1174                          (setq done t replaced t))
1175                         ((eq def 'act-and-show)
1176                          (if (not replaced)
1177                              (progn
1178                                (replace-match next-replacement nocasify literal)
1179                                (setq replace-count (1+ replace-count))
1180                                (setq replaced t))))
1181                         ((eq def 'automatic)
1182                          (or replaced
1183                              (progn
1184                                (replace-match next-replacement nocasify literal)
1185                                (setq replace-count (1+ replace-count))))
1186                          (setq done t query-flag nil replaced t))
1187                         ((eq def 'skip)
1188                          (setq done t))
1189                         ((eq def 'recenter)
1190                          (recenter nil))
1191                         ((eq def 'edit)
1192                          (let ((opos (point-marker)))
1193                            (goto-char (match-beginning 0))
1194                            (save-excursion
1195                              (funcall search-function search-string limit t)
1196                              (setq real-match-data (match-data)))
1197                            (save-excursion
1198                              (save-window-excursion
1199                                (recursive-edit)))
1200                            (goto-char opos))
1201                          (set-match-data real-match-data)
1202                          ;; Before we make the replacement,
1203                          ;; decide whether the search string
1204                          ;; can match again just after this match.
1205                          (if (and regexp-flag nonempty-match)
1206                              (setq match-again (and (looking-at search-string)
1207                                                     (match-data)))))
1208
1209                         ;; Edit replacement.
1210                         ((eq def 'edit-replacement)
1211                          (setq next-replacement
1212                                (read-input "Edit replacement string: "
1213                                            next-replacement))
1214                          (or replaced
1215                              (replace-match next-replacement nocasify literal))
1216                          (setq done t))
1217
1218                         ((eq def 'delete-and-edit)
1219                          (delete-region (match-beginning 0) (match-end 0))
1220                          (set-match-data
1221                           (prog1 (match-data)
1222                             (save-excursion (recursive-edit))))
1223                          (setq replaced t))
1224                         ;; Note: we do not need to treat `exit-prefix'
1225                         ;; specially here, since we reread
1226                         ;; any unrecognized character.
1227                         (t
1228                          (setq this-command 'mode-exited)
1229                          (setq keep-going nil)
1230                          (setq unread-command-events
1231                                (append (listify-key-sequence key)
1232                                        unread-command-events))
1233                          (setq done t))))
1234                 ;; Record previous position for ^ when we move on.
1235                 ;; Change markers to numbers in the match data
1236                 ;; since lots of markers slow down editing.
1237                 (setq stack
1238                       (cons (cons (point)
1239                                   (or replaced (match-data t)))
1240                             stack))))))
1241
1242       ;; The code preventing adjacent regexp matches in the condition
1243       ;; of the while-loop above will haven taken us one character
1244       ;; beyond the last replacement.  Undo that.
1245       (when (and regexp-flag (not match-again) (> replace-count 0))
1246         (backward-char 1))
1247
1248       (replace-dehighlight))
1249     (or unread-command-events
1250         (message "Replaced %d occurrence%s"
1251                  replace-count
1252                  (if (= replace-count 1) "" "s")))
1253     (and keep-going stack)))
1254
1255 (defcustom query-replace-highlight t
1256   "*Non-nil means to highlight words during query replacement."
1257   :type 'boolean
1258   :group 'matching)
1259
1260 (defvar replace-overlay nil)
1261
1262 (defun replace-dehighlight ()
1263   (and replace-overlay
1264        (progn
1265          (delete-overlay replace-overlay)
1266          (setq replace-overlay nil))))
1267
1268 (defun replace-highlight (start end)
1269   (and query-replace-highlight
1270        (progn
1271          (or replace-overlay
1272              (progn
1273                (setq replace-overlay (make-overlay start end))
1274                (overlay-put replace-overlay 'face
1275                             (if (facep 'query-replace)
1276                                 'query-replace 'region))))
1277          (move-overlay replace-overlay start end (current-buffer)))))
1278
1279 ;;; replace.el ends here