build-aux/git-hooks/commit-msg

   1 #!/bin/sh
   2 # Check the format of GNU Emacs change log entries.
   3
   4 # Copyright 2014-2016 Free Software Foundation, Inc.
   5
   6 # This file is part of GNU Emacs.
   7
   8 # GNU Emacs is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12
  13 # GNU Emacs is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # Written by Paul Eggert.
  22
  23 # Prefer gawk if available, as it handles NUL bytes properly.
  24 if type gawk >/dev/null 2>&1; then
  25   awk=gawk
  26 else
  27   awk=awk
  28 fi
  29
  30 # Use a UTF-8 locale if available, so that the UTF-8 check works.
  31 # Use U+00A2 CENT SIGN to test whether the locale works.
  32 cent_sign_utf8_format='\302\242\n'
  33 cent_sign=`printf "$cent_sign_utf8_format"`
  34 print_at_sign='BEGIN {print substr("'$cent_sign'@", 2)}'
  35 at_sign=`$awk "$print_at_sign" </dev/null 2>/dev/null`
  36 if test "$at_sign" != @; then
  37   at_sign=`LC_ALL=en_US.UTF-8 $awk "$print_at_sign" </dev/null 2>/dev/null`
  38   if test "$at_sign" = @; then
  39     LC_ALL=en_US.UTF-8
  40   else
  41     LC_ALL=C
  42   fi
  43   export LC_ALL
  44 fi
  45
  46 # Check the log entry.
  47 exec $awk -v at_sign="$at_sign" -v cent_sign="$cent_sign" '
  48   BEGIN {
  49     # These regular expressions assume traditional Unix unibyte behavior.
  50     # They are needed for old or broken versions of awk, e.g.,
  51     # mawk 1.3.3 (1996), or gawk on MSYS (2015), and/or for systems that
  52     # cannot use UTF-8 as the codeset for the locale.
  53     space = "[ \f\n\r\t\v]"
  54     non_space = "[^ \f\n\r\t\v]"
  55     # The non_print below rejects control characters and surrogates
  56     # UTF-8 for: 0x01-0x1f 0x7f   0x80-0x9f  0xd800-0xdbff  0xdc00-0xdfff
  57     non_print = "[\1-\37\177]|\302[\200-\237]|\355[\240-\277][\200-\277]"
  58
  59     # Prefer POSIX regular expressions if available, as they do a
  60     # better job of checking.  Similarly, prefer POSIX negated
  61     # expressions if UTF-8 also works.
  62     if (" " ~ /[[:space:]]/) {
  63       space = "[[:space:]]"
  64       if (at_sign == "@" && cent_sign ~ /^[[:print:]]$/) {
  65         non_space = "[^[:space:]]"
  66         non_print = "[^[:print:]]"
  67       }
  68     }
  69   }
  70
  71   /^#/ {
  72     # Ignore every line after a scissors line.
  73     if (/^# *---* *(>[8%]|[8%]<) *---* *$/) { exit }
  74
  75     # Ignore comment lines.
  76     next
  77   }
  78
  79   !/^.*$/ {
  80     print "Invalid character (not UTF-8) in commit message"
  81     status = 1
  82   }
  83
  84   nlines == 0 && $0 !~ non_space { next }
  85
  86   { nlines++ }
  87
  88   nlines == 1 {
  89     # Ignore special markers used by "git rebase --autosquash".
  90     if (! sub(/^fixup! /, ""))
  91       sub(/^squash! /, "")
  92
  93     if ($0 ~ "^" space) {
  94       print "White space at start of commit message'\''s first line"
  95       status = 1
  96     }
  97   }
  98
  99   nlines == 2 && $0 ~ non_space {
 100     print "Nonempty second line in commit message"
 101     status = 1
 102   }
 103
 104   {
 105     # Expand tabs to spaces for length calculations etc.
 106     while (match($0, /\t/)) {
 107       before_tab = substr($0, 1, RSTART - 1)
 108       after_tab = substr($0, RSTART + 1)
 109       $0 = sprintf("%s%*s%s", before_tab, 8 - (RSTART - 1) % 8, "", after_tab)
 110     }
 111   }
 112
 113   78 < length && $0 ~ space {
 114     print "Line longer than 78 characters in commit message"
 115     status = 1
 116   }
 117
 118   140 < length {
 119     print "Word longer than 140 characters in commit message"
 120     status = 1
 121   }
 122
 123   /^Signed-off-by: / {
 124     print "'\''Signed-off-by:'\'' in commit message"
 125     status = 1
 126   }
 127
 128   $0 ~ non_print {
 129     print "Unprintable character in commit message"
 130     status = 1
 131   }
 132
 133   END {
 134     if (nlines == 0) {
 135       print "Empty commit message"
 136       status = 1
 137     }
 138     if (status != 0) {
 139       print "Commit aborted; please see the file 'CONTRIBUTE'"
 140     }
 141     exit status
 142   }
 143 ' <"$1"