lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1994-1996, 2001-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: faces, i18n, Unicode, multilingual
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Describe-Text Mode.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'quail))
  31 (require 'help-mode)
  32
  33 ;;; Describe-Text Utilities.
  34
  35 (defun describe-text-widget (widget)
  36   "Insert text to describe WIDGET in the current buffer."
  37   (insert-text-button
  38    (symbol-name (if (symbolp widget) widget (car widget)))
  39    'action (lambda (&rest _ignore) (widget-browse widget))
  40    'help-echo "mouse-2, RET: browse this widget")
  41   (insert " ")
  42   (insert-text-button
  43    "(widget)Top" 'type 'help-info 'help-args '("(widget)Top")))
  44
  45 (defun describe-text-sexp (sexp)
  46   "Insert a short description of SEXP in the current buffer."
  47   (let ((pp (condition-case signal
  48                 (pp-to-string sexp)
  49               (error (prin1-to-string signal)))))
  50     (when (string-match-p "\n\\'" pp)
  51       (setq pp (substring pp 0 (1- (length pp)))))
  52
  53     (if (and (not (string-match-p "\n" pp))
  54              (<= (length pp) (- (window-width) (current-column))))
  55         (insert pp)
  56       (insert-text-button
  57        "[Show]" 'action (lambda (&rest _ignore)
  58                           (with-output-to-temp-buffer
  59                               "*Pp Eval Output*"
  60                             (princ pp)))
  61        'help-echo "mouse-2, RET: pretty print value in another buffer"))))
  62
  63 (defun describe-property-list (properties)
  64   "Insert a description of PROPERTIES in the current buffer.
  65 PROPERTIES should be a list of overlay or text properties.
  66 The `category', `face' and `font-lock-face' properties are made
  67 into help buttons that call `describe-text-category' or
  68 `describe-face' when pushed."
  69   ;; Sort the properties by the size of their value.
  70   (dolist (elt (sort (let (ret)
  71                        (while properties
  72                          (push (list (pop properties) (pop properties)) ret))
  73                        ret)
  74                      (lambda (a b) (string< (prin1-to-string (nth 0 a) t)
  75                                             (prin1-to-string (nth 0 b) t)))))
  76     (let ((key (nth 0 elt))
  77           (value (nth 1 elt)))
  78       (insert (propertize (format "  %-20s " key)
  79                           'face 'help-argument-name))
  80       (cond ((eq key 'category)
  81              (insert-text-button
  82               (symbol-name value)
  83               'action (lambda (&rest _ignore)
  84                         (describe-text-category value))
  85               'follow-link t
  86               'help-echo "mouse-2, RET: describe this category"))
  87             ((memq key '(face font-lock-face mouse-face))
  88              (insert-text-button
  89               (format "%S" value)
  90               'type 'help-face 'help-args (list value)))
  91             ((widgetp value)
  92              (describe-text-widget value))
  93             (t
  94              (describe-text-sexp value))))
  95     (insert "\n")))
  96 \f
  97 ;;; Describe-Text Commands.
  98
  99 (defun describe-text-category (category)
 100   "Describe a text property category."
 101   (interactive "SCategory: ")
 102   (help-setup-xref (list #'describe-text-category category)
 103                    (called-interactively-p 'interactive))
 104   (with-help-window (help-buffer)
 105     (with-current-buffer standard-output
 106       (insert "Category " (format "%S" category) ":\n\n")
 107       (describe-property-list (symbol-plist category))
 108       (goto-char (point-min)))))
 109
 110 ;;;###autoload
 111 (defun describe-text-properties (pos &optional output-buffer buffer)
 112   "Describe widgets, buttons, overlays, and text properties at POS.
 113 POS is taken to be in BUFFER or in current buffer if nil.
 114 Interactively, describe them for the character after point.
 115 If optional second argument OUTPUT-BUFFER is non-nil,
 116 insert the output into that buffer, and don't initialize or clear it
 117 otherwise."
 118   (interactive "d")
 119   (let ((src-buf (current-buffer)))
 120     (if buffer (set-buffer buffer) (setq buffer (current-buffer)))
 121   (if (>= pos (point-max))
 122       (error "No character follows specified position"))
 123   (if output-buffer
 124       (describe-text-properties-1 pos output-buffer)
 125     (if (not (or (text-properties-at pos) (overlays-at pos)))
 126         (message "This is plain text.")
 127         (with-temp-buffer
 128             (setq output-buffer (current-buffer))
 129             (insert "Text content at position " (format "%d" pos) ":\n\n")
 130           (set-buffer buffer)
 131           (describe-text-properties-1 pos output-buffer)
 132           (set-buffer src-buf)
 133           (help-setup-xref (list 'describe-text-properties pos nil buffer)
 134                            (called-interactively-p 'interactive))
 135           (with-help-window (help-buffer)
 136             (with-current-buffer standard-output
 137               (buffer-swap-text output-buffer)
 138               (goto-char (point-min)))))))))
 139
 140 (defun describe-text-properties-1 (pos output-buffer)
 141   (let* ((properties (text-properties-at pos))
 142          (overlays (overlays-in pos (1+ pos)))
 143          (wid-field (get-char-property pos 'field))
 144          (wid-button (get-char-property pos 'button))
 145          (wid-doc (get-char-property pos 'widget-doc))
 146          ;; If button.el is not loaded, we have no buttons in the text.
 147          (button (and (fboundp 'button-at) (button-at pos)))
 148          (button-type (and button (button-type button)))
 149          (button-label (and button (button-label button)))
 150          (widget (or wid-field wid-button wid-doc)))
 151     (with-current-buffer output-buffer
 152       ;; Widgets
 153       (when (widgetp widget)
 154         (newline)
 155         (insert (cond (wid-field "This is an editable text area")
 156                       (wid-button "This is an active area")
 157                       (wid-doc "This is documentation text")))
 158         (insert " of a ")
 159         (describe-text-widget widget)
 160         (insert ".\n\n"))
 161       ;; Buttons
 162       (when (and button (not (widgetp wid-button)))
 163         (newline)
 164         (insert "Here is a `" (format "%S" button-type)
 165                 "' button labeled `" button-label "'.\n\n"))
 166       ;; Overlays
 167       (when overlays
 168         (newline)
 169         (if (eq (length overlays) 1)
 170             (insert "There is an overlay here:\n")
 171           (insert "There are " (format "%d" (length overlays))
 172                          " overlays here:\n"))
 173         (dolist (overlay overlays)
 174           (insert " From " (format "%d" (overlay-start overlay))
 175                          " to " (format "%d" (overlay-end overlay)) "\n")
 176           (describe-property-list (overlay-properties overlay)))
 177         (insert "\n"))
 178       ;; Text properties
 179       (when properties
 180         (newline)
 181         (insert "There are text properties here:\n")
 182         (describe-property-list properties)))))
 183 \f
 184 (defcustom describe-char-unidata-list
 185   '(name old-name general-category decomposition)
 186   "List of Unicode-based character property names shown by `describe-char'."
 187   :group 'mule
 188   :version "23.1"
 189   :type '(choice (const :tag "All properties" t)
 190           (set
 191            (const :tag "Unicode name" name)
 192            (const :tag "Unicode old name" old-name)
 193            (const :tag "Unicode general category " general-category)
 194            (const :tag "Unicode canonical combining class"
 195                   canonical-combining-class)
 196            (const :tag "Unicode bidi class" bidi-class)
 197            (const :tag "Unicode decomposition mapping" decomposition)
 198            (const :tag "Unicode decimal digit value" decimal-digit-value)
 199            (const :tag "Unicode digit value" digit-value)
 200            (const :tag "Unicode numeric value" numeric-value)
 201            (const :tag "Unicode mirrored" mirrored)
 202            (const :tag "Unicode ISO 10646 comment" iso-10646-comment)
 203            (const :tag "Unicode simple uppercase mapping" uppercase)
 204            (const :tag "Unicode simple lowercase mapping" lowercase)
 205            (const :tag "Unicode simple titlecase mapping" titlecase))))
 206
 207 (defcustom describe-char-unicodedata-file nil
 208   "Location of Unicode data file.
 209 This is the UnicodeData.txt file from the Unicode Consortium, used for
 210 diagnostics.  If it is non-nil `describe-char' will print data
 211 looked up from it.  This facility is mostly of use to people doing
 212 multilingual development.
 213
 214 This is a fairly large file, not typically present on GNU systems.
 215 At the time of writing it is at the URL
 216 `http://www.unicode.org/Public/UNIDATA/UnicodeData.txt'."
 217   :group 'mule
 218   :version "22.1"
 219   :type '(choice (const :tag "None" nil)
 220                  file))
 221
 222 (defun describe-char-unicode-data (char)
 223   "Return a list of Unicode data for Unicode CHAR.
 224 Each element is a list of a property description and the property value.
 225 The list is null if CHAR isn't found in `describe-char-unicodedata-file'.
 226 This function is semi-obsolete.  Use `get-char-code-property'."
 227   (when describe-char-unicodedata-file
 228     (unless (file-exists-p describe-char-unicodedata-file)
 229       (error "`unicodedata-file' %s not found" describe-char-unicodedata-file))
 230     (with-current-buffer (get-buffer-create " *Unicode Data*")
 231       (when (zerop (buffer-size))
 232         ;; Don't use -literally in case of DOS line endings.
 233         (insert-file-contents describe-char-unicodedata-file))
 234       (goto-char (point-min))
 235       (let ((hex (format "%04X" char))
 236             found first last)
 237         (if (re-search-forward (concat "^" hex) nil t)
 238             (setq found t)
 239           ;; It's not listed explicitly.  Look for ranges, e.g. CJK
 240           ;; ideographs, and check whether it's in one of them.
 241           (while (and (re-search-forward "^\\([^;]+\\);[^;]+First>;" nil t)
 242                       (>= char (setq first
 243                                      (string-to-number (match-string 1) 16)))
 244                       (progn
 245                         (forward-line 1)
 246                         (looking-at "^\\([^;]+\\);[^;]+Last>;")
 247                         (> char
 248                            (setq last
 249                                  (string-to-number (match-string 1) 16))))))
 250           (if (and (>= char first)
 251                    (<= char last))
 252               (setq found t)))
 253         (if found
 254             (let ((fields (mapcar (lambda (elt)
 255                                     (if (> (length elt) 0)
 256                                         elt))
 257                                   (cdr (split-string
 258                                         (buffer-substring
 259                                          (line-beginning-position)
 260                                          (line-end-position))
 261                                         ";")))))
 262               ;; The length depends on whether the last field was empty.
 263               (unless (or (= 13 (length fields))
 264                           (= 14 (length fields)))
 265                 (error "Invalid contents in %s" describe-char-unicodedata-file))
 266               ;; The field names and values lists are slightly
 267               ;; modified from Mule-UCS unidata.el.
 268               (list
 269                (list "Name" (let ((name (nth 0 fields)))
 270                               ;; Check for <..., First>, <..., Last>
 271                               (if (string-match "\\`\\(<[^,]+\\)," name)
 272                                   (concat (match-string 1 name) ">")
 273                                 name)))
 274                (list "Category"
 275                      (let ((val (nth 1 fields)))
 276                        (or (char-code-property-description
 277                             'general-category (intern val))
 278                            val)))
 279                (list "Combining class"
 280                      (let ((val (nth 1 fields)))
 281                        (or (char-code-property-description
 282                             'canonical-combining-class (intern val))
 283                            val)))
 284                (list "Bidi category"
 285                      (let ((val (nth 1 fields)))
 286                        (or (char-code-property-description
 287                             'bidi-class (intern val))
 288                            val)))
 289                (list
 290                 "Decomposition"
 291                 (if (nth 4 fields)
 292                     (let* ((parts (split-string (nth 4 fields)))
 293                            (info (car parts)))
 294                       (if (string-match "\\`<\\(.+\\)>\\'" info)
 295                           (setq info (match-string 1 info))
 296                         (setq info nil))
 297                       (if info (setq parts (cdr parts)))
 298                       (setq parts (mapconcat
 299                                    (lambda (arg)
 300                                      (string (string-to-number arg 16)))
 301                                    parts " "))
 302                       (concat info (if info " ") parts))))
 303                (list "Decimal digit value"
 304                      (nth 5 fields))
 305                (list "Digit value"
 306                      (nth 6 fields))
 307                (list "Numeric value"
 308                      (nth 7 fields))
 309                (list "Mirrored"
 310                      (if (equal "Y" (nth 8 fields))
 311                          "yes"))
 312                (list "Old name" (nth 9 fields))
 313                (list "ISO 10646 comment" (nth 10 fields))
 314                (list "Uppercase" (and (nth 11 fields)
 315                                       (string (string-to-number
 316                                                (nth 11 fields) 16))))
 317                (list "Lowercase" (and (nth 12 fields)
 318                                       (string (string-to-number
 319                                                (nth 12 fields) 16))))
 320                (list "Titlecase" (and (nth 13 fields)
 321                                       (string (string-to-number
 322                                                (nth 13 fields) 16)))))))))))
 323
 324 ;; Not defined on builds without X, but behind display-graphic-p.
 325 (declare-function internal-char-font "fontset.c" (position &optional ch))
 326
 327 ;; Return information about how CHAR is displayed at the buffer
 328 ;; position POS.  If the selected frame is on a graphic display,
 329 ;; return a string "FONT-DRIVER:FONT-NAME (GLYPH-CODE)" where:
 330 ;;   FONT-DRIVER is the font-driver name,
 331 ;;   FONT-NAME is the font name,
 332 ;;   GLYPH-CODE is a hexadigit string representing the glyph-ID.
 333 ;; Otherwise, return a string describing the terminal codes for the
 334 ;; character.
 335 (defun describe-char-display (pos char)
 336   (if (display-graphic-p (selected-frame))
 337       (let ((char-font-info (internal-char-font pos char)))
 338         (if char-font-info
 339             (let ((type (font-get (car char-font-info) :type))
 340                   (name (font-xlfd-name (car char-font-info)))
 341                   (code (cdr char-font-info)))
 342                (if (integerp code)
 343                    (format "%s:%s (#x%02X)" type name code)
 344                  (format "%s:%s (#x%04X%04X)"
 345                          type name (car code) (cdr code))))))
 346     (let* ((charset (get-text-property pos 'charset))
 347            (coding (or (terminal-coding-system) 'us-ascii))
 348            (encoded (encode-coding-char char coding charset)))
 349       (if encoded
 350           (encoded-string-description encoded coding)))))
 351
 352 \f
 353 ;; Return a string of CH with composition for padding on both sides.
 354 ;; It is displayed without overlapping with the left/right columns.
 355 (defsubst describe-char-padded-string (ch)
 356   (if (and (display-multi-font-p)
 357            (internal-char-font nil ch))
 358       (compose-string (string ch) 0 1 (format "\t%c\t" ch))
 359     (string ch)))
 360
 361 ;; Return a nicely formatted list of categories; extended category
 362 ;; description is added to the category name as a tooltip
 363 (defsubst describe-char-categories (category-set)
 364   (let ((mnemonics (category-set-mnemonics category-set)))
 365     (unless (eq mnemonics "")
 366       (list (mapconcat
 367              (lambda (x)
 368                (let* ((c (category-docstring x))
 369                       (doc (if (string-match "\\`\\(.*?\\)\n" c)
 370                                (propertize (match-string 1 c)
 371                                            'help-echo
 372                                            (substring c (1+ (match-end 1))))
 373                              c)))
 374                  (format "%c:%s" x doc)))
 375              mnemonics ", ")))))
 376
 377 (declare-function quail-find-key "quail" (char))
 378
 379 ;;;###autoload
 380 (defun describe-char (pos &optional buffer)
 381   "Describe position POS (interactively, point) and the char after POS.
 382 POS is taken to be in BUFFER, or the current buffer if BUFFER is nil.
 383 The information is displayed in buffer `*Help*'.
 384
 385 The position information includes POS; the total size of BUFFER; the
 386 region limits, if narrowed; the column number; and the horizontal
 387 scroll amount, if the buffer is horizontally scrolled.
 388
 389 The character information includes the character code; charset and
 390 code points in it; syntax; category; how the character is encoded in
 391 BUFFER and in BUFFER's file; character composition information (if
 392 relevant); the font and font glyphs used to display the character;
 393 the character's canonical name and other properties defined by the
 394 Unicode Data Base; and widgets, buttons, overlays, and text properties
 395 relevant to POS."
 396   (interactive "d")
 397   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 398   (let ((src-buf (current-buffer)))
 399     (set-buffer buffer)
 400     (if (>= pos (point-max))
 401         (error "No character follows specified position"))
 402     (let* ((char (char-after pos))
 403            (eight-bit-p (and (not enable-multibyte-characters) (>= char 128)))
 404            (charset (if eight-bit-p 'eight-bit
 405                       (or (get-text-property pos 'charset)
 406                           (char-charset char))))
 407            (composition (find-composition pos nil nil t))
 408            (component-chars nil)
 409            (display-table (or (window-display-table)
 410                               buffer-display-table
 411                               standard-display-table))
 412            (disp-vector (and display-table (aref display-table char)))
 413            (multibyte-p enable-multibyte-characters)
 414            (overlays (mapcar (lambda (o) (overlay-properties o))
 415                              (overlays-at pos)))
 416            (char-description (if (not multibyte-p)
 417                                  (single-key-description char)
 418                                (if (< char 128)
 419                                    (single-key-description char)
 420                                  (string-to-multibyte
 421                                   (char-to-string char)))))
 422            (text-props-desc
 423             (let ((tmp-buf (generate-new-buffer " *text-props*")))
 424               (unwind-protect
 425                   (progn
 426                     (describe-text-properties pos tmp-buf)
 427                     (with-current-buffer tmp-buf (buffer-string)))
 428                 (kill-buffer tmp-buf))))
 429            item-list max-width code)
 430
 431       (if multibyte-p
 432           (or (setq code (encode-char char charset))
 433               (setq charset (char-charset char)
 434                     code (encode-char char charset)))
 435         (setq code char))
 436       (cond
 437        ;; Append a PDF character to left-to-right directional
 438        ;; embeddings and overrides, to prevent potential messup of the
 439        ;; following text.
 440        ((memq char '(?\x202a ?\x202d))
 441         (setq char-description
 442               (concat char-description
 443                       (propertize (string ?\x202c) 'invisible t))))
 444        ;; Append a PDF character followed by LRM to right-to-left
 445        ;; directional embeddings and overrides, to prevent potential
 446        ;; messup of the following numerical text.
 447        ((memq char '(?\x202b ?\x202e))
 448         (setq char-description
 449               (concat char-description
 450                       (propertize (string ?\x202c ?\x200e) 'invisible t))))
 451        ;; Append a PDI character to directional isolate initiators, to
 452        ;; prevent potential messup of the following numerical text
 453        ((memq char '(?\x2066 ?\x2067 ?\x2068))
 454         (setq char-description
 455               (concat char-description
 456                       (propertize (string ?\x2069) 'invisible t))))
 457        ;; Append a LRM character to any strong character to avoid
 458        ;; messing up the numerical codepoint.
 459        ((memq (get-char-code-property char 'bidi-class) '(R AL))
 460         (setq char-description
 461               (concat char-description
 462                       (propertize (string ?\x200e) 'invisible t)))))
 463       (when composition
 464         ;; When the composition is trivial (i.e. composed only with the
 465         ;; current character itself without any alternate characters),
 466         ;; we don't show the composition information.  Otherwise, store
 467         ;; two descriptive strings in the first two elements of
 468         ;; COMPOSITION.
 469         (or (catch 'tag
 470               (let ((from (car composition))
 471                     (to (nth 1 composition))
 472                     (components (nth 2 composition))
 473                     ch)
 474                 (if (and (vectorp components) (vectorp (aref components 0)))
 475                     (let ((idx (- pos from))
 476                           (nglyphs (lgstring-glyph-len components))
 477                           (i 0) j glyph glyph-from)
 478                       ;; COMPONENTS is a gstring.  Find a grapheme
 479                       ;; cluster containing the current character.
 480                       (while (and (< i nglyphs)
 481                                   (setq glyph (lgstring-glyph components i))
 482                                   (< (lglyph-to glyph) idx))
 483                         (setq i (1+ i)))
 484                       (if (or (not glyph) (= i nglyphs))
 485                           ;; The composition is broken.
 486                           (throw 'tag nil))
 487                       (setq glyph-from (lglyph-from glyph)
 488                             to (+ from (lglyph-to glyph) 1)
 489                             from (+ from glyph-from)
 490                             j i)
 491                       (while (and (< j nglyphs)
 492                                   (setq glyph (lgstring-glyph components j))
 493                                   (= (lglyph-from glyph) glyph-from))
 494                         (setq j (1+ j)))
 495                       (if (and (= to (1+ from))
 496                                (= i (1- j))
 497                                (setq glyph (lgstring-glyph components i))
 498                                (= char (lglyph-char glyph)))
 499                           ;; The composition is trivial.
 500                           (throw 'tag nil))
 501                       (nconc composition (list i (1- j))))
 502                   (dotimes (i (length components))
 503                     (if (integerp (setq ch (aref components i)))
 504                         (push (cons ch (describe-char-display pos ch))
 505                               component-chars)))
 506                   (setq component-chars (nreverse component-chars)))
 507                 (if (< from pos)
 508                     (if (< (1+ pos) to)
 509                         (setcar composition
 510                                 (concat
 511                                  " with the surrounding characters \""
 512                                  (mapconcat 'describe-char-padded-string
 513                                             (buffer-substring from pos) "")
 514                                  "\" and \""
 515                                  (mapconcat 'describe-char-padded-string
 516                                             (buffer-substring (1+ pos) to) "")
 517                                  "\""))
 518                       (setcar composition
 519                               (concat
 520                                " with the preceding character(s) \""
 521                                (mapconcat 'describe-char-padded-string
 522                                           (buffer-substring from pos) "")
 523                                "\"")))
 524                   (if (< (1+ pos) to)
 525                       (setcar composition
 526                               (concat
 527                                " with the following character(s) \""
 528                                (mapconcat 'describe-char-padded-string
 529                                           (buffer-substring (1+ pos) to) "")
 530                                "\""))
 531                     (setcar composition nil)))
 532                 (setcar (cdr composition)
 533                         (format "composed to form \"%s\" (see below)"
 534                                 (buffer-substring from to)))))
 535             (setq composition nil)))
 536
 537       (setq item-list
 538             `(("position"
 539                ,(let* ((beg      (point-min))
 540                        (end      (point-max))
 541                        (total    (buffer-size))
 542                        (percent  (if (> total 50000) ; Avoid overflow multiplying by 100
 543                                      (/ (+ (/ total 200) (1- pos))  (max (/ total 100) 1))
 544                                    (/ (+ (/ total 2) (* 100 (1- pos)))  (max total 1))))
 545                        (hscroll  (if (= (window-hscroll) 0)
 546                                      ""
 547                                    (format ", Hscroll: %d" (window-hscroll))))
 548                        (col      (current-column)))
 549                   (if (or (/= beg 1)  (/= end (1+ total)))
 550                       (format "%d of %d (%d%%), restriction: <%d-%d>, column: %d%s"
 551                               pos total percent beg end col hscroll)
 552                     (if (= pos end)
 553                         (format "%d of %d (EOB), column: %d%s" pos total col hscroll)
 554                       (format "%d of %d (%d%%), column: %d%s"
 555                               pos total percent col hscroll)))))
 556               ("character"
 557                ,(format "%s (displayed as %s) (codepoint %d, #o%o, #x%x)"
 558                         char-description
 559                         (apply 'propertize char-description
 560                                (text-properties-at pos))
 561                         char char char))
 562               ("preferred charset"
 563                ,`(insert-text-button
 564                   ,(symbol-name charset)
 565                   'type 'help-character-set 'help-args '(,charset))
 566                ,(format "(%s)" (charset-description charset)))
 567               ("code point in charset"
 568                ,(let ((str (if (integerp code)
 569                                (format (if (< code 256) "0x%02X" "0x%04X")
 570                                        code)
 571                              (format "0x%04X%04X" (car code) (cdr code)))))
 572                   (if (<= (charset-dimension charset) 2)
 573                       `(insert-text-button
 574                         ,str
 575                         'action (lambda (&rest ignore)
 576                                   (list-charset-chars ',charset)
 577                                   (with-selected-window
 578                                       (get-buffer-window "*Character List*" 0)
 579                                     (goto-char (point-min))
 580                                     (forward-line 2) ;Skip the header.
 581                                     (let ((case-fold-search nil))
 582                                       (if (search-forward
 583                                            ,(char-to-string char) nil t)
 584                                           (goto-char (match-beginning 0))))))
 585                         'follow-link t
 586                         'help-echo
 587                         "mouse-2, RET: show this character in its character set")
 588                     str)))
 589               ,@(let ((script (aref char-script-table char)))
 590                   (if script
 591                       (list (list "script" (symbol-name script)))))
 592               ("syntax"
 593                ,(let ((syntax (syntax-after pos)))
 594                   (with-temp-buffer
 595                     (internal-describe-syntax-value syntax)
 596                     (buffer-string))))
 597               ("category"
 598                ,@(if (not eight-bit-p)
 599                      (let ((category-set (char-category-set char)))
 600                        (if category-set
 601                            (describe-char-categories category-set)
 602                          '("-- none --")))))
 603               ("to input"
 604                ,@(if (not eight-bit-p)
 605                      (let ((key-list (and (eq input-method-function
 606                                               'quail-input-method)
 607                                           (quail-find-key char))))
 608                        (if (consp key-list)
 609                            (list "type"
 610                                  (concat "\""
 611                                          (mapconcat 'identity
 612                                                     key-list "\" or \"")
 613                                          "\"")
 614                                  "with"
 615                                  `(insert-text-button
 616                                    ,current-input-method
 617                                    'type 'help-input-method
 618                                    'help-args '(,current-input-method))
 619                                  "input method")
 620                          (list
 621                           "type \"C-x 8 RET HEX-CODEPOINT\" or \"C-x 8 RET NAME\"")))))
 622               ("buffer code"
 623                ,(if multibyte-p
 624                     (encoded-string-description
 625                      (string-as-unibyte (char-to-string char)) nil)
 626                   (format "#x%02X" char)))
 627               ("file code"
 628                ,@(if multibyte-p
 629                      (let* ((coding buffer-file-coding-system)
 630                             (encoded (encode-coding-char char coding charset)))
 631                        (if encoded
 632                            (list (encoded-string-description encoded coding)
 633                                  (format "(encoded by coding system %S)"
 634                                          coding))
 635                          (list "not encodable by coding system"
 636                                (symbol-name coding))))
 637                    (list (format "#x%02X" char))))
 638               ("display"
 639                ,(cond
 640                  (disp-vector
 641                   (setq disp-vector (copy-sequence disp-vector))
 642                   (dotimes (i (length disp-vector))
 643                     (aset disp-vector i
 644                           (cons (aref disp-vector i)
 645                                 (describe-char-display
 646                                  pos (glyph-char (aref disp-vector i))))))
 647                   (format "by display table entry [%s] (see below)"
 648                           (mapconcat
 649                            (lambda (x)
 650                              (format "?%c" (glyph-char (car x))))
 651                            disp-vector " ")))
 652                  (composition
 653                   (cadr composition))
 654                  (t
 655                   (let ((display (describe-char-display pos char)))
 656                     (if (display-graphic-p (selected-frame))
 657                         (if display
 658                             (concat "by this font (glyph code)\n    " display)
 659                           "no font available")
 660                       (if display
 661                           (format "terminal code %s" display)
 662                         "not encodable for terminal"))))))
 663               ,@(let ((face
 664                        (if (not (or disp-vector composition))
 665                            (cond
 666                             ((and show-trailing-whitespace
 667                                   (save-excursion (goto-char pos)
 668                                                   (looking-at-p "[ \t]+$")))
 669                              'trailing-whitespace)
 670                             ((and nobreak-char-display char (eq char '#xa0))
 671                              'nobreak-space)
 672                             ((and nobreak-char-display char
 673                                   (memq char '(#xad #x2010 #x2011)))
 674                              'escape-glyph)
 675                             ((and (< char 32) (not (memq char '(9 10))))
 676                              'escape-glyph)))))
 677                   (if face (list (list "hardcoded face"
 678                                        `(insert-text-button ;FIXME: Wrap in lambda!
 679                                          ,(symbol-name face)
 680                                          'type 'help-face
 681                                          'help-args '(,face))))))
 682               ,@(if (not eight-bit-p)
 683                     (let ((unicodedata (describe-char-unicode-data char)))
 684                       (if unicodedata
 685                           (cons (list "Unicode data" "") unicodedata))))))
 686       (setq max-width (apply 'max (mapcar (lambda (x)
 687                                             (if (cadr x) (length (car x)) 0))
 688                                           item-list)))
 689       (set-buffer src-buf)
 690       (help-setup-xref (list 'describe-char pos buffer)
 691                        (called-interactively-p 'interactive))
 692       (with-help-window (help-buffer)
 693         (with-current-buffer standard-output
 694           (set-buffer-multibyte multibyte-p)
 695           (let ((formatter (format "%%%ds:" max-width)))
 696             (dolist (elt item-list)
 697               (when (cadr elt)
 698                 (insert (format formatter (car elt)))
 699                 (dolist (clm (cdr elt))
 700                   (cond ((eq (car-safe clm) 'insert-text-button)
 701                          (insert " ")
 702                          (eval clm))
 703                         ((not (zerop (length clm)))
 704                          (insert " " clm))))
 705                 (insert "\n"))))
 706
 707           (when overlays
 708             (save-excursion
 709               (goto-char (point-min))
 710               (re-search-forward "(displayed as ")
 711               (let ((end (+ (point) (length char-description))))
 712                 (mapc (lambda (props)
 713                         (let ((o (make-overlay (point) end)))
 714                           (while props
 715                             (overlay-put o (car props) (nth 1 props))
 716                             (setq props (cddr props)))))
 717                       overlays))))
 718
 719           (when disp-vector
 720             (insert
 721              "\nThe display table entry is displayed by ")
 722             (if (display-graphic-p (selected-frame))
 723                 (progn
 724                   (insert "these fonts (glyph codes):\n")
 725                   (dotimes (i (length disp-vector))
 726                     (insert (glyph-char (car (aref disp-vector i))) ?:
 727                             (propertize " " 'display '(space :align-to 5))
 728                             (or (cdr (aref disp-vector i)) "-- no font --")
 729                             "\n")
 730                     (let ((face (glyph-face (car (aref disp-vector i)))))
 731                       (when face
 732                         (insert (propertize " " 'display '(space :align-to 5))
 733                                 "face: ")
 734                         (insert (concat "`" (symbol-name face) "'"))
 735                         (insert "\n")))))
 736               (insert "these terminal codes:\n")
 737               (dotimes (i (length disp-vector))
 738                 (insert (car (aref disp-vector i))
 739                         (propertize " " 'display '(space :align-to 5))
 740                         (or (cdr (aref disp-vector i)) "-- not encodable --")
 741                         "\n"))))
 742
 743           (when composition
 744             (insert "\nComposed")
 745             (if (car composition)
 746                 (insert (car composition)))
 747             (if (and (vectorp (nth 2 composition))
 748                      (vectorp (aref (nth 2 composition) 0)))
 749                 (let* ((gstring (nth 2 composition))
 750                        (font (lgstring-font gstring))
 751                        (from (nth 3 composition))
 752                        (to (nth 4 composition))
 753                        glyph)
 754                   (if (fontp font)
 755                       (progn
 756                         (insert " using this font:\n  "
 757                                 (symbol-name (font-get font :type))
 758                                 ?:
 759                                 (aref (query-font font) 0)
 760                                 "\nby these glyphs:\n")
 761                         (while (and (<= from to)
 762                                     (setq glyph (lgstring-glyph gstring from)))
 763                           (insert (format "  %S\n" glyph))
 764                           (setq from (1+ from))))
 765                     (insert " by these characters:\n")
 766                     (while (and (<= from to)
 767                                 (setq glyph (lgstring-glyph gstring from)))
 768                       (insert (format " %c (#x%x)\n"
 769                                       (lglyph-char glyph) (lglyph-char glyph)))
 770                       (setq from (1+ from)))))
 771               (insert " by the rule:\n\t(")
 772               (let ((first t))
 773                 (mapc (lambda (x)
 774                         (if first (setq first nil)
 775                           (insert " "))
 776                         (if (consp x) (insert (format "%S" x))
 777                           (if (= x ?\t) (insert (single-key-description x))
 778                             (insert ??)
 779                             (insert (describe-char-padded-string x)))))
 780                       (nth 2 composition)))
 781               (insert  ")\nThe component character(s) are displayed by ")
 782               (if (display-graphic-p (selected-frame))
 783                   (progn
 784                     (insert "these fonts (glyph codes):")
 785                     (dolist (elt component-chars)
 786                       (if (/= (car elt) ?\t)
 787                           (insert "\n "
 788                                   (describe-char-padded-string (car elt))
 789                                   ?:
 790                                   (propertize " "
 791                                               'display '(space :align-to 5))
 792                                   (or (cdr elt) "-- no font --")))))
 793                 (insert "these terminal codes:")
 794                 (dolist (elt component-chars)
 795                   (insert "\n  " (car elt) ":"
 796                           (propertize " " 'display '(space :align-to 4))
 797                           (or (cdr elt) "-- not encodable --"))))
 798               (insert "\nSee the variable `reference-point-alist' for "
 799                       "the meaning of the rule.\n")))
 800
 801           (unless eight-bit-p
 802             (insert (if (not describe-char-unidata-list)
 803                         "\nCharacter code properties are not shown: "
 804                       "\nCharacter code properties: "))
 805             (insert-text-button
 806              "customize what to show"
 807              'action (lambda (&rest _ignore)
 808                        (customize-variable
 809                         'describe-char-unidata-list))
 810              'follow-link t)
 811             (insert "\n")
 812             (dolist (elt (if (eq describe-char-unidata-list t)
 813                              (nreverse (mapcar 'car char-code-property-alist))
 814                            describe-char-unidata-list))
 815               (let ((val (get-char-code-property char elt))
 816                     description)
 817                 (when val
 818                   (setq description (char-code-property-description elt val))
 819                   (insert (if description
 820                               (format "  %s: %s (%s)\n" elt val description)
 821                             (format "  %s: %s\n" elt val)))))))
 822
 823           (if text-props-desc (insert text-props-desc))
 824           (setq buffer-read-only t))))))
 825
 826 (define-obsolete-function-alias 'describe-char-after 'describe-char "22.1")
 827
 828 ;;; Describe-Char-ElDoc
 829
 830 (defun describe-char-eldoc--truncate (name width)
 831   "Truncate NAME at white spaces such that it is no longer than WIDTH.
 832
 833 Split NAME on white space character and return string with as
 834 many leading words of NAME as possible without exceeding WIDTH
 835 characters.  If NAME consists of white space characters only,
 836 return an empty string.  Three dots (\"...\") are appended to
 837 returned string if some of the words from NAME have been omitted.
 838
 839 NB: Function may return string longer than WIDTH if name consists
 840 of a single word, or it's first word is longer than WIDTH
 841 characters."
 842   (let ((words (split-string name)))
 843     (if words
 844         (let ((last words))
 845           (setq width (- width (length (car words))))
 846           (while (and (cdr last)
 847                       (<= (+ (length (cadr last)) (if (cddr last) 4 1)) width))
 848             (setq last (cdr last))
 849             (setq width (- width (length (car last)) 1)))
 850           (let ((ellipsis (and (cdr last) "...")))
 851             (setcdr last nil)
 852             (concat (mapconcat 'identity words " ") ellipsis)))
 853       "")))
 854
 855 (defun describe-char-eldoc--format (ch &optional width)
 856   "Format a description for character CH which is no more than WIDTH characters.
 857
 858 Full description message has a \"U+HEX: NAME (GC: GENERAL-CATEGORY)\"
 859 format where:
 860 - HEX is a hexadecimal codepoint of the character (zero-padded to at
 861   least four digits),
 862 - NAME is name of the character.
 863 - GC is a two-letter abbreviation of the general-category of the
 864   character, and
 865 - GENERAL-CATEGORY is full name of the general-category of the
 866   character.
 867
 868 If WIDTH is non-nil some elements of the description may be
 869 omitted to accommodate the length restriction.  Under certain
 870 condition, the function may return string longer than WIDTH, see
 871 `describe-char-eldoc--truncate'."
 872   (let ((name (get-char-code-property ch 'name)))
 873     (when name
 874       (let* ((code (propertize (format "U+%04X" ch)
 875                                'face 'font-lock-constant-face))
 876              (gc (get-char-code-property ch 'general-category))
 877              (gc-desc (char-code-property-description 'general-category gc)))
 878
 879         (unless (or (not width) (<= (length name) width))
 880           (setq name (describe-char-eldoc--truncate name width)))
 881         (setq name (concat (substring name 0 1) (downcase (substring name 1))))
 882         (setq name (propertize name 'face 'font-lock-variable-name-face))
 883
 884         (setq gc (propertize (symbol-name gc) 'face 'font-lock-comment-face))
 885         (when gc-desc
 886           (setq gc-desc (propertize gc-desc 'face 'font-lock-comment-face)))
 887
 888         (let ((lcode    (length code))
 889               (lname    (length name))
 890               (lgc      (length gc))
 891               (lgc-desc (and gc-desc (length gc-desc))))
 892           (cond
 893            ((and gc-desc
 894                  (or (not width) (<= (+ lcode lname lgc lgc-desc 7) width)))
 895             (concat code ": " name " (" gc ": " gc-desc ")"))
 896            ((and gc-desc (<= (+ lcode lname lgc-desc 5) width))
 897             (concat code ": " name " (" gc-desc ")"))
 898            ((or (not width) (<= (+ lcode lname lgc 5) width))
 899             (concat code ": " name " (" gc ")"))
 900            ((<= (+ lname lgc 3) width)
 901             (concat name " (" gc ")"))
 902            (t name)))))))
 903
 904 ;;;###autoload
 905 (defun describe-char-eldoc ()
 906   "Return a description of character at point for use by ElDoc mode.
 907
 908 Return nil if character at point is a printable ASCII
 909 character (i.e. codepoint between 32 and 127 inclusively).
 910 Otherwise return a description formatted by
 911 `describe-char-eldoc--format' function taking into account value
 912 of `eldoc-echo-area-use-multiline-p' variable and width of
 913 minibuffer window for width limit.
 914
 915 This function is meant to be used as a value of
 916 `eldoc-documentation-function' variable."
 917   (let ((ch (following-char)))
 918     (when (and (not (zerop ch)) (or (< ch 32) (> ch 127)))
 919       (describe-char-eldoc--format
 920        ch
 921        (unless (eq eldoc-echo-area-use-multiline-p t)
 922          (1- (window-width (minibuffer-window))))))))
 923
 924 (provide 'descr-text)
 925
 926 ;;; descr-text.el ends here