lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Morten Welinder <terra@gnu.org>
   6 ;; Keywords: archives msdog editing major-mode
   7 ;; Favourite-brand-of-beer: None, I hate beer.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  29 ;; to files whose name end in ".arc"
  30 ;;
  31 ;; This code does not decode any files internally, although it does
  32 ;; understand the directory level of the archives.  For this reason,
  33 ;; you should expect this code to need more fiddling than tar-mode.el
  34 ;; (although it at present has fewer bugs :-)  In particular, I have
  35 ;; not tested this under Ms-Dog myself.
  36 ;; -------------------------------------
  37 ;; INTERACTION: arc-mode.el should play together with
  38 ;;
  39 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  40 ;;                to you) are handled by doing all updates on a local
  41 ;;                copy.  When you make changes to a remote file the
  42 ;;                changes will first take effect when the archive buffer
  43 ;;                is saved.  You will be warned about this.
  44 ;;
  45 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  46 ;;                conversion.
  47 ;;
  48 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  49 ;; such this could be fixed (but wouldn't be useful) by declaring such
  50 ;; archives to be "remote".  For the members this is a general Emacs
  51 ;; problem that 19.29's file formats may fix.
  52 ;; -------------------------------------
  53 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  54 ;; structure for handling just about anything is in place.
  55 ;;
  56 ;;                        Arc     Lzh     Zip     Zoo
  57 ;;                        --------------------------------
  58 ;; View listing           Intern  Intern  Intern  Intern
  59 ;; Extract member         Y       Y       Y       Y
  60 ;; Save changed member    Y       Y       Y       Y
  61 ;; Add new member         N       N       N       N
  62 ;; Delete member          Y       Y       Y       Y
  63 ;; Rename member          Y       Y       N       N
  64 ;; Chmod                  -       Y       Y       -
  65 ;; Chown                  -       Y       -       -
  66 ;; Chgrp                  -       Y       -       -
  67 ;;
  68 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  69 ;; on the first released version of this package.
  70 ;;
  71 ;; This code is partly based on tar-mode.el from Emacs.
  72 ;; -------------------------------------
  73 ;; ARCHIVE STRUCTURES:
  74 ;; (This is mostly for myself.)
  75 ;;
  76 ;; ARC         A series of (header,file).  No interactions among members.
  77 ;;
  78 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  79 ;;             interaction among members.
  80 ;;             Headers come in three flavours called level 0, 1 and 2 headers.
  81 ;;             Level 2 header is free of DOS specific restrictions and most
  82 ;;             prevalently used.  Also level 1 and 2 headers consist of base
  83 ;;             and extension headers.  For more details see
  84 ;;             http://homepage1.nifty.com/dangan/en/Content/Program/Java/jLHA/Notes/Notes.html
  85 ;;             http://www.osirusoft.com/joejared/lzhformat.html
  86 ;;
  87 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  88 ;;             which is a series of (cheader) followed by an end-of-
  89 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  90 ;;             links to c-d.  cheaders link to lheaders which are basically
  91 ;;             cut-down versions of the cheaders.
  92 ;;
  93 ;; ZOO         An archive header followed by a series of (header,file).
  94 ;;             Each member header points to the next.  The archive is
  95 ;;             terminated by a bogus header with a zero next link.
  96 ;; -------------------------------------
  97 ;; HOOKS: `foo' means one of the supported archive types.
  98 ;;
  99 ;; archive-mode-hook
 100 ;; archive-foo-mode-hook
 101 ;; archive-extract-hooks
 102
 103 ;;; Code:
 104
 105 ;; -------------------------------------------------------------------------
 106 ;; Section: Configuration.
 107
 108 (defgroup archive nil
 109   "Simple editing of archives."
 110   :group 'data)
 111
 112 (defgroup archive-arc nil
 113   "ARC-specific options to archive."
 114   :group 'archive)
 115
 116 (defgroup archive-lzh nil
 117   "LZH-specific options to archive."
 118   :group 'archive)
 119
 120 (defgroup archive-zip nil
 121   "ZIP-specific options to archive."
 122   :group 'archive)
 123
 124 (defgroup archive-zoo nil
 125   "ZOO-specific options to archive."
 126   :group 'archive)
 127
 128 (defcustom archive-tmpdir
 129   ;; make-temp-name is safe here because we use this name
 130   ;; to create a directory.
 131   (make-temp-name
 132    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 133                      temporary-file-directory))
 134   "*Directory for temporary files made by arc-mode.el"
 135   :type 'directory
 136   :group 'archive)
 137
 138 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 139   "*Regexp recognizing archive files names that are not local.
 140 A non-local file is one whose file name is not proper outside Emacs.
 141 A local copy of the archive will be used when updating."
 142   :type 'regexp
 143   :group 'archive)
 144
 145 (defcustom archive-extract-hooks nil
 146   "*Hooks to run when an archive member has been extracted."
 147   :type 'hook
 148   :group 'archive)
 149 ;; ------------------------------
 150 ;; Arc archive configuration
 151
 152 ;; We always go via a local file since there seems to be no reliable way
 153 ;; to extract to stdout without junk getting added.
 154 (defcustom archive-arc-extract
 155   '("arc" "x")
 156   "*Program and its options to run in order to extract an arc file member.
 157 Extraction should happen to the current directory.  Archive and member
 158 name will be added."
 159   :type '(list (string :tag "Program")
 160                 (repeat :tag "Options"
 161                         :inline t
 162                         (string :format "%v")))
 163   :group 'archive-arc)
 164
 165 (defcustom archive-arc-expunge
 166   '("arc" "d")
 167   "*Program and its options to run in order to delete arc file members.
 168 Archive and member names will be added."
 169   :type '(list (string :tag "Program")
 170                 (repeat :tag "Options"
 171                         :inline t
 172                         (string :format "%v")))
 173   :group 'archive-arc)
 174
 175 (defcustom archive-arc-write-file-member
 176   '("arc" "u")
 177   "*Program and its options to run in order to update an arc file member.
 178 Archive and member name will be added."
 179   :type '(list (string :tag "Program")
 180                 (repeat :tag "Options"
 181                         :inline t
 182                         (string :format "%v")))
 183   :group 'archive-arc)
 184 ;; ------------------------------
 185 ;; Lzh archive configuration
 186
 187 (defcustom archive-lzh-extract
 188   '("lha" "pq")
 189   "*Program and its options to run in order to extract an lzh file member.
 190 Extraction should happen to standard output.  Archive and member name will
 191 be added."
 192   :type '(list (string :tag "Program")
 193                 (repeat :tag "Options"
 194                         :inline t
 195                         (string :format "%v")))
 196   :group 'archive-lzh)
 197
 198 (defcustom archive-lzh-expunge
 199   '("lha" "d")
 200   "*Program and its options to run in order to delete lzh file members.
 201 Archive and member names will be added."
 202   :type '(list (string :tag "Program")
 203                 (repeat :tag "Options"
 204                         :inline t
 205                         (string :format "%v")))
 206   :group 'archive-lzh)
 207
 208 (defcustom archive-lzh-write-file-member
 209   '("lha" "a")
 210   "*Program and its options to run in order to update an lzh file member.
 211 Archive and member name will be added."
 212   :type '(list (string :tag "Program")
 213                 (repeat :tag "Options"
 214                         :inline t
 215                         (string :format "%v")))
 216   :group 'archive-lzh)
 217 ;; ------------------------------
 218 ;; Zip archive configuration
 219
 220 (defcustom archive-zip-extract
 221   (if (locate-file "unzip" nil 'file-executable-p)
 222       '("unzip" "-qq" "-c")
 223     (if (locate-file "pkunzip" nil 'file-executable-p)
 224         '("pkunzip" "-e" "-o-")
 225       '("unzip" "-qq" "-c")))
 226   "*Program and its options to run in order to extract a zip file member.
 227 Extraction should happen to standard output.  Archive and member name will
 228 be added.  If `archive-zip-use-pkzip' is non-nil then this program is
 229 expected to extract to a file junking the directory part of the name."
 230   :type '(list (string :tag "Program")
 231                 (repeat :tag "Options"
 232                         :inline t
 233                         (string :format "%v")))
 234   :group 'archive-zip)
 235
 236 ;; For several reasons the latter behaviour is not desirable in general.
 237 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 238 ;; existent.  (3) It tends to do funny things with other systems' file
 239 ;; names.
 240
 241 (defcustom archive-zip-expunge
 242   (if (locate-file "zip" nil 'file-executable-p)
 243       '("zip" "-d" "-q")
 244     (if (locate-file "pkzip" nil 'file-executable-p)
 245          '("pkzip" "-d")
 246       '("zip" "-d" "-q")))
 247   "*Program and its options to run in order to delete zip file members.
 248 Archive and member names will be added."
 249   :type '(list (string :tag "Program")
 250                 (repeat :tag "Options"
 251                         :inline t
 252                         (string :format "%v")))
 253   :group 'archive-zip)
 254
 255 (defcustom archive-zip-update
 256   (if (locate-file "zip" nil 'file-executable-p)
 257       '("zip" "-q")
 258     (if (locate-file "pkzip" nil 'file-executable-p)
 259          '("pkzip" "-u" "-P")
 260       '("zip" "-q")))
 261   "*Program and its options to run in order to update a zip file member.
 262 Options should ensure that specified directory will be put into the zip
 263 file.  Archive and member name will be added."
 264   :type '(list (string :tag "Program")
 265                 (repeat :tag "Options"
 266                         :inline t
 267                         (string :format "%v")))
 268   :group 'archive-zip)
 269
 270 (defcustom archive-zip-update-case
 271   (if (locate-file "zip" nil 'file-executable-p)
 272       '("zip" "-q" "-k")
 273     (if (locate-file "pkzip" nil 'file-executable-p)
 274          '("pkzip" "-u" "-P")
 275       '("zip" "-q" "-k")))
 276   "*Program and its options to run in order to update a case fiddled zip member.
 277 Options should ensure that specified directory will be put into the zip file.
 278 Archive and member name will be added."
 279   :type '(list (string :tag "Program")
 280                 (repeat :tag "Options"
 281                         :inline t
 282                         (string :format "%v")))
 283   :group 'archive-zip)
 284
 285 (defcustom archive-zip-case-fiddle t
 286   "*If non-nil then zip file members may be down-cased.
 287 This case fiddling will only happen for members created by a system
 288 that uses caseless file names."
 289   :type 'boolean
 290   :group 'archive-zip)
 291 ;; ------------------------------
 292 ;; Zoo archive configuration
 293
 294 (defcustom archive-zoo-extract
 295   '("zoo" "xpq")
 296   "*Program and its options to run in order to extract a zoo file member.
 297 Extraction should happen to standard output.  Archive and member name will
 298 be added."
 299   :type '(list (string :tag "Program")
 300                 (repeat :tag "Options"
 301                         :inline t
 302                         (string :format "%v")))
 303   :group 'archive-zoo)
 304
 305 (defcustom archive-zoo-expunge
 306   '("zoo" "DqPP")
 307   "*Program and its options to run in order to delete zoo file members.
 308 Archive and member names will be added."
 309   :type '(list (string :tag "Program")
 310                 (repeat :tag "Options"
 311                         :inline t
 312                         (string :format "%v")))
 313   :group 'archive-zoo)
 314
 315 (defcustom archive-zoo-write-file-member
 316   '("zoo" "a")
 317   "*Program and its options to run in order to update a zoo file member.
 318 Archive and member name will be added."
 319   :type '(list (string :tag "Program")
 320                 (repeat :tag "Options"
 321                         :inline t
 322                         (string :format "%v")))
 323   :group 'archive-zoo)
 324 ;; -------------------------------------------------------------------------
 325 ;; Section: Variables
 326
 327 (defvar archive-subtype nil "Symbol describing archive type.")
 328 (defvar archive-file-list-start nil "Position of first contents line.")
 329 (defvar archive-file-list-end nil "Position just after last contents line.")
 330 (defvar archive-proper-file-start nil "Position of real archive's start.")
 331 (defvar archive-read-only nil "Non-nil if the archive is read-only on disk.")
 332 (defvar archive-local-name nil "Name of local copy of remote archive.")
 333 (defvar archive-mode-map nil "Local keymap for archive mode listings.")
 334 (defvar archive-file-name-indent nil "Column where file names start.")
 335
 336 (defvar archive-remote nil "Non-nil if the archive is outside file system.")
 337 (make-variable-buffer-local 'archive-remote)
 338 (put 'archive-remote 'permanent-local t)
 339
 340 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 341 (make-variable-buffer-local 'archive-member-coding-system)
 342
 343 (defvar archive-alternate-display nil
 344   "Non-nil when alternate information is shown.")
 345 (make-variable-buffer-local 'archive-alternate-display)
 346 (put 'archive-alternate-display 'permanent-local t)
 347
 348 (defvar archive-superior-buffer nil "In archive members, points to archive.")
 349 (put 'archive-superior-buffer 'permanent-local t)
 350
 351 (defvar archive-subfile-mode nil "Non-nil in archive member buffers.")
 352 (make-variable-buffer-local 'archive-subfile-mode)
 353 (put 'archive-subfile-mode 'permanent-local t)
 354
 355 (defvar archive-files nil
 356   "Vector of file descriptors.
 357 Each descriptor is a vector of the form
 358  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 359 (make-variable-buffer-local 'archive-files)
 360
 361 (defvar archive-lemacs
 362   (string-match "\\(Lucid\\|Xemacs\\)" emacs-version)
 363   "*Non-nil when running under under Lucid Emacs or Xemacs.")
 364 ;; -------------------------------------------------------------------------
 365 ;; Section: Support functions.
 366
 367 (defsubst archive-name (suffix)
 368   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 369
 370 (defun archive-l-e (str &optional len)
 371   "Convert little endian string/vector to integer.
 372 Alternatively, first argument may be a buffer position in the current buffer
 373 in which case a second argument, length, should be supplied."
 374   (if (stringp str)
 375       (setq len (length str))
 376     (setq str (buffer-substring str (+ str len))))
 377   (let ((result 0)
 378         (i 0))
 379     (while (< i len)
 380       (setq i (1+ i)
 381             result (+ (ash result 8) (aref str (- len i)))))
 382     result))
 383
 384 (defun archive-int-to-mode (mode)
 385   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 386   ;; FIXME: merge with tar-grind-file-mode.
 387   (string
 388     (if (zerop (logand  8192 mode))
 389         (if (zerop (logand 16384 mode)) ?- ?d)
 390       ?c) ; completeness
 391     (if (zerop (logand   256 mode)) ?- ?r)
 392     (if (zerop (logand   128 mode)) ?- ?w)
 393     (if (zerop (logand    64 mode))
 394         (if (zerop (logand  1024 mode)) ?- ?S)
 395       (if (zerop (logand  1024 mode)) ?x ?s))
 396     (if (zerop (logand    32 mode)) ?- ?r)
 397     (if (zerop (logand    16 mode)) ?- ?w)
 398     (if (zerop (logand     8 mode))
 399         (if (zerop (logand  2048 mode)) ?- ?S)
 400       (if (zerop (logand  2048 mode)) ?x ?s))
 401     (if (zerop (logand     4 mode)) ?- ?r)
 402     (if (zerop (logand     2 mode)) ?- ?w)
 403     (if (zerop (logand     1 mode)) ?- ?x)))
 404
 405 (defun archive-calc-mode (oldmode newmode &optional error)
 406   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 407 NEWMODE may be an octal number including a leading zero in which case it
 408 will become the new mode.\n
 409 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 410 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 411 If optional third argument ERROR is non-nil an error will be signaled if
 412 the mode is invalid.  If ERROR is nil then nil will be returned."
 413   (cond ((string-match "^0[0-7]*$" newmode)
 414          (let ((result 0)
 415                (len (length newmode))
 416                (i 1))
 417            (while (< i len)
 418              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 419                    i (1+ i)))
 420            (logior (logand oldmode 65024) result)))
 421         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 422          (let ((who 0)
 423                (result oldmode)
 424                (op (aref newmode (match-beginning 2)))
 425                (bits 0)
 426                (i (match-beginning 3)))
 427            (while (< i (match-end 3))
 428              (let ((rwx (aref newmode i)))
 429                (setq bits (logior bits (cond ((= rwx ?r)  292)
 430                                              ((= rwx ?w)  146)
 431                                              ((= rwx ?x)   73)
 432                                              ((= rwx ?s) 3072)
 433                                              ((= rwx ?t)  512)))
 434                      i (1+ i))))
 435            (while (< who (match-end 1))
 436              (let* ((whoc (aref newmode who))
 437                     (whomask (cond ((= whoc ?a) 4095)
 438                                    ((= whoc ?u) 1472)
 439                                    ((= whoc ?g) 2104)
 440                                    ((= whoc ?o)    7))))
 441                (if (= op ?=)
 442                    (setq result (logand result (lognot whomask))))
 443                (if (= op ?-)
 444                    (setq result (logand result (lognot (logand whomask bits))))
 445                  (setq result (logior result (logand whomask bits)))))
 446              (setq who (1+ who)))
 447            result))
 448         (t
 449          (if error
 450              (error "Invalid mode specification: %s" newmode)))))
 451
 452 (defun archive-dosdate (date)
 453   "Stringify dos packed DATE record."
 454   (let ((year (+ 1980 (logand (ash date -9) 127)))
 455         (month (logand (ash date -5) 15))
 456         (day (logand date 31)))
 457     (if (or (> month 12) (< month 1))
 458         ""
 459       (format "%2d-%s-%d"
 460               day
 461               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 462                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 463               year))))
 464
 465 (defun archive-dostime (time)
 466   "Stringify dos packed TIME record."
 467   (let ((hour (logand (ash time -11) 31))
 468         (minute (logand (ash time -5) 63))
 469         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 470     (format "%02d:%02d:%02d" hour minute second)))
 471
 472 (defun archive-unixdate (low high)
 473   "Stringify unix (LOW HIGH) date."
 474   (let ((str (current-time-string (cons high low))))
 475     (format "%s-%s-%s"
 476             (substring str 8 10)
 477             (substring str 4 7)
 478             (substring str 20 24))))
 479
 480 (defun archive-unixtime (low high)
 481   "Stringify unix (LOW HIGH) time."
 482   (let ((str (current-time-string (cons high low))))
 483     (substring str 11 19)))
 484
 485 (defun archive-get-lineno ()
 486   (if (>= (point) archive-file-list-start)
 487       (count-lines archive-file-list-start
 488                    (save-excursion (beginning-of-line) (point)))
 489     0))
 490
 491 (defun archive-get-descr (&optional noerror)
 492   "Return the descriptor vector for file at point.
 493 Does not signal an error if optional second argument NOERROR is non-nil."
 494   (let ((no (archive-get-lineno)))
 495     (if (and (>= (point) archive-file-list-start)
 496              (< no (length archive-files)))
 497         (let ((item (aref archive-files no)))
 498           (if (vectorp item)
 499               item
 500             (if (not noerror)
 501                 (error "Entry is not a regular member of the archive"))))
 502       (if (not noerror)
 503           (error "Line does not describe a member of the archive")))))
 504 ;; -------------------------------------------------------------------------
 505 ;; Section: the mode definition
 506
 507 ;;;###autoload
 508 (defun archive-mode (&optional force)
 509   "Major mode for viewing an archive file in a dired-like way.
 510 You can move around using the usual cursor motion commands.
 511 Letters no longer insert themselves.
 512 Type `e' to pull a file out of the archive and into its own buffer;
 513 or click mouse-2 on the file's line in the archive mode buffer.
 514
 515 If you edit a sub-file of this archive (as with the `e' command) and
 516 save it, the contents of that buffer will be saved back into the
 517 archive.
 518
 519 \\{archive-mode-map}"
 520   ;; This is not interactive because you shouldn't be turning this
 521   ;; mode on and off.  You can corrupt things that way.
 522   (if (zerop (buffer-size))
 523       ;; At present we cannot create archives from scratch
 524       (funcall default-major-mode)
 525     (if (and (not force) archive-files) nil
 526       (let* ((type (archive-find-type))
 527              (typename (capitalize (symbol-name type))))
 528         (kill-all-local-variables)
 529         (make-local-variable 'archive-subtype)
 530         (setq archive-subtype type)
 531
 532         ;; Buffer contains treated image of file before the file contents
 533         (make-local-variable 'revert-buffer-function)
 534         (setq revert-buffer-function 'archive-mode-revert)
 535         (auto-save-mode 0)
 536
 537         ;; Remote archives are not written by a hook.
 538         (if archive-remote nil
 539           (make-local-variable 'write-contents-hooks)
 540           (add-hook 'write-contents-hooks 'archive-write-file))
 541
 542         (make-local-variable 'require-final-newline)
 543         (setq require-final-newline nil)
 544         (make-local-variable 'local-enable-local-variables)
 545         (setq local-enable-local-variables nil)
 546
 547         ;; Prevent loss of data when saving the file.
 548         (make-local-variable 'file-precious-flag)
 549         (setq file-precious-flag t)
 550
 551         (make-local-variable 'archive-read-only)
 552         ;; Archives which are inside other archives and whose
 553         ;; names are invalid for this OS, can't be written.
 554         (setq archive-read-only
 555               (or (not (file-writable-p (buffer-file-name)))
 556                   (and archive-subfile-mode
 557                        (string-match file-name-invalid-regexp
 558                                      (aref archive-subfile-mode 0)))))
 559
 560         ;; Should we use a local copy when accessing from outside Emacs?
 561         (make-local-variable 'archive-local-name)
 562
 563         ;; An archive can contain another archive whose name is invalid
 564         ;; on local filesystem.  Treat such archives as remote.
 565         (or archive-remote
 566             (setq archive-remote
 567                   (or (string-match archive-remote-regexp (buffer-file-name))
 568                       (string-match file-name-invalid-regexp
 569                                     (buffer-file-name)))))
 570
 571         (setq major-mode 'archive-mode)
 572         (setq mode-name (concat typename "-Archive"))
 573         ;; Run archive-foo-mode-hook and archive-mode-hook
 574         (run-hooks (archive-name "mode-hook") 'archive-mode-hook)
 575         (use-local-map archive-mode-map))
 576
 577       (make-local-variable 'archive-proper-file-start)
 578       (make-local-variable 'archive-file-list-start)
 579       (make-local-variable 'archive-file-list-end)
 580       (make-local-variable 'archive-file-name-indent)
 581       (archive-summarize nil)
 582       (setq buffer-read-only t))))
 583
 584 ;; Archive mode is suitable only for specially formatted data.
 585 (put 'archive-mode 'mode-class 'special)
 586 ;; -------------------------------------------------------------------------
 587 ;; Section: Key maps
 588
 589 (if archive-mode-map nil
 590   (setq archive-mode-map (make-keymap))
 591   (suppress-keymap archive-mode-map)
 592   (define-key archive-mode-map " " 'archive-next-line)
 593   (define-key archive-mode-map "a" 'archive-alternate-display)
 594   ;;(define-key archive-mode-map "c" 'archive-copy)
 595   (define-key archive-mode-map "d" 'archive-flag-deleted)
 596   (define-key archive-mode-map "\C-d" 'archive-flag-deleted)
 597   (define-key archive-mode-map "e" 'archive-extract)
 598   (define-key archive-mode-map "f" 'archive-extract)
 599   (define-key archive-mode-map "\C-m" 'archive-extract)
 600   (define-key archive-mode-map "g" 'revert-buffer)
 601   (define-key archive-mode-map "h" 'describe-mode)
 602   (define-key archive-mode-map "m" 'archive-mark)
 603   (define-key archive-mode-map "n" 'archive-next-line)
 604   (define-key archive-mode-map "\C-n" 'archive-next-line)
 605   (define-key archive-mode-map [down] 'archive-next-line)
 606   (define-key archive-mode-map "o" 'archive-extract-other-window)
 607   (define-key archive-mode-map "p" 'archive-previous-line)
 608   (define-key archive-mode-map "q" 'quit-window)
 609   (define-key archive-mode-map "\C-p" 'archive-previous-line)
 610   (define-key archive-mode-map [up] 'archive-previous-line)
 611   (define-key archive-mode-map "r" 'archive-rename-entry)
 612   (define-key archive-mode-map "u" 'archive-unflag)
 613   (define-key archive-mode-map "\M-\C-?" 'archive-unmark-all-files)
 614   (define-key archive-mode-map "v" 'archive-view)
 615   (define-key archive-mode-map "x" 'archive-expunge)
 616   (define-key archive-mode-map "\177" 'archive-unflag-backwards)
 617   (define-key archive-mode-map "E" 'archive-extract-other-window)
 618   (define-key archive-mode-map "M" 'archive-chmod-entry)
 619   (define-key archive-mode-map "G" 'archive-chgrp-entry)
 620   (define-key archive-mode-map "O" 'archive-chown-entry)
 621
 622   (if archive-lemacs
 623       (progn
 624         ;; Not a nice "solution" but it'll have to do
 625         (define-key archive-mode-map "\C-xu" 'archive-undo)
 626         (define-key archive-mode-map "\C-_" 'archive-undo))
 627     (define-key archive-mode-map [remap advertised-undo] 'archive-undo)
 628     (define-key archive-mode-map [remap undo] 'archive-undo))
 629
 630   (define-key archive-mode-map
 631     (if archive-lemacs 'button2 [mouse-2]) 'archive-mouse-extract)
 632
 633   (if archive-lemacs
 634       ()                                ; out of luck
 635
 636     (define-key archive-mode-map [menu-bar immediate]
 637       (cons "Immediate" (make-sparse-keymap "Immediate")))
 638     (define-key archive-mode-map [menu-bar immediate alternate]
 639       '(menu-item "Alternate Display" archive-alternate-display
 640                   :enable (boundp (archive-name "alternate-display"))
 641                   :help "Toggle alternate file info display"))
 642     (define-key archive-mode-map [menu-bar immediate view]
 643       '(menu-item "View This File" archive-view
 644                   :help "Display file at cursor in View Mode"))
 645     (define-key archive-mode-map [menu-bar immediate display]
 646       '(menu-item "Display in Other Window" archive-display-other-window
 647                   :help "Display file at cursor in another window"))
 648     (define-key archive-mode-map [menu-bar immediate find-file-other-window]
 649       '(menu-item "Find in Other Window" archive-extract-other-window
 650                   :help "Edit file at cursor in another window"))
 651     (define-key archive-mode-map [menu-bar immediate find-file]
 652       '(menu-item "Find This File" archive-extract
 653                   :help "Extract file at cursor and edit it"))
 654
 655     (define-key archive-mode-map [menu-bar mark]
 656       (cons "Mark" (make-sparse-keymap "Mark")))
 657     (define-key archive-mode-map [menu-bar mark unmark-all]
 658       '(menu-item "Unmark All" archive-unmark-all-files
 659                   :help "Unmark all marked files"))
 660     (define-key archive-mode-map [menu-bar mark deletion]
 661       '(menu-item "Flag" archive-flag-deleted
 662                   :help "Flag file at cursor for deletion"))
 663     (define-key archive-mode-map [menu-bar mark unmark]
 664       '(menu-item "Unflag" archive-unflag
 665                   :help "Unmark file at cursor"))
 666     (define-key archive-mode-map [menu-bar mark mark]
 667       '(menu-item "Mark" archive-mark
 668                   :help "Mark file at cursor"))
 669
 670     (define-key archive-mode-map [menu-bar operate]
 671       (cons "Operate" (make-sparse-keymap "Operate")))
 672     (define-key archive-mode-map [menu-bar operate chown]
 673       '(menu-item "Change Owner..." archive-chown-entry
 674                   :enable (fboundp (archive-name "chown-entry"))
 675                   :help "Change owner of marked files"))
 676     (define-key archive-mode-map [menu-bar operate chgrp]
 677       '(menu-item "Change Group..." archive-chgrp-entry
 678                   :enable (fboundp (archive-name "chgrp-entry"))
 679                   :help "Change group ownership of marked files"))
 680     (define-key archive-mode-map [menu-bar operate chmod]
 681       '(menu-item "Change Mode..." archive-chmod-entry
 682                   :enable (fboundp (archive-name "chmod-entry"))
 683                   :help "Change mode (permissions) of marked files"))
 684     (define-key archive-mode-map [menu-bar operate rename]
 685       '(menu-item "Rename to..." archive-rename-entry
 686                   :enable (fboundp (archive-name "rename-entry"))
 687                   :help "Rename marked files"))
 688     ;;(define-key archive-mode-map [menu-bar operate copy]
 689     ;;  '(menu-item "Copy to..." archive-copy))
 690     (define-key archive-mode-map [menu-bar operate expunge]
 691       '(menu-item "Expunge Marked Files" archive-expunge
 692                   :help "Delete all flagged files from archive"))
 693   ))
 694
 695 (let* ((item1 '(archive-subfile-mode " Archive"))
 696        (items (list item1)))
 697   (or (member item1 minor-mode-alist)
 698       (setq minor-mode-alist (append items minor-mode-alist))))
 699 ;; -------------------------------------------------------------------------
 700 (defun archive-find-type ()
 701   (widen)
 702   (goto-char (point-min))
 703   ;; The funny [] here make it unlikely that the .elc file will be treated
 704   ;; as an archive by other software.
 705   (let (case-fold-search)
 706     (cond ((looking-at "[P]K\003\004") 'zip)
 707           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 708           ((looking-at "....................[\334]\247\304\375") 'zoo)
 709           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 710                 (string-match "\\.[aA][rR][cC]$"
 711                               (or buffer-file-name (buffer-name))))
 712            'arc)
 713           (t (error "Buffer format not recognized")))))
 714 ;; -------------------------------------------------------------------------
 715 (defun archive-summarize (&optional shut-up)
 716   "Parse the contents of the archive file in the current buffer.
 717 Place a dired-like listing on the front;
 718 then narrow to it, so that only that listing
 719 is visible (and the real data of the buffer is hidden).
 720 Optional argument SHUT-UP, if non-nil, means don't print messages
 721 when parsing the archive."
 722   (widen)
 723   (set-buffer-multibyte nil)
 724   (let (buffer-read-only)
 725     (or shut-up
 726         (message "Parsing archive file..."))
 727     (buffer-disable-undo (current-buffer))
 728     (setq archive-files (funcall (archive-name "summarize")))
 729     (or shut-up
 730         (message "Parsing archive file...done."))
 731     (setq archive-proper-file-start (point-marker))
 732     (narrow-to-region (point-min) (point))
 733     (set-buffer-modified-p nil)
 734     (buffer-enable-undo))
 735   (goto-char archive-file-list-start)
 736   (archive-next-line 0))
 737
 738 (defun archive-resummarize ()
 739   "Recreate the contents listing of an archive."
 740   (let ((modified (buffer-modified-p))
 741         (no (archive-get-lineno))
 742         buffer-read-only)
 743     (widen)
 744     (delete-region (point-min) archive-proper-file-start)
 745     (archive-summarize t)
 746     (set-buffer-modified-p modified)
 747     (goto-char archive-file-list-start)
 748     (archive-next-line no)))
 749
 750 (defun archive-summarize-files (files)
 751   "Insert a description of a list of files annotated with proper mouse face."
 752   (setq archive-file-list-start (point-marker))
 753   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 754   ;; We don't want to do an insert for each element since that takes too
 755   ;; long when the archive -- which has to be moved in memory -- is large.
 756   (insert
 757    (apply
 758     (function concat)
 759     (mapcar
 760      (function
 761       (lambda (fil)
 762         ;; Using `concat' here copies the text also, so we can add
 763         ;; properties without problems.
 764         (let ((text (concat (aref fil 0) "\n")))
 765           (if archive-lemacs
 766               ()                        ; out of luck
 767             (add-text-properties
 768              (aref fil 1) (aref fil 2)
 769              '(mouse-face highlight
 770                help-echo "mouse-2: extract this file into a buffer")
 771              text))
 772           text)))
 773      files)))
 774   (setq archive-file-list-end (point-marker)))
 775
 776 (defun archive-alternate-display ()
 777   "Toggle alternative display.
 778 To avoid very long lines some archive mode don't show all information.
 779 This function changes the set of information shown for each files."
 780   (interactive)
 781   (setq archive-alternate-display (not archive-alternate-display))
 782   (archive-resummarize))
 783 ;; -------------------------------------------------------------------------
 784 ;; Section: Local archive copy handling
 785
 786 (defun archive-unique-fname (fname dir)
 787   "Make sure a file FNAME can be created uniquely in directory DIR.
 788
 789 If FNAME can be uniquely created in DIR, it is returned unaltered.
 790 If FNAME is something our underlying filesystem can't grok, or if another
 791 file by that name already exists in DIR, a unique new name is generated
 792 using `make-temp-file', and the generated name is returned."
 793   (let ((fullname (expand-file-name fname dir))
 794         (alien (string-match file-name-invalid-regexp fname)))
 795     (if (or alien (file-exists-p fullname))
 796         (make-temp-file
 797          (expand-file-name
 798           (if (if (fboundp 'msdos-long-file-names)
 799                   (not (msdos-long-file-names)))
 800               "am"
 801             "arc-mode.")
 802           dir))
 803       fullname)))
 804
 805 (defun archive-maybe-copy (archive)
 806   (let ((coding-system-for-write 'no-conversion))
 807     (if archive-remote
 808         (let ((start (point-max))
 809               ;; Sometimes ARCHIVE is invalid while its actual name, as
 810               ;; recorded in its parent archive, is not.  For example, an
 811               ;; archive bar.zip inside another archive foo.zip gets a name
 812               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 813               ;; So use the actual name if available.
 814               (archive-name
 815                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 816                    archive)))
 817           (make-directory archive-tmpdir t)
 818           (setq archive-local-name
 819                 (archive-unique-fname archive-name archive-tmpdir))
 820           (save-restriction
 821             (widen)
 822             (write-region start (point-max) archive-local-name nil 'nomessage))
 823           archive-local-name)
 824       (if (buffer-modified-p) (save-buffer))
 825       archive)))
 826
 827 (defun archive-maybe-update (unchanged)
 828   (if archive-remote
 829       (let ((name archive-local-name)
 830             (modified (buffer-modified-p))
 831             (coding-system-for-read 'no-conversion)
 832             (lno (archive-get-lineno))
 833             buffer-read-only)
 834         (if unchanged nil
 835           (setq archive-files nil)
 836           (erase-buffer)
 837           (insert-file-contents name)
 838           (archive-mode t)
 839           (goto-char archive-file-list-start)
 840           (archive-next-line lno))
 841         (archive-delete-local name)
 842         (if (not unchanged)
 843             (message
 844              "Buffer `%s' must be saved for changes to take effect"
 845              (buffer-name (current-buffer))))
 846         (set-buffer-modified-p (or modified (not unchanged))))))
 847
 848 (defun archive-delete-local (name)
 849   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 850   (let ((again t)
 851         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 852     (condition-case nil
 853         (delete-file name)
 854       (error nil))
 855     (while again
 856       (setq name (directory-file-name (file-name-directory name)))
 857       (condition-case nil
 858           (delete-directory name)
 859         (error nil))
 860       (if (string= name top) (setq again nil)))))
 861 ;; -------------------------------------------------------------------------
 862 ;; Section: Member extraction
 863
 864 (defun archive-file-name-handler (op &rest args)
 865   (or (eq op 'file-exists-p)
 866       (let ((file-name-handler-alist nil))
 867         (apply op args))))
 868
 869 (defun archive-set-buffer-as-visiting-file (filename)
 870   "Set the current buffer as if it were visiting FILENAME."
 871   (save-excursion
 872     (goto-char (point-min))
 873     (let ((coding
 874            (or coding-system-for-read
 875                (and set-auto-coding-function
 876                     (save-excursion
 877                       (funcall set-auto-coding-function
 878                                filename (- (point-max) (point-min)))))
 879                ;; dos-w32.el defines find-operation-coding-system for
 880                ;; DOS/Windows systems which preserves the coding-system
 881                ;; of existing files.  We want it to act here as if the
 882                ;; extracted file existed.
 883                (let ((file-name-handler-alist
 884                       '(("" . archive-file-name-handler))))
 885                  (car (find-operation-coding-system 'insert-file-contents
 886                                                     filename t))))))
 887       (if (and (not coding-system-for-read)
 888                (not enable-multibyte-characters))
 889           (setq coding
 890                 (coding-system-change-text-conversion coding 'raw-text)))
 891       (if (and coding
 892                (not (eq coding 'no-conversion)))
 893           (decode-coding-region (point-min) (point-max) coding)
 894         (setq last-coding-system-used coding))
 895       (set-buffer-modified-p nil)
 896       (kill-local-variable 'buffer-file-coding-system)
 897       (after-insert-file-set-coding (- (point-max) (point-min))))))
 898
 899 (defun archive-mouse-extract (event)
 900   "Extract a file whose name you click on."
 901   (interactive "e")
 902   (mouse-set-point event)
 903   (switch-to-buffer
 904    (save-excursion
 905      (archive-extract)
 906      (current-buffer))))
 907
 908 (defun archive-extract (&optional other-window-p)
 909   "In archive mode, extract this entry of the archive into its own buffer."
 910   (interactive)
 911   (let* ((view-p (eq other-window-p 'view))
 912          (descr (archive-get-descr))
 913          (ename (aref descr 0))
 914          (iname (aref descr 1))
 915          (archive-buffer (current-buffer))
 916          (arcdir default-directory)
 917          (archive (buffer-file-name))
 918          (arcname (file-name-nondirectory archive))
 919          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 920          (extractor (archive-name "extract"))
 921          ;; Members with file names which aren't valid for the
 922          ;; underlying filesystem, are treated as read-only.
 923          (read-only-p (or archive-read-only
 924                           view-p
 925                           (string-match file-name-invalid-regexp ename)))
 926          (buffer (get-buffer bufname))
 927          (just-created nil))
 928       (if buffer
 929           nil
 930         (setq archive (archive-maybe-copy archive))
 931         (setq buffer (get-buffer-create bufname))
 932         (setq just-created t)
 933         (save-excursion
 934           (set-buffer buffer)
 935           (setq buffer-file-name
 936                 (expand-file-name (concat arcname ":" iname)))
 937           (setq buffer-file-truename
 938                 (abbreviate-file-name buffer-file-name))
 939           ;; Set the default-directory to the dir of the superior buffer.
 940           (setq default-directory arcdir)
 941           (make-local-variable 'archive-superior-buffer)
 942           (setq archive-superior-buffer archive-buffer)
 943           (make-local-variable 'local-write-file-hooks)
 944           (add-hook 'local-write-file-hooks 'archive-write-file-member)
 945           (setq archive-subfile-mode descr)
 946           (if (and
 947                (null
 948                 (let (;; We may have to encode file name arguement for
 949                       ;; external programs.
 950                       (coding-system-for-write
 951                        (and enable-multibyte-characters
 952                             file-name-coding-system))
 953                       ;; We read an archive member by no-conversion at
 954                       ;; first, then decode appropriately by calling
 955                       ;; archive-set-buffer-as-visiting-file later.
 956                       (coding-system-for-read 'no-conversion))
 957                   (condition-case err
 958                       (if (fboundp extractor)
 959                           (funcall extractor archive ename)
 960                         (archive-*-extract archive ename
 961                                            (symbol-value extractor)))
 962                     (error
 963                      (ding (message "%s" (error-message-string err)))
 964                      nil))))
 965                just-created)
 966               (progn
 967                 (set-buffer-modified-p nil)
 968                 (kill-buffer buffer))
 969             (archive-set-buffer-as-visiting-file ename)
 970             (goto-char (point-min))
 971             (rename-buffer bufname)
 972             (setq buffer-read-only read-only-p)
 973             (setq buffer-undo-list nil)
 974             (set-buffer-modified-p nil)
 975             (setq buffer-saved-size (buffer-size))
 976             (normal-mode)
 977             ;; Just in case an archive occurs inside another archive.
 978             (if (eq major-mode 'archive-mode)
 979                 (progn
 980                   (setq archive-remote t)
 981                   (if read-only-p (setq archive-read-only t))
 982                   ;; We will write out the archive ourselves if it is
 983                   ;; part of another archive.
 984                   (remove-hook 'write-contents-hooks 'archive-write-file t)))
 985             (run-hooks 'archive-extract-hooks)
 986             (if archive-read-only
 987                 (message "Note: altering this archive is not implemented."))))
 988         (archive-maybe-update t))
 989       (or (not (buffer-name buffer))
 990           (progn
 991             (if view-p
 992                 (view-buffer buffer (and just-created 'kill-buffer))
 993               (if (eq other-window-p 'display)
 994                   (display-buffer buffer)
 995                 (if other-window-p
 996                     (switch-to-buffer-other-window buffer)
 997                   (switch-to-buffer buffer))))))))
 998
 999 (defun archive-*-extract (archive name command)
1000   (let* ((default-directory (file-name-as-directory archive-tmpdir))
1001          (tmpfile (expand-file-name (file-name-nondirectory name)
1002                                     default-directory))
1003          exit-status success)
1004     (make-directory (directory-file-name default-directory) t)
1005     (setq exit-status
1006           (apply 'call-process
1007                  (car command)
1008                  nil
1009                  nil
1010                  nil
1011                  (append (cdr command) (list archive name))))
1012     (cond ((and (numberp exit-status) (= exit-status 0))
1013            (if (not (file-exists-p tmpfile))
1014                (ding (message "`%s': no such file or directory" tmpfile))
1015              (insert-file-contents tmpfile)
1016              (setq success t)))
1017           ((numberp exit-status)
1018            (ding
1019             (message "`%s' exited with status %d" (car command) exit-status)))
1020           ((stringp exit-status)
1021            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1022           (t
1023            (ding (message "`%s' failed" (car command)))))
1024     (archive-delete-local tmpfile)
1025     success))
1026
1027 (defun archive-extract-by-stdout (archive name command)
1028   (apply 'call-process
1029          (car command)
1030          nil
1031          t
1032          nil
1033          (append (cdr command) (list archive name))))
1034
1035 (defun archive-extract-other-window ()
1036   "In archive mode, find this member in another window."
1037   (interactive)
1038   (archive-extract t))
1039
1040 (defun archive-display-other-window ()
1041   "In archive mode, display this member in another window."
1042   (interactive)
1043   (archive-extract 'display))
1044
1045 (defun archive-view ()
1046   "In archive mode, view the member on this line."
1047   (interactive)
1048   (archive-extract 'view))
1049
1050 (defun archive-add-new-member (arcbuf name)
1051   "Add current buffer to the archive in ARCBUF naming it NAME."
1052   (interactive
1053    (list (get-buffer
1054           (read-buffer "Buffer containing archive: "
1055                        ;; Find first archive buffer and suggest that
1056                        (let ((bufs (buffer-list)))
1057                          (while (and bufs (not (eq (save-excursion
1058                                                      (set-buffer (car bufs))
1059                                                      major-mode)
1060                                                    'archive-mode)))
1061                            (setq bufs (cdr bufs)))
1062                          (if bufs
1063                              (car bufs)
1064                            (error "There are no archive buffers")))
1065                        t))
1066          (read-string "File name in archive: "
1067                       (if buffer-file-name
1068                           (file-name-nondirectory buffer-file-name)
1069                         ""))))
1070   (save-excursion
1071     (set-buffer arcbuf)
1072     (or (eq major-mode 'archive-mode)
1073         (error "Buffer is not an archive buffer"))
1074     (if archive-read-only
1075         (error "Archive is read-only")))
1076   (if (eq arcbuf (current-buffer))
1077       (error "An archive buffer cannot be added to itself"))
1078   (if (string= name "")
1079       (error "Archive members may not be given empty names"))
1080   (let ((func (save-excursion (set-buffer arcbuf)
1081                               (archive-name "add-new-member")))
1082         (membuf (current-buffer)))
1083     (if (fboundp func)
1084         (save-excursion
1085           (set-buffer arcbuf)
1086           (funcall func buffer-file-name membuf name))
1087       (error "Adding a new member is not supported for this archive type"))))
1088 ;; -------------------------------------------------------------------------
1089 ;; Section: IO stuff
1090
1091 (defun archive-write-file-member ()
1092   (save-excursion
1093     (save-restriction
1094       (message "Updating archive...")
1095       (widen)
1096       (let ((writer  (save-excursion (set-buffer archive-superior-buffer)
1097                                      (archive-name "write-file-member")))
1098             (archive (save-excursion (set-buffer archive-superior-buffer)
1099                                      (archive-maybe-copy (buffer-file-name)))))
1100         (if (fboundp writer)
1101             (funcall writer archive archive-subfile-mode)
1102           (archive-*-write-file-member archive
1103                                        archive-subfile-mode
1104                                        (symbol-value writer)))
1105         (set-buffer-modified-p nil)
1106         (message "Updating archive...done"))
1107       (set-buffer archive-superior-buffer)
1108       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1109   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1110   ;; won't reset the coding-system of this archive member.
1111   (if (local-variable-p 'archive-member-coding-system)
1112       (setq last-coding-system-used archive-member-coding-system))
1113   t)
1114
1115 (defun archive-*-write-file-member (archive descr command)
1116   (let* ((ename (aref descr 0))
1117          (tmpfile (expand-file-name ename archive-tmpdir))
1118          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1119          (default-directory (file-name-as-directory top)))
1120     (unwind-protect
1121         (progn
1122           (make-directory (file-name-directory tmpfile) t)
1123           ;; If the member is itself an archive, write it without
1124           ;; the dired-like listing we created.
1125           (if (eq major-mode 'archive-mode)
1126               (archive-write-file tmpfile)
1127             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1128           ;; basic-save-buffer needs last-coding-system-used to have
1129           ;; the value used to write the file, so save it before any
1130           ;; further processing clobbers it (we restore it in
1131           ;; archive-write-file-member, above).
1132           (setq archive-member-coding-system last-coding-system-used)
1133           (if (aref descr 3)
1134               ;; Set the file modes, but make sure we can read it.
1135               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1136           (if enable-multibyte-characters
1137               (setq ename
1138                     (encode-coding-string ename file-name-coding-system)))
1139           (let ((exitcode (apply 'call-process
1140                                  (car command)
1141                                  nil
1142                                  nil
1143                                  nil
1144                                  (append (cdr command) (list archive ename)))))
1145             (if (equal exitcode 0)
1146                 nil
1147               (error "Updating was unsuccessful (%S)" exitcode))))
1148       (archive-delete-local tmpfile))))
1149
1150 (defun archive-write-file (&optional file)
1151   (save-excursion
1152     (let ((coding-system-for-write 'no-conversion))
1153       (write-region archive-proper-file-start (point-max)
1154                     (or file buffer-file-name) nil t)
1155       (set-buffer-modified-p nil))
1156     t))
1157 ;; -------------------------------------------------------------------------
1158 ;; Section: Marking and unmarking.
1159
1160 (defun archive-flag-deleted (p &optional type)
1161   "In archive mode, mark this member to be deleted from the archive.
1162 With a prefix argument, mark that many files."
1163   (interactive "p")
1164   (or type (setq type ?D))
1165   (beginning-of-line)
1166   (let ((sign (if (>= p 0) +1 -1))
1167         (modified (buffer-modified-p))
1168         buffer-read-only)
1169     (while (not (zerop p))
1170       (if (archive-get-descr t)
1171           (progn
1172             (delete-char 1)
1173             (insert type)))
1174       (forward-line sign)
1175       (setq p (- p sign)))
1176     (set-buffer-modified-p modified))
1177   (archive-next-line 0))
1178
1179 (defun archive-unflag (p)
1180   "In archive mode, un-mark this member if it is marked to be deleted.
1181 With a prefix argument, un-mark that many files forward."
1182   (interactive "p")
1183   (archive-flag-deleted p ? ))
1184
1185 (defun archive-unflag-backwards (p)
1186   "In archive mode, un-mark this member if it is marked to be deleted.
1187 With a prefix argument, un-mark that many members backward."
1188   (interactive "p")
1189   (archive-flag-deleted (- p) ? ))
1190
1191 (defun archive-unmark-all-files ()
1192   "Remove all marks."
1193   (interactive)
1194   (let ((modified (buffer-modified-p))
1195         buffer-read-only)
1196     (save-excursion
1197       (goto-char archive-file-list-start)
1198       (while (< (point) archive-file-list-end)
1199         (or (= (following-char) ? )
1200             (progn (delete-char 1) (insert ? )))
1201         (forward-line 1)))
1202     (set-buffer-modified-p modified)))
1203
1204 (defun archive-mark (p)
1205   "In archive mode, mark this member for group operations.
1206 With a prefix argument, mark that many members.
1207 Use \\[archive-unmark-all-files] to remove all marks."
1208   (interactive "p")
1209   (archive-flag-deleted p ?*))
1210
1211 (defun archive-get-marked (mark &optional default)
1212   (let (files)
1213     (save-excursion
1214       (goto-char archive-file-list-start)
1215       (while (< (point) archive-file-list-end)
1216         (if (= (following-char) mark)
1217             (setq files (cons (archive-get-descr) files)))
1218         (forward-line 1)))
1219     (or (nreverse files)
1220         (and default
1221              (list (archive-get-descr))))))
1222 ;; -------------------------------------------------------------------------
1223 ;; Section: Operate
1224
1225 (defun archive-next-line (p)
1226   (interactive "p")
1227   (forward-line p)
1228   (or (eobp)
1229       (forward-char archive-file-name-indent)))
1230
1231 (defun archive-previous-line (p)
1232   (interactive "p")
1233   (archive-next-line (- p)))
1234
1235 (defun archive-chmod-entry (new-mode)
1236   "Change the protection bits associated with all marked or this member.
1237 The new protection bits can either be specified as an octal number or
1238 as a relative change like \"g+rw\" as for chmod(2)"
1239   (interactive "sNew mode (octal or relative): ")
1240   (if archive-read-only (error "Archive is read-only"))
1241   (let ((func (archive-name "chmod-entry")))
1242     (if (fboundp func)
1243         (progn
1244           (funcall func new-mode (archive-get-marked ?* t))
1245           (archive-resummarize))
1246       (error "Setting mode bits is not supported for this archive type"))))
1247
1248 (defun archive-chown-entry (new-uid)
1249   "Change the owner of all marked or this member."
1250   (interactive "nNew uid: ")
1251   (if archive-read-only (error "Archive is read-only"))
1252   (let ((func (archive-name "chown-entry")))
1253     (if (fboundp func)
1254         (progn
1255           (funcall func new-uid (archive-get-marked ?* t))
1256           (archive-resummarize))
1257       (error "Setting owner is not supported for this archive type"))))
1258
1259 (defun archive-chgrp-entry (new-gid)
1260   "Change the group of all marked or this member."
1261   (interactive "nNew gid: ")
1262   (if archive-read-only (error "Archive is read-only"))
1263   (let ((func (archive-name "chgrp-entry")))
1264     (if (fboundp func)
1265         (progn
1266           (funcall func new-gid (archive-get-marked ?* t))
1267           (archive-resummarize))
1268       (error "Setting group is not supported for this archive type"))))
1269
1270 (defun archive-expunge ()
1271   "Do the flagged deletions."
1272   (interactive)
1273   (let (files)
1274     (save-excursion
1275       (goto-char archive-file-list-start)
1276       (while (< (point) archive-file-list-end)
1277         (if (= (following-char) ?D)
1278             (setq files (cons (aref (archive-get-descr) 0) files)))
1279         (forward-line 1)))
1280     (setq files (nreverse files))
1281     (and files
1282          (or (not archive-read-only)
1283              (error "Archive is read-only"))
1284          (or (yes-or-no-p (format "Really delete %d member%s? "
1285                                   (length files)
1286                                   (if (null (cdr files)) "" "s")))
1287              (error "Operation aborted"))
1288          (let ((archive (archive-maybe-copy (buffer-file-name)))
1289                (expunger (archive-name "expunge")))
1290            (if (fboundp expunger)
1291                (funcall expunger archive files)
1292              (archive-*-expunge archive files (symbol-value expunger)))
1293            (archive-maybe-update nil)
1294            (if archive-remote
1295                (archive-resummarize)
1296              (revert-buffer))))))
1297
1298 (defun archive-*-expunge (archive files command)
1299   (apply 'call-process
1300          (car command)
1301          nil
1302          nil
1303          nil
1304          (append (cdr command) (cons archive files))))
1305
1306 (defun archive-rename-entry (newname)
1307   "Change the name associated with this entry in the tar file."
1308   (interactive "sNew name: ")
1309   (if archive-read-only (error "Archive is read-only"))
1310   (if (string= newname "")
1311       (error "Archive members may not be given empty names"))
1312   (let ((func (archive-name "rename-entry"))
1313         (descr (archive-get-descr)))
1314     (if (fboundp func)
1315         (progn
1316           (funcall func (buffer-file-name)
1317                    (if enable-multibyte-characters
1318                        (encode-coding-string newname file-name-coding-system)
1319                      newname)
1320                    descr)
1321           (archive-resummarize))
1322       (error "Renaming is not supported for this archive type"))))
1323
1324 ;; Revert the buffer and recompute the dired-like listing.
1325 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1326   (let ((no (archive-get-lineno)))
1327     (setq archive-files nil)
1328     (let ((revert-buffer-function nil)
1329           (coding-system-for-read 'no-conversion))
1330       (set-buffer-multibyte nil)
1331       (revert-buffer t t))
1332     (archive-mode)
1333     (goto-char archive-file-list-start)
1334     (archive-next-line no)))
1335
1336 (defun archive-undo ()
1337   "Undo in an archive buffer.
1338 This doesn't recover lost files, it just undoes changes in the buffer itself."
1339   (interactive)
1340   (let (buffer-read-only)
1341     (undo)))
1342 ;; -------------------------------------------------------------------------
1343 ;; Section: Arc Archives
1344
1345 (defun archive-arc-summarize ()
1346   (let ((p 1)
1347         (totalsize 0)
1348         (maxlen 8)
1349         files
1350         visual)
1351     (while (and (< (+ p 29) (point-max))
1352                 (= (char-after p) ?\C-z)
1353                 (> (char-after (1+ p)) 0))
1354       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1355              (fnlen   (or (string-match "\0" namefld) 13))
1356              (efnname (substring namefld 0 fnlen))
1357              (csize   (archive-l-e (+ p 15) 4))
1358              (moddate (archive-l-e (+ p 19) 2))
1359              (modtime (archive-l-e (+ p 21) 2))
1360              (ucsize  (archive-l-e (+ p 25) 4))
1361              (fiddle  (string= efnname (upcase efnname)))
1362              (ifnname (if fiddle (downcase efnname) efnname))
1363              (text    (format "  %8d  %-11s  %-8s  %s"
1364                               ucsize
1365                               (archive-dosdate moddate)
1366                               (archive-dostime modtime)
1367                               ifnname)))
1368         (setq maxlen (max maxlen fnlen)
1369               totalsize (+ totalsize ucsize)
1370               visual (cons (vector text
1371                                    (- (length text) (length ifnname))
1372                                    (length text))
1373                            visual)
1374               files (cons (vector efnname ifnname fiddle nil (1- p))
1375                           files)
1376               p (+ p 29 csize))))
1377     (goto-char (point-min))
1378     (let ((dash (concat "- --------  -----------  --------  "
1379                         (make-string maxlen ?-)
1380                         "\n")))
1381       (insert "M   Length  Date         Time      File\n"
1382               dash)
1383       (archive-summarize-files (nreverse visual))
1384       (insert dash
1385               (format "  %8d                         %d file%s"
1386                       totalsize
1387                       (length files)
1388                       (if (= 1 (length files)) "" "s"))
1389               "\n"))
1390     (apply 'vector (nreverse files))))
1391
1392 (defun archive-arc-rename-entry (archive newname descr)
1393   (if (string-match "[:\\\\/]" newname)
1394       (error "File names in arc files must not contain a directory component"))
1395   (if (> (length newname) 12)
1396       (error "File names in arc files are limited to 12 characters"))
1397   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1398                                          (length newname))))
1399         buffer-read-only)
1400     (save-restriction
1401       (save-excursion
1402         (widen)
1403         (set-buffer-multibyte nil)
1404         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1405         (delete-char 13)
1406         (insert name)))))
1407 ;; -------------------------------------------------------------------------
1408 ;; Section: Lzh Archives
1409
1410 (defun archive-lzh-summarize ()
1411   (let ((p 1)
1412         (totalsize 0)
1413         (maxlen 8)
1414         files
1415         visual)
1416     (while (progn (goto-char p)         ;beginning of a base header.
1417                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1418       (let* ((hsize   (char-after p))   ;size of the base header (level 0 and 1)
1419              (csize   (archive-l-e (+ p 7) 4)) ;size of a compressed file to follow (level 0 and 2),
1420                                         ;size of extended headers + the compressed file to follow (level 1).
1421              (ucsize  (archive-l-e (+ p 11) 4)) ;size of an uncompressed file.
1422              (time1   (archive-l-e (+ p 15) 2)) ;date/time (MSDOS format in level 0, 1 headers
1423              (time2   (archive-l-e (+ p 17) 2)) ;and UNIX format in level 2 header.)
1424              (hdrlvl  (char-after (+ p 20))) ;header level
1425              thsize             ;total header size (base + extensions)
1426              fnlen efnname fiddle ifnname width p2 creator
1427              neh        ;beginning of next extension header (level 1 and 2)
1428              mode modestr uid gid text dir prname
1429              gname uname modtime moddate)
1430         (if (= hdrlvl 3) (error "can't handle lzh level 3 header type"))
1431         (when (or (= hdrlvl 0) (= hdrlvl 1))
1432           (setq fnlen   (char-after (+ p 21))) ;filename length
1433           (setq efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen)))) ;filename from offset 22
1434                         (if file-name-coding-system
1435                             (decode-coding-string str file-name-coding-system)
1436                           (string-as-multibyte str))))
1437           (setq p2      (+ p 22 fnlen))) ;
1438         (if (= hdrlvl 1)
1439             (progn              ;specific to level 1 header
1440               (setq creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1441               (setq neh (+ p2 3)))
1442           (if (= hdrlvl 2)
1443               (progn            ;specific to level 2 header
1444                 (setq creator (char-after (+ p 23)) )
1445                 (setq neh (+ p 24)))))
1446         (if neh         ;if level 1 or 2 we expect extension headers to follow
1447             (let* ((ehsize (archive-l-e neh 2)) ;size of the extension header
1448                    (etype (char-after (+ neh 2)))) ;extension type
1449               (while (not (= ehsize 0))
1450                   (cond
1451                  ((= etype 1)   ;file name
1452                   (let ((i (+ neh 3)))
1453                     (while (< i (+ neh ehsize))
1454                       (setq efnname (concat efnname (char-to-string (char-after i))))
1455                       (setq i (1+ i)))))
1456                  ((= etype 2)   ;directory name
1457                   (let ((i (+ neh 3)))
1458                     (while (< i (+ neh ehsize))
1459                                     (setq dir (concat dir
1460                                                        (if (= (char-after i)
1461                                                               255)
1462                                                            "/"
1463                                                          (char-to-string
1464                                                           (char-after i)))))
1465                                     (setq i (1+ i)))))
1466                  ((= etype 80)          ;Unix file permission
1467                   (setq mode (archive-l-e (+ neh 3) 2)))
1468                  ((= etype 81)          ;UNIX file group/user ID
1469                   (progn (setq uid (archive-l-e (+ neh 3) 2))
1470                          (setq gid (archive-l-e (+ neh 5) 2))))
1471                  ((= etype 82)          ;UNIX file group name
1472                   (let ((i (+ neh 3)))
1473                     (while (< i (+ neh ehsize))
1474                       (setq gname (concat gname (char-to-string (char-after i))))
1475                       (setq i (1+ i)))))
1476                  ((= etype 83)          ;UNIX file user name
1477                   (let ((i (+ neh 3)))
1478                     (while (< i (+ neh ehsize))
1479                       (setq uname (concat uname (char-to-string (char-after i))))
1480                       (setq i (1+ i)))))
1481                    )
1482                 (setq neh (+ neh ehsize))
1483                 (setq ehsize (archive-l-e neh 2))
1484                 (setq etype (char-after (+ neh 2))))
1485               ;;get total header size for level 1 and 2 headers
1486               (setq thsize (- neh p))))
1487         (if (= hdrlvl 0)  ;total header size
1488             (setq thsize hsize))
1489         (setq fiddle  (if efnname (string= efnname (upcase efnname))))
1490         (setq ifnname (if fiddle (downcase efnname) efnname))
1491         (setq prname (if dir (concat dir ifnname) ifnname))
1492         (setq width (if prname (string-width prname) 0))
1493         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1494         (setq moddate (if (= hdrlvl 2)
1495                           (archive-unixdate time1 time2) ;level 2 header in UNIX format
1496                         (archive-dosdate time2))) ;level 0 and 1 header in DOS format
1497         (setq modtime (if (= hdrlvl 2)
1498                           (archive-unixtime time1 time2)
1499                         (archive-dostime time1)))
1500         (setq text    (if archive-alternate-display
1501                           (format "  %8d  %5S  %5S  %s"
1502                                   ucsize
1503                                   (or uid "?")
1504                                   (or gid "?")
1505                                   ifnname)
1506                         (format "  %10s  %8d  %-11s  %-8s  %s"
1507                                 modestr
1508                                 ucsize
1509                                 moddate
1510                                 modtime
1511                                 prname)))
1512         (setq maxlen (max maxlen width)
1513               totalsize (+ totalsize ucsize)
1514               visual (cons (vector text
1515                                    (- (length text) (length prname))
1516                                    (length text))
1517                            visual)
1518               files (cons (vector prname ifnname fiddle mode (1- p))
1519                           files))
1520         (cond ((= hdrlvl 1)
1521                (setq p (+ p hsize 2 csize)))
1522               ((or (= hdrlvl 2) (= hdrlvl 0))
1523                (setq p (+ p thsize 2 csize))))
1524         ))
1525     (goto-char (point-min))
1526     (set-buffer-multibyte default-enable-multibyte-characters)
1527     (let ((dash (concat (if archive-alternate-display
1528                             "- --------  -----  -----  "
1529                           "- ----------  --------  -----------  --------  ")
1530                         (make-string maxlen ?-)
1531                         "\n"))
1532           (header (if archive-alternate-display
1533                        "M   Length    Uid    Gid  File\n"
1534                     "M   Filemode    Length  Date         Time      File\n"))
1535           (sumline (if archive-alternate-display
1536                        "  %8d                %d file%s"
1537                      "              %8d                         %d file%s")))
1538       (insert header dash)
1539       (archive-summarize-files (nreverse visual))
1540       (insert dash
1541               (format sumline
1542                       totalsize
1543                       (length files)
1544                       (if (= 1 (length files)) "" "s"))
1545               "\n"))
1546     (apply 'vector (nreverse files))))
1547
1548 (defconst archive-lzh-alternate-display t)
1549
1550 (defun archive-lzh-extract (archive name)
1551   (archive-extract-by-stdout archive name archive-lzh-extract))
1552
1553 (defun archive-lzh-resum (p count)
1554   (let ((sum 0))
1555     (while (> count 0)
1556       (setq count (1- count)
1557             sum (+ sum (char-after p))
1558             p (1+ p)))
1559     (logand sum 255)))
1560
1561 (defun archive-lzh-rename-entry (archive newname descr)
1562   (save-restriction
1563     (save-excursion
1564       (widen)
1565       (set-buffer-multibyte nil)
1566       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1567              (oldhsize (char-after p))
1568              (oldfnlen (char-after (+ p 21)))
1569              (newfnlen (length newname))
1570              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1571              buffer-read-only)
1572         (if (> newhsize 255)
1573             (error "The file name is too long"))
1574         (goto-char (+ p 21))
1575         (delete-char (1+ oldfnlen))
1576         (insert newfnlen newname)
1577         (goto-char p)
1578         (delete-char 2)
1579         (insert newhsize (archive-lzh-resum p newhsize))))))
1580
1581 (defun archive-lzh-ogm (newval files errtxt ofs)
1582   (save-restriction
1583     (save-excursion
1584       (widen)
1585       (set-buffer-multibyte nil)
1586       (while files
1587         (let* ((fil (car files))
1588                (p (+ archive-proper-file-start (aref fil 4)))
1589                (hsize   (char-after p))
1590                (fnlen   (char-after (+ p 21)))
1591                (p2      (+ p 22 fnlen))
1592                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1593                buffer-read-only)
1594           (if (= creator ?U)
1595               (progn
1596                 (or (numberp newval)
1597                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1598                 (goto-char (+ p2 ofs))
1599                 (delete-char 2)
1600                 (insert (logand newval 255) (lsh newval -8))
1601                 (goto-char (1+ p))
1602                 (delete-char 1)
1603                 (insert (archive-lzh-resum (1+ p) hsize)))
1604             (message "Member %s does not have %s field"
1605                      (aref fil 1) errtxt)))
1606         (setq files (cdr files))))))
1607
1608 (defun archive-lzh-chown-entry (newuid files)
1609   (archive-lzh-ogm newuid files "an uid" 10))
1610
1611 (defun archive-lzh-chgrp-entry (newgid files)
1612   (archive-lzh-ogm newgid files "a gid" 12))
1613
1614 (defun archive-lzh-chmod-entry (newmode files)
1615   (archive-lzh-ogm
1616    ;; This should work even though newmode will be dynamically accessed.
1617    (function (lambda (old) (archive-calc-mode old newmode t)))
1618    files "a unix-style mode" 8))
1619 ;; -------------------------------------------------------------------------
1620 ;; Section: Zip Archives
1621
1622 (defun archive-zip-summarize ()
1623   (goto-char (- (point-max) (- 22 18)))
1624   (search-backward-regexp "[P]K\005\006")
1625   (let ((p (+ (point-min) (archive-l-e (+ (point) 16) 4)))
1626         (maxlen 8)
1627         (totalsize 0)
1628         files
1629         visual)
1630     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1631       (let* ((creator (char-after (+ p 5)))
1632              (method  (archive-l-e (+ p 10) 2))
1633              (modtime (archive-l-e (+ p 12) 2))
1634              (moddate (archive-l-e (+ p 14) 2))
1635              (ucsize  (archive-l-e (+ p 24) 4))
1636              (fnlen   (archive-l-e (+ p 28) 2))
1637              (exlen   (archive-l-e (+ p 30) 2))
1638              (fclen   (archive-l-e (+ p 32) 2))
1639              (lheader (archive-l-e (+ p 42) 4))
1640              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1641                         (if file-name-coding-system
1642                             (decode-coding-string str file-name-coding-system)
1643                           (string-as-multibyte str))))
1644              (isdir   (and (= ucsize 0)
1645                            (string= (file-name-nondirectory efnname) "")))
1646              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1647                              (archive-l-e (+ p 40) 2))
1648                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1649                              (logior ?\444
1650                                      (if isdir (logior 16384 ?\111) 0)
1651                                      (if (zerop
1652                                           (logand 1 (char-after (+ p 38))))
1653                                          ?\222 0)))
1654                             (t nil)))
1655              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1656              (fiddle  (and archive-zip-case-fiddle
1657                            (not (not (memq creator '(0 2 4 5 9))))
1658                            (string= (upcase efnname) efnname)))
1659              (ifnname (if fiddle (downcase efnname) efnname))
1660              (width (string-width ifnname))
1661              (text    (format "  %10s  %8d  %-11s  %-8s  %s"
1662                               modestr
1663                               ucsize
1664                               (archive-dosdate moddate)
1665                               (archive-dostime modtime)
1666                               ifnname)))
1667         (setq maxlen (max maxlen width)
1668               totalsize (+ totalsize ucsize)
1669               visual (cons (vector text
1670                                    (- (length text) (length ifnname))
1671                                    (length text))
1672                            visual)
1673               files (cons (if isdir
1674                               nil
1675                             (vector efnname ifnname fiddle mode
1676                                     (list (1- p) lheader)))
1677                           files)
1678               p (+ p 46 fnlen exlen fclen))))
1679     (goto-char (point-min))
1680     (let ((dash (concat "- ----------  --------  -----------  --------  "
1681                         (make-string maxlen ?-)
1682                         "\n")))
1683       (insert "M Filemode      Length  Date         Time      File\n"
1684               dash)
1685       (archive-summarize-files (nreverse visual))
1686       (insert dash
1687               (format "              %8d                         %d file%s"
1688                       totalsize
1689                       (length files)
1690                       (if (= 1 (length files)) "" "s"))
1691               "\n"))
1692     (apply 'vector (nreverse files))))
1693
1694 (defun archive-zip-extract (archive name)
1695   (if (equal (car archive-zip-extract) "pkzip")
1696       (archive-*-extract archive name archive-zip-extract)
1697     (archive-extract-by-stdout archive name archive-zip-extract)))
1698
1699 (defun archive-zip-write-file-member (archive descr)
1700   (archive-*-write-file-member
1701    archive
1702    descr
1703    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1704
1705 (defun archive-zip-chmod-entry (newmode files)
1706   (save-restriction
1707     (save-excursion
1708       (widen)
1709       (set-buffer-multibyte nil)
1710       (while files
1711         (let* ((fil (car files))
1712                (p (+ archive-proper-file-start (car (aref fil 4))))
1713                (creator (char-after (+ p 5)))
1714                (oldmode (aref fil 3))
1715                (newval  (archive-calc-mode oldmode newmode t))
1716                buffer-read-only)
1717           (cond ((memq creator '(2 3)) ; Unix + VMS
1718                  (goto-char (+ p 40))
1719                  (delete-char 2)
1720                  (insert (logand newval 255) (lsh newval -8)))
1721                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1722                  (goto-char (+ p 38))
1723                  (insert (logior (logand (char-after (point)) 254)
1724                                  (logand (logxor 1 (lsh newval -7)) 1)))
1725                  (delete-char 1))
1726                 (t (message "Don't know how to change mode for this member"))))
1727         (setq files (cdr files))))))
1728 ;; -------------------------------------------------------------------------
1729 ;; Section: Zoo Archives
1730
1731 (defun archive-zoo-summarize ()
1732   (let ((p (1+ (archive-l-e 25 4)))
1733         (maxlen 8)
1734         (totalsize 0)
1735         files
1736         visual)
1737     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1738                 (> (archive-l-e (+ p 6) 4) 0))
1739       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1740              (moddate (archive-l-e (+ p 14) 2))
1741              (modtime (archive-l-e (+ p 16) 2))
1742              (ucsize  (archive-l-e (+ p 20) 4))
1743              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1744              (dirtype (char-after (+ p 4)))
1745              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1746              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1747              (fnlen   (or (string-match "\0" namefld) 13))
1748              (efnname (let ((str
1749                              (concat
1750                               (if (> ldirlen 0)
1751                                   (concat (buffer-substring
1752                                            (+ p 58 lfnlen)
1753                                            (+ p 58 lfnlen ldirlen -1))
1754                                           "/")
1755                                 "")
1756                               (if (> lfnlen 0)
1757                                   (buffer-substring (+ p 58)
1758                                                     (+ p 58 lfnlen -1))
1759                                 (substring namefld 0 fnlen)))))
1760                         (if file-name-coding-system
1761                             (decode-coding-string str file-name-coding-system)
1762                           (string-as-multibyte str))))
1763              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1764              (ifnname (if fiddle (downcase efnname) efnname))
1765              (width (string-width ifnname))
1766              (text    (format "  %8d  %-11s  %-8s  %s"
1767                               ucsize
1768                               (archive-dosdate moddate)
1769                               (archive-dostime modtime)
1770                               ifnname)))
1771         (setq maxlen (max maxlen width)
1772               totalsize (+ totalsize ucsize)
1773               visual (cons (vector text
1774                                    (- (length text) (length ifnname))
1775                                    (length text))
1776                            visual)
1777               files (cons (vector efnname ifnname fiddle nil (1- p))
1778                           files)
1779               p next)))
1780     (goto-char (point-min))
1781     (let ((dash (concat "- --------  -----------  --------  "
1782                         (make-string maxlen ?-)
1783                         "\n")))
1784       (insert "M   Length  Date         Time      File\n"
1785               dash)
1786       (archive-summarize-files (nreverse visual))
1787       (insert dash
1788               (format "  %8d                         %d file%s"
1789                       totalsize
1790                       (length files)
1791                       (if (= 1 (length files)) "" "s"))
1792               "\n"))
1793     (apply 'vector (nreverse files))))
1794
1795 (defun archive-zoo-extract (archive name)
1796   (archive-extract-by-stdout archive name archive-zoo-extract))
1797 ;; -------------------------------------------------------------------------
1798 ;; This line was a mistake; it is kept now for compatibility.
1799 ;; rms  15 Oct 98
1800 (provide 'archive-mode)
1801
1802 (provide 'arc-mode)
1803
1804 ;;; arch-tag: e5966a01-35ec-4f27-8095-a043a79b457b
1805 ;;; arc-mode.el ends here