lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el
   2
   3 ;; Copyright (C) 1988, 1994, 1997, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   7 ;; Maintainer: FSF
   8 ;; Keywords: processes, lisp
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;    This is a customization of comint-mode (see comint.el)
  28 ;;
  29 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  30 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  31 ;; 8/88
  32 ;;
  33 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  34 ;; merge them into the master source.
  35 ;;
  36 ;; The changelog is at the end of this file.
  37 ;;
  38 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  39 ;; interface that communicates process state back to the superior emacs by
  40 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  41 ;; lots and lots of special purpose code to read these control sequences, and
  42 ;; so is very tightly integrated with the cscheme process. The cscheme
  43 ;; interrupt handler and debugger read single character commands in cbreak
  44 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  45 ;; the single letter command keys to emacs functions that directly send the
  46 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  47 ;; functionality. If you are a cscheme user, you may prefer to use the
  48 ;; xscheme.el/cscheme -emacs interaction.
  49 ;;
  50 ;; Here's a summary of the pros and cons, as I see them.
  51 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  52 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  53 ;;           history only keeps the immediately prior input. Bizarre
  54 ;;           keybindings.
  55 ;;
  56 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  57 ;;            Carefully integrated functionality with the entire suite of
  58 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  59 ;;            Zwei and Hemlock. Good input history. A few commands not in
  60 ;;            xscheme.
  61 ;;
  62 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  63 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  64 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  65 ;; invited to port xscheme functionality on top of comint mode...
  66
  67 ;;; CHANGE LOG
  68 ;; ===========================================================================
  69 ;; 8/88 Olin
  70 ;; Created.
  71 ;;
  72 ;; 2/15/89 Olin
  73 ;; Removed -emacs flag from process invocation. It's only useful for
  74 ;; cscheme, and makes cscheme assume it's running under xscheme.el,
  75 ;; which messes things up royally. A bug.
  76 ;;
  77 ;; 5/22/90 Olin
  78 ;; - Upgraded to use comint-send-string and comint-send-region.
  79 ;; - run-scheme now offers to let you edit the command line if
  80 ;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  81 ;;   has been removed.
  82 ;; - Explicit references to process "scheme" have been replaced with
  83 ;;   (scheme-proc). This allows better handling of multiple process bufs.
  84 ;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  85 ;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  86 ;;   and friends, but interested hackers might find a useful application
  87 ;;   of this facility.
  88 ;;
  89 ;; 3/12/90 Olin
  90 ;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  91 ;;   Tale suggested this.
  92
  93 ;;; Code:
  94
  95 (require 'scheme)
  96 (require 'comint)
  97
  98
  99 (defgroup cmuscheme nil
 100   "Run a scheme process in a buffer."
 101   :group 'scheme)
 102
 103 ;;; INFERIOR SCHEME MODE STUFF
 104 ;;;============================================================================
 105
 106 (defcustom inferior-scheme-mode-hook nil
 107   "Hook for customizing inferior-scheme mode."
 108   :type 'hook
 109   :group 'cmuscheme)
 110
 111 (defvar inferior-scheme-mode-map
 112   (let ((m (make-sparse-keymap)))
 113     (define-key m "\M-\C-x" 'scheme-send-definition) ;gnu convention
 114     (define-key m "\C-x\C-e" 'scheme-send-last-sexp)
 115     (define-key m "\C-c\C-l" 'scheme-load-file)
 116     (define-key m "\C-c\C-k" 'scheme-compile-file)
 117     (scheme-mode-commands m)
 118     m))
 119
 120 ;; Install the process communication commands in the scheme-mode keymap.
 121 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 122 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 123 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 124 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 125 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 126 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 127 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 128 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 129 (define-key scheme-mode-map "\C-c\C-t" 'scheme-trace-procedure)
 130 (define-key scheme-mode-map "\C-c\C-x" 'scheme-expand-current-form)
 131 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 132 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 133 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 134
 135 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 136   (define-key map [separator-eval] '("--"))
 137   (define-key map [compile-file]
 138     '("Compile Scheme File" . scheme-compile-file))
 139   (define-key map [load-file]
 140     '("Load Scheme File" . scheme-load-file))
 141   (define-key map [switch]
 142     '("Switch to Scheme" . switch-to-scheme))
 143   (define-key map [com-def-go]
 144     '("Compile Definition & Go" . scheme-compile-definition-and-go))
 145   (define-key map [com-def]
 146     '("Compile Definition" . scheme-compile-definition))
 147   (define-key map [exp-form]
 148     '("Expand current form" . scheme-expand-current-form))
 149   (define-key map [trace-proc]
 150     '("Trace procedure" . scheme-trace-procedure))
 151   (define-key map [send-def-go]
 152     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 153   (define-key map [send-def]
 154     '("Evaluate Last Definition" . scheme-send-definition))
 155   (define-key map [send-region-go]
 156     '("Evaluate Region & Go" . scheme-send-region-and-go))
 157   (define-key map [send-region]
 158     '("Evaluate Region" . scheme-send-region))
 159   (define-key map [send-sexp]
 160     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 161   )
 162
 163 (defvar scheme-buffer)
 164
 165 (define-derived-mode inferior-scheme-mode comint-mode "Inferior Scheme"
 166   "Major mode for interacting with an inferior Scheme process.
 167
 168 The following commands are available:
 169 \\{inferior-scheme-mode-map}
 170
 171 A Scheme process can be fired up with M-x run-scheme.
 172
 173 Customization: Entry to this mode runs the hooks on comint-mode-hook and
 174 inferior-scheme-mode-hook (in that order).
 175
 176 You can send text to the inferior Scheme process from other buffers containing
 177 Scheme source.
 178     switch-to-scheme switches the current buffer to the Scheme process buffer.
 179     scheme-send-definition sends the current definition to the Scheme process.
 180     scheme-compile-definition compiles the current definition.
 181     scheme-send-region sends the current region to the Scheme process.
 182     scheme-compile-region compiles the current region.
 183
 184     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 185         scheme-send-region-and-go, and scheme-compile-region-and-go
 186         switch to the Scheme process buffer after sending their text.
 187 For information on running multiple processes in multiple buffers, see
 188 documentation for variable scheme-buffer.
 189
 190 Commands:
 191 Return after the end of the process' output sends the text from the
 192     end of process to point.
 193 Return before the end of the process' output copies the sexp ending at point
 194     to the end of the process' output, and sends it.
 195 Delete converts tabs to spaces as it moves back.
 196 Tab indents for Scheme; with argument, shifts rest
 197     of expression rigidly with the current line.
 198 C-M-q does Tab on each line starting within following expression.
 199 Paragraphs are separated only by blank lines.  Semicolons start comments.
 200 If you accidentally suspend your process, use \\[comint-continue-subjob]
 201 to continue it."
 202   ;; Customize in inferior-scheme-mode-hook
 203   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 204   (scheme-mode-variables)
 205   (setq mode-line-process '(":%s"))
 206   (setq comint-input-filter (function scheme-input-filter))
 207   (setq comint-get-old-input (function scheme-get-old-input)))
 208
 209 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 210   "Input matching this regexp are not saved on the history list.
 211 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 212   :type 'regexp
 213   :group 'cmuscheme)
 214
 215 (defun scheme-input-filter (str)
 216   "Don't save anything matching `inferior-scheme-filter-regexp'."
 217   (not (string-match inferior-scheme-filter-regexp str)))
 218
 219 (defun scheme-get-old-input ()
 220   "Snarf the sexp ending at point."
 221   (save-excursion
 222     (let ((end (point)))
 223       (backward-sexp)
 224       (buffer-substring (point) end))))
 225
 226 ;;;###autoload
 227 (defun run-scheme (cmd)
 228   "Run an inferior Scheme process, input and output via buffer `*scheme*'.
 229 If there is a process already running in `*scheme*', switch to that buffer.
 230 With argument, allows you to edit the command line (default is value
 231 of `scheme-program-name').
 232 If the file `~/.emacs_SCHEMENAME' or `~/.emacs.d/init_SCHEMENAME.scm' exists,
 233 it is given as initial input.
 234 Note that this may lose due to a timing error if the Scheme processor
 235 discards input when it starts up.
 236 Runs the hook `inferior-scheme-mode-hook' \(after the `comint-mode-hook'
 237 is run).
 238 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 239
 240   (interactive (list (if current-prefix-arg
 241                          (read-string "Run Scheme: " scheme-program-name)
 242                          scheme-program-name)))
 243   (if (not (comint-check-proc "*scheme*"))
 244       (let ((cmdlist (split-string-and-unquote cmd)))
 245         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 246                            (scheme-start-file (car cmdlist)) (cdr cmdlist)))
 247         (inferior-scheme-mode)))
 248   (setq scheme-program-name cmd)
 249   (setq scheme-buffer "*scheme*")
 250   (pop-to-buffer "*scheme*"))
 251 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 252
 253 (defun scheme-start-file (prog)
 254   "Return the name of the start file corresponding to PROG.
 255 Search in the directories \"~\" and \"~/.emacs.d\", in this
 256 order.  Return nil if no start file found."
 257   (let* ((progname (file-name-nondirectory prog))
 258          (start-file (concat "~/.emacs_" progname))
 259          (alt-start-file (concat user-emacs-directory "init_" progname ".scm")))
 260     (if (file-exists-p start-file)
 261         start-file
 262       (and (file-exists-p alt-start-file) alt-start-file))))
 263
 264 (defun scheme-send-region (start end)
 265   "Send the current region to the inferior Scheme process."
 266   (interactive "r")
 267   (comint-send-region (scheme-proc) start end)
 268   (comint-send-string (scheme-proc) "\n"))
 269
 270 (defun scheme-send-definition ()
 271   "Send the current definition to the inferior Scheme process."
 272   (interactive)
 273   (save-excursion
 274    (end-of-defun)
 275    (let ((end (point)))
 276      (beginning-of-defun)
 277      (scheme-send-region (point) end))))
 278
 279 (defun scheme-send-last-sexp ()
 280   "Send the previous sexp to the inferior Scheme process."
 281   (interactive)
 282   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 283
 284 (defcustom scheme-compile-exp-command "(compile '%s)"
 285   "Template for issuing commands to compile arbitrary Scheme expressions."
 286   :type 'string
 287   :group 'cmuscheme)
 288
 289 (defun scheme-compile-region (start end)
 290   "Compile the current region in the inferior Scheme process.
 291 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 292   (interactive "r")
 293   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 294                                             (format "(begin %s)"
 295                                                     (buffer-substring start end))))
 296   (comint-send-string (scheme-proc) "\n"))
 297
 298 (defun scheme-compile-definition ()
 299   "Compile the current definition in the inferior Scheme process."
 300   (interactive)
 301   (save-excursion
 302    (end-of-defun)
 303    (let ((end (point)))
 304      (beginning-of-defun)
 305      (scheme-compile-region (point) end))))
 306
 307 (defcustom scheme-trace-command "(trace %s)"
 308   "Template for issuing commands to trace a Scheme procedure.
 309 Some Scheme implementations might require more elaborate commands here.
 310 For PLT-Scheme, e.g., one should use
 311
 312    (setq scheme-trace-command \"(begin (require (lib \\\"trace.ss\\\")) (trace %s))\")
 313
 314 For Scheme 48 and Scsh use \",trace %s\"."
 315   :type 'string
 316   :group 'cmuscheme)
 317
 318 (defcustom scheme-untrace-command "(untrace %s)"
 319   "Template for switching off tracing of a Scheme procedure.
 320 Scheme 48 and Scsh users should set this variable to \",untrace %s\"."
 321
 322   :type 'string
 323   :group 'cmuscheme)
 324
 325 (defun scheme-trace-procedure (proc &optional untrace)
 326   "Trace procedure PROC in the inferior Scheme process.
 327 With a prefix argument switch off tracing of procedure PROC."
 328   (interactive
 329    (list (let ((current (symbol-at-point))
 330                (action (if current-prefix-arg "Untrace" "Trace")))
 331            (if current
 332                (read-string (format "%s procedure [%s]: " action current) nil nil (symbol-name current))
 333              (read-string (format "%s procedure: " action))))
 334          current-prefix-arg))
 335   (when (= (length proc) 0)
 336     (error "Invalid procedure name"))
 337   (comint-send-string (scheme-proc)
 338                       (format
 339                        (if untrace scheme-untrace-command scheme-trace-command)
 340                        proc))
 341   (comint-send-string (scheme-proc) "\n"))
 342
 343 (defcustom scheme-macro-expand-command "(expand %s)"
 344   "Template for macro-expanding a Scheme form.
 345 For Scheme 48 and Scsh use \",expand %s\"."
 346   :type 'string
 347   :group 'cmuscheme)
 348
 349 (defun scheme-expand-current-form ()
 350   "Macro-expand the form at point in the inferior Scheme process."
 351   (interactive)
 352   (let ((current-form (scheme-form-at-point)))
 353     (if current-form
 354         (progn
 355           (comint-send-string (scheme-proc)
 356                               (format
 357                                scheme-macro-expand-command
 358                                current-form))
 359           (comint-send-string (scheme-proc) "\n"))
 360       (error "Not at a form"))))
 361
 362 (defun scheme-form-at-point ()
 363   (let ((next-sexp (thing-at-point 'sexp)))
 364     (if (and next-sexp (string-equal (substring next-sexp 0 1) "("))
 365         next-sexp
 366       (save-excursion
 367         (backward-up-list)
 368         (scheme-form-at-point)))))
 369
 370 (defun switch-to-scheme (eob-p)
 371   "Switch to the scheme process buffer.
 372 With argument, position cursor at end of buffer."
 373   (interactive "P")
 374   (if (or (and scheme-buffer (get-buffer scheme-buffer))
 375           (scheme-interactively-start-process))
 376       (pop-to-buffer scheme-buffer)
 377     (error "No current process buffer.  See variable `scheme-buffer'"))
 378   (when eob-p
 379     (push-mark)
 380     (goto-char (point-max))))
 381
 382 (defun scheme-send-region-and-go (start end)
 383   "Send the current region to the inferior Scheme process.
 384 Then switch to the process buffer."
 385   (interactive "r")
 386   (scheme-send-region start end)
 387   (switch-to-scheme t))
 388
 389 (defun scheme-send-definition-and-go ()
 390   "Send the current definition to the inferior Scheme.
 391 Then switch to the process buffer."
 392   (interactive)
 393   (scheme-send-definition)
 394   (switch-to-scheme t))
 395
 396 (defun scheme-compile-definition-and-go ()
 397   "Compile the current definition in the inferior Scheme.
 398 Then switch to the process buffer."
 399   (interactive)
 400   (scheme-compile-definition)
 401   (switch-to-scheme t))
 402
 403 (defun scheme-compile-region-and-go (start end)
 404   "Compile the current region in the inferior Scheme.
 405 Then switch to the process buffer."
 406   (interactive "r")
 407   (scheme-compile-region start end)
 408   (switch-to-scheme t))
 409
 410 (defcustom scheme-source-modes '(scheme-mode)
 411   "Used to determine if a buffer contains Scheme source code.
 412 If it's loaded into a buffer that is in one of these major modes, it's
 413 considered a scheme source file by `scheme-load-file' and `scheme-compile-file'.
 414 Used by these commands to determine defaults."
 415   :type '(repeat function)
 416   :group 'cmuscheme)
 417
 418 (defvar scheme-prev-l/c-dir/file nil
 419   "Caches the last (directory . file) pair.
 420 Caches the last pair used in the last `scheme-load-file' or
 421 `scheme-compile-file' command.  Used for determining the default
 422 in the next one.")
 423
 424 (defun scheme-load-file (file-name)
 425   "Load a Scheme file FILE-NAME into the inferior Scheme process."
 426   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 427                                   scheme-source-modes t)) ; t because `load'
 428                                                           ; needs an exact name
 429   (comint-check-source file-name) ; Check to see if buffer needs saved.
 430   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 431                                        (file-name-nondirectory file-name)))
 432   (comint-send-string (scheme-proc) (concat "(load \""
 433                                             file-name
 434                                             "\"\)\n")))
 435
 436 (defun scheme-compile-file (file-name)
 437   "Compile a Scheme file FILE-NAME in the inferior Scheme process."
 438   (interactive (comint-get-source "Compile Scheme file: "
 439                                   scheme-prev-l/c-dir/file
 440                                   scheme-source-modes
 441                                   nil)) ; nil because COMPILE doesn't
 442                                         ; need an exact name.
 443   (comint-check-source file-name) ; Check to see if buffer needs saved.
 444   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 445                                        (file-name-nondirectory file-name)))
 446   (comint-send-string (scheme-proc) (concat "(compile-file \""
 447                                             file-name
 448                                             "\"\)\n")))
 449
 450 \f
 451 (defvar scheme-buffer nil "*The current scheme process buffer.
 452
 453 MULTIPLE PROCESS SUPPORT
 454 ===========================================================================
 455 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 456 processes.  To run multiple Scheme processes, you start the first up with
 457 \\[run-scheme].  It will be in a buffer named *scheme*.  Rename this buffer
 458 with \\[rename-buffer].  You may now start up a new process with another
 459 \\[run-scheme].  It will be in a new buffer, named *scheme*.  You can
 460 switch between the different process buffers with \\[switch-to-buffer].
 461
 462 Commands that send text from source buffers to Scheme processes --
 463 like `scheme-send-definition' or `scheme-compile-region' -- have to choose a
 464 process to send to, when you have more than one Scheme process around.  This
 465 is determined by the global variable `scheme-buffer'.  Suppose you
 466 have three inferior Schemes running:
 467     Buffer      Process
 468     foo         scheme
 469     bar         scheme<2>
 470     *scheme*    scheme<3>
 471 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 472 code, what process do you send it to?
 473
 474 - If you're in a process buffer (foo, bar, or *scheme*),
 475   you send it to that process.
 476 - If you're in some other buffer (e.g., a source file), you
 477   send it to the process attached to buffer `scheme-buffer'.
 478 This process selection is performed by function `scheme-proc'.
 479
 480 Whenever \\[run-scheme] fires up a new process, it resets `scheme-buffer'
 481 to be the new process's buffer.  If you only run one process, this will
 482 do the right thing.  If you run multiple processes, you can change
 483 `scheme-buffer' to another process buffer with \\[set-variable].
 484
 485 More sophisticated approaches are, of course, possible.  If you find yourself
 486 needing to switch back and forth between multiple processes frequently,
 487 you may wish to consider ilisp.el, a larger, more sophisticated package
 488 for running inferior Lisp and Scheme processes.  The approach taken here is
 489 for a minimal, simple implementation.  Feel free to extend it.")
 490
 491 (defun scheme-proc ()
 492   "Return the current Scheme process, starting one if necessary.
 493 See variable `scheme-buffer'."
 494   (unless (and scheme-buffer
 495                (get-buffer scheme-buffer)
 496                (comint-check-proc scheme-buffer))
 497     (scheme-interactively-start-process))
 498   (or (scheme-get-process)
 499       (error "No current process.  See variable `scheme-buffer'")))
 500
 501 (defun scheme-get-process ()
 502   "Return the current Scheme process or nil if none is running."
 503   (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 504                           (current-buffer)
 505                         scheme-buffer)))
 506
 507 (defun scheme-interactively-start-process (&optional cmd)
 508   "Start an inferior Scheme process.  Return the process started.
 509 Since this command is run implicitly, always ask the user for the
 510 command to run."
 511   (save-window-excursion
 512     (run-scheme (read-string "Run Scheme: " scheme-program-name))))
 513
 514 ;;; Do the user's customization...
 515
 516 (defcustom cmuscheme-load-hook nil
 517   "This hook is run when cmuscheme is loaded in.
 518 This is a good place to put keybindings."
 519   :type 'hook
 520   :group 'cmuscheme)
 521
 522 (run-hooks 'cmuscheme-load-hook)
 523
 524 (provide 'cmuscheme)
 525
 526 ;; arch-tag: e8795f4a-c496-45a2-97b4-8e0f2a2c57d2
 527 ;;; cmuscheme.el ends here