lisp/help-macro.el

   1 ;;; help-macro.el --- makes command line help such as help-for-help
   2
   3 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Lynn Slater <lrs@indetech.com>
   7 ;; Maintainer: FSF
   8 ;; Created: Mon Oct  1 11:42:39 1990
   9 ;; Adapted-By: ESR
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This file supplies the macro make-help-screen which constructs
  30 ;; single character dispatching with browsable help such as that provided
  31 ;; by help-for-help. This can be used to make many modes easier to use; for
  32 ;; example, the GNU Emacs Empire Tool uses this for every "nested" mode map
  33 ;; called from the main mode map.
  34
  35 ;;       The name of this package was changed from help-screen.el to
  36 ;; help-macro.el in order to fit in a 14-character limit.
  37
  38 ;;-> ***********************  Example of use *********************************
  39
  40 ;;->(make-help-screen help-for-empire-redistribute-map
  41 ;;->              "c:civ m:mil p:population f:food ?"
  42 ;;->              "You have discovered the GEET redistribution commands
  43 ;;->   From here, you can use the following options:
  44 ;;->
  45 ;;->c   Redistribute civs from overfull sectors into connected underfull ones
  46 ;;->      The functions typically named by empire-ideal-civ-fcn control
  47 ;;->          based in part on empire-sector-civ-threshold
  48 ;;->m   Redistribute military using levels given by empire-ideal-mil-fcn
  49 ;;->p   Redistribute excess population to highways for max pop growth
  50 ;;->      Excess is any sector so full babies will not be born.
  51 ;;->f   Even out food on highways to highway min and leave levels
  52 ;;->      This is good to pump max food to all warehouses/dist pts
  53 ;;->
  54 ;;->
  55 ;;->Use \\[help-for-empire-redistribute-map] for help on redistribution.
  56 ;;->Use \\[help-for-empire-extract-map] for help on data extraction.
  57 ;;->Please use \\[describe-key] to find out more about any of the other keys."
  58 ;;->              empire-shell-redistribute-map)
  59
  60 ;;->  (define-key c-mp "\C-h" 'help-for-empire-redistribute-map)
  61 ;;->  (define-key c-mp help-character 'help-for-empire-redistribute-map)
  62
  63 ;;; Change Log:
  64 ;;
  65 ;; 22-Jan-1991          Lynn Slater x2048
  66 ;;    Last Modified: Mon Oct  1 11:43:52 1990 #3 (Lynn Slater)
  67 ;;    documented better
  68
  69 ;;; Code:
  70
  71 (require 'backquote)
  72
  73 ;;;###autoload
  74 (defcustom three-step-help nil
  75   "Non-nil means give more info about Help command in three steps.
  76 The three steps are simple prompt, prompt with all options, and
  77 window listing and describing the options.
  78 A value of nil means skip the middle step, so that \\[help-command] \\[help-command]
  79 gives the window that lists the options."
  80   :type 'boolean
  81   :group 'help)
  82
  83 (defmacro make-help-screen (fname help-line help-text helped-map)
  84   "Construct help-menu function name FNAME.
  85 When invoked, FNAME shows HELP-LINE and reads a command using HELPED-MAP.
  86 If the command is the help character, FNAME displays HELP-TEXT
  87 and continues trying to read a command using HELPED-MAP.
  88 If HELP-TEXT contains the sequence `%THIS-KEY%', that is replaced
  89 with the key sequence that invoked FNAME.
  90 When FNAME finally does get a command, it executes that command
  91 and then returns."
  92   (let ((doc-fn (intern (concat (symbol-name fname) "-doc"))))
  93     `(progn
  94        (defun ,doc-fn () ,help-text nil)
  95        (defun ,fname ()
  96          "Help command."
  97          (interactive)
  98          (let ((line-prompt
  99                 (substitute-command-keys ,help-line)))
 100            (when three-step-help
 101              (message "%s" line-prompt))
 102            (let* ((help-screen (documentation (quote ,doc-fn)))
 103                   ;; We bind overriding-local-map for very small
 104                   ;; sections, *excluding* where we switch buffers
 105                   ;; and where we execute the chosen help command.
 106                   (local-map (make-sparse-keymap))
 107                   (new-minor-mode-map-alist minor-mode-map-alist)
 108                   (prev-frame (selected-frame))
 109                   config new-frame key char)
 110              (when (string-match "%THIS-KEY%" help-screen)
 111                (setq help-screen
 112                      (replace-match (key-description
 113                                      (substring (this-command-keys) 0 -1))
 114                                     t t help-screen)))
 115              (unwind-protect
 116                  (let ((minor-mode-map-alist nil))
 117                    (setcdr local-map ,helped-map)
 118                    (define-key local-map [t] 'undefined)
 119                    ;; Make the scroll bar keep working normally.
 120                    (define-key local-map [vertical-scroll-bar]
 121                      (lookup-key global-map [vertical-scroll-bar]))
 122                    (if three-step-help
 123                        (progn
 124                          (setq key (let ((overriding-local-map local-map))
 125                                      (read-key-sequence nil)))
 126                          ;; Make the HELP key translate to C-h.
 127                          (if (lookup-key function-key-map key)
 128                              (setq key (lookup-key function-key-map key)))
 129                          (setq char (aref key 0)))
 130                      (setq char ??))
 131                    (when (or (eq char ??) (eq char help-char)
 132                              (memq char help-event-list))
 133                      (setq config (current-window-configuration))
 134                      (switch-to-buffer-other-window "*Help*")
 135                      (and (fboundp 'make-frame)
 136                           (not (eq (window-frame (selected-window))
 137                                    prev-frame))
 138                           (setq new-frame (window-frame (selected-window))
 139                                 config nil))
 140                      (setq buffer-read-only nil)
 141                      (let ((inhibit-read-only t))
 142                        (erase-buffer)
 143                        (insert help-screen))
 144                      (let ((minor-mode-map-alist new-minor-mode-map-alist))
 145                        (help-mode)
 146                        (setq new-minor-mode-map-alist minor-mode-map-alist))
 147                      (goto-char (point-min))
 148                      (while (or (memq char (append help-event-list
 149                                                    (cons help-char '(?? ?\C-v ?\s ?\177 delete backspace vertical-scroll-bar ?\M-v))))
 150                                 (eq (car-safe char) 'switch-frame)
 151                                 (equal key "\M-v"))
 152                        (condition-case nil
 153                            (cond
 154                             ((eq (car-safe char) 'switch-frame)
 155                              (handle-switch-frame char))
 156                             ((memq char '(?\C-v ?\s))
 157                              (scroll-up))
 158                             ((or (memq char '(?\177 ?\M-v delete backspace))
 159                                  (equal key "\M-v"))
 160                              (scroll-down)))
 161                          (error nil))
 162                        (let ((cursor-in-echo-area t)
 163                              (overriding-local-map local-map))
 164                          (setq key (read-key-sequence
 165                                     (format "Type one of the options listed%s: "
 166                                             (if (pos-visible-in-window-p
 167                                                  (point-max))
 168                                                 "" ", or SPACE or DEL to scroll")))
 169                                char (aref key 0)))
 170
 171                        ;; If this is a scroll bar command, just run it.
 172                        (when (eq char 'vertical-scroll-bar)
 173                          (command-execute (lookup-key local-map key) nil key))))
 174                    ;; We don't need the prompt any more.
 175                    (message "")
 176                    ;; Mouse clicks are not part of the help feature,
 177                    ;; so reexecute them in the standard environment.
 178                    (if (listp char)
 179                        (setq unread-command-events
 180                              (cons char unread-command-events)
 181                              config nil)
 182                      (let ((defn (lookup-key local-map key)))
 183                        (if defn
 184                            (progn
 185                              (when config
 186                                (set-window-configuration config)
 187                                (setq config nil))
 188                              ;; `defn' must make sure that its frame is
 189                              ;; selected, so we won't iconify it below.
 190                              (call-interactively defn)
 191                              (when new-frame
 192                                ;; Do not iconify the selected frame.
 193                                (unless (eq new-frame (selected-frame))
 194                                  (iconify-frame new-frame))
 195                                (setq new-frame nil)))
 196                          (ding)))))
 197                (when config
 198                  (set-window-configuration config))
 199                (when new-frame
 200                  (iconify-frame new-frame))
 201                (setq minor-mode-map-alist new-minor-mode-map-alist))))))))
 202
 203 (provide 'help-macro)
 204
 205 ;; arch-tag: 59fee949-1686-485a-8a05-83418073e257
 206 ;;; help-macro.el ends here