lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; This program is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 2, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with this program ; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; These functions should be automatically loaded when called, but you
  30 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  31 ;; preloaded.
  32
  33 ;;; Code:
  34
  35 (require 'ibuffer)
  36
  37 (eval-when-compile
  38   (require 'ibuf-macs)
  39   (require 'cl))
  40
  41 ;;; Utility functions
  42 (defun ibuffer-delete-alist (key alist)
  43   "Delete all entries in ALIST that have a key equal to KEY."
  44   (let (entry)
  45     (while (setq entry (assoc key alist))
  46       (setq alist (delete entry alist)))
  47     alist))
  48
  49 ;; borrowed from Gnus
  50 (defun ibuffer-remove-duplicates (list)
  51   "Return a copy of LIST with duplicate elements removed."
  52   (let ((new nil)
  53         (tail list))
  54     (while tail
  55       (or (member (car tail) new)
  56           (setq new (cons (car tail) new)))
  57       (setq tail (cdr tail)))
  58     (nreverse new)))
  59
  60 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  61   (let ((hip-crowd nil)
  62         (lamers nil))
  63     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  64       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  65           (push ibuffer-split-list-elt hip-crowd)
  66         (push ibuffer-split-list-elt lamers)))
  67     ;; Too bad Emacs Lisp doesn't have multiple values.
  68     (list (nreverse hip-crowd) (nreverse lamers))))
  69
  70 (defcustom ibuffer-never-show-predicates nil
  71   "A list of predicates (a regexp or function) for buffers not to display.
  72 If a regexp, then it will be matched against the buffer's name.
  73 If a function, it will be called with the buffer as an argument, and
  74 should return non-nil if this buffer should not be shown."
  75   :type '(repeat (choice regexp function))
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-mode nil
  95   "If non-nil, Ibuffer auto-mode should be enabled for this buffer.
  96 Do not set this variable directly!  Use the function
  97 `ibuffer-auto-mode' instead.")
  98
  99 (defvar ibuffer-auto-buffers-changed nil)
 100
 101 (defcustom ibuffer-saved-filters '(("gnus"
 102                                     ((or (mode . message-mode)
 103                                          (mode . mail-mode)
 104                                          (mode . gnus-group-mode)
 105                                          (mode . gnus-summary-mode)
 106                                          (mode . gnus-article-mode))))
 107                                    ("programming"
 108                                     ((or (mode . emacs-lisp-mode)
 109                                          (mode . cperl-mode)
 110                                          (mode . c-mode)
 111                                          (mode . java-mode)
 112                                          (mode . idl-mode)
 113                                          (mode . lisp-mode)))))
 114
 115   "An alist of filter qualifiers to switch between.
 116
 117 This variable should look like ((\"STRING\" QUALIFIERS)
 118                                 (\"STRING\" QUALIFIERS) ...), where
 119 QUALIFIERS is a list of the same form as
 120 `ibuffer-filtering-qualifiers'.
 121 See also the variables `ibuffer-filtering-qualifiers',
 122 `ibuffer-filtering-alist', and the functions
 123 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 124   :type '(repeat sexp)
 125   :group 'ibuffer)
 126
 127 (defvar ibuffer-filtering-qualifiers nil
 128   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 129 See also `ibuffer-filtering-alist'.")
 130
 131 ;; This is now frobbed by `define-ibuffer-filter'.
 132 (defvar ibuffer-filtering-alist nil
 133   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 134
 135 You most likely do not want to modify this variable directly; see
 136 `define-ibuffer-filter'.
 137
 138 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 139 displaying information to the user.  FUNCTION is given a buffer and
 140 the value of the qualifier, and returns non-nil if and only if the
 141 buffer should be displayed.")
 142
 143 (defcustom ibuffer-filter-format-alist nil
 144   "An alist which has special formats used when a filter is active.
 145 The contents of this variable should look like:
 146  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 147
 148 For example, suppose that when you add a filter for buffers whose
 149 major mode is `emacs-lisp-mode', you only want to see the mark and the
 150 name of the buffer.  You could accomplish that by adding:
 151  (mode ((mark \" \" name)))
 152 to this variable."
 153   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 154                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 155   :group 'ibuffer)
 156
 157 (defvar ibuffer-cached-filter-formats nil)
 158 (defvar ibuffer-compiled-filter-formats nil)
 159
 160 (defvar ibuffer-filter-groups nil
 161   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 162 The SYMBOL should be one from `ibuffer-filtering-alist'.
 163 The QUALIFIER should be the same as QUALIFIER in
 164 `ibuffer-filtering-qualifiers'.")
 165
 166 (defcustom ibuffer-show-empty-filter-groups t
 167   "If non-nil, then show the names of filter groups which are empty."
 168   :type 'boolean
 169   :group 'ibuffer)
 170
 171 (defcustom ibuffer-saved-filter-groups nil
 172   "An alist of filtering groups to switch between.
 173
 174 This variable should look like ((\"STRING\" QUALIFIERS)
 175                                 (\"STRING\" QUALIFIERS) ...), where
 176 QUALIFIERS is a list of the same form as
 177 `ibuffer-filtering-qualifiers'.
 178
 179 See also the variables `ibuffer-filter-groups',
 180 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 181 functions `ibuffer-switch-to-saved-filter-group',
 182 `ibuffer-save-filter-group'."
 183   :type '(repeat sexp)
 184   :group 'ibuffer)
 185
 186 (defvar ibuffer-hidden-filter-groups nil
 187   "A list of filtering groups which are currently hidden.")
 188
 189 (defvar ibuffer-filter-group-kill-ring nil)
 190
 191 (defcustom ibuffer-old-time 72
 192   "The number of hours before a buffer is considered \"old\"."
 193   :type '(choice (const :tag "72 hours (3 days)" 72)
 194                  (const :tag "48 hours (2 days)" 48)
 195                  (const :tag "24 hours (1 day)" 24)
 196                  (integer :tag "hours"))
 197   :group 'ibuffer)
 198
 199 (defcustom ibuffer-save-with-custom t
 200   "If non-nil, then use Custom to save interactively changed variables.
 201 Currently, this only applies to `ibuffer-saved-filters' and
 202 `ibuffer-saved-filter-groups'."
 203   :type 'boolean
 204   :group 'ibuffer)
 205
 206 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 207   (or
 208    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 209    (and (not
 210          (or
 211           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 212           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 213         (or all
 214             (not
 215              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 216         (or ibuffer-view-ibuffer
 217             (and ibuffer-buf
 218                  (not (eq ibuffer-buf buf))))
 219         (or
 220          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 221          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 222
 223 (defun ibuffer-auto-update-changed ()
 224   (when ibuffer-auto-buffers-changed
 225     (setq ibuffer-auto-buffers-changed nil)
 226     (mapcar #'(lambda (buf)
 227                 (ignore-errors
 228                   (with-current-buffer buf
 229                     (when (and ibuffer-auto-mode
 230                                (eq major-mode 'ibuffer-mode))
 231                       (ibuffer-update nil t)))))
 232             (buffer-list))))
 233
 234 ;;;###autoload
 235 (defun ibuffer-auto-mode (&optional arg)
 236   "Toggle use of Ibuffer's auto-update facility.
 237 With numeric ARG, enable auto-update if and only if ARG is positive."
 238   (interactive)
 239   (unless (eq major-mode 'ibuffer-mode)
 240     (error "This buffer is not in Ibuffer mode"))
 241   (set (make-local-variable 'ibuffer-auto-mode)
 242        (if arg
 243            (plusp arg)
 244          (not ibuffer-auto-mode)))
 245   (defadvice get-buffer-create (after ibuffer-notify-create activate)
 246     (setq ibuffer-auto-buffers-changed t))
 247   (defadvice kill-buffer (after ibuffer-notify-kill activate)
 248     (setq ibuffer-auto-buffers-changed t))
 249   (add-hook 'post-command-hook 'ibuffer-auto-update-changed)
 250   (ibuffer-update-mode-name))
 251
 252 ;;;###autoload
 253 (defun ibuffer-mouse-filter-by-mode (event)
 254   "Enable or disable filtering by the major mode chosen via mouse."
 255   (interactive "e")
 256   (ibuffer-interactive-filter-by-mode event))
 257
 258 ;;;###autoload
 259 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 260   "Enable or disable filtering by the major mode at point."
 261   (interactive "d")
 262   (if (eventp event-or-point)
 263       (mouse-set-point event-or-point)
 264     (goto-char event-or-point))
 265   (let ((buf (ibuffer-current-buffer)))
 266     (if (assq 'mode ibuffer-filtering-qualifiers)
 267         (setq ibuffer-filtering-qualifiers
 268               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 269       (ibuffer-push-filter (cons 'mode
 270                                 (with-current-buffer buf
 271                                   major-mode)))))
 272   (ibuffer-update nil t))
 273
 274 ;;;###autoload
 275 (defun ibuffer-mouse-toggle-filter-group (event)
 276   "Toggle the display status of the filter group chosen with the mouse."
 277   (interactive "e")
 278   (ibuffer-toggle-filter-group-1 (save-excursion
 279                                    (mouse-set-point event)
 280                                    (point))))
 281
 282 ;;;###autoload
 283 (defun ibuffer-toggle-filter-group ()
 284   "Toggle the display status of the filter group on this line."
 285   (interactive)
 286   (ibuffer-toggle-filter-group-1 (point)))
 287
 288 (defun ibuffer-toggle-filter-group-1 (posn)
 289   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 290     (unless (stringp name)
 291       (error "No filtering group name present"))
 292     (if (member name ibuffer-hidden-filter-groups)
 293         (setq ibuffer-hidden-filter-groups
 294               (delete name ibuffer-hidden-filter-groups))
 295       (push name ibuffer-hidden-filter-groups))
 296     (ibuffer-update nil t)))
 297
 298 ;;;###autoload
 299 (defun ibuffer-forward-filter-group (&optional count)
 300   "Move point forwards by COUNT filtering groups."
 301   (interactive "P")
 302   (unless count
 303     (setq count 1))
 304   (when (> count 0)
 305     (when (get-text-property (point) 'ibuffer-filter-group-name)
 306       (goto-char (next-single-property-change
 307                   (point) 'ibuffer-filter-group-name
 308                   nil (point-max))))
 309     (goto-char (next-single-property-change
 310                 (point) 'ibuffer-filter-group-name
 311                 nil (point-max)))
 312     (ibuffer-forward-filter-group (1- count)))
 313   (ibuffer-forward-line 0))
 314
 315 ;;;###autoload
 316 (defun ibuffer-backward-filter-group (&optional count)
 317   "Move point backwards by COUNT filtering groups."
 318   (interactive "P")
 319   (unless count
 320     (setq count 1))
 321   (when (> count 0)
 322     (when (get-text-property (point) 'ibuffer-filter-group-name)
 323       (goto-char (previous-single-property-change
 324                   (point) 'ibuffer-filter-group-name
 325                   nil (point-min))))
 326     (goto-char (previous-single-property-change
 327                 (point) 'ibuffer-filter-group-name
 328                 nil (point-min)))
 329     (ibuffer-backward-filter-group (1- count)))
 330   (when (= (point) (point-min))
 331     (goto-char (point-max))
 332     (ibuffer-backward-filter-group 1))
 333   (ibuffer-forward-line 0))
 334
 335 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext.el")
 336 (define-ibuffer-op shell-command-pipe (command)
 337   "Pipe the contents of each marked buffer to shell command COMMAND."
 338   (:interactive "sPipe to shell command: "
 339    :opstring "Shell command executed on"
 340    :modifier-p nil)
 341   (shell-command-on-region
 342    (point-min) (point-max) command
 343    (get-buffer-create "* ibuffer-shell-output*")))
 344
 345 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext.el")
 346 (define-ibuffer-op shell-command-pipe-replace (command)
 347   "Replace the contents of marked buffers with output of pipe to COMMAND."
 348   (:interactive "sPipe to shell command (replace): "
 349    :opstring "Buffer contents replaced in"
 350    :active-opstring "replace buffer contents in"
 351    :dangerous t
 352    :modifier-p t)
 353   (with-current-buffer buf
 354     (shell-command-on-region (point-min) (point-max)
 355                              command nil t)))
 356
 357 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext.el")
 358 (define-ibuffer-op shell-command-file (command)
 359   "Run shell command COMMAND separately on files of marked buffers."
 360   (:interactive "sShell command on buffer's file: "
 361    :opstring "Shell command executed on"
 362    :modifier-p nil)
 363   (shell-command (concat command " "
 364                          (shell-quote-argument
 365                           (if buffer-file-name
 366                               buffer-file-name
 367                             (make-temp-file
 368                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 369
 370 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext.el")
 371 (define-ibuffer-op eval (form)
 372   "Evaluate FORM in each of the buffers.
 373 Does not display the buffer during evaluation. See
 374 `ibuffer-do-view-and-eval' for that."
 375   (:interactive "xEval in buffers (form): "
 376    :opstring "evaluated in"
 377    :modifier-p :maybe)
 378   (eval form))
 379
 380 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext.el")
 381 (define-ibuffer-op view-and-eval (form)
 382   "Evaluate FORM while displaying each of the marked buffers.
 383 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 384   (:interactive "xEval viewing buffers (form): "
 385    :opstring "evaluated in"
 386    :complex t
 387    :modifier-p :maybe)
 388   (let ((ibuffer-buf (current-buffer)))
 389     (unwind-protect
 390         (progn
 391           (switch-to-buffer buf)
 392           (eval form))
 393       (switch-to-buffer ibuffer-buf))))
 394
 395 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext.el")
 396 (define-ibuffer-op rename-uniquely ()
 397   "Rename marked buffers as with `rename-uniquely'."
 398   (:opstring "renamed"
 399    :modifier-p t)
 400   (rename-uniquely))
 401
 402 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext.el")
 403 (define-ibuffer-op revert ()
 404   "Revert marked buffers as with `revert-buffer'."
 405   (:dangerous t
 406    :opstring "reverted"
 407    :active-opstring "revert"
 408    :modifier-p :maybe)
 409   (revert-buffer t t))
 410
 411 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext.el")
 412 (define-ibuffer-op replace-regexp (from-str to-str)
 413   "Perform a `replace-regexp' in marked buffers."
 414   (:interactive
 415    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 416           (to-str (read-from-minibuffer (concat "Replace " from-str
 417                                                 " with: "))))
 418      (list from-str to-str))
 419    :opstring "replaced in"
 420    :complex t
 421    :modifier-p :maybe)
 422   (save-window-excursion
 423     (switch-to-buffer buf)
 424     (save-excursion
 425       (goto-char (point-min))
 426       (let ((case-fold-search ibuffer-case-fold-search))
 427         (while (re-search-forward from-str nil t)
 428           (replace-match to-str))))
 429     t))
 430
 431 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext.el")
 432 (define-ibuffer-op query-replace (&rest args)
 433   "Perform a `query-replace' in marked buffers."
 434   (:interactive
 435    (query-replace-read-args "Query replace" t t)
 436    :opstring "replaced in"
 437    :complex t
 438    :modifier-p :maybe)
 439   (save-window-excursion
 440     (switch-to-buffer buf)
 441     (save-excursion
 442       (let ((case-fold-search ibuffer-case-fold-search))
 443         (goto-char (point-min))
 444         (apply #'query-replace args)))
 445     t))
 446
 447 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext.el")
 448 (define-ibuffer-op query-replace-regexp (&rest args)
 449   "Perform a `query-replace-regexp' in marked buffers."
 450   (:interactive
 451    (query-replace-read-args "Query replace regexp" t t)
 452    :opstring "replaced in"
 453    :complex t
 454    :modifier-p :maybe)
 455   (save-window-excursion
 456     (switch-to-buffer buf)
 457     (save-excursion
 458       (let ((case-fold-search ibuffer-case-fold-search))
 459         (goto-char (point-min))
 460         (apply #'query-replace-regexp args)))
 461     t))
 462
 463 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext.el")
 464 (define-ibuffer-op print ()
 465   "Print marked buffers as with `print-buffer'."
 466   (:opstring "printed"
 467    :modifier-p nil)
 468   (print-buffer))
 469
 470 ;;;###autoload
 471 (defun ibuffer-included-in-filters-p (buf filters)
 472   (not
 473    (memq nil ;; a filter will return nil if it failed
 474          (mapcar
 475           ;; filter should be like (TYPE . QUALIFIER), or
 476           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 477           #'(lambda (qual)
 478               (ibuffer-included-in-filter-p buf qual))
 479           filters))))
 480
 481 (defun ibuffer-included-in-filter-p (buf filter)
 482   (if (eq (car filter) 'not)
 483       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 484     (ibuffer-included-in-filter-p-1 buf filter)))
 485
 486 (defun ibuffer-included-in-filter-p-1 (buf filter)
 487   (not
 488    (not
 489     (case (car filter)
 490       (or
 491        (memq t (mapcar #'(lambda (x)
 492                            (ibuffer-included-in-filter-p buf x))
 493                        (cdr filter))))
 494       (saved
 495        (let ((data
 496               (assoc (cdr filter)
 497                      ibuffer-saved-filters)))
 498          (unless data
 499            (ibuffer-filter-disable)
 500            (error "Unknown saved filter %s" (cdr filter)))
 501          (ibuffer-included-in-filters-p buf (cadr data))))
 502       (t
 503        (let ((filterdat (assq (car filter)
 504                               ibuffer-filtering-alist)))
 505          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 506          ;; just a sanity check
 507         (unless filterdat
 508           (ibuffer-filter-disable)
 509           (error "Undefined filter %s" (car filter)))
 510         (not
 511          (not
 512           (funcall (caddr filterdat)
 513                    buf
 514                    (cdr filter))))))))))
 515
 516 (defun ibuffer-generate-filter-groups (bmarklist)
 517   (let ((filter-group-alist (append ibuffer-filter-groups
 518                                        (list (cons "Default" nil)))))
 519 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 520 ;;       (setq filter-group-alist (ibuffer-delete-alist
 521 ;;                                 hidden filter-group-alist)))
 522     (let ((vec (make-vector (length filter-group-alist) nil))
 523           (i 0))
 524       (dolist (filtergroup filter-group-alist)
 525         (let ((filterset (cdr filtergroup)))
 526           (multiple-value-bind (hip-crowd lamers)
 527               (ibuffer-split-list (lambda (bufmark)
 528                                     (ibuffer-included-in-filters-p (car bufmark)
 529                                                                    filterset))
 530                                   bmarklist)
 531             (aset vec i hip-crowd)
 532             (incf i)
 533             (setq bmarklist lamers))))
 534       (let ((ret nil))
 535         (dotimes (j i ret)
 536           (push (cons (car (nth j filter-group-alist))
 537                       (aref vec j))
 538                 ret))))))
 539
 540 ;;;###autoload
 541 (defun ibuffer-filters-to-filter-group (name)
 542   "Make the current filters into a filtering group."
 543   (interactive "sName for filtering group: ")
 544   (when (null ibuffer-filtering-qualifiers)
 545     (error "No filters in effect"))
 546   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 547   (ibuffer-filter-disable))
 548
 549 ;;;###autoload
 550 (defun ibuffer-set-filter-groups-by-mode ()
 551   "Set the current filter groups to filter by mode."
 552   (interactive)
 553   (setq ibuffer-filter-groups
 554         (mapcar (lambda (mode)
 555                   (cons (format "%s" mode) `((mode . ,mode))))
 556                 (let ((modes
 557                        (ibuffer-remove-duplicates
 558                         (mapcar (lambda (buf)
 559                                   (with-current-buffer buf major-mode))
 560                                 (buffer-list)))))
 561                   (if ibuffer-view-ibuffer
 562                       modes
 563                     (delq 'ibuffer-mode modes)))))
 564   (ibuffer-update nil t))
 565
 566 ;;;###autoload
 567 (defun ibuffer-pop-filter-group ()
 568   "Remove the first filter group."
 569   (interactive)
 570   (when (null ibuffer-filter-groups)
 571     (error "No filter groups active"))
 572   (setq ibuffer-hidden-filter-groups
 573         (delete (pop ibuffer-filter-groups)
 574                 ibuffer-hidden-filter-groups))
 575   (ibuffer-update nil t))
 576
 577 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 578   (when (and (not noerror) (null ibuffer-filter-groups))
 579     (error "No filter groups active"))
 580   (let ((groups (mapcar #'car ibuffer-filter-groups)))
 581     (completing-read msg (if nodefault
 582                              groups
 583                            (cons "Default" groups))
 584                      nil t)))
 585
 586 ;;;###autoload
 587 (defun ibuffer-decompose-filter-group (group)
 588   "Decompose the filter group GROUP into active filters."
 589   (interactive
 590    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 591   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 592     (setq ibuffer-filter-groups (ibuffer-delete-alist
 593                                  group ibuffer-filter-groups)
 594           ibuffer-filtering-qualifiers data))
 595   (ibuffer-update nil t))
 596
 597 ;;;###autoload
 598 (defun ibuffer-clear-filter-groups ()
 599   "Remove all filter groups."
 600   (interactive)
 601   (setq ibuffer-filter-groups nil
 602         ibuffer-hidden-filter-groups nil)
 603   (ibuffer-update nil t))
 604
 605 (defun ibuffer-current-filter-groups-with-position ()
 606   (save-excursion
 607     (goto-char (point-min))
 608     (let ((pos nil)
 609           (result nil))
 610       (while (and (not (eobp))
 611                   (setq pos (next-single-property-change
 612                              (point) 'ibuffer-filter-group-name)))
 613         (goto-char pos)
 614         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 615                     pos)
 616               result)
 617         (goto-char (next-single-property-change
 618                     pos 'ibuffer-filter-group-name)))
 619       (nreverse result))))
 620
 621 ;;;###autoload
 622 (defun ibuffer-jump-to-filter-group (name)
 623   "Move point to the filter group whose name is NAME."
 624   (interactive
 625    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 626   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 627       (goto-char (cdr it))
 628     (error "No filter group with name %s" name)))
 629
 630 ;;;###autoload
 631 (defun ibuffer-kill-filter-group (name)
 632   "Kill the filter group named NAME.
 633 The group will be added to `ibuffer-filter-group-kill-ring'."
 634   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 635   (when (equal name "Default")
 636     (error "Can't kill default filter group"))
 637   (ibuffer-aif (assoc name ibuffer-filter-groups)
 638       (progn
 639         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 640         (setq ibuffer-filter-groups (ibuffer-delete-alist
 641                                      name ibuffer-filter-groups))
 642         (setq ibuffer-hidden-filter-groups
 643               (delete name ibuffer-hidden-filter-groups)))
 644     (error "No filter group with name \"%s\"" name))
 645   (ibuffer-update nil t))
 646
 647 ;;;###autoload
 648 (defun ibuffer-kill-line (&optional arg interactive-p)
 649   "Kill the filter group at point.
 650 See also `ibuffer-kill-filter-group'."
 651   (interactive "P\np")
 652   (ibuffer-aif (save-excursion
 653                  (ibuffer-forward-line 0)
 654                  (get-text-property (point) 'ibuffer-filter-group-name))
 655       (progn
 656         (ibuffer-kill-filter-group it))
 657       (funcall (if interactive-p #'call-interactively #'funcall)
 658                #'kill-line arg)))
 659
 660 (defun ibuffer-insert-filter-group-before (newgroup group)
 661   (let* ((found nil)
 662          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 663                     (res 0))
 664                 (while groups
 665                   (if (equal (car groups) group)
 666                       (setq found t
 667                             groups nil)
 668                     (incf res)
 669                     (setq groups (cdr groups))))
 670                 res)))
 671     (cond ((not found)
 672            (setq ibuffer-filter-groups
 673                  (nconc ibuffer-filter-groups (list newgroup))))
 674           ((zerop pos)
 675            (push newgroup ibuffer-filter-groups))
 676           (t
 677            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 678              (setf (cdr cell) (cons (car cell) (cdr cell)))
 679              (setf (car cell) newgroup))))))
 680
 681 ;;;###autoload
 682 (defun ibuffer-yank ()
 683   "Yank the last killed filter group before group at point."
 684   (interactive)
 685   (ibuffer-yank-filter-group
 686    (or (get-text-property (point) 'ibuffer-filter-group-name)
 687        (get-text-property (point) 'ibuffer-filter-group)
 688        (error "No filter group at point"))))
 689
 690 ;;;###autoload
 691 (defun ibuffer-yank-filter-group (name)
 692   "Yank the last killed filter group before group named NAME."
 693   (interactive (list (ibuffer-read-filter-group-name
 694                         "Yank filter group before group: ")))
 695   (unless ibuffer-filter-group-kill-ring
 696     (error "The Ibuffer filter group kill-ring is empty"))
 697   (save-excursion
 698     (ibuffer-forward-line 0)
 699     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 700                                         name))
 701   (ibuffer-update nil t))
 702
 703 ;;;###autoload
 704 (defun ibuffer-save-filter-groups (name groups)
 705   "Save all active filter groups GROUPS as NAME.
 706 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 707 prompt for NAME, and use the current filters."
 708   (interactive
 709    (if (null ibuffer-filter-groups)
 710        (error "No filter groups active")
 711      (list
 712       (read-from-minibuffer "Save current filter groups as: ")
 713       ibuffer-filter-groups)))
 714   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 715       (setcdr it groups)
 716     (push (cons name groups) ibuffer-saved-filter-groups))
 717   (ibuffer-maybe-save-stuff)
 718   (ibuffer-update-mode-name))
 719
 720 ;;;###autoload
 721 (defun ibuffer-delete-saved-filter-groups (name)
 722   "Delete saved filter groups with NAME.
 723 They are removed from `ibuffer-saved-filter-groups'."
 724   (interactive
 725    (list
 726     (if (null ibuffer-saved-filter-groups)
 727         (error "No saved filter groups")
 728       (completing-read "Delete saved filter group: "
 729                        ibuffer-saved-filter-groups nil t))))
 730   (setq ibuffer-saved-filter-groups
 731         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 732   (ibuffer-maybe-save-stuff)
 733   (ibuffer-update nil t))
 734
 735 ;;;###autoload
 736 (defun ibuffer-switch-to-saved-filter-groups (name)
 737   "Set this buffer's filter groups to saved version with NAME.
 738 The value from `ibuffer-saved-filters' is used.
 739 If prefix argument ADD is non-nil, then add the saved filters instead
 740 of replacing the current filters."
 741   (interactive
 742    (list
 743     (if (null ibuffer-saved-filter-groups)
 744         (error "No saved filters")
 745       (completing-read "Switch to saved filter group: "
 746                        ibuffer-saved-filter-groups nil t))))
 747   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 748         ibuffer-hidden-filter-groups nil)
 749   (ibuffer-update nil t))
 750
 751 ;;;###autoload
 752 (defun ibuffer-filter-disable ()
 753   "Disable all filters currently in effect in this buffer."
 754   (interactive)
 755   (setq ibuffer-filtering-qualifiers nil)
 756   (ibuffer-update nil t))
 757
 758 ;;;###autoload
 759 (defun ibuffer-pop-filter ()
 760   "Remove the top filter in this buffer."
 761   (interactive)
 762   (when (null ibuffer-filtering-qualifiers)
 763     (error "No filters in effect"))
 764   (pop ibuffer-filtering-qualifiers)
 765   (ibuffer-update nil t))
 766
 767 (defun ibuffer-push-filter (qualifier)
 768   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 769   (push qualifier ibuffer-filtering-qualifiers))
 770
 771 ;;;###autoload
 772 (defun ibuffer-decompose-filter ()
 773   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 774
 775 This means that the topmost filter on the filtering stack, which must
 776 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 777 turned into two separate filters [name: foo] and [mode: bar-mode]."
 778   (interactive)
 779   (when (null ibuffer-filtering-qualifiers)
 780     (error "No filters in effect"))
 781   (let ((lim (pop ibuffer-filtering-qualifiers)))
 782     (case (car lim)
 783       (or
 784        (setq ibuffer-filtering-qualifiers (append
 785                                           (cdr lim)
 786                                           ibuffer-filtering-qualifiers)))
 787       (saved
 788        (let ((data
 789               (assoc (cdr lim)
 790                      ibuffer-saved-filters)))
 791          (unless data
 792            (ibuffer-filter-disable)
 793            (error "Unknown saved filter %s" (cdr lim)))
 794          (setq ibuffer-filtering-qualifiers (append
 795                                             (cadr data)
 796                                             ibuffer-filtering-qualifiers))))
 797       (not
 798        (push (cdr lim)
 799              ibuffer-filtering-qualifiers))
 800       (t
 801        (error "Filter type %s is not compound" (car lim)))))
 802   (ibuffer-update nil t))
 803
 804 ;;;###autoload
 805 (defun ibuffer-exchange-filters ()
 806   "Exchange the top two filters on the stack in this buffer."
 807   (interactive)
 808   (when (< (length ibuffer-filtering-qualifiers)
 809            2)
 810     (error "Need two filters to exchange"))
 811   (let ((first (pop ibuffer-filtering-qualifiers))
 812         (second (pop ibuffer-filtering-qualifiers)))
 813     (push first ibuffer-filtering-qualifiers)
 814     (push second ibuffer-filtering-qualifiers))
 815   (ibuffer-update nil t))
 816
 817 ;;;###autoload
 818 (defun ibuffer-negate-filter ()
 819   "Negate the sense of the top filter in the current buffer."
 820   (interactive)
 821   (when (null ibuffer-filtering-qualifiers)
 822     (error "No filters in effect"))
 823   (let ((lim (pop ibuffer-filtering-qualifiers)))
 824     (push (if (eq (car lim) 'not)
 825               (cdr lim)
 826             (cons 'not lim))
 827           ibuffer-filtering-qualifiers))
 828   (ibuffer-update nil t))
 829
 830 ;;;###autoload
 831 (defun ibuffer-or-filter (&optional reverse)
 832   "Replace the top two filters in this buffer with their logical OR.
 833 If optional argument REVERSE is non-nil, instead break the top OR
 834 filter into parts."
 835   (interactive "P")
 836   (if reverse
 837       (progn
 838         (when (or (null ibuffer-filtering-qualifiers)
 839                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 840           (error "Top filter is not an OR"))
 841         (let ((lim (pop ibuffer-filtering-qualifiers)))
 842           (setq ibuffer-filtering-qualifiers
 843                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 844     (when (< (length ibuffer-filtering-qualifiers) 2)
 845       (error "Need two filters to OR"))
 846     ;; If the second filter is an OR, just add to it.
 847     (let ((first (pop ibuffer-filtering-qualifiers))
 848           (second (pop ibuffer-filtering-qualifiers)))
 849       (if (eq 'or (car second))
 850           (push (nconc (list 'or first) (cdr second))
 851                 ibuffer-filtering-qualifiers)
 852         (push (list 'or first second)
 853               ibuffer-filtering-qualifiers))))
 854   (ibuffer-update nil t))
 855
 856 (defun ibuffer-maybe-save-stuff ()
 857   (when ibuffer-save-with-custom
 858     (if (fboundp 'customize-save-variable)
 859         (progn
 860           (customize-save-variable 'ibuffer-saved-filters
 861                                    ibuffer-saved-filters)
 862           (customize-save-variable 'ibuffer-saved-filter-groups
 863                                    ibuffer-saved-filter-groups))
 864       (message "Not saved permanently: Customize not available"))))
 865
 866 ;;;###autoload
 867 (defun ibuffer-save-filters (name filters)
 868   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 869 Interactively, prompt for NAME, and use the current filters."
 870   (interactive
 871    (if (null ibuffer-filtering-qualifiers)
 872        (error "No filters currently in effect")
 873      (list
 874       (read-from-minibuffer "Save current filters as: ")
 875       ibuffer-filtering-qualifiers)))
 876   (ibuffer-aif (assoc name ibuffer-saved-filters)
 877       (setcdr it filters)
 878     (push (list name filters) ibuffer-saved-filters))
 879   (ibuffer-maybe-save-stuff)
 880   (ibuffer-update-mode-name))
 881
 882 ;;;###autoload
 883 (defun ibuffer-delete-saved-filters (name)
 884   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 885   (interactive
 886    (list
 887     (if (null ibuffer-saved-filters)
 888         (error "No saved filters")
 889       (completing-read "Delete saved filters: "
 890                        ibuffer-saved-filters nil t))))
 891   (setq ibuffer-saved-filters
 892         (ibuffer-delete-alist name ibuffer-saved-filters))
 893   (ibuffer-maybe-save-stuff)
 894   (ibuffer-update nil t))
 895
 896 ;;;###autoload
 897 (defun ibuffer-add-saved-filters (name)
 898   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 899   (interactive
 900    (list
 901     (if (null ibuffer-saved-filters)
 902         (error "No saved filters")
 903       (completing-read "Add saved filters: "
 904                        ibuffer-saved-filters nil t))))
 905   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 906   (ibuffer-update nil t))
 907
 908 ;;;###autoload
 909 (defun ibuffer-switch-to-saved-filters (name)
 910   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'.
 911 If prefix argument ADD is non-nil, then add the saved filters instead
 912 of replacing the current filters."
 913   (interactive
 914    (list
 915     (if (null ibuffer-saved-filters)
 916         (error "No saved filters")
 917       (completing-read "Switch to saved filters: "
 918                        ibuffer-saved-filters nil t))))
 919   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 920   (ibuffer-update nil t))
 921
 922 (defun ibuffer-format-filter-group-data (filter)
 923   (if (equal filter "Default")
 924       ""
 925     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 926                                  (cdr (assq filter ibuffer-filter-groups))
 927                                  " "))))
 928
 929 (defun ibuffer-format-qualifier (qualifier)
 930   (if (eq (car-safe qualifier) 'not)
 931       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 932     (ibuffer-format-qualifier-1 qualifier)))
 933
 934 (defun ibuffer-format-qualifier-1 (qualifier)
 935   (case (car qualifier)
 936     (saved
 937      (concat " [filter: " (cdr qualifier) "]"))
 938     (or
 939      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 940                                (cdr qualifier) "") "]"))
 941     (t
 942      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 943        (unless qualifier
 944          (error "Ibuffer: bad qualifier %s" qualifier))
 945        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 946
 947
 948 (defun ibuffer-list-buffer-modes ()
 949   "Create an alist of buffer modes currently in use.
 950 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 951   (let ((bufs (buffer-list))
 952         (modes)
 953         (this-mode))
 954     (while bufs
 955       (setq this-mode
 956             (with-current-buffer
 957                 (car bufs)
 958               major-mode)
 959             bufs (cdr bufs))
 960       (add-to-list
 961        'modes
 962        `(,(symbol-name this-mode) .
 963          ,this-mode)))
 964     modes))
 965
 966
 967 ;;; Extra operation definitions
 968
 969 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext.el")
 970 (define-ibuffer-filter mode
 971   "Toggle current view to buffers with major mode QUALIFIER."
 972   (:description "major mode"
 973    :reader
 974    (intern
 975     (completing-read "Filter by major mode: " obarray
 976                      #'(lambda (e)
 977                          (string-match "-mode$"
 978                                        (symbol-name e)))
 979                      t
 980                      (let ((buf (ibuffer-current-buffer)))
 981                        (if (and buf (buffer-live-p buf))
 982                            (with-current-buffer buf
 983                              (symbol-name major-mode))
 984                          "")))))
 985   (eq qualifier (with-current-buffer buf major-mode)))
 986
 987 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext.el")
 988 (define-ibuffer-filter used-mode
 989   "Toggle current view to buffers with major mode QUALIFIER.
 990 Called interactively, this function allows selection of modes
 991 currently used by buffers."
 992   (:description "major mode in use"
 993                 :reader
 994                 (intern
 995                  (completing-read "Filter by major mode: "
 996                                   (ibuffer-list-buffer-modes)
 997                                   nil
 998                                   t
 999                                   (let ((buf (ibuffer-current-buffer)))
1000                                     (if (and buf (buffer-live-p buf))
1001                                         (with-current-buffer buf
1002                                           (symbol-name major-mode))
1003                                       "")))))
1004   (eq qualifier (with-current-buffer buf major-mode)))
1005
1006 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext.el")
1007 (define-ibuffer-filter name
1008   "Toggle current view to buffers with name matching QUALIFIER."
1009   (:description "buffer name"
1010    :reader (read-from-minibuffer "Filter by name (regexp): "))
1011   (string-match qualifier (buffer-name buf)))
1012
1013 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext.el")
1014 (define-ibuffer-filter filename
1015   "Toggle current view to buffers with filename matching QUALIFIER."
1016   (:description "filename"
1017    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1018   (ibuffer-awhen (with-current-buffer buf
1019                    (or buffer-file-name
1020                        (and (boundp 'dired-directory)
1021                             dired-directory
1022                             (expand-file-name dired-directory))))
1023     (string-match qualifier it)))
1024
1025 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext.el")
1026 (define-ibuffer-filter size-gt
1027   "Toggle current view to buffers with size greater than QUALIFIER."
1028   (:description "size greater than"
1029    :reader
1030    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1031   (> (with-current-buffer buf (buffer-size))
1032      qualifier))
1033
1034 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext.el")
1035 (define-ibuffer-filter size-lt
1036    "Toggle current view to buffers with size less than QUALIFIER."
1037   (:description "size less than"
1038    :reader
1039    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1040   (< (with-current-buffer buf (buffer-size))
1041      qualifier))
1042
1043 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext.el")
1044 (define-ibuffer-filter content
1045    "Toggle current view to buffers whose contents match QUALIFIER."
1046   (:description "content"
1047    :reader (read-from-minibuffer "Filter by content (regexp): "))
1048   (with-current-buffer buf
1049     (save-excursion
1050       (goto-char (point-min))
1051       (re-search-forward qualifier nil t))))
1052
1053 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext.el")
1054 (define-ibuffer-filter predicate
1055    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1056   (:description "predicate"
1057    :reader (read-minibuffer "Filter by predicate (form): "))
1058   (with-current-buffer buf
1059     (eval qualifier)))
1060
1061 ;;; Sorting
1062
1063 ;;;###autoload
1064 (defun ibuffer-toggle-sorting-mode ()
1065   "Toggle the current sorting mode.
1066 Default sorting modes are:
1067  Recency - the last time the buffer was viewed
1068  Name - the name of the buffer
1069  Major Mode - the name of the major mode of the buffer
1070  Size - the size of the buffer"
1071   (interactive)
1072   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1073     (add-to-list 'modes 'recency)
1074     (setq modes (sort modes 'string-lessp))
1075     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1076                     (car modes))))
1077       (setq ibuffer-sorting-mode next)
1078       (message "Sorting by %s" next)))
1079   (ibuffer-redisplay t))
1080
1081 ;;;###autoload
1082 (defun ibuffer-invert-sorting ()
1083   "Toggle whether or not sorting is in reverse order."
1084   (interactive)
1085   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1086   (message "Sorting order %s"
1087            (if ibuffer-sorting-reversep
1088                "reversed"
1089              "normal"))
1090   (ibuffer-redisplay t))
1091
1092 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext.el")
1093 (define-ibuffer-sorter major-mode
1094   "Sort the buffers by major modes.
1095 Ordering is lexicographic."
1096   (:description "major mode")
1097   (string-lessp (downcase
1098                  (symbol-name (with-current-buffer
1099                                   (car a)
1100                                 major-mode)))
1101                 (downcase
1102                  (symbol-name (with-current-buffer
1103                                   (car b)
1104                                 major-mode)))))
1105
1106 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext.el")
1107 (define-ibuffer-sorter mode-name
1108   "Sort the buffers by their mode name.
1109 Ordering is lexicographic."
1110   (:description "major mode name")
1111   (string-lessp (downcase
1112                   (with-current-buffer
1113                       (car a)
1114                     mode-name))
1115                 (downcase
1116                  (with-current-buffer
1117                      (car b)
1118                    mode-name))))
1119
1120 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext.el")
1121 (define-ibuffer-sorter alphabetic
1122   "Sort the buffers by their names.
1123 Ordering is lexicographic."
1124   (:description "buffer name")
1125   (string-lessp
1126    (buffer-name (car a))
1127    (buffer-name (car b))))
1128
1129 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext.el")
1130 (define-ibuffer-sorter size
1131  "Sort the buffers by their size."
1132   (:description "size")
1133   (< (with-current-buffer (car a)
1134        (buffer-size))
1135      (with-current-buffer (car b)
1136        (buffer-size))))
1137
1138 ;;; Functions to emulate bs.el
1139
1140 ;;;###autoload
1141 (defun ibuffer-bs-show ()
1142   "Emulate `bs-show' from the bs.el package."
1143   (interactive)
1144   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1145   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1146
1147 (defun ibuffer-bs-toggle-all ()
1148   "Emulate `bs-toggle-show-all' from the bs.el package."
1149   (interactive)
1150   (if ibuffer-filtering-qualifiers
1151       (ibuffer-pop-filter)
1152     (progn (ibuffer-push-filter '(filename . ".*"))
1153            (ibuffer-update nil t))))
1154
1155 ;;; Handy functions
1156
1157 ;;;###autoload
1158 (defun ibuffer-add-to-tmp-hide (regexp)
1159   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1160 This means that buffers whose name matches REGEXP will not be shown
1161 for this Ibuffer session."
1162   (interactive
1163    (list
1164     (read-from-minibuffer "Never show buffers matching: "
1165                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1166   (push regexp ibuffer-tmp-hide-regexps))
1167
1168 ;;;###autoload
1169 (defun ibuffer-add-to-tmp-show (regexp)
1170   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1171 This means that buffers whose name matches REGEXP will always be shown
1172 for this Ibuffer session."
1173   (interactive
1174    (list
1175     (read-from-minibuffer "Always show buffers matching: "
1176                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1177   (push regexp ibuffer-tmp-show-regexps))
1178
1179 ;;;###autoload
1180 (defun ibuffer-forward-next-marked (&optional count mark direction)
1181   "Move forward by COUNT marked buffers (default 1).
1182
1183 If MARK is non-nil, it should be a character denoting the type of mark
1184 to move by.  The default is `ibuffer-marked-char'.
1185
1186 If DIRECTION is non-nil, it should be an integer; negative integers
1187 mean move backwards, non-negative integers mean move forwards."
1188   (interactive "P")
1189   (unless count
1190     (setq count 1))
1191   (unless mark
1192     (setq mark ibuffer-marked-char))
1193   (unless direction
1194     (setq direction 1))
1195   ;; Skip the title
1196   (ibuffer-forward-line 0)
1197   (let ((opos (point))
1198         curmark)
1199     (ibuffer-forward-line direction)
1200     (while (not (or (= (point) opos)
1201                     (eq (setq curmark (ibuffer-current-mark))
1202                         mark)))
1203       (ibuffer-forward-line direction))
1204     (when (and (= (point) opos)
1205                (not (eq (ibuffer-current-mark) mark)))
1206       (error "No buffers with mark %c" mark))))
1207
1208 ;;;###autoload
1209 (defun ibuffer-backwards-next-marked (&optional count mark)
1210    "Move backwards by COUNT marked buffers (default 1).
1211
1212 If MARK is non-nil, it should be a character denoting the type of mark
1213 to move by.  The default is `ibuffer-marked-char'."
1214    (interactive "P")
1215    (ibuffer-forward-next-marked count mark -1))
1216
1217 ;;;###autoload
1218 (defun ibuffer-do-kill-lines ()
1219   "Hide all of the currently marked lines."
1220   (interactive)
1221   (if (= (ibuffer-count-marked-lines) 0)
1222       (message "No buffers marked; use 'm' to mark a buffer")
1223     (let ((count
1224            (ibuffer-map-marked-lines
1225             #'(lambda (buf mark)
1226                 'kill))))
1227       (message "Killed %s lines" count))))
1228
1229 ;;;###autoload
1230 (defun ibuffer-jump-to-buffer (name)
1231   "Move point to the buffer whose name is NAME.
1232
1233 If called interactively, prompt for a buffer name and go to the
1234 corresponding line in the Ibuffer buffer.  If said buffer is in a
1235 hidden group filter, open it.
1236
1237 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1238 visible buffers in the completion list.  Calling the command with
1239 a prefix argument reverses the meaning of that variable."
1240   (interactive (list
1241                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1242                   (when current-prefix-arg
1243                     (setq only-visible (not only-visible)))
1244                   (if only-visible
1245                       (let ((table (mapcar #'(lambda (x)
1246                                                (buffer-name (car x)))
1247                                            (ibuffer-current-state-list))))
1248                         (when (null table)
1249                           (error "No buffers!"))
1250                         (completing-read "Jump to buffer: "
1251                                          table nil t))
1252                     (read-buffer "Jump to buffer: " nil t)))))
1253   (when (not (string= "" name))
1254     (let (buf-point)
1255       ;; Blindly search for our buffer: it is very likely that it is
1256       ;; not in a hidden filter group.
1257       (ibuffer-map-lines #'(lambda (buf marks)
1258                              (when (string= (buffer-name buf) name)
1259                                (setq buf-point (point))
1260                                nil))
1261                          t nil)
1262       (when (and
1263              (null buf-point)
1264              (not (null ibuffer-hidden-filter-groups)))
1265         ;; We did not find our buffer.  It must be in a hidden filter
1266         ;; group, so go through all hidden filter groups to find it.
1267         (catch 'found
1268           (dolist (group ibuffer-hidden-filter-groups)
1269             (ibuffer-jump-to-filter-group group)
1270             (ibuffer-toggle-filter-group)
1271             (ibuffer-map-lines #'(lambda (buf marks)
1272                                    (when (string= (buffer-name buf) name)
1273                                      (setq buf-point (point))
1274                                      nil))
1275                                t group)
1276             (if buf-point
1277                 (throw 'found nil)
1278               (ibuffer-toggle-filter-group)))))
1279       (if (null buf-point)
1280           ;; Still not found even though we expanded all hidden filter
1281           ;; groups: that must be because it's hidden by predicate:
1282           ;; we won't bother trying to display it.
1283           (error "No buffer with name %s" name)
1284         (goto-char buf-point)))))
1285
1286 ;;;###autoload
1287 (defun ibuffer-diff-with-file ()
1288   "View the differences between this buffer and its associated file.
1289 This requires the external program \"diff\" to be in your `exec-path'."
1290   (interactive)
1291   (let ((buf (ibuffer-current-buffer)))
1292     (unless (buffer-live-p buf)
1293       (error "Buffer %s has been killed" buf))
1294     (diff-buffer-with-file buf)))
1295
1296 ;;;###autoload
1297 (defun ibuffer-copy-filename-as-kill (&optional arg)
1298   "Copy filenames of marked buffers into the kill ring.
1299
1300 The names are separated by a space.
1301 If a buffer has no filename, it is ignored.
1302
1303 With no prefix arg, use the filename sans its directory of each marked file.
1304 With a zero prefix arg, use the complete filename of each marked file.
1305 With \\[universal-argument], use the filename of each marked file relative
1306 to `ibuffer-default-directory' iff non-nil, otherwise `default-directory'.
1307
1308 You can then feed the file name(s) to other commands with \\[yank]."
1309   (interactive "p")
1310   (if (zerop (ibuffer-count-marked-lines))
1311       (message "No buffers marked; use 'm' to mark a buffer")
1312     (let ((ibuffer-copy-filename-as-kill-result "")
1313           (type (cond ((zerop arg)
1314                        'full)
1315                       ((= arg 4)
1316                        'relative)
1317                       (t
1318                        'name))))
1319       (ibuffer-map-marked-lines
1320        #'(lambda (buf mark)
1321            (setq ibuffer-copy-filename-as-kill-result
1322                  (concat ibuffer-copy-filename-as-kill-result
1323                          (let ((name (buffer-file-name buf)))
1324                            (if name
1325                                (case type
1326                                  (full
1327                                   name)
1328                                  (relative
1329                                   (file-relative-name
1330                                    name (or ibuffer-default-directory
1331                                             default-directory)))
1332                                  (t
1333                                   (file-name-nondirectory name)))
1334                              ""))
1335                          " "))))
1336       (kill-new ibuffer-copy-filename-as-kill-result))))
1337
1338 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1339   (let ((count
1340          (ibuffer-map-lines
1341           #'(lambda (buf mark)
1342               (when (funcall func buf)
1343                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1344                                         ibuffer-marked-char))
1345                 t))
1346           nil
1347           group)))
1348     (ibuffer-redisplay t)
1349     (message "Marked %s buffers" count)))
1350
1351 ;;;###autoload
1352 (defun ibuffer-mark-by-name-regexp (regexp)
1353   "Mark all buffers whose name matches REGEXP."
1354   (interactive "sMark by name (regexp): ")
1355   (ibuffer-mark-on-buffer
1356    #'(lambda (buf)
1357        (string-match regexp (buffer-name buf)))))
1358
1359 ;;;###autoload
1360 (defun ibuffer-mark-by-mode-regexp (regexp)
1361   "Mark all buffers whose major mode matches REGEXP."
1362   (interactive "sMark by major mode (regexp): ")
1363   (ibuffer-mark-on-buffer
1364    #'(lambda (buf)
1365        (with-current-buffer buf
1366          (string-match regexp mode-name)))))
1367
1368 ;;;###autoload
1369 (defun ibuffer-mark-by-file-name-regexp (regexp)
1370   "Mark all buffers whose file name matches REGEXP."
1371   (interactive "sMark by file name (regexp): ")
1372   (ibuffer-mark-on-buffer
1373    #'(lambda (buf)
1374        (let ((name (or (buffer-file-name buf)
1375                        (with-current-buffer buf
1376                          (and
1377                           (boundp 'dired-directory)
1378                           (stringp dired-directory)
1379                           dired-directory)))))
1380          (when name
1381            (string-match regexp name))))))
1382
1383 ;;;###autoload
1384 (defun ibuffer-mark-by-mode (mode)
1385   "Mark all buffers whose major mode equals MODE."
1386   (interactive
1387    (list (intern (completing-read "Mark by major mode: " obarray
1388                                   #'(lambda (e)
1389                                       ;; kind of a hack...
1390                                       (and (fboundp e)
1391                                            (string-match "-mode$"
1392                                                          (symbol-name e))))
1393                                   t
1394                                   (let ((buf (ibuffer-current-buffer)))
1395                                     (if (and buf (buffer-live-p buf))
1396                                         (with-current-buffer buf
1397                                           (cons (symbol-name major-mode)
1398                                                 0))
1399                                       ""))))))
1400   (ibuffer-mark-on-buffer
1401    #'(lambda (buf)
1402        (with-current-buffer buf
1403          (eq major-mode mode)))))
1404
1405 ;;;###autoload
1406 (defun ibuffer-mark-modified-buffers ()
1407   "Mark all modified buffers."
1408   (interactive)
1409   (ibuffer-mark-on-buffer
1410    #'(lambda (buf) (buffer-modified-p buf))))
1411
1412 ;;;###autoload
1413 (defun ibuffer-mark-unsaved-buffers ()
1414   "Mark all modified buffers that have an associated file."
1415   (interactive)
1416   (ibuffer-mark-on-buffer
1417    #'(lambda (buf) (and (with-current-buffer buf buffer-file-name)
1418                         (buffer-modified-p buf)))))
1419
1420 ;;;###autoload
1421 (defun ibuffer-mark-dissociated-buffers ()
1422   "Mark all buffers whose associated file does not exist."
1423   (interactive)
1424   (ibuffer-mark-on-buffer
1425    #'(lambda (buf)
1426        (with-current-buffer buf
1427          (or
1428           (and buffer-file-name
1429                (not (file-exists-p buffer-file-name)))
1430           (and (eq major-mode 'dired-mode)
1431                (boundp 'dired-directory)
1432                (stringp dired-directory)
1433                (not (file-exists-p (file-name-directory dired-directory)))))))))
1434
1435 ;;;###autoload
1436 (defun ibuffer-mark-help-buffers ()
1437   "Mark buffers like *Help*, *Apropos*, *Info*."
1438   (interactive)
1439   (ibuffer-mark-on-buffer
1440    #'(lambda (buf)
1441        (with-current-buffer buf
1442          (memq major-mode ibuffer-help-buffer-modes)))))
1443
1444 ;;;###autoload
1445 (defun ibuffer-mark-old-buffers ()
1446   "Mark buffers which have not been viewed in `ibuffer-old-time' days."
1447   (interactive)
1448   (ibuffer-mark-on-buffer
1449    #'(lambda (buf)
1450        (with-current-buffer buf
1451          ;; hacked from midnight.el
1452          (when buffer-display-time
1453            (let* ((tm (current-time))
1454                   (now (+ (* (float (ash 1 16)) (car tm))
1455                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1456                   (then (+ (* (float (ash 1 16))
1457                               (car buffer-display-time))
1458                            (float (cadr buffer-display-time))
1459                            (* 0.0000001 (caddr buffer-display-time)))))
1460              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1461
1462 ;;;###autoload
1463 (defun ibuffer-mark-special-buffers ()
1464   "Mark all buffers whose name begins and ends with '*'."
1465   (interactive)
1466   (ibuffer-mark-on-buffer
1467    #'(lambda (buf) (string-match "^\\*.+\\*$"
1468                                  (buffer-name buf)))))
1469
1470 ;;;###autoload
1471 (defun ibuffer-mark-read-only-buffers ()
1472   "Mark all read-only buffers."
1473   (interactive)
1474   (ibuffer-mark-on-buffer
1475    #'(lambda (buf)
1476        (with-current-buffer buf
1477          buffer-read-only))))
1478
1479 ;;;###autoload
1480 (defun ibuffer-mark-dired-buffers ()
1481   "Mark all `dired' buffers."
1482   (interactive)
1483   (ibuffer-mark-on-buffer
1484    #'(lambda (buf)
1485        (with-current-buffer buf
1486          (eq major-mode 'dired-mode)))))
1487
1488 ;;;###autoload
1489 (defun ibuffer-do-occur (regexp &optional nlines)
1490   "View lines which match REGEXP in all marked buffers.
1491 Optional argument NLINES says how many lines of context to display: it
1492 defaults to one."
1493   (interactive (occur-read-primary-args))
1494   (if (or (not (integerp nlines))
1495           (< nlines 0))
1496       (setq nlines 0))
1497   (when (zerop (ibuffer-count-marked-lines))
1498     (ibuffer-set-mark ibuffer-marked-char))
1499   (let ((ibuffer-do-occur-bufs nil))
1500     ;; Accumulate a list of marked buffers
1501     (ibuffer-map-marked-lines
1502      #'(lambda (buf mark)
1503          (push buf ibuffer-do-occur-bufs)))
1504     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1505
1506 (provide 'ibuf-ext)
1507
1508 ;;; arch-tag: 9af21953-deda-4c30-b76d-f81d9128e76d
1509 ;;; ibuf-ext.el ends here