lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Emmanuel Briot  <briot@gnat.com>
   6 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
   7 ;; Keywords: xml, data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file contains a somewhat incomplete non-validating XML parser.  It
  27 ;; parses a file, and returns a list that can be used internally by
  28 ;; any other Lisp libraries.
  29
  30 ;;; FILE FORMAT
  31
  32 ;; The document type declaration may either be ignored or (optionally)
  33 ;; parsed, but currently the parsing will only accept element
  34 ;; declarations.  The XML file is assumed to be well-formed.  In case
  35 ;; of error, the parsing stops and the XML file is shown where the
  36 ;; parsing stopped.
  37 ;;
  38 ;; It also knows how to ignore comments and processing instructions.
  39 ;;
  40 ;; The XML file should have the following format:
  41 ;;    <node1 attr1="name1" attr2="name2" ...>value
  42 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  43 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  44 ;;    </node1>
  45 ;; Of course, the name of the nodes and attributes can be anything.  There can
  46 ;; be any number of attributes (or none), as well as any number of children
  47 ;; below the nodes.
  48 ;;
  49 ;; There can be only top level node, but with any number of children below.
  50
  51 ;;; LIST FORMAT
  52
  53 ;; The functions `xml-parse-file', `xml-parse-region' and
  54 ;; `xml-parse-tag' return a list with the following format:
  55 ;;
  56 ;;    xml-list   ::= (node node ...)
  57 ;;    node       ::= (qname attribute-list . child_node_list)
  58 ;;    child_node_list ::= child_node child_node ...
  59 ;;    child_node ::= node | string
  60 ;;    qname      ::= (:namespace-uri . "name") | "name"
  61 ;;    attribute_list ::= ((qname . "value") (qname . "value") ...)
  62 ;;                       | nil
  63 ;;    string     ::= "..."
  64 ;;
  65 ;; Some macros are provided to ease the parsing of this list.
  66 ;; Whitespace is preserved.  Fixme: There should be a tree-walker that
  67 ;; can remove it.
  68
  69 ;; TODO:
  70 ;;  * xml:base, xml:space support
  71 ;;  * more complete DOCTYPE parsing
  72 ;;  * pi support
  73
  74 ;;; Code:
  75
  76 ;; Note that buffer-substring and match-string were formerly used in
  77 ;; several places, because the -no-properties variants remove
  78 ;; composition info.  However, after some discussion on emacs-devel,
  79 ;; the consensus was that the speed of the -no-properties variants was
  80 ;; a worthwhile tradeoff especially since we're usually parsing files
  81 ;; instead of hand-crafted XML.
  82
  83 ;;*******************************************************************
  84 ;;**
  85 ;;**  Macros to parse the list
  86 ;;**
  87 ;;*******************************************************************
  88
  89 (defconst xml-undefined-entity "?"
  90   "What to substitute for undefined entities")
  91
  92 (defvar xml-entity-alist
  93   '(("lt"   . "<")
  94     ("gt"   . ">")
  95     ("apos" . "'")
  96     ("quot" . "\"")
  97     ("amp"  . "&"))
  98   "The defined entities.  Entities are added to this when the DTD is parsed.")
  99
 100 (defvar xml-sub-parser nil
 101   "Dynamically set this to a non-nil value if you want to parse an XML fragment.")
 102
 103 (defvar xml-validating-parser nil
 104   "Set to non-nil to get validity checking.")
 105
 106 (defsubst xml-node-name (node)
 107   "Return the tag associated with NODE.
 108 Without namespace-aware parsing, the tag is a symbol.
 109
 110 With namespace-aware parsing, the tag is a cons of a string
 111 representing the uri of the namespace with the local name of the
 112 tag.  For example,
 113
 114     <foo>
 115
 116 would be represented by
 117
 118     '(\"\" . \"foo\")."
 119
 120   (car node))
 121
 122 (defsubst xml-node-attributes (node)
 123   "Return the list of attributes of NODE.
 124 The list can be nil."
 125   (nth 1 node))
 126
 127 (defsubst xml-node-children (node)
 128   "Return the list of children of NODE.
 129 This is a list of nodes, and it can be nil."
 130   (cddr node))
 131
 132 (defun xml-get-children (node child-name)
 133   "Return the children of NODE whose tag is CHILD-NAME.
 134 CHILD-NAME should match the value returned by `xml-node-name'."
 135   (let ((match ()))
 136     (dolist (child (xml-node-children node))
 137       (if (and (listp child)
 138                (equal (xml-node-name child) child-name))
 139           (push child match)))
 140     (nreverse match)))
 141
 142 (defun xml-get-attribute-or-nil (node attribute)
 143   "Get from NODE the value of ATTRIBUTE.
 144 Return nil if the attribute was not found.
 145
 146 See also `xml-get-attribute'."
 147   (cdr (assoc attribute (xml-node-attributes node))))
 148
 149 (defsubst xml-get-attribute (node attribute)
 150   "Get from NODE the value of ATTRIBUTE.
 151 An empty string is returned if the attribute was not found.
 152
 153 See also `xml-get-attribute-or-nil'."
 154   (or (xml-get-attribute-or-nil node attribute) ""))
 155
 156 ;;*******************************************************************
 157 ;;**
 158 ;;**  Creating the list
 159 ;;**
 160 ;;*******************************************************************
 161
 162 ;;;###autoload
 163 (defun xml-parse-file (file &optional parse-dtd parse-ns)
 164   "Parse the well-formed XML file FILE.
 165 If FILE is already visited, use its buffer and don't kill it.
 166 Returns the top node with all its children.
 167 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
 168 If PARSE-NS is non-nil, then QNAMES are expanded."
 169   (if (get-file-buffer file)
 170       (with-current-buffer (get-file-buffer file)
 171         (save-excursion
 172           (xml-parse-region (point-min)
 173                             (point-max)
 174                             (current-buffer)
 175                             parse-dtd parse-ns)))
 176     (with-temp-buffer
 177       (insert-file-contents file)
 178       (xml-parse-region (point-min)
 179                         (point-max)
 180                         (current-buffer)
 181                         parse-dtd parse-ns))))
 182
 183
 184 (defvar xml-name-re)
 185 (defvar xml-entity-value-re)
 186 (defvar xml-att-def-re)
 187 (let* ((start-chars (concat "[:alpha:]:_"))
 188        (name-chars  (concat "-[:digit:]." start-chars))
 189        ;;[3]    S          ::=          (#x20 | #x9 | #xD | #xA)+
 190        (whitespace  "[ \t\n\r]"))
 191   ;;[4] NameStartChar ::= ":" | [A-Z] | "_" | [a-z] | [#xC0-#xD6]
 192   ;;                      | [#xD8-#xF6] | [#xF8-#x2FF] | [#x370-#x37D] | [#x37F-#x1FFF]
 193   ;;                      | [#x200C-#x200D] | [#x2070-#x218F] | [#x2C00-#x2FEF] | [#x3001-#xD7FF]
 194   ;;                      | [#xF900-#xFDCF] | [#xFDF0-#xFFFD] | [#x10000-#xEFFFF]
 195   (defvar xml-name-start-char-re (concat "[" start-chars "]"))
 196   ;;[4a] NameChar       ::= NameStartChar | "-" | "." | [0-9] | #xB7 | [#x0300-#x036F] | [#x203F-#x2040]
 197   (defvar xml-name-char-re       (concat "[" name-chars  "]"))
 198   ;;[5] Name     ::= NameStartChar (NameChar)*
 199   (defvar xml-name-re            (concat xml-name-start-char-re xml-name-char-re "*"))
 200   ;;[6] Names    ::= Name (#x20 Name)*
 201   (defvar xml-names-re           (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
 202   ;;[7] Nmtoken ::= (NameChar)+
 203   (defvar xml-nmtoken-re         (concat xml-name-char-re "+"))
 204   ;;[8] Nmtokens ::= Nmtoken (#x20 Nmtoken)*
 205   (defvar xml-nmtokens-re        (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
 206   ;;[66] CharRef ::= '&#' [0-9]+ ';' | '&#x' [0-9a-fA-F]+ ';'
 207   (defvar xml-char-ref-re        "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
 208   ;;[68] EntityRef   ::= '&' Name ';'
 209   (defvar xml-entity-ref         (concat "&" xml-name-re ";"))
 210   ;;[69] PEReference ::= '%' Name ';'
 211   (defvar xml-pe-reference-re    (concat "%" xml-name-re ";"))
 212   ;;[67] Reference   ::= EntityRef | CharRef
 213   (defvar xml-reference-re       (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
 214   ;;[10]        AttValue           ::=          '"' ([^<&"] | Reference)* '"' |  "'" ([^<&'] | Reference)* "'"
 215   (defvar xml-att-value-re    (concat "\\(?:\"\\(?:[^&\"]\\|" xml-reference-re "\\)*\"\\|"
 216                                       "'\\(?:[^&']\\|" xml-reference-re "\\)*'\\)"))
 217   ;;[56]        TokenizedType      ::=          'ID'       [VC: ID] [VC: One ID per Element Type] [VC: ID Attribute Default]
 218   ;;                                            | 'IDREF'    [VC: IDREF]
 219   ;;                                                  | 'IDREFS'   [VC: IDREF]
 220   ;;                                            | 'ENTITY'   [VC: Entity Name]
 221   ;;                                            | 'ENTITIES' [VC: Entity Name]
 222   ;;                                            | 'NMTOKEN'  [VC: Name Token]
 223   ;;                                            | 'NMTOKENS' [VC: Name Token]
 224   (defvar xml-tokenized-type-re "\\(?:ID\\|IDREF\\|IDREFS\\|ENTITY\\|ENTITIES\\|NMTOKEN\\|NMTOKENS\\)")
 225   ;;[58]        NotationType       ::=          'NOTATION' S '(' S? Name (S? '|' S? Name)* S? ')'
 226   (defvar xml-notation-type-re (concat "\\(?:NOTATION" whitespace "(" whitespace "*" xml-name-re
 227                                        "\\(?:" whitespace "*|" whitespace "*" xml-name-re "\\)*" whitespace "*)\\)"))
 228   ;;[59]        Enumeration        ::=          '(' S? Nmtoken (S? '|' S? Nmtoken)* S? ')'      [VC: Enumeration] [VC: No Duplicate Tokens]
 229   (defvar xml-enumeration-re (concat "\\(?:(" whitespace "*" xml-nmtoken-re
 230                                      "\\(?:" whitespace "*|" whitespace "*" xml-nmtoken-re "\\)*"
 231                                      whitespace ")\\)"))
 232   ;;[57]        EnumeratedType     ::=          NotationType | Enumeration
 233   (defvar xml-enumerated-type-re (concat "\\(?:" xml-notation-type-re "\\|" xml-enumeration-re "\\)"))
 234   ;;[54]        AttType    ::=          StringType | TokenizedType | EnumeratedType
 235   ;;[55]        StringType         ::=          'CDATA'
 236   (defvar xml-att-type-re (concat "\\(?:CDATA\\|" xml-tokenized-type-re "\\|" xml-notation-type-re"\\|" xml-enumerated-type-re "\\)"))
 237   ;;[60]        DefaultDecl        ::=          '#REQUIRED' | '#IMPLIED' | (('#FIXED' S)? AttValue)
 238   (defvar xml-default-decl-re (concat "\\(?:#REQUIRED\\|#IMPLIED\\|\\(?:#FIXED" whitespace "\\)*" xml-att-value-re "\\)"))
 239   ;;[53]        AttDef     ::=          S Name S AttType S DefaultDecl
 240   (defvar xml-att-def-re         (concat "\\(?:" whitespace "*" xml-name-re
 241                                          whitespace "*" xml-att-type-re
 242                                          whitespace "*" xml-default-decl-re "\\)"))
 243   ;;[9] EntityValue ::= '"' ([^%&"] | PEReference | Reference)* '"'
 244   ;;               |  "'" ([^%&'] | PEReference | Reference)* "'"
 245   (defvar xml-entity-value-re    (concat "\\(?:\"\\(?:[^%&\"]\\|" xml-pe-reference-re
 246                                          "\\|" xml-reference-re "\\)*\"\\|'\\(?:[^%&']\\|"
 247                                          xml-pe-reference-re "\\|" xml-reference-re "\\)*'\\)")))
 248 ;;[75] ExternalID ::= 'SYSTEM' S SystemLiteral
 249 ;;                 | 'PUBLIC' S PubidLiteral S SystemLiteral
 250 ;;[76] NDataDecl ::=    S 'NDATA' S
 251 ;;[73] EntityDef  ::= EntityValue| (ExternalID NDataDecl?)
 252 ;;[71] GEDecl     ::= '<!ENTITY' S Name S EntityDef S? '>'
 253 ;;[74] PEDef      ::= EntityValue | ExternalID
 254 ;;[72] PEDecl     ::= '<!ENTITY' S '%' S Name S PEDef S? '>'
 255 ;;[70] EntityDecl ::= GEDecl | PEDecl
 256
 257 ;; Note that this is setup so that we can do whitespace-skipping with
 258 ;; `(skip-syntax-forward " ")', inter alia.  Previously this was slow
 259 ;; compared with `re-search-forward', but that has been fixed.  Also
 260 ;; note that the standard syntax table contains other characters with
 261 ;; whitespace syntax, like NBSP, but they are invalid in contexts in
 262 ;; which we might skip whitespace -- specifically, they're not
 263 ;; NameChars [XML 4].
 264
 265 (defvar xml-syntax-table
 266   (let ((table (make-syntax-table)))
 267     ;; Get space syntax correct per XML [3].
 268     (dotimes (c 31)
 269       (modify-syntax-entry c "." table)) ; all are space in standard table
 270     (dolist (c '(?\t ?\n ?\r))           ; these should be space
 271       (modify-syntax-entry c " " table))
 272     ;; For skipping attributes.
 273     (modify-syntax-entry ?\" "\"" table)
 274     (modify-syntax-entry ?' "\"" table)
 275     ;; Non-alnum name chars should be symbol constituents (`-' and `_'
 276     ;; are OK by default).
 277     (modify-syntax-entry ?. "_" table)
 278     (modify-syntax-entry ?: "_" table)
 279     ;; XML [89]
 280     (unless (featurep 'xemacs)
 281       (dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
 282                           #x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
 283                           #x30FD #x30FE))
 284         (modify-syntax-entry (decode-char 'ucs c) "w" table)))
 285     ;; Fixme: rest of [4]
 286     table)
 287   "Syntax table used by `xml-parse-region'.")
 288
 289 ;; XML [5]
 290 ;; Note that [:alpha:] matches all multibyte chars with word syntax.
 291 (eval-and-compile
 292   (defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
 293
 294 ;; Fixme:  This needs re-writing to deal with the XML grammar properly, i.e.
 295 ;;   document    ::=    prolog element Misc*
 296 ;;   prolog    ::=    XMLDecl? Misc* (doctypedecl Misc*)?
 297
 298 ;;;###autoload
 299 (defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
 300   "Parse the region from BEG to END in BUFFER.
 301 If BUFFER is nil, it defaults to the current buffer.
 302 Returns the XML list for the region, or raises an error if the region
 303 is not well-formed XML.
 304 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 305 and returned as the first element of the list.
 306 If PARSE-NS is non-nil, then QNAMES are expanded."
 307   ;; Use fixed syntax table to ensure regexp char classes and syntax
 308   ;; specs DTRT.
 309   (with-syntax-table (standard-syntax-table)
 310     (let ((case-fold-search nil)        ; XML is case-sensitive.
 311           xml result dtd)
 312       (save-excursion
 313         (if buffer
 314             (set-buffer buffer))
 315         (save-restriction
 316           (narrow-to-region beg end)
 317           (goto-char (point-min))
 318           (while (not (eobp))
 319             (if (search-forward "<" nil t)
 320                 (progn
 321                   (forward-char -1)
 322                   (setq result (xml-parse-tag parse-dtd parse-ns))
 323                   (cond
 324                    ((null result)
 325                     ;; Not looking at an xml start tag.
 326                     (forward-char 1))
 327                    ((and xml (not xml-sub-parser))
 328                     ;; Translation of rule [1] of XML specifications
 329                     (error "XML: (Not Well-Formed) Only one root tag allowed"))
 330                    ((and (listp (car result))
 331                          parse-dtd)
 332                     (setq dtd (car result))
 333                     (if (cdr result)    ; possible leading comment
 334                         (add-to-list 'xml (cdr result))))
 335                    (t
 336                     (add-to-list 'xml result))))
 337               (goto-char (point-max))))
 338           (if parse-dtd
 339               (cons dtd (nreverse xml))
 340             (nreverse xml)))))))
 341
 342 (defun xml-maybe-do-ns (name default xml-ns)
 343   "Perform any namespace expansion.
 344 NAME is the name to perform the expansion on.
 345 DEFAULT is the default namespace.  XML-NS is a cons of namespace
 346 names to uris.  When namespace-aware parsing is off, then XML-NS
 347 is nil.
 348
 349 During namespace-aware parsing, any name without a namespace is
 350 put into the namespace identified by DEFAULT.  nil is used to
 351 specify that the name shouldn't be given a namespace."
 352   (if (consp xml-ns)
 353       (let* ((nsp (string-match ":" name))
 354              (lname (if nsp (substring name (match-end 0)) name))
 355              (prefix (if nsp (substring name 0 (match-beginning 0)) default))
 356              (special (and (string-equal lname "xmlns") (not prefix)))
 357              ;; Setting default to nil will insure that there is not
 358              ;; matching cons in xml-ns.  In which case we
 359              (ns (or (cdr (assoc (if special "xmlns" prefix)
 360                                  xml-ns))
 361                      "")))
 362         (cons ns (if special "" lname)))
 363     (intern name)))
 364
 365 (defun xml-parse-fragment (&optional parse-dtd parse-ns)
 366   "Parse xml-like fragments."
 367   (let ((xml-sub-parser t)
 368         children)
 369     (while (not (eobp))
 370       (let ((bit (xml-parse-tag
 371                   parse-dtd parse-ns)))
 372         (if children
 373             (setq children (append (list bit) children))
 374           (if (stringp bit)
 375               (setq children (list bit))
 376             (setq children bit)))))
 377     (reverse children)))
 378
 379 (defun xml-parse-tag (&optional parse-dtd parse-ns)
 380   "Parse the tag at point.
 381 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 382 returned as the first element in the list.
 383 If PARSE-NS is non-nil, then QNAMES are expanded.
 384 Returns one of:
 385  - a list : the matching node
 386  - nil    : the point is not looking at a tag.
 387  - a pair : the first element is the DTD, the second is the node."
 388   (let ((xml-validating-parser (or parse-dtd xml-validating-parser))
 389         (xml-ns (if (consp parse-ns)
 390                     parse-ns
 391                   (if parse-ns
 392                       (list
 393                        ;; Default for empty prefix is no namespace
 394                        (cons ""      "")
 395                        ;; "xml" namespace
 396                        (cons "xml"   "http://www.w3.org/XML/1998/namespace")
 397                        ;; We need to seed the xmlns namespace
 398                        (cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
 399     (cond
 400      ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 401      ;; beginning of a document).
 402      ((looking-at "<\\?")
 403       (search-forward "?>")
 404       (skip-syntax-forward " ")
 405       (xml-parse-tag parse-dtd xml-ns))
 406      ;;  Character data (CDATA) sections, in which no tag should be interpreted
 407      ((looking-at "<!\\[CDATA\\[")
 408       (let ((pos (match-end 0)))
 409         (unless (search-forward "]]>" nil t)
 410           (error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
 411         (concat
 412          (buffer-substring-no-properties pos (match-beginning 0))
 413          (xml-parse-string))))
 414      ;;  DTD for the document
 415      ((looking-at "<!DOCTYPE")
 416       (let ((dtd (xml-parse-dtd parse-ns)))
 417         (skip-syntax-forward " ")
 418         (if xml-validating-parser
 419             (cons dtd (xml-parse-tag nil xml-ns))
 420           (xml-parse-tag nil xml-ns))))
 421      ;;  skip comments
 422      ((looking-at "<!--")
 423       (search-forward "-->")
 424       nil)
 425      ;;  end tag
 426      ((looking-at "</")
 427       '())
 428      ;;  opening tag
 429      ((looking-at "<\\([^/>[:space:]]+\\)")
 430       (goto-char (match-end 1))
 431
 432       ;; Parse this node
 433       (let* ((node-name (match-string-no-properties 1))
 434              ;; Parse the attribute list.
 435              (attrs (xml-parse-attlist xml-ns))
 436              children pos)
 437
 438         ;; add the xmlns:* attrs to our cache
 439         (when (consp xml-ns)
 440           (dolist (attr attrs)
 441             (when (and (consp (car attr))
 442                        (equal "http://www.w3.org/2000/xmlns/"
 443                               (caar attr)))
 444               (push (cons (cdar attr) (cdr attr))
 445                     xml-ns))))
 446
 447         (setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
 448
 449         ;; is this an empty element ?
 450         (if (looking-at "/>")
 451             (progn
 452               (forward-char 2)
 453               (nreverse children))
 454
 455           ;; is this a valid start tag ?
 456           (if (eq (char-after) ?>)
 457               (progn
 458                 (forward-char 1)
 459                 ;;  Now check that we have the right end-tag. Note that this
 460                 ;;  one might contain spaces after the tag name
 461                 (let ((end (concat "</" node-name "\\s-*>")))
 462                   (while (not (looking-at end))
 463                     (cond
 464                      ((looking-at "</")
 465                       (error "XML: (Not Well-Formed) Invalid end tag (expecting %s) at pos %d"
 466                              node-name (point)))
 467                      ((= (char-after) ?<)
 468                       (let ((tag (xml-parse-tag nil xml-ns)))
 469                         (when tag
 470                           (push tag children))))
 471                      (t
 472                       (let ((expansion (xml-parse-string)))
 473                         (setq children
 474                               (if (stringp expansion)
 475                                   (if (stringp (car children))
 476                                       ;; The two strings were separated by a comment.
 477                                       (setq children (append (list (concat (car children) expansion))
 478                                                              (cdr children)))
 479                                     (setq children (append (list expansion) children)))
 480                                 (setq children (append expansion children))))))))
 481
 482                   (goto-char (match-end 0))
 483                   (nreverse children)))
 484             ;;  This was an invalid start tag (Expected ">", but didn't see it.)
 485             (error "XML: (Well-Formed) Couldn't parse tag: %s"
 486                    (buffer-substring-no-properties (- (point) 10) (+ (point) 1)))))))
 487      (t ;; (Not one of PI, CDATA, Comment, End tag, or Start tag)
 488       (unless xml-sub-parser            ; Usually, we error out.
 489         (error "XML: (Well-Formed) Invalid character"))
 490
 491       ;; However, if we're parsing incrementally, then we need to deal
 492       ;; with stray CDATA.
 493       (xml-parse-string)))))
 494
 495 (defun xml-parse-string ()
 496   "Parse the next whatever.  Could be a string, or an element."
 497   (let* ((pos (point))
 498          (string (progn (skip-chars-forward "^<")
 499                         (buffer-substring-no-properties pos (point)))))
 500     ;; Clean up the string.  As per XML specifications, the XML
 501     ;; processor should always pass the whole string to the
 502     ;; application.  But \r's should be replaced:
 503     ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 504     (setq pos 0)
 505     (while (string-match "\r\n?" string pos)
 506       (setq string (replace-match "\n" t t string))
 507       (setq pos (1+ (match-beginning 0))))
 508
 509     (xml-substitute-special string)))
 510
 511 (defun xml-parse-attlist (&optional xml-ns)
 512   "Return the attribute-list after point.
 513 Leave point at the first non-blank character after the tag."
 514   (let ((attlist ())
 515         end-pos name)
 516     (skip-syntax-forward " ")
 517     (while (looking-at (eval-when-compile
 518                          (concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
 519       (setq end-pos (match-end 0))
 520       (setq name (xml-maybe-do-ns (match-string-no-properties 1) nil xml-ns))
 521       (goto-char end-pos)
 522
 523       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 524
 525       ;; Do we have a string between quotes (or double-quotes),
 526       ;;  or a simple word ?
 527       (if (looking-at "\"\\([^\"]*\\)\"")
 528           (setq end-pos (match-end 0))
 529         (if (looking-at "'\\([^']*\\)'")
 530             (setq end-pos (match-end 0))
 531           (error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
 532
 533       ;; Each attribute must be unique within a given element
 534       (if (assoc name attlist)
 535           (error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
 536
 537       ;; Multiple whitespace characters should be replaced with a single one
 538       ;; in the attributes
 539       (let ((string (match-string-no-properties 1))
 540             (pos 0))
 541         (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
 542         (let ((expansion (xml-substitute-special string)))
 543           (unless (stringp expansion)
 544                                         ; We say this is the constraint.  It is acctually that
 545                                         ; external entities nor "<" can be in an attribute value.
 546             (error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
 547           (push (cons name expansion) attlist)))
 548
 549       (goto-char end-pos)
 550       (skip-syntax-forward " "))
 551     (nreverse attlist)))
 552
 553 ;;*******************************************************************
 554 ;;**
 555 ;;**  The DTD (document type declaration)
 556 ;;**  The following functions know how to skip or parse the DTD of
 557 ;;**  a document
 558 ;;**
 559 ;;*******************************************************************
 560
 561 ;; Fixme: This fails at least if the DTD contains conditional sections.
 562
 563 (defun xml-skip-dtd ()
 564   "Skip the DTD at point.
 565 This follows the rule [28] in the XML specifications."
 566   (let ((xml-validating-parser nil))
 567     (xml-parse-dtd)))
 568
 569 (defun xml-parse-dtd (&optional parse-ns)
 570   "Parse the DTD at point."
 571   (forward-char (eval-when-compile (length "<!DOCTYPE")))
 572   (skip-syntax-forward " ")
 573   (if (and (looking-at ">")
 574            xml-validating-parser)
 575       (error "XML: (Validity) Invalid DTD (expecting name of the document)"))
 576
 577   ;;  Get the name of the document
 578   (looking-at xml-name-regexp)
 579   (let ((dtd (list (match-string-no-properties 0) 'dtd))
 580         type element end-pos)
 581     (goto-char (match-end 0))
 582
 583     (skip-syntax-forward " ")
 584     ;; XML [75]
 585     (cond ((looking-at "PUBLIC\\s-+")
 586            (goto-char (match-end 0))
 587            (unless (or (re-search-forward
 588                         "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
 589                         nil t)
 590                        (re-search-forward
 591                         "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
 592                         nil t))
 593              (error "XML: Missing Public ID"))
 594            (let ((pubid (match-string-no-properties 1)))
 595              (skip-syntax-forward " ")
 596              (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 597                          (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 598                (error "XML: Missing System ID"))
 599              (push (list pubid (match-string-no-properties 1) 'public) dtd)))
 600           ((looking-at "SYSTEM\\s-+")
 601            (goto-char (match-end 0))
 602            (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 603                        (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 604              (error "XML: Missing System ID"))
 605            (push (list (match-string-no-properties 1) 'system) dtd)))
 606     (skip-syntax-forward " ")
 607     (if (eq ?> (char-after))
 608         (forward-char)
 609       (if (not (eq (char-after) ?\[))
 610           (error "XML: Bad DTD")
 611         (forward-char)
 612         ;;  Parse the rest of the DTD
 613         ;;  Fixme: Deal with NOTATION, PIs.
 614         (while (not (looking-at "\\s-*\\]"))
 615           (skip-syntax-forward " ")
 616           (cond
 617
 618            ;;  Translation of rule [45] of XML specifications
 619            ((looking-at
 620              "<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
 621
 622             (setq element (match-string-no-properties 1)
 623                   type    (match-string-no-properties 2))
 624             (setq end-pos (match-end 0))
 625
 626             ;;  Translation of rule [46] of XML specifications
 627             (cond
 628              ((string-match "^EMPTY[ \t\n\r]*$" type) ;; empty declaration
 629               (setq type 'empty))
 630              ((string-match "^ANY[ \t\n\r]*$" type) ;; any type of contents
 631               (setq type 'any))
 632              ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 633               (setq type (xml-parse-elem-type (match-string-no-properties 1 type))))
 634              ((string-match "^%[^;]+;[ \t\n\r]*$" type) ;; substitution
 635               nil)
 636              (t
 637               (if xml-validating-parser
 638                   (error "XML: (Validity) Invalid element type in the DTD"))))
 639
 640             ;;  rule [45]: the element declaration must be unique
 641             (if (and (assoc element dtd)
 642                      xml-validating-parser)
 643                 (error "XML: (Validity) Element declarations must be unique in a DTD (<%s>)"
 644                        element))
 645
 646             ;;  Store the element in the DTD
 647             (push (list element type) dtd)
 648             (goto-char end-pos))
 649
 650            ;; Translation of rule [52] of XML specifications
 651            ((looking-at (concat "<!ATTLIST[ \t\n\r]*\\(" xml-name-re
 652                                 "\\)[ \t\n\r]*\\(" xml-att-def-re
 653                                 "\\)*[ \t\n\r]*>"))
 654
 655             ;; We don't do anything with ATTLIST currently
 656             (goto-char (match-end 0)))
 657
 658            ((looking-at "<!--")
 659             (search-forward "-->"))
 660            ((looking-at (concat "<!ENTITY[ \t\n\r]*\\(" xml-name-re
 661                                 "\\)[ \t\n\r]*\\(" xml-entity-value-re
 662                                 "\\)[ \t\n\r]*>"))
 663             (let ((name  (match-string-no-properties 1))
 664                   (value (substring (match-string-no-properties 2) 1
 665                                     (- (length (match-string-no-properties 2)) 1))))
 666               (goto-char (match-end 0))
 667               (setq xml-entity-alist
 668                     (append xml-entity-alist
 669                             (list (cons name
 670                                         (with-temp-buffer
 671                                           (insert value)
 672                                           (goto-char (point-min))
 673                                           (xml-parse-fragment
 674                                            xml-validating-parser
 675                                            parse-ns))))))))
 676            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 677                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 678                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 679                 (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 680                                     "\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
 681                                     "\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 682                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
 683                                     "[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
 684                                     "[ \t\n\r]*>")))
 685             (let ((name  (match-string-no-properties 1))
 686                   (file  (substring (match-string-no-properties 2) 1
 687                                     (- (length (match-string-no-properties 2)) 1))))
 688               (goto-char (match-end 0))
 689               (setq xml-entity-alist
 690                     (append xml-entity-alist
 691                             (list (cons name (with-temp-buffer
 692                                                (insert-file-contents file)
 693                                                (goto-char (point-min))
 694                                                (xml-parse-fragment
 695                                                 xml-validating-parser
 696                                                 parse-ns))))))))
 697            ;; skip parameter entity declarations
 698            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+%[ \t\n\r]+\\(" xml-name-re
 699                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 700                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 701                 (looking-at (concat "<!ENTITY[ \t\n\r]+"
 702                                     "%[ \t\n\r]+"
 703                                     "\\(" xml-name-re "\\)[ \t\n\r]+"
 704                                     "PUBLIC[ \t\n\r]+"
 705                                     "\\(\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 706                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'\\)[ \t\n\r]+"
 707                                     "\\(\"[^\"]+\"\\|'[^']+'\\)"
 708                                     "[ \t\n\r]*>")))
 709             (goto-char (match-end 0)))
 710            ;; skip parameter entities
 711            ((looking-at (concat "%" xml-name-re ";"))
 712             (goto-char (match-end 0)))
 713            (t
 714             (when xml-validating-parser
 715               (error "XML: (Validity) Invalid DTD item"))))))
 716       (if (looking-at "\\s-*]>")
 717           (goto-char (match-end 0))))
 718     (nreverse dtd)))
 719
 720 (defun xml-parse-elem-type (string)
 721   "Convert element type STRING into a Lisp structure."
 722
 723   (let (elem modifier)
 724     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 725         (progn
 726           (setq elem     (match-string-no-properties 1 string)
 727                 modifier (match-string-no-properties 2 string))
 728           (if (string-match "|" elem)
 729               (setq elem (cons 'choice
 730                                (mapcar 'xml-parse-elem-type
 731                                        (split-string elem "|"))))
 732             (if (string-match "," elem)
 733                 (setq elem (cons 'seq
 734                                  (mapcar 'xml-parse-elem-type
 735                                          (split-string elem ",")))))))
 736       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 737           (setq elem     (match-string-no-properties 1 string)
 738                 modifier (match-string-no-properties 2 string))))
 739
 740     (if (and (stringp elem) (string= elem "#PCDATA"))
 741         (setq elem 'pcdata))
 742
 743     (cond
 744      ((string= modifier "+")
 745       (list '+ elem))
 746      ((string= modifier "*")
 747       (list '* elem))
 748      ((string= modifier "?")
 749       (list '\? elem))
 750      (t
 751       elem))))
 752
 753 ;;*******************************************************************
 754 ;;**
 755 ;;**  Substituting special XML sequences
 756 ;;**
 757 ;;*******************************************************************
 758
 759 (defun xml-substitute-special (string)
 760   "Return STRING, after subsituting entity references."
 761   ;; This originally made repeated passes through the string from the
 762   ;; beginning, which isn't correct, since then either "&amp;amp;" or
 763   ;; "&#38;amp;" won't DTRT.
 764
 765   (let ((point 0)
 766         children end-point)
 767     (while (string-match "&\\([^;]*\\);" string point)
 768       (setq end-point (match-end 0))
 769       (let* ((this-part (match-string-no-properties 1 string))
 770              (prev-part (substring string point (match-beginning 0)))
 771              (entity (assoc this-part xml-entity-alist))
 772              (expansion
 773               (cond ((string-match "#\\([0-9]+\\)" this-part)
 774                      (let ((c (decode-char
 775                                'ucs
 776                                (string-to-number (match-string-no-properties 1 this-part)))))
 777                        (if c (string c))))
 778                     ((string-match "#x\\([[:xdigit:]]+\\)" this-part)
 779                      (let ((c (decode-char
 780                                'ucs
 781                                (string-to-number (match-string-no-properties 1 this-part) 16))))
 782                        (if c (string c))))
 783                     (entity
 784                      (cdr entity))
 785                     ((eq (length this-part) 0)
 786                      (error "XML: (Not Well-Formed) No entity given"))
 787                     (t
 788                      (if xml-validating-parser
 789                          (error "XML: (Validity) Undefined entity `%s'"
 790                                 this-part)
 791                        xml-undefined-entity)))))
 792
 793         (cond ((null children)
 794                ;; FIXME: If we have an entity that expands into XML, this won't work.
 795                (setq children
 796                      (concat prev-part expansion)))
 797               ((stringp children)
 798                (if (stringp expansion)
 799                    (setq children (concat children prev-part expansion))
 800                  (setq children (list expansion (concat prev-part children)))))
 801               ((and (stringp expansion)
 802                     (stringp (car children)))
 803                (setcar children (concat prev-part expansion (car children))))
 804               ((stringp expansion)
 805                (setq children (append (concat prev-part expansion)
 806                                       children)))
 807               ((stringp (car children))
 808                (setcar children (concat (car children) prev-part))
 809                (setq children (append expansion children)))
 810               (t
 811                (setq children (list expansion
 812                                     prev-part
 813                                     children))))
 814         (setq point end-point)))
 815     (cond ((stringp children)
 816            (concat children (substring string point)))
 817           ((stringp (car (last children)))
 818            (concat (car (last children)) (substring string point)))
 819           ((null children)
 820            string)
 821           (t
 822            (concat (mapconcat 'identity
 823                               (nreverse children)
 824                               "")
 825                    (substring string point))))))
 826
 827 (defun xml-substitute-numeric-entities (string)
 828   "Substitute SGML numeric entities by their respective utf characters.
 829 This function replaces numeric entities in the input STRING and
 830 returns the modified string.  For example \"&#42;\" gets replaced
 831 by \"*\"."
 832   (if (and string (stringp string))
 833       (let ((start 0))
 834         (while (string-match "&#\\([0-9]+\\);" string start)
 835           (condition-case nil
 836               (setq string (replace-match
 837                             (string (read (substring string
 838                                                      (match-beginning 1)
 839                                                      (match-end 1))))
 840                             nil nil string))
 841             (error nil))
 842           (setq start (1+ (match-beginning 0))))
 843         string)
 844     nil))
 845
 846 ;;*******************************************************************
 847 ;;**
 848 ;;**  Printing a tree.
 849 ;;**  This function is intended mainly for debugging purposes.
 850 ;;**
 851 ;;*******************************************************************
 852
 853 (defun xml-debug-print (xml &optional indent-string)
 854   "Outputs the XML in the current buffer.
 855 XML can be a tree or a list of nodes.
 856 The first line is indented with the optional INDENT-STRING."
 857   (setq indent-string (or indent-string ""))
 858   (dolist (node xml)
 859     (xml-debug-print-internal node indent-string)))
 860
 861 (defalias 'xml-print 'xml-debug-print)
 862
 863 (defun xml-escape-string (string)
 864   "Return the string with entity substitutions made from
 865 xml-entity-alist."
 866   (mapconcat (lambda (byte)
 867                (let ((char (char-to-string byte)))
 868                  (if (rassoc char xml-entity-alist)
 869                      (concat "&" (car (rassoc char xml-entity-alist)) ";")
 870                    char)))
 871              ;; This differs from the non-unicode branch.  Just
 872              ;; grabbing the string works here.
 873              string ""))
 874
 875 (defun xml-debug-print-internal (xml indent-string)
 876   "Outputs the XML tree in the current buffer.
 877 The first line is indented with INDENT-STRING."
 878   (let ((tree xml)
 879         attlist)
 880     (insert indent-string ?< (symbol-name (xml-node-name tree)))
 881
 882     ;;  output the attribute list
 883     (setq attlist (xml-node-attributes tree))
 884     (while attlist
 885       (insert ?\  (symbol-name (caar attlist)) "=\""
 886               (xml-escape-string (cdar attlist)) ?\")
 887       (setq attlist (cdr attlist)))
 888
 889     (setq tree (xml-node-children tree))
 890
 891     (if (null tree)
 892         (insert ?/ ?>)
 893       (insert ?>)
 894
 895       ;;  output the children
 896       (dolist (node tree)
 897         (cond
 898          ((listp node)
 899           (insert ?\n)
 900           (xml-debug-print-internal node (concat indent-string "  ")))
 901          ((stringp node)
 902           (insert (xml-escape-string node)))
 903          (t
 904           (error "Invalid XML tree"))))
 905
 906       (when (not (and (null (cdr tree))
 907                       (stringp (car tree))))
 908         (insert ?\n indent-string))
 909       (insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
 910
 911 (provide 'xml)
 912
 913 ;;; xml.el ends here