lisp/saveplace.el

   1 ;;; saveplace.el --- automatically save place in files
   2
   3 ;; Copyright (C) 1993, 1994, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Karl Fogel <kfogel@red-bean.com>
   6 ;; Maintainer: FSF
   7 ;; Created: July, 1993
   8 ;; Keywords: bookmarks, placeholders
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Automatically save place in files, so that visiting them later
  30 ;; (even during a different Emacs session) automatically moves point
  31 ;; to the saved position, when the file is first found.  Uses the
  32 ;; value of buffer-local variable save-place to determine whether to
  33 ;; save position or not.
  34 ;;
  35 ;; Thanks to Stefan Schoef, who sent a patch with the
  36 ;; `save-place-version-control' stuff in it.
  37
  38 ;;; Code:
  39
  40 ;; this is what I was using during testing:
  41 ;; (define-key ctl-x-map "p" 'toggle-save-place)
  42
  43 (defgroup save-place nil
  44   "Automatically save place in files."
  45   :group 'data)
  46
  47
  48 (defvar save-place-alist nil
  49   "Alist of saved places to go back to when revisiting files.
  50 Each element looks like (FILENAME . POSITION);
  51 visiting file FILENAME goes automatically to position POSITION
  52 rather than the beginning of the buffer.
  53 This alist is saved between Emacs sessions.")
  54
  55 (defcustom save-place nil
  56   "*Non-nil means automatically save place in each file.
  57 This means when you visit a file, point goes to the last place
  58 where it was when you previously visited the same file.
  59 This variable is automatically buffer-local.
  60
  61 If you wish your place in any file to always be automatically saved,
  62 simply put this in your `~/.emacs' file:
  63
  64 \(setq-default save-place t\)"
  65   :type 'boolean
  66   :require 'saveplace
  67   :group 'save-place)
  68
  69 (make-variable-buffer-local 'save-place)
  70
  71 (defcustom save-place-file (convert-standard-filename "~/.emacs-places")
  72   "*Name of the file that records `save-place-alist' value."
  73   :type 'file
  74   :group 'save-place)
  75
  76 (defcustom save-place-version-control nil
  77   "*Controls whether to make numbered backups of master save-place file.
  78 It can have four values: t, nil, `never', and `nospecial'.  The first
  79 three have the same meaning that they do for the variable
  80 `version-control', and the final value `nospecial' means just use the
  81 value of `version-control'."
  82   :type '(radio (const :tag "Unconditionally" t)
  83                 (const :tag "For VC Files" nil)
  84                 (const never)
  85                 (const :tag "Use value of `version-control'" nospecial))
  86   :group 'save-place)
  87
  88 (defvar save-place-loaded nil
  89   "Non-nil means that the `save-place-file' has been loaded.")
  90
  91 (defcustom save-place-limit nil
  92   "Maximum number of entries to retain in the list; nil means no limit."
  93   :type '(choice (integer :tag "Entries" :value 1)
  94                  (const :tag "No Limit" nil))
  95   :group 'save-place)
  96
  97 (defun toggle-save-place (&optional parg)
  98   "Toggle whether to save your place in this file between sessions.
  99 If this mode is enabled, point is recorded when you kill the buffer
 100 or exit Emacs.  Visiting this file again will go to that position,
 101 even in a later Emacs session.
 102
 103 If called with a prefix arg, the mode is enabled if and only if
 104 the argument is positive.
 105
 106 To save places automatically in all files, put this in your `.emacs' file:
 107
 108 \(setq-default save-place t\)"
 109   (interactive "P")
 110   (if (not buffer-file-name)
 111       (message "Buffer `%s' not visiting a file" (buffer-name))
 112     (if (and save-place (or (not parg) (<= parg 0)))
 113         (progn
 114           (message "No place will be saved in this file")
 115           (setq save-place nil))
 116       (message "Place will be saved")
 117       (setq save-place t))))
 118
 119 (defun save-place-to-alist ()
 120   ;; put filename and point in a cons box and then cons that onto the
 121   ;; front of the save-place-alist, if save-place is non-nil.
 122   ;; Otherwise, just delete that file from the alist.
 123   ;; first check to make sure alist has been loaded in from the master
 124   ;; file.  If not, do so, then feel free to modify the alist.  It
 125   ;; will be saved again when Emacs is killed.
 126   (or save-place-loaded (load-save-place-alist-from-file))
 127   (if buffer-file-name
 128       (progn
 129         (let ((cell (assoc buffer-file-name save-place-alist))
 130               (position (if (not (eq major-mode 'hexl-mode))
 131                             (point)
 132                           (1+ (hexl-current-address)))))
 133           (if cell
 134               (setq save-place-alist (delq cell save-place-alist)))
 135           (if (and save-place
 136                    (not (= position 1)))  ;; Optimize out the degenerate case.
 137               (setq save-place-alist
 138                     (cons (cons buffer-file-name position)
 139                           save-place-alist)))))))
 140
 141 (defun save-place-alist-to-file ()
 142   (let ((file (expand-file-name save-place-file)))
 143     (save-excursion
 144       (message "Saving places to %s..." file)
 145       (set-buffer (get-buffer-create " *Saved Places*"))
 146       (delete-region (point-min) (point-max))
 147       (print save-place-alist (current-buffer))
 148       (let ((version-control
 149              (cond
 150               ((null save-place-version-control) nil)
 151               ((eq 'never save-place-version-control) 'never)
 152               ((eq 'nospecial save-place-version-control) version-control)
 153               (t
 154                t))))
 155         (write-file file)
 156         (kill-buffer (current-buffer))
 157         (message "Saving places to %s...done" file)))))
 158
 159 (defun load-save-place-alist-from-file ()
 160   (if (not save-place-loaded)
 161       (progn
 162         (setq save-place-loaded t)
 163         (let ((file (expand-file-name save-place-file)))
 164           ;; make sure that the alist does not get overwritten, and then
 165           ;; load it if it exists:
 166           (if (file-readable-p file)
 167               (save-excursion
 168                 (message "Loading places from %s..." save-place-file)
 169                 ;; don't want to use find-file because we have been
 170                 ;; adding hooks to it.
 171                 (set-buffer (get-buffer-create " *Saved Places*"))
 172                 (delete-region (point-min) (point-max))
 173                 (insert-file-contents file)
 174                 (goto-char (point-min))
 175                 (setq save-place-alist
 176                       (car (read-from-string
 177                             (buffer-substring (point-min) (point-max)))))
 178
 179                 ;; If there is a limit, and we're over it, then we'll
 180                 ;; have to truncate the end of the list:
 181                 (if save-place-limit
 182                     (if (<= save-place-limit 0)
 183                         ;; Zero gets special cased.  I'm not thrilled
 184                         ;; with this, but the loop for >= 1 is tight.
 185                         (setq save-place-alist nil)
 186                       ;; Else the limit is >= 1, so enforce it by
 187                       ;; counting and then `setcdr'ing.
 188                       (let ((s save-place-alist)
 189                             (count 1))
 190                         (while s
 191                           (if (>= count save-place-limit)
 192                               (setcdr s nil)
 193                             (setq count (1+ count)))
 194                           (setq s (cdr s))))))
 195
 196                 (kill-buffer (current-buffer))
 197                 (message "Loading places from %s...done" file)))
 198           nil))))
 199
 200 (defun save-places-to-alist ()
 201   ;; go through buffer-list, saving places to alist if save-place is
 202   ;; non-nil, deleting them from alist if it is nil.
 203   (let ((buf-list (buffer-list)))
 204     (while buf-list
 205       ;; put this into a save-excursion in case someone is counting on
 206       ;; another function in kill-emacs-hook to act on the last buffer
 207       ;; they were in:
 208       (save-excursion
 209         (set-buffer (car buf-list))
 210         ;; save-place checks buffer-file-name too, but we can avoid
 211         ;; overhead of function call by checking here too.
 212         (and buffer-file-name (save-place-to-alist))
 213         (setq buf-list (cdr buf-list))))))
 214
 215 (defun save-place-find-file-hook ()
 216   (or save-place-loaded (load-save-place-alist-from-file))
 217   (let ((cell (assoc buffer-file-name save-place-alist)))
 218     (if cell
 219         (progn
 220           (or after-find-file-from-revert-buffer
 221               (goto-char (cdr cell)))
 222           ;; and make sure it will be saved again for later
 223           (setq save-place t)))))
 224
 225 (defun save-place-kill-emacs-hook ()
 226   ;; First update the alist.  This loads the old save-place-file if nec.
 227   (save-places-to-alist)
 228   ;; Now save the alist in the file, if we have ever loaded the file
 229   ;; (including just now).
 230   (if save-place-loaded
 231       (save-place-alist-to-file)))
 232
 233 (add-hook 'find-file-hooks 'save-place-find-file-hook t)
 234
 235 (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook)
 236
 237 (add-hook 'kill-buffer-hook 'save-place-to-alist)
 238
 239 (provide 'saveplace) ; why not...
 240
 241 ;;; saveplace.el ends here