lisp/saveplace.el

   1 ;;; saveplace.el --- automatically save place in files
   2
   3 ;; Copyright (C) 1993, 1994, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Karl Fogel <kfogel@red-bean.com>
   6 ;; Maintainer: FSF
   7 ;; Created: July, 1993
   8 ;; Keywords: bookmarks, placeholders
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Automatically save place in files, so that visiting them later
  30 ;; (even during a different Emacs session) automatically moves point
  31 ;; to the saved position, when the file is first found.  Uses the
  32 ;; value of buffer-local variable save-place to determine whether to
  33 ;; save position or not.
  34 ;;
  35 ;; Thanks to Stefan Schoef, who sent a patch with the
  36 ;; `save-place-version-control' stuff in it.
  37
  38 ;;; Code:
  39
  40 ;; this is what I was using during testing:
  41 ;; (define-key ctl-x-map "p" 'toggle-save-place)
  42
  43 (defgroup save-place nil
  44   "Automatically save place in files."
  45   :group 'data)
  46
  47
  48 (defvar save-place-alist nil
  49   "Alist of saved places to go back to when revisiting files.
  50 Each element looks like (FILENAME . POSITION);
  51 visiting file FILENAME goes automatically to position POSITION
  52 rather than the beginning of the buffer.
  53 This alist is saved between Emacs sessions.")
  54
  55 (defcustom save-place nil
  56   "*Non-nil means automatically save place in each file.
  57 This means when you visit a file, point goes to the last place
  58 where it was when you previously visited the same file.
  59 This variable is automatically buffer-local.
  60
  61 If you wish your place in any file to always be automatically saved,
  62 simply put this in your `~/.emacs' file:
  63
  64 \(setq-default save-place t)
  65 \(require 'saveplace)
  66
  67 or else use the Custom facility to set this option."
  68   :type 'boolean
  69   :require 'saveplace
  70   :group 'save-place)
  71
  72 (make-variable-buffer-local 'save-place)
  73
  74 (defcustom save-place-file (convert-standard-filename "~/.emacs-places")
  75   "*Name of the file that records `save-place-alist' value."
  76   :type 'file
  77   :group 'save-place)
  78
  79 (defcustom save-place-version-control nil
  80   "*Controls whether to make numbered backups of master save-place file.
  81 It can have four values: t, nil, `never', and `nospecial'.  The first
  82 three have the same meaning that they do for the variable
  83 `version-control', and the final value `nospecial' means just use the
  84 value of `version-control'."
  85   :type '(radio (const :tag "Unconditionally" t)
  86                 (const :tag "For VC Files" nil)
  87                 (const never)
  88                 (const :tag "Use value of `version-control'" nospecial))
  89   :group 'save-place)
  90
  91 (defvar save-place-loaded nil
  92   "Non-nil means that the `save-place-file' has been loaded.")
  93
  94 (defcustom save-place-limit nil
  95   "Maximum number of entries to retain in the list; nil means no limit."
  96   :type '(choice (integer :tag "Entries" :value 1)
  97                  (const :tag "No Limit" nil))
  98   :group 'save-place)
  99
 100 (defcustom save-place-forget-unreadable-files t
 101   "Non-nil means forget place in unreadable files.
 102
 103 The filenames in `save-place-alist' that do not match
 104 `save-place-skip-check-regexp' are filtered through
 105 `file-readable-p'. if nil, their alist entries are removed.
 106
 107 You may do this anytime by calling the complementary function,
 108 `save-place-forget-unreadable-files'.  When this option is turned on,
 109 this happens automatically before saving `save-place-alist' to
 110 `save-place-file'."
 111   :type 'boolean :group 'save-place)
 112
 113 (defcustom save-place-save-skipped t
 114   "If non-nil, remember files matching `save-place-skip-check-regexp'.
 115
 116 When filtering `save-place-alist' for unreadable files, some will not
 117 be checked, based on said regexp, and instead saved or forgotten based
 118 on this flag."
 119   :type 'boolean :group 'save-place)
 120
 121 (defcustom save-place-skip-check-regexp
 122   ;; thanks to ange-ftp-name-format
 123   "\\`/\\(?:cdrom\\|floppy\\|mnt\\|\\(?:[^@/:]*@\\)?[^@/:]*[^@/:.]:\\)"
 124   "Regexp whose file names shall not be checked for readability.
 125
 126 When forgetting unreadable files, file names matching this regular
 127 expression shall not be checked for readability, but instead be
 128 subject to `save-place-save-skipped'.
 129
 130 Files for which such a check may be inconvenient include those on
 131 removable and network volumes."
 132   :type 'regexp :group 'save-place)
 133
 134 (defun toggle-save-place (&optional parg)
 135   "Toggle whether to save your place in this file between sessions.
 136 If this mode is enabled, point is recorded when you kill the buffer
 137 or exit Emacs.  Visiting this file again will go to that position,
 138 even in a later Emacs session.
 139
 140 If called with a prefix arg, the mode is enabled if and only if
 141 the argument is positive.
 142
 143 To save places automatically in all files, put this in your `.emacs' file:
 144
 145 \(setq-default save-place t\)"
 146   (interactive "P")
 147   (if (not buffer-file-name)
 148       (message "Buffer `%s' not visiting a file" (buffer-name))
 149     (if (and save-place (or (not parg) (<= parg 0)))
 150         (progn
 151           (message "No place will be saved in this file")
 152           (setq save-place nil))
 153       (message "Place will be saved")
 154       (setq save-place t))))
 155
 156 (defun save-place-to-alist ()
 157   ;; put filename and point in a cons box and then cons that onto the
 158   ;; front of the save-place-alist, if save-place is non-nil.
 159   ;; Otherwise, just delete that file from the alist.
 160   ;; first check to make sure alist has been loaded in from the master
 161   ;; file.  If not, do so, then feel free to modify the alist.  It
 162   ;; will be saved again when Emacs is killed.
 163   (or save-place-loaded (load-save-place-alist-from-file))
 164   (if buffer-file-name
 165       (progn
 166         (let ((cell (assoc buffer-file-name save-place-alist))
 167               (position (if (not (eq major-mode 'hexl-mode))
 168                             (point)
 169                           (1+ (hexl-current-address)))))
 170           (if cell
 171               (setq save-place-alist (delq cell save-place-alist)))
 172           (if (and save-place
 173                    (not (= position 1)))  ;; Optimize out the degenerate case.
 174               (setq save-place-alist
 175                     (cons (cons buffer-file-name position)
 176                           save-place-alist)))))))
 177
 178 (defun save-place-forget-unreadable-files ()
 179   "Remove unreadable files from `save-place-alist'.
 180 For each entry in the alist, if `file-readable-p' returns nil for the
 181 filename, remove the entry.  Save the new alist \(as the first pair
 182 may have changed\) back to `save-place-alist'."
 183   (interactive)
 184   ;; the following was adapted from an in-place filtering function,
 185   ;; `filter-mod', used in the original.
 186   (unless (null save-place-alist)       ;says it better than `when'
 187     ;; first, check all except first
 188     (let ((fmprev save-place-alist) (fmcur (cdr save-place-alist)))
 189       (while fmcur                      ;not null
 190         ;; a value is only saved when it becomes FMPREV.
 191         (if (if (string-match save-place-skip-check-regexp (caar fmcur))
 192                 save-place-save-skipped
 193               (file-readable-p (caar fmcur)))
 194             (setq fmprev fmcur)
 195           (setcdr fmprev (cdr fmcur)))
 196         (setq fmcur (cdr fmcur))))
 197     ;; test first pair, keep it if OK, otherwise 2nd element, which
 198     ;; may be '()
 199     (unless (if (string-match save-place-skip-check-regexp
 200                               (caar save-place-alist))
 201                 save-place-save-skipped
 202               (file-readable-p (caar save-place-alist)))
 203       (setq save-place-alist (cdr save-place-alist)))))
 204
 205 (defun save-place-alist-to-file ()
 206   (let ((file (expand-file-name save-place-file)))
 207     (save-excursion
 208       (message "Saving places to %s..." file)
 209       (set-buffer (get-buffer-create " *Saved Places*"))
 210       (delete-region (point-min) (point-max))
 211       (when save-place-forget-unreadable-files
 212         (save-place-forget-unreadable-files))
 213       (let ((print-length nil)
 214             (print-level nil))
 215         (print save-place-alist (current-buffer)))
 216       (let ((version-control
 217              (cond
 218               ((null save-place-version-control) nil)
 219               ((eq 'never save-place-version-control) 'never)
 220               ((eq 'nospecial save-place-version-control) version-control)
 221               (t
 222                t))))
 223         (write-file file)
 224         (kill-buffer (current-buffer))
 225         (message "Saving places to %s...done" file)))))
 226
 227 (defun load-save-place-alist-from-file ()
 228   (if (not save-place-loaded)
 229       (progn
 230         (setq save-place-loaded t)
 231         (let ((file (expand-file-name save-place-file)))
 232           ;; make sure that the alist does not get overwritten, and then
 233           ;; load it if it exists:
 234           (if (file-readable-p file)
 235               (save-excursion
 236                 (message "Loading places from %s..." save-place-file)
 237                 ;; don't want to use find-file because we have been
 238                 ;; adding hooks to it.
 239                 (set-buffer (get-buffer-create " *Saved Places*"))
 240                 (delete-region (point-min) (point-max))
 241                 (insert-file-contents file)
 242                 (goto-char (point-min))
 243                 (setq save-place-alist
 244                       (car (read-from-string
 245                             (buffer-substring (point-min) (point-max)))))
 246
 247                 ;; If there is a limit, and we're over it, then we'll
 248                 ;; have to truncate the end of the list:
 249                 (if save-place-limit
 250                     (if (<= save-place-limit 0)
 251                         ;; Zero gets special cased.  I'm not thrilled
 252                         ;; with this, but the loop for >= 1 is tight.
 253                         (setq save-place-alist nil)
 254                       ;; Else the limit is >= 1, so enforce it by
 255                       ;; counting and then `setcdr'ing.
 256                       (let ((s save-place-alist)
 257                             (count 1))
 258                         (while s
 259                           (if (>= count save-place-limit)
 260                               (setcdr s nil)
 261                             (setq count (1+ count)))
 262                           (setq s (cdr s))))))
 263
 264                 (kill-buffer (current-buffer))
 265                 (message "Loading places from %s...done" file)))
 266           nil))))
 267
 268 (defun save-places-to-alist ()
 269   ;; go through buffer-list, saving places to alist if save-place is
 270   ;; non-nil, deleting them from alist if it is nil.
 271   (let ((buf-list (buffer-list)))
 272     (while buf-list
 273       ;; put this into a save-excursion in case someone is counting on
 274       ;; another function in kill-emacs-hook to act on the last buffer
 275       ;; they were in:
 276       (save-excursion
 277         (set-buffer (car buf-list))
 278         ;; save-place checks buffer-file-name too, but we can avoid
 279         ;; overhead of function call by checking here too.
 280         (and buffer-file-name (save-place-to-alist))
 281         (setq buf-list (cdr buf-list))))))
 282
 283 (defun save-place-find-file-hook ()
 284   (or save-place-loaded (load-save-place-alist-from-file))
 285   (let ((cell (assoc buffer-file-name save-place-alist)))
 286     (if cell
 287         (progn
 288           (or after-find-file-from-revert-buffer
 289               (goto-char (cdr cell)))
 290           ;; and make sure it will be saved again for later
 291           (setq save-place t)))))
 292
 293 (defun save-place-kill-emacs-hook ()
 294   ;; First update the alist.  This loads the old save-place-file if nec.
 295   (save-places-to-alist)
 296   ;; Now save the alist in the file, if we have ever loaded the file
 297   ;; (including just now).
 298   (if save-place-loaded
 299       (save-place-alist-to-file)))
 300
 301 (add-hook 'find-file-hook 'save-place-find-file-hook t)
 302
 303 (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook)
 304
 305 (add-hook 'kill-buffer-hook 'save-place-to-alist)
 306
 307 (provide 'saveplace) ; why not...
 308
 309 ;;; arch-tag: 3c2ef47b-0a22-4558-b116-118c9ef454a0
 310 ;;; saveplace.el ends here