lisp/pcvs.el

   1 ;;; pcvs.el --- a front-end to CVS
   2
   3 ;; Copyright (C) 1991,92,93,94,95,95,97,98,99,2000,02,03,2004
   4 ;;               Free Software Foundation, Inc.
   5
   6 ;; Author: (The PCL-CVS Trust) pcl-cvs@cyclic.com
   7 ;;      (Per Cederqvist) ceder@lysator.liu.se
   8 ;;      (Greg A. Woods) woods@weird.com
   9 ;;      (Jim Blandy) jimb@cyclic.com
  10 ;;      (Karl Fogel) kfogel@floss.red-bean.com
  11 ;;      (Jim Kingdon) kingdon@cyclic.com
  12 ;;      (Stefan Monnier) monnier@cs.yale.edu
  13 ;;      (Greg Klanderman) greg@alphatech.com
  14 ;;      (Jari Aalto+mail.emacs) jari.aalto@poboxes.com
  15 ;; Maintainer: (Stefan Monnier) monnier@gnu.org
  16 ;; Keywords: CVS, version control, release management
  17
  18 ;; This file is part of GNU Emacs.
  19
  20 ;; GNU Emacs is free software; you can redistribute it and/or modify
  21 ;; it under the terms of the GNU General Public License as published by
  22 ;; the Free Software Foundation; either version 2, or (at your option)
  23 ;; any later version.
  24
  25 ;; GNU Emacs is distributed in the hope that it will be useful,
  26 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  27 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  28 ;; GNU General Public License for more details.
  29
  30 ;; You should have received a copy of the GNU General Public License
  31 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  32 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  33 ;; Boston, MA 02111-1307, USA.
  34
  35 ;;; Commentary:
  36
  37 ;; PCL-CVS is a front-end to the CVS version control system.  For people
  38 ;; familiar with VC, it is somewhat like VC-dired: it presents the status of
  39 ;; all the files in your working area and allows you to commit/update several
  40 ;; of them at a time.  Compared to VC-dired, it is considerably better and
  41 ;; faster (but only for CVS).
  42
  43 ;; PCL-CVS was originally written by Per Cederqvist many years ago.  This
  44 ;; version derives from the XEmacs-21 version, itself based on the 2.0b2
  45 ;; version (last release from Per).  It is a thorough rework.
  46
  47 ;; Contrary to what you'd expect, PCL-CVS is not a replacement for VC but only
  48 ;; for VC-dired.  As such, I've tried to make PCL-CVS and VC interoperate
  49 ;; seamlessly (I also use VC).
  50
  51 ;; To use PCL-CVS just use `M-x cvs-examine RET <dir> RET'.
  52 ;; There is a TeXinfo manual, which can be helpful to get started.
  53
  54 ;;; Bugs:
  55
  56 ;; - Extracting an old version seems not to recognize encoding correctly.
  57 ;;   That's probably because it's done via a process rather than a file.
  58
  59 ;;; Todo:
  60
  61 ;; ******** FIX THE DOCUMENTATION *********
  62 ;;
  63 ;; - rework the displaying of error messages.
  64 ;; - allow to flush messages only
  65 ;; - allow to protect files like ChangeLog from flushing
  66 ;; - automatically cvs-mode-insert files from find-file-hook
  67 ;;   (and don't flush them as long as they are visited)
  68 ;; - query the user for cvs-get-marked (for some cmds or if nothing's selected)
  69 ;; - don't return the first (resp last) FI if the cursor is before
  70 ;;   (resp after) it.
  71 ;; - allow cvs-confirm-removals to force always confirmation.
  72 ;; - cvs-checkout should ask for a revision (with completion).
  73 ;; - removal confirmation should allow specifying another file name.
  74 ;;
  75 ;; - hide fileinfos without getting rid of them (will require ewok work).
  76 ;; - add toolbar entries
  77 ;; - marking
  78 ;;    marking directories should jump to just after the dir.
  79 ;;    allow (un)marking directories at a time with the mouse.
  80 ;;    allow cvs-cmd-do to either clear the marks or not.
  81 ;;    add a "marks active" notion, like transient-mark-mode does.
  82 ;; - liveness indicator
  83 ;; - indicate in docstring if the cmd understands the `b' prefix(es).
  84 ;; - call smerge-mode when opening CONFLICT files.
  85 ;; - have vc-checkin delegate to cvs-mode-commit when applicable
  86 ;; - higher-level CVS operations
  87 ;;    cvs-mode-rename
  88 ;;    cvs-mode-branch
  89 ;; - module-level commands
  90 ;;    add support for parsing 'modules' file ("cvs co -c")
  91 ;;    cvs-mode-rcs2log
  92 ;;    cvs-rdiff
  93 ;;    cvs-release
  94 ;;    cvs-import
  95 ;;    C-u M-x cvs-checkout should ask for a cvsroot
  96 ;;    cvs-mode-handle-new-vendor-version
  97 ;;      - checks out module, or alternately does update join
  98 ;;      - does "cvs -n tag LAST_VENDOR" to find old files into *cvs*
  99 ;;    cvs-export
 100 ;;      (with completion on tag names and hooks to help generate full releases)
 101 ;; - display stickiness information.  And current CVS/Tag as well.
 102 ;; - write 'cvs-mode-admin' to do arbitrary 'cvs admin' commands
 103 ;;   Most interesting would be version removal and log message replacement.
 104 ;;   The last one would be neat when called from log-view-mode.
 105 ;; - cvs-mode-incorporate
 106 ;;      It would merge in the status from one *cvs* buffer into another.
 107 ;;      This would be used to populate such a buffer that had been created with
 108 ;;      a `cvs {update,status,checkout} -l'.
 109 ;; - cvs-mode-(i)diff-other-{file,buffer,cvs-buffer}
 110 ;; - offer the choice to kill the process when the user kills the cvs buffer.
 111 ;;      right now, it's killed without further ado.
 112 ;; - make `cvs-mode-ignore' allow manually entering a pattern.
 113 ;;      to which dir should it apply ?
 114 ;; - cvs-mode-ignore should try to remove duplicate entries.
 115 ;; - maybe poll/check CVS/Entries files to react to external `cvs' commands ?
 116 ;; - some kind of `cvs annotate' support ?
 117 ;;      but vc-annotate can be used instead.
 118 ;; - proper `g' that passes safe args and uses either cvs-status or cvs-examine
 119 ;;   maybe also use cvs-update depending on I-don't-know-what.
 120 ;; - add message-levels so that we can hide some levels of messages
 121
 122 ;;; Code:
 123
 124 (eval-when-compile (require 'cl))
 125 (require 'ewoc)                         ;Ewoc was once cookie
 126 (require 'pcvs-defs)
 127 (require 'pcvs-util)
 128 (require 'pcvs-parse)
 129 (require 'pcvs-info)
 130
 131 \f
 132 ;;;;
 133 ;;;; global vars
 134 ;;;;
 135
 136 (defvar cvs-cookies) ;;nil
 137   ;;"Handle for the cookie structure that is displayed in the *cvs* buffer.")
 138 ;;(make-variable-buffer-local 'cvs-cookies)
 139
 140 ;;;;
 141 ;;;; Dynamically scoped variables
 142 ;;;;
 143
 144 (defvar cvs-from-vc nil "Bound to t inside VC advice.")
 145
 146 ;;;;
 147 ;;;; flags variables
 148 ;;;;
 149
 150 (defun cvs-defaults (&rest defs)
 151   (let ((defs (cvs-first defs cvs-shared-start)))
 152     (append defs
 153             (make-list (- cvs-shared-start (length defs)) (car defs))
 154             cvs-shared-flags)))
 155
 156 ;; For cvs flags, we need to add "-f" to override the cvsrc settings
 157 ;; we also want to evict the annoying -q and -Q options that hide useful
 158 ;; information from pcl-cvs.
 159 (cvs-flags-define cvs-cvs-flags '(("-f")))
 160
 161 (cvs-flags-define cvs-checkout-flags (cvs-defaults '("-P")))
 162 (cvs-flags-define cvs-status-flags (cvs-defaults '("-v") nil))
 163 (cvs-flags-define cvs-log-flags (cvs-defaults nil))
 164 (cvs-flags-define cvs-diff-flags (cvs-defaults '("-u" "-N") '("-c" "-N") '("-u" "-b")))
 165 (cvs-flags-define cvs-tag-flags (cvs-defaults nil))
 166 (cvs-flags-define cvs-add-flags (cvs-defaults nil))
 167 (cvs-flags-define cvs-commit-flags (cvs-defaults nil))
 168 (cvs-flags-define cvs-remove-flags (cvs-defaults nil))
 169 ;;(cvs-flags-define cvs-undo-flags (cvs-defaults nil))
 170 (cvs-flags-define cvs-update-flags (cvs-defaults '("-d" "-P")))
 171
 172 (defun cvs-reread-cvsrc ()
 173   "Reset the default arguments to those in the `cvs-cvsrc-file'."
 174   (interactive)
 175   (condition-case nil
 176       (with-temp-buffer
 177         (insert-file-contents cvs-cvsrc-file)
 178         ;; fetch the values
 179         (dolist (cmd '("cvs" "checkout" "status" "log" "diff" "tag"
 180                        "add" "commit" "remove" "update"))
 181           (goto-char (point-min))
 182           (when (re-search-forward
 183                  (concat "^" cmd "\\(\\s-+\\(.*\\)\\)?$") nil t)
 184             (let* ((sym (intern (concat "cvs-" cmd "-flags")))
 185                    (val (cvs-string->strings (or (match-string 2) ""))))
 186               (cvs-flags-set sym 0 val))))
 187         ;; ensure that cvs doesn't have -q or -Q
 188         (cvs-flags-set 'cvs-cvs-flags 0
 189                        (cons "-f"
 190                              (cdr (cvs-partition
 191                                    (lambda (x) (member x '("-q" "-Q" "-f")))
 192                                    (cvs-flags-query 'cvs-cvs-flags
 193                                                     nil 'noquery))))))
 194       (file-error nil)))
 195
 196 ;; initialize to cvsrc's default values
 197 (cvs-reread-cvsrc)
 198
 199 \f
 200 ;;;;
 201 ;;;; Mouse bindings and mode motion
 202 ;;;;
 203
 204 (defvar cvs-minor-current-files)
 205
 206 (defun cvs-menu (e)
 207   "Popup the CVS menu."
 208   (interactive "e")
 209   (let ((cvs-minor-current-files
 210          (list (ewoc-data (ewoc-locate
 211                            cvs-cookies (posn-point (event-end e)))))))
 212     (popup-menu cvs-menu e)))
 213
 214 (defvar cvs-mode-line-process nil
 215   "Mode-line control for displaying info on cvs process status.")
 216
 217
 218 ;;;;
 219 ;;;; Query-Type-Descriptor for Tags
 220 ;;;;
 221
 222 (autoload 'cvs-status-get-tags "cvs-status")
 223 (defun cvs-tags-list ()
 224   "Return a list of acceptable tags, ready for completions."
 225   (assert (cvs-buffer-p))
 226   (let ((marked (cvs-get-marked)))
 227     (list* '("BASE") '("HEAD")
 228            (when marked
 229              (with-temp-buffer
 230                (call-process cvs-program
 231                              nil        ;no input
 232                              t          ;output to current-buffer
 233                              nil        ;don't update display while running
 234                              "status"
 235                              "-v"
 236                              (cvs-fileinfo->full-path (car marked)))
 237                (goto-char (point-min))
 238                (let ((tags (cvs-status-get-tags)))
 239                  (when (listp tags) tags)))))))
 240
 241 (defvar cvs-tag-history nil)
 242 (defconst cvs-qtypedesc-tag
 243   (cvs-qtypedesc-create 'identity 'identity 'cvs-tags-list 'cvs-tag-history))
 244
 245 ;;;;
 246
 247 (defun cvs-mode! (&optional -cvs-mode!-fun)
 248   "Switch to the *cvs* buffer.
 249 If -CVS-MODE!-FUN is provided, it is executed *cvs* being the current buffer
 250   and with its window selected.  Else, the *cvs* buffer is simply selected.
 251 -CVS-MODE!-FUN is called interactively if applicable and else with no argument."
 252   (let* ((-cvs-mode!-buf (current-buffer))
 253          (cvsbuf (cond ((cvs-buffer-p) (current-buffer))
 254                        ((and cvs-buffer (cvs-buffer-p cvs-buffer)) cvs-buffer)
 255                        (t (error "can't find the *cvs* buffer"))))
 256          (-cvs-mode!-wrapper cvs-minor-wrap-function)
 257          (-cvs-mode!-cont (lambda ()
 258                             (save-current-buffer
 259                               (if (commandp -cvs-mode!-fun)
 260                                   (call-interactively -cvs-mode!-fun)
 261                                 (funcall -cvs-mode!-fun))))))
 262     (if (not -cvs-mode!-fun) (set-buffer cvsbuf)
 263       (let ((cvs-mode!-buf (current-buffer))
 264             (cvs-mode!-owin (selected-window))
 265             (cvs-mode!-nwin (get-buffer-window cvsbuf 'visible)))
 266         (unwind-protect
 267             (progn
 268               (set-buffer cvsbuf)
 269               (when cvs-mode!-nwin (select-window cvs-mode!-nwin))
 270               (if -cvs-mode!-wrapper
 271                   (funcall -cvs-mode!-wrapper -cvs-mode!-buf -cvs-mode!-cont)
 272                 (funcall -cvs-mode!-cont)))
 273           (set-buffer cvs-mode!-buf)
 274           (when (and cvs-mode!-nwin (eq cvs-mode!-nwin (selected-window)))
 275             ;; the selected window has not been changed by FUN
 276             (select-window cvs-mode!-owin)))))))
 277
 278 ;;;;
 279 ;;;; Prefixes
 280 ;;;;
 281
 282 (defvar cvs-branches (list cvs-vendor-branch "HEAD" "HEAD"))
 283 (cvs-prefix-define cvs-branch-prefix
 284   "Current selected branch."
 285   "version"
 286   (cons cvs-vendor-branch cvs-branches)
 287   cvs-qtypedesc-tag)
 288
 289 (defun cvs-set-branch-prefix (arg)
 290   "Set the branch prefix to take action at the next command.
 291 See `cvs-prefix-set' for a further the description of the behavior.
 292 \\[universal-argument] 1 selects the vendor branch
 293 and \\[universal-argument] 2 selects the HEAD."
 294   (interactive "P")
 295   (cvs-mode!)
 296   (cvs-prefix-set 'cvs-branch-prefix arg))
 297
 298 (defun cvs-add-branch-prefix (flags &optional arg)
 299   "Add branch selection argument if the branch prefix was set.
 300 The argument is added (or not) to the list of FLAGS and is constructed
 301 by appending the branch to ARG which defaults to \"-r\"."
 302   (let ((branch (cvs-prefix-get 'cvs-branch-prefix)))
 303     ;; deactivate the secondary prefix, even if not used.
 304     (cvs-prefix-get 'cvs-secondary-branch-prefix)
 305     (if branch (cons (concat (or arg "-r") branch) flags) flags)))
 306
 307 (cvs-prefix-define cvs-secondary-branch-prefix
 308   "Current secondary selected branch."
 309   "version"
 310   (cons cvs-vendor-branch cvs-branches)
 311   cvs-qtypedesc-tag)
 312
 313 (defun cvs-set-secondary-branch-prefix (arg)
 314   "Set the branch prefix to take action at the next command.
 315 See `cvs-prefix-set' for a further the description of the behavior.
 316 \\[universal-argument] 1 selects the vendor branch
 317 and \\[universal-argument] 2 selects the HEAD."
 318   (interactive "P")
 319   (cvs-mode!)
 320   (cvs-prefix-set 'cvs-secondary-branch-prefix arg))
 321
 322 (defun cvs-add-secondary-branch-prefix (flags &optional arg)
 323   "Add branch selection argument if the secondary branch prefix was set.
 324 The argument is added (or not) to the list of FLAGS and is constructed
 325 by appending the branch to ARG which defaults to \"-r\".
 326 Since the `cvs-secondary-branch-prefix' is only active if the primary
 327 prefix is active, it is important to read the secondary prefix before
 328 the primay since reading the primary can deactivate it."
 329   (let ((branch (and (cvs-prefix-get 'cvs-branch-prefix 'read-only)
 330                      (cvs-prefix-get 'cvs-secondary-branch-prefix))))
 331     (if branch (cons (concat (or arg "-r") branch) flags) flags)))
 332
 333 ;;;;
 334
 335 (define-minor-mode cvs-minor-mode
 336   "This mode is used for buffers related to a main *cvs* buffer.
 337 All the `cvs-mode' buffer operations are simply rebound under
 338 the \\[cvs-mode-map] prefix."
 339   nil " CVS"
 340   :group 'pcl-cvs)
 341 (put 'cvs-minor-mode 'permanent-local t)
 342
 343
 344 (defvar cvs-temp-buffers nil)
 345 (defun cvs-temp-buffer (&optional cmd normal nosetup)
 346   "Create a temporary buffer to run CMD in.
 347 If CMD is a string, use it to lookup `cvs-buffer-name-alist' to find
 348 the buffer name to be used and its `major-mode'.
 349
 350 The selected window will not be changed.  The new buffer will not maintain undo
 351 information and will be read-only unless NORMAL is non-nil.  It will be emptied
 352 \(unless NOSETUP is non-nil\) and its `default-directory' will be inherited
 353 from the current buffer."
 354   (let* ((cvs-buf (current-buffer))
 355          (info (cdr (assoc cmd cvs-buffer-name-alist)))
 356          (name (eval (nth 0 info)))
 357          (mode (nth 1 info))
 358          (dir default-directory)
 359          (buf (cond
 360                (name (cvs-get-buffer-create name))
 361                ((and (bufferp cvs-temp-buffer) (buffer-name cvs-temp-buffer))
 362                 cvs-temp-buffer)
 363                (t
 364                 (set (make-local-variable 'cvs-temp-buffer)
 365                      (cvs-get-buffer-create
 366                       (eval cvs-temp-buffer-name) 'noreuse))))))
 367
 368     ;; handle the potential pre-existing process
 369     (let ((proc (get-buffer-process buf)))
 370       (when (and (not normal) (processp proc)
 371                  (memq (process-status proc) '(run stop)))
 372         (if cmd
 373             ;; When CMD is specified, the buffer is normally shown to the
 374             ;; user, so interrupting the process is not harmful.
 375             ;; Use `delete-process' rather than `kill-process' otherwise
 376             ;; the pending output of the process will still get inserted
 377             ;; after we erase the buffer.
 378             (delete-process proc)
 379           (error "Can not run two cvs processes simultaneously"))))
 380
 381     (if (not name) (kill-local-variable 'other-window-scroll-buffer)
 382       ;; Strangely, if no window is created, `display-buffer' ends up
 383       ;; doing a `switch-to-buffer' which does a `set-buffer', hence
 384       ;; the need for `save-excursion'.
 385       (unless nosetup (save-excursion (display-buffer buf)))
 386       ;; FIXME: this doesn't do the right thing if the user later on
 387       ;; does a `find-file-other-window' and `scroll-other-window'
 388       (set (make-local-variable 'other-window-scroll-buffer) buf))
 389
 390     (add-to-list 'cvs-temp-buffers buf)
 391
 392     (with-current-buffer buf
 393       (setq buffer-read-only nil)
 394       (setq default-directory dir)
 395       (unless nosetup (erase-buffer))
 396       (set (make-local-variable 'cvs-buffer) cvs-buf)
 397       ;;(cvs-minor-mode 1)
 398       (let ((lbd list-buffers-directory))
 399         (if (fboundp mode) (funcall mode) (fundamental-mode))
 400         (when lbd (set (make-local-variable 'list-buffers-directory) lbd)))
 401       (cvs-minor-mode 1)
 402       ;;(set (make-local-variable 'cvs-buffer) cvs-buf)
 403       (unless normal
 404         (setq buffer-read-only t)
 405         (buffer-disable-undo))
 406       buf)))
 407
 408 (defun cvs-mode-kill-buffers ()
 409   "Kill all the \"temporary\" buffers created by the *cvs* buffer."
 410   (interactive)
 411   (dolist (buf cvs-temp-buffers) (ignore-errors (kill-buffer buf))))
 412
 413 (defun cvs-make-cvs-buffer (dir &optional new)
 414   "Create the *cvs* buffer for directory DIR.
 415 If non-nil, NEW means to create a new buffer no matter what."
 416   ;; the real cvs-buffer creation
 417   (setq dir (cvs-expand-dir-name dir))
 418   (let* ((buffer-name (eval cvs-buffer-name))
 419          (buffer
 420           (or (and (not new)
 421                    (eq cvs-reuse-cvs-buffer 'current)
 422                    (cvs-buffer-p)       ;reuse the current buffer if possible
 423                    (current-buffer))
 424               ;; look for another cvs buffer visiting the same directory
 425               (save-excursion
 426                 (unless new
 427                   (dolist (buffer (cons (current-buffer) (buffer-list)))
 428                     (set-buffer buffer)
 429                     (and (cvs-buffer-p)
 430                          (case cvs-reuse-cvs-buffer
 431                            (always t)
 432                            (subdir
 433                             (or (cvs-string-prefix-p default-directory dir)
 434                                 (cvs-string-prefix-p dir default-directory)))
 435                            (samedir (string= default-directory dir)))
 436                          (return buffer)))))
 437               ;; we really have to create a new buffer:
 438               ;; we temporarily bind cwd to "" to prevent
 439               ;; create-file-buffer from using directory info
 440               ;; unless it is explicitly in the cvs-buffer-name.
 441               (cvs-get-buffer-create buffer-name new))))
 442     (with-current-buffer buffer
 443       (or
 444        (and (string= dir default-directory) (cvs-buffer-p)
 445             ;; just a refresh
 446             (ignore-errors
 447               (cvs-cleanup-collection cvs-cookies nil nil t)
 448               (current-buffer)))
 449        ;; setup from scratch
 450        (progn
 451          (setq default-directory dir)
 452          (setq buffer-read-only nil)
 453          (erase-buffer)
 454          (insert "Repository : " (directory-file-name (cvs-get-cvsroot))
 455                  "\nModule     : " (cvs-get-module)
 456                  "\nWorking dir: " (abbreviate-file-name dir)
 457                  (if (not (file-readable-p "CVS/Tag")) "\n"
 458                    (let ((tag (cvs-file-to-string "CVS/Tag")))
 459                      (cond
 460                       ((string-match "\\`T" tag)
 461                        (concat "\nTag        : " (substring tag 1)))
 462                       ((string-match "\\`D" tag)
 463                        (concat "\nDate       : " (substring tag 1)))
 464                       ("\n"))))
 465                  "\n")
 466          (setq buffer-read-only t)
 467          (cvs-mode)
 468          (set (make-local-variable 'list-buffers-directory) buffer-name)
 469          ;;(set (make-local-variable 'cvs-temp-buffer) (cvs-temp-buffer))
 470          (let ((cookies (ewoc-create 'cvs-fileinfo-pp "\n" "")))
 471            (set (make-local-variable 'cvs-cookies) cookies)
 472            (add-hook 'kill-buffer-hook
 473                      (lambda ()
 474                        (ignore-errors (kill-buffer cvs-temp-buffer)))
 475                      nil t)
 476            ;;(set-buffer buf)
 477            buffer))))))
 478
 479 (defun* cvs-cmd-do (cmd dir flags fis new
 480                         &key cvsargs noexist dont-change-disc noshow)
 481   (let* ((dir (file-name-as-directory
 482                (abbreviate-file-name (expand-file-name dir))))
 483          (cvsbuf (cvs-make-cvs-buffer dir new)))
 484     ;; Check that dir is under CVS control.
 485     (unless (file-directory-p dir)
 486       (error "%s is not a directory" dir))
 487     (unless (or noexist (file-directory-p (expand-file-name "CVS" dir))
 488                 (file-expand-wildcards (expand-file-name "*/CVS" dir)))
 489       (error "%s does not contain CVS controlled files" dir))
 490
 491     (set-buffer cvsbuf)
 492     (cvs-mode-run cmd flags fis
 493                   :cvsargs cvsargs :dont-change-disc dont-change-disc)
 494
 495     (if noshow cvsbuf
 496       (let ((pop-up-windows nil)) (pop-to-buffer cvsbuf)))))
 497 ;;      (funcall (if (and (boundp 'pop-up-frames) pop-up-frames)
 498 ;;                 'pop-to-buffer 'switch-to-buffer)
 499 ;;             cvsbuf))))
 500
 501 (defun cvs-run-process (args fis postprocess &optional single-dir)
 502   (assert (cvs-buffer-p cvs-buffer))
 503   (save-current-buffer
 504     (let ((procbuf (current-buffer))
 505           (cvsbuf cvs-buffer)
 506           (single-dir (or single-dir (eq cvs-execute-single-dir t))))
 507
 508       (set-buffer procbuf)
 509       (goto-char (point-max))
 510       (unless (bolp) (let ((inhibit-read-only t)) (insert "\n")))
 511       ;; find the set of files we'll process in this round
 512       (let* ((dir+files+rest
 513               (if (or (null fis) (not single-dir))
 514                   ;; not single-dir mode: just process the whole thing
 515                   (list "" (mapcar 'cvs-fileinfo->full-path fis) nil)
 516                 ;; single-dir mode: extract the same-dir-elements
 517                 (let ((dir (cvs-fileinfo->dir (car fis))))
 518                   ;; output the concerned dir so the parser can translate paths
 519                   (let ((inhibit-read-only t))
 520                     (insert "pcl-cvs: descending directory " dir "\n"))
 521                   ;; loop to find the same-dir-elems
 522                   (do* ((files () (cons (cvs-fileinfo->file fi) files))
 523                         (fis fis (cdr fis))
 524                         (fi (car fis) (car fis)))
 525                       ((not (and fis (string= dir (cvs-fileinfo->dir fi))))
 526                        (list dir files fis))))))
 527              (dir (nth 0 dir+files+rest))
 528              (files (nth 1 dir+files+rest))
 529              (rest (nth 2 dir+files+rest)))
 530
 531         ;; setup the (current) process buffer
 532         (set (make-local-variable 'cvs-postprocess)
 533              (if (null rest)
 534                  ;; this is the last invocation
 535                  postprocess
 536                ;; else, we have to register ourselves to be rerun on the rest
 537                `(cvs-run-process ',args ',rest ',postprocess ',single-dir)))
 538         (add-hook 'kill-buffer-hook
 539                   (lambda ()
 540                     (let ((proc (get-buffer-process (current-buffer))))
 541                       (when (processp proc)
 542                         (set-process-filter proc nil)
 543                         (set-process-sentinel proc nil)
 544                         (delete-process proc))))
 545                   nil t)
 546
 547         ;; create the new process and setup the procbuffer correspondingly
 548         (let* ((args (append (cvs-flags-query 'cvs-cvs-flags nil 'noquery)
 549                              (if cvs-cvsroot (list "-d" cvs-cvsroot))
 550                              args
 551                              files))
 552                ;; If process-connection-type is nil and the repository
 553                ;; is accessed via SSH, a bad interaction between libc,
 554                ;; CVS and SSH can lead to garbled output.
 555                ;; It might be a glibc-specific problem (but it also happens
 556                ;; under Mac OS X, it seems).
 557                ;; Until the problem is cleared, we'll use a pty rather than
 558                ;; a pipe.
 559                ;; (process-connection-type nil) ; Use a pipe, not a pty.
 560                (process
 561                 ;; the process will be run in the selected dir
 562                 (let ((default-directory (cvs-expand-dir-name dir)))
 563                   (apply 'start-process "cvs" procbuf cvs-program args))))
 564           (set-process-sentinel process 'cvs-sentinel)
 565           (set-process-filter process 'cvs-update-filter)
 566           (set-marker (process-mark process) (point-max))
 567           (ignore-errors (process-send-eof process)) ;close its stdin to avoid hangs
 568
 569           ;; now finish setting up the cvs-buffer
 570           (set-buffer cvsbuf)
 571           (setq cvs-mode-line-process (symbol-name (process-status process)))
 572           (force-mode-line-update)))))
 573
 574   ;; The following line is said to improve display updates on some
 575   ;; emacsen. It shouldn't be needed, but it does no harm.
 576   (sit-for 0))
 577
 578 (defun cvs-update-header (args fis) ; inline
 579   (let* ((lastarg nil)
 580          (args (mapcar (lambda (arg)
 581                          (cond
 582                           ;; filter out the largish commit message
 583                           ((and (eq lastarg nil) (string= arg "commit"))
 584                            (setq lastarg 'commit) arg)
 585                           ((and (eq lastarg 'commit) (string= arg "-m"))
 586                            (setq lastarg '-m) arg)
 587                           ((eq lastarg '-m)
 588                            (setq lastarg 'done) "<log message>")
 589                           ;; filter out the largish `admin -mrev:msg' message
 590                           ((and (eq lastarg nil) (string= arg "admin"))
 591                            (setq lastarg 'admin) arg)
 592                           ((and (eq lastarg 'admin)
 593                                 (string-match "\\`-m[^:]*:" arg))
 594                            (setq lastarg 'done)
 595                            (concat (match-string 0 arg) "<log message>"))
 596                           ;; Keep the rest as is.
 597                           (t arg)))
 598                        args))
 599          ;; turn them into a string
 600          (arg (cvs-strings->string
 601                (append (cvs-flags-query 'cvs-cvs-flags nil 'noquery)
 602                        (if cvs-cvsroot (list "-d" cvs-cvsroot))
 603                        args
 604                        (mapcar 'cvs-fileinfo->full-path fis))))
 605          (str (if args (concat "-- Running " cvs-program " " arg " ...\n")
 606                 "\n")))
 607     (if nil (insert str)                ;inline
 608       ;;(with-current-buffer cvs-buffer
 609       (let* ((prev-msg (car (ewoc-get-hf cvs-cookies)))
 610              (tin (ewoc-nth cvs-cookies 0)))
 611         ;; look for the first *real* fileinfo (to determine emptyness)
 612         (while
 613             (and tin
 614                  (memq (cvs-fileinfo->type (ewoc-data tin))
 615                        '(MESSAGE DIRCHANGE)))
 616           (setq tin (ewoc-next cvs-cookies tin)))
 617         ;; cleanup the prev-msg
 618         (when (string-match "Running \\(.*\\) ...\n" prev-msg)
 619           (setq prev-msg
 620                 (concat
 621                  "-- last cmd: "
 622                  (match-string 1 prev-msg)
 623                  " --")))
 624         ;; set the new header and footer
 625         (ewoc-set-hf cvs-cookies
 626                      str (concat "\n--------------------- "
 627                                  (if tin "End" "Empty")
 628                                  " ---------------------\n"
 629                                  prev-msg))))))
 630
 631
 632 (defun cvs-sentinel (proc msg)
 633   "Sentinel for the cvs update process.
 634 This is responsible for parsing the output from the cvs update when
 635 it is finished."
 636   (when (memq (process-status proc) '(signal exit))
 637     (if (null (buffer-name (process-buffer proc)))
 638         ;;(set-process-buffer proc nil)
 639         (error "cvs' process buffer was killed")
 640       (let* ((obuf (current-buffer))
 641              (procbuffer (process-buffer proc)))
 642         (set-buffer (with-current-buffer procbuffer cvs-buffer))
 643         (setq cvs-mode-line-process (symbol-name (process-status proc)))
 644         (force-mode-line-update)
 645         (set-buffer procbuffer)
 646         (let ((cvs-postproc cvs-postprocess))
 647           ;; Since the buffer and mode line will show that the
 648           ;; process is dead, we can delete it now.  Otherwise it
 649           ;; will stay around until M-x list-processes.
 650           (delete-process proc)
 651           (setq cvs-postprocess nil)
 652           ;; do the postprocessing like parsing and such
 653           (save-excursion (eval cvs-postproc))
 654           ;; check whether something is left
 655           (unless cvs-postprocess
 656             ;; IIRC, we enable undo again once the process is finished
 657             ;; for cases where the output was inserted in *vc-diff* or
 658             ;; in a file-like buffer.  -stef
 659             (buffer-enable-undo)
 660             (with-current-buffer cvs-buffer
 661               (cvs-update-header nil nil) ;FIXME: might need to be inline
 662               (message "CVS process has completed in %s" (buffer-name)))))
 663         ;; This might not even be necessary
 664         (set-buffer obuf)))))
 665
 666 (defun cvs-parse-process (dcd &optional subdir old-fis)
 667   "Parse the output of a cvs process.
 668 DCD is the `dont-change-disc' flag to use when parsing that output.
 669 SUBDIR is the subdirectory (if any) where this command was run.
 670 OLD-FIS is the list of fileinfos on which the cvs command was applied and
 671   which should be considered up-to-date if they are missing from the output."
 672   (when (eq system-type 'darwin)
 673     ;; Fixup the ^D^H^H inserted at beginning of buffer sometimes on MacOSX
 674     ;; because of the call to `process-send-eof'.
 675     (save-excursion
 676       (goto-char (point-min))
 677       (while (re-search-forward "^\\^D\b+" nil t)
 678         (let ((inhibit-read-only t))
 679           (delete-region (match-beginning 0) (match-end 0))))))
 680   (let* ((fileinfos (cvs-parse-buffer 'cvs-parse-table dcd subdir))
 681          last)
 682     (with-current-buffer cvs-buffer
 683       ;; Expand OLD-FIS to actual files.
 684       (let ((fis nil))
 685         (dolist (fi old-fis)
 686           (setq fis (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
 687                         (nconc (ewoc-collect cvs-cookies 'cvs-dir-member-p
 688                                              (cvs-fileinfo->dir fi))
 689                                fis)
 690                       (cons fi fis))))
 691         (setq old-fis fis))
 692       ;; Drop OLD-FIS which were already up-to-date.
 693       (let ((fis nil))
 694         (dolist (fi old-fis)
 695           (unless (eq (cvs-fileinfo->type fi) 'UP-TO-DATE) (push fi fis)))
 696         (setq old-fis fis))
 697       ;; Add the new fileinfos to the ewoc.
 698       (dolist (fi fileinfos)
 699         (setq last (cvs-addto-collection cvs-cookies fi last))
 700         ;; This FI was in the output, so remove it from OLD-FIS.
 701         (setq old-fis (delq (ewoc-data last) old-fis)))
 702       ;; Process the "silent output" (i.e. absence means up-to-date).
 703       (dolist (fi old-fis)
 704         (setf (cvs-fileinfo->type fi) 'UP-TO-DATE)
 705         (setq last (cvs-addto-collection cvs-cookies fi last)))
 706       (setq fileinfos (nconc old-fis fileinfos))
 707       ;; Clean up the ewoc as requested by the user.
 708       (cvs-cleanup-collection cvs-cookies
 709                               (eq cvs-auto-remove-handled t)
 710                               cvs-auto-remove-directories
 711                               nil)
 712       ;; Revert buffers if necessary.
 713       (when (and cvs-auto-revert (not dcd) (not cvs-from-vc))
 714         (cvs-revert-if-needed fileinfos)))))
 715
 716 (defmacro defun-cvs-mode (fun args docstring interact &rest body)
 717   "Define a function to be used in a *cvs* buffer.
 718 This will look for a *cvs* buffer and execute BODY in it.
 719 Since the interactive arguments might need to be queried after
 720 switching to the *cvs* buffer, the generic code is rather ugly,
 721 but luckily we can often use simpler alternatives.
 722
 723 FUN can be either a symbol (i.e. STYLE is nil) or a cons (FUN . STYLE).
 724 ARGS and DOCSTRING are the normal argument list.
 725 INTERACT is the interactive specification or nil for non-commands.
 726
 727 STYLE can be either SIMPLE, NOARGS or DOUBLE.  It's an error for it
 728 to have any other value, unless other details of the function make it
 729 clear what alternative to use.
 730 - SIMPLE will get all the interactive arguments from the original buffer.
 731 - NOARGS will get all the arguments from the *cvs* buffer and will
 732   always behave as if called interactively.
 733 - DOUBLE is the generic case."
 734   (declare (debug (&define sexp lambda-list stringp ("interactive" interactive) def-body)))
 735   (let ((style (cvs-cdr fun))
 736         (fun (cvs-car fun)))
 737     (cond
 738      ;; a trivial interaction, no need to move it
 739      ((or (eq style 'SIMPLE)
 740           (null (nth 1 interact))
 741           (stringp (nth 1 interact)))
 742       `(defun ,fun ,args ,docstring ,interact
 743          (cvs-mode! (lambda () ,@body))))
 744
 745      ;; fun is only called interactively:  move all the args to the inner fun
 746      ((eq style 'NOARGS)
 747       `(defun ,fun () ,docstring (interactive)
 748          (cvs-mode! (lambda ,args ,interact ,@body))))
 749
 750      ;; bad case
 751      ((eq style 'DOUBLE)
 752       (string-match ".*" docstring)
 753       (let ((line1 (match-string 0 docstring))
 754             (fun-1 (intern (concat (symbol-name fun) "-1"))))
 755         `(progn
 756            (defun ,fun-1 ,args
 757              ,(concat docstring "\nThis function only works within a *cvs* buffer.
 758 For interactive use, use `" (symbol-name fun) "' instead.")
 759              ,interact
 760              ,@body)
 761            (defun ,fun ()
 762              ,(concat line1 "\nWrapper function that switches to a *cvs* buffer
 763 before calling the real function `" (symbol-name fun-1) "'.\n")
 764              (interactive)
 765              (cvs-mode! ',fun-1)))))
 766
 767      (t (error "unknown style %s in `defun-cvs-mode'" style)))))
 768
 769 (defun-cvs-mode cvs-mode-kill-process ()
 770   "Kill the temporary buffer and associated process."
 771   (interactive)
 772   (when (and (bufferp cvs-temp-buffer) (buffer-name cvs-temp-buffer))
 773     (let ((proc (get-buffer-process cvs-temp-buffer)))
 774       (when proc (delete-process proc)))))
 775
 776 ;;
 777 ;; Maintaining the collection in the face of updates
 778 ;;
 779
 780 (defun cvs-addto-collection (c fi &optional tin)
 781   "Add FI to C and return FI's corresponding tin.
 782 FI is inserted in its proper place or maybe even merged with a preexisting
 783   fileinfo if applicable.
 784 TIN specifies an optional starting point."
 785   (unless tin (setq tin (ewoc-nth c 0)))
 786   (while (and tin (cvs-fileinfo< fi (ewoc-data tin)))
 787     (setq tin (ewoc-prev c tin)))
 788   (if (null tin) (ewoc-enter-first c fi) ;empty collection
 789     (assert (not (cvs-fileinfo< fi (ewoc-data tin))))
 790     (let ((next-tin (ewoc-next c tin)))
 791       (while (not (or (null next-tin)
 792                       (cvs-fileinfo< fi (ewoc-data next-tin))))
 793         (setq tin next-tin next-tin (ewoc-next c next-tin)))
 794       (if (or (cvs-fileinfo< (ewoc-data tin) fi)
 795               (eq (cvs-fileinfo->type  fi) 'MESSAGE))
 796           ;; tin < fi < next-tin
 797           (ewoc-enter-after c tin fi)
 798         ;; fi == tin
 799         (cvs-fileinfo-update (ewoc-data tin) fi)
 800         (ewoc-invalidate c tin)
 801         ;; Move cursor back to where it belongs.
 802         (when (bolp) (cvs-move-to-goal-column))
 803         tin))))
 804
 805 (defcustom cvs-cleanup-functions nil
 806   "Functions to tweak the cleanup process.
 807 The functions are called with a single argument (a FILEINFO) and should
 808 return a non-nil value if that fileinfo should be removed."
 809   :group 'pcl-cvs
 810   :type '(hook :options (cvs-cleanup-removed)))
 811
 812 (defun cvs-cleanup-removed (fi)
 813   "Non-nil if FI has been cvs-removed but still exists.
 814 This is intended for use on `cvs-cleanup-functions' when you have cvs-removed
 815 automatically generated files (which should hence not be under CVS control)
 816 but can't commit the removal because the repository's owner doesn't understand
 817 the problem."
 818   (and (or (eq (cvs-fileinfo->type fi) 'REMOVED)
 819            (and (eq (cvs-fileinfo->type fi) 'CONFLICT)
 820                 (eq (cvs-fileinfo->subtype fi) 'REMOVED)))
 821        (file-exists-p (cvs-fileinfo->full-path fi))))
 822
 823 ;; called at the following times:
 824 ;; - postparse  ((eq cvs-auto-remove-handled t) cvs-auto-remove-directories nil)
 825 ;; - pre-run    ((eq cvs-auto-remove-handled 'delayed) nil t)
 826 ;; - remove-handled (t (or cvs-auto-remove-directories 'handled) t)
 827 ;; - cvs-cmd-do (nil nil t)
 828 ;; - post-ignore (nil nil nil)
 829 ;; - acknowledge (nil nil nil)
 830 ;; - remove     (nil nil nil)
 831 (defun cvs-cleanup-collection (c rm-handled rm-dirs rm-msgs)
 832   "Remove undesired entries.
 833 C is the collection
 834 RM-HANDLED if non-nil means remove handled entries.
 835 RM-DIRS behaves like `cvs-auto-remove-directories'.
 836 RM-MSGS if non-nil means remove messages."
 837   (let (last-fi first-dir (rerun t))
 838     (while rerun
 839       (setq rerun nil)
 840       (setq first-dir t)
 841       (setq last-fi (cvs-create-fileinfo 'DEAD "../" "" "")) ;place-holder
 842       (ewoc-filter
 843        c (lambda (fi)
 844            (let* ((type (cvs-fileinfo->type fi))
 845                   (subtype (cvs-fileinfo->subtype fi))
 846                   (keep
 847                    (case type
 848                      ;; remove temp messages and keep the others
 849                      (MESSAGE (not (or rm-msgs (eq subtype 'TEMP))))
 850                      ;; remove entries
 851                      (DEAD nil)
 852                      ;; handled also?
 853                      (UP-TO-DATE (not rm-handled))
 854                      ;; keep the rest
 855                      (t (not (run-hook-with-args-until-success
 856                               'cvs-cleanup-functions fi))))))
 857
 858              ;; mark dirs for removal
 859              (when (and keep rm-dirs
 860                         (eq (cvs-fileinfo->type last-fi) 'DIRCHANGE)
 861                         (not (when first-dir (setq first-dir nil) t))
 862                         (or (eq rm-dirs 'all)
 863                             (not (cvs-string-prefix-p
 864                                   (cvs-fileinfo->dir last-fi)
 865                                   (cvs-fileinfo->dir fi)))
 866                             (and (eq type 'DIRCHANGE) (eq rm-dirs 'empty))
 867                             (eq subtype 'FOOTER)))
 868                (setf (cvs-fileinfo->type last-fi) 'DEAD)
 869                (setq rerun t))
 870              (when keep (setq last-fi fi)))))
 871       ;; remove empty last dir
 872       (when (and rm-dirs
 873                  (not first-dir)
 874                  (eq (cvs-fileinfo->type last-fi) 'DIRCHANGE))
 875         (setf (cvs-fileinfo->type last-fi) 'DEAD)
 876         (setq rerun t)))))
 877
 878 (defun cvs-get-cvsroot ()
 879   "Gets the CVSROOT for DIR."
 880   (let ((cvs-cvsroot-file (expand-file-name "Root" "CVS")))
 881     (or (cvs-file-to-string cvs-cvsroot-file t)
 882         cvs-cvsroot
 883         (getenv "CVSROOT")
 884         "?????")))
 885
 886 (defun cvs-get-module ()
 887   "Return the current CVS module.
 888 This usually doesn't really work but is a handy initval in a prompt."
 889   (let* ((repfile (expand-file-name "Repository" "CVS"))
 890          (rep (cvs-file-to-string repfile t)))
 891     (cond
 892      ((null rep) "")
 893      ((not (file-name-absolute-p rep)) rep)
 894      (t
 895       (let* ((root (cvs-get-cvsroot))
 896              (str (concat (file-name-as-directory (or root "/")) " || " rep)))
 897         (if (and root (string-match "\\(.*\\) || \\1\\(.*\\)\\'" str))
 898             (match-string 2 str)
 899           (file-name-nondirectory rep)))))))
 900
 901
 902 \f
 903 ;;;;
 904 ;;;; running a "cvs checkout".
 905 ;;;;
 906
 907 ;;;###autoload
 908 (defun cvs-checkout (modules dir flags)
 909   "Run a 'cvs checkout MODULES' in DIR.
 910 Feed the output to a *cvs* buffer, display it in the current window,
 911 and run `cvs-mode' on it.
 912
 913 With a prefix argument, prompt for cvs FLAGS to use."
 914   (interactive
 915    (list (cvs-string->strings (read-string "Module(s): " (cvs-get-module)))
 916          (read-directory-name "CVS Checkout Directory: "
 917                          nil default-directory nil)
 918          (cvs-add-branch-prefix
 919           (cvs-flags-query 'cvs-checkout-flags "cvs checkout flags"))))
 920   (when (eq flags t)
 921     (setf flags (cvs-flags-query 'cvs-checkout-flags nil 'noquery)))
 922   (cvs-cmd-do "checkout" (or dir default-directory)
 923               (append flags modules) nil 'new
 924               :noexist t))
 925
 926 \f
 927 ;;;;
 928 ;;;; The code for running a "cvs update" and friends in various ways.
 929 ;;;;
 930
 931 (defun-cvs-mode (cvs-mode-revert-buffer . SIMPLE)
 932                 (&optional ignore-auto noconfirm)
 933   "Rerun `cvs-examine' on the current directory with the default flags."
 934   (interactive)
 935   (cvs-examine default-directory t))
 936
 937 (defun cvs-query-directory (msg)
 938   ;; last-command-char = ?\r hints that the command was run via M-x
 939   (if (and (cvs-buffer-p)
 940            (not current-prefix-arg)
 941            (not (eq last-command-char ?\r)))
 942       default-directory
 943     (read-directory-name msg nil default-directory nil)))
 944
 945 ;;;###autoload
 946 (defun cvs-quickdir (dir &optional flags noshow)
 947   "Open a *cvs* buffer on DIR without running cvs.
 948 With a prefix argument, prompt for a directory to use.
 949 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
 950   prevents reuse of an existing *cvs* buffer.
 951 Optional argument NOSHOW if non-nil means not to display the buffer.
 952 FLAGS is ignored."
 953   (interactive (list (cvs-query-directory "CVS quickdir (directory): ")))
 954   ;; FIXME: code duplication with cvs-cmd-do and cvs-parse-process
 955   (let* ((dir (file-name-as-directory
 956                (abbreviate-file-name (expand-file-name dir))))
 957          (new (> (prefix-numeric-value current-prefix-arg) 8))
 958          (cvsbuf (cvs-make-cvs-buffer dir new))
 959          last)
 960     ;; Check that dir is under CVS control.
 961     (unless (file-directory-p dir)
 962       (error "%s is not a directory" dir))
 963     (unless (file-directory-p (expand-file-name "CVS" dir))
 964       (error "%s does not contain CVS controlled files" dir))
 965     (set-buffer cvsbuf)
 966     (dolist (fi (cvs-fileinfo-from-entries ""))
 967       (setq last (cvs-addto-collection cvs-cookies fi last)))
 968     (cvs-cleanup-collection cvs-cookies
 969                             (eq cvs-auto-remove-handled t)
 970                             cvs-auto-remove-directories
 971                             nil)
 972     (if noshow cvsbuf
 973       (let ((pop-up-windows nil)) (pop-to-buffer cvsbuf)))))
 974
 975 ;;;###autoload
 976 (defun cvs-examine (directory flags &optional noshow)
 977   "Run a `cvs -n update' in the specified DIRECTORY.
 978 That is, check what needs to be done, but don't change the disc.
 979 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
 980 With a prefix argument, prompt for a directory and cvs FLAGS to use.
 981 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
 982   prevents reuse of an existing *cvs* buffer.
 983 Optional argument NOSHOW if non-nil means not to display the buffer."
 984   (interactive (list (cvs-query-directory "CVS Examine (directory): ")
 985                      (cvs-flags-query 'cvs-update-flags "cvs -n update flags")))
 986   (when (eq flags t)
 987     (setf flags (cvs-flags-query 'cvs-update-flags nil 'noquery)))
 988   (when find-file-visit-truename (setq directory (file-truename directory)))
 989   (cvs-cmd-do "update" directory flags nil
 990               (> (prefix-numeric-value current-prefix-arg) 8)
 991               :cvsargs '("-n")
 992               :noshow noshow
 993               :dont-change-disc t))
 994
 995
 996 ;;;###autoload
 997 (defun cvs-update (directory flags)
 998   "Run a `cvs update' in the current working DIRECTORY.
 999 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
1000 With a \\[universal-argument] prefix argument, prompt for a directory to use.
1001 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
1002   prevents reuse of an existing *cvs* buffer.
1003 The prefix is also passed to `cvs-flags-query' to select the FLAGS
1004   passed to cvs."
1005   (interactive (list (cvs-query-directory "CVS Update (directory): ")
1006                      (cvs-flags-query 'cvs-update-flags "cvs update flags")))
1007   (when (eq flags t)
1008     (setf flags (cvs-flags-query 'cvs-update-flags nil 'noquery)))
1009   (cvs-cmd-do "update" directory flags nil
1010               (> (prefix-numeric-value current-prefix-arg) 8)))
1011
1012
1013 ;;;###autoload
1014 (defun cvs-status (directory flags &optional noshow)
1015   "Run a `cvs status' in the current working DIRECTORY.
1016 Feed the output to a *cvs* buffer and run `cvs-mode' on it.
1017 With a prefix argument, prompt for a directory and cvs FLAGS to use.
1018 A prefix arg >8 (ex: \\[universal-argument] \\[universal-argument]),
1019   prevents reuse of an existing *cvs* buffer.
1020 Optional argument NOSHOW if non-nil means not to display the buffer."
1021   (interactive (list (cvs-query-directory "CVS Status (directory): ")
1022                      (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1023   (when (eq flags t)
1024     (setf flags (cvs-flags-query 'cvs-status-flags nil 'noquery)))
1025   (cvs-cmd-do "status" directory flags nil
1026               (> (prefix-numeric-value current-prefix-arg) 8)
1027               :noshow noshow :dont-change-disc t))
1028
1029 (defun cvs-update-filter (proc string)
1030   "Filter function for pcl-cvs.
1031 This function gets the output that CVS sends to stdout.  It inserts
1032 the STRING into (process-buffer PROC) but it also checks if CVS is waiting
1033 for a lock file.  If so, it inserts a message cookie in the *cvs* buffer."
1034   (save-match-data
1035     (with-current-buffer (process-buffer proc)
1036       (let ((inhibit-read-only t))
1037         (save-excursion
1038           ;; Insert the text, moving the process-marker.
1039           (goto-char (process-mark proc))
1040           (insert string)
1041           (set-marker (process-mark proc) (point))
1042           ;; FIXME: Delete any old lock message
1043           ;;(if (tin-nth cookies 1)
1044           ;;  (tin-delete cookies
1045           ;;          (tin-nth cookies 1)))
1046           ;; Check if CVS is waiting for a lock.
1047           (beginning-of-line 0)       ;Move to beginning of last complete line.
1048           (when (looking-at "^[ a-z]+: \\(.*waiting for .*lock in \\(.*\\)\\)$")
1049             (let ((msg (match-string 1))
1050                   (lock (match-string 2)))
1051               (with-current-buffer cvs-buffer
1052                 (set (make-local-variable 'cvs-lock-file) lock)
1053                 ;; display the lock situation in the *cvs* buffer:
1054                 (ewoc-enter-last
1055                  cvs-cookies
1056                  (cvs-create-fileinfo
1057                   'MESSAGE "" " "
1058                   (concat msg
1059                           (when (file-exists-p lock)
1060                             (substitute-command-keys
1061                              "\n\t(type \\[cvs-mode-delete-lock] to delete it)")))
1062                   :subtype 'TEMP))
1063                 (pop-to-buffer (current-buffer))
1064                 (goto-char (point-max))
1065                 (beep)))))))))
1066
1067 \f
1068 ;;;;
1069 ;;;; The cvs-mode and its associated commands.
1070 ;;;;
1071
1072 (cvs-prefix-define cvs-force-command "" "" '("/F") cvs-qtypedesc-string1)
1073 (defun-cvs-mode cvs-mode-force-command (arg)
1074   "Force the next cvs command to operate on all the selected files.
1075 By default, cvs commands only operate on files on which the command
1076 \"makes sense\".  This overrides the safety feature on the next cvs command.
1077 It actually behaves as a toggle.  If prefixed by \\[universal-argument] \\[universal-argument],
1078 the override will persist until the next toggle."
1079   (interactive "P")
1080   (cvs-prefix-set 'cvs-force-command arg))
1081
1082 (put 'cvs-mode 'mode-class 'special)
1083 (define-derived-mode cvs-mode nil "CVS"
1084   "Mode used for PCL-CVS, a frontend to CVS.
1085 Full documentation is in the Texinfo file."
1086   (setq mode-line-process
1087         '("" cvs-force-command cvs-ignore-marks-modif
1088           ":" (cvs-branch-prefix
1089                ("" cvs-branch-prefix (cvs-secondary-branch-prefix
1090                                       ("->" cvs-secondary-branch-prefix))))
1091           " " cvs-mode-line-process))
1092   (if buffer-file-name
1093       (error "Use M-x cvs-quickdir to get a *cvs* buffer."))
1094   (buffer-disable-undo)
1095   ;;(set (make-local-variable 'goal-column) cvs-cursor-column)
1096   (set (make-local-variable 'revert-buffer-function) 'cvs-mode-revert-buffer)
1097   (setq truncate-lines t)
1098   (cvs-prefix-make-local 'cvs-branch-prefix)
1099   (cvs-prefix-make-local 'cvs-secondary-branch-prefix)
1100   (cvs-prefix-make-local 'cvs-force-command)
1101   (cvs-prefix-make-local 'cvs-ignore-marks-modif)
1102   (make-local-variable 'cvs-mode-line-process)
1103   (make-local-variable 'cvs-temp-buffers))
1104
1105
1106 (defun cvs-buffer-p (&optional buffer)
1107   "Return whether the (by default current) BUFFER is a `cvs-mode' buffer."
1108   (save-excursion
1109     (if buffer (set-buffer buffer))
1110     (and (eq major-mode 'cvs-mode))))
1111
1112 (defun cvs-buffer-check ()
1113   "Check that the current buffer follows cvs-buffer's conventions."
1114   (let ((buf (current-buffer))
1115         (check 'none))
1116     (or (and (setq check 'collection)
1117              (eq (ewoc-buffer cvs-cookies) buf)
1118              (setq check 'cvs-temp-buffer)
1119              (or (null cvs-temp-buffer)
1120                  (null (buffer-name cvs-temp-buffer))
1121                  (and (eq (with-current-buffer cvs-temp-buffer cvs-buffer) buf)
1122                       (equal (with-current-buffer cvs-temp-buffer
1123                                default-directory)
1124                              default-directory)))
1125              t)
1126         (error "Inconsistent %s in buffer %s" check (buffer-name buf)))))
1127
1128
1129 (defun cvs-mode-quit ()
1130   "Quit PCL-CVS, killing the *cvs* buffer."
1131   (interactive)
1132   (and (y-or-n-p "Quit pcl-cvs? ") (kill-buffer (current-buffer))))
1133
1134 ;; Give help....
1135
1136 (defun cvs-help ()
1137   "Display help for various PCL-CVS commands."
1138   (interactive)
1139   (if (eq last-command 'cvs-help)
1140       (describe-function 'cvs-mode)   ; would need minor-mode for log-edit-mode
1141     (message
1142      (substitute-command-keys
1143       "`\\[cvs-help]':help `\\[cvs-mode-add]':add `\\[cvs-mode-commit]':commit \
1144 `\\[cvs-mode-diff-map]':diff* `\\[cvs-mode-log]':log \
1145 `\\[cvs-mode-remove]':remove `\\[cvs-mode-status]':status \
1146 `\\[cvs-mode-undo]':undo"))))
1147
1148 ;; Move around in the buffer
1149
1150 (defun cvs-move-to-goal-column ()
1151   (let* ((eol (line-end-position))
1152          (fpos (next-single-property-change (point) 'cvs-goal-column nil eol)))
1153     (when (< fpos eol)
1154       (goto-char fpos))))
1155
1156 (defun-cvs-mode cvs-mode-previous-line (arg)
1157   "Go to the previous line.
1158 If a prefix argument is given, move by that many lines."
1159   (interactive "p")
1160   (ewoc-goto-prev cvs-cookies arg)
1161   (cvs-move-to-goal-column))
1162
1163 (defun-cvs-mode cvs-mode-next-line (arg)
1164   "Go to the next line.
1165 If a prefix argument is given, move by that many lines."
1166   (interactive "p")
1167   (ewoc-goto-next cvs-cookies arg)
1168   (cvs-move-to-goal-column))
1169
1170 ;;;;
1171 ;;;; Mark handling
1172 ;;;;
1173
1174 (defun-cvs-mode cvs-mode-mark (&optional arg)
1175   "Mark the fileinfo on the current line.
1176 If the fileinfo is a directory, all the contents of that directory are
1177 marked instead. A directory can never be marked."
1178   (interactive)
1179   (let* ((tin (ewoc-locate cvs-cookies))
1180          (fi (ewoc-data tin)))
1181     (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
1182         ;; it's a directory: let's mark all files inside
1183         (ewoc-map
1184          (lambda (f dir)
1185            (when (cvs-dir-member-p f dir)
1186              (setf (cvs-fileinfo->marked f)
1187                    (not (if (eq arg 'toggle) (cvs-fileinfo->marked f) arg)))
1188              t))                        ;Tell cookie to redisplay this cookie.
1189          cvs-cookies
1190          (cvs-fileinfo->dir fi))
1191       ;; not a directory: just do the obvious
1192       (setf (cvs-fileinfo->marked fi)
1193             (not (if (eq arg 'toggle) (cvs-fileinfo->marked fi) arg)))
1194       (ewoc-invalidate cvs-cookies tin)
1195       (cvs-mode-next-line 1))))
1196
1197 (defun cvs-mouse-toggle-mark (e)
1198   "Toggle the mark of the entry under the mouse."
1199   (interactive "e")
1200   (save-excursion
1201     (mouse-set-point e)
1202     (cvs-mode-mark 'toggle)))
1203
1204 (defun-cvs-mode cvs-mode-unmark ()
1205   "Unmark the fileinfo on the current line."
1206   (interactive)
1207   (cvs-mode-mark t))
1208
1209 (defun-cvs-mode cvs-mode-mark-all-files ()
1210   "Mark all files."
1211   (interactive)
1212   (ewoc-map (lambda (cookie)
1213               (unless (eq (cvs-fileinfo->type cookie) 'DIRCHANGE)
1214                 (setf (cvs-fileinfo->marked cookie) t)))
1215             cvs-cookies))
1216
1217 (defun-cvs-mode (cvs-mode-mark-on-state . SIMPLE) (state)
1218   "Mark all files in state STATE."
1219   (interactive
1220    (list
1221     (let ((default
1222             (condition-case nil
1223                 (downcase
1224                  (symbol-name
1225                   (cvs-fileinfo->type
1226                    (cvs-mode-marked nil nil :read-only t :one t :noquery t))))
1227               (error nil))))
1228       (intern
1229        (upcase
1230         (completing-read
1231          (concat
1232           "Mark files in state" (if default (concat " [" default "]")) ": ")
1233          (mapcar (lambda (x)
1234                    (list (downcase (symbol-name (car x)))))
1235                  cvs-states)
1236          nil t nil nil default))))))
1237   (ewoc-map (lambda (fi)
1238               (when (eq (cvs-fileinfo->type fi) state)
1239                 (setf (cvs-fileinfo->marked fi) t)))
1240             cvs-cookies))
1241
1242 (defun-cvs-mode cvs-mode-mark-matching-files (regex)
1243   "Mark all files matching REGEX."
1244   (interactive "sMark files matching: ")
1245   (ewoc-map (lambda (cookie)
1246               (when (and (not (eq (cvs-fileinfo->type cookie) 'DIRCHANGE))
1247                          (string-match regex (cvs-fileinfo->file cookie)))
1248                 (setf (cvs-fileinfo->marked cookie) t)))
1249             cvs-cookies))
1250
1251 (defun-cvs-mode cvs-mode-unmark-all-files ()
1252   "Unmark all files.
1253 Directories are also unmarked, but that doesn't matter, since
1254 they should always be unmarked."
1255   (interactive)
1256   (ewoc-map (lambda (cookie)
1257               (setf (cvs-fileinfo->marked cookie) nil)
1258               t)
1259             cvs-cookies))
1260
1261 (defun-cvs-mode cvs-mode-unmark-up ()
1262   "Unmark the file on the previous line."
1263   (interactive)
1264   (let ((tin (ewoc-goto-prev cvs-cookies 1)))
1265     (when tin
1266       (setf (cvs-fileinfo->marked (ewoc-data tin)) nil)
1267       (ewoc-invalidate cvs-cookies tin)))
1268   (cvs-move-to-goal-column))
1269
1270 (defconst cvs-ignore-marks-alternatives
1271   '(("toggle-marks"     . "/TM")
1272     ("force-marks"      . "/FM")
1273     ("ignore-marks"     . "/IM")))
1274
1275 (cvs-prefix-define cvs-ignore-marks-modif
1276   "Prefix to decide whether to ignore marks or not."
1277   "active"
1278   (mapcar 'cdr cvs-ignore-marks-alternatives)
1279   (cvs-qtypedesc-create
1280    (lambda (str) (cdr (assoc str cvs-ignore-marks-alternatives)))
1281    (lambda (obj) (car (rassoc obj cvs-ignore-marks-alternatives)))
1282    (lambda () cvs-ignore-marks-alternatives)
1283    nil t))
1284
1285 (defun-cvs-mode cvs-mode-toggle-marks (arg)
1286   "Toggle whether the next CVS command uses marks.
1287 See `cvs-prefix-set' for further description of the behavior.
1288 \\[universal-argument] 1 selects `force-marks',
1289 \\[universal-argument] 2 selects `ignore-marks',
1290 \\[universal-argument] 3 selects `toggle-marks'."
1291   (interactive "P")
1292   (cvs-prefix-set 'cvs-ignore-marks-modif arg))
1293
1294 (defun cvs-ignore-marks-p (cmd &optional read-only)
1295   (let ((default (if (member cmd cvs-invert-ignore-marks)
1296                      (not cvs-default-ignore-marks)
1297                    cvs-default-ignore-marks))
1298         (modif (cvs-prefix-get 'cvs-ignore-marks-modif read-only)))
1299     (cond
1300      ((equal modif "/IM") t)
1301      ((equal modif "/TM") (not default))
1302      ((equal modif "/FM") nil)
1303      (t default))))
1304
1305 (defun cvs-mode-mark-get-modif (cmd)
1306   (if (cvs-ignore-marks-p cmd 'read-only) "/IM" "/FM"))
1307
1308 (defun cvs-get-marked (&optional ignore-marks ignore-contents)
1309   "Return a list of all selected fileinfos.
1310 If there are any marked tins, and IGNORE-MARKS is nil, return them.
1311 Otherwise, if the cursor selects a directory, and IGNORE-CONTENTS is
1312 nil, return all files in it, else return just the directory.
1313 Otherwise return (a list containing) the file the cursor points to, or
1314 an empty list if it doesn't point to a file at all.
1315
1316 Args: &optional IGNORE-MARKS IGNORE-CONTENTS."
1317
1318   (let ((fis nil))
1319     (dolist (fi (if (and (boundp 'cvs-minor-current-files)
1320                          (consp cvs-minor-current-files))
1321                     (mapcar
1322                      (lambda (f)
1323                        (if (cvs-fileinfo-p f) f
1324                          (let ((f (file-relative-name f)))
1325                            (if (file-directory-p f)
1326                                (cvs-create-fileinfo
1327                                 'DIRCHANGE (file-name-as-directory f) "." "")
1328                              (let ((dir (file-name-directory f))
1329                                    (file (file-name-nondirectory f)))
1330                                (cvs-create-fileinfo
1331                                 'UNKNOWN (or dir "") file ""))))))
1332                      cvs-minor-current-files)
1333                   (or (and (not ignore-marks)
1334                            (ewoc-collect cvs-cookies 'cvs-fileinfo->marked))
1335                       (list (ewoc-data (ewoc-locate cvs-cookies))))))
1336
1337       (if (or ignore-contents (not (eq (cvs-fileinfo->type fi) 'DIRCHANGE)))
1338           (push fi fis)
1339         ;; If a directory is selected, return members, if any.
1340         (setq fis
1341               (append (ewoc-collect
1342                        cvs-cookies 'cvs-dir-member-p (cvs-fileinfo->dir fi))
1343                       fis))))
1344     (nreverse fis)))
1345
1346 (defun* cvs-mode-marked (filter &optional cmd
1347                                 &key read-only one file noquery)
1348   "Get the list of marked FIS.
1349 CMD is used to determine whether to use the marks or not.
1350 Only files for which FILTER is applicable are returned.
1351 If READ-ONLY is non-nil, the current toggling is left intact.
1352 If ONE is non-nil, marks are ignored and a single FI is returned.
1353 If FILE is non-nil, directory entries won't be selected."
1354   (unless cmd (setq cmd (symbol-name filter)))
1355   (let* ((fis (cvs-get-marked (or one (cvs-ignore-marks-p cmd read-only))
1356                               (and (not file)
1357                                    (cvs-applicable-p 'DIRCHANGE filter))))
1358          (force (cvs-prefix-get 'cvs-force-command))
1359          (fis (car (cvs-partition
1360                     (lambda (fi) (cvs-applicable-p fi (and (not force) filter)))
1361                     fis))))
1362     (when (and (or (null fis) (and one (cdr fis))) (not noquery))
1363       (message (if (null fis)
1364                    "`%s' is not applicable to any of the selected files."
1365                  "`%s' is only applicable to a single file.") cmd)
1366       (sit-for 1)
1367       (setq fis (list (cvs-insert-file
1368                        (read-file-name (format "File to %s: " cmd))))))
1369     (if one (car fis) fis)))
1370
1371 (defun cvs-enabledp (filter)
1372   "Determine whether FILTER applies to at least one of the selected files."
1373   (ignore-errors (cvs-mode-marked filter nil :read-only t :noquery t)))
1374
1375 (defun cvs-mode-files (&rest -cvs-mode-files-args)
1376   (cvs-mode!
1377    (lambda ()
1378      (mapcar 'cvs-fileinfo->full-path
1379              (apply 'cvs-mode-marked -cvs-mode-files-args)))))
1380
1381 ;;
1382 ;; Interface between Log-Edit and PCL-CVS
1383 ;;
1384
1385 (defun cvs-mode-commit-setup ()
1386   "Run `cvs-mode-commit' with setup."
1387   (interactive)
1388   (cvs-mode-commit 'force))
1389
1390 (defcustom cvs-mode-commit-hook nil
1391   "Hook run after setting up the commit buffer."
1392   :type 'hook
1393   :options '(cvs-mode-diff)
1394   :group 'pcl-cvs)
1395
1396 (defun cvs-mode-commit (setup)
1397   "Check in all marked files, or the current file.
1398 The user will be asked for a log message in a buffer.
1399 The buffer's mode and name is determined by the \"message\" setting
1400   of `cvs-buffer-name-alist'.
1401 The POSTPROC specified there (typically `log-edit') is then called,
1402   passing it the SETUP argument."
1403   (interactive "P")
1404   ;; It seems that the save-excursion that happens if I use the better
1405   ;; form of `(cvs-mode! (lambda ...))' screws up a couple things which
1406   ;; end up being rather annoying (like log-edit-mode's message being
1407   ;; displayed in the wrong minibuffer).
1408   (cvs-mode!)
1409   (let ((buf (cvs-temp-buffer "message" 'normal 'nosetup))
1410         (lbd list-buffers-directory)
1411         (setupfun (or (nth 2 (cdr (assoc "message" cvs-buffer-name-alist)))
1412                       'log-edit)))
1413     (funcall setupfun 'cvs-do-commit setup 'cvs-commit-filelist buf)
1414     (set (make-local-variable 'cvs-minor-wrap-function) 'cvs-commit-minor-wrap)
1415     (set (make-local-variable 'list-buffers-directory) lbd)
1416     (run-hooks 'cvs-mode-commit-hook)))
1417
1418 (defun cvs-commit-minor-wrap (buf f)
1419   (let ((cvs-ignore-marks-modif (cvs-mode-mark-get-modif "commit")))
1420     (funcall f)))
1421
1422 (defun cvs-commit-filelist ()
1423   (cvs-mode-files 'commit nil :read-only t :file t :noquery t))
1424
1425 (defun cvs-do-commit (flags)
1426   "Do the actual commit, using the current buffer as the log message."
1427   (interactive (list (cvs-flags-query 'cvs-commit-flags "cvs commit flags")))
1428   (let ((msg (buffer-substring-no-properties (point-min) (point-max))))
1429     (cvs-mode!)
1430     ;;(pop-to-buffer cvs-buffer)
1431     (cvs-mode-do "commit" (list* "-m" msg flags) 'commit)))
1432
1433
1434 ;;;; Editing existing commit log messages.
1435
1436 (defun cvs-edit-log-text-at-point ()
1437   (save-excursion
1438     (end-of-line)
1439     (when (re-search-backward "^revision " nil t)
1440       (forward-line 1)
1441       (if (looking-at "date:") (forward-line 1))
1442       (if (looking-at "branches:") (forward-line 1))
1443       (buffer-substring
1444        (point)
1445        (if (re-search-forward
1446             "^\\(-\\{28\\}\\|=\\{77\\}\\|revision [.0-9]+\\)$"
1447             nil t)
1448            (match-beginning 0)
1449          (point))))))
1450
1451 (defvar cvs-edit-log-revision)
1452 (defun cvs-mode-edit-log (rev &optional text)
1453   "Edit the log message at point.
1454 This is best called from a `log-view-mode' buffer."
1455   (interactive
1456    (list
1457     (or (cvs-mode! (lambda () (cvs-prefix-get 'cvs-branch-prefix)))
1458         (read-string "Revision to edit: "))
1459     (cvs-edit-log-text-at-point)))
1460   ;; It seems that the save-excursion that happens if I use the better
1461   ;; form of `(cvs-mode! (lambda ...))' screws up a couple things which
1462   ;; end up being rather annoying (like log-edit-mode's message being
1463   ;; displayed in the wrong minibuffer).
1464   (cvs-mode!)
1465   (let ((buf (cvs-temp-buffer "message" 'normal 'nosetup))
1466         (lbd list-buffers-directory)
1467         (setupfun (or (nth 2 (cdr (assoc "message" cvs-buffer-name-alist)))
1468                       'log-edit)))
1469     (funcall setupfun 'cvs-do-edit-log nil 'cvs-edit-log-filelist buf)
1470     (when text (erase-buffer) (insert text))
1471     (set (make-local-variable 'cvs-edit-log-revision) rev)
1472     (set (make-local-variable 'cvs-minor-wrap-function) 'cvs-edit-log-minor-wrap)
1473     (set (make-local-variable 'list-buffers-directory) lbd)
1474     ;; (run-hooks 'cvs-mode-commit-hook)
1475     ))
1476
1477 (defun cvs-edit-log-minor-wrap (buf f)
1478   (let ((cvs-ignore-marks-modif (cvs-mode-mark-get-modif "commit")))
1479     (funcall f)))
1480
1481 (defun cvs-edit-log-filelist ()
1482   (cvs-mode-files nil nil :read-only t :file t :noquery t))
1483
1484 (defun cvs-do-edit-log (rev)
1485   "Do the actual commit, using the current buffer as the log message."
1486   (interactive (list cvs-edit-log-revision))
1487   (let ((msg (buffer-substring-no-properties (point-min) (point-max))))
1488     (cvs-mode!)
1489     (cvs-mode-do "admin" (list (concat "-m" rev ":" msg)) nil)))
1490
1491
1492 ;;;;
1493 ;;;; CVS Mode commands
1494 ;;;;
1495
1496 (defun-cvs-mode (cvs-mode-insert . NOARGS) (file)
1497   "Insert an entry for a specific file into the current listing.
1498 This is typically used if the file is up-to-date (or has been added
1499 outside of PCL-CVS) and one wants to do some operation on it."
1500   (interactive
1501    (list (read-file-name
1502           "File to insert: "
1503           ;; Can't use ignore-errors here because interactive
1504           ;; specs aren't byte-compiled.
1505           (condition-case nil
1506               (file-name-as-directory
1507                (expand-file-name
1508                 (cvs-fileinfo->dir
1509                  (cvs-mode-marked nil nil :read-only t :one t :noquery t))))
1510             (error nil)))))
1511   (cvs-insert-file file))
1512
1513 (defun cvs-insert-file (file)
1514   "Insert FILE (and its contents if it's a dir) and return its FI."
1515   (let ((file (file-relative-name (directory-file-name file))) last)
1516     (dolist (fi (cvs-fileinfo-from-entries file))
1517       (setq last (cvs-addto-collection cvs-cookies fi last)))
1518     ;; There should have been at least one entry.
1519     (goto-char (ewoc-location last))
1520     (ewoc-data last)))
1521
1522 (defun cvs-mark-fis-dead (fis)
1523   ;; Helper function, introduced because of the need for macro-expansion.
1524   (dolist (fi fis)
1525     (setf (cvs-fileinfo->type fi) 'DEAD)))
1526
1527 (defun-cvs-mode (cvs-mode-add . SIMPLE) (flags)
1528   "Add marked files to the cvs repository.
1529 With prefix argument, prompt for cvs flags."
1530   (interactive (list (cvs-flags-query 'cvs-add-flags "cvs add flags")))
1531   (let ((fis (cvs-mode-marked 'add))
1532         (needdesc nil) (dirs nil))
1533     ;; find directories and look for fis needing a description
1534     (dolist (fi fis)
1535       (cond
1536        ((file-directory-p (cvs-fileinfo->full-path fi)) (push fi dirs))
1537        ((eq (cvs-fileinfo->type fi) 'UNKNOWN) (setq needdesc t))))
1538     ;; prompt for description if necessary
1539     (let* ((msg (if (and needdesc
1540                          (or current-prefix-arg (not cvs-add-default-message)))
1541                     (read-from-minibuffer "Enter description: ")
1542                   (or cvs-add-default-message "")))
1543            (flags (list* "-m" msg flags))
1544            (postproc
1545             ;; setup postprocessing for the directory entries
1546             (when dirs
1547               `((cvs-run-process (list "-n" "update")
1548                                  ',dirs
1549                                  '(cvs-parse-process t))
1550                 (cvs-mark-fis-dead ',dirs)))))
1551       (cvs-mode-run "add" flags fis :postproc postproc))))
1552
1553 (defun-cvs-mode (cvs-mode-diff . DOUBLE) (flags)
1554   "Diff the selected files against the repository.
1555 This command compares the files in your working area against the
1556 revision which they are based upon."
1557   (interactive
1558    (list (cvs-add-branch-prefix
1559           (cvs-add-secondary-branch-prefix
1560            (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))))
1561   (cvs-mode-do "diff" flags 'diff
1562                :show t)) ;; :ignore-exit t
1563
1564 (defun-cvs-mode (cvs-mode-diff-head . SIMPLE) (flags)
1565   "Diff the selected files against the head of the current branch.
1566 See ``cvs-mode-diff'' for more info."
1567   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1568   (cvs-mode-diff-1 (cons "-rHEAD" flags)))
1569
1570 (defun-cvs-mode (cvs-mode-diff-vendor . SIMPLE) (flags)
1571   "Diff the selected files against the head of the vendor branch.
1572 See ``cvs-mode-diff'' for more info."
1573   (interactive (list (cvs-flags-query 'cvs-diff-flags "cvs diff flags")))
1574   (cvs-mode-diff-1 (cons (concat "-r" cvs-vendor-branch) flags)))
1575
1576 ;; sadly, this is not provided by cvs, so we have to roll our own
1577 (defun-cvs-mode (cvs-mode-diff-backup . SIMPLE) (flags)
1578   "Diff the files against the backup file.
1579 This command can be used on files that are marked with \"Merged\"
1580 or \"Conflict\" in the *cvs* buffer."
1581   (interactive (list (cvs-flags-query 'cvs-diff-flags "diff flags")))
1582   (unless (listp flags) (error "flags should be a list of strings"))
1583   (save-some-buffers)
1584   (let* ((marked (cvs-get-marked (cvs-ignore-marks-p "diff")))
1585          (fis (car (cvs-partition 'cvs-fileinfo->backup-file marked))))
1586     (unless (consp fis)
1587       (error "No files with a backup file selected!"))
1588     ;; let's extract some info into the environment for `buffer-name'
1589     (let* ((dir (cvs-fileinfo->dir (car fis)))
1590            (file (cvs-fileinfo->file (car fis))))
1591       (set-buffer (cvs-temp-buffer "diff")))
1592     (message "cvs diff backup...")
1593     (cvs-execute-single-file-list fis 'cvs-diff-backup-extractor
1594                                   cvs-diff-program flags))
1595   (message "cvs diff backup... Done."))
1596
1597 (defun cvs-diff-backup-extractor (fileinfo)
1598   "Return the filename and the name of the backup file as a list.
1599 Signal an error if there is no backup file."
1600   (let ((backup-file (cvs-fileinfo->backup-file fileinfo)))
1601     (unless backup-file
1602       (error "%s has no backup file" (cvs-fileinfo->full-path fileinfo)))
1603     (list backup-file (cvs-fileinfo->full-path fileinfo))))
1604
1605 ;;
1606 ;; Emerge support
1607 ;;
1608 (defun cvs-emerge-diff (b1 b2) (emerge-buffers b1 b2 b1))
1609 (defun cvs-emerge-merge (b1 b2 base out)
1610   (emerge-buffers-with-ancestor b1 b2 base (find-file-noselect out)))
1611
1612 ;;
1613 ;; Ediff support
1614 ;;
1615
1616 (defvar ediff-after-quit-destination-buffer)
1617 (defvar ediff-after-quit-hook-internal)
1618 (defvar cvs-transient-buffers)
1619 (defun cvs-ediff-startup-hook ()
1620   (add-hook 'ediff-after-quit-hook-internal
1621             `(lambda ()
1622                (cvs-ediff-exit-hook
1623                 ',ediff-after-quit-destination-buffer ',cvs-transient-buffers))
1624             nil 'local))
1625
1626 (defun cvs-ediff-exit-hook (cvs-buf tmp-bufs)
1627   ;; kill the temp buffers (and their associated windows)
1628   (dolist (tb tmp-bufs)
1629     (when (and tb (buffer-live-p tb) (not (buffer-modified-p tb)))
1630       (let ((win (get-buffer-window tb t)))
1631         (kill-buffer tb)
1632         (when (window-live-p win) (ignore-errors (delete-window win))))))
1633   ;; switch back to the *cvs* buffer
1634   (when (and cvs-buf (buffer-live-p cvs-buf)
1635              (not (get-buffer-window cvs-buf t)))
1636     (ignore-errors (switch-to-buffer cvs-buf))))
1637
1638 (defun cvs-ediff-diff (b1 b2)
1639   (let ((ediff-after-quit-destination-buffer (current-buffer))
1640         (startup-hook '(cvs-ediff-startup-hook)))
1641     (ediff-buffers b1 b2 startup-hook 'ediff-revision)))
1642
1643 (defun cvs-ediff-merge (b1 b2 base out)
1644   (let ((ediff-after-quit-destination-buffer (current-buffer))
1645         (startup-hook '(cvs-ediff-startup-hook)))
1646     (ediff-merge-buffers-with-ancestor
1647      b1 b2 base startup-hook
1648      'ediff-merge-revisions-with-ancestor
1649      out)))
1650
1651 ;;
1652 ;; Interactive merge/diff support.
1653 ;;
1654
1655 (defun cvs-retrieve-revision (fileinfo rev)
1656   "Retrieve the given REVision of the file in FILEINFO into a new buffer."
1657   (let* ((file (cvs-fileinfo->full-path fileinfo))
1658          (buffile (concat file "." rev)))
1659     (or (find-buffer-visiting buffile)
1660         (with-current-buffer (create-file-buffer buffile)
1661           (message "Retrieving revision %s..." rev)
1662           ;; Discard stderr output to work around the CVS+SSH+libc
1663           ;; problem when stdout and stderr are the same.
1664           ;; FIXME: this doesn't seem to make any difference :-(
1665           (let ((res (apply 'call-process cvs-program nil '(t . nil) nil
1666                             "-q" "update" "-p"
1667                             ;; If `rev' is HEAD, don't pass it at all:
1668                             ;; the default behavior is to get the head
1669                             ;; of the current branch whereas "-r HEAD"
1670                             ;; stupidly gives you the head of the trunk.
1671                             (append (unless (equal rev "HEAD") (list "-r" rev))
1672                                     (list file)))))
1673             (when (and res (not (and (equal 0 res))))
1674               (error "Something went wrong retrieving revision %s: %s" rev res))
1675             (set-buffer-modified-p nil)
1676             (let ((buffer-file-name (expand-file-name file)))
1677               (after-find-file))
1678             (toggle-read-only 1)
1679             (message "Retrieving revision %s... Done" rev)
1680             (current-buffer))))))
1681
1682 (eval-and-compile (autoload 'smerge-ediff "smerge-mode"))
1683
1684 ;; FIXME: The user should be able to specify ancestor/head/backup and we should
1685 ;; provide sensible defaults when merge info is unavailable (rather than rely
1686 ;; on smerge-ediff).  Also provide sane defaults for need-merge files.
1687 (defun-cvs-mode cvs-mode-imerge ()
1688   "Merge interactively appropriate revisions of the selected file."
1689   (interactive)
1690   (let ((fi (cvs-mode-marked 'merge nil :one t :file t)))
1691     (let ((merge (cvs-fileinfo->merge fi))
1692           (file (cvs-fileinfo->full-path fi))
1693           (backup-file (cvs-fileinfo->backup-file fi)))
1694       (if (not (and merge backup-file))
1695           (let ((buf (find-file-noselect file)))
1696             (message "Missing merge info or backup file, using VC.")
1697             (with-current-buffer buf
1698               (smerge-ediff)))
1699         (let* ((ancestor-buf (cvs-retrieve-revision fi (car merge)))
1700                (head-buf (cvs-retrieve-revision fi (cdr merge)))
1701                (backup-buf (let ((auto-mode-alist nil))
1702                              (find-file-noselect backup-file)))
1703                ;; this binding is used by cvs-ediff-startup-hook
1704                (cvs-transient-buffers (list ancestor-buf backup-buf head-buf)))
1705           (with-current-buffer backup-buf
1706             (let ((buffer-file-name (expand-file-name file)))
1707               (after-find-file)))
1708           (funcall (cdr cvs-idiff-imerge-handlers)
1709                    backup-buf head-buf ancestor-buf file))))))
1710
1711 (cvs-flags-define cvs-idiff-version
1712                   (list "BASE" cvs-vendor-branch cvs-vendor-branch "BASE" "BASE")
1713                   "version: " cvs-qtypedesc-tag)
1714
1715 (defun-cvs-mode (cvs-mode-idiff . NOARGS) (&optional rev1 rev2)
1716   "Diff interactively current file to revisions."
1717   (interactive
1718    (let* ((rev1 (cvs-prefix-get 'cvs-branch-prefix))
1719           (rev2 (and rev1 (cvs-prefix-get 'cvs-secondary-branch-prefix))))
1720      (list (or rev1 (cvs-flags-query 'cvs-idiff-version))
1721            rev2)))
1722   (let ((fi (cvs-mode-marked 'diff "idiff" :one t :file t)))
1723     (let* ((file (cvs-fileinfo->full-path fi))
1724            (rev1-buf (cvs-retrieve-revision fi (or rev1 "BASE")))
1725            (rev2-buf (if rev2 (cvs-retrieve-revision fi rev2)))
1726            ;; this binding is used by cvs-ediff-startup-hook
1727            (cvs-transient-buffers (list rev1-buf rev2-buf)))
1728       (funcall (car cvs-idiff-imerge-handlers)
1729                rev1-buf (or rev2-buf (find-file-noselect file))))))
1730
1731 (defun-cvs-mode (cvs-mode-idiff-other . NOARGS) ()
1732   "Diff interactively current file to revisions."
1733   (interactive)
1734   (let* ((rev1 (cvs-prefix-get 'cvs-branch-prefix))
1735          (rev2 (and rev1 (cvs-prefix-get 'cvs-secondary-branch-prefix)))
1736          (fis (cvs-mode-marked 'diff "idiff" :file t)))
1737     (when (> (length fis) 2)
1738       (error "idiff-other cannot be applied to more than 2 files at a time"))
1739     (let* ((fi1 (car fis))
1740            (rev1-buf (if rev1 (cvs-retrieve-revision fi1 rev1)
1741                        (find-file-noselect (cvs-fileinfo->full-path fi1))))
1742            rev2-buf)
1743       (if (cdr fis)
1744           (let ((fi2 (nth 1 fis)))
1745             (setq rev2-buf
1746                   (if rev2 (cvs-retrieve-revision fi2 rev2)
1747                     (find-file-noselect (cvs-fileinfo->full-path fi2)))))
1748         (error "idiff-other doesn't know what other file/buffer to use"))
1749       (let* (;; this binding is used by cvs-ediff-startup-hook
1750              (cvs-transient-buffers (list rev1-buf rev2-buf)))
1751         (funcall (car cvs-idiff-imerge-handlers)
1752                  rev1-buf rev2-buf)))))
1753
1754
1755 (defun cvs-is-within-p (fis dir)
1756   "Non-nil is buffer is inside one of FIS (in DIR)."
1757   (when (stringp buffer-file-name)
1758     (setq buffer-file-name (expand-file-name buffer-file-name))
1759     (let (ret)
1760       (dolist (fi (or fis (list (cvs-create-fileinfo 'DIRCHANGE "" "." ""))))
1761         (when (cvs-string-prefix-p
1762                (expand-file-name (cvs-fileinfo->full-path fi) dir)
1763                buffer-file-name)
1764           (setq ret t)))
1765       ret)))
1766
1767 (defun* cvs-mode-run (cmd flags fis
1768                       &key (buf (cvs-temp-buffer))
1769                            dont-change-disc cvsargs postproc)
1770   "Generic cvs-mode-<foo> function.
1771 Executes `cvs CVSARGS CMD FLAGS FIS'.
1772 BUF is the buffer to be used for cvs' output.
1773 DONT-CHANGE-DISC non-nil indicates that the command will not change the
1774   contents of files.  This is only used by the parser.
1775 POSTPROC is a list of expressions to be evaluated at the very end (after
1776   parsing if applicable).  It will be prepended with `progn' is necessary."
1777   (let ((def-dir default-directory))
1778     ;; Save the relevant buffers
1779     (save-some-buffers nil (lambda () (cvs-is-within-p fis def-dir))))
1780   (unless (listp flags) (error "flags should be a list of strings"))
1781   ;; Some w32 versions of CVS don't like an explicit . too much.
1782   (when (and (car fis) (null (cdr fis))
1783              (eq (cvs-fileinfo->type (car fis)) 'DIRCHANGE)
1784              ;; (equal (cvs-fileinfo->file (car fis)) ".")
1785              (equal (cvs-fileinfo->dir (car fis)) ""))
1786     (setq fis nil))
1787   (let* ((single-dir (or (not (listp cvs-execute-single-dir))
1788                          (member cmd cvs-execute-single-dir)))
1789          (parse (member cmd cvs-parse-known-commands))
1790          (args (append cvsargs (list cmd) flags))
1791          (after-mode (nth 2 (cdr (assoc cmd cvs-buffer-name-alist)))))
1792     (cvs-cleanup-collection cvs-cookies ;cleanup remaining messages
1793                             (eq cvs-auto-remove-handled 'delayed) nil t)
1794     (when (fboundp after-mode)
1795       (setq postproc (append postproc `((,after-mode)))))
1796     (when parse
1797       (let ((old-fis
1798              (when (member cmd '("status" "update"))    ;FIXME: Yuck!!
1799                 ;; absence of `cvs update' output has a specific meaning.
1800                 (or fis (list (cvs-create-fileinfo 'DIRCHANGE "" "." ""))))))
1801         (push `(cvs-parse-process ',dont-change-disc nil ',old-fis) postproc)))
1802     (setq postproc (if (cdr postproc) (cons 'progn postproc) (car postproc)))
1803     (cvs-update-header args fis)
1804     (with-current-buffer buf
1805       (let ((inhibit-read-only t)) (erase-buffer))
1806       (message "Running cvs %s ..." cmd)
1807       (cvs-run-process args fis postproc single-dir))))
1808
1809
1810 (defun* cvs-mode-do (cmd flags filter
1811                      &key show dont-change-disc cvsargs postproc)
1812   "Generic cvs-mode-<foo> function.
1813 Executes `cvs CVSARGS CMD FLAGS' on the selected files.
1814 FILTER is passed to `cvs-applicable-p' to only apply the command to
1815   files for which it makes sense.
1816 SHOW indicates that CMD should be not be run in the default temp buffer and
1817   should be shown to the user.  The buffer and mode to be used is determined
1818   by `cvs-buffer-name-alist'.
1819 DONT-CHANGE-DISC non-nil indicates that the command will not change the
1820   contents of files.  This is only used by the parser."
1821   (cvs-mode-run cmd flags (cvs-mode-marked filter cmd)
1822                 :buf (cvs-temp-buffer (when show cmd))
1823                 :dont-change-disc dont-change-disc
1824                 :cvsargs cvsargs
1825                 :postproc postproc))
1826
1827 (defun-cvs-mode (cvs-mode-status . SIMPLE) (flags)
1828   "Show cvs status for all marked files.
1829 With prefix argument, prompt for cvs flags."
1830   (interactive (list (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1831   (cvs-mode-do "status" flags nil :dont-change-disc t :show t
1832                :postproc (when (eq cvs-auto-remove-handled 'status)
1833                            '((with-current-buffer ,(current-buffer)
1834                                (cvs-mode-remove-handled))))))
1835
1836 (defun-cvs-mode (cvs-mode-tree . SIMPLE) (flags)
1837   "Call cvstree using the file under the point as a keyfile."
1838   (interactive (list (cvs-flags-query 'cvs-status-flags "cvs status flags")))
1839   (cvs-mode-run "status" (cons "-v" flags) (cvs-mode-marked nil "status")
1840                 :buf (cvs-temp-buffer "tree")
1841                 :dont-change-disc t
1842                 :postproc '((cvs-status-cvstrees))))
1843
1844 ;; cvs log
1845
1846 (defun-cvs-mode (cvs-mode-log . NOARGS) (flags)
1847   "Display the cvs log of all selected files.
1848 With prefix argument, prompt for cvs flags."
1849   (interactive (list (cvs-add-branch-prefix
1850                       (cvs-flags-query 'cvs-log-flags "cvs log flags"))))
1851   (cvs-mode-do "log" flags nil :show t))
1852
1853
1854 (defun-cvs-mode (cvs-mode-update . NOARGS) (flags)
1855   "Update all marked files.
1856 With a prefix argument, prompt for cvs flags."
1857   (interactive
1858    (list (cvs-add-branch-prefix
1859           (cvs-add-secondary-branch-prefix
1860            (cvs-flags-query 'cvs-update-flags "cvs update flags")
1861            "-j") "-j")))
1862   (cvs-mode-do "update" flags 'update))
1863
1864
1865 (defun-cvs-mode (cvs-mode-examine . NOARGS) (flags)
1866   "Re-examine all marked files.
1867 With a prefix argument, prompt for cvs flags."
1868   (interactive
1869    (list (cvs-add-branch-prefix
1870           (cvs-add-secondary-branch-prefix
1871            (cvs-flags-query 'cvs-update-flags "cvs -n update flags")
1872            "-j") "-j")))
1873   (cvs-mode-do "update" flags nil :cvsargs '("-n") :dont-change-disc t))
1874
1875
1876 (defun-cvs-mode cvs-mode-ignore (&optional pattern)
1877   "Arrange so that CVS ignores the selected files.
1878 This command ignores files that are not flagged as `Unknown'."
1879   (interactive)
1880   (dolist (fi (cvs-mode-marked 'ignore))
1881     (cvs-append-to-ignore (cvs-fileinfo->dir fi) (cvs-fileinfo->file fi)
1882                           (eq (cvs-fileinfo->subtype fi) 'NEW-DIR))
1883     (setf (cvs-fileinfo->type fi) 'DEAD))
1884   (cvs-cleanup-collection cvs-cookies nil nil nil))
1885
1886
1887 (defun cvs-append-to-ignore (dir str &optional old-dir)
1888   "Add STR to the .cvsignore file in DIR.
1889 If OLD-DIR is non-nil, then this is a directory that we don't want
1890 to hear about anymore."
1891   (with-current-buffer
1892       (find-file-noselect (expand-file-name ".cvsignore" dir))
1893     (when (ignore-errors
1894             (and buffer-read-only
1895                  (eq 'CVS (vc-backend buffer-file-name))
1896                  (not (vc-editable-p buffer-file-name))))
1897       ;; CVSREAD=on special case
1898       (vc-checkout buffer-file-name t))
1899     (goto-char (point-max))
1900     (unless (bolp) (insert "\n"))
1901     (insert str (if old-dir "/\n" "\n"))
1902     (if cvs-sort-ignore-file (sort-lines nil (point-min) (point-max)))
1903     (save-buffer)))
1904
1905
1906 (defun cvs-mode-find-file-other-window (e)
1907   "Select a buffer containing the file in another window."
1908   (interactive (list last-input-event))
1909   (cvs-mode-find-file e t))
1910
1911
1912 (defun cvs-mode-display-file (e)
1913   "Show a buffer containing the file in another window."
1914   (interactive (list last-input-event))
1915   (cvs-mode-find-file e 'dont-select))
1916
1917
1918 (defun cvs-find-modif (fi)
1919   (with-temp-buffer
1920     (call-process cvs-program nil (current-buffer) nil
1921                   "-f" "diff" (cvs-fileinfo->file fi))
1922     (goto-char (point-min))
1923     (if (re-search-forward "^\\([0-9]+\\)" nil t)
1924         (string-to-number (match-string 1))
1925       1)))
1926
1927
1928 (defun cvs-mode-find-file (e &optional other)
1929   "Select a buffer containing the file.
1930 With a prefix, opens the buffer in an OTHER window."
1931   (interactive (list last-input-event current-prefix-arg))
1932   ;; If the event moves point, check that it moves it to a valid location.
1933   (when (and (/= (point) (progn (ignore-errors (mouse-set-point e)) (point)))
1934              (not (memq (get-text-property (1- (line-end-position))
1935                                            'font-lock-face)
1936                         '(cvs-header-face cvs-filename-face))))
1937     (error "Not a file name"))
1938   (cvs-mode!
1939    (lambda (&optional rev)
1940      (interactive (list (cvs-prefix-get 'cvs-branch-prefix)))
1941      (let* ((cvs-buf (current-buffer))
1942             (fi (cvs-mode-marked nil nil :one t)))
1943        (if (eq (cvs-fileinfo->type fi) 'DIRCHANGE)
1944            (let ((odir default-directory))
1945              (setq default-directory
1946                    (cvs-expand-dir-name (cvs-fileinfo->dir fi)))
1947              (cond ((eq other 'dont-select)
1948                     (display-buffer (find-file-noselect default-directory)))
1949                    (other (dired-other-window default-directory))
1950                    (t (dired default-directory)))
1951              (set-buffer cvs-buf)
1952              (setq default-directory odir))
1953          (let ((buf (if rev (cvs-retrieve-revision fi rev)
1954                       (find-file-noselect (cvs-fileinfo->full-path fi)))))
1955            (funcall (cond ((eq other 'dont-select) 'display-buffer)
1956                           (other 'switch-to-buffer-other-window)
1957                           (t 'switch-to-buffer))
1958                     buf)
1959            (when (and cvs-find-file-and-jump (cvs-applicable-p fi 'diff-base))
1960              (goto-line (cvs-find-modif fi)))
1961            buf))))))
1962
1963
1964 (defun-cvs-mode (cvs-mode-undo . SIMPLE) (flags)
1965   "Undo local changes to all marked files.
1966 The file is removed and `cvs update FILE' is run."
1967   ;;"With prefix argument, prompt for cvs FLAGS."
1968   (interactive (list nil));; (cvs-flags-query 'cvs-undo-flags "undo flags")
1969   (if current-prefix-arg (call-interactively 'cvs-mode-revert-to-rev)
1970     (let* ((fis (cvs-do-removal 'undo "update" 'all))
1971            (removedp (lambda (fi)
1972                        (or (eq (cvs-fileinfo->type fi) 'REMOVED)
1973                            (and (eq (cvs-fileinfo->type fi) 'CONFLICT)
1974                                 (eq (cvs-fileinfo->subtype fi) 'REMOVED)))))
1975            (fis-split (cvs-partition removedp fis))
1976            (fis-removed (car fis-split))
1977            (fis-other (cdr fis-split)))
1978       (if (null fis-other)
1979           (when fis-removed (cvs-mode-run "add" nil fis-removed))
1980         (cvs-mode-run "update" flags fis-other
1981                       :postproc
1982                       (when fis-removed
1983                         `((with-current-buffer ,(current-buffer)
1984                             (cvs-mode-run "add" nil ',fis-removed)))))))))
1985
1986
1987 (defun-cvs-mode (cvs-mode-revert-to-rev . NOARGS) (rev)
1988   "Revert the selected files to an old revision."
1989   (interactive
1990    (list (or (cvs-prefix-get 'cvs-branch-prefix)
1991              (let ((current-prefix-arg '(4)))
1992                (cvs-flags-query 'cvs-idiff-version)))))
1993   (let* ((fis (cvs-mode-marked 'revert "revert" :file t))
1994          (tag (concat "tmp_pcl_tag_" (make-temp-name "")))
1995          (untag `((with-current-buffer ,(current-buffer)
1996                     (cvs-mode-run "tag" (list "-d" ',tag) ',fis))))
1997          (update `((with-current-buffer ,(current-buffer)
1998                      (cvs-mode-run "update" (list "-j" ',tag "-j" ',rev) ',fis
1999                                    :postproc ',untag)))))
2000     (cvs-mode-run "tag" (list tag) fis :postproc update)))
2001
2002
2003 (defun-cvs-mode cvs-mode-delete-lock ()
2004   "Delete the lock file that CVS is waiting for.
2005 Note that this can be dangerous.  You should only do this
2006 if you are convinced that the process that created the lock is dead."
2007   (interactive)
2008   (let* ((default-directory (cvs-expand-dir-name cvs-lock-file))
2009          (locks (directory-files default-directory nil cvs-lock-file-regexp)))
2010     (cond
2011      ((not locks) (error "No lock files found"))
2012      ((yes-or-no-p (concat "Really delete locks in " cvs-lock-file "? "))
2013       (dolist (lock locks)
2014         (cond ((file-directory-p lock) (delete-directory lock))
2015               ((file-exists-p lock) (delete-file lock))))))))
2016
2017
2018 (defun-cvs-mode cvs-mode-remove-handled ()
2019   "Remove all lines that are handled.
2020 Empty directories are removed."
2021   (interactive)
2022   (cvs-cleanup-collection cvs-cookies
2023                           t (or cvs-auto-remove-directories 'handled) t))
2024
2025
2026 (defun-cvs-mode cvs-mode-acknowledge ()
2027   "Remove all marked files from the buffer."
2028   (interactive)
2029   (dolist (fi (cvs-get-marked (cvs-ignore-marks-p "acknowledge") t))
2030     (setf (cvs-fileinfo->type fi) 'DEAD))
2031   (cvs-cleanup-collection cvs-cookies nil nil nil))
2032
2033 (defun cvs-do-removal (filter &optional cmd all)
2034   "Remove files.
2035 Returns a list of FIS that should be `cvs remove'd."
2036   (let* ((files (cvs-mode-marked filter cmd :file t :read-only t))
2037          (fis (cdr (cvs-partition (lambda (fi)
2038                                     (eq (cvs-fileinfo->type fi) 'UNKNOWN))
2039                                   (cvs-mode-marked filter cmd))))
2040          (silent (or (not cvs-confirm-removals)
2041                      (cvs-every (lambda (fi)
2042                                   (or (not (file-exists-p
2043                                             (cvs-fileinfo->full-path fi)))
2044                                       (cvs-applicable-p fi 'safe-rm)))
2045                                 files)))
2046          (tmpbuf (cvs-temp-buffer)))
2047     (when (and (not silent) (equal cvs-confirm-removals 'list))
2048       (with-current-buffer tmpbuf
2049         (let ((inhibit-read-only t))
2050           (cvs-insert-strings (mapcar 'cvs-fileinfo->full-path fis))
2051           (cvs-pop-to-buffer-same-frame (current-buffer))
2052           (shrink-window-if-larger-than-buffer))))
2053     (if (not (or silent
2054                  (unwind-protect
2055                      (yes-or-no-p
2056                       (let ((nfiles (length files))
2057                             (verb (if (eq filter 'undo) "Undo" "Delete")))
2058                         (if (= 1 nfiles)
2059                             (format "%s file: \"%s\" ? "
2060                                     verb
2061                                     (cvs-fileinfo->file (car files)))
2062                           (format "%s %d files? "
2063                                   verb
2064                                   nfiles))))
2065                    (cvs-bury-buffer tmpbuf cvs-buffer))))
2066         (progn (message "Aborting") nil)
2067       (dolist (fi files)
2068         (let* ((type (cvs-fileinfo->type fi))
2069                (file (cvs-fileinfo->full-path fi)))
2070           (when (or all (eq type 'UNKNOWN))
2071             (when (file-exists-p file) (delete-file file))
2072             (unless all (setf (cvs-fileinfo->type fi) 'DEAD) t))))
2073       fis)))
2074
2075 (defun-cvs-mode (cvs-mode-remove . SIMPLE) (flags)
2076   "Remove all marked files.
2077 With prefix argument, prompt for cvs flags."
2078   (interactive (list (cvs-flags-query 'cvs-remove-flags "cvs remove flags")))
2079   (let ((fis (cvs-do-removal 'remove)))
2080     (if fis (cvs-mode-run "remove" (cons "-f" flags) fis)
2081       (cvs-cleanup-collection cvs-cookies nil nil nil))))
2082
2083
2084 (defvar cvs-tag-name "")
2085 (defun-cvs-mode (cvs-mode-tag . SIMPLE) (tag &optional flags)
2086   "Run `cvs tag TAG' on all selected files.
2087 With prefix argument, prompt for cvs flags.
2088 By default this can only be used on directories.
2089 Use \\[cvs-mode-force-command] or change `cvs-force-dir-tag' if you need
2090 to use it on individual files."
2091   (interactive
2092    (list (setq cvs-tag-name
2093                (cvs-query-read cvs-tag-name "Tag name: " cvs-qtypedesc-tag))
2094          (cvs-flags-query 'cvs-tag-flags "tag flags")))
2095   (cvs-mode-do "tag" (append flags (list tag))
2096                (when cvs-force-dir-tag 'tag)))
2097
2098 (defun-cvs-mode (cvs-mode-untag . SIMPLE) (tag &optional flags)
2099   "Run `cvs tag -d TAG' on all selected files.
2100 With prefix argument, prompt for cvs flags."
2101   (interactive
2102    (list (setq cvs-tag-name
2103                (cvs-query-read cvs-tag-name "Tag to delete: " cvs-qtypedesc-tag))
2104          (cvs-flags-query 'cvs-tag-flags "tag flags")))
2105   (cvs-mode-do "tag" (append '("-d") flags (list tag))
2106                (when cvs-force-dir-tag 'tag)))
2107
2108
2109 ;; Byte compile files.
2110
2111 (defun-cvs-mode cvs-mode-byte-compile-files ()
2112   "Run byte-compile-file on all selected files that end in '.el'."
2113   (interactive)
2114   (let ((marked (cvs-get-marked (cvs-ignore-marks-p "byte-compile"))))
2115     (dolist (fi marked)
2116       (let ((filename (cvs-fileinfo->full-path fi)))
2117         (when (string-match "\\.el\\'" filename)
2118           (byte-compile-file filename))))))
2119
2120 ;; ChangeLog support.
2121
2122 (defun-cvs-mode cvs-mode-add-change-log-entry-other-window ()
2123   "Add a ChangeLog entry in the ChangeLog of the current directory."
2124   (interactive)
2125   (dolist (fi (cvs-mode-marked nil nil))
2126     (let* ((default-directory (cvs-expand-dir-name (cvs-fileinfo->dir fi)))
2127            (buffer-file-name (expand-file-name (cvs-fileinfo->file fi))))
2128       (kill-local-variable 'change-log-default-name)
2129       (save-excursion (add-change-log-entry-other-window)))))
2130
2131 ;; interactive commands to set optional flags
2132
2133 (defun cvs-mode-set-flags (flag)
2134   "Ask for new setting of cvs-FLAG-flags."
2135   (interactive
2136    (list (completing-read
2137           "Which flag: "
2138           '("cvs" "diff" "update" "status" "log" "tag" ;"rtag"
2139             "commit" "remove" "undo" "checkout")
2140           nil t)))
2141   (let* ((sym (intern (concat "cvs-" flag "-flags"))))
2142     (let ((current-prefix-arg '(16)))
2143       (cvs-flags-query sym (concat flag " flags")))))
2144
2145 \f
2146 ;;;;
2147 ;;;; Utilities for the *cvs* buffer
2148 ;;;;
2149
2150 (defun cvs-dir-member-p (fileinfo dir)
2151   "Return true if FILEINFO represents a file in directory DIR."
2152   (and (not (eq (cvs-fileinfo->type fileinfo) 'DIRCHANGE))
2153        (cvs-string-prefix-p dir (cvs-fileinfo->dir fileinfo))))
2154
2155 (defun cvs-execute-single-file (fi extractor program constant-args)
2156   "Internal function for `cvs-execute-single-file-list'."
2157   (let* ((arg-list (funcall extractor fi))
2158          (inhibit-read-only t))
2159
2160     ;; Execute the command unless extractor returned t.
2161     (when (listp arg-list)
2162       (let* ((args (append constant-args arg-list)))
2163
2164         (insert (format "=== %s %s\n\n"
2165                         program (cvs-strings->string args)))
2166
2167         ;; FIXME: return the exit status?
2168         (apply 'call-process program nil t t args)
2169         (goto-char (point-max))))))
2170
2171 ;; FIXME: make this run in the background ala cvs-run-process...
2172 (defun cvs-execute-single-file-list (fis extractor program constant-args)
2173   "Run PROGRAM on all elements on FIS.
2174 CONSTANT-ARGS is a list of strings to pass as arguments to PROGRAM.
2175 The arguments given to the program will be CONSTANT-ARGS followed by
2176 the list that EXTRACTOR returns.
2177
2178 EXTRACTOR will be called once for each file on FIS.  It is given
2179 one argument, the cvs-fileinfo.  It can return t, which means ignore
2180 this file, or a list of arguments to send to the program."
2181   (dolist (fi fis)
2182     (cvs-execute-single-file fi extractor program constant-args)))
2183
2184 \f
2185 (defun cvs-revert-if-needed (fis)
2186   (dolist (fileinfo fis)
2187     (let* ((file (cvs-fileinfo->full-path fileinfo))
2188            (buffer (find-buffer-visiting file)))
2189       ;; For a revert to happen the user must be editing the file...
2190       (unless (or (null buffer)
2191                   (eq (cvs-fileinfo->type fileinfo) 'MESSAGE)
2192                   ;; FIXME: check whether revert is really needed.
2193                   ;; `(verify-visited-file-modtime buffer)' doesn't cut it
2194                   ;; because it only looks at the time stamp (it ignores
2195                   ;; read-write changes) which is not changed by `commit'.
2196                   (buffer-modified-p buffer))
2197         (with-current-buffer buffer
2198           (ignore-errors
2199             (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
2200             ;; `preserve-modes' avoids changing the (minor) modes.  But we
2201             ;; do want to reset the mode for VC, so we do it explicitly.
2202             (vc-find-file-hook)
2203             (when (eq (cvs-fileinfo->type fileinfo) 'CONFLICT)
2204               (smerge-mode 1))))))))
2205
2206 \f
2207 (defun cvs-change-cvsroot (newroot)
2208   "Change the cvsroot."
2209   (interactive "DNew repository: ")
2210   (if (or (file-directory-p (expand-file-name "CVSROOT" newroot))
2211           (y-or-n-p (concat "Warning: no CVSROOT found inside repository."
2212                             " Change cvs-cvsroot anyhow?")))
2213       (setq cvs-cvsroot newroot)))
2214
2215 ;;;;
2216 ;;;; useful global settings
2217 ;;;;
2218
2219 ;;;###autoload
2220 (add-to-list 'completion-ignored-extensions "CVS/")
2221
2222 ;;
2223 ;; Hook to allow calling PCL-CVS by visiting the /CVS subdirectory
2224 ;;
2225
2226 ;;;###autoload
2227 (defcustom cvs-dired-action 'cvs-quickdir
2228   "The action to be performed when opening a CVS directory.
2229 Sensible values are `cvs-examine', `cvs-status' and `cvs-quickdir'."
2230   :group 'pcl-cvs
2231   :type '(choice (const cvs-examine) (const cvs-status) (const cvs-quickdir)))
2232
2233 ;;;###autoload
2234 (defcustom cvs-dired-use-hook '(4)
2235   "Whether or not opening a CVS directory should run PCL-CVS.
2236 nil means never do it.
2237 ALWAYS means to always do it unless a prefix argument is given to the
2238   command that prompted the opening of the directory.
2239 Anything else means to do it only if the prefix arg is equal to this value."
2240   :group 'pcl-cvs
2241   :type '(choice (const :tag "Never" nil)
2242                  (const :tag "Always" always)
2243                  (const :tag "Prefix" (4))))
2244
2245 ;;;###autoload
2246 (progn (defun cvs-dired-noselect (dir)
2247   "Run `cvs-examine' if DIR is a CVS administrative directory.
2248 The exact behavior is determined also by `cvs-dired-use-hook'."
2249   (when (stringp dir)
2250     (setq dir (directory-file-name dir))
2251     (when (and (string= "CVS" (file-name-nondirectory dir))
2252                (file-readable-p (expand-file-name "Entries" dir))
2253                cvs-dired-use-hook
2254                (if (eq cvs-dired-use-hook 'always)
2255                    (not current-prefix-arg)
2256                  (equal current-prefix-arg cvs-dired-use-hook)))
2257       (save-excursion
2258         (funcall cvs-dired-action (file-name-directory dir) t t))))))
2259
2260 ;;
2261 ;; hook into VC
2262 ;;
2263
2264 (add-hook 'vc-post-command-functions 'cvs-vc-command-advice)
2265
2266 (defun cvs-vc-command-advice (command file flags)
2267   (when (and (equal command "cvs")
2268              (progn
2269                (while (and (stringp (car flags))
2270                            (string-match "\\`-" (car flags)))
2271                  (pop flags))
2272                ;; don't parse output we don't understand.
2273                (member (car flags) cvs-parse-known-commands))
2274              ;; Don't parse "update -p" output.
2275              (not (and (member (car flags) '("update" "checkout"))
2276                        (let ((found-p nil))
2277                          (dolist (flag flags found-p)
2278                            (if (equal flag "-p") (setq found-p t)))))))
2279     (save-current-buffer
2280       (let ((buffer (current-buffer))
2281             (dir default-directory)
2282             (cvs-from-vc t))
2283         (dolist (cvs-buf (buffer-list))
2284           (set-buffer cvs-buf)
2285           ;; look for a corresponding pcl-cvs buffer
2286           (when (and (eq major-mode 'cvs-mode)
2287                      (cvs-string-prefix-p default-directory dir))
2288             (let ((subdir (substring dir (length default-directory))))
2289               (set-buffer buffer)
2290               (set (make-local-variable 'cvs-buffer) cvs-buf)
2291               ;; `cvs -q add file' produces no useful output :-(
2292               (when (and (equal (car flags) "add")
2293                          (goto-char (point-min))
2294                          (looking-at ".*to add this file permanently\n\\'"))
2295                 (insert "cvs add: scheduling file `"
2296                         (file-name-nondirectory file)
2297                         "' for addition\n"))
2298               ;; VC never (?) does `cvs -n update' so dcd=nil
2299               ;; should probably always be the right choice.
2300               (cvs-parse-process nil subdir))))))))
2301
2302 ;;
2303 ;; Hook into write-buffer
2304 ;;
2305
2306 (defun cvs-mark-buffer-changed ()
2307   (let* ((file (expand-file-name buffer-file-name))
2308          (version (and (fboundp 'vc-backend)
2309                        (eq (vc-backend file) 'CVS)
2310                        (vc-workfile-version file))))
2311     (when version
2312       (save-excursion
2313         (dolist (cvs-buf (buffer-list))
2314           (set-buffer cvs-buf)
2315           ;; look for a corresponding pcl-cvs buffer
2316           (when (and (eq major-mode 'cvs-mode)
2317                      (cvs-string-prefix-p default-directory file))
2318             (let* ((file (substring file (length default-directory)))
2319                    (fi (cvs-create-fileinfo
2320                         (if (string= "0" version)
2321                             'ADDED 'MODIFIED)
2322                         (or (file-name-directory file) "")
2323                         (file-name-nondirectory file)
2324                         "cvs-mark-buffer-changed")))
2325               (cvs-addto-collection cvs-cookies fi))))))))
2326
2327 (add-hook 'after-save-hook 'cvs-mark-buffer-changed)
2328
2329 \f
2330 (provide 'pcvs)
2331
2332 ;;; arch-tag: 8e3a7494-0453-4389-9ab3-a557ce9fab61
2333 ;;; pcvs.el ends here