lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2004  Free Software Foundation, Inc.
   4
   5 ;; Author: Gerd Moellmann <gerd@acm.org>
   6 ;; Keywords: help c mouse tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl)) ; for case macro
  30
  31 \f
  32 ;;; Customizable settings
  33
  34 (defgroup tooltip nil
  35   "Customization group for the `tooltip' package."
  36   :group 'help
  37   :group 'gud
  38   :group 'mouse
  39   :group 'tools
  40   :version "21.1"
  41   :tag "Tool Tips")
  42
  43 (defvar tooltip-mode)
  44
  45 (defcustom tooltip-delay 0.7
  46   "Seconds to wait before displaying a tooltip the first time."
  47   :tag "Delay"
  48   :type 'number
  49   :group 'tooltip)
  50
  51 (defcustom tooltip-short-delay 0.1
  52   "Seconds to wait between subsequent tooltips on different items."
  53   :tag "Short delay"
  54   :type 'number
  55   :group 'tooltip)
  56
  57 (defcustom tooltip-recent-seconds 1
  58   "Display tooltips if changing tip items within this many seconds.
  59 Do so after `tooltip-short-delay'."
  60   :tag "Recent seconds"
  61   :type 'number
  62   :group 'tooltip)
  63
  64 (defcustom tooltip-hide-delay 10
  65   "Hide tooltips automatically after this many seconds."
  66   :tag "Hide delay"
  67   :type 'number
  68   :group 'tooltip)
  69
  70 (defcustom tooltip-x-offset nil
  71   "X offset, in pixels, for the display of tooltips.
  72 The offset is relative to the position of the mouse.  It must
  73 be chosen so that the tooltip window doesn't contain the mouse
  74 when it pops up.  If the value is nil, the default offset is 5
  75 pixels.
  76
  77 If `tooltip-frame-parameters' includes the `left' parameter,
  78 the value of `tooltip-x-offset' is ignored."
  79   :tag "X offset"
  80   :type '(choice (const :tag "Default" nil)
  81                  (integer :tag "Offset" :value 1))
  82   :group 'tooltip)
  83
  84 (defcustom tooltip-y-offset nil
  85   "Y offset, in pixels, for the display of tooltips.
  86 The offset is relative to the position of the mouse.  It must
  87 be chosen so that the tooltip window doesn't contain the mouse
  88 when it pops up.  If the value is nil, the default offset is -10
  89 pixels.
  90
  91 If `tooltip-frame-parameters' includes the `top' parameter,
  92 the value of `tooltip-y-offset' is ignored."
  93   :tag "Y offset"
  94   :type '(choice (const :tag "Default" nil)
  95                  (integer :tag "Offset" :value 1))
  96   :group 'tooltip)
  97
  98 (defcustom tooltip-frame-parameters
  99   '((name . "tooltip")
 100     (internal-border-width . 5)
 101     (border-width . 1))
 102   "Frame parameters used for tooltips.
 103
 104 If `left' or `top' parameters are included, they specify the absolute
 105 position to pop up the tooltip."
 106   :type 'sexp
 107   :tag "Frame Parameters"
 108   :group 'tooltip)
 109
 110 (defface tooltip
 111   '((((class color))
 112      :background "lightyellow"
 113      :foreground "black"
 114      :inherit variable-pitch)
 115     (t
 116      :inherit variable-pitch))
 117   "Face for tooltips."
 118   :group 'tooltip)
 119
 120 (defcustom tooltip-gud-tips-p nil
 121   "*Non-nil means show tooltips in GUD sessions."
 122   :type 'boolean
 123   :tag "GUD"
 124   :set #'(lambda (symbol on)
 125            (setq tooltip-gud-tips-p on))
 126   :group 'tooltip)
 127
 128 (defcustom tooltip-gud-modes '(gud-mode c-mode c++-mode)
 129   "List of modes for which to enable GUD tips."
 130   :type 'sexp
 131   :tag "GUD modes"
 132   :group 'tooltip)
 133
 134 (defcustom tooltip-gud-display
 135   '((eq (tooltip-event-buffer tooltip-gud-event)
 136         (marker-buffer overlay-arrow-position)))
 137   "List of forms determining where GUD tooltips are displayed.
 138
 139 Forms in the list are combined with AND.  The default is to display
 140 only tooltips in the buffer containing the overlay arrow."
 141   :type 'sexp
 142   :tag "GUD buffers predicate"
 143   :group 'tooltip)
 144
 145 (defcustom tooltip-use-echo-area nil
 146   "Use the echo area instead of tooltip frames.
 147 This is only relevant GUD display, since otherwise it is equivalent to
 148 turning off Tooltip mode."
 149   :type 'boolean
 150   :tag "Use echo area"
 151   :group 'tooltip)
 152
 153 \f
 154 ;;; Variables that are not customizable.
 155
 156 (defvar tooltip-hook nil
 157   "Functions to call to display tooltips.
 158 Each function is called with one argument EVENT which is a copy of
 159 the last mouse movement event that occurred.")
 160
 161 (defvar tooltip-timeout-id nil
 162   "The id of the timeout started when Emacs becomes idle.")
 163
 164 (defvar tooltip-last-mouse-motion-event nil
 165   "A copy of the last mouse motion event seen.")
 166
 167 (defvar tooltip-hide-time nil
 168   "Time when the last tooltip was hidden.")
 169
 170 \f
 171 ;;; Event accessors
 172
 173 (defun tooltip-event-buffer (event)
 174   "Return the buffer over which event EVENT occurred.
 175 This might return nil if the event did not occur over a buffer."
 176   (let ((window (posn-window (event-end event))))
 177     (and window (window-buffer window))))
 178
 179 \f
 180 ;;; Switching tooltips on/off
 181
 182 ;; We don't set track-mouse globally because this is a big redisplay
 183 ;; problem in buffers having a pre-command-hook or such installed,
 184 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 185 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 186 ;; would be accompanied by a full redisplay.
 187
 188 ;;;###autoload
 189 (defun tooltip-mode (&optional arg)
 190   "Mode for tooltip display.
 191 With ARG, turn tooltip mode on if and only if ARG is positive."
 192   (interactive "P")
 193   (unless (fboundp 'x-show-tip)
 194     (error "Sorry, tooltips are not yet available on this system"))
 195   (let* ((on (if arg
 196                  (> (prefix-numeric-value arg) 0)
 197                (not tooltip-mode)))
 198          (hook-fn (if on 'add-hook 'remove-hook)))
 199     (setq tooltip-mode on)
 200     (funcall hook-fn 'change-major-mode-hook 'tooltip-change-major-mode)
 201     (tooltip-activate-mouse-motions-if-enabled)
 202     (funcall hook-fn 'pre-command-hook 'tooltip-hide)
 203     (funcall hook-fn 'tooltip-hook 'tooltip-gud-tips)
 204     (funcall hook-fn 'tooltip-hook 'tooltip-help-tips)
 205     (setq show-help-function (if on 'tooltip-show-help-function nil))
 206     ;; `ignore' is the default binding for mouse movements.
 207     (define-key global-map [mouse-movement]
 208       (if on 'tooltip-mouse-motion 'ignore))))
 209
 210 \f
 211 ;;; Timeout for tooltip display
 212
 213 (defun tooltip-delay ()
 214   "Return the delay in seconds for the next tooltip."
 215   (let ((delay tooltip-delay)
 216         (now (float-time)))
 217     (when (and tooltip-hide-time
 218                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 219       (setq delay tooltip-short-delay))
 220     delay))
 221
 222 (defun tooltip-cancel-delayed-tip ()
 223   "Disable the tooltip timeout."
 224   (when tooltip-timeout-id
 225     (disable-timeout tooltip-timeout-id)
 226     (setq tooltip-timeout-id nil)))
 227
 228 (defun tooltip-start-delayed-tip ()
 229   "Add a one-shot timeout to call function tooltip-timeout."
 230   (setq tooltip-timeout-id
 231         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 232
 233 (defun tooltip-timeout (object)
 234   "Function called when timer with id tooltip-timeout-id fires."
 235   (run-hook-with-args-until-success 'tooltip-hook
 236                                     tooltip-last-mouse-motion-event))
 237
 238 \f
 239 ;;; Reacting on mouse movements
 240
 241 (defun tooltip-change-major-mode ()
 242   "Function added to `change-major-mode-hook' when tooltip mode is on."
 243   (add-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled))
 244
 245 (defun tooltip-activate-mouse-motions-if-enabled ()
 246   "Reconsider for all buffers whether mouse motion events are desired."
 247   (remove-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled)
 248   (let ((buffers (buffer-list)))
 249     (save-excursion
 250       (while buffers
 251         (set-buffer (car buffers))
 252         (if (and tooltip-mode
 253                  tooltip-gud-tips-p
 254                  (memq major-mode tooltip-gud-modes))
 255             (tooltip-activate-mouse-motions t)
 256           (tooltip-activate-mouse-motions nil))
 257         (setq buffers (cdr buffers))))))
 258
 259 (defvar tooltip-mouse-motions-active nil
 260   "Locally t in a buffer if tooltip processing of mouse motion is enabled.")
 261
 262 (defun tooltip-activate-mouse-motions (activatep)
 263   "Activate/deactivate mouse motion events for the current buffer.
 264 ACTIVATEP non-nil means activate mouse motion events."
 265   (if activatep
 266       (progn
 267         (make-local-variable 'tooltip-mouse-motions-active)
 268         (setq tooltip-mouse-motions-active t)
 269         (make-local-variable 'track-mouse)
 270         (setq track-mouse t))
 271     (when tooltip-mouse-motions-active
 272       (kill-local-variable 'tooltip-mouse-motions-active)
 273       (kill-local-variable 'track-mouse))))
 274
 275 (defun tooltip-mouse-motion (event)
 276   "Command handler for mouse movement events in `global-map'."
 277   (interactive "e")
 278   (tooltip-hide)
 279   (when (car (mouse-pixel-position))
 280     (setq tooltip-last-mouse-motion-event (copy-sequence event))
 281     (tooltip-start-delayed-tip)))
 282
 283 \f
 284 ;;; Displaying tips
 285
 286 (defun tooltip-set-param (alist key value)
 287   "Change the value of KEY in alist ALIST to VALUE.
 288 If there's no association for KEY in ALIST, add one, otherwise
 289 change the existing association.  Value is the resulting alist."
 290   (let ((param (assq key alist)))
 291     (if (consp param)
 292         (setcdr param value)
 293       (push (cons key value) alist))
 294     alist))
 295
 296 (defun tooltip-show (text)
 297   "Show a tooltip window displaying TEXT.
 298
 299 Text larger than `x-max-tooltip-size' (which see) is clipped.
 300
 301 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 302 parameters, they determine the x and y position where the tooltip
 303 is displayed.  Otherwise, the tooltip pops at offsets specified by
 304 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 305 position."
 306   (if tooltip-use-echo-area
 307       (message "%s" text)
 308     (condition-case error
 309         (let ((params (copy-sequence tooltip-frame-parameters))
 310               (fg (face-attribute 'tooltip :foreground))
 311               (bg (face-attribute 'tooltip :background)))
 312           (when (stringp fg)
 313             (setq params (tooltip-set-param params 'foreground-color fg))
 314             (setq params (tooltip-set-param params 'border-color fg)))
 315           (when (stringp bg)
 316             (setq params (tooltip-set-param params 'background-color bg)))
 317           (x-show-tip (propertize text 'face 'tooltip)
 318                       (selected-frame)
 319                       params
 320                       tooltip-hide-delay
 321                       tooltip-x-offset
 322                       tooltip-y-offset))
 323       (error
 324        (message "Error while displaying tooltip: %s" error)
 325        (sit-for 1)
 326        (message "%s" text)))))
 327
 328 (defun tooltip-hide (&optional ignored-arg)
 329   "Hide a tooltip, if one is displayed.
 330 Value is non-nil if tooltip was open."
 331   (tooltip-cancel-delayed-tip)
 332   (when (x-hide-tip)
 333     (setq tooltip-hide-time (float-time))))
 334
 335 \f
 336 ;;; Debugger-related functions
 337
 338 (defun tooltip-identifier-from-point (point)
 339   "Extract the identifier at POINT, if any.
 340 Value is nil if no identifier exists at point.  Identifier extraction
 341 is based on the current syntax table."
 342   (save-excursion
 343     (goto-char point)
 344     (let ((start (progn (skip-syntax-backward "w_") (point))))
 345       (unless (looking-at "[0-9]")
 346         (skip-syntax-forward "w_")
 347         (when (> (point) start)
 348           (buffer-substring start (point)))))))
 349
 350 (defmacro tooltip-region-active-p ()
 351   "Value is non-nil if the region is currently active."
 352   (if (string-match "^GNU" (emacs-version))
 353       `(and transient-mark-mode mark-active)
 354     `(region-active-p)))
 355
 356 (defun tooltip-expr-to-print (event)
 357   "Return an expression that should be printed for EVENT.
 358 If a region is active and the mouse is inside the region, print
 359 the region.  Otherwise, figure out the identifier around the point
 360 where the mouse is."
 361   (save-excursion
 362     (set-buffer (tooltip-event-buffer event))
 363     (let ((point (posn-point (event-end event))))
 364       (if (tooltip-region-active-p)
 365           (when (and (<= (region-beginning) point) (<= point (region-end)))
 366             (buffer-substring (region-beginning) (region-end)))
 367         (tooltip-identifier-from-point point)))))
 368
 369 (defun tooltip-process-prompt-regexp (process)
 370   "Return regexp matching the prompt of PROCESS at the end of a string.
 371 The prompt is taken from the value of COMINT-PROMPT-REGEXP in the buffer
 372 of PROCESS."
 373   (let ((prompt-regexp (save-excursion
 374                          (set-buffer (process-buffer process))
 375                          comint-prompt-regexp)))
 376     ;; Most start with `^' but the one for `sdb' cannot be easily
 377     ;; stripped.  Code the prompt for `sdb' fixed here.
 378     (if (= (aref prompt-regexp 0) ?^)
 379         (setq prompt-regexp (substring prompt-regexp 1))
 380       (setq prompt-regexp "\\*"))
 381     (concat "\n*" prompt-regexp "$")))
 382
 383 (defun tooltip-strip-prompt (process output)
 384   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 385   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 386     (save-match-data
 387       (when (string-match prompt-regexp output)
 388         (setq output (substring output 0 (match-beginning 0)))))
 389     output))
 390
 391 \f
 392 ;;; Tips for `gud'
 393
 394 (defvar tooltip-gud-original-filter nil
 395   "Process filter to restore after GUD output has been received.")
 396
 397 (defvar tooltip-gud-dereference nil
 398   "Non-nil means print expressions with a `*' in front of them.
 399 For C this would dereference a pointer expression.")
 400
 401 (defvar tooltip-gud-event nil
 402   "The mouse movement event that led to a tooltip display.
 403 This event can be examined by forms in TOOLTIP-GUD-DISPLAY.")
 404
 405 (defun tooltip-gud-toggle-dereference ()
 406   "Toggle whether tooltips should show `* expr' or `expr'."
 407   (interactive)
 408   (setq tooltip-gud-dereference (not tooltip-gud-dereference))
 409   (when (interactive-p)
 410     (message "Dereferencing is now %s."
 411              (if tooltip-gud-dereference "on" "off"))))
 412
 413 ; This will only display data that comes in one chunk.
 414 ; Larger arrays (say 400 elements) are displayed in
 415 ; the tootip incompletely and spill over into the gud buffer.
 416 ; Switching the process-filter creates timing problems and
 417 ; it may be difficult to do better. gdba in gdb-ui.el
 418 ; gets round this problem.
 419 (defun tooltip-gud-process-output (process output)
 420   "Process debugger output and show it in a tooltip window."
 421   (set-process-filter process tooltip-gud-original-filter)
 422   (tooltip-show (tooltip-strip-prompt process output)))
 423
 424 (defun tooltip-gud-print-command (expr)
 425   "Return a suitable command to print the expression EXPR.
 426 If TOOLTIP-GUD-DEREFERENCE is t, also prepend a `*' to EXPR."
 427   (when tooltip-gud-dereference
 428     (setq expr (concat "*" expr)))
 429   (case gud-minor-mode
 430     ((gdb gdba) (concat "server print " expr))
 431     (dbx (concat "print " expr))
 432     (xdb (concat "p " expr))
 433     (sdb (concat expr "/"))
 434     (perldb expr)))
 435
 436 (defun tooltip-gud-tips (event)
 437   "Show tip for identifier or selection under the mouse.
 438 The mouse must either point at an identifier or inside a selected
 439 region for the tip window to be shown.  If tooltip-gud-dereference is t,
 440 add a `*' in front of the printed expression.
 441
 442 This function must return nil if it doesn't handle EVENT."
 443   (let (gud-buffer process)
 444     (when (and (eventp event)
 445                tooltip-gud-tips-p
 446                (boundp 'gud-comint-buffer)
 447                (setq gud-buffer gud-comint-buffer)
 448                (setq process (get-buffer-process gud-buffer))
 449                (posn-point (event-end event))
 450                (progn (setq tooltip-gud-event event)
 451                       (eval (cons 'and tooltip-gud-display))))
 452       (let ((expr (tooltip-expr-to-print event)))
 453         (when expr
 454           (let ((cmd (tooltip-gud-print-command expr)))
 455             (unless (null cmd)         ; CMD can be nil if unknown debugger
 456               (case gud-minor-mode
 457                     (gdba (gdb-enqueue-input
 458                            (list  (concat cmd "\n") 'gdb-tooltip-print)))
 459                     (t
 460                      (setq tooltip-gud-original-filter (process-filter process))
 461                        (set-process-filter process 'tooltip-gud-process-output)
 462                        (gud-basic-call cmd)))
 463                     expr)))))))
 464
 465 (defun gdb-tooltip-print ()
 466   (tooltip-show
 467    (with-current-buffer (gdb-get-buffer 'gdb-partial-output-buffer)
 468      (buffer-string))))
 469
 470 \f
 471 ;;; Tooltip help.
 472
 473 (defvar tooltip-help-message nil
 474   "The last help message received via `tooltip-show-help-function'.")
 475
 476 (defun tooltip-show-help-function (msg)
 477   "Function installed as `show-help-function'.
 478 MSG is either a help string to display, or nil to cancel the display."
 479   (let ((previous-help tooltip-help-message))
 480     (setq tooltip-help-message msg)
 481     (cond ((null msg)
 482            ;; Cancel display.  This also cancels a delayed tip, if
 483            ;; there is one.
 484            (tooltip-hide))
 485           ((equal previous-help msg)
 486            ;; Same help as before (but possibly the mouse has moved).
 487            ;; Keep what we have.
 488            )
 489           (t
 490            ;; A different help.  Remove a previous tooltip, and
 491            ;; display a new one, with some delay.
 492            (tooltip-hide)
 493            (tooltip-start-delayed-tip)))))
 494
 495 (defun tooltip-help-tips (event)
 496   "Hook function to display a help tooltip.
 497 This is installed on the hook `tooltip-hook', which is run when
 498 the timer with ID `tooltip-timeout-id' fires.
 499 Value is non-nil if this function handled the tip."
 500   (when (stringp tooltip-help-message)
 501     (tooltip-show tooltip-help-message)
 502     t))
 503
 504 \f
 505 ;;; Do this after all functions have been defined that are called from
 506 ;;; `tooltip-mode'.  The actual default value of `tooltip-mode' is set
 507 ;;; in startup.el.
 508
 509 ;;;###autoload
 510 (defcustom tooltip-mode nil
 511   "Non-nil if Tooltip mode is enabled.
 512 Setting this variable directly does not take effect;
 513 use either \\[customize] or the function `tooltip-mode'."
 514   :set (lambda (symbol value)
 515          (tooltip-mode (or value 0)))
 516   :initialize 'custom-initialize-default
 517   :type 'boolean
 518   :require 'tooltip
 519   :group 'tooltip)
 520
 521 (provide 'tooltip)
 522
 523 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 524 ;;; tooltip.el ends here