configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(maintainer-mode,
 239 [AS_HELP_STRING([--disable-maintainer-mode],
 240                 [disable make rules and dependencies not useful (and sometimes
 241                  confusing) to the casual installer])],
 242       USE_MAINTAINER_MODE=$enableval,
 243       USE_MAINTAINER_MODE=yes)
 244 if test $USE_MAINTAINER_MODE = yes; then
 245   MAINT=
 246 else
 247   MAINT=#
 248 fi
 249 AC_SUBST(MAINT)
 250
 251 AC_ARG_ENABLE(locallisppath,
 252 [AS_HELP_STRING([--enable-locallisppath=PATH],
 253                 [directories Emacs should search for lisp files specific
 254                  to this site])],
 255 if test "${enableval}" = "no"; then
 256   locallisppath=
 257 elif test "${enableval}" != "yes"; then
 258   locallisppath=${enableval}
 259 fi)
 260
 261 AC_ARG_ENABLE(checking,
 262 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 263                 [enable expensive run-time checks.  With LIST,
 264                  enable only specific categories of checks.
 265                  Categories are: all,yes,no.
 266                  Flags are: stringbytes, stringoverrun, stringfreelist,
 267                  xmallocoverrun, conslist])],
 268 [ac_checking_flags="${enableval}"],[])
 269 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 270 for check in $ac_checking_flags
 271 do
 272         case $check in
 273         # these set all the flags to specific states
 274         yes)            ac_enable_checking=1 ;;
 275         no)             ac_enable_checking= ;
 276                         ac_gc_check_stringbytes= ;
 277                         ac_gc_check_string_overrun= ;
 278                         ac_gc_check_string_free_list= ;
 279                         ac_xmalloc_overrun= ;
 280                         ac_gc_check_cons_list= ;;
 281         all)            ac_enable_checking=1 ;
 282                         ac_gc_check_stringbytes=1 ;
 283                         ac_gc_check_string_overrun=1 ;
 284                         ac_gc_check_string_free_list=1 ;
 285                         ac_xmalloc_overrun=1 ;
 286                         ac_gc_check_cons_list=1 ;;
 287         # these enable particular checks
 288         stringbytes)    ac_gc_check_stringbytes=1 ;;
 289         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 290         stringfreelist) ac_gc_check_string_free_list=1 ;;
 291         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 292         conslist)       ac_gc_check_cons_list=1 ;;
 293         *)      AC_MSG_ERROR(unknown check category $check) ;;
 294         esac
 295 done
 296 IFS="$ac_save_IFS"
 297
 298 if test x$ac_enable_checking != x ; then
 299   AC_DEFINE(ENABLE_CHECKING, 1,
 300 [Enable expensive run-time checking of data types?])
 301 fi
 302 if test x$ac_gc_check_stringbytes != x ; then
 303   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 304 [Define this temporarily to hunt a bug.  If defined, the size of
 305    strings is redundantly recorded in sdata structures so that it can
 306    be compared to the sizes recorded in Lisp strings.])
 307 fi
 308 if test x$ac_gc_check_string_overrun != x ; then
 309   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 310 [Define this to check for short string overrun.])
 311 fi
 312 if test x$ac_gc_check_string_free_list != x ; then
 313   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 314 [Define this to check the string free list.])
 315 fi
 316 if test x$ac_xmalloc_overrun != x ; then
 317   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 318 [Define this to check for malloc buffer overrun.])
 319 fi
 320 if test x$ac_gc_check_cons_list != x ; then
 321   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 322 [Define this to check for errors in cons list.])
 323 fi
 324
 325 AC_ARG_ENABLE(use-lisp-union-type,
 326 [AS_HELP_STRING([--enable-use-lisp-union-type],
 327                 [use a union for the Lisp_Object data type.
 328                 This is only useful for development for catching certain types of bugs.])],
 329 if test "${enableval}" != "no"; then
 330    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 331    [Define this to use a lisp union for the Lisp_Object data type.])
 332 fi)
 333
 334
 335 AC_ARG_ENABLE(profiling,
 336 [AS_HELP_STRING([--enable-profiling],
 337                 [build emacs with profiling support.
 338                  This might not work on all platforms])],
 339 [ac_enable_profiling="${enableval}"],[])
 340 if test x$ac_enable_profiling != x ; then
 341    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 342 else
 343    PROFILING_CFLAGS=
 344 fi
 345 AC_SUBST(PROFILING_CFLAGS)
 346
 347 AC_ARG_ENABLE(autodepend,
 348 [AS_HELP_STRING([--enable-autodepend],
 349                 [automatically generate dependencies to .h-files.
 350                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 351                  found])],
 352 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 353
 354 #### Make srcdir absolute, if it isn't already.  It's important to
 355 #### avoid running the path through pwd unnecessarily, since pwd can
 356 #### give you automounter prefixes, which can go away.  We do all this
 357 #### so Emacs can find its files when run uninstalled.
 358 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 359 unset CDPATH
 360 case "${srcdir}" in
 361   /* ) ;;
 362   . )
 363     ## We may be able to use the $PWD environment variable to make this
 364     ## absolute.  But sometimes PWD is inaccurate.
 365     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 366     ## but that tested only for a well-formed and valid PWD,
 367     ## it did not object when PWD was well-formed and valid but just wrong.
 368     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 369     then
 370       srcdir="$PWD"
 371     else
 372       srcdir="`(cd ${srcdir}; pwd)`"
 373     fi
 374   ;;
 375   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 376 esac
 377
 378 #### Given the configuration name, set machfile and opsysfile to the
 379 #### names of the m/*.h and s/*.h files we should use.
 380
 381 ### Canonicalize the configuration name.
 382
 383 AC_CANONICAL_HOST
 384 canonical=$host
 385 configuration=${host_alias-${build_alias-$host}}
 386
 387 dnl This used to use changequote, but, apart from `changequote is evil'
 388 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 389 dnl the great gob of text.  Thus it's not processed for possible expansion.
 390 dnl Just make sure the brackets remain balanced.
 391 dnl
 392 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 393 dnl indicated by comments.
 394 dnl quotation begins
 395 [
 396
 397 ### If you add support for a new configuration, add code to this
 398 ### switch statement to recognize your configuration name and select
 399 ### the appropriate operating system and machine description files.
 400
 401 ### You would hope that you could choose an m/*.h file pretty much
 402 ### based on the machine portion of the configuration name, and an s/*.h
 403 ### file based on the operating system portion.  However, it turns out
 404 ### that each m/*.h file is pretty manufacturer-specific - for
 405 ### example mips.h is MIPS
 406 ### So we basically have to have a special case for each
 407 ### configuration name.
 408 ###
 409 ### As far as handling version numbers on operating systems is
 410 ### concerned, make sure things will fail in a fixable way.  If
 411 ### /etc/MACHINES doesn't say anything about version numbers, be
 412 ### prepared to handle anything reasonably.  If version numbers
 413 ### matter, be sure /etc/MACHINES says something about it.
 414
 415 machine='' opsys='' unported=no
 416 case "${canonical}" in
 417
 418   ## GNU/Linux and similar ports
 419   *-*-linux* )
 420     opsys=gnu-linux
 421     case ${canonical} in
 422       alpha*)   machine=alpha ;;
 423       s390x-*)  machine=ibms390x ;;
 424       powerpc*) machine=macppc ;;
 425       sparc*)   machine=sparc ;;
 426       ia64*)    machine=ia64 ;;
 427       m68k*)    machine=m68k ;;
 428       x86_64*)  machine=amdx86-64 ;;
 429     esac
 430   ;;
 431
 432   ## FreeBSD ports
 433   *-*-freebsd* )
 434     opsys=freebsd
 435     case "${canonical}" in
 436       alpha*)           machine=alpha ;;
 437       amd64-*|x86_64-*) machine=amdx86-64 ;;
 438       ia64-*)           machine=ia64 ;;
 439       i[3456]86-*)      machine=intel386 ;;
 440       powerpc-*)        machine=macppc ;;
 441       sparc-*)          machine=sparc ;;
 442       sparc64-*)        machine=sparc ;;
 443     esac
 444   ;;
 445
 446   ## FreeBSD kernel + glibc based userland
 447   *-*-kfreebsd*gnu* )
 448     opsys=gnu-kfreebsd
 449     case "${canonical}" in
 450       alpha*)           machine=alpha ;;
 451       amd64-*|x86_64-*) machine=amdx86-64 ;;
 452       ia64-*)           machine=ia64 ;;
 453       i[3456]86-*)      machine=intel386 ;;
 454       powerpc-*)        machine=macppc ;;
 455       sparc-*)          machine=sparc ;;
 456       sparc64-*)        machine=sparc ;;
 457     esac
 458   ;;
 459
 460   ## NetBSD ports
 461   *-*-netbsd* )
 462     opsys=netbsd
 463     case "${canonical}" in
 464       alpha*)      machine=alpha ;;
 465       x86_64-*)    machine=amdx86-64 ;;
 466       i[3456]86-*) machine=intel386 ;;
 467       m68k-*)      machine=m68k ;;
 468       powerpc-*)   machine=macppc ;;
 469       sparc*-)     machine=sparc ;;
 470     esac
 471   ;;
 472
 473   ## OpenBSD ports
 474   *-*-openbsd* )
 475     opsys=openbsd
 476     case "${canonical}" in
 477       alpha*)    machine=alpha ;;
 478       x86_64-*)  machine=amdx86-64 ;;
 479       i386-*)    machine=intel386 ;;
 480       powerpc-*) machine=macppc ;;
 481       sparc*)    machine=sparc ;;
 482     esac
 483   ;;
 484
 485   ## Apple Darwin / Mac OS X
 486   *-apple-darwin* )
 487     case "${canonical}" in
 488       i[3456]86-* )  machine=intel386 ;;
 489       powerpc-* )    machine=macppc ;;
 490       x86_64-* )     machine=amdx86-64 ;;
 491       * )            unported=yes ;;
 492     esac
 493     opsys=darwin
 494     ## Use fink packages if available.
 495     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 496 ##    if test -d /sw/include && test -d /sw/lib; then
 497 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 498 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 499 ##    fi
 500   ;;
 501
 502   ## HP 9000 series 700 and 800, running HP/UX
 503   hppa*-hp-hpux10.2* )
 504     opsys=hpux10-20
 505   ;;
 506   hppa*-hp-hpux1[1-9]* )
 507     opsys=hpux11
 508     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 509   ;;
 510
 511   ## IBM machines
 512   rs6000-ibm-aix4.[23]* )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   powerpc-ibm-aix4.[23]*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix[56]* )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   powerpc-ibm-aix[56]*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524
 525   ## Silicon Graphics machines
 526   ## Iris 4D
 527   mips-sgi-irix6.5 )
 528     opsys=irix6-5
 529     # Without defining _LANGUAGE_C, things get masked out in the headers
 530     # so that, for instance, grepping for `free' in stdlib.h fails and
 531     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 532     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 533   ;;
 534
 535   ## Suns
 536   *-sun-solaris* \
 537     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 538     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 539     case "${canonical}" in
 540       i[3456]86-*-* )     machine=intel386 ;;
 541       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 542       sparc* )          machine=sparc ;;
 543       * )               unported=yes ;;
 544     esac
 545     case "${canonical}" in
 546       *-sunos5.6* | *-solaris2.6* )
 547                 opsys=sol2-6
 548                 RANLIB="ar -ts"
 549                 ;;
 550       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 551                 opsys=sol2-6
 552                 emacs_check_sunpro_c=yes
 553                 ;;
 554       *-sunos5* | *-solaris* )
 555                 opsys=sol2-10
 556                 emacs_check_sunpro_c=yes
 557                 ;;
 558     esac
 559     ## Watch out for a compiler that we know will not work.
 560     case "${canonical}" in
 561      *-solaris* | *-sunos5* )
 562                 if [ "x$CC" = x/usr/ucb/cc ]; then
 563                   ## /usr/ucb/cc doesn't work;
 564                   ## we should find some other compiler that does work.
 565                   unset CC
 566                 fi
 567                 ;;
 568       *) ;;
 569     esac
 570   ;;
 571
 572   ## Intel 386 machines where we don't care about the manufacturer.
 573   i[3456]86-*-* )
 574     machine=intel386
 575     case "${canonical}" in
 576       *-cygwin )                opsys=cygwin ;;
 577       *-darwin* )               opsys=darwin ;;
 578       *-sysv4.2uw* )            opsys=unixware ;;
 579       *-sysv5uw* )              opsys=unixware ;;
 580       *-sysv5OpenUNIX* )        opsys=unixware ;;
 581       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 582     esac
 583   ;;
 584
 585   * )
 586     unported=yes
 587   ;;
 588 esac
 589
 590 ### If the code above didn't choose an operating system, just choose
 591 ### an operating system based on the configuration name.  You really
 592 ### only want to use this when you have no idea what the right
 593 ### operating system is; if you know what operating systems a machine
 594 ### runs, it's cleaner to make it explicit in the case statement
 595 ### above.
 596 if test x"${opsys}" = x; then
 597   case "${canonical}" in
 598     *-gnu* )                            opsys=gnu ;;
 599     * )
 600       unported=yes
 601     ;;
 602   esac
 603 fi
 604
 605 ]
 606 dnl quotation ends
 607
 608 if test $unported = yes; then
 609   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 610 Check `etc/MACHINES' for recognized configuration names.])
 611 fi
 612
 613 if test -n "$machine"; then
 614   machfile="m/${machine}.h"
 615 else
 616   machfile=
 617 fi
 618 opsysfile="s/${opsys}.h"
 619
 620
 621 #### Choose a compiler.
 622
 623 dnl Sets GCC=yes if using gcc.
 624 AC_PROG_CC
 625 AM_PROG_CC_C_O
 626
 627 if test x$GCC = xyes; then
 628   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 629 else
 630   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 631 fi
 632
 633 # Initialize gnulib right after choosing the compiler.
 634 gl_EARLY
 635
 636 AC_ARG_ENABLE([gcc-warnings],
 637   [AS_HELP_STRING([--enable-gcc-warnings],
 638                   [turn on lots of GCC warnings (for developers)])],
 639   [case $enableval in
 640      yes|no) ;;
 641      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 642    esac
 643    gl_gcc_warnings=$enableval],
 644   [gl_gcc_warnings=no]
 645 )
 646
 647 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 648 # ------------------------------------------------
 649 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 650 # Otherwise, run RUN-IF-NOT-FOUND.
 651 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 652   [AC_PREPROC_IFELSE(
 653     [AC_LANG_PROGRAM(
 654       [[
 655 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 656 /* ok */
 657 #else
 658 # error "your version of gcc is older than $1.$2"
 659 #endif
 660       ]]),
 661     ], [$3], [$4])
 662   ]
 663 )
 664
 665 # When compiling with GCC, prefer -isystem to -I when including system
 666 # include files, to avoid generating useless diagnostics for the files.
 667 if test "$gl_gcc_warnings" != yes; then
 668   isystem='-I'
 669 else
 670   isystem='-isystem '
 671
 672   # This, $nw, is the list of warnings we disable.
 673   nw=
 674
 675   case $with_x_toolkit in
 676     lucid | athena | motif)
 677        # Old toolkits mishandle 'const'.
 678        nw="$nw -Wwrite-strings"
 679        ;;
 680     *)
 681        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 682        ;;
 683   esac
 684   AC_SUBST([WERROR_CFLAGS])
 685
 686   nw="$nw -Waggregate-return"       # anachronistic
 687   nw="$nw -Wlong-long"              # C90 is anachronistic
 688   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 689   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 690   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 691   nw="$nw -Wcast-qual"              # Too many warnings for now
 692   nw="$nw -Wconversion"             # Too many warnings for now
 693   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 694   nw="$nw -Wsign-conversion"        # Too many warnings for now
 695   nw="$nw -Woverlength-strings"     # Not a problem these days
 696   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 697   nw="$nw -Wpadded"                 # Our structs are not padded
 698   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 699   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 700   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 701   nw="$nw -Wvla"                    # warnings in gettext.h
 702   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 703   nw="$nw -Wswitch-enum"            # Too many warnings for now
 704   nw="$nw -Wswitch-default"         # Too many warnings for now
 705   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 706   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 707
 708   # Emacs doesn't care about shadowing; see
 709   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 710   nw="$nw -Wshadow"
 711
 712   # The following lines should be removable at some point.
 713   nw="$nw -Wstack-protector"
 714   nw="$nw -Wstrict-overflow"
 715   nw="$nw -Wsuggest-attribute=const"
 716   nw="$nw -Wsuggest-attribute=pure"
 717
 718   gl_MANYWARN_ALL_GCC([ws])
 719   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 720   for w in $ws; do
 721     gl_WARN_ADD([$w])
 722   done
 723   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 724   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 725   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 726   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 727   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 728   gl_WARN_ADD([-Wno-format-nonliteral])
 729
 730   # In spite of excluding -Wlogical-op above, it is enabled, as of
 731   # gcc 4.5.0 20090517.
 732   gl_WARN_ADD([-Wno-logical-op])
 733
 734   gl_WARN_ADD([-fdiagnostics-show-option])
 735   gl_WARN_ADD([-funit-at-a-time])
 736
 737   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 738   AC_DEFINE([_FORTIFY_SOURCE], [2],
 739     [enable compile-time and run-time bounds-checking, and some warnings])
 740   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 741
 742   # We use a slightly smaller set of warning options for lib/.
 743   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 744   nw=
 745   nw="$nw -Wunused-macros"
 746
 747   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 748   AC_SUBST([GNULIB_WARN_CFLAGS])
 749 fi
 750
 751
 752
 753 dnl Some other nice autoconf tests.
 754 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 755 dnl AC_PROG_INSTALL
 756 dnl AC_PROG_MKDIR_P
 757 dnl if test "x$RANLIB" = x; then
 758 dnl   AC_PROG_RANLIB
 759 dnl fi
 760
 761 ## Although we're running on an amd64 kernel, we're actually compiling for
 762 ## the x86 architecture.  The user should probably have provided an
 763 ## explicit --build to `configure', but if everything else than the kernel
 764 ## is running in i386 mode, we can help them out.
 765 if test "$machine" = "amdx86-64"; then
 766   AC_CHECK_DECL([i386])
 767   if test "$ac_cv_have_decl_i386" = "yes"; then
 768     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 769     machine=intel386
 770     machfile="m/${machine}.h"
 771   fi
 772 fi
 773
 774 AC_PATH_PROG(INSTALL_INFO, install-info)
 775 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 776 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 777 dnl Don't use GZIP, which is used by gzip for additional parameters.
 778 AC_PATH_PROG(GZIP_PROG, gzip)
 779
 780
 781 ## Need makeinfo >= 4.7 (?) to build the manuals.
 782 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 783 dnl By this stage, configure has already checked for egrep and set EGREP,
 784 dnl or exited with an error if no egrep was found.
 785 if test "$MAKEINFO" != "no" && \
 786   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 787    MAKEINFO=no
 788 fi
 789
 790 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 791 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 792 ## therefore in the category of "special tools" not normally required, which
 793 ## configure does not have to check for (eg autoconf itself).
 794 ## In a Bazaar checkout on the other hand, the manuals are not included.
 795 ## So makeinfo is a requirement to build from Bazaar, and configure
 796 ## should test for it as it does for any other build requirement.
 797 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 798 ## with pre-built manuals, from a Bazaar checkout.
 799 HAVE_MAKEINFO=yes
 800
 801 if test "$MAKEINFO" = "no"; then
 802   MAKEINFO=makeinfo
 803   if test "x${with_makeinfo}" = "xno"; then
 804     HAVE_MAKEINFO=no
 805   elif test ! -e $srcdir/info/emacs; then
 806     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 807 source tree does not seem to have pre-built manuals in the `info' directory.
 808 Either install a suitable version of makeinfo, or re-run configure
 809 with the `--without-makeinfo' option to build without the manuals.] )
 810   fi
 811 fi
 812 AC_SUBST(HAVE_MAKEINFO)
 813
 814 dnl Just so that there is only a single place we need to edit.
 815 INFO_EXT=.info
 816 INFO_OPTS=--no-split
 817 AC_SUBST(INFO_EXT)
 818 AC_SUBST(INFO_OPTS)
 819
 820 dnl Add our options to ac_link now, after it is set up.
 821
 822 if test x$GCC = xyes; then
 823   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 824     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 825 else
 826   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 827     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 828 fi
 829
 830 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 831 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 832 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 833 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 834 dnl if not built to support GNU ld.
 835
 836 late_LDFLAGS=$LDFLAGS
 837 if test x$GCC = xyes; then
 838   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 839 else
 840   LDFLAGS="$LDFLAGS -znocombreloc"
 841 fi
 842
 843 AC_MSG_CHECKING([for -znocombreloc])
 844 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 845   [AC_MSG_RESULT(yes)],
 846   LDFLAGS=$late_LDFLAGS
 847   [AC_MSG_RESULT(no)])
 848
 849
 850 dnl The function dump-emacs will not be defined and temacs will do
 851 dnl (load "loadup") automatically unless told otherwise.
 852 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 853 case "$opsys" in
 854   your-opsys-here) CANNOT_DUMP=yes ;;
 855 esac
 856
 857 test "$CANNOT_DUMP" = "yes" && \
 858   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 859
 860 AC_SUBST(CANNOT_DUMP)
 861
 862
 863 UNEXEC_OBJ=unexelf.o
 864 case "$opsys" in
 865   # MSDOS uses unexcoff.o
 866   # MSWindows uses unexw32.o
 867   aix4-2)
 868    UNEXEC_OBJ=unexaix.o
 869    ;;
 870   cygwin)
 871    UNEXEC_OBJ=unexcw.o
 872    ;;
 873   darwin)
 874    UNEXEC_OBJ=unexmacosx.o
 875    ;;
 876   hpux10-20 | hpux11)
 877    UNEXEC_OBJ=unexhp9k800.o
 878    ;;
 879   sol2-10)
 880    # Use the Solaris dldump() function, called from unexsol.c, to dump
 881    # emacs, instead of the generic ELF dump code found in unexelf.c.
 882    # The resulting binary has a complete symbol table, and is better
 883    # for debugging and other observability tools (debuggers, pstack, etc).
 884    #
 885    # If you encounter a problem using dldump(), please consider sending
 886    # a message to the OpenSolaris tools-linking mailing list:
 887    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 888    #
 889    # It is likely that dldump() works with older Solaris too, but this has
 890    # not been tested, so for now this change is for Solaris 10 or newer.
 891    UNEXEC_OBJ=unexsol.o
 892    ;;
 893 esac
 894
 895 LD_SWITCH_SYSTEM=
 896 case "$opsys" in
 897   freebsd)
 898    ## Let `ld' find image libs and similar things in /usr/local/lib.
 899    ## The system compiler, GCC, has apparently been modified to not
 900    ## look there, contrary to what a stock GCC would do.
 901 ### It's not our place to do this.  See bug#10313#17.
 902 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 903       :
 904    ;;
 905
 906   gnu-linux)
 907    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 908    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 909    ;;
 910
 911   netbsd)
 912 ### It's not our place to do this.  See bug#10313#17.
 913 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 914       :
 915    ;;
 916
 917   openbsd)
 918    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 919    ## otherwise Emacs dumps core on elf systems.
 920    LD_SWITCH_SYSTEM="-Z"
 921    ;;
 922 esac
 923 AC_SUBST(LD_SWITCH_SYSTEM)
 924
 925 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 926
 927 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 928 ## which has not been defined yet.  When this was handled with cpp,
 929 ## it was expanded to null when configure sourced the s/*.h file.
 930 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 931 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 932 ## (or somesuch), but because it is supposed to go at the _front_
 933 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 934 ## Compare with the gnu-linux case below, which added to the end
 935 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 936 ## LD_SWITCH_SYSTEM_TEMACS.
 937 case "$opsys" in
 938   netbsd|openbsd)
 939    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 940 esac
 941
 942
 943 C_SWITCH_MACHINE=
 944 if test "$machine" = "alpha"; then
 945   AC_CHECK_DECL([__ELF__])
 946   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 947     ## With ELF, make sure that all common symbols get allocated to in the
 948     ## data section.  Otherwise, the dump of temacs may miss variables in
 949     ## the shared library that have been initialized.  For example, with
 950     ## GNU libc, __malloc_initialized would normally be resolved to the
 951     ## shared library's .bss section, which is fatal.
 952     if test "x$GCC" = "xyes"; then
 953       C_SWITCH_MACHINE="-fno-common"
 954     else
 955       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 956     fi
 957   else
 958     UNEXEC_OBJ=unexalpha.o
 959   fi
 960 fi
 961 AC_SUBST(C_SWITCH_MACHINE)
 962
 963 AC_SUBST(UNEXEC_OBJ)
 964
 965 C_SWITCH_SYSTEM=
 966 ## Some programs in src produce warnings saying certain subprograms
 967 ## are too complex and need a MAXMEM value greater than 2000 for
 968 ## additional optimization.  --nils@exp-math.uni-essen.de
 969 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 970   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 971 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 972 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 973 AC_SUBST(C_SWITCH_SYSTEM)
 974
 975
 976 LIBS_SYSTEM=
 977 case "$opsys" in
 978   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 979   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 980
 981   freebsd) LIBS_SYSTEM="-lutil" ;;
 982
 983   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 984
 985   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 986
 987   ## Motif needs -lgen.
 988   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 989 esac
 990 AC_SUBST(LIBS_SYSTEM)
 991
 992
 993 ### Make sure subsequent tests use flags consistent with the build flags.
 994
 995 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 996   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 997 else
 998   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 999 fi
