lisp/scroll-bar.el

   1 ;;; scroll-bar.el --- window system-independent scroll bar support.
   2
   3 ;; Copyright (C) 1993, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: hardware
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Window-system-independent bindings of mouse clicks on the scroll bar.
  28 ;; Presently emulates the scroll-bar behavior of xterm.
  29
  30 ;;; Code:
  31
  32 (require 'mouse)
  33
  34 \f
  35 ;;;; Utilities.
  36
  37 (defun scroll-bar-event-ratio (event)
  38   "Given a scroll bar event EVENT, return the scroll bar position as a ratio.
  39 The value is a cons cell (PORTION . WHOLE) containing two integers
  40 whose ratio gives the event's vertical position in the scroll bar, with 0
  41 referring to the top and 1 to the bottom."
  42   (nth 2 event))
  43
  44 (defun scroll-bar-scale (num-denom whole)
  45   "Given a pair (NUM . DENOM) and WHOLE, return (/ (* NUM WHOLE) DENOM).
  46 This is handy for scaling a position on a scroll bar into real units,
  47 like buffer positions.  If SCROLL-BAR-POS is the (PORTION . WHOLE) pair
  48 from a scroll bar event, then (scroll-bar-scale SCROLL-BAR-POS
  49 \(buffer-size)) is the position in the current buffer corresponding to
  50 that scroll bar position."
  51   ;; We multiply before we divide to maintain precision.
  52   ;; We use floating point because the product of a large buffer size
  53   ;; with a large scroll bar portion can easily overflow a lisp int.
  54   (truncate (/ (* (float (car num-denom)) whole) (cdr num-denom))))
  55
  56 \f
  57 ;;;; Helpful functions for enabling and disabling scroll bars.
  58
  59 (defvar scroll-bar-mode)
  60
  61 (defvar scroll-bar-mode-explicit nil
  62   "Non-nil means `set-scroll-bar-mode' should really do something.
  63 This is nil while loading `scroll-bar.el', and t afterward.")
  64
  65 (defun set-scroll-bar-mode-1 (ignore value)
  66   (set-scroll-bar-mode value))
  67
  68 (defun set-scroll-bar-mode (value)
  69   "Set `scroll-bar-mode' to VALUE and put the new value into effect."
  70   (setq scroll-bar-mode value)
  71
  72   (when scroll-bar-mode-explicit
  73     ;; Apply it to default-frame-alist.
  74     (let ((parameter (assq 'vertical-scroll-bars default-frame-alist)))
  75       (if (consp parameter)
  76           (setcdr parameter scroll-bar-mode)
  77         (setq default-frame-alist
  78               (cons (cons 'vertical-scroll-bars scroll-bar-mode)
  79                     default-frame-alist))))
  80
  81     ;; Apply it to existing frames.
  82     (let ((frames (frame-list)))
  83       (while frames
  84         (modify-frame-parameters
  85          (car frames)
  86          (list (cons 'vertical-scroll-bars scroll-bar-mode)))
  87         (setq frames (cdr frames))))))
  88
  89 (defcustom scroll-bar-mode
  90   (if (eq system-type 'windows-nt) 'right 'left)
  91   "*Specify whether to have vertical scroll bars, and on which side.
  92 Possible values are nil (no scroll bars), `left' (scroll bars on left)
  93 and `right' (scroll bars on right).
  94 To set this variable in a Lisp program, use `set-scroll-bar-mode'
  95 to make it take real effect.
  96 Setting the variable with a customization buffer also takes effect."
  97   :type '(choice (const :tag "none (nil)")
  98                  (const left)
  99                  (const right))
 100   :group 'frames
 101   :set 'set-scroll-bar-mode-1)
 102
 103 ;; We just set scroll-bar-mode, but that was the default.
 104 ;; If it is set again, that is for real.
 105 (setq scroll-bar-mode-explicit t)
 106
 107 (defun scroll-bar-mode (flag)
 108   "Toggle display of vertical scroll bars on all frames.
 109 This command applies to all frames that exist and frames to be
 110 created in the future.
 111 With a numeric argument, if the argument is negative,
 112 turn off scroll bars; otherwise, turn on scroll bars."
 113   (interactive "P")
 114   (if flag (setq flag (prefix-numeric-value flag)))
 115
 116   ;; Tweedle the variable according to the argument.
 117   (set-scroll-bar-mode (if (null flag) (not scroll-bar-mode)
 118                          (and (or (not (numberp flag)) (>= flag 0))
 119                               (if (eq system-type 'windows-nt) 'right 'left)))))
 120
 121 (defun toggle-scroll-bar (arg)
 122   "Toggle whether or not the selected frame has vertical scroll bars.
 123 With arg, turn vertical scroll bars on if and only if arg is positive.
 124 The variable `scroll-bar-mode' controls which side the scroll bars are on
 125 when they are turned on; if it is nil, they go on the left."
 126   (interactive "P")
 127   (if (null arg)
 128       (setq arg
 129             (if (cdr (assq 'vertical-scroll-bars
 130                            (frame-parameters (selected-frame))))
 131                 -1 1))
 132     (setq arg (prefix-numeric-value arg)))
 133   (modify-frame-parameters
 134    (selected-frame)
 135    (list (cons 'vertical-scroll-bars
 136                (if (> arg 0)
 137                    (or scroll-bar-mode
 138                        (if (eq system-type 'windows-nt) 'right 'left)))))))
 139
 140 (defun toggle-horizontal-scroll-bar (arg)
 141   "Toggle whether or not the selected frame has horizontal scroll bars.
 142 With arg, turn horizontal scroll bars on if and only if arg is positive.
 143 Horizontal scroll bars aren't implemented yet."
 144   (interactive "P")
 145   (error "Horizontal scroll bars aren't implemented yet"))
 146 \f
 147 ;;;; Buffer navigation using the scroll bar.
 148
 149 ;;; This was used for up-events on button 2, but no longer.
 150 (defun scroll-bar-set-window-start (event)
 151   "Set the window start according to where the scroll bar is dragged.
 152 EVENT should be a scroll bar click or drag event."
 153   (interactive "e")
 154   (let* ((end-position (event-end event))
 155          (window (nth 0 end-position))
 156          (portion-whole (nth 2 end-position)))
 157     (save-excursion
 158       (set-buffer (window-buffer window))
 159       (save-excursion
 160         (goto-char (+ (point-min)
 161                       (scroll-bar-scale portion-whole
 162                                         (- (point-max) (point-min)))))
 163         (beginning-of-line)
 164         (set-window-start window (point))))))
 165
 166 (defun scroll-bar-drag-position (portion-whole)
 167   "Calculate new window start for drag event."
 168   (save-excursion
 169     (goto-char (+ (point-min)
 170                   (scroll-bar-scale portion-whole
 171                                     (- (point-max) (point-min)))))
 172     (beginning-of-line)
 173     (point)))
 174
 175 (defun scroll-bar-maybe-set-window-start (event)
 176   "Set the window start according to where the scroll bar is dragged.
 177 Only change window start if the new start is substantially different.
 178 EVENT should be a scroll bar click or drag event."
 179   (interactive "e")
 180   (let* ((end-position (event-end event))
 181          (window (nth 0 end-position))
 182          (portion-whole (nth 2 end-position))
 183          (next-portion-whole (cons (1+ (car portion-whole))
 184                                    (cdr portion-whole)))
 185          portion-start
 186          next-portion-start
 187          (current-start (window-start window)))
 188     (save-excursion
 189       (set-buffer (window-buffer window))
 190       (setq portion-start (scroll-bar-drag-position portion-whole))
 191       (setq next-portion-start (max
 192                                 (scroll-bar-drag-position next-portion-whole)
 193                                 (1+ portion-start)))
 194       (if (or (>= current-start next-portion-start)
 195               (< current-start portion-start))
 196           (set-window-start window portion-start)
 197         ;; Always set window start, to ensure scroll bar position is updated.
 198         (set-window-start window current-start)))))
 199
 200 ;; Scroll the window to the proper position for EVENT.
 201 (defun scroll-bar-drag-1 (event)
 202   (let* ((start-position (event-start event))
 203          (window (nth 0 start-position))
 204          (portion-whole (nth 2 start-position)))
 205     (save-excursion
 206       (set-buffer (window-buffer window))
 207       ;; Calculate position relative to the accessible part of the buffer.
 208       (goto-char (+ (point-min)
 209                     (scroll-bar-scale portion-whole
 210                                       (- (point-max) (point-min)))))
 211       (beginning-of-line)
 212       (set-window-start window (point)))))
 213
 214 (defun scroll-bar-drag (event)
 215   "Scroll the window by dragging the scroll bar slider.
 216 If you click outside the slider, the window scrolls to bring the slider there."
 217   (interactive "e")
 218   (let* (done
 219          (echo-keystrokes 0)
 220          (end-position (event-end event))
 221          (window (nth 0 end-position))
 222          (before-scroll))
 223     (with-current-buffer (window-buffer window)
 224       (setq before-scroll point-before-scroll))
 225     (save-selected-window
 226       (select-window window)
 227       (setq before-scroll
 228             (or before-scroll (point))))
 229     (scroll-bar-drag-1 event)
 230     (track-mouse
 231       (while (not done)
 232         (setq event (read-event))
 233         (if (eq (car-safe event) 'mouse-movement)
 234             (setq event (read-event)))
 235         (cond ((eq (car-safe event) 'scroll-bar-movement)
 236                (scroll-bar-drag-1 event))
 237               (t
 238                ;; Exit when we get the drag event; ignore that event.
 239                (setq done t)))))
 240     (sit-for 0)
 241     (with-current-buffer (window-buffer window)
 242       (setq point-before-scroll before-scroll))))
 243
 244 (defun scroll-bar-scroll-down (event)
 245   "Scroll the window's top line down to the location of the scroll bar click.
 246 EVENT should be a scroll bar click."
 247   (interactive "e")
 248   (let* ((end-position (event-end event))
 249          (window (nth 0 end-position))
 250          (before-scroll))
 251     (with-current-buffer (window-buffer window)
 252       (setq before-scroll point-before-scroll))
 253     (unwind-protect
 254         (save-selected-window
 255           (let ((portion-whole (nth 2 end-position)))
 256             (select-window window)
 257             (setq before-scroll
 258                   (or before-scroll (point)))
 259             (scroll-down
 260              (scroll-bar-scale portion-whole (1- (window-height)))))
 261           (sit-for 0))
 262       (with-current-buffer (window-buffer window)
 263         (setq point-before-scroll before-scroll)))))
 264
 265 (defun scroll-bar-scroll-up (event)
 266   "Scroll the line next to the scroll bar click to the top of the window.
 267 EVENT should be a scroll bar click."
 268   (interactive "e")
 269   (let* ((end-position (event-end event))
 270          (window (nth 0 end-position))
 271          (before-scroll))
 272     (with-current-buffer (window-buffer window)
 273       (setq before-scroll point-before-scroll))
 274     (unwind-protect
 275         (save-selected-window
 276           (let ((portion-whole (nth 2 end-position)))
 277             (select-window window)
 278             (setq before-scroll
 279                   (or before-scroll (point)))
 280             (scroll-up
 281              (scroll-bar-scale portion-whole (1- (window-height)))))
 282           (sit-for 0))
 283       (with-current-buffer (window-buffer window)
 284         (setq point-before-scroll before-scroll)))))
 285
 286 \f
 287 ;;; Tookit scroll bars.
 288
 289 (defun scroll-bar-toolkit-scroll (event)
 290   (interactive "e")
 291   (let* ((end-position (event-end event))
 292          (window (nth 0 end-position))
 293          (part (nth 4 end-position))
 294          before-scroll)
 295     (cond ((eq part 'end-scroll))
 296           (t
 297            (with-current-buffer (window-buffer window)
 298              (setq before-scroll point-before-scroll))
 299            (save-selected-window
 300              (select-window window)
 301              (setq before-scroll (or before-scroll (point)))
 302              (cond ((eq part 'above-handle)
 303                     (scroll-up '-))
 304                    ((eq part 'below-handle)
 305                     (scroll-up nil))
 306                    ((eq part 'ratio)
 307                     (let* ((portion-whole (nth 2 end-position))
 308                            (lines (scroll-bar-scale portion-whole
 309                                                     (1- (window-height)))))
 310                       (scroll-up (cond ((not (zerop lines)) lines)
 311                                        ((< (car portion-whole) 0) -1)
 312                                        (t 1)))))
 313                    ((eq part 'up)
 314                     (scroll-up -1))
 315                    ((eq part 'down)
 316                     (scroll-up 1))
 317                    ((eq part 'top)
 318                     (set-window-start window (point-min)))
 319                    ((eq part 'bottom)
 320                     (goto-char (point-max))
 321                     (recenter))
 322                    ((eq part 'handle)
 323                     (scroll-bar-drag-1 event))))
 324            (sit-for 0)
 325            (with-current-buffer (window-buffer window)
 326              (setq point-before-scroll before-scroll))))))
 327
 328
 329 \f
 330 ;;;; Bindings.
 331
 332 ;;; For now, we'll set things up to work like xterm.
 333 (cond (x-toolkit-scroll-bars-p
 334        (global-set-key [vertical-scroll-bar mouse-1]
 335                        'scroll-bar-toolkit-scroll))
 336       (t
 337        (global-set-key [vertical-scroll-bar mouse-1]
 338                        'scroll-bar-scroll-up)
 339        (global-set-key [vertical-scroll-bar drag-mouse-1]
 340                        'scroll-bar-scroll-up)
 341        (global-set-key [vertical-scroll-bar down-mouse-2]
 342                        'scroll-bar-drag)
 343        (global-set-key [vertical-scroll-bar mouse-3]
 344                        'scroll-bar-scroll-down)
 345        (global-set-key [vertical-scroll-bar drag-mouse-3]
 346                        'scroll-bar-scroll-down)))
 347
 348 \f
 349 (provide 'scroll-bar)
 350
 351 ;;; scroll-bar.el ends here