lisp/dirtrack.el

   1 ;;; dirtrack.el --- Directory Tracking by watching the prompt
   2
   3 ;; Copyright (C) 1996, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Peter Breton <pbreton@cs.umb.edu>
   7 ;; Created: Sun Nov 17 1996
   8 ;; Keywords: processes
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Shell directory tracking by watching the prompt.
  28 ;;
  29 ;; This is yet another attempt at a directory-tracking package for
  30 ;; Emacs shell-mode.  However, this package makes one strong assumption:
  31 ;; that you can customize your shell's prompt to contain the
  32 ;; current working directory.  Most shells do support this, including
  33 ;; almost every type of Bourne and C shell on Unix, the native shells on
  34 ;; Windows95 (COMMAND.COM) and Windows NT (CMD.EXE), and most 3rd party
  35 ;; Windows shells.  If you cannot do this, or do not wish to, this package
  36 ;; will be useless to you.
  37 ;;
  38 ;; Installation:
  39 ;;
  40 ;; 1) Set your shell's prompt to contain the current working directory.
  41 ;; You may need to consult your shell's documentation to find out how to
  42 ;; do this.
  43 ;;
  44 ;; Note that directory tracking is done by matching regular expressions,
  45 ;; therefore it is *VERY IMPORTANT* for your prompt to be easily
  46 ;; distinguishable from other output.  If your prompt regexp is too general,
  47 ;; you will see error messages from the dirtrack filter as it attempts to cd
  48 ;; to non-existent directories.
  49 ;;
  50 ;; 2) Set the variable `dirtrack-list' to an appropriate value.  This
  51 ;; should be a list of two elements: the first is a regular expression
  52 ;; which matches your prompt up to and including the pathname part.
  53 ;; The second is a number which tells which regular expression group to
  54 ;; match to extract only the pathname.  If you use a multi-line prompt,
  55 ;; add 't' as a third element.  Note that some of the functions in
  56 ;; 'comint.el' assume a single-line prompt (eg, comint-bol).
  57 ;;
  58 ;; Determining this information may take some experimentation.  Using
  59 ;; `dirtrack-debug-mode' may help; it causes the directory-tracking
  60 ;; filter to log messages to the buffer `dirtrack-debug-buffer'.
  61 ;;
  62 ;; 3) Activate `dirtrack-mode'.  You may wish to turn ordinary shell
  63 ;; tracking off by calling `shell-dirtrack-mode'.
  64 ;;
  65 ;; Examples:
  66 ;;
  67 ;; 1) On Windows NT, my prompt is set to emacs$S$P$G.
  68 ;; 'dirtrack-list' is set to (list "^emacs \\([a-zA-Z]:.*\\)>" 1)
  69 ;;
  70 ;; 2) On Solaris running bash, my prompt is set like this:
  71 ;;    PS1="\w\012emacs@\h(\!) [\t]% "
  72 ;;    'dirtrack-list' is set to (list "^\\([/~].*\\)\nemacs@[^%]+% *" 1 t)
  73 ;;
  74 ;; I'd appreciate other examples from people who use this package.
  75 ;;
  76 ;; Here's one from Stephen Eglen:
  77 ;;
  78 ;;   Running under tcsh:
  79 ;;   (setq-default dirtrack-list '("^%E \\([^ ]+\\)" 1))
  80 ;;
  81 ;;   It might be worth mentioning in your file that emacs sources start up
  82 ;;   files of the form: ~/.emacs_<SHELL> where <SHELL> is the name of the
  83 ;;   shell.  So for example, I have the following in ~/.emacs_tcsh:
  84 ;;
  85 ;;   set prompt = "%%E %~ %h% "
  86 ;;
  87 ;;   This produces a prompt of the form:
  88 ;;   %E /var/spool 10%
  89 ;;
  90 ;;   This saves me from having to use the %E prefix in other non-emacs
  91 ;;   shells.
  92 ;;
  93 ;; A final note:
  94 ;;
  95 ;;   I run LOTS of shell buffers through Emacs, sometimes as different users
  96 ;;   (eg, when logged in as myself, I'll run a root shell in the same Emacs).
  97 ;;   If you do this, and the shell prompt contains a ~, Emacs will interpret
  98 ;;   this relative to the user which owns the Emacs process, not the user
  99 ;;   who owns the shell buffer.  This may cause dirtrack to behave strangely
 100 ;;   (typically it reports that it is unable to cd to a directory
 101 ;;   with a ~ in it).
 102 ;;
 103 ;;   The same behavior can occur if you use dirtrack with remote filesystems
 104 ;;   (using telnet, rlogin, etc) as Emacs will be checking the local
 105 ;;   filesystem, not the remote one.  This problem is not specific to dirtrack,
 106 ;;   but also affects file completion, etc.
 107
 108 ;;; Code:
 109
 110 (eval-when-compile
 111   (require 'comint)
 112   (require 'shell))
 113
 114 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 115 ;; Customization Variables
 116 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 117
 118 (defgroup dirtrack nil
 119   "Directory tracking by watching the prompt."
 120   :prefix "dirtrack-"
 121   :group 'shell)
 122
 123 (defcustom dirtrack-list (list "^emacs \\([a-zA-Z]:.*\\)>" 1)
 124   "List for directory tracking.
 125 First item is a regexp that describes where to find the path in a prompt.
 126 Second is a number, the regexp group to match.  Optional third item is
 127 whether the prompt is multi-line.  If nil or omitted, prompt is assumed to
 128 be on a single line."
 129   :group 'dirtrack
 130   :type  '(sexp (regexp  :tag "Prompt Expression")
 131                 (integer :tag "Regexp Group")
 132                 (boolean :tag "Multiline Prompt")))
 133
 134 (make-variable-buffer-local 'dirtrack-list)
 135
 136 (defcustom dirtrack-debug nil
 137   "If non-nil, the function `dirtrack' will report debugging info."
 138   :group 'dirtrack
 139   :type  'boolean)
 140
 141 (defcustom dirtrack-debug-buffer "*Directory Tracking Log*"
 142   "Buffer in which to write directory tracking debug information."
 143   :group 'dirtrack
 144   :type  'string)
 145
 146 (defcustom dirtrackp t
 147   "If non-nil, directory tracking via `dirtrack' is enabled."
 148   :group 'dirtrack
 149   :type  'boolean)
 150
 151 (make-variable-buffer-local 'dirtrackp)
 152
 153 (defcustom dirtrack-directory-function
 154   (if (memq system-type (list 'ms-dos 'windows-nt 'cygwin))
 155       'dirtrack-windows-directory-function
 156     'file-name-as-directory)
 157   "Function to apply to the prompt directory for comparison purposes."
 158   :group 'dirtrack
 159   :type  'function)
 160
 161 (defcustom dirtrack-canonicalize-function
 162   (if (memq system-type (list 'ms-dos 'windows-nt 'cygwin))
 163       'downcase 'identity)
 164   "Function to apply to the default directory for comparison purposes."
 165   :group 'dirtrack
 166   :type  'function)
 167
 168 (defcustom dirtrack-directory-change-hook nil
 169   "Hook that is called when a directory change is made."
 170   :group 'dirtrack
 171   :type 'hook)
 172
 173
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175 ;; Functions
 176 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 177
 178
 179 (defun dirtrack-windows-directory-function (dir)
 180   "Return a canonical directory for comparison purposes.
 181 Such a directory is all lowercase, has forward-slashes as delimiters,
 182 and ends with a forward slash."
 183   (file-name-as-directory (downcase (subst-char-in-string ?\\ ?/ dir))))
 184
 185 (defun dirtrack-cygwin-directory-function (dir)
 186   "Return a canonical directory taken from a Cygwin path for comparison purposes."
 187   (if (string-match "/cygdrive/\\([A-Z]\\)\\(.*\\)" dir)
 188       (concat (match-string 1 dir) ":" (match-string 2 dir))
 189     dir))
 190
 191
 192 ;;;###autoload
 193 (define-minor-mode dirtrack-mode
 194   "Enable or disable Dirtrack directory tracking in a shell buffer.
 195 This method requires that your shell prompt contain the full
 196 current working directory at all times, and that `dirtrack-list'
 197 is set to match the prompt.  This is an alternative to
 198 `shell-dirtrack-mode', which works differently, by tracking `cd'
 199 and similar commands which change the shell working directory."
 200   nil nil nil
 201   (if dirtrack-mode
 202       (add-hook 'comint-preoutput-filter-functions 'dirtrack nil t)
 203     (remove-hook 'comint-preoutput-filter-functions 'dirtrack t)))
 204
 205 (define-obsolete-function-alias 'dirtrack-toggle 'dirtrack-mode "23.1")
 206 (define-obsolete-variable-alias 'dirtrackp 'dirtrack-mode "23.1")
 207
 208
 209 (define-minor-mode dirtrack-debug-mode
 210   "Enable or disable Dirtrack debugging."
 211   nil nil nil
 212   (if dirtrack-debug-mode
 213       (display-buffer (get-buffer-create dirtrack-debug-buffer))))
 214
 215 (define-obsolete-function-alias 'dirtrack-debug-toggle 'dirtrack-debug-mode
 216   "23.1")
 217 (define-obsolete-variable-alias 'dirtrack-debug 'dirtrack-debug-mode "23.1")
 218
 219
 220 (defun dirtrack-debug-message (string)
 221   "Insert string at the end of `dirtrack-debug-buffer'."
 222   (when dirtrack-debug-mode
 223     (with-current-buffer (get-buffer-create dirtrack-debug-buffer)
 224       (goto-char (point-max))
 225       (insert (concat string "\n")))))
 226
 227 ;;;###autoload
 228 (defun dirtrack (input)
 229   "Determine the current directory by scanning the process output for a prompt.
 230 The prompt to look for is the first item in `dirtrack-list'.
 231
 232 You can toggle directory tracking by using the function `dirtrack-mode'.
 233
 234 If directory tracking does not seem to be working, you can use the
 235 function `dirtrack-debug-mode' to turn on debugging output."
 236   (unless (or (null dirtrack-mode)
 237               (eq (point) (point-min)))     ; no output?
 238     (let (prompt-path
 239           (current-dir default-directory)
 240           (dirtrack-regexp    (nth 0 dirtrack-list))
 241           (match-num          (nth 1 dirtrack-list))
 242           ;; Currently unimplemented, it seems.  --Stef
 243           (multi-line         (nth 2 dirtrack-list)))
 244       (save-excursion
 245         ;; No match
 246         (if (not (string-match dirtrack-regexp input))
 247             (dirtrack-debug-message
 248              (format "Input `%s' failed to match `dirtrack-list'" input))
 249           (setq prompt-path (match-string match-num input))
 250           ;; Empty string
 251           (if (not (> (length prompt-path) 0))
 252               (dirtrack-debug-message "Match is empty string")
 253             ;; Transform prompts into canonical forms
 254             (setq prompt-path (funcall dirtrack-directory-function
 255                                        prompt-path)
 256                   current-dir (funcall dirtrack-canonicalize-function
 257                                        current-dir))
 258             (dirtrack-debug-message
 259              (format "Prompt is %s\nCurrent directory is %s"
 260                      prompt-path current-dir))
 261             ;; Compare them
 262             (if (or (string= current-dir prompt-path)
 263                     (string= current-dir (abbreviate-file-name prompt-path)))
 264                 (dirtrack-debug-message (format "Not changing directory"))
 265               ;; It's possible that Emacs will think the directory
 266               ;; won't exist (eg, rlogin buffers)
 267               (if (file-accessible-directory-p prompt-path)
 268                   ;; Change directory
 269                   (and (shell-process-cd prompt-path)
 270                        (run-hooks 'dirtrack-directory-change-hook)
 271                        (dirtrack-debug-message
 272                         (format "Changing directory to %s" prompt-path)))
 273                 (error "Directory %s does not exist" prompt-path)))
 274             )))))
 275   input)
 276
 277 (provide 'dirtrack)
 278
 279 ;; arch-tag: 168de071-be88-4937-aff6-2aba9f328d5a
 280 ;;; dirtrack.el ends here