1000
1001 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1002 AC_DEFUN([AC_TYPE_SIZE_T])
1003 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1004 AC_DEFUN([AC_TYPE_UID_T])
1005
1006 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1007 AC_SYS_LARGEFILE
1008
1009
1010 LIB_MATH=-lm
1011 LIB_STANDARD=
1012 START_FILES=
1013
1014 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1015 case $opsys in
1016   cygwin )
1017     LIB_MATH=
1018     START_FILES='pre-crt0.o'
1019     ;;
1020   darwin )
1021     ## Adding -lm confuses the dynamic linker, so omit it.
1022     LIB_MATH=
1023     START_FILES='pre-crt0.o'
1024     ;;
1025   freebsd )
1026     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1027     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1028     ;;
1029   gnu-linux | gnu-kfreebsd )
1030     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1031     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1032     ;;
1033   hpux10-20 | hpux11 )
1034     LIB_STANDARD=-lc
1035     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1036     ;;
1037   dnl NB this may be adjusted below.
1038   netbsd | openbsd )
1039     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1040     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1041     ;;
1042 esac
1043
1044 AC_SUBST(LIB_MATH)
1045 AC_SUBST(START_FILES)
1046
1047 dnl Not all platforms use crtn.o files.  Check if the current one does.
1048 crt_files=
1049
1050 for file in x $LIB_STANDARD $START_FILES; do
1051   case "$file" in
1052     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1053   esac
1054 done
1055
1056 if test "x$crt_files" != x; then
1057
1058   ## If user specified a crt-dir, use that unconditionally.
1059   crt_gcc=no
1060
1061   if test "X$CRT_DIR" = "X"; then
1062
1063     CRT_DIR=/usr/lib            # default
1064
1065     case "$canonical" in
1066       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1067       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1068       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1069       ## For anything else (eg /usr/lib32), it is up the user to specify
1070       ## the location (bug#5655).
1071       ## Test for crtn.o, not just the directory, because sometimes the
1072       ## directory exists but does not have the relevant files (bug#1287).
1073       ## FIXME better to test for binary compatibility somehow.
1074       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1075       ;;
1076
1077       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1078     esac
1079
1080     case "$opsys" in
1081       hpux10-20) CRT_DIR=/lib ;;
1082     esac
1083
1084     test "x${GCC}" = xyes && crt_gcc=yes
1085
1086   fi                            # CRT_DIR = ""
1087
1088   crt_missing=
1089
1090   for file in $crt_files; do
1091
1092     ## If we're using gcc, try to determine it automatically by asking
1093     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1094     ## system-dependent default from above.]
1095     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1096
1097        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1098        case "$crt_file" in
1099          */*)
1100            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1101            ;;
1102        esac
1103     fi
1104
1105     dnl We expect all the files to be in a single directory, so after the
1106     dnl first there is no point asking gcc.
1107     crt_gcc=no
1108
1109     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1110   done                          # $crt_files
1111
1112   test "x$crt_missing" = x || \
1113     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1114 Try using the --with-crt-dir option.])
1115
1116 fi                              # crt_files != ""
1117
1118 AC_SUBST(CRT_DIR)
1119
1120 case $opsys in
1121   netbsd | openbsd )
1122     if test -f $CRT_DIR/crti.o; then
1123
1124         test -f $CRT_DIR/crtn.o || \
1125           AC_MSG_ERROR([Required file not found: crtn.o])
1126
1127         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1128         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1129     fi
1130     ;;
1131 esac
1132
1133
1134 dnl This function definition taken from Gnome 2.0
1135 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1136 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1137 dnl also defines GSTUFF_PKG_ERRORS on error
1138 AC_DEFUN([PKG_CHECK_MODULES], [
1139   succeeded=no
1140
1141   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1142
1143   if test "$PKG_CONFIG" = "no" ; then
1144      ifelse([$4], , [AC_MSG_ERROR([
1145       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1146   else
1147      PKG_CONFIG_MIN_VERSION=0.9.0
1148      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1149         AC_MSG_CHECKING(for $2)
1150
1151         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1152            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1153            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1154             edit_cflags="
1155               s,///*,/,g
1156               s/^/ /
1157               s/ -I/ $isystem/g
1158               s/^ //
1159             "
1160             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1161             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1162             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1163             succeeded=yes
1164         else
1165             AC_MSG_RESULT(no)
1166             $1_CFLAGS=""
1167             $1_LIBS=""
1168             ## If we have a custom action on failure, don't print errors, but
1169             ## do set a variable so people can do so.
1170             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1171             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1172         fi
1173
1174         AC_SUBST($1_CFLAGS)
1175         AC_SUBST($1_LIBS)
1176      else
1177         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1178         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1179      fi
1180   fi
1181
1182   if test $succeeded = yes; then
1183      ifelse([$3], , :, [$3])
1184   else
1185      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1186   fi
1187 ])
1188
1189
1190 if test "${with_sound}" != "no"; then
1191   # Sound support for GNU/Linux and the free BSDs.
1192   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1193     have_sound_header=yes)
1194   # Emulation library used on NetBSD.
1195   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1196   AC_SUBST(LIBSOUND)
1197
1198   ALSA_REQUIRED=1.0.0
1199   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1200   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1201   if test $HAVE_ALSA = yes; then
1202     SAVE_CFLAGS="$CFLAGS"
1203     SAVE_LIBS="$LIBS"
1204     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1205     LIBS="$ALSA_LIBS $LIBS"
1206     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1207                     emacs_alsa_normal=yes,
1208                     emacs_alsa_normal=no)
1209     if test "$emacs_alsa_normal" != yes; then
1210       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1211                      [[snd_lib_error_set_handler (0);]])],
1212                      emacs_alsa_subdir=yes,
1213                      emacs_alsa_subdir=no)
1214       if test "$emacs_alsa_subdir" != yes; then
1215         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1216       fi
1217       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1218     fi
1219
1220     CFLAGS="$SAVE_CFLAGS"
1221     LIBS="$SAVE_LIBS"
1222     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1223     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1224     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1225   fi
1226
1227   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1228   dnl compiles only on the specified platforms.  For others, it
1229   dnl probably doesn't make sense to try.
1230   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1231      case "$opsys" in
1232        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1233        gnu-linux|freebsd|netbsd)
1234          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1235          ;;
1236      esac
1237   fi
1238
1239   AC_SUBST(CFLAGS_SOUND)
1240 fi
1241
1242 dnl checks for header files
1243 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1244   linux/version.h sys/systeminfo.h \
1245   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1246   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1247   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1248
1249 AC_MSG_CHECKING(if personality LINUX32 can be set)
1250 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1251                emacs_cv_personality_linux32=yes,
1252                emacs_cv_personality_linux32=no)
1253 AC_MSG_RESULT($emacs_cv_personality_linux32)
1254
1255 if test $emacs_cv_personality_linux32 = yes; then
1256   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1257             [Define to 1 if personality LINUX32 can be set.])
1258 fi
1259
1260 dnl On Solaris 8 there's a compilation warning for term.h because
1261 dnl it doesn't define `bool'.
1262 AC_CHECK_HEADERS(term.h, , , -)
1263 AC_HEADER_TIME
1264 AC_CHECK_DECLS([sys_siglist])
1265 if test $ac_cv_have_decl_sys_siglist != yes; then
1266   # For Tru64, at least:
1267   AC_CHECK_DECLS([__sys_siglist])
1268   if test $ac_cv_have_decl___sys_siglist = yes; then
1269     AC_DEFINE(sys_siglist, __sys_siglist,
1270               [Define to any substitute for sys_siglist.])
1271   fi
1272 fi
1273 AC_HEADER_SYS_WAIT
1274
1275 dnl Some systems have utime.h but don't declare the struct anyplace.
1276 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1277 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1278 #include <sys/time.h>
1279 #include <time.h>
1280 #else
1281 #ifdef HAVE_SYS_TIME_H
1282 #include <sys/time.h>
1283 #else
1284 #include <time.h>
1285 #endif
1286 #endif
1287 #ifdef HAVE_UTIME_H
1288 #include <utime.h>
1289 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1290   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1291 if test $emacs_cv_struct_utimbuf = yes; then
1292   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1293 fi
1294
1295 dnl Check for speed_t typedef.
1296 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1297   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1298     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1299 if test $emacs_cv_speed_t = yes; then
1300   AC_DEFINE(HAVE_SPEED_T, 1,
1301            [Define to 1 if `speed_t' is declared by <termios.h>.])
1302 fi
1303
1304 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1305 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1306 #include <sys/time.h>
1307 #include <time.h>
1308 #else
1309 #ifdef HAVE_SYS_TIME_H
1310 #include <sys/time.h>
1311 #else
1312 #include <time.h>
1313 #endif
1314 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1315   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1316 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1317 if test $emacs_cv_struct_timeval = yes; then
1318   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1319 fi
1320
1321 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1322 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1323 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1324   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1325 HAVE_EXCEPTION=$emacs_cv_struct_exception
1326 if test $emacs_cv_struct_exception != yes; then
1327   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1328 fi
1329
1330 AC_CHECK_HEADERS(sys/socket.h)
1331 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1332 #if HAVE_SYS_SOCKET_H
1333 #include <sys/socket.h>
1334 #endif])
1335 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1336 #if HAVE_SYS_SOCKET_H
1337 #include <sys/socket.h>
1338 #endif])
1339 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1340 #if HAVE_SYS_SOCKET_H
1341 #include <sys/socket.h>
1342 #endif])
1343 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1344
1345 dnl checks for structure members
1346 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1347                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1348                   struct ifreq.ifr_addr,
1349                   struct ifreq.ifr_addr.sa_len], , ,
1350                  [AC_INCLUDES_DEFAULT
1351 #if HAVE_SYS_SOCKET_H
1352 #include <sys/socket.h>
1353 #endif
1354 #if HAVE_NET_IF_H
1355 #include <net/if.h>
1356 #endif])
1357
1358 dnl checks for compiler characteristics
1359
1360 dnl Testing __STDC__ to determine prototype support isn't good enough.
1361 dnl DEC C, for instance, doesn't define it with default options, and
1362 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1363 dnl and void *.
1364 AC_C_PROTOTYPES
1365 AC_C_VOLATILE
1366 AC_C_CONST
1367 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1368   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1369                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1370 if test $emacs_cv_void_star = yes; then
1371   AC_DEFINE(POINTER_TYPE, void)
1372 else
1373   AC_DEFINE(POINTER_TYPE, char)
1374 fi
1375 AH_TEMPLATE(POINTER_TYPE,
1376             [Define as `void' if your compiler accepts `void *'; otherwise
1377              define as `char'.])dnl
1378
1379 dnl Check for endianness.
1380 AC_C_BIGENDIAN
1381
1382 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1383   [emacs_cv_attribute_aligned],
1384   [AC_COMPILE_IFELSE(
1385      [AC_LANG_PROGRAM(
1386         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1387         [[]])],
1388      [emacs_cv_attribute_aligned=yes],
1389      [emacs_cv_attribute_aligned=no])])
1390 if test $emacs_cv_attribute_aligned = yes; then
1391   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1392     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1393 fi
1394
1395 dnl check for Make feature
1396 AC_PROG_MAKE_SET
1397
1398 DEPFLAGS=
1399 MKDEPDIR=":"
1400 deps_frag=deps.mk
1401 dnl check for GNU Make if we have GCC and autodepend is on.
1402 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1403    AC_MSG_CHECKING([whether we are using GNU Make])
1404    HAVE_GNU_MAKE=no
1405    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1406    if test "x$testval" != x; then
1407       HAVE_GNU_MAKE=yes
1408    else
1409       ac_enable_autodepend=no
1410    fi
1411    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1412    if test $HAVE_GNU_MAKE = yes; then
1413       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1414       SAVE_CFLAGS="$CFLAGS"
1415       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1416       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1417       CFLAGS="$SAVE_CFLAGS"
1418       test -f deps.d || ac_enable_autodepend=no
1419       rm -rf deps.d
1420       AC_MSG_RESULT([$ac_enable_autodepend])
1421    fi
1422    if test $ac_enable_autodepend = yes; then
1423       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1424       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1425       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1426       deps_frag=autodeps.mk
1427    fi
1428 fi
1429 deps_frag=$srcdir/src/$deps_frag
1430 AC_SUBST(MKDEPDIR)
1431 AC_SUBST(DEPFLAGS)
1432 AC_SUBST_FILE(deps_frag)
1433
1434
1435 lisp_frag=$srcdir/src/lisp.mk
1436 AC_SUBST_FILE(lisp_frag)
1437
1438
1439 dnl checks for operating system services
1440 AC_SYS_LONG_FILE_NAMES
1441
1442 #### Choose a window system.
1443
1444 AC_PATH_X
1445 if test "$no_x" = yes; then
1446   window_system=none
1447 else
1448   window_system=x11
1449 fi
1450
1451 LD_SWITCH_X_SITE_RPATH=
1452 if test "${x_libraries}" != NONE; then
1453   if test -n "${x_libraries}"; then
1454     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1455     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1456   fi
1457   x_default_search_path=""
1458   x_search_path=${x_libraries}
1459   if test -z "${x_search_path}"; then
1460     x_search_path=/usr/lib
1461   fi
1462   for x_library in `echo ${x_search_path}: | \
1463                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1464     x_search_path="\
1465 ${x_library}/X11/%L/%T/%N%C%S:\
1466 ${x_library}/X11/%l/%T/%N%C%S:\
1467 ${x_library}/X11/%T/%N%C%S:\
1468 ${x_library}/X11/%L/%T/%N%S:\
1469 ${x_library}/X11/%l/%T/%N%S:\
1470 ${x_library}/X11/%T/%N%S"
1471     if test x"${x_default_search_path}" = x; then
1472       x_default_search_path=${x_search_path}
1473     else
1474       x_default_search_path="${x_search_path}:${x_default_search_path}"
1475     fi
1476   done
1477 fi
1478 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1479
1480 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1481   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1482 fi
1483
1484 if test x"${x_includes}" = x; then
1485   bitmapdir=/usr/include/X11/bitmaps
1486 else
1487   # accumulate include directories that have X11 bitmap subdirectories
1488   bmd_acc="dummyval"
1489   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1490     if test -d "${bmd}/X11/bitmaps"; then
1491       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1492     fi
1493     if test -d "${bmd}/bitmaps"; then
1494       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1495     fi
1496   done
1497   if test ${bmd_acc} != "dummyval"; then
1498     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1499   fi
1500 fi
1501
1502 HAVE_NS=no
1503 NS_IMPL_COCOA=no
1504 NS_IMPL_GNUSTEP=no
1505 tmp_CPPFLAGS="$CPPFLAGS"
1506 tmp_CFLAGS="$CFLAGS"
1507 CPPFLAGS="$CPPFLAGS -x objective-c"
1508 CFLAGS="$CFLAGS -x objective-c"
1509 TEMACS_LDFLAGS2="\${LDFLAGS}"
1510 GNU_OBJC_CFLAGS=
1511 if test "${with_ns}" != no; then
1512   if test "${opsys}" = darwin; then
1513      NS_IMPL_COCOA=yes
1514      ns_appdir=`pwd`/nextstep/Emacs.app
1515      ns_appbindir=${ns_appdir}/Contents/MacOS
1516      ns_appresdir=${ns_appdir}/Contents/Resources
1517      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1518   elif test -f $GNUSTEP_CONFIG_FILE; then
1519      NS_IMPL_GNUSTEP=yes
1520      ns_appdir=`pwd`/nextstep/Emacs.app
1521      ns_appbindir=${ns_appdir}
1522      ns_appresdir=${ns_appdir}/Resources
1523      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1524      dnl FIXME sourcing this several times in subshells seems inefficient.
1525      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1526      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1527      dnl I seemed to need these as well with GNUstep-startup 0.25.
1528      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1529      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1530      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1531        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1532      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1533        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1534      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1535      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1536      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1537      LIB_STANDARD=
1538      START_FILES=
1539      TEMACS_LDFLAGS2=
1540      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1541      dnl If they had chosen to either define it or not, we could have
1542      dnl just used AC_CHECK_DECL here.
1543      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1544        emacs_cv_objc_exceptions,
1545 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1546 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1547 1;
1548 #else
1549 fail;
1550 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1551      if test $emacs_cv_objc_exceptions = yes; then
1552        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1553        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1554          [Define if GNUstep uses ObjC exceptions.])
1555        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1556      fi
1557   fi
1558
1559   dnl This is only used while we test the NS headers, it gets reset below.
1560   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1561
1562   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1563                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1564   files are missing or cannot be compiled.])])
1565   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1566                                      [NSInteger i;])],
1567                     ns_have_nsinteger=yes,
1568                     ns_have_nsinteger=no)
1569   if test $ns_have_nsinteger = yes; then
1570     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1571   fi
1572 fi
1573 AC_SUBST(TEMACS_LDFLAGS2)
1574
1575 INSTALL_ARCH_INDEP_EXTRA=install-etc
1576 ns_self_contained=no
1577 ns_frag=/dev/null
1578 NS_OBJ=
1579 NS_OBJC_OBJ=
1580 if test "${HAVE_NS}" = yes; then
1581   if test "$with_toolkit_scroll_bars" = "no"; then
1582     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1583   fi
1584
1585   window_system=nextstep
1586   with_xft=no
1587   # set up packaging dirs
1588   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1589      ns_self_contained=yes
1590      prefix=${ns_appresdir}
1591      exec_prefix=${ns_appbindir}
1592      dnl This one isn't really used, only archlibdir is.
1593      libexecdir="\${ns_appbindir}/libexec"
1594      archlibdir="\${ns_appbindir}/libexec"
1595      docdir="\${ns_appresdir}/etc"
1596      etcdir="\${ns_appresdir}/etc"
1597      dnl FIXME maybe set datarootdir instead.
1598      dnl That would also get applications, icons, man.
1599      infodir="\${ns_appresdir}/info"
1600      mandir="\${ns_appresdir}/man"
1601      lispdir="\${ns_appresdir}/lisp"
1602      leimdir="\${ns_appresdir}/leim"
1603      INSTALL_ARCH_INDEP_EXTRA=
1604   fi
1605   ns_frag=$srcdir/src/ns.mk
1606   NS_OBJ="fontset.o fringe.o image.o"
1607   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1608 fi
1609 CFLAGS="$tmp_CFLAGS"
1610 CPPFLAGS="$tmp_CPPFLAGS"
1611 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1612 AC_SUBST(ns_self_contained)
1613 AC_SUBST(NS_OBJ)
1614 AC_SUBST(NS_OBJC_OBJ)
1615 AC_SUBST(LIB_STANDARD)
1616 AC_SUBST_FILE(ns_frag)
1617
1618 case "${window_system}" in
1619   x11 )
1620     HAVE_X_WINDOWS=yes
1621     HAVE_X11=yes
1622     case "${with_x_toolkit}" in
1623       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1624       motif ) USE_X_TOOLKIT=MOTIF ;;
1625       gtk ) with_gtk=yes
1626 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1627 dnl USE_X_TOOLKIT is set.
1628             USE_X_TOOLKIT=none ;;
1629       gtk3 ) with_gtk3=yes
1630              USE_X_TOOLKIT=none ;;
1631       no ) USE_X_TOOLKIT=none ;;
1632 dnl If user did not say whether to use a toolkit, make this decision later:
1633 dnl use the toolkit if we have gtk, or X11R5 or newer.
1634       * ) USE_X_TOOLKIT=maybe ;;
1635     esac
1636   ;;
1637   nextstep | none )
1638     HAVE_X_WINDOWS=no
1639     HAVE_X11=no
1640     USE_X_TOOLKIT=none
1641   ;;
1642 esac
1643
1644 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1645    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1646    if test "$HAVE_XSERVER" = true ||
1647       test -n "$DISPLAY" ||
1648       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1649         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1650 were found.  You should install the relevant development files for X
1651 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1652 sure you have development files for image handling, i.e.
1653 tiff, gif, jpeg, png and xpm.
1654 If you are sure you want Emacs compiled without X window support, pass
1655   --without-x
1656 to configure.])
1657    fi
1658 fi
1659
1660 ### If we're using X11, we should use the X menu package.
1661 HAVE_MENUS=no
1662 case ${HAVE_X11} in
1663   yes ) HAVE_MENUS=yes ;;
1664 esac
1665
1666 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1667 # Assume not, until told otherwise.
1668 GNU_MALLOC=yes
1669
1670 AC_CACHE_CHECK(
1671   [whether malloc is Doug Lea style],
1672   [emacs_cv_var_doug_lea_malloc],
1673   [AC_LINK_IFELSE(
1674      [AC_LANG_PROGRAM(
1675         [[#include <malloc.h>
1676           static void hook (void) {}]],
1677         [[malloc_set_state (malloc_get_state ());
1678           __after_morecore_hook = hook;
1679           __malloc_initialize_hook = hook;]])],
1680      [emacs_cv_var_doug_lea_malloc=yes],
1681      [emacs_cv_var_doug_lea_malloc=no])])
1682 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1683
1684
1685 dnl See comments in aix4-2.h about maybe using system malloc there.
1686 system_malloc=no
1687 case "$opsys" in
1688   ## darwin ld insists on the use of malloc routines in the System framework.
1689   darwin|sol2-10) system_malloc=yes ;;
1690 esac
1691
1692 if test "${system_malloc}" = "yes"; then
1693   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1694   GNU_MALLOC=no
1695   GNU_MALLOC_reason="
1696     (The GNU allocators don't work with this system configuration.)"
1697   GMALLOC_OBJ=
1698   VMLIMIT_OBJ=
1699 else
1700   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1701   VMLIMIT_OBJ=vm-limit.o
1702 fi
1703 AC_SUBST(GMALLOC_OBJ)
1704 AC_SUBST(VMLIMIT_OBJ)
1705
1706 if test "$doug_lea_malloc" = "yes" ; then
1707   if test "$GNU_MALLOC" = yes ; then
1708     GNU_MALLOC_reason="
1709       (Using Doug Lea's new malloc from the GNU C Library.)"
1710   fi
1711   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1712             [Define to 1 if you are using the GNU C Library.])
1713
1714   ## Use mmap directly for allocating larger buffers.
1715   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1716   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1717   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1718   case "$opsys" in
1719     gnu*) REL_ALLOC=no ;;
1720   esac
1721 fi
1722
1723 if test x"${REL_ALLOC}" = x; then
1724   REL_ALLOC=${GNU_MALLOC}
1725 fi
1726
1727 use_mmap_for_buffers=no
1728 case "$opsys" in
1729   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1730 esac
1731
1732 AC_FUNC_MMAP
1733 if test $use_mmap_for_buffers = yes; then
1734   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1735   REL_ALLOC=no
1736 fi
1737
1738 LIBS="$LIBS_SYSTEM $LIBS"
1739
1740 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1741 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1742 AC_CHECK_LIB(dnet, dnet_ntoa)
1743 dnl This causes -lresolv to get used in subsequent tests,
1744 dnl which causes failures on some systems such as HPUX 9.
1745 dnl AC_CHECK_LIB(resolv, gethostbyname)
1746
1747 dnl FIXME replace main with a function we actually want from this library.
1748 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1749
1750 dnl Check if pthreads is available.
1751 LIB_PTHREAD=
1752 AC_CHECK_HEADERS(pthread.h)
1753 if test "$ac_cv_header_pthread_h"; then
1754   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1755   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1756   dnl testing for pthread_self if Emacs uses gmalloc.c.
1757   if test "$GMALLOC_OBJ" = gmalloc.o; then
1758     emacs_pthread_function=pthread_atfork
1759   else
1760     emacs_pthread_function=pthread_self
1761   fi
1762   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1763 fi
1764 if test "$HAVE_PTHREAD" = yes; then
1765   case "${canonical}" in
1766     *-hpux*) ;;
1767     *) LIB_PTHREAD="-lpthread"
1768        LIBS="$LIB_PTHREAD $LIBS" ;;
1769   esac
1770   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1771 fi
1772 AC_SUBST([LIB_PTHREAD])
1773
1774 AC_CHECK_LIB(pthreads, cma_open)
1775
1776 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1777 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1778 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1779 ## added to LIBS in configure would never contain the pthreads part,
1780 ## but the value used in Makefiles might.  FIXME?
1781 ##
1782 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1783 ## be harmless on older versions of X where it happens to exist.
1784 test "$opsys" = "aix4-2" && \
1785   test $ac_cv_lib_pthreads_cma_open = yes && \
1786   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1787
1788 dnl Check for need for bigtoc support on IBM AIX
1789
1790 case ${host_os} in
1791 aix*)
1792   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1793     case $GCC in
1794     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1795     *) gdb_cv_bigtoc=-bbigtoc ;;
1796     esac
1797
1798     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1799     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1800   ])
1801   ;;
1802 esac
1803
1804 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1805 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1806 # REAL_CPPFLAGS later on.
1807
1808 REAL_CFLAGS="$CFLAGS"
1809 REAL_CPPFLAGS="$CPPFLAGS"
1810
1811 if test "${HAVE_X11}" = "yes"; then
1812   DEFS="$C_SWITCH_X_SITE $DEFS"
1813   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1814   LIBS="-lX11 $LIBS"
1815   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1816   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1817
1818   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1819   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1820   # but it's more convenient here to set LD_RUN_PATH since this
1821   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1822   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1823     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1824     export LD_RUN_PATH
1825   fi
1826
1827   if test "${opsys}" = "gnu-linux"; then
1828     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1829     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1830      [[XOpenDisplay ("foo");]])],
1831      [xgnu_linux_first_failure=no],
1832      [xgnu_linux_first_failure=yes])
1833     if test "${xgnu_linux_first_failure}" = "yes"; then
1834       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1835       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1836       OLD_CPPFLAGS="$CPPFLAGS"
1837       OLD_LIBS="$LIBS"
1838       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1839       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1840       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1841       LIBS="$LIBS -b i486-linuxaout"
1842       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1843        [[XOpenDisplay ("foo");]])],
1844        [xgnu_linux_second_failure=no],
1845        [xgnu_linux_second_failure=yes])
1846       if test "${xgnu_linux_second_failure}" = "yes"; then
1847         # If we get the same failure with -b, there is no use adding -b.
1848         # So take it out.  This plays safe.
1849         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1850         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1851         CPPFLAGS="$OLD_CPPFLAGS"
1852         LIBS="$OLD_LIBS"
1853         AC_MSG_RESULT(no)
1854       else
1855         AC_MSG_RESULT(yes)
1856       fi
1857     else
1858       AC_MSG_RESULT(no)
1859     fi
1860   fi
1861
1862   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1863   # header files included from there.
1864   AC_MSG_CHECKING(for Xkb)
1865   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1866 #include <X11/XKBlib.h>]],
1867         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1868         emacs_xkb=yes, emacs_xkb=no)
1869   AC_MSG_RESULT($emacs_xkb)
1870   if test $emacs_xkb = yes; then
1871     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1872   fi
1873
1874   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1875 XScreenNumberOfScreen)
1876 fi
1877
1878 if test "${window_system}" = "x11"; then
1879   AC_MSG_CHECKING(X11 version 6)
1880   AC_CACHE_VAL(emacs_cv_x11_version_6,
1881   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1882 [[#if XlibSpecificationRelease < 6
1883 fail;
1884 #endif
1885 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1886   if test $emacs_cv_x11_version_6 = yes; then
1887     AC_MSG_RESULT(6 or newer)
1888     AC_DEFINE(HAVE_X11R6, 1,
1889               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1890     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1891     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1892     ## XIM support.
1893     case "$opsys" in
1894       sol2-*) : ;;
1895       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1896            [Define if you have usable X11R6-style XIM support.])
1897          ;;
1898     esac
1899   else
1900     AC_MSG_RESULT(before 6)
1901   fi
1902 fi
1903
1904
1905 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1906 HAVE_RSVG=no
1907 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1908   if test "${with_rsvg}" != "no"; then
1909     RSVG_REQUIRED=2.11.0
1910     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1911
1912     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1913     AC_SUBST(RSVG_CFLAGS)
1914     AC_SUBST(RSVG_LIBS)
1915
1916     if test $HAVE_RSVG = yes; then
1917       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1918       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1919       LIBS="$RSVG_LIBS $LIBS"
1920     fi
1921   fi
1922 fi
1923
1924 HAVE_IMAGEMAGICK=no
1925 if test "${HAVE_X11}" = "yes"; then
1926   if test "${with_imagemagick}" != "no"; then
1927     ## 6.2.8 is the earliest version known to work, but earlier versions
1928     ## might work - let us know if you find one.
1929     ## 6.0.7 does not work.  See bug#7955.
1930     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1931     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1932     AC_SUBST(IMAGEMAGICK_CFLAGS)
1933     AC_SUBST(IMAGEMAGICK_LIBS)
1934
1935     if test $HAVE_IMAGEMAGICK = yes; then
1936       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1937       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1938       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1939       AC_CHECK_FUNCS(MagickExportImagePixels)
1940     fi
1941   fi
1942 fi
1943
1944
1945 HAVE_GTK=no
1946 GTK_OBJ=
1947 if test "${with_gtk3}" = "yes"; then
1948   GLIB_REQUIRED=2.28
1949   GTK_REQUIRED=3.0
1950   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1951
1952   dnl Checks for libraries.
1953   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1954   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1955      AC_MSG_ERROR($GTK_PKG_ERRORS)
1956   fi
1957   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1958   GTK_OBJ=emacsgtkfixed.o
1959 fi
1960
1961 if test "$pkg_check_gtk" != "yes"; then
1962   HAVE_GTK=no
1963 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1964   GLIB_REQUIRED=2.10
1965   GTK_REQUIRED=2.10
1966   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1967
1968   dnl Checks for libraries.
1969   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1970   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1971      AC_MSG_ERROR($GTK_PKG_ERRORS)
1972   fi
1973 fi
1974 fi
1975
1976 if test x"$pkg_check_gtk" = xyes; then
1977
1978   AC_SUBST(GTK_CFLAGS)
1979   AC_SUBST(GTK_LIBS)
1980   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1981   CFLAGS="$CFLAGS $GTK_CFLAGS"
1982   LIBS="$GTK_LIBS $LIBS"
1983   dnl Try to compile a simple GTK program.
1984   GTK_COMPILES=no
1985   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1986   if test "${GTK_COMPILES}" != "yes"; then
1987     if test "$USE_X_TOOLKIT" != "maybe"; then
1988       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1989     fi
1990   else
1991     HAVE_GTK=yes
1992     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1993     GTK_OBJ="gtkutil.o $GTK_OBJ"
1994     USE_X_TOOLKIT=none
1995     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1996       :
1997     else
1998       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1999        closing open displays.  This is no problem if you just use
2000        one display, but if you use more than one and close one of them
2001        Emacs may crash.]])
2002       sleep 3
2003     fi
2004   fi
2005
2006 fi
2007 AC_SUBST(GTK_OBJ)
2008
2009
2010 if test "${HAVE_GTK}" = "yes"; then
2011
2012   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2013   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2014   if test "$with_toolkit_scroll_bars" != no; then
2015     with_toolkit_scroll_bars=yes
2016   fi
2017
2018   dnl  Check if we have the old file selection dialog declared and
2019   dnl  in the link library.  In 2.x it may be in the library,
2020   dnl  but not declared if deprecated featured has been selected out.
2021   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2022   HAVE_GTK_FILE_SELECTION=no
2023   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2024                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2025 #include <gtk/gtk.h>])
2026   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2027     AC_CHECK_FUNCS(gtk_file_selection_new)
2028   fi
2029
2030
2031   dnl Check for functions introduced in 2.14 and later.
2032   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2033                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2034                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2035                  gtk_orientable_set_orientation \
2036                  gtk_window_set_has_resize_grip)
2037 fi
2038
2039 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2040 dnl other platforms.
2041 HAVE_DBUS=no
2042 DBUS_OBJ=
2043 if test "${with_dbus}" = "yes"; then
2044    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2045    if test "$HAVE_DBUS" = yes; then
2046      LIBS="$LIBS $DBUS_LIBS"
2047      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2048      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2049      dnl dbus_validate_* have been introduced in D-Bus 1.5.12.
2050      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2051                     dbus_validate_bus_name \
2052                     dbus_validate_path \
2053                     dbus_validate_interface \
2054                     dbus_validate_member)
2055      DBUS_OBJ=dbusbind.o
2056    fi
2057 fi
2058 AC_SUBST(DBUS_OBJ)
2059
2060 dnl GSettings has been tested under GNU/Linux only.
2061 HAVE_GSETTINGS=no
2062 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2063    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2064    if test "$HAVE_GSETTINGS" = "yes"; then
2065       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2066       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2067       SETTINGS_LIBS="$GSETTINGS_LIBS"
2068    fi
2069 fi
2070
2071 dnl GConf has been tested under GNU/Linux only.
2072 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2073 HAVE_GCONF=no
2074 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2075    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2076    if test "$HAVE_GCONF" = yes; then
2077       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2078       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2079       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2080       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2081    fi
2082 fi
2083
2084 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2085     SAVE_CFLAGS="$CFLAGS"
2086     SAVE_LIBS="$LIBS"
2087     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2088     LIBS="$SETTINGS_LIBS $LIBS"
2089     AC_CHECK_FUNCS([g_type_init])
2090     CFLAGS="$SAVE_CFLAGS"
2091     LIBS="$SAVE_LIBS"
2092 fi
2093 AC_SUBST(SETTINGS_CFLAGS)
2094 AC_SUBST(SETTINGS_LIBS)
2095
2096
2097 dnl SELinux is available for GNU/Linux only.
2098 HAVE_LIBSELINUX=no
2099 LIBSELINUX_LIBS=
2100 if test "${with_selinux}" = "yes"; then
2101    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2102    if test "$HAVE_LIBSELINUX" = yes; then
2103       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2104       LIBSELINUX_LIBS=-lselinux
2105    fi
2106 fi
2107 AC_SUBST(LIBSELINUX_LIBS)
2108
2109 HAVE_GNUTLS=no
2110 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2111 if test "${with_gnutls}" = "yes" ; then
2112   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2113   if test "${HAVE_GNUTLS}" = "yes"; then
2114     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2115   fi
2116
2117   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2118   LIBS="$LIBGNUTLS_LIBS $LIBS"
2119   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2120
2121   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2122     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2123   fi
2124 fi
2125
2126 AC_SUBST(LIBGNUTLS_LIBS)
2127 AC_SUBST(LIBGNUTLS_CFLAGS)
2128
2129 dnl Do not put whitespace before the #include statements below.
2130 dnl Older compilers (eg sunos4 cc) choke on it.
2131 HAVE_XAW3D=no
2132 LUCID_LIBW=
2133 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2134   if test "$with_xaw3d" != no; then
2135     AC_MSG_CHECKING(for xaw3d)
2136     AC_CACHE_VAL(emacs_cv_xaw3d,
2137     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2138 #include <X11/Intrinsic.h>
2139 #include <X11/Xaw3d/Simple.h>]],
2140       [[]])],
2141       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2142                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2143       emacs_cv_xaw3d=no)])
2144   else
2145     emacs_cv_xaw3d=no
2146   fi
2147   if test $emacs_cv_xaw3d = yes; then
2148     AC_MSG_RESULT([yes; using Lucid toolkit])
2149     USE_X_TOOLKIT=LUCID
2150     HAVE_XAW3D=yes
2151     LUCID_LIBW=-lXaw3d
2152     AC_DEFINE(HAVE_XAW3D, 1,
2153               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2154   else
2155     AC_MSG_RESULT(no)
2156     AC_MSG_CHECKING(for libXaw)
2157     AC_CACHE_VAL(emacs_cv_xaw,
2158     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2159 #include <X11/Intrinsic.h>
2160 #include <X11/Xaw/Simple.h>]],
2161       [[]])],
2162       emacs_cv_xaw=yes,
2163       emacs_cv_xaw=no)])
2164     if test $emacs_cv_xaw = yes; then
2165       AC_MSG_RESULT([yes; using Lucid toolkit])
2166       USE_X_TOOLKIT=LUCID
2167       LUCID_LIBW=-lXaw
2168     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2169       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2170     else
2171       AC_MSG_ERROR([No X toolkit could be found.
2172 If you are sure you want Emacs compiled without an X toolkit, pass
2173   --with-x-toolkit=no
2174 to configure.  Otherwise, install the development libraries for the toolkit
2175 that you want to use (e.g. Gtk+) and re-run configure.])
2176     fi
2177   fi
2178 fi
2179
2180 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2181
2182 LIBXTR6=
2183 if test "${USE_X_TOOLKIT}" != "none"; then
2184   AC_MSG_CHECKING(X11 toolkit version)
2185   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2186   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2187 [[#if XtSpecificationRelease < 6
2188 fail;
2189 #endif
2190 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2191   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2192   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2193     AC_MSG_RESULT(6 or newer)
2194     AC_DEFINE(HAVE_X11XTR6, 1,
2195               [Define to 1 if you have the X11R6 or newer version of Xt.])
2196     LIBXTR6="-lSM -lICE"
2197     case "$opsys" in
2198       ## Use libw.a along with X11R6 Xt.
2199       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2200     esac
2201   else
2202     AC_MSG_RESULT(before 6)
2203   fi
2204
2205 dnl If using toolkit, check whether libXmu.a exists.
2206 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2207   OLDLIBS="$LIBS"
2208   if test x$HAVE_X11XTR6 = xyes; then
2209     LIBS="-lXt -lSM -lICE $LIBS"
2210   else
2211     LIBS="-lXt $LIBS"
2212   fi
2213   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2214   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2215 fi
2216 AC_SUBST(LIBXTR6)
2217
2218 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2219 dnl Why not just test for libxmu in the normal way?
2220 LIBXMU=-lXmu
2221 case $opsys in
2222   ## These systems don't supply Xmu.
2223   hpux* | aix4-2 )
2224     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2225     ;;
2226 esac
2227 AC_SUBST(LIBXMU)
2228
2229 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2230 if test "${HAVE_X11}" = "yes"; then
2231   if test "${USE_X_TOOLKIT}" != "none"; then
2232     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2233   fi
2234 fi
2235
2236 LIBXP=
2237 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2238   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2239   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2240     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2241 int x = 5;
2242 #else
2243 Motif version prior to 2.1.
2244 #endif]])],
2245     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2246   if test $emacs_cv_motif_version_2_1 = yes; then
2247     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2248   else
2249     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2250     # We put this in CFLAGS temporarily to precede other -I options
2251     # that might be in CFLAGS temporarily.
2252     # We put this in CPPFLAGS where it precedes the other -I options.
2253     OLD_CPPFLAGS=$CPPFLAGS
2254     OLD_CFLAGS=$CFLAGS
2255     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2256     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2257     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2258       [[int x = 5;]])],
2259       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2260     if test $emacs_cv_lesstif = yes; then
2261       # Make sure this -I option remains in CPPFLAGS after it is set
2262       # back to REAL_CPPFLAGS.
2263       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2264       # have those other -I options anyway.  Ultimately, having this
2265       # directory ultimately in CPPFLAGS will be enough.
2266       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2267       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2268     else
2269       CFLAGS=$OLD_CFLAGS
2270       CPPFLAGS=$OLD_CPPFLAGS
2271     fi
2272   fi
2273   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2274     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2275 fi
2276
2277 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2278 dnl using Motif or Xaw3d is available, and unless
2279 dnl --with-toolkit-scroll-bars=no was specified.
2280
2281 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2282             [Define to 1 if we should use toolkit scroll bars.])dnl
2283 USE_TOOLKIT_SCROLL_BARS=no
2284 if test "${with_toolkit_scroll_bars}" != "no"; then
2285   if test "${USE_X_TOOLKIT}" != "none"; then
2286     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2287       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2288       HAVE_XAW3D=no
2289       USE_TOOLKIT_SCROLL_BARS=yes
2290     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2291       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2292       USE_TOOLKIT_SCROLL_BARS=yes
2293     fi
2294   elif test "${HAVE_GTK}" = "yes"; then
2295     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2296     USE_TOOLKIT_SCROLL_BARS=yes
2297   elif test "${HAVE_NS}" = "yes"; then
2298     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2299     USE_TOOLKIT_SCROLL_BARS=yes
2300   fi
2301 fi
2302
2303 dnl See if XIM is available.
2304 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2305           #include <X11/Xlib.h>
2306           #include <X11/Xresource.h>]],
2307          [[XIMProc  callback;]])],
2308          [HAVE_XIM=yes
2309          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2310          HAVE_XIM=no)
2311
2312 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2313
2314 if test "${with_xim}" != "no"; then
2315   AC_DEFINE(USE_XIM, 1,
2316             [Define to 1 if we should use XIM, if it is available.])
2317 fi
2318
2319
2320 if test "${HAVE_XIM}" != "no"; then
2321   late_CFLAGS=$CFLAGS
2322   if test "$GCC" = yes; then
2323     CFLAGS="$CFLAGS --pedantic-errors"
2324   fi
2325   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2326 #include <X11/Xlib.h>
2327 #include <X11/Xresource.h>]],
2328 [[Display *display;
2329 XrmDatabase db;
2330 char *res_name;
2331 char *res_class;
2332 XIMProc  callback;
2333 XPointer *client_data;
2334 #ifndef __GNUC__
2335 /* If we're not using GCC, it's probably not XFree86, and this is
2336    probably right, but we can't use something like --pedantic-errors.  */
2337 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2338                                            char*, XIMProc, XPointer*);
2339 #endif
2340 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2341    client_data);]])],
2342     [emacs_cv_arg6_star=yes])
2343   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2344          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2345 either XPointer or XPointer*.])dnl
2346   if test "$emacs_cv_arg6_star" = yes; then
2347     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2348   else
2349     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2350   fi
2351   CFLAGS=$late_CFLAGS
2352 fi
2353
2354 ### Start of font-backend (under any platform) section.
2355 # (nothing here yet -- this is a placeholder)
2356 ### End of font-backend (under any platform) section.
2357
2358 ### Start of font-backend (under X11) section.
2359 if test "${HAVE_X11}" = "yes"; then
2360    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2361
2362    ## Use -lXft if available, unless `--with-xft=no'.
2363    HAVE_XFT=maybe
2364     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2365       with_xft="no";
2366     fi
2367     if test "x${with_xft}" != "xno"; then
2368
2369       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2370       ## Because xftfont.c uses XRenderQueryExtension, we also
2371       ## need to link to -lXrender.
2372       HAVE_XRENDER=no
2373       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2374       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2375         OLD_CPPFLAGS="$CPPFLAGS"
2376         OLD_CFLAGS="$CFLAGS"
2377         OLD_LIBS="$LIBS"
2378         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2379         CFLAGS="$CFLAGS $XFT_CFLAGS"
2380         XFT_LIBS="-lXrender $XFT_LIBS"
2381         LIBS="$XFT_LIBS $LIBS"
2382         AC_CHECK_HEADER(X11/Xft/Xft.h,
2383           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2384
2385         if test "${HAVE_XFT}" = "yes"; then
2386           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2387             AC_SUBST(XFT_LIBS)
2388           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2389         else
2390           CPPFLAGS="$OLD_CPPFLAGS"
2391           CFLAGS="$OLD_CFLAGS"
2392           LIBS="$OLD_LIBS"
2393         fi                        # "${HAVE_XFT}" = "yes"
2394       fi                          # "$HAVE_XFT" != no
2395     fi                            # "x${with_xft}" != "xno"
2396
2397     ## We used to allow building with FreeType and without Xft.
2398     ## However, the ftx font backend driver is not in good shape.
2399     if test "$HAVE_XFT" != "yes"; then
2400        dnl For the "Does Emacs use" message at the end.
2401        HAVE_XFT=no
2402        HAVE_FREETYPE=no
2403     else
2404        dnl Strict linkers fail with
2405        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2406        dnl if -lfreetype is not specified.
2407        dnl The following is needed to set FREETYPE_LIBS.
2408        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2409                          HAVE_FREETYPE=no)
2410
2411        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2412     fi
2413
2414     HAVE_LIBOTF=no
2415     if test "${HAVE_FREETYPE}" = "yes"; then
2416       AC_DEFINE(HAVE_FREETYPE, 1,
2417                 [Define to 1 if using the freetype and fontconfig libraries.])
2418       if test "${with_libotf}" != "no"; then
2419         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2420                           HAVE_LIBOTF=no)
2421         if test "$HAVE_LIBOTF" = "yes"; then
2422           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2423           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2424                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2425                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2426           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2427             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2428                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2429           fi
2430         fi
2431       fi
2432     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2433     dnl Does the new font backend require it, or can it work without it?
2434     fi
2435
2436     HAVE_M17N_FLT=no
2437     if test "${HAVE_LIBOTF}" = yes; then
2438       if test "${with_m17n_flt}" != "no"; then
2439         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2440         if test "$HAVE_M17N_FLT" = "yes"; then
2441           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2442         fi
2443       fi
2444     fi
2445 else
2446     HAVE_XFT=no
2447     HAVE_FREETYPE=no
2448     HAVE_LIBOTF=no
2449     HAVE_M17N_FLT=no
2450 fi
2451
2452 ### End of font-backend (under X11) section.
2453
2454 AC_SUBST(FREETYPE_CFLAGS)
2455 AC_SUBST(FREETYPE_LIBS)
2456 AC_SUBST(FONTCONFIG_CFLAGS)
2457 AC_SUBST(FONTCONFIG_LIBS)
2458 AC_SUBST(LIBOTF_CFLAGS)
2459 AC_SUBST(LIBOTF_LIBS)
2460 AC_SUBST(M17N_FLT_CFLAGS)
2461 AC_SUBST(M17N_FLT_LIBS)
2462
2463 ### Use -lXpm if available, unless `--with-xpm=no'.
2464 HAVE_XPM=no
2465 LIBXPM=
2466 if test "${HAVE_X11}" = "yes"; then
2467   if test "${with_xpm}" != "no"; then
2468     AC_CHECK_HEADER(X11/xpm.h,
2469       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2470     if test "${HAVE_XPM}" = "yes"; then
2471       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2472       AC_EGREP_CPP(no_return_alloc_pixels,
2473       [#include "X11/xpm.h"
2474 #ifndef XpmReturnAllocPixels
2475 no_return_alloc_pixels
2476 #endif
2477       ], HAVE_XPM=no, HAVE_XPM=yes)
2478
2479       if test "${HAVE_XPM}" = "yes"; then
2480         AC_MSG_RESULT(yes)
2481       else
2482         AC_MSG_RESULT(no)
2483       fi
2484     fi
2485   fi
2486
2487   if test "${HAVE_XPM}" = "yes"; then
2488     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2489     LIBXPM=-lXpm
2490   fi
2491 fi
2492 AC_SUBST(LIBXPM)
2493
2494 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2495 HAVE_JPEG=no
2496 LIBJPEG=
2497 if test "${HAVE_X11}" = "yes"; then
2498   if test "${with_jpeg}" != "no"; then
2499     dnl Checking for jpeglib.h can lose because of a redefinition of
2500     dnl  HAVE_STDLIB_H.
2501     AC_CHECK_HEADER(jerror.h,
2502       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2503   fi
2504
2505   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2506   if test "${HAVE_JPEG}" = "yes"; then
2507     AC_DEFINE(HAVE_JPEG)
2508     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2509         [#include <jpeglib.h>
2510          version=JPEG_LIB_VERSION
2511 ],
2512         [AC_DEFINE(HAVE_JPEG)],
2513         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2514         HAVE_JPEG=no])
2515   fi
2516   if test "${HAVE_JPEG}" = "yes"; then
2517     LIBJPEG=-ljpeg
2518   fi
2519 fi
2520 AC_SUBST(LIBJPEG)
2521
2522 ### Use -lpng if available, unless `--with-png=no'.
2523 HAVE_PNG=no
2524 LIBPNG=
2525 if test "${HAVE_X11}" = "yes"; then
2526   if test "${with_png}" != "no"; then
2527     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2528     # in /usr/include/libpng.
2529     AC_CHECK_HEADERS(png.h libpng/png.h)
2530     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2531       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2532     fi
2533   fi
2534
2535   if test "${HAVE_PNG}" = "yes"; then
2536     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2537     LIBPNG="-lpng -lz -lm"
2538   fi
2539 fi
2540 AC_SUBST(LIBPNG)
2541
2542 ### Use -ltiff if available, unless `--with-tiff=no'.
2543 HAVE_TIFF=no
2544 LIBTIFF=
2545 if test "${HAVE_X11}" = "yes"; then
2546   if test "${with_tiff}" != "no"; then
2547     AC_CHECK_HEADER(tiffio.h,
2548       [tifflibs="-lz -lm"
2549       # At least one tiff package requires the jpeg library.
2550       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2551       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2552   fi
2553
2554   if test "${HAVE_TIFF}" = "yes"; then
2555     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2556     dnl FIXME -lz -lm, as per libpng?
2557     LIBTIFF=-ltiff
2558   fi
2559 fi
2560 AC_SUBST(LIBTIFF)
2561
2562 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2563 HAVE_GIF=no
2564 LIBGIF=
2565 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2566   AC_CHECK_HEADER(gif_lib.h,
2567 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2568 # Earlier versions can crash Emacs.
2569     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2570
2571   if test "$HAVE_GIF" = yes; then
2572     LIBGIF=-lgif
2573   elif test "$HAVE_GIF" = maybe; then
2574 # If gif_lib.h but no libgif, try libungif.
2575     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2576     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2577   fi
2578
2579   if test "${HAVE_GIF}" = "yes"; then
2580     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2581   fi
2582 fi
2583 AC_SUBST(LIBGIF)
2584
2585 dnl Check for required libraries.
2586 if test "${HAVE_X11}" = "yes"; then
2587   MISSING=""
2588   WITH_NO=""
2589   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2590     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2591   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2592     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2593   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2594     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2595   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2596     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2597   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2598     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2599
2600   if test "X${MISSING}" != X; then
2601     AC_MSG_ERROR([The following required libraries were not found:
2602     $MISSING
2603 Maybe some development libraries/packages are missing?
2604 If you don't want to link with them give
2605     $WITH_NO
2606 as options to configure])
2607   fi
2608 fi
2609
2610 ### Use -lgpm if available, unless `--with-gpm=no'.
2611 HAVE_GPM=no
2612 LIBGPM=
2613 if test "${with_gpm}" != "no"; then
2614   AC_CHECK_HEADER(gpm.h,
2615     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2616
2617   if test "${HAVE_GPM}" = "yes"; then
2618     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2619     LIBGPM=-lgpm
2620   fi
2621 fi
2622 AC_SUBST(LIBGPM)
2623
2624 dnl Check for malloc/malloc.h on darwin
2625 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2626
2627 GNUSTEP_CFLAGS=
2628 ### Use NeXTstep API to implement GUI.
2629 if test "${HAVE_NS}" = "yes"; then
2630   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2631   if test "${NS_IMPL_COCOA}" = "yes"; then
2632     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2633   fi
2634   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2635     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2636     # See also .m.o rule in Makefile.in */
2637     # FIXME: are all these flags really needed?  Document here why.  */
2638     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2639     ## Extra CFLAGS applied to src/*.m files.
2640     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2641   fi
2642   # We also have mouse menus.
2643   HAVE_MENUS=yes
2644   OTHER_FILES=ns-app
2645 fi
2646
2647
2648 ### Use session management (-lSM -lICE) if available
2649 HAVE_X_SM=no
2650 LIBXSM=
2651 if test "${HAVE_X11}" = "yes"; then
2652   AC_CHECK_HEADER(X11/SM/SMlib.h,
2653     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2654
2655   if test "${HAVE_X_SM}" = "yes"; then
2656     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2657     LIBXSM="-lSM -lICE"
2658     case "$LIBS" in
2659       *-lSM*) ;;
2660       *)      LIBS="$LIBXSM $LIBS" ;;
2661     esac
2662   fi
2663 fi
2664 AC_SUBST(LIBXSM)
2665
2666 ### Use libxml (-lxml2) if available
2667 HAVE_LIBXML2=no
2668 if test "${with_xml2}" != "no"; then
2669   ### I'm not sure what the version number should be, so I just guessed.
2670   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2671   if test "${HAVE_LIBXML2}" = "yes"; then
2672     LIBS="$LIBXML2_LIBS $LIBS"
2673     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2674     if test "${HAVE_LIBXML2}" = "yes"; then
2675       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2676     else
2677       LIBXML2_LIBS=""
2678       LIBXML2_CFLAGS=""
2679     fi
2680   fi
2681 fi
2682 AC_SUBST(LIBXML2_LIBS)
2683 AC_SUBST(LIBXML2_CFLAGS)
2684
2685 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2686 AC_CACHE_CHECK(whether netdb declares h_errno,
2687                emacs_cv_netdb_declares_h_errno,
2688 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2689   [[return h_errno;]])],
2690   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2691 if test $emacs_cv_netdb_declares_h_errno = yes; then
2692   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2693 fi
2694
2695 # fmod, logb, and frexp are found in -lm on most systems.
2696 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2697 AC_CHECK_LIB(m, sqrt)
2698
2699 # Check for mail-locking functions in a "mail" library.  Probably this should
2700 # have the same check as for liblockfile below.
2701 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2702 if test $have_mail = yes; then
2703   LIBS_MAIL=-lmail
2704   LIBS="$LIBS_MAIL $LIBS"
2705   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2706 else
2707   LIBS_MAIL=
2708 fi
2709 dnl Debian, at least:
2710 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2711 if test $have_lockfile = yes; then
2712    LIBS_MAIL=-llockfile
2713    LIBS="$LIBS_MAIL $LIBS"
2714    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2715 else
2716 # If we have the shared liblockfile, assume we must use it for mail
2717 # locking (e.g. Debian).  If we couldn't link against liblockfile
2718 # (no liblockfile.a installed), ensure that we don't need to.
2719   dnl This works for files generally, not just executables.
2720   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2721   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2722                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2723   if test $ac_cv_prog_liblockfile = yes; then
2724     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2725 This probably means that movemail could lose mail.
2726 There may be a `development' package to install containing liblockfile.])
2727   fi
2728 fi
2729 AC_CHECK_FUNCS(touchlock)
2730 AC_CHECK_HEADERS(maillock.h)
2731 AC_SUBST(LIBS_MAIL)
2732
2733 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2734 ## interlock access to the mail spool.  The alternative is a lock file named
2735 ## /usr/spool/mail/$USER.lock.
2736 mail_lock=no
2737 case "$opsys" in
2738   aix4-2) mail_lock="lockf" ;;
2739
2740   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2741
2742   ## On GNU/Linux systems, both methods are used by various mail programs.
2743   ## I assume most people are using newer mailers that have heard of flock.
2744   ## Change this if you need to.
2745   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2746   ## configure gets the right answers, and that means *NOT* using flock.
2747   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2748   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2749   ## Debian maintainer hasn't provided a clean fix for Emacs.
2750   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2751   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2752   ## correct logic.  -- fx
2753   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2754   ## liblockfile is a Free Software replacement for libmail, used on
2755   ## Debian systems and elsewhere. -rfr.
2756   gnu-*)
2757     mail_lock="flock"
2758     if test $have_mail = yes || test $have_lockfile = yes; then
2759       test $ac_cv_header_maillock_h = yes && mail_lock=no
2760     fi
2761     ;;
2762 esac
2763
2764 BLESSMAIL_TARGET=
2765 case "$mail_lock" in
2766   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2767
2768   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2769
2770   *) BLESSMAIL_TARGET="need-blessmail" ;;
2771 esac
2772 AC_SUBST(BLESSMAIL_TARGET)
2773
2774
2775 AC_CHECK_FUNCS(gethostname \
2776 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2777 random lrand48 logb frexp fmod rint cbrt setsid \
2778 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2779 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2780 __fpending strsignal setitimer \
2781 sendto recvfrom getsockname getpeername \
2782 gai_strerror mkstemp getline getdelim fsync sync \
2783 difftime posix_memalign \
2784 getpwent endpwent getgrent endgrent \
2785 cfmakeraw cfsetspeed copysign __executable_start)
2786
2787 dnl Cannot use AC_CHECK_FUNCS
2788 AC_CACHE_CHECK([for __builtin_unwind_init],
2789                emacs_cv_func___builtin_unwind_init,
2790 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2791                 emacs_cv_func___builtin_unwind_init=yes,
2792                 emacs_cv_func___builtin_unwind_init=no)])
2793 if test $emacs_cv_func___builtin_unwind_init = yes; then
2794   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2795             [Define to 1 if you have the `__builtin_unwind_init' function.])
2796 fi
2797
2798 AC_CHECK_HEADERS(sys/un.h)
2799
2800 AC_FUNC_FSEEKO
2801
2802 AC_FUNC_GETPGRP
2803
2804 # UNIX98 PTYs.
2805 AC_CHECK_FUNCS(grantpt)
2806
2807 # PTY-related GNU extensions.
2808 AC_CHECK_FUNCS(getpt)
2809
2810 # Check this now, so that we will NOT find the above functions in ncurses.
2811 # That is because we have not set up to link ncurses in lib-src.
2812 # It's better to believe a function is not available
2813 # than to expect to find it in ncurses.
2814 # Also we need tputs and friends to be able to build at all.
2815 AC_MSG_CHECKING([for library containing tputs])
2816 # Run a test program that contains a call to tputs, a call that is
2817 # never executed.  This tests whether a pre-'main' dynamic linker
2818 # works with the library.  It's too much trouble to actually call
2819 # tputs in the test program, due to portability hassles.  When
2820 # cross-compiling, assume the test program will run if it links.
2821 AC_DEFUN([tputs_link_source], [
2822   AC_LANG_SOURCE(
2823      [[extern void tputs (const char *, int, int (*)(int));
2824        int main (int argc, char **argv)
2825        {
2826           if (argc == 10000)
2827             tputs (argv[0], 0, 0);
2828           return 0;
2829        }]])
2830 ])
2831 # Maybe curses should be tried earlier?
2832 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2833 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2834   OLIBS=$LIBS
2835   if test -z "$tputs_library"; then
2836     LIBS_TERMCAP=
2837     msg='none required'
2838   else
2839     LIBS_TERMCAP=-l$tputs_library
2840     msg=$LIBS_TERMCAP
2841     LIBS="$LIBS_TERMCAP $LIBS"
2842   fi
2843   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2844     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2845   LIBS=$OLIBS
2846   if test "X$msg" != Xno; then
2847     break
2848   fi
2849 done
2850 AC_MSG_RESULT([$msg])
2851 if test "X$msg" = Xno; then
2852   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2853 The following libraries were tried (in order):
2854   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2855 Please try installing whichever of these libraries is most appropriate
2856 for your system, together with its header files.
2857 For example, a libncurses-dev(el) or similar package.])
2858 fi
2859
2860 ## Use termcap instead of terminfo?
2861 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2862 TERMINFO=yes
2863 ## FIXME?  In the cases below where we unconditionally set
2864 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2865 ## if that was found above to have tputs.
2866 ## Should we use the gnu* logic everywhere?
2867 case "$opsys" in
2868   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2869   ##  The ncurses library has been moved out of the System framework in
2870   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2871   ##  option to use it.
2872   darwin) LIBS_TERMCAP="-lncurses" ;;
2873
2874   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2875
2876   freebsd)
2877     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2878     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2879     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2880 [[#if __FreeBSD_version < 400000
2881 fail;
2882 #endif
2883 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2884
2885     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2886
2887     if test $emacs_cv_freebsd_terminfo = yes; then
2888       LIBS_TERMCAP="-lncurses"
2889     else
2890       TERMINFO=no
2891       LIBS_TERMCAP="-ltermcap"
2892     fi
2893     ;;
2894
2895   netbsd)
2896     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2897       TERMINFO=no
2898       LIBS_TERMCAP="-ltermcap"
2899     fi
2900     ;;
2901
2902   openbsd) LIBS_TERMCAP="-lncurses" ;;
2903
2904   ## hpux: Make sure we get select from libc rather than from libcurses
2905   ##  because libcurses on HPUX 10.10 has a broken version of select.
2906   ##  We used to use -lc -lcurses, but this may be cleaner.
2907   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2908   # set that way, now it uses the default).  Isn't this a contradiction?
2909   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2910
2911 esac
2912
2913 TERMCAP_OBJ=tparam.o
2914 if test $TERMINFO = yes; then
2915   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2916   TERMCAP_OBJ=terminfo.o
2917 fi
2918 AC_SUBST(LIBS_TERMCAP)
2919 AC_SUBST(TERMCAP_OBJ)
2920
2921
2922 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2923 resolv=no
2924 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2925 #include <arpa/nameser.h>
2926 #include <resolv.h>]],
2927     [[return res_init();]])],
2928     have_res_init=yes, have_res_init=no)
2929 if test "$have_res_init" = no; then
2930   OLIBS="$LIBS"
2931   LIBS="$LIBS -lresolv"
2932   AC_MSG_CHECKING(for res_init with -lresolv)
2933   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2934 #include <arpa/nameser.h>
2935 #include <resolv.h>]],
2936     [[return res_init();]])],
2937     have_res_init=yes, have_res_init=no)
2938   AC_MSG_RESULT($have_res_init)
2939   if test "$have_res_init" = yes ; then
2940     resolv=yes
2941   fi
2942   LIBS="$OLIBS"
2943 fi
2944
2945 if test "$have_res_init" = yes; then
2946   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2947 fi
2948
2949 # Do we need the Hesiod library to provide the support routines?
2950 LIBHESIOD=
2951 if test "$with_hesiod" != no ; then
2952   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2953   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2954      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2955                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2956   if test "$resolv" = yes ; then
2957     RESOLVLIB=-lresolv
2958   else
2959     RESOLVLIB=
2960   fi
2961   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2962         hesiod=yes, :, $RESOLVLIB)])
2963
2964   if test x"$hesiod" = xyes; then
2965     AC_DEFINE(HAVE_LIBHESIOD, 1,
2966               [Define to 1 if you have the hesiod library (-lhesiod).])
2967     LIBHESIOD=-lhesiod
2968   fi
2969 fi
2970 AC_SUBST(LIBHESIOD)
2971
2972 # Do we need libresolv (due to res_init or Hesiod)?
2973 if test "$resolv" = yes ; then
2974   AC_DEFINE(HAVE_LIBRESOLV, 1,
2975             [Define to 1 if you have the resolv library (-lresolv).])
2976   LIBRESOLV=-lresolv
2977 else
2978   LIBRESOLV=
2979 fi
2980 AC_SUBST(LIBRESOLV)
2981
2982 # These tell us which Kerberos-related libraries to use.
2983 COM_ERRLIB=
2984 CRYPTOLIB=
2985 KRB5LIB=
2986 DESLIB=
2987 KRB4LIB=
2988
2989 if test "${with_kerberos}" != no; then
2990   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2991   if test $have_com_err = yes; then
2992     COM_ERRLIB=-lcom_err
2993     LIBS="$COM_ERRLIB $LIBS"
2994     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2995   fi
2996   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2997   if test $have_crypto = yes; then
2998     CRYPTOLIB=-lcrypto
2999     LIBS="$CRYPTOLIB $LIBS"
3000     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3001   fi
3002   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3003   if test $have_k5crypto = yes; then
3004     CRYPTOLIB=-lk5crypto
3005     LIBS="$CRYPTOLIB $LIBS"
3006     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3007   fi
3008   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3009   if test $have_krb5=yes; then
3010     KRB5LIB=-lkrb5
3011     LIBS="$KRB5LIB $LIBS"
3012     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3013   fi
3014   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3015   if test "${with_kerberos5}" = no; then
3016     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3017     if test $have_des425 = yes; then
3018       DESLIB=-ldes425
3019       LIBS="$DESLIB $LIBS"
3020       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3021     else
3022       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3023       if test $have_des = yes; then
3024         DESLIB=-ldes
3025         LIBS="$DESLIB $LIBS"
3026         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3027       fi
3028     fi
3029     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3030     if test $have_krb4 = yes; then
3031       KRB4LIB=-lkrb4
3032       LIBS="$KRB4LIB $LIBS"
3033       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3034     else
3035       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3036       if test $have_krb = yes; then
3037         KRB4LIB=-lkrb
3038         LIBS="$KRB4LIB $LIBS"
3039         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3040       fi
3041     fi
3042   fi
3043
3044   if test "${with_kerberos5}" != no; then
3045     AC_CHECK_HEADERS(krb5.h,
3046       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3047                         [#include <krb5.h>])])
3048   else
3049     AC_CHECK_HEADERS(des.h,,
3050                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3051                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3052     AC_CHECK_HEADERS(krb.h,,
3053                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3054                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3055   fi
3056   AC_CHECK_HEADERS(com_err.h)
3057 fi
3058
3059 AC_SUBST(COM_ERRLIB)
3060 AC_SUBST(CRYPTOLIB)
3061 AC_SUBST(KRB5LIB)
3062 AC_SUBST(DESLIB)
3063 AC_SUBST(KRB4LIB)
3064
3065 AC_MSG_CHECKING(whether localtime caches TZ)
3066 AC_CACHE_VAL(emacs_cv_localtime_cache,
3067 [if test x$ac_cv_func_tzset = xyes; then
3068 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3069 char TZ_GMT0[] = "TZ=GMT0";
3070 char TZ_PST8[] = "TZ=PST8";
3071 main()
3072 {
3073   time_t now = time ((time_t *) 0);
3074   int hour_GMT0, hour_unset;
3075   if (putenv (TZ_GMT0) != 0)
3076     exit (1);
3077   hour_GMT0 = localtime (&now)->tm_hour;
3078   unsetenv("TZ");
3079   hour_unset = localtime (&now)->tm_hour;
3080   if (putenv (TZ_PST8) != 0)
3081     exit (1);
3082   if (localtime (&now)->tm_hour == hour_GMT0)
3083     exit (1);
3084   unsetenv("TZ");
3085   if (localtime (&now)->tm_hour != hour_unset)
3086     exit (1);
3087   exit (0);
3088 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3089 [# If we have tzset, assume the worst when cross-compiling.
3090 emacs_cv_localtime_cache=yes])
3091 else
3092         # If we lack tzset, report that localtime does not cache TZ,
3093         # since we can't invalidate the cache if we don't have tzset.
3094         emacs_cv_localtime_cache=no
3095 fi])dnl
3096 AC_MSG_RESULT($emacs_cv_localtime_cache)
3097 if test $emacs_cv_localtime_cache = yes; then
3098   AC_DEFINE(LOCALTIME_CACHE, 1,
3099             [Define to 1 if localtime caches TZ.])
3100 fi
3101
3102 if test "x$HAVE_TIMEVAL" = xyes; then
3103   AC_CHECK_FUNCS(gettimeofday)
3104   if test $ac_cv_func_gettimeofday = yes; then
3105     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3106                    emacs_cv_gettimeofday_two_arguments,
3107     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3108 #ifdef TIME_WITH_SYS_TIME
3109 #include <sys/time.h>
3110 #include <time.h>
3111 #else
3112 #ifdef HAVE_SYS_TIME_H
3113 #include <sys/time.h>
3114 #else
3115 #include <time.h>
3116 #endif
3117 #endif]],
3118       [[struct timeval time;
3119        gettimeofday (&time, 0);]])],
3120       emacs_cv_gettimeofday_two_arguments=yes,
3121       emacs_cv_gettimeofday_two_arguments=no)])
3122     if test $emacs_cv_gettimeofday_two_arguments = no; then
3123       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3124                 [Define to 1 if gettimeofday accepts only one argument.])
3125     fi
3126   fi
3127 fi
3128
3129 ok_so_far=yes
3130 AC_CHECK_FUNC(socket, , ok_so_far=no)
3131 if test $ok_so_far = yes; then
3132   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3133 fi
3134 if test $ok_so_far = yes; then
3135   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3136 fi
3137 if test $ok_so_far = yes; then
3138 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3139   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3140             [Define to 1 if you have inet sockets.])
3141 fi
3142
3143 if test -f /usr/lpp/X11/bin/smt.exp; then
3144   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3145             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3146 fi
3147
3148 AC_MSG_CHECKING(whether system supports dynamic ptys)
3149 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3150   AC_MSG_RESULT(yes)
3151   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3152 else
3153   AC_MSG_RESULT(no)
3154 fi
3155
3156 AC_FUNC_FORK
3157
3158 AC_CHECK_FUNCS(snprintf)
3159
3160 dnl Adapted from Haible's version.
3161 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3162   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3163     [[char* cs = nl_langinfo(CODESET);]])],
3164     emacs_cv_langinfo_codeset=yes,
3165     emacs_cv_langinfo_codeset=no)
3166   ])
3167 if test $emacs_cv_langinfo_codeset = yes; then
3168   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3169     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3170 fi
3171
3172 AC_TYPE_MBSTATE_T
3173
3174 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3175   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3176                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3177 if test "$emacs_cv_c_restrict_arr" = yes; then
3178   AC_DEFINE(__restrict_arr, __restrict,
3179     [Define to compiler's equivalent of C99 restrict keyword in array
3180      declarations.  Define as empty for no equivalent.])
3181 fi
3182
3183 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3184 dnl how the tty code is related to POSIX and/or other versions of termios.
3185 dnl The following looks like a useful start.
3186 dnl
3187 dnl AC_SYS_POSIX_TERMIOS
3188 dnl if test $ac_cv_sys_posix_termios = yes; then
3189 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3190 dnl                                and macros for terminal control.])
3191 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3192 dnl fi
3193
3194 # Set up the CFLAGS for real compilation, so we can substitute it.
3195 CFLAGS="$REAL_CFLAGS"
3196 CPPFLAGS="$REAL_CPPFLAGS"
3197
3198 ## Hack to detect a buggy GCC version.
3199 if test "x$GCC" = xyes \
3200    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3201    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3202    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3203    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3204 fi
3205
3206 version=$PACKAGE_VERSION
3207
3208 ### Specify what sort of things we'll be editing into Makefile and config.h.
3209 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3210 AC_SUBST(version)
3211 AC_SUBST(configuration)
3212 ## Unused?
3213 AC_SUBST(canonical)
3214 AC_SUBST(srcdir)
3215 AC_SUBST(prefix)
3216 AC_SUBST(exec_prefix)
3217 AC_SUBST(bindir)
3218 AC_SUBST(datadir)
3219 AC_SUBST(sharedstatedir)
3220 AC_SUBST(libexecdir)
3221 AC_SUBST(mandir)
3222 AC_SUBST(infodir)
3223 AC_SUBST(lispdir)
3224 AC_SUBST(leimdir)
3225 AC_SUBST(locallisppath)
3226 AC_SUBST(lisppath)
3227 AC_SUBST(x_default_search_path)
3228 AC_SUBST(etcdir)
3229 AC_SUBST(archlibdir)
3230 AC_SUBST(docdir)
3231 AC_SUBST(bitmapdir)
3232 AC_SUBST(gamedir)
3233 AC_SUBST(gameuser)
3234 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3235 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3236 ## end of LIBX_BASE, but nothing ever set it.
3237 AC_SUBST(LD_SWITCH_X_SITE)
3238 AC_SUBST(C_SWITCH_X_SITE)
3239 AC_SUBST(GNUSTEP_CFLAGS)
3240 AC_SUBST(CFLAGS)
3241 ## Used in lwlib/Makefile.in.
3242 AC_SUBST(X_TOOLKIT_TYPE)
3243 if test -n "${machfile}"; then
3244   M_FILE="\$(srcdir)/${machfile}"
3245 else
3246   M_FILE=
3247 fi
3248 S_FILE="\$(srcdir)/${opsysfile}"
3249 AC_SUBST(M_FILE)
3250 AC_SUBST(S_FILE)
3251 AC_SUBST(ns_appdir)
3252 AC_SUBST(ns_appbindir)
3253 AC_SUBST(ns_appresdir)
3254 AC_SUBST(ns_appsrc)
3255 AC_SUBST(GNU_OBJC_CFLAGS)
3256 AC_SUBST(OTHER_FILES)
3257
3258 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3259                    [Define to the canonical Emacs configuration name.])
3260 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3261                    [Define to the options passed to configure.])
3262 if test -n "$machfile"; then
3263   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3264                      [Define to the used machine dependent file.])
3265 fi
3266 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3267                    [Define to the used os dependent file.])
3268
3269 XMENU_OBJ=
3270 XOBJ=
3271 FONT_OBJ=
3272 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3273   AC_DEFINE(HAVE_X_WINDOWS, 1,
3274             [Define to 1 if you want to use the X window system.])
3275   XMENU_OBJ=xmenu.o
3276   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3277   FONT_OBJ=xfont.o
3278   if test "$HAVE_XFT" = "yes"; then
3279     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3280   elif test "$HAVE_FREETYPE" = "yes"; then
3281     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3282   fi
3283   AC_SUBST(FONT_OBJ)
3284 fi
3285 AC_SUBST(XMENU_OBJ)
3286 AC_SUBST(XOBJ)
3287 AC_SUBST(FONT_OBJ)
3288
3289 WIDGET_OBJ=
3290 MOTIF_LIBW=
3291 if test "${USE_X_TOOLKIT}" != "none" ; then
3292   WIDGET_OBJ=widget.o
3293   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3294   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3295     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3296   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3297     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3298     MOTIF_LIBW=-lXm
3299     case "$opsys" in
3300       gnu-linux)
3301         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3302         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3303         ;;
3304
3305       unixware)
3306         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3307         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3308         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3309         ;;
3310
3311       aix4-2)
3312         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3313         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3314         ;;
3315     esac
3316     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3317   fi
3318 fi
3319 AC_SUBST(WIDGET_OBJ)
3320
3321 TOOLKIT_LIBW=
3322 case "$USE_X_TOOLKIT" in
3323   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3324   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3325   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3326 esac
3327 AC_SUBST(TOOLKIT_LIBW)
3328
3329 if test "$USE_X_TOOLKIT" = "none"; then
3330   LIBXT_OTHER="\$(LIBXSM)"
3331   OLDXMENU_TARGET="really-oldXMenu"
3332 else
3333   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3334   OLDXMENU_TARGET="really-lwlib"
3335 fi
3336 AC_SUBST(LIBXT_OTHER)
3337
3338 ## The X Menu stuff is present in the X10 distribution, but missing
3339 ## from X11.  If we have X10, just use the installed library;
3340 ## otherwise, use our own copy.
3341 if test "${HAVE_X11}" = "yes" ; then
3342   AC_DEFINE(HAVE_X11, 1,
3343             [Define to 1 if you want to use version 11 of X windows.
3344              Otherwise, Emacs expects to use version 10.])
3345
3346   if test "$USE_X_TOOLKIT" = "none"; then
3347     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3348   else
3349     OLDXMENU="\${lwlibdir}/liblw.a"
3350   fi
3351   LIBXMENU="\$(OLDXMENU)"
3352   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3353   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3354 else
3355   ## For a syntactically valid Makefile; not actually used for anything.
3356   ## See comments in src/Makefile.in.
3357   OLDXMENU=nothing
3358   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3359   if test "${HAVE_X_WINDOWS}" = "yes"; then
3360     LIBXMENU="-lXMenu"
3361   else
3362     LIBXMENU=
3363   fi
3364   LIBX_OTHER=
3365   OLDXMENU_DEPS=
3366 fi
3367
3368 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3369   OLDXMENU_TARGET=
3370   OLDXMENU=nothing
3371   LIBXMENU=
3372   OLDXMENU_DEPS=
3373 fi
3374
3375 AC_SUBST(OLDXMENU_TARGET)
3376 AC_SUBST(OLDXMENU)
3377 AC_SUBST(LIBXMENU)
3378 AC_SUBST(LIBX_OTHER)
3379 AC_SUBST(OLDXMENU_DEPS)
3380
3381 if test "${HAVE_MENUS}" = "yes" ; then
3382   AC_DEFINE(HAVE_MENUS, 1,
3383             [Define to 1 if you have mouse menus.
3384              (This is automatic if you use X, but the option to specify it remains.)
3385              It is also defined with other window systems that support xmenu.c.])
3386 fi
3387
3388 if test "${GNU_MALLOC}" = "yes" ; then
3389   AC_DEFINE(GNU_MALLOC, 1,
3390             [Define to 1 if you want to use the GNU memory allocator.])
3391 fi
3392
3393 RALLOC_OBJ=
3394 if test "${REL_ALLOC}" = "yes" ; then
3395   AC_DEFINE(REL_ALLOC, 1,
3396             [Define REL_ALLOC if you want to use the relocating allocator for
3397              buffer space.])
3398
3399   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3400 fi
3401 AC_SUBST(RALLOC_OBJ)
3402
3403 if test "$opsys" = "cygwin"; then
3404   CYGWIN_OBJ="sheap.o"
3405   ## Cygwin differs because of its unexec().
3406   PRE_ALLOC_OBJ=
3407   POST_ALLOC_OBJ=lastfile.o
3408 else
3409   CYGWIN_OBJ=
3410   PRE_ALLOC_OBJ=lastfile.o
3411   POST_ALLOC_OBJ=
3412 fi
3413 AC_SUBST(CYGWIN_OBJ)
3414 AC_SUBST(PRE_ALLOC_OBJ)
3415 AC_SUBST(POST_ALLOC_OBJ)
3416
3417 # Configure gnulib here, now that we know LIBS.
3418 gl_ASSERT_NO_GNULIB_POSIXCHECK
3419 gl_ASSERT_NO_GNULIB_TESTS
3420 gl_INIT
3421
3422 case "$opsys" in
3423   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3424
3425   darwin)
3426    ## The -headerpad option tells ld (see man page) to leave room at the
3427    ## end of the header for adding load commands.  Needed for dumping.
3428    ## 0x690 is the total size of 30 segment load commands (at 56
3429    ## each); under Cocoa 31 commands are required.
3430    if test "$HAVE_NS" = "yes"; then
3431      libs_nsgui="-framework AppKit"
3432      headerpad_extra=6C8
3433    else
3434      libs_nsgui=
3435      headerpad_extra=690
3436    fi
3437    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3438
3439    ## This is here because src/Makefile.in did some extra fiddling around
3440    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3441    ##   #ifndef LD_SWITCH_SYSTEM
3442    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3443    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3444    ## not using gcc, darwin system not on an alpha (ie darwin, since
3445    ## darwin + alpha does not occur).
3446    ## Because this was done in src/Makefile.in, the resulting part of
3447    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3448    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3449    ## rather than LD_SWITCH_SYSTEM.
3450    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3451      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3452    ;;
3453
3454   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3455   ## find X at run-time.
3456   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3457   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3458   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3459   ## had different values in configure (in ac_link) and src/Makefile.in.
3460   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3461   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3462
3463   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3464 esac
3465
3466 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3467   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3468 fi
3469
3470 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3471
3472
3473 LD_FIRSTFLAG=
3474 ORDINARY_LINK=
3475 case "$opsys" in
3476   ## gnu: GNU needs its own crt0.
3477   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3478
3479   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3480   ## library search parth, i.e. it won't search /usr/lib for libc and
3481   ## friends.  Using -nostartfiles instead avoids this problem, and
3482   ## will also work on earlier NetBSD releases.
3483   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3484
3485   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3486   ##   MkLinux/LinuxPPC needs this.
3487   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3488   gnu-*)
3489     case "$machine" in
3490       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3491     esac
3492     ;;
3493 esac
3494
3495
3496 if test "x$ORDINARY_LINK" = "xyes"; then
3497
3498   LD_FIRSTFLAG=""
3499   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3500
3501 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3502 ## freebsd, gnu-* not on macppc|ibms390x.
3503 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3504
3505   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3506   ## places that are difficult to figure out at make time.  Fortunately,
3507   ## these same versions allow you to pass arbitrary flags on to the
3508   ## linker, so there is no reason not to use it as a linker.
3509   ##
3510   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3511   ## searching for libraries in its internal directories, so we have to
3512   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3513   LD_FIRSTFLAG="-nostdlib"
3514 fi
3515
3516 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3517 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3518
3519 AC_SUBST(LD_FIRSTFLAG)
3520
3521
3522 ## FIXME? The logic here is not precisely the same as that above.
3523 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3524 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3525 LIB_GCC=
3526 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3527
3528   case "$opsys" in
3529     freebsd|netbsd|openbsd) LIB_GCC= ;;
3530
3531     gnu-*)
3532       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3533       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3534       case $host_cpu in
3535       arm*)
3536         LIB_GCC="-lgcc_s"
3537         ;;
3538       *)
3539         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3540         ## immediately undefine it again and redefine it to empty.
3541         ## Was the C_SWITCH_X_SITE part really necessary?
3542 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3543         LIB_GCC=
3544         ;;
3545       esac
3546       ;;
3547
3548     ## Ask GCC where to find libgcc.a.
3549     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3550   esac
3551 fi                              dnl if $GCC
3552 AC_SUBST(LIB_GCC)
3553
3554
3555 ## If we're using X11/GNUstep, define some consequences.
3556 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3557   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3558   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3559 fi
3560
3561
3562 AH_TOP([/* GNU Emacs site configuration template file.
3563
3564 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3565   Free Software Foundation, Inc.
3566
3567 This file is part of GNU Emacs.
3568
3569 GNU Emacs is free software: you can redistribute it and/or modify
3570 it under the terms of the GNU General Public License as published by
3571 the Free Software Foundation, either version 3 of the License, or
3572 (at your option) any later version.
3573
3574 GNU Emacs is distributed in the hope that it will be useful,
3575 but WITHOUT ANY WARRANTY; without even the implied warranty of
3576 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3577 GNU General Public License for more details.
3578
3579 You should have received a copy of the GNU General Public License
3580 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3581
3582
3583 /* No code in Emacs #includes config.h twice, but some bits of code
3584    intended to work with other packages as well (like gmalloc.c)
3585    think they can include it as many times as they like.  */
3586 #ifndef EMACS_CONFIG_H
3587 #define EMACS_CONFIG_H
3588 ])dnl
3589
3590 AH_BOTTOM([
3591 /* On AIX 3 this must be included before any other include file.  */
3592 #include <alloca.h>
3593 #if ! HAVE_ALLOCA
3594 # error "alloca not available on this machine"
3595 #endif
3596
3597 /* Define AMPERSAND_FULL_NAME if you use the convention
3598    that & in the full name stands for the login id.  */
3599 /* Turned on June 1996 supposing nobody will mind it.  */
3600 #define AMPERSAND_FULL_NAME
3601
3602 /* `subprocesses' should be defined if you want to
3603    have code for asynchronous subprocesses
3604    (as used in M-x compile and M-x shell).
3605    Only MSDOS does not support this (it overrides
3606    this in its config_opsysfile below).  */
3607
3608 #define subprocesses
3609
3610 /* Include the os and machine dependent files.  */
3611 #include config_opsysfile
3612 #ifdef config_machfile
3613 # include config_machfile
3614 #endif
3615
3616 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3617    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3618   (There is probably a better place to do this, but right now the
3619    Cocoa side does this in s/darwin.h and we cannot parallel this
3620    exactly since GNUstep is multi-OS.  */
3621 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3622 #  define SYSTEM_PURESIZE_EXTRA 30000
3623 #endif
3624
3625 #ifdef emacs /* Don't do this for lib-src.  */
3626 /* Tell regex.c to use a type compatible with Emacs.  */
3627 #define RE_TRANSLATE_TYPE Lisp_Object
3628 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3629 #ifdef make_number
3630 /* If make_number is a macro, use it.  */
3631 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3632 #else
3633 /* If make_number is a function, avoid it.  */
3634 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3635 #endif
3636 #endif
3637
3638 /* These default definitions are good for almost all machines.
3639    Any exceptions should override them in m/MACHINE.h.
3640    They must be usable in preprocessor conditionals.  */
3641
3642 #ifndef BITS_PER_CHAR
3643 #define BITS_PER_CHAR 8
3644 #endif
3645
3646 #ifndef BITS_PER_SHORT
3647 #define BITS_PER_SHORT 16
3648 #endif
3649
3650 #ifndef BITS_PER_INT
3651 #define BITS_PER_INT 32
3652 #endif
3653
3654 #ifndef BITS_PER_LONG
3655 #ifdef _LP64
3656 #define BITS_PER_LONG 64
3657 #else
3658 #define BITS_PER_LONG 32
3659 #endif
3660 #endif
3661
3662 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3663 #define BITS_PER_LONG_LONG 64
3664 #endif
3665
3666 /* Define if the compiler supports function prototypes.  It may do so but
3667    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3668 #undef PROTOTYPES
3669
3670 #include <string.h>
3671 #include <stdlib.h>
3672
3673 #if defined __GNUC__ && (__GNUC__ > 2 \
3674                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3675 #define NO_RETURN       __attribute__ ((__noreturn__))
3676 #else
3677 #define NO_RETURN       /* nothing */
3678 #endif
3679
3680 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3681 #define NO_INLINE __attribute__((noinline))
3682 #else
3683 #define NO_INLINE
3684 #endif
3685
3686 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3687 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3688 #else
3689 #define EXTERNALLY_VISIBLE
3690 #endif
3691
3692 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3693 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3694 #else
3695 # define ATTRIBUTE_FORMAT(spec) /* empty */
3696 #endif
3697
3698 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3699 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3700    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3701 #else
3702 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3703    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3704 #endif
3705
3706 /* Some versions of GNU/Linux define noinline in their headers.  */
3707 #ifdef noinline
3708 #undef noinline
3709 #endif
3710
3711 /* These won't be used automatically yet.  We also need to know, at least,
3712    that the stack is continuous.  */
3713 #ifdef __GNUC__
3714 #  ifndef GC_SETJMP_WORKS
3715   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3716 #    define GC_SETJMP_WORKS 1
3717 #  endif
3718 #endif
3719
3720 #endif /* EMACS_CONFIG_H */
3721
3722 /*
3723 Local Variables:
3724 mode: c
3725 End:
3726 */
3727 ])dnl
3728
3729 #### Report on what we decided to do.
3730 #### Report GTK as a toolkit, even if it doesn't use Xt.
3731 #### It makes printing result more understandable as using GTK sets
3732 #### toolkit_scroll_bars to yes by default.
3733 if test "${HAVE_GTK}" = "yes"; then
3734   USE_X_TOOLKIT=GTK
3735 fi
3736
3737 and_machfile=
3738 if test -n "$machfile"; then
3739   and_machfile=" and \`${machfile}'"
3740 fi
3741
3742 echo "
3743 Configured for \`${canonical}'.
3744
3745   Where should the build process find the source code?    ${srcdir}
3746   What operating system and machine description files should Emacs use?
3747         \`${opsysfile}'${and_machfile}
3748   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3749   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3750   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3751   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3752   What window system should Emacs use?                    ${window_system}
3753   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3754
3755 if test -n "${x_includes}"; then
3756 echo "  Where do we find X Windows header files?                ${x_includes}"
3757 else
3758 echo "  Where do we find X Windows header files?                Standard dirs"
3759 fi
3760 if test -n "${x_libraries}"; then
3761 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3762 else
3763 echo "  Where do we find X Windows libraries?                   Standard dirs"
3764 fi
3765
3766 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3767 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3768 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3769 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3770 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3771 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3772 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3773 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3774
3775 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3776 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3777 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3778 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3779 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3780 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3781 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3782
3783 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3784 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3785 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3786 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3787
3788 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3789 echo
3790
3791 if test -n "${EMACSDATA}"; then
3792    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3793 fi
3794 if test -n "${EMACSDOC}"; then
3795    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3796 fi
3797
3798 if test $USE_XASSERTS = yes; then
3799    echo "  Compiling with asserts turned on."
3800    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3801 fi
3802
3803 echo
3804
3805 if test "$HAVE_NS" = "yes"; then
3806    echo
3807    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3808 The installed application will go to nextstep/Emacs.app and can be
3809 run or moved from there."
3810    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3811       echo "The application will be fully self-contained."
3812     else
3813       echo "The lisp resources for the application will be installed under ${prefix}.
3814 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3815 to run if these resources are not installed."
3816    fi
3817    echo
3818 fi
3819
3820 if test "${opsys}" = "cygwin"; then
3821   case `uname -r` in
3822     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3823            echo
3824            ;;
3825   esac
3826 fi
3827
3828 # Remove any trailing slashes in these variables.
3829 [test "${prefix}" != NONE &&
3830   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3831 test "${exec_prefix}" != NONE &&
3832   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3833
3834 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3835 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3836 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3837 dnl (else you get "no `Makefile.am' found for any configure output").
3838 dnl This will work, but you get a config.status that is not quite right
3839 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3840 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3841 dnl it seems better to just live with the duplication.
3842 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3843
3844 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3845        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3846        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3847        leim/Makefile])
3848
3849 dnl test/ is not present in release tarfiles.
3850 opt_makefile=test/automated/Makefile
3851
3852 if test -f $srcdir/${opt_makefile}.in; then
3853   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3854   dnl Again, it's best not to use a variable.  Though you can add
3855   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3856   AC_CONFIG_FILES([test/automated/Makefile])
3857 fi
3858
3859
3860 dnl admin/ may or may not be present.
3861 opt_makefile=admin/unidata/Makefile
3862
3863 if test -f $srcdir/${opt_makefile}.in; then
3864   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3865   AC_CONFIG_FILES([admin/unidata/Makefile])
3866 fi
3867
3868
3869 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3870
3871 AC_SUBST(SUBDIR_MAKEFILES_IN)
3872
3873 dnl Make the necessary directories, if they don't exist.
3874 AC_CONFIG_COMMANDS([mkdirs], [
3875 for dir in etc lisp ; do
3876   test -d ${dir} || mkdir ${dir}
3877 done
3878 ])
3879
3880 dnl You might wonder (I did) why epaths.h is generated by running make,
3881 dnl rather than just letting configure generate it from epaths.in.
3882 dnl One reason is that the various paths are not fully expanded (see above);
3883 dnl eg gamedir=${prefix}/var/games/emacs.
3884 dnl Secondly, the GNU Coding standards require that one should be able
3885 dnl to run `make prefix=/some/where/else' and override the values set
3886 dnl by configure.  This also explains the `move-if-change' test and
3887 dnl the use of force in the `epaths-force' rule in Makefile.in.
3888 AC_CONFIG_COMMANDS([epaths], [
3889 echo creating src/epaths.h
3890 ${MAKE-make} epaths-force
3891 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3892
3893 AC_CONFIG_COMMANDS([gdbinit], [
3894 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3895   echo creating src/.gdbinit
3896   echo source $srcdir/src/.gdbinit > src/.gdbinit
3897 fi
3898 ])
3899
3900 AC_OUTPUT
3901
3902 dnl configure.in ends here