lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  28 ;; associated support machinery, such as adding hyperlinks, etc.,
  29
  30 ;;; Code:
  31
  32 (require 'button)
  33 (require 'view)
  34 (eval-when-compile (require 'easymenu))
  35
  36 (defvar help-mode-map
  37   (let ((map (make-sparse-keymap)))
  38     (set-keymap-parent map button-buffer-map)
  39
  40     (define-key map [mouse-2] 'help-follow-mouse)
  41     (define-key map "\C-c\C-b" 'help-go-back)
  42     (define-key map "\C-c\C-f" 'help-go-forward)
  43     (define-key map "\C-c\C-c" 'help-follow-symbol)
  44     ;; Documentation only, since we use minor-mode-overriding-map-alist.
  45     (define-key map "\r" 'help-follow)
  46     map)
  47   "Keymap for help mode.")
  48
  49 (easy-menu-define help-mode-menu help-mode-map
  50   "Menu for Help Mode."
  51   '("Help-Mode"
  52     ["Show Help for Symbol" help-follow-symbol
  53      :help "Show the docs for the symbol at point"]
  54     ["Previous Topic" help-go-back
  55      :help "Go back to previous topic in this help buffer"]
  56     ["Next Topic" help-go-forward
  57      :help "Go back to next topic in this help buffer"]
  58     ["Move to Previous Button" backward-button
  59      :help "Move to the Next Button in the help buffer"]
  60     ["Move to Next Button" forward-button
  61       :help "Move to the Next Button in the help buffer"]))
  62
  63 (defvar help-xref-stack nil
  64   "A stack of ways by which to return to help buffers after following xrefs.
  65 Used by `help-follow' and `help-xref-go-back'.
  66 An element looks like (POSITION FUNCTION ARGS...).
  67 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  68 (put 'help-xref-stack 'permanent-local t)
  69 (make-variable-buffer-local 'help-xref-stack)
  70
  71 (defvar help-xref-forward-stack nil
  72   "A stack used to navigate help forwards after using the back button.
  73 Used by `help-follow' and `help-xref-go-forward'.
  74 An element looks like (POSITION FUNCTION ARGS...).
  75 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  76 (put 'help-xref-forward-stack 'permanent-local t)
  77 (make-variable-buffer-local 'help-xref-forward-stack)
  78
  79 (defvar help-xref-stack-item nil
  80   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  81 The format is (FUNCTION ARGS...).")
  82 (put 'help-xref-stack-item 'permanent-local t)
  83 (make-variable-buffer-local 'help-xref-stack-item)
  84
  85 (defvar help-xref-stack-forward-item nil
  86   "An item for `help-go-back' to push onto `help-xref-forward-stack'.
  87 The format is (FUNCTION ARGS...).")
  88 (put 'help-xref-stack-forward-item 'permanent-local t)
  89 (make-variable-buffer-local 'help-xref-stack-forward-item)
  90
  91 (setq-default help-xref-stack nil help-xref-stack-item nil)
  92 (setq-default help-xref-forward-stack nil help-xref-forward-stack-item nil)
  93
  94 (defcustom help-mode-hook nil
  95   "Hook run by `help-mode'."
  96   :type 'hook
  97   :group 'help)
  98 \f
  99 ;; Button types used by help
 100
 101 (define-button-type 'help-xref
 102   'follow-link t
 103   'action #'help-button-action)
 104
 105 (defun help-button-action (button)
 106   "Call BUTTON's help function."
 107   (help-do-xref (button-start button)
 108                 (button-get button 'help-function)
 109                 (button-get button 'help-args)))
 110
 111 ;; These 6 calls to define-button-type were generated in a dolist
 112 ;; loop, but that is bad because it means these button types don't
 113 ;; have an easily found definition.
 114
 115 (define-button-type 'help-function
 116   :supertype 'help-xref
 117   'help-function 'describe-function
 118   'help-echo (purecopy "mouse-2, RET: describe this function"))
 119
 120 (define-button-type 'help-variable
 121   :supertype 'help-xref
 122   'help-function 'describe-variable
 123   'help-echo (purecopy "mouse-2, RET: describe this variable"))
 124
 125 (define-button-type 'help-face
 126   :supertype 'help-xref
 127   'help-function 'describe-face
 128   'help-echo (purecopy "mouse-2, RET: describe this face"))
 129
 130 (define-button-type 'help-coding-system
 131   :supertype 'help-xref
 132   'help-function 'describe-coding-system
 133   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 134
 135 (define-button-type 'help-input-method
 136   :supertype 'help-xref
 137   'help-function 'describe-input-method
 138   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 139
 140 (define-button-type 'help-character-set
 141   :supertype 'help-xref
 142   'help-function 'describe-character-set
 143   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 144
 145 ;; make some more ideosyncratic button types
 146
 147 (define-button-type 'help-symbol
 148   :supertype 'help-xref
 149   'help-function #'help-xref-interned
 150   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 151
 152 (define-button-type 'help-back
 153   :supertype 'help-xref
 154   'help-function #'help-xref-go-back
 155   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 156
 157 (define-button-type 'help-forward
 158   :supertype 'help-xref
 159   'help-function #'help-xref-go-forward
 160   'help-echo (purecopy "mouse-2, RET: move forward to next help buffer"))
 161
 162 (define-button-type 'help-info-variable
 163   :supertype 'help-xref
 164   ;; the name of the variable is put before the argument to Info
 165   'help-function (lambda (_a v) (info v))
 166   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 167
 168 (define-button-type 'help-info
 169   :supertype 'help-xref
 170   'help-function #'info
 171   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 172
 173 (define-button-type 'help-url
 174   :supertype 'help-xref
 175   'help-function #'browse-url
 176   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 177
 178 (define-button-type 'help-customize-variable
 179   :supertype 'help-xref
 180   'help-function (lambda (v)
 181                    (customize-variable v))
 182   'help-echo (purecopy "mouse-2, RET: customize variable"))
 183
 184 (define-button-type 'help-customize-face
 185   :supertype 'help-xref
 186   'help-function (lambda (v)
 187                    (customize-face v))
 188   'help-echo (purecopy "mouse-2, RET: customize face"))
 189
 190 (define-button-type 'help-function-def
 191   :supertype 'help-xref
 192   'help-function (lambda (fun file)
 193                    (require 'find-func)
 194                    (when (eq file 'C-source)
 195                      (setq file
 196                            (help-C-file-name (indirect-function fun) 'fun)))
 197                    ;; Don't use find-function-noselect because it follows
 198                    ;; aliases (which fails for built-in functions).
 199                    (let ((location
 200                           (find-function-search-for-symbol fun nil file)))
 201                      (pop-to-buffer (car location))
 202                      (if (cdr location)
 203                          (goto-char (cdr location))
 204                        (message "Unable to find location in file"))))
 205   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 206
 207 (define-button-type 'help-function-cmacro
 208   :supertype 'help-xref
 209   'help-function (lambda (fun file)
 210                    (setq file (locate-library file t))
 211                    (if (and file (file-readable-p file))
 212                        (progn
 213                          (pop-to-buffer (find-file-noselect file))
 214                          (goto-char (point-min))
 215                          (if (re-search-forward
 216                               (format "^[ \t]*(define-compiler-macro[ \t]+%s"
 217                                       (regexp-quote (symbol-name fun))) nil t)
 218                              (forward-line 0)
 219                            (message "Unable to find location in file")))
 220                      (message "Unable to find file")))
 221   'help-echo (purecopy "mouse-2, RET: find function's compiler macro"))
 222
 223 (define-button-type 'help-variable-def
 224   :supertype 'help-xref
 225   'help-function (lambda (var &optional file)
 226                    (when (eq file 'C-source)
 227                      (setq file (help-C-file-name var 'var)))
 228                    (let ((location (find-variable-noselect var file)))
 229                      (pop-to-buffer (car location))
 230                      (if (cdr location)
 231                        (goto-char (cdr location))
 232                        (message "Unable to find location in file"))))
 233   'help-echo (purecopy "mouse-2, RET: find variable's definition"))
 234
 235 (define-button-type 'help-face-def
 236   :supertype 'help-xref
 237   'help-function (lambda (fun file)
 238                    (require 'find-func)
 239                    ;; Don't use find-function-noselect because it follows
 240                    ;; aliases (which fails for built-in functions).
 241                    (let ((location
 242                           (find-function-search-for-symbol fun 'defface file)))
 243                      (pop-to-buffer (car location))
 244                      (if (cdr location)
 245                          (goto-char (cdr location))
 246                        (message "Unable to find location in file"))))
 247   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 248
 249 (define-button-type 'help-package
 250   :supertype 'help-xref
 251   'help-function 'describe-package
 252   'help-echo (purecopy "mouse-2, RET: Describe package"))
 253
 254 (define-button-type 'help-package-def
 255   :supertype 'help-xref
 256   'help-function (lambda (file) (dired file))
 257   'help-echo (purecopy "mouse-2, RET: visit package directory"))
 258
 259 (define-button-type 'help-theme-def
 260   :supertype 'help-xref
 261   'help-function 'find-file
 262   'help-echo (purecopy "mouse-2, RET: visit theme file"))
 263
 264 (define-button-type 'help-theme-edit
 265   :supertype 'help-xref
 266   'help-function 'customize-create-theme
 267   'help-echo (purecopy "mouse-2, RET: edit this theme file"))
 268 \f
 269 ;;;###autoload
 270 (defun help-mode ()
 271   "Major mode for viewing help text and navigating references in it.
 272 Entry to this mode runs the normal hook `help-mode-hook'.
 273 Commands:
 274 \\{help-mode-map}"
 275   (interactive)
 276   (kill-all-local-variables)
 277   (use-local-map help-mode-map)
 278   (setq mode-name "Help")
 279   (setq major-mode 'help-mode)
 280
 281   (view-mode)
 282   (set (make-local-variable 'view-no-disable-on-exit) t)
 283   ;; With Emacs 22 `view-exit-action' could delete the selected window
 284   ;; disregarding whether the help buffer was shown in that window at
 285   ;; all.  Since `view-exit-action' is called with the help buffer as
 286   ;; argument it seems more appropriate to have it work on the buffer
 287   ;; only and leave it to `view-mode-exit' to delete any associated
 288   ;; window(s).
 289   (setq view-exit-action
 290         (lambda (buffer)
 291           ;; Use `with-current-buffer' to make sure that `bury-buffer'
 292           ;; also removes BUFFER from the selected window.
 293           (with-current-buffer buffer
 294             (bury-buffer))))
 295
 296   (set (make-local-variable 'revert-buffer-function)
 297        'help-mode-revert-buffer)
 298
 299   (run-mode-hooks 'help-mode-hook))
 300
 301 ;;;###autoload
 302 (defun help-mode-setup ()
 303   (help-mode)
 304   (setq buffer-read-only nil))
 305
 306 ;;;###autoload
 307 (defun help-mode-finish ()
 308   (when (eq major-mode 'help-mode)
 309     ;; View mode's read-only status of existing *Help* buffer is lost
 310     ;; by with-output-to-temp-buffer.
 311     (toggle-read-only 1)
 312
 313     (save-excursion
 314       (goto-char (point-min))
 315       (let ((inhibit-read-only t))
 316         (when (re-search-forward "^This [^[:space:]]+ is advised.$" nil t)
 317           (put-text-property (match-beginning 0)
 318                              (match-end 0)
 319                              'face 'font-lock-warning-face))))
 320
 321     (help-make-xrefs (current-buffer))))
 322 \f
 323 ;; Grokking cross-reference information in doc strings and
 324 ;; hyperlinking it.
 325
 326 ;; This may have some scope for extension and the same or something
 327 ;; similar should be done for widget doc strings, which currently use
 328 ;; another mechanism.
 329
 330 (defvar help-back-label (purecopy "[back]")
 331   "Label to use by `help-make-xrefs' for the go-back reference.")
 332
 333 (defvar help-forward-label (purecopy "[forward]")
 334   "Label to use by `help-make-xrefs' for the go-forward reference.")
 335
 336 (defconst help-xref-symbol-regexp
 337   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"  ; Link to var
 338                     "\\(function\\|command\\)\\|"          ; Link to function
 339                     "\\(face\\)\\|"                        ; Link to face
 340                     "\\(symbol\\|program\\|property\\)\\|" ; Don't link
 341                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 342                     "[ \t\n]+\\)?"
 343                     ;; Note starting with word-syntax character:
 344                     "`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
 345   "Regexp matching doc string references to symbols.
 346
 347 The words preceding the quoted symbol can be used in doc strings to
 348 distinguish references to variables, functions and symbols.")
 349
 350 (defvar help-xref-mule-regexp nil
 351   "Regexp matching doc string references to MULE-related keywords.
 352
 353 It is usually nil, and is temporarily bound to an appropriate regexp
 354 when help commands related to multilingual environment (e.g.,
 355 `describe-coding-system') are invoked.")
 356
 357
 358 (defconst help-xref-info-regexp
 359   (purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
 360   "Regexp matching doc string references to an Info node.")
 361
 362 (defconst help-xref-url-regexp
 363   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+`\\([^']+\\)'")
 364   "Regexp matching doc string references to a URL.")
 365
 366 ;;;###autoload
 367 (defun help-setup-xref (item interactive-p)
 368   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 369
 370 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 371 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 372 calling command was invoked interactively.  In this case the stack of
 373 items for help buffer \"back\" buttons is cleared.
 374
 375 This should be called very early, before the output buffer is cleared,
 376 because we want to record the \"previous\" position of point so we can
 377 restore it properly when going back."
 378   (with-current-buffer (help-buffer)
 379     (when help-xref-stack-item
 380       (push (cons (point) help-xref-stack-item) help-xref-stack)
 381       (setq help-xref-forward-stack nil))
 382     (when interactive-p
 383       (let ((tail (nthcdr 10 help-xref-stack)))
 384         ;; Truncate the stack.
 385         (if tail (setcdr tail nil))))
 386     (setq help-xref-stack-item item)))
 387
 388 (defvar help-xref-following nil
 389   "Non-nil when following a help cross-reference.")
 390
 391 ;;;###autoload
 392 (defun help-buffer ()
 393   "Return the name of a buffer for inserting help.
 394 If `help-xref-following' is non-nil, this is the name of the
 395 current buffer.  Signal an error if this buffer is not derived
 396 from `help-mode'.
 397 Otherwise, return \"*Help*\", creating a buffer with that name if
 398 it does not already exist."
 399   (buffer-name                          ;for with-output-to-temp-buffer
 400    (if (not help-xref-following)
 401        (get-buffer-create "*Help*")
 402      (unless (derived-mode-p 'help-mode)
 403        (error "Current buffer is not in Help mode"))
 404      (current-buffer))))
 405
 406 (defvar help-xref-override-view-map
 407   (let ((map (make-sparse-keymap)))
 408     (set-keymap-parent map view-mode-map)
 409     (define-key map "\r" nil)
 410     map)
 411   "Replacement keymap for `view-mode' in help buffers.")
 412
 413 ;;;###autoload
 414 (defun help-make-xrefs (&optional buffer)
 415   "Parse and hyperlink documentation cross-references in the given BUFFER.
 416
 417 Find cross-reference information in a buffer and activate such cross
 418 references for selection with `help-follow'.  Cross-references have
 419 the canonical form `...'  and the type of reference may be
 420 disambiguated by the preceding word(s) used in
 421 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 422 preceded or followed by the word `face'.  Variables without
 423 variable documentation do not get cross-referenced, unless
 424 preceded by the word `variable' or `option'.
 425
 426 If the variable `help-xref-mule-regexp' is non-nil, find also
 427 cross-reference information related to multilingual environment
 428 \(e.g., coding-systems).  This variable is also used to disambiguate
 429 the type of reference as the same way as `help-xref-symbol-regexp'.
 430
 431 A special reference `back' is made to return back through a stack of
 432 help buffers.  Variable `help-back-label' specifies the text for
 433 that."
 434   (interactive "b")
 435   (with-current-buffer (or buffer (current-buffer))
 436     (save-excursion
 437       (goto-char (point-min))
 438       ;; Skip the header-type info, though it might be useful to parse
 439       ;; it at some stage (e.g. "function in `library'").
 440       (forward-paragraph)
 441       (let ((old-modified (buffer-modified-p)))
 442         (let ((stab (syntax-table))
 443               (case-fold-search t)
 444               (inhibit-read-only t))
 445           (set-syntax-table emacs-lisp-mode-syntax-table)
 446           ;; The following should probably be abstracted out.
 447           (unwind-protect
 448               (progn
 449                 ;; Info references
 450                 (save-excursion
 451                   (while (re-search-forward help-xref-info-regexp nil t)
 452                     (let ((data (match-string 2)))
 453                       (save-match-data
 454                         (unless (string-match "^([^)]+)" data)
 455                           (setq data (concat "(emacs)" data)))
 456                         (setq data ;; possible newlines if para filled
 457                               (replace-regexp-in-string "[ \t\n]+" " " data t t)))
 458                       (help-xref-button 2 'help-info data))))
 459                 ;; URLs
 460                 (save-excursion
 461                   (while (re-search-forward help-xref-url-regexp nil t)
 462                     (let ((data (match-string 1)))
 463                       (help-xref-button 1 'help-url data))))
 464                 ;; Mule related keywords.  Do this before trying
 465                 ;; `help-xref-symbol-regexp' because some of Mule
 466                 ;; keywords have variable or function definitions.
 467                 (if help-xref-mule-regexp
 468                     (save-excursion
 469                       (while (re-search-forward help-xref-mule-regexp nil t)
 470                         (let* ((data (match-string 7))
 471                                (sym (intern-soft data)))
 472                           (cond
 473                            ((match-string 3) ; coding system
 474                             (and sym (coding-system-p sym)
 475                                  (help-xref-button 6 'help-coding-system sym)))
 476                            ((match-string 4) ; input method
 477                             (and (assoc data input-method-alist)
 478                                  (help-xref-button 7 'help-input-method data)))
 479                            ((or (match-string 5) (match-string 6)) ; charset
 480                             (and sym (charsetp sym)
 481                                  (help-xref-button 7 'help-character-set sym)))
 482                            ((assoc data input-method-alist)
 483                             (help-xref-button 7 'help-character-set data))
 484                            ((and sym (coding-system-p sym))
 485                             (help-xref-button 7 'help-coding-system sym))
 486                            ((and sym (charsetp sym))
 487                             (help-xref-button 7 'help-character-set sym)))))))
 488                 ;; Quoted symbols
 489                 (save-excursion
 490                   (while (re-search-forward help-xref-symbol-regexp nil t)
 491                     (let* ((data (match-string 8))
 492                            (sym (intern-soft data)))
 493                       (if sym
 494                           (cond
 495                            ((match-string 3) ; `variable' &c
 496                             (and (or (boundp sym) ; `variable' doesn't ensure
 497                                         ; it's actually bound
 498                                      (get sym 'variable-documentation))
 499                                  (help-xref-button 8 'help-variable sym)))
 500                            ((match-string 4) ; `function' &c
 501                             (and (fboundp sym) ; similarly
 502                                  (help-xref-button 8 'help-function sym)))
 503                            ((match-string 5) ; `face'
 504                             (and (facep sym)
 505                                  (help-xref-button 8 'help-face sym)))
 506                            ((match-string 6)) ; nothing for `symbol'
 507                            ((match-string 7)
 508                             ;; this used:
 509                             ;; #'(lambda (arg)
 510                             ;;     (let ((location
 511                             ;;            (find-function-noselect arg)))
 512                             ;;       (pop-to-buffer (car location))
 513                             ;;  (goto-char (cdr location))))
 514                             (help-xref-button 8 'help-function-def sym))
 515                            ((and
 516                              (facep sym)
 517                              (save-match-data (looking-at "[ \t\n]+face\\W")))
 518                             (help-xref-button 8 'help-face sym))
 519                            ((and (or (boundp sym)
 520                                      (get sym 'variable-documentation))
 521                                  (fboundp sym))
 522                             ;; We can't intuit whether to use the
 523                             ;; variable or function doc -- supply both.
 524                             (help-xref-button 8 'help-symbol sym))
 525                            ((and
 526                              (or (boundp sym)
 527                                  (get sym 'variable-documentation))
 528                              (or
 529                               (documentation-property
 530                                sym 'variable-documentation)
 531                               (condition-case nil
 532                                   (documentation-property
 533                                    (indirect-variable sym)
 534                                    'variable-documentation)
 535                                 (cyclic-variable-indirection nil))))
 536                             (help-xref-button 8 'help-variable sym))
 537                            ((fboundp sym)
 538                             (help-xref-button 8 'help-function sym)))))))
 539                 ;; An obvious case of a key substitution:
 540                 (save-excursion
 541                   (while (re-search-forward
 542                           ;; Assume command name is only word and symbol
 543                           ;; characters to get things like `use M-x foo->bar'.
 544                           ;; Command required to end with word constituent
 545                           ;; to avoid `.' at end of a sentence.
 546                           "\\<M-x\\s-+\\(\\sw\\(\\sw\\|\\s_\\)*\\sw\\)" nil t)
 547                     (let ((sym (intern-soft (match-string 1))))
 548                       (if (fboundp sym)
 549                           (help-xref-button 1 'help-function sym)))))
 550                 ;; Look for commands in whole keymap substitutions:
 551                 (save-excursion
 552                   ;; Make sure to find the first keymap.
 553                   (goto-char (point-min))
 554                   ;; Find a header and the column at which the command
 555                   ;; name will be found.
 556
 557                   ;; If the keymap substitution isn't the last thing in
 558                   ;; the doc string, and if there is anything on the same
 559                   ;; line after it, this code won't recognize the end of it.
 560                   (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 561                                             nil t)
 562                     (let ((col (- (match-end 1) (match-beginning 1))))
 563                       (while
 564                           (and (not (eobp))
 565                                ;; Stop at a pair of blank lines.
 566                                (not (looking-at "\n\\s-*\n")))
 567                         ;; Skip a single blank line.
 568                         (and (eolp) (forward-line))
 569                         (end-of-line)
 570                         (skip-chars-backward "^ \t\n")
 571                         (if (and (>= (current-column) col)
 572                                  (looking-at "\\(\\sw\\|\\s_\\)+$"))
 573                             (let ((sym (intern-soft (match-string 0))))
 574                               (if (fboundp sym)
 575                                   (help-xref-button 0 'help-function sym))))
 576                         (forward-line))))))
 577             (set-syntax-table stab))
 578           ;; Delete extraneous newlines at the end of the docstring
 579           (goto-char (point-max))
 580           (while (and (not (bobp)) (bolp))
 581             (delete-char -1))
 582           (insert "\n")
 583           (when (or help-xref-stack help-xref-forward-stack)
 584             (insert "\n"))
 585           ;; Make a back-reference in this buffer if appropriate.
 586           (when help-xref-stack
 587             (help-insert-xref-button help-back-label 'help-back
 588                                      (current-buffer)))
 589           ;; Make a forward-reference in this buffer if appropriate.
 590           (when help-xref-forward-stack
 591             (when help-xref-stack
 592               (insert "\t"))
 593             (help-insert-xref-button help-forward-label 'help-forward
 594                                      (current-buffer)))
 595           (when (or help-xref-stack help-xref-forward-stack)
 596             (insert "\n")))
 597         ;; View mode steals RET from us.
 598         (set (make-local-variable 'minor-mode-overriding-map-alist)
 599              (list (cons 'view-mode help-xref-override-view-map)))
 600         (set-buffer-modified-p old-modified)))))
 601
 602 ;;;###autoload
 603 (defun help-xref-button (match-number type &rest args)
 604   "Make a hyperlink for cross-reference text previously matched.
 605 MATCH-NUMBER is the subexpression of interest in the last matched
 606 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 607 passed to the button's help-function when it is invoked.
 608 See `help-make-xrefs'."
 609   ;; Don't mung properties we've added specially in some instances.
 610   (unless (button-at (match-beginning match-number))
 611     (make-text-button (match-beginning match-number)
 612                       (match-end match-number)
 613                       'type type 'help-args args)))
 614
 615 ;;;###autoload
 616 (defun help-insert-xref-button (string type &rest args)
 617   "Insert STRING and make a hyperlink from cross-reference text on it.
 618 TYPE is the type of button to use.  Any remaining arguments are passed
 619 to the button's help-function when it is invoked.
 620 See `help-make-xrefs'."
 621   (unless (button-at (point))
 622     (insert-text-button string 'type type 'help-args args)))
 623
 624 ;;;###autoload
 625 (defun help-xref-on-pp (from to)
 626   "Add xrefs for symbols in `pp's output between FROM and TO."
 627   (if (> (- to from) 5000) nil
 628     (with-syntax-table emacs-lisp-mode-syntax-table
 629       (save-excursion
 630         (save-restriction
 631           (narrow-to-region from to)
 632           (goto-char (point-min))
 633           (condition-case nil
 634               (while (not (eobp))
 635                 (cond
 636                  ((looking-at "\"") (forward-sexp 1))
 637                  ((looking-at "#<") (search-forward ">" nil 'move))
 638                  ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 639                   (let* ((sym (intern-soft (match-string 1)))
 640                          (type (cond ((fboundp sym) 'help-function)
 641                                      ((or (memq sym '(t nil))
 642                                           (keywordp sym))
 643                                       nil)
 644                                      ((and sym
 645                                            (or (boundp sym)
 646                                                (get sym
 647                                                     'variable-documentation)))
 648                                       'help-variable))))
 649                     (when type (help-xref-button 1 type sym)))
 650                   (goto-char (match-end 1)))
 651                  (t (forward-char 1))))
 652             (error nil)))))))
 653
 654 \f
 655 ;; Additional functions for (re-)creating types of help buffers.
 656 (defun help-xref-interned (symbol)
 657   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 658 Both variable, function and face documentation are extracted into a single
 659 help buffer."
 660   (with-current-buffer (help-buffer)
 661     ;; Push the previous item on the stack before clobbering the output buffer.
 662     (help-setup-xref nil nil)
 663     (let ((facedoc (when (facep symbol)
 664                      ;; Don't record the current entry in the stack.
 665                      (setq help-xref-stack-item nil)
 666                      (describe-face symbol)))
 667           (fdoc (when (fboundp symbol)
 668                   ;; Don't record the current entry in the stack.
 669                   (setq help-xref-stack-item nil)
 670                   (describe-function symbol)))
 671           (sdoc (when (or (boundp symbol)
 672                           (get symbol 'variable-documentation))
 673                   ;; Don't record the current entry in the stack.
 674                   (setq help-xref-stack-item nil)
 675                   (describe-variable symbol))))
 676       (cond
 677        (sdoc
 678         ;; We now have a help buffer on the variable.
 679         ;; Insert the function and face text before it.
 680         (when (or fdoc facedoc)
 681           (goto-char (point-min))
 682           (let ((inhibit-read-only t))
 683             (when fdoc
 684               (insert fdoc "\n\n")
 685               (when facedoc
 686                 (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 687                         " is also a " "face." "\n\n")))
 688             (when facedoc
 689               (insert facedoc "\n\n"))
 690             (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 691                     " is also a " "variable." "\n\n"))
 692           ;; Don't record the `describe-variable' item in the stack.
 693           (setq help-xref-stack-item nil)
 694           (help-setup-xref (list #'help-xref-interned symbol) nil)))
 695        (fdoc
 696         ;; We now have a help buffer on the function.
 697         ;; Insert face text before it.
 698         (when facedoc
 699           (goto-char (point-max))
 700           (let ((inhibit-read-only t))
 701             (insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
 702                     " is also a " "face." "\n\n" facedoc))
 703           ;; Don't record the `describe-function' item in the stack.
 704           (setq help-xref-stack-item nil)
 705           (help-setup-xref (list #'help-xref-interned symbol) nil)))))))
 706
 707 \f
 708 ;; Navigation/hyperlinking with xrefs
 709
 710 (defun help-xref-go-back (buffer)
 711   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 712   (let (item position method args)
 713     (with-current-buffer buffer
 714       (push (cons (point) help-xref-stack-item) help-xref-forward-stack)
 715       (when help-xref-stack
 716         (setq item (pop help-xref-stack)
 717               ;; Clear the current item so that it won't get pushed
 718               ;; by the function we're about to call.  TODO: We could also
 719               ;; push it onto a "forward" stack and add a `forw' button.
 720               help-xref-stack-item nil
 721               position (car item)
 722               method (cadr item)
 723               args (cddr item))))
 724     (apply method args)
 725     (with-current-buffer buffer
 726       (if (get-buffer-window buffer)
 727           (set-window-point (get-buffer-window buffer) position)
 728         (goto-char position)))))
 729
 730 (defun help-xref-go-forward (buffer)
 731   "From BUFFER, go forward to next help buffer."
 732   (let (item position method args)
 733     (with-current-buffer buffer
 734       (push (cons (point) help-xref-stack-item) help-xref-stack)
 735       (when help-xref-forward-stack
 736         (setq item (pop help-xref-forward-stack)
 737               ;; Clear the current item so that it won't get pushed
 738               ;; by the function we're about to call.  TODO: We could also
 739               ;; push it onto a "forward" stack and add a `forw' button.
 740               help-xref-stack-item nil
 741               position (car item)
 742               method (cadr item)
 743               args (cddr item))))
 744     (apply method args)
 745     (with-current-buffer buffer
 746       (if (get-buffer-window buffer)
 747           (set-window-point (get-buffer-window buffer) position)
 748         (goto-char position)))))
 749
 750 (defun help-go-back ()
 751   "Go back to previous topic in this help buffer."
 752   (interactive)
 753   (if help-xref-stack
 754       (help-xref-go-back (current-buffer))
 755     (error "No previous help buffer")))
 756
 757 (defun help-go-forward ()
 758   "Go back to next topic in this help buffer."
 759   (interactive)
 760   (if help-xref-forward-stack
 761       (help-xref-go-forward (current-buffer))
 762     (error "No next help buffer")))
 763
 764 (defun help-do-xref (_pos function args)
 765   "Call the help cross-reference function FUNCTION with args ARGS.
 766 Things are set up properly so that the resulting help-buffer has
 767 a proper [back] button."
 768   ;; There is a reference at point.  Follow it.
 769   (let ((help-xref-following t))
 770     (apply function args)))
 771
 772 ;; The doc string is meant to explain what buttons do.
 773 (defun help-follow-mouse ()
 774   "Follow the cross-reference that you click on."
 775   (interactive)
 776   (error "No cross-reference here"))
 777
 778 ;; The doc string is meant to explain what buttons do.
 779 (defun help-follow ()
 780   "Follow cross-reference at point.
 781
 782 For the cross-reference format, see `help-make-xrefs'."
 783   (interactive)
 784   (error "No cross-reference here"))
 785
 786 (defun help-follow-symbol (&optional pos)
 787   "In help buffer, show docs for symbol at POS, defaulting to point.
 788 Show all docs for that symbol as either a variable, function or face."
 789   (interactive "d")
 790   (unless pos
 791     (setq pos (point)))
 792   ;; check if the symbol under point is a function, variable or face
 793   (let ((sym
 794          (intern
 795           (save-excursion
 796             (goto-char pos) (skip-syntax-backward "w_")
 797             (buffer-substring (point)
 798                               (progn (skip-syntax-forward "w_")
 799                                      (point)))))))
 800     (when (or (boundp sym)
 801               (get sym 'variable-documentation)
 802               (fboundp sym) (facep sym))
 803       (help-do-xref pos #'help-xref-interned (list sym)))))
 804
 805 (defun help-mode-revert-buffer (_ignore-auto noconfirm)
 806   (when (or noconfirm (yes-or-no-p "Revert help buffer? "))
 807     (let ((pos (point))
 808           (item help-xref-stack-item)
 809           ;; Pretend there is no current item to add to the history.
 810           (help-xref-stack-item nil)
 811           ;; Use the current buffer.
 812           (help-xref-following t))
 813       (apply (car item) (cdr item))
 814       (goto-char pos))))
 815
 816 (defun help-insert-string (string)
 817   "Insert STRING to the help buffer and install xref info for it.
 818 This function can be used to restore the old contents of the help buffer
 819 when going back to the previous topic in the xref stack.  It is needed
 820 in case when it is impossible to recompute the old contents of the
 821 help buffer by other means."
 822   (setq help-xref-stack-item (list #'help-insert-string string))
 823   (with-output-to-temp-buffer (help-buffer)
 824     (insert string)))
 825
 826 (provide 'help-mode)
 827
 828 ;;; help-mode.el ends here