lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993-1994, 2000-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; For those who are annoyed by the mouse pointer obscuring text,
  26 ;; this mode moves the mouse pointer - either just a little out of
  27 ;; the way, or all the way to the corner of the frame.
  28 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  29 ;; To set up permanently, put the following in your .emacs:
  30 ;;
  31 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  32 ;;
  33 ;; Other legitimate alternatives include
  34 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  35 ;; They do somewhat different things.
  36 ;; See the documentation for function `mouse-avoidance-mode' for
  37 ;; details of the different modes.
  38 ;;
  39 ;; For added silliness, make the animatee animate...
  40 ;; put something similar to the following into your .emacs:
  41 ;;
  42 ;; (if (eq window-system 'x)
  43 ;;     (mouse-avoidance-set-pointer-shape
  44 ;;           (eval (nth (random 4)
  45 ;;                      '(x-pointer-man x-pointer-spider
  46 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  47 ;;
  48 ;; For completely random pointer shape, replace the setq above with:
  49 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  50 ;;
  51 ;; Bugs / Warnings / To-Do:
  52 ;;
  53 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  54 ;;   be too bad, and on my workstation even "animate" is reasonable.
  55 ;;
  56 ;; - It ought to find out where any overlapping frames are and avoid them,
  57 ;;   rather than always raising the frame.
  58
  59 ;; Credits:
  60 ;; This code was helped by all those who contributed suggestions,
  61 ;;   fixes, and additions
  62 ;; Joe Harrington (and his advisor), for the original inspiration.
  63 ;; Ken Manheimer, for dreaming up the Protean mode.
  64 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  65 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  66 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  67
  68 ;;; Code:
  69
  70 (eval-when-compile (require 'cl-lib))
  71
  72 (defgroup avoid nil
  73   "Make mouse pointer stay out of the way of editing."
  74   :prefix "mouse-avoidance-"
  75   :group 'mouse)
  76
  77 ;;;###autoload
  78 (defcustom mouse-avoidance-mode nil
  79   "Activate Mouse Avoidance mode.
  80 See function `mouse-avoidance-mode' for possible values.
  81 Setting this variable directly does not take effect;
  82 use either \\[customize] or the function `mouse-avoidance-mode'."
  83   :set (lambda (_symbol value)
  84          ;; 'none below prevents toggling when value is nil.
  85          (mouse-avoidance-mode (or value 'none)))
  86   :initialize 'custom-initialize-default
  87   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  88                  (const animate) (const exile) (const proteus))
  89   :group 'avoid
  90   :require 'avoid
  91   :version "20.3")
  92
  93
  94 (defcustom mouse-avoidance-nudge-dist 15
  95   "Average distance that mouse will be moved when approached by cursor.
  96 Only applies in Mouse Avoidance mode `jump' and its derivatives.
  97 For best results make this larger than `mouse-avoidance-threshold'."
  98   :type 'integer
  99   :group 'avoid)
 100
 101 (defcustom mouse-avoidance-nudge-var 10
 102   "Variability of `mouse-avoidance-nudge-dist' (which see)."
 103   :type 'integer
 104   :group 'avoid)
 105
 106 (defcustom mouse-avoidance-animation-delay .01
 107   "Delay between animation steps, in seconds."
 108   :type 'number
 109   :group 'avoid)
 110
 111 (defcustom mouse-avoidance-threshold 5
 112   "Mouse-pointer's flight distance.
 113 If the cursor gets closer than this, the mouse pointer will move away.
 114 Only applies in Mouse Avoidance modes `animate' and `jump'."
 115   :type 'integer
 116   :group 'avoid)
 117
 118 (defcustom mouse-avoidance-banish-position '((frame-or-window . frame)
 119                                              (side . right)
 120                                              (side-pos . 3)
 121                                              (top-or-bottom . top)
 122                                              (top-or-bottom-pos . 0))
 123   "Position to which Mouse Avoidance mode `banish' moves the mouse.
 124 An alist where keywords mean:
 125 FRAME-OR-WINDOW: banish the mouse to corner of frame or window.
 126 SIDE: banish the mouse on right or left corner of frame or window.
 127 SIDE-POS: Distance from right or left edge of frame or window.
 128 TOP-OR-BOTTOM: banish the mouse to top or bottom of frame or window.
 129 TOP-OR-BOTTOM-POS: Distance from top or bottom edge of frame or window."
 130   :group   'avoid
 131   :type    '(alist :key-type symbol :value-type symbol)
 132   :options '(frame-or-window side (side-pos integer)
 133              top-or-bottom (top-or-bottom-pos integer)))
 134
 135 ;; Internal variables
 136 (defvar mouse-avoidance-state nil)
 137 (defvar mouse-avoidance-pointer-shapes nil)
 138 (defvar mouse-avoidance-n-pointer-shapes 0)
 139 (defvar mouse-avoidance-old-pointer-shape nil)
 140 (defvar mouse-avoidance-animating-pointer nil)
 141
 142 ;; This timer is used to run something when Emacs is idle.
 143 (defvar mouse-avoidance-timer nil)
 144
 145 ;;; Functions:
 146
 147 (defsubst mouse-avoidance-set-pointer-shape (shape)
 148   "Set the shape of the mouse pointer to SHAPE."
 149   (when (boundp 'x-pointer-shape)
 150     (setq x-pointer-shape shape)
 151     (set-mouse-color nil)))
 152
 153 (defun mouse-avoidance-point-position ()
 154   "Return the position of point as (FRAME X . Y).
 155 Analogous to `mouse-position'."
 156   (let ((edges (window-inside-edges))
 157         (x-y (posn-x-y (posn-at-point))))
 158     (cons (selected-frame)
 159           (cons (+ (car edges)
 160                    (/ (car x-y) (frame-char-width)))
 161                 (+ (car (cdr edges))
 162                    (/ (cdr x-y) (frame-char-height)))))))
 163
 164 ;(defun mouse-avoidance-point-position-test ()
 165 ;  (interactive)
 166 ;  (message (format "point=%s mouse=%s"
 167 ;                  (cdr (mouse-avoidance-point-position))
 168 ;                  (cdr (mouse-position)))))
 169
 170 (defun mouse-avoidance-set-mouse-position (pos)
 171   ;; Carefully set mouse position to given position (X . Y)
 172   ;; Ideally, should check if X,Y is in the current frame, and if not,
 173   ;; leave the mouse where it was.  However, this is currently
 174   ;; difficult to do, so we just raise the frame to avoid frame switches.
 175   ;; Returns t if it moved the mouse.
 176   (let ((f (selected-frame)))
 177     (raise-frame f)
 178     (set-mouse-position f (car pos) (cdr pos))
 179     t))
 180
 181 (defun mouse-avoidance-too-close-p (mouse)
 182   "Return t if mouse pointer and point cursor are too close.
 183 MOUSE is the current mouse position as returned by `mouse-position'.
 184 Acceptable distance is defined by `mouse-avoidance-threshold'."
 185   (let* ((frame (car mouse))
 186          (mouse-y (cdr (cdr mouse)))
 187          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 188     (or tool-bar-lines
 189         (setq tool-bar-lines 0))
 190     (if (and mouse-y (< mouse-y tool-bar-lines))
 191         nil
 192       (let ((point (mouse-avoidance-point-position))
 193             (mouse-x (car (cdr mouse))))
 194         (and (eq frame (car point))
 195              (not (null mouse-x))
 196              (< (abs (- mouse-x (car (cdr point))))
 197                 mouse-avoidance-threshold)
 198              (< (abs (- mouse-y (cdr (cdr point))))
 199                 mouse-avoidance-threshold))))))
 200
 201 (defun mouse-avoidance-banish-destination ()
 202   "The position to which Mouse Avoidance mode `banish' moves the mouse.
 203
 204 If you want the mouse banished to a different corner set
 205 `mouse-avoidance-banish-position' as you need."
 206   (let* ((fra-or-win         (assoc-default
 207                               'frame-or-window
 208                               mouse-avoidance-banish-position 'eq))
 209          (list-values        (pcase fra-or-win
 210                                (`frame (list 0 0 (frame-width) (frame-height)))
 211                                (`window (window-edges))))
 212          (alist              (cl-loop for v in list-values
 213                                       for k in '(left top right bottom)
 214                                       collect (cons k v)))
 215          (side               (assoc-default
 216                               'side
 217                               mouse-avoidance-banish-position #'eq))
 218          (side-dist          (assoc-default
 219                               'side-pos
 220                               mouse-avoidance-banish-position #'eq))
 221          (top-or-bottom      (assoc-default
 222                               'top-or-bottom
 223                               mouse-avoidance-banish-position #'eq))
 224          (top-or-bottom-dist (assoc-default
 225                               'top-or-bottom-pos
 226                               mouse-avoidance-banish-position #'eq))
 227          (side-fn            (pcase side
 228                                (`left '+)
 229                                (`right '-)))
 230          (top-or-bottom-fn   (pcase top-or-bottom
 231                                (`top '+)
 232                                (`bottom '-))))
 233     (cons (funcall side-fn                        ; -/+
 234                    (assoc-default side alist 'eq) ; right or left
 235                    side-dist)                     ; distance from side
 236           (funcall top-or-bottom-fn                        ; -/+
 237                    (assoc-default top-or-bottom alist 'eq) ; top/bottom
 238                    top-or-bottom-dist)))) ; distance from top/bottom
 239
 240 (defun mouse-avoidance-banish-mouse ()
 241   "Put the mouse pointer to `mouse-avoidance-banish-position'."
 242   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 243
 244 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 245   ;; Decide how far to move in either dimension.
 246   ;; Args are the CURRENT location, the desired DELTA for
 247   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 248   ;; in distance allowed, and the MIN and MAX possible window positions.
 249   ;; Returns something as close to DELTA as possible within the constraints.
 250   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 251         (R1                  (+ (- dist)    var ))
 252         (L2                  (+    dist  (- var)))
 253         (R2 (min (- max cur) (+    dist     var))))
 254     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 255     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 256     (cond ((and L1 (< delta L1)) L1)
 257           ((and R1 (< delta R1)) delta)
 258           ((and R1 (< delta 0)) R1)
 259           ((and L2 (< delta L2)) L2)
 260           ((and R2 (< delta R2)) delta)
 261           (R2)
 262           ((or R1 L2))
 263           (t 0))))
 264
 265 (defun mouse-avoidance-nudge-mouse ()
 266   ;; Push the mouse a little way away, possibly animating the move.
 267   ;; For these modes, state keeps track of the total offset that we've
 268   ;; accumulated, and tries to keep it close to zero.
 269   (let* ((cur (mouse-position))
 270          (cur-pos (cdr cur))
 271          (pos (window-edges))
 272          (wleft (pop pos))
 273          (wtop (pop pos))
 274          (wright (pop pos))
 275          (wbot (pop pos))
 276          (deltax (mouse-avoidance-delta
 277                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 278                                    (car mouse-avoidance-state))
 279                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 280                   wleft (1- wright)))
 281          (deltay (mouse-avoidance-delta
 282                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 283                                    (cdr mouse-avoidance-state))
 284                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 285                   wtop (1- wbot))))
 286     (setq mouse-avoidance-state
 287           (cons (+ (car mouse-avoidance-state) deltax)
 288                 (+ (cdr mouse-avoidance-state) deltay)))
 289     (if (or (eq mouse-avoidance-mode 'animate)
 290             (eq mouse-avoidance-mode 'proteus))
 291         (let ((i 0.0)
 292               (incr (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 293           (setq mouse-avoidance-animating-pointer t)
 294           (while (<= i 1)
 295             (mouse-avoidance-set-mouse-position
 296              (cons (+ (car cur-pos) (round (* i deltax)))
 297                    (+ (cdr cur-pos) (round (* i deltay)))))
 298             (setq i (+ i incr))
 299             (if (eq mouse-avoidance-mode 'proteus)
 300                 (mouse-avoidance-set-pointer-shape
 301                  (mouse-avoidance-random-shape)))
 302             (sit-for mouse-avoidance-animation-delay))
 303           (setq mouse-avoidance-animating-pointer nil))
 304       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 305                                                 (+ (cdr (cdr cur)) deltay))))))
 306
 307 (defun mouse-avoidance-random-shape ()
 308   "Return a random cursor shape.
 309 This assumes that any variable whose name begins with x-pointer- and
 310 has an integer value is a valid cursor shape.  You might want to
 311 redefine this function to suit your own tastes."
 312   (if (null mouse-avoidance-pointer-shapes)
 313       (progn
 314         (setq mouse-avoidance-pointer-shapes
 315               (mapcar (lambda (x) (symbol-value (intern x)))
 316                       (all-completions "x-pointer-" obarray
 317                                        (lambda (x)
 318                                           (and (boundp x)
 319                                                (integerp (symbol-value x)))))))
 320         (setq mouse-avoidance-n-pointer-shapes
 321               (length mouse-avoidance-pointer-shapes))))
 322   (nth (random mouse-avoidance-n-pointer-shapes)
 323        mouse-avoidance-pointer-shapes))
 324
 325 (defun mouse-avoidance-ignore-p ()
 326   (let ((mp (mouse-position)))
 327     (or (not (frame-pointer-visible-p)) ; The pointer is hidden
 328         (not cursor-type)               ; There's no cursor
 329         executing-kbd-macro            ; don't check inside macro
 330         (null (cadr mp))               ; don't move unless in an Emacs frame
 331         (not (eq (car mp) (selected-frame)))
 332         ;; Don't do anything if last event was a mouse event.
 333         ;; FIXME: this code fails in the case where the mouse was moved
 334         ;; since the last key-press but without generating any event.
 335         (and (consp last-input-event)
 336              (symbolp (car last-input-event))
 337              (let ((modifiers (event-modifiers (car last-input-event))))
 338                (or (memq (car last-input-event)
 339                          '(mouse-movement scroll-bar-movement
 340                            select-window switch-frame))
 341                    (memq 'click modifiers)
 342                    (memq 'double modifiers)
 343                    (memq 'triple modifiers)
 344                    (memq 'drag modifiers)
 345                    (memq 'down modifiers)))))))
 346
 347 (defun mouse-avoidance-banish ()
 348   (if (not (mouse-avoidance-ignore-p))
 349       (mouse-avoidance-banish-mouse)))
 350
 351 (defun mouse-avoidance-exile ()
 352   ;; For exile mode, the state is nil when the mouse is in its normal
 353   ;; position, and set to the old mouse-position when the mouse is in exile.
 354   (if (not (mouse-avoidance-ignore-p))
 355       (let ((mp (mouse-position)))
 356         (cond ((and (not mouse-avoidance-state)
 357                     (mouse-avoidance-too-close-p mp))
 358                (setq mouse-avoidance-state mp)
 359                (mouse-avoidance-banish-mouse))
 360               ((and mouse-avoidance-state
 361                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 362                (if (and (eq (car mp) (selected-frame))
 363                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 364                    (mouse-avoidance-set-mouse-position
 365                     ;; move back only if user has not moved mouse
 366                     (cdr mouse-avoidance-state)))
 367                ;; but clear state anyway, to be ready for another move
 368                (setq mouse-avoidance-state nil))))))
 369
 370 (defun mouse-avoidance-fancy ()
 371   ;; Used for the "fancy" modes, ie jump et al.
 372   (if (and (not mouse-avoidance-animating-pointer)
 373            (not (mouse-avoidance-ignore-p))
 374            (mouse-avoidance-too-close-p (mouse-position)))
 375       (let ((old-pos (mouse-position)))
 376         (mouse-avoidance-nudge-mouse)
 377         (if (not (eq (selected-frame) (car old-pos)))
 378             ;; This should never happen.
 379             (apply 'set-mouse-position old-pos)))))
 380
 381 ;;;###autoload
 382 (defun mouse-avoidance-mode (&optional mode)
 383   "Set Mouse Avoidance mode to MODE.
 384 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 385 `cat-and-mouse', `proteus', or `none'.
 386
 387 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 388 modes.  Positive numbers and symbols other than the above are treated
 389 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 390
 391 Effects of the different modes:
 392  * banish: Move the mouse to the upper-right corner on any keypress.
 393  * exile: Move the mouse to the corner only if the cursor gets too close,
 394      and allow it to return once the cursor is out of the way.
 395  * jump: If the cursor gets too close to the mouse, displace the mouse
 396      a random distance & direction.
 397  * animate: As `jump', but shows steps along the way for illusion of motion.
 398  * cat-and-mouse: Same as `animate'.
 399  * proteus: As `animate', but changes the shape of the mouse pointer too.
 400
 401 Whenever the mouse is moved, the frame is also raised.
 402
 403 \(See `mouse-avoidance-threshold' for definition of \"too close\",
 404 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 405 definition of \"random distance\".)"
 406   (interactive
 407    (list (intern (completing-read
 408                   "Select cursor avoidance technique (SPACE for list): "
 409                   '(("banish") ("exile") ("jump") ("animate")
 410                     ("cat-and-mouse") ("proteus") ("none"))
 411                   nil t))))
 412   (if (eq mode 'cat-and-mouse)
 413       (setq mode 'animate))
 414   (if mouse-avoidance-timer
 415       (cancel-timer mouse-avoidance-timer))
 416   (setq mouse-avoidance-timer nil)
 417
 418   ;; Restore pointer shape if necessary
 419   (if (eq mouse-avoidance-mode 'proteus)
 420       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 421
 422   ;; Do additional setup depending on version of mode requested
 423   (cond ((eq mode 'none)
 424          (setq mouse-avoidance-mode nil))
 425         ((or (eq mode 'jump)
 426              (eq mode 'animate)
 427              (eq mode 'proteus))
 428          (setq mouse-avoidance-timer
 429                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy))
 430          (setq mouse-avoidance-mode mode
 431                mouse-avoidance-state (cons 0 0)
 432                mouse-avoidance-old-pointer-shape
 433                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 434         ((eq mode 'exile)
 435          (setq mouse-avoidance-timer
 436                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile))
 437          (setq mouse-avoidance-mode mode
 438                mouse-avoidance-state nil))
 439         ((or (eq mode 'banish)
 440              (eq mode t)
 441              (and (null mode) (null mouse-avoidance-mode))
 442              (and mode (> (prefix-numeric-value mode) 0)))
 443          (setq mouse-avoidance-timer
 444                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish))
 445          (setq mouse-avoidance-mode 'banish))
 446         (t (setq mouse-avoidance-mode nil)))
 447   (force-mode-line-update))
 448
 449 ;; Most people who use avoid mode leave it on all the time, so it's not
 450 ;; very informative to announce it in the mode line.
 451 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 452 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 453 ;;                               minor-mode-alist)))
 454
 455 ;; Needed for custom.
 456 (if mouse-avoidance-mode
 457     (mouse-avoidance-mode mouse-avoidance-mode))
 458
 459 (provide 'avoid)
 460
 461 ;;; avoid.el ends here