lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2015 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 (defvar help-fns-describe-function-functions nil
  36   "List of functions to run in help buffer in `describe-function'.
  37 Those functions will be run after the header line and argument
  38 list was inserted, and before the documentation will be inserted.
  39 The functions will receive the function name as argument.")
  40
  41 ;; Functions
  42
  43 ;;;###autoload
  44 (defun describe-function (function)
  45   "Display the full documentation of FUNCTION (a symbol)."
  46   (interactive
  47    (let ((fn (function-called-at-point))
  48          (enable-recursive-minibuffers t)
  49          val)
  50      (setq val (completing-read (if fn
  51                                     (format "Describe function (default %s): " fn)
  52                                   "Describe function: ")
  53                                 obarray 'fboundp t nil nil
  54                                 (and fn (symbol-name fn))))
  55      (list (if (equal val "")
  56                fn (intern val)))))
  57   (or (and function (symbolp function))
  58       (user-error "You didn't specify a function symbol"))
  59   (or (fboundp function)
  60       (user-error "Symbol's function definition is void: %s" function))
  61   (help-setup-xref (list #'describe-function function)
  62                    (called-interactively-p 'interactive))
  63   (save-excursion
  64     (with-help-window (help-buffer)
  65       (prin1 function)
  66       ;; Use " is " instead of a colon so that
  67       ;; it is easier to get out the function name using forward-sexp.
  68       (princ " is ")
  69       (describe-function-1 function)
  70       (with-current-buffer standard-output
  71         ;; Return the text we displayed.
  72         (buffer-string)))))
  73
  74
  75 ;; Could be this, if we make symbol-file do the work below.
  76 ;; (defun help-C-file-name (subr-or-var kind)
  77 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
  78 ;; KIND should be `var' for a variable or `subr' for a subroutine."
  79 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
  80 ;;               (subr-name subr-or-var))
  81 ;;             (if (eq kind 'var) 'defvar 'defun)))
  82 ;;;###autoload
  83 (defun help-C-file-name (subr-or-var kind)
  84   "Return the name of the C file where SUBR-OR-VAR is defined.
  85 KIND should be `var' for a variable or `subr' for a subroutine."
  86   (let ((docbuf (get-buffer-create " *DOC*"))
  87         (name (if (eq 'var kind)
  88                   (concat "V" (symbol-name subr-or-var))
  89                 (concat "F" (subr-name (advice--cd*r subr-or-var))))))
  90     (with-current-buffer docbuf
  91       (goto-char (point-min))
  92       (if (eobp)
  93           (insert-file-contents-literally
  94            (expand-file-name internal-doc-file-name doc-directory)))
  95       (let ((file (catch 'loop
  96                     (while t
  97                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
  98                         (re-search-backward "\x1fS\\(.*\\)")
  99                         (let ((file (match-string 1)))
 100                           (if (member file build-files)
 101                               (throw 'loop file)
 102                             (goto-char pnt))))))))
 103         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 104             (setq file (replace-match ".m" t t file 1))
 105           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 106               (setq file (replace-match ".c" t t file))))
 107         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 108             (concat "src/" file)
 109           file)))))
 110
 111 (defcustom help-downcase-arguments nil
 112   "If non-nil, argument names in *Help* buffers are downcased."
 113   :type 'boolean
 114   :group 'help
 115   :version "23.2")
 116
 117 (defun help-highlight-arg (arg)
 118   "Highlight ARG as an argument name for a *Help* buffer.
 119 Return ARG in face `help-argument-name'; ARG is also downcased
 120 if the variable `help-downcase-arguments' is non-nil."
 121   (propertize (if help-downcase-arguments (downcase arg) arg)
 122               'face 'help-argument-name))
 123
 124 (defun help-do-arg-highlight (doc args)
 125   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 126     (modify-syntax-entry ?\- "w")
 127     (dolist (arg args)
 128       (setq doc (replace-regexp-in-string
 129                  ;; This is heuristic, but covers all common cases
 130                  ;; except ARG1-ARG2
 131                  (concat "\\<"                   ; beginning of word
 132                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 133                          "\\("
 134                          (regexp-quote arg)
 135                          "\\)"
 136                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 137                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 138                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 139                          "\\>")                  ; end of word
 140                  (help-highlight-arg arg)
 141                  doc t t 1)))
 142     doc))
 143
 144 (defun help-highlight-arguments (usage doc &rest args)
 145   (when (and usage (string-match "^(" usage))
 146     (with-temp-buffer
 147       (insert usage)
 148       (goto-char (point-min))
 149       (let ((case-fold-search nil)
 150             (next (not (or args (looking-at "\\["))))
 151             (opt nil))
 152         ;; Make a list of all arguments
 153         (skip-chars-forward "^ ")
 154         (while next
 155           (or opt (not (looking-at " &")) (setq opt t))
 156           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 157               (setq next nil)
 158             (setq args (cons (match-string 2) args))
 159             (when (and opt (string= (match-string 1) "("))
 160               ;; A pesky CL-style optional argument with default value,
 161               ;; so let's skip over it
 162               (search-backward "(")
 163               (goto-char (scan-sexps (point) 1)))))
 164         ;; Highlight arguments in the USAGE string
 165         (setq usage (help-do-arg-highlight (buffer-string) args))
 166         ;; Highlight arguments in the DOC string
 167         (setq doc (and doc (help-do-arg-highlight doc args))))))
 168   ;; Return value is like the one from help-split-fundoc, but highlighted
 169   (cons usage doc))
 170
 171 ;; The following function was compiled from the former functions
 172 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 173 ;; some excerpts from `describe-function-1' and `describe-variable'.
 174 ;; The only additional twists provided are (1) locate the defining file
 175 ;; for autoloaded functions, and (2) give preference to files in the
 176 ;; "install directory" (directories found via `load-path') rather than
 177 ;; to files in the "compile directory" (directories found by searching
 178 ;; the loaddefs.el file).  We autoload it because it's also used by
 179 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 180
 181 ;;;###autoload
 182 (defun find-lisp-object-file-name (object type)
 183   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 184 OBJECT should be a symbol associated with a function, variable, or face;
 185   alternatively, it can be a function definition.
 186 If TYPE is `defvar', search for a variable definition.
 187 If TYPE is `defface', search for a face definition.
 188 If TYPE is not a symbol, search for a function definition.
 189
 190 The return value is the absolute name of a readable file where OBJECT is
 191 defined.  If several such files exist, preference is given to a file
 192 found via `load-path'.  The return value can also be `C-source', which
 193 means that OBJECT is a function or variable defined in C.  If no
 194 suitable file is found, return nil."
 195   (let* ((autoloaded (autoloadp type))
 196          (file-name (or (and autoloaded (nth 1 type))
 197                         (symbol-file
 198                          ;; FIXME: Why do we have this weird "If TYPE is the
 199                          ;; value returned by `symbol-function' for a function
 200                          ;; symbol" exception?
 201                          object (or (if (symbolp type) type) 'defun)))))
 202     (cond
 203      (autoloaded
 204       ;; An autoloaded function: Locate the file since `symbol-function'
 205       ;; has only returned a bare string here.
 206       (setq file-name
 207             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 208      ((and (stringp file-name)
 209            (string-match "[.]*loaddefs.el\\'" file-name))
 210       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 211       ;; and try to extract the defining file.  The following form is
 212       ;; from `describe-function-1' and `describe-variable'.
 213       (let ((location
 214              (condition-case nil
 215                  (find-function-search-for-symbol object nil file-name)
 216                (error nil))))
 217         (when (cdr location)
 218           (with-current-buffer (car location)
 219             (goto-char (cdr location))
 220             (when (re-search-backward
 221                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 222               (setq file-name
 223                     (locate-file
 224                      (file-name-sans-extension
 225                       (match-string-no-properties 1))
 226                      load-path '(".el" ".elc") 'readable))))))))
 227
 228     (cond
 229      ((and (not file-name) (subrp type))
 230       ;; A built-in function.  The form is from `describe-function-1'.
 231       (if (get-buffer " *DOC*")
 232           (help-C-file-name type 'subr)
 233         'C-source))
 234      ((and (not file-name) (symbolp object)
 235            (integerp (get object 'variable-documentation)))
 236       ;; A variable defined in C.  The form is from `describe-variable'.
 237       (if (get-buffer " *DOC*")
 238           (help-C-file-name object 'var)
 239         'C-source))
 240      ((not (stringp file-name))
 241       ;; If we don't have a file-name string by now, we lost.
 242       nil)
 243      ;; Now, `file-name' should have become an absolute file name.
 244      ;; For files loaded from ~/.foo.elc, try ~/.foo.
 245      ;; This applies to config files like ~/.emacs,
 246      ;; which people sometimes compile.
 247      ((let (fn)
 248         (and (string-match "\\`\\..*\\.elc\\'"
 249                            (file-name-nondirectory file-name))
 250              (string-equal (file-name-directory file-name)
 251                            (file-name-as-directory (expand-file-name "~")))
 252              (file-readable-p (setq fn (file-name-sans-extension file-name)))
 253              fn)))
 254      ;; When the Elisp source file can be found in the install
 255      ;; directory, return the name of that file.
 256      ((let ((lib-name
 257              (if (string-match "[.]elc\\'" file-name)
 258                  (substring-no-properties file-name 0 -1)
 259                file-name)))
 260         (or (and (file-readable-p lib-name) lib-name)
 261             ;; The library might be compressed.
 262             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 263      ((let* ((lib-name (file-name-nondirectory file-name))
 264              ;; The next form is from `describe-simplify-lib-file-name'.
 265              (file-name
 266               ;; Try converting the absolute file name to a library
 267               ;; name, convert that back to a file name and see if we
 268               ;; get the original one.  If so, they are equivalent.
 269               (if (equal file-name (locate-file lib-name load-path '("")))
 270                   (if (string-match "[.]elc\\'" lib-name)
 271                       (substring-no-properties lib-name 0 -1)
 272                     lib-name)
 273                 file-name))
 274              ;; The next three forms are from `find-source-lisp-file'.
 275              (elc-file (locate-file
 276                         (concat file-name
 277                                 (if (string-match "\\.el\\'" file-name)
 278                                     "c"
 279                                   ".elc"))
 280                         load-path nil 'readable))
 281              (str (when elc-file
 282                     (with-temp-buffer
 283                       (insert-file-contents-literally elc-file nil 0 256)
 284                       (buffer-string))))
 285              (src-file (and str
 286                             (string-match ";;; from file \\(.*\\.el\\)" str)
 287                             (match-string 1 str))))
 288         (and src-file (file-readable-p src-file) src-file))))))
 289
 290 (defun help-fns--key-bindings (function)
 291   (when (commandp function)
 292     (let ((pt2 (with-current-buffer standard-output (point)))
 293           (remapped (command-remapping function)))
 294       (unless (memq remapped '(ignore undefined))
 295         (let ((keys (where-is-internal
 296                      (or remapped function) overriding-local-map nil nil))
 297               non-modified-keys)
 298           (if (and (eq function 'self-insert-command)
 299                    (vectorp (car-safe keys))
 300                    (consp (aref (car keys) 0)))
 301               (princ "It is bound to many ordinary text characters.\n")
 302             ;; Which non-control non-meta keys run this command?
 303             (dolist (key keys)
 304               (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 305                   (push key non-modified-keys)))
 306             (when remapped
 307               (princ "Its keys are remapped to ")
 308               (princ (if (symbolp remapped)
 309                          (concat "`" (symbol-name remapped) "'")
 310                        "an anonymous command"))
 311               (princ ".\n"))
 312
 313             (when keys
 314               (princ (if remapped
 315                          "Without this remapping, it would be bound to "
 316                        "It is bound to "))
 317               ;; If lots of ordinary text characters run this command,
 318               ;; don't mention them one by one.
 319               (if (< (length non-modified-keys) 10)
 320                   (princ (mapconcat 'key-description keys ", "))
 321                 (dolist (key non-modified-keys)
 322                   (setq keys (delq key keys)))
 323                 (if keys
 324                     (progn
 325                       (princ (mapconcat 'key-description keys ", "))
 326                       (princ ", and many ordinary text characters"))
 327                   (princ "many ordinary text characters"))))
 328             (when (or remapped keys non-modified-keys)
 329               (princ ".")
 330               (terpri)))))
 331
 332       (with-current-buffer standard-output
 333         (fill-region-as-paragraph pt2 (point))
 334         (unless (looking-back "\n\n" (- (point) 2))
 335           (terpri))))))
 336
 337 (defun help-fns--compiler-macro (function)
 338   (let ((handler (function-get function 'compiler-macro)))
 339     (when handler
 340       (insert "\nThis function has a compiler macro")
 341       (if (symbolp handler)
 342           (progn
 343             (insert (format " `%s'" handler))
 344             (save-excursion
 345               (re-search-backward "`\\([^`']+\\)'" nil t)
 346               (help-xref-button 1 'help-function handler)))
 347         ;; FIXME: Obsolete since 24.4.
 348         (let ((lib (get function 'compiler-macro-file)))
 349           (when (stringp lib)
 350             (insert (format " in `%s'" lib))
 351             (save-excursion
 352               (re-search-backward "`\\([^`']+\\)'" nil t)
 353               (help-xref-button 1 'help-function-cmacro function lib)))))
 354       (insert ".\n"))))
 355
 356 (defun help-fns--signature (function doc real-def real-function)
 357   "Insert usage at point and return docstring.  With highlighting."
 358   (if (keymapp function)
 359       doc                       ; If definition is a keymap, skip arglist note.
 360     (let* ((advertised (gethash real-def advertised-signature-table t))
 361            (arglist (if (listp advertised)
 362                         advertised (help-function-arglist real-def)))
 363            (usage (help-split-fundoc doc function)))
 364       (if usage (setq doc (cdr usage)))
 365       (let* ((use (cond
 366                    ((and usage (not (listp advertised))) (car usage))
 367                    ((listp arglist)
 368                     (format "%S" (help-make-usage function arglist)))
 369                    ((stringp arglist) arglist)
 370                    ;; Maybe the arglist is in the docstring of a symbol
 371                    ;; this one is aliased to.
 372                    ((let ((fun real-function))
 373                       (while (and (symbolp fun)
 374                                   (setq fun (symbol-function fun))
 375                                   (not (setq usage (help-split-fundoc
 376                                                     (documentation fun)
 377                                                     function)))))
 378                       usage)
 379                     (car usage))
 380                    ((or (stringp real-def)
 381                         (vectorp real-def))
 382                     (format "\nMacro: %s" (format-kbd-macro real-def)))
 383                    (t "[Missing arglist.  Please make a bug report.]")))
 384              (high (help-highlight-arguments use doc)))
 385         (let ((fill-begin (point)))
 386           (insert (car high) "\n")
 387           (fill-region fill-begin (point)))
 388         (cdr high)))))
 389
 390 (defun help-fns--parent-mode (function)
 391   ;; If this is a derived mode, link to the parent.
 392   (let ((parent-mode (and (symbolp function)
 393                           (get function
 394                                'derived-mode-parent))))
 395     (when parent-mode
 396       (insert "\nParent mode: `")
 397       (let ((beg (point)))
 398         (insert (format "%s" parent-mode))
 399         (make-text-button beg (point)
 400                           'type 'help-function
 401                           'help-args (list parent-mode)))
 402       (insert "'.\n"))))
 403
 404 (defun help-fns--obsolete (function)
 405   ;; Ignore lambda constructs, keyboard macros, etc.
 406   (let* ((obsolete (and (symbolp function)
 407                         (get function 'byte-obsolete-info)))
 408          (use (car obsolete)))
 409     (when obsolete
 410       (insert "\nThis "
 411               (if (eq (car-safe (symbol-function function)) 'macro)
 412                   "macro"
 413                 "function")
 414               " is obsolete")
 415       (when (nth 2 obsolete)
 416         (insert (format " since %s" (nth 2 obsolete))))
 417       (insert (cond ((stringp use) (concat ";\n" use))
 418                     (use (format ";\nuse `%s' instead." use))
 419                     (t "."))
 420               "\n"))))
 421
 422 ;; We could use `symbol-file' but this is a wee bit more efficient.
 423 (defun help-fns--autoloaded-p (function file)
 424   "Return non-nil if FUNCTION has previously been autoloaded.
 425 FILE is the file where FUNCTION was probably defined."
 426   (let* ((file (file-name-sans-extension (file-truename file)))
 427          (load-hist load-history)
 428          (target (cons t function))
 429          found)
 430     (while (and load-hist (not found))
 431       (and (caar load-hist)
 432            (equal (file-name-sans-extension (caar load-hist)) file)
 433            (setq found (member target (cdar load-hist))))
 434       (setq load-hist (cdr load-hist)))
 435     found))
 436
 437 (defun help-fns--interactive-only (function)
 438   "Insert some help blurb if FUNCTION should only be used interactively."
 439   ;; Ignore lambda constructs, keyboard macros, etc.
 440   (and (symbolp function)
 441        (not (eq (car-safe (symbol-function function)) 'macro))
 442        (let* ((interactive-only
 443                (or (get function 'interactive-only)
 444                    (if (boundp 'byte-compile-interactive-only-functions)
 445                        (memq function
 446                              byte-compile-interactive-only-functions)))))
 447          (when interactive-only
 448            (insert "\nThis function is for interactive use only"
 449                    ;; Cf byte-compile-form.
 450                    (cond ((stringp interactive-only)
 451                           (format ";\nin Lisp code %s" interactive-only))
 452                          ((and (symbolp 'interactive-only)
 453                                (not (eq interactive-only t)))
 454                           (format ";\nin Lisp code use `%s' instead."
 455                                   interactive-only))
 456                          (t "."))
 457                    "\n")))))
 458
 459 (defun help-fns-short-filename (filename)
 460   (let* ((abbrev (abbreviate-file-name filename))
 461          (short abbrev))
 462     (dolist (dir load-path)
 463       (let ((rel (file-relative-name filename dir)))
 464         (if (< (length rel) (length short))
 465             (setq short rel)))
 466       (let ((rel (file-relative-name abbrev dir)))
 467         (if (< (length rel) (length short))
 468             (setq short rel))))
 469     short))
 470
 471 ;;;###autoload
 472 (defun describe-function-1 (function)
 473   (let* ((advised (and (symbolp function)
 474                        (featurep 'nadvice)
 475                        (advice--p (advice--symbol-function function))))
 476          ;; If the function is advised, use the symbol that has the
 477          ;; real definition, if that symbol is already set up.
 478          (real-function
 479           (or (and advised
 480                    (advice--cd*r (advice--symbol-function function)))
 481               function))
 482          ;; Get the real definition.
 483          (def (if (symbolp real-function)
 484                   (or (symbol-function real-function)
 485                       (signal 'void-function (list real-function)))
 486                 real-function))
 487          (aliased (or (symbolp def)
 488                       ;; Advised & aliased function.
 489                       (and advised (symbolp real-function))))
 490          (real-def (cond
 491                     (aliased (let ((f real-function))
 492                                (while (and (fboundp f)
 493                                            (symbolp (symbol-function f)))
 494                                  (setq f (symbol-function f)))
 495                                f))
 496                     ((subrp def) (intern (subr-name def)))
 497                     (t def)))
 498          (sig-key (if (subrp def)
 499                       (indirect-function real-def)
 500                     real-def))
 501          (file-name (find-lisp-object-file-name function def))
 502          (pt1 (with-current-buffer (help-buffer) (point)))
 503          (beg (if (and (or (byte-code-function-p def)
 504                            (keymapp def)
 505                            (memq (car-safe def) '(macro lambda closure)))
 506                        (stringp file-name)
 507                        (help-fns--autoloaded-p function file-name))
 508                   (if (commandp def)
 509                       "an interactive autoloaded "
 510                     "an autoloaded ")
 511                 (if (commandp def) "an interactive " "a "))))
 512
 513     ;; Print what kind of function-like object FUNCTION is.
 514     (princ (cond ((or (stringp def) (vectorp def))
 515                   "a keyboard macro")
 516                  ((subrp def)
 517                   (if (eq 'unevalled (cdr (subr-arity def)))
 518                       (concat beg "special form")
 519                     (concat beg "built-in function")))
 520                  ;; Aliases are Lisp functions, so we need to check
 521                  ;; aliases before functions.
 522                  (aliased
 523                   (format "an alias for `%s'" real-def))
 524                  ((autoloadp def)
 525                   (format "%s autoloaded %s"
 526                           (if (commandp def) "an interactive" "an")
 527                           (if (eq (nth 4 def) 'keymap) "keymap"
 528                             (if (nth 4 def) "Lisp macro" "Lisp function"))))
 529                  ((or (eq (car-safe def) 'macro)
 530                       ;; For advised macros, def is a lambda
 531                       ;; expression or a byte-code-function-p, so we
 532                       ;; need to check macros before functions.
 533                       (macrop function))
 534                   (concat beg "Lisp macro"))
 535                  ((byte-code-function-p def)
 536                   (concat beg "compiled Lisp function"))
 537                  ((eq (car-safe def) 'lambda)
 538                   (concat beg "Lisp function"))
 539                  ((eq (car-safe def) 'closure)
 540                   (concat beg "Lisp closure"))
 541                  ((keymapp def)
 542                   (let ((is-full nil)
 543                         (elts (cdr-safe def)))
 544                     (while elts
 545                       (if (char-table-p (car-safe elts))
 546                           (setq is-full t
 547                                 elts nil))
 548                       (setq elts (cdr-safe elts)))
 549                     (concat beg (if is-full "keymap" "sparse keymap"))))
 550                  (t "")))
 551
 552     (if (and aliased (not (fboundp real-def)))
 553         (princ ",\nwhich is not defined.  Please make a bug report.")
 554       (with-current-buffer standard-output
 555         (save-excursion
 556           (save-match-data
 557             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 558               (help-xref-button 1 'help-function real-def)))))
 559
 560       (when file-name
 561         (princ " in `")
 562         ;; We used to add .el to the file name,
 563         ;; but that's completely wrong when the user used load-file.
 564         (princ (if (eq file-name 'C-source)
 565                    "C source code"
 566                  (help-fns-short-filename file-name)))
 567         (princ "'")
 568         ;; Make a hyperlink to the library.
 569         (with-current-buffer standard-output
 570           (save-excursion
 571             (re-search-backward "`\\([^`']+\\)'" nil t)
 572             (help-xref-button 1 'help-function-def function file-name))))
 573       (princ ".")
 574       (with-current-buffer (help-buffer)
 575         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 576                                   (point)))
 577       (terpri)(terpri)
 578
 579       (let* ((doc-raw (documentation function t))
 580              ;; If the function is autoloaded, and its docstring has
 581              ;; key substitution constructs, load the library.
 582              (doc (progn
 583                     (and (autoloadp real-def) doc-raw
 584                          help-enable-auto-load
 585                          (string-match "\\([^\\]=\\|[^=]\\|\\`\\)\\\\[[{<]"
 586                                        doc-raw)
 587                          (autoload-do-load real-def))
 588                     (substitute-command-keys doc-raw))))
 589
 590         (help-fns--key-bindings function)
 591         (with-current-buffer standard-output
 592           (setq doc (help-fns--signature function doc sig-key real-function))
 593           (run-hook-with-args 'help-fns-describe-function-functions function)
 594           (insert "\n"
 595                   (or doc "Not documented.")))))))
 596
 597 ;; Add defaults to `help-fns-describe-function-functions'.
 598 (add-hook 'help-fns-describe-function-functions #'help-fns--obsolete)
 599 (add-hook 'help-fns-describe-function-functions #'help-fns--interactive-only)
 600 (add-hook 'help-fns-describe-function-functions #'help-fns--parent-mode)
 601 (add-hook 'help-fns-describe-function-functions #'help-fns--compiler-macro)
 602
 603 \f
 604 ;; Variables
 605
 606 ;;;###autoload
 607 (defun variable-at-point (&optional any-symbol)
 608   "Return the bound variable symbol found at or before point.
 609 Return 0 if there is no such symbol.
 610 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 611   (with-syntax-table emacs-lisp-mode-syntax-table
 612     (or (condition-case ()
 613             (save-excursion
 614               (skip-chars-forward "'")
 615               (or (not (zerop (skip-syntax-backward "_w")))
 616                   (eq (char-syntax (following-char)) ?w)
 617                   (eq (char-syntax (following-char)) ?_)
 618                   (forward-sexp -1))
 619               (skip-chars-forward "'")
 620               (let ((obj (read (current-buffer))))
 621                 (and (symbolp obj) (boundp obj) obj)))
 622           (error nil))
 623         (let* ((str (find-tag-default))
 624                (sym (if str (intern-soft str))))
 625           (if (and sym (or any-symbol (boundp sym)))
 626               sym
 627             (save-match-data
 628               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 629                 (setq sym (intern-soft (match-string 1 str)))
 630                 (and (or any-symbol (boundp sym)) sym)))))
 631         0)))
 632
 633 (defun describe-variable-custom-version-info (variable)
 634   (let ((custom-version (get variable 'custom-version))
 635         (cpv (get variable 'custom-package-version))
 636         (output nil))
 637     (if custom-version
 638         (setq output
 639               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 640                       custom-version))
 641       (when cpv
 642         (let* ((package (car-safe cpv))
 643                (version (if (listp (cdr-safe cpv))
 644                             (car (cdr-safe cpv))
 645                           (cdr-safe cpv)))
 646                (pkg-versions (assq package customize-package-emacs-version-alist))
 647                (emacsv (cdr (assoc version pkg-versions))))
 648           (if (and package version)
 649               (setq output
 650                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 651                                     (if emacsv
 652                                         (format " that is part of Emacs %s" emacsv))
 653                                     ".\n")
 654                             version package))))))
 655     output))
 656
 657 ;;;###autoload
 658 (defun describe-variable (variable &optional buffer frame)
 659   "Display the full documentation of VARIABLE (a symbol).
 660 Returns the documentation as a string, also.
 661 If VARIABLE has a buffer-local value in BUFFER or FRAME
 662 \(default to the current buffer and current frame),
 663 it is displayed along with the global value."
 664   (interactive
 665    (let ((v (variable-at-point))
 666          (enable-recursive-minibuffers t)
 667          val)
 668      (setq val (completing-read (if (symbolp v)
 669                                     (format
 670                                      "Describe variable (default %s): " v)
 671                                   "Describe variable: ")
 672                                 obarray
 673                                 (lambda (vv)
 674                                   (or (get vv 'variable-documentation)
 675                                       (and (boundp vv) (not (keywordp vv)))))
 676                                 t nil nil
 677                                 (if (symbolp v) (symbol-name v))))
 678      (list (if (equal val "")
 679                v (intern val)))))
 680   (let (file-name)
 681     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 682     (unless (frame-live-p frame) (setq frame (selected-frame)))
 683     (if (not (symbolp variable))
 684         (message "You did not specify a variable")
 685       (save-excursion
 686         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 687               (permanent-local (get variable 'permanent-local))
 688               val val-start-pos locus)
 689           ;; Extract the value before setting up the output buffer,
 690           ;; in case `buffer' *is* the output buffer.
 691           (unless valvoid
 692             (with-selected-frame frame
 693               (with-current-buffer buffer
 694                 (setq val (symbol-value variable)
 695                       locus (variable-binding-locus variable)))))
 696           (help-setup-xref (list #'describe-variable variable buffer)
 697                            (called-interactively-p 'interactive))
 698           (with-help-window (help-buffer)
 699             (with-current-buffer buffer
 700               (prin1 variable)
 701               (setq file-name (find-lisp-object-file-name variable 'defvar))
 702
 703               (if file-name
 704                   (progn
 705                     (princ " is a variable defined in `")
 706                     (princ (if (eq file-name 'C-source)
 707                                "C source code"
 708                              (file-name-nondirectory file-name)))
 709                     (princ "'.\n")
 710                     (with-current-buffer standard-output
 711                       (save-excursion
 712                         (re-search-backward "`\\([^`']+\\)'" nil t)
 713                         (help-xref-button 1 'help-variable-def
 714                                           variable file-name)))
 715                     (if valvoid
 716                         (princ "It is void as a variable.")
 717                       (princ "Its ")))
 718                 (if valvoid
 719                     (princ " is void as a variable.")
 720                   (princ "'s "))))
 721             (unless valvoid
 722               (with-current-buffer standard-output
 723                 (setq val-start-pos (point))
 724                 (princ "value is ")
 725                 (let ((from (point))
 726                       (line-beg (line-beginning-position))
 727                       (print-rep
 728                        (let ((print-quoted t))
 729                          (prin1-to-string val))))
 730                   (if (< (+ (length print-rep) (point) (- line-beg)) 68)
 731                       (insert print-rep)
 732                     (terpri)
 733                     (pp val)
 734                     (if (< (point) (+ 68 (line-beginning-position 0)))
 735                         (delete-region from (1+ from))
 736                       (delete-region (1- from) from)))
 737                   (let* ((sv (get variable 'standard-value))
 738                          (origval (and (consp sv)
 739                                        (condition-case nil
 740                                            (eval (car sv))
 741                                          (error :help-eval-error)))))
 742                     (when (and (consp sv)
 743                                (not (equal origval val))
 744                                (not (equal origval :help-eval-error)))
 745                       (princ "\nOriginal value was \n")
 746                       (setq from (point))
 747                       (pp origval)
 748                       (if (< (point) (+ from 20))
 749                           (delete-region (1- from) from)))))))
 750             (terpri)
 751             (when locus
 752               (cond
 753                ((bufferp locus)
 754                 (princ (format "Local in buffer %s; "
 755                                (buffer-name buffer))))
 756                ((framep locus)
 757                 (princ (format "It is a frame-local variable; ")))
 758                ((terminal-live-p locus)
 759                 (princ (format "It is a terminal-local variable; ")))
 760                (t
 761                 (princ (format "It is local to %S" locus))))
 762               (if (not (default-boundp variable))
 763                   (princ "globally void")
 764                 (let ((global-val (default-value variable)))
 765                   (with-current-buffer standard-output
 766                     (princ "global value is ")
 767                     (if (eq val global-val)
 768                         (princ "the same.")
 769                       (terpri)
 770                       ;; Fixme: pp can take an age if you happen to
 771                       ;; ask for a very large expression.  We should
 772                       ;; probably print it raw once and check it's a
 773                       ;; sensible size before prettyprinting.  -- fx
 774                       (let ((from (point)))
 775                         (pp global-val)
 776                         ;; See previous comment for this function.
 777                         ;; (help-xref-on-pp from (point))
 778                         (if (< (point) (+ from 20))
 779                             (delete-region (1- from) from)))))))
 780               (terpri))
 781
 782             ;; If the value is large, move it to the end.
 783             (with-current-buffer standard-output
 784               (when (> (count-lines (point-min) (point-max)) 10)
 785                 ;; Note that setting the syntax table like below
 786                 ;; makes forward-sexp move over a `'s' at the end
 787                 ;; of a symbol.
 788                 (set-syntax-table emacs-lisp-mode-syntax-table)
 789                 (goto-char val-start-pos)
 790                 ;; The line below previously read as
 791                 ;; (delete-region (point) (progn (end-of-line) (point)))
 792                 ;; which suppressed display of the buffer local value for
 793                 ;; large values.
 794                 (when (looking-at "value is") (replace-match ""))
 795                 (save-excursion
 796                   (insert "\n\nValue:")
 797                   (set (make-local-variable 'help-button-cache)
 798                        (point-marker)))
 799                 (insert "value is shown ")
 800                 (insert-button "below"
 801                                'action help-button-cache
 802                                'follow-link t
 803                                'help-echo "mouse-2, RET: show value")
 804                 (insert ".\n")))
 805             (terpri)
 806
 807             (let* ((alias (condition-case nil
 808                               (indirect-variable variable)
 809                             (error variable)))
 810                    (obsolete (get variable 'byte-obsolete-variable))
 811                    (use (car obsolete))
 812                    (safe-var (get variable 'safe-local-variable))
 813                    (doc (or (documentation-property
 814                              variable 'variable-documentation)
 815                             (documentation-property
 816                              alias 'variable-documentation)))
 817                    (extra-line nil))
 818
 819               ;; Mention if it's a local variable.
 820               (cond
 821                ((and (local-variable-if-set-p variable)
 822                      (or (not (local-variable-p variable))
 823                          (with-temp-buffer
 824                            (local-variable-if-set-p variable))))
 825                 (setq extra-line t)
 826                 (princ "  Automatically becomes ")
 827                 (if permanent-local
 828                     (princ "permanently "))
 829                 (princ "buffer-local when set.\n"))
 830                ((not permanent-local))
 831                ((bufferp locus)
 832                 (setq extra-line t)
 833                 (princ "  This variable's buffer-local value is permanent.\n"))
 834                (t
 835                 (setq extra-line t)
 836                 (princ "  This variable's value is permanent \
 837 if it is given a local binding.\n")))
 838
 839               ;; Mention if it's an alias.
 840               (unless (eq alias variable)
 841                 (setq extra-line t)
 842                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 843
 844               (when obsolete
 845                 (setq extra-line t)
 846                 (princ "  This variable is obsolete")
 847                 (if (nth 2 obsolete)
 848                     (princ (format " since %s" (nth 2 obsolete))))
 849                 (princ (cond ((stringp use) (concat ";\n  " use))
 850                              (use (format ";\n  use `%s' instead." (car obsolete)))
 851                              (t ".")))
 852                 (terpri))
 853
 854               (when (member (cons variable val)
 855                             (with-current-buffer buffer
 856                               file-local-variables-alist))
 857                 (setq extra-line t)
 858                 (if (member (cons variable val)
 859                              (with-current-buffer buffer
 860                                dir-local-variables-alist))
 861                     (let ((file (and (buffer-file-name buffer)
 862                                       (not (file-remote-p
 863                                             (buffer-file-name buffer)))
 864                                       (dir-locals-find-file
 865                                        (buffer-file-name buffer))))
 866                           (dir-file t))
 867                       (princ "  This variable's value is directory-local")
 868                       (if (null file)
 869                           (princ ".\n")
 870                         (princ ", set ")
 871                         (if (consp file) ; result from cache
 872                             ;; If the cache element has an mtime, we
 873                             ;; assume it came from a file.
 874                             (if (nth 2 file)
 875                                 (setq file (expand-file-name
 876                                             dir-locals-file (car file)))
 877                               ;; Otherwise, assume it was set directly.
 878                               (setq file (car file)
 879                                     dir-file nil)))
 880                         (princ (if dir-file
 881                                    "by the file\n  `"
 882                                  "for the directory\n  `"))
 883                         (with-current-buffer standard-output
 884                           (insert-text-button
 885                            file 'type 'help-dir-local-var-def
 886                            'help-args (list variable file)))
 887                         (princ "'.\n")))
 888                   (princ "  This variable's value is file-local.\n")))
 889
 890               (when (memq variable ignored-local-variables)
 891                 (setq extra-line t)
 892                 (princ "  This variable is ignored as a file-local \
 893 variable.\n"))
 894
 895               ;; Can be both risky and safe, eg auto-fill-function.
 896               (when (risky-local-variable-p variable)
 897                 (setq extra-line t)
 898                 (princ "  This variable may be risky if used as a \
 899 file-local variable.\n")
 900                 (when (assq variable safe-local-variable-values)
 901                   (princ "  However, you have added it to \
 902 `safe-local-variable-values'.\n")))
 903
 904               (when safe-var
 905                 (setq extra-line t)
 906                 (princ "  This variable is safe as a file local variable ")
 907                 (princ "if its value\n  satisfies the predicate ")
 908                 (princ (if (byte-code-function-p safe-var)
 909                            "which is a byte-compiled expression.\n"
 910                          (format "`%s'.\n" safe-var))))
 911
 912               (if extra-line (terpri))
 913               (princ "Documentation:\n")
 914               (with-current-buffer standard-output
 915                 (insert (or doc "Not documented as a variable."))))
 916
 917             ;; Make a link to customize if this variable can be customized.
 918             (when (custom-variable-p variable)
 919               (let ((customize-label "customize"))
 920                 (terpri)
 921                 (terpri)
 922                 (princ (concat "You can " customize-label " this variable."))
 923                 (with-current-buffer standard-output
 924                   (save-excursion
 925                     (re-search-backward
 926                      (concat "\\(" customize-label "\\)") nil t)
 927                     (help-xref-button 1 'help-customize-variable variable))))
 928               ;; Note variable's version or package version
 929               (let ((output (describe-variable-custom-version-info variable)))
 930                 (when output
 931                   (terpri)
 932                   (terpri)
 933                   (princ output))))
 934
 935             (with-current-buffer standard-output
 936               ;; Return the text we displayed.
 937               (buffer-string))))))))
 938
 939
 940 ;;;###autoload
 941 (defun describe-function-or-variable (symbol &optional buffer frame)
 942   "Display the full documentation of the function or variable SYMBOL.
 943 If SYMBOL is a variable and has a buffer-local value in BUFFER or FRAME
 944 \(default to the current buffer and current frame), it is displayed along
 945 with the global value."
 946   (interactive
 947    (let* ((v-or-f (variable-at-point))
 948           (found (symbolp v-or-f))
 949           (v-or-f (if found v-or-f (function-called-at-point)))
 950           (found (or found v-or-f))
 951           (enable-recursive-minibuffers t)
 952           val)
 953      (setq val (completing-read (if found
 954                                     (format
 955                                         "Describe function or variable (default %s): " v-or-f)
 956                                   "Describe function or variable: ")
 957                                 obarray
 958                                 (lambda (vv)
 959                                   (or (fboundp vv)
 960                                       (get vv 'variable-documentation)
 961                                       (and (boundp vv) (not (keywordp vv)))))
 962                                 t nil nil
 963                                 (if found (symbol-name v-or-f))))
 964      (list (if (equal val "")
 965                v-or-f (intern val)))))
 966   (if (not (symbolp symbol)) (message "You didn't specify a function or variable")
 967     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 968     (unless (frame-live-p frame) (setq frame (selected-frame)))
 969     (help-xref-interned symbol buffer frame)))
 970
 971 ;;;###autoload
 972 (defun describe-syntax (&optional buffer)
 973   "Describe the syntax specifications in the syntax table of BUFFER.
 974 The descriptions are inserted in a help buffer, which is then displayed.
 975 BUFFER defaults to the current buffer."
 976   (interactive)
 977   (setq buffer (or buffer (current-buffer)))
 978   (help-setup-xref (list #'describe-syntax buffer)
 979                    (called-interactively-p 'interactive))
 980   (with-help-window (help-buffer)
 981     (let ((table (with-current-buffer buffer (syntax-table))))
 982       (with-current-buffer standard-output
 983         (describe-vector table 'internal-describe-syntax-value)
 984         (while (setq table (char-table-parent table))
 985           (insert "\nThe parent syntax table is:")
 986           (describe-vector table 'internal-describe-syntax-value))))))
 987
 988 (defun help-describe-category-set (value)
 989   (insert (cond
 990            ((null value) "default")
 991            ((char-table-p value) "deeper char-table ...")
 992            (t (condition-case nil
 993                   (category-set-mnemonics value)
 994                 (error "invalid"))))))
 995
 996 ;;;###autoload
 997 (defun describe-categories (&optional buffer)
 998   "Describe the category specifications in the current category table.
 999 The descriptions are inserted in a buffer, which is then displayed.
1000 If BUFFER is non-nil, then describe BUFFER's category table instead.
1001 BUFFER should be a buffer or a buffer name."
1002   (interactive)
1003   (setq buffer (or buffer (current-buffer)))
1004   (help-setup-xref (list #'describe-categories buffer)
1005                    (called-interactively-p 'interactive))
1006   (with-help-window (help-buffer)
1007     (let* ((table (with-current-buffer buffer (category-table)))
1008            (docs (char-table-extra-slot table 0)))
1009       (if (or (not (vectorp docs)) (/= (length docs) 95))
1010           (error "Invalid first extra slot in this category table\n"))
1011       (with-current-buffer standard-output
1012         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
1013         (let ((pos (point)) (items 0) lines n)
1014           (dotimes (i 95)
1015             (if (aref docs i) (setq items (1+ items))))
1016           (setq lines (1+ (/ (1- items) 4)))
1017           (setq n 0)
1018           (dotimes (i 95)
1019             (let ((elt (aref docs i)))
1020               (when elt
1021                 (string-match ".*" elt)
1022                 (setq elt (match-string 0 elt))
1023                 (if (>= (length elt) 17)
1024                     (setq elt (concat (substring elt 0 14) "...")))
1025                 (if (< (point) (point-max))
1026                     (move-to-column (* 20 (/ n lines)) t))
1027                 (insert (+ i ?\s) ?: elt)
1028                 (if (< (point) (point-max))
1029                     (forward-line 1)
1030                   (insert "\n"))
1031                 (setq n (1+ n))
1032                 (if (= (% n lines) 0)
1033                     (goto-char pos))))))
1034         (goto-char (point-max))
1035         (insert "\n"
1036                 "character(s)\tcategory mnemonics\n"
1037                 "------------\t------------------")
1038         (describe-vector table 'help-describe-category-set)
1039         (insert "Legend of category mnemonics:\n")
1040         (dotimes (i 95)
1041           (let ((elt (aref docs i)))
1042             (when elt
1043               (if (string-match "\n" elt)
1044                   (setq elt (substring elt (match-end 0))))
1045               (insert (+ i ?\s) ": " elt "\n"))))
1046         (while (setq table (char-table-parent table))
1047           (insert "\nThe parent category table is:")
1048           (describe-vector table 'help-describe-category-set))))))
1049
1050 \f
1051 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
1052
1053 ;; Replaces lib-src/digest-doc.c.
1054 ;;;###autoload
1055 (defun doc-file-to-man (file)
1056   "Produce an nroff buffer containing the doc-strings from the DOC file."
1057   (interactive (list (read-file-name "Name of DOC file: " doc-directory
1058                                      internal-doc-file-name t)))
1059   (or (file-readable-p file)
1060       (error "Cannot read file `%s'" file))
1061   (pop-to-buffer (generate-new-buffer "*man-doc*"))
1062   (setq buffer-undo-list t)
1063   (insert ".TH \"Command Summary for GNU Emacs\"\n"
1064           ".AU Richard M. Stallman\n")
1065   (insert-file-contents file)
1066   (let (notfirst)
1067     (while (search-forward "\x1f" nil 'move)
1068       (if (looking-at "S")
1069           (delete-region (1- (point)) (line-end-position))
1070         (delete-char -1)
1071         (if notfirst
1072             (insert "\n.DE\n")
1073           (setq notfirst t))
1074         (insert "\n.SH ")
1075         (insert (if (looking-at "F") "Function " "Variable "))
1076         (delete-char 1)
1077         (forward-line 1)
1078         (insert ".DS L\n"))))
1079   (insert "\n.DE\n")
1080   (setq buffer-undo-list nil)
1081   (nroff-mode))
1082
1083 ;; Replaces lib-src/sorted-doc.c.
1084 ;;;###autoload
1085 (defun doc-file-to-info (file)
1086   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
1087   (interactive (list (read-file-name "Name of DOC file: " doc-directory
1088                                      internal-doc-file-name t)))
1089   (or (file-readable-p file)
1090       (error "Cannot read file `%s'" file))
1091   (let ((i 0) type name doc alist)
1092     (with-temp-buffer
1093       (insert-file-contents file)
1094       ;; The characters "@{}" need special treatment.
1095       (while (re-search-forward "[@{}]" nil t)
1096         (backward-char)
1097         (insert "@")
1098         (forward-char 1))
1099       (goto-char (point-min))
1100       (while (search-forward "\x1f" nil t)
1101         (unless (looking-at "S")
1102           (setq type (char-after)
1103                 name (buffer-substring (1+ (point)) (line-end-position))
1104                 doc (buffer-substring (line-beginning-position 2)
1105                                       (if (search-forward  "\x1f" nil 'move)
1106                                           (1- (point))
1107                                         (point)))
1108                 alist (cons (list name type doc) alist))
1109           (backward-char 1))))
1110     (pop-to-buffer (generate-new-buffer "*info-doc*"))
1111     (setq buffer-undo-list t)
1112     ;; Write the output header.
1113     (insert "\\input texinfo  @c -*-texinfo-*-\n"
1114             "@setfilename emacsdoc.info\n"
1115             "@settitle Command Summary for GNU Emacs\n"
1116             "@finalout\n"
1117             "\n@node Top\n"
1118             "@unnumbered Command Summary for GNU Emacs\n\n"
1119             "@table @asis\n\n"
1120             "@iftex\n"
1121             "@global@let@ITEM@item\n"
1122             "@def@item{@filbreak@vskip5pt@ITEM}\n"
1123             "@font@tensy cmsy10 scaled @magstephalf\n"
1124             "@font@teni cmmi10 scaled @magstephalf\n"
1125             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
1126             "@def|{{@tensy@char106}}\n"
1127             "@def@{{{@tensy@char102}}\n"
1128             "@def@}{{@tensy@char103}}\n"
1129             "@def<{{@teni@char62}}\n"
1130             "@def>{{@teni@char60}}\n"
1131             "@chardef@@64\n"
1132             "@catcode43=12\n"
1133             "@tableindent-0.2in\n"
1134             "@end iftex\n")
1135     ;; Sort the array by name; within each name, by type (functions first).
1136     (setq alist (sort alist (lambda (e1 e2)
1137                               (if (string-equal (car e1) (car e2))
1138                                   (<= (cadr e1) (cadr e2))
1139                                 (string-lessp (car e1) (car e2))))))
1140     ;; Print each function.
1141     (dolist (e alist)
1142       (insert "\n@item "
1143               (if (char-equal (cadr e) ?\F) "Function" "Variable")
1144               " @code{" (car e) "}\n@display\n"
1145               (nth 2 e)
1146               "\n@end display\n")
1147       ;; Try to avoid a save size overflow in the TeX output routine.
1148       (if (zerop (setq i (% (1+ i) 100)))
1149           (insert "\n@end table\n@table @asis\n")))
1150     (insert "@end table\n"
1151             "@bye\n")
1152     (setq buffer-undo-list nil)
1153     (texinfo-mode)))
1154
1155 (provide 'help-fns)
1156
1157 ;;; help-fns.el ends